data/qcsrc/server/gamec/t_items.c

   1 void Item_ClearRespawnEffect (void) {
   2         self.effects = self.effects - (self.effects & EF_STARDUST);
   3 }
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // Savage: Add simple Respawn effect and make sure it gets removed
  13         self.effects = self.effects | EF_STARDUST;
  14         self.think = Item_ClearRespawnEffect;
  15         self.nextthink = time + 0.1;
  16 }
  17
  18 void Item_Touch (void)
  19 {
  20         local entity oldself;
  21         local float _switchweapon;
  22
  23         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  24         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  25         {
  26                 remove(self);
  27                 return;
  28         }
  29         if (other.classname != "player")
  30                 return;
  31         if (other.deadflag)
  32                 return;
  33         if (self.solid != SOLID_TRIGGER)
  34                 return;
  35         if (self.health && other.health >= other.max_health)
  36                 return;
  37         if (self.owner == other)
  38                 return;
  39         // Savage: Remove the respawn effect if still present
  40         self.effects = self.effects - (self.effects & EF_STARDUST);
  41
  42         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  43
  44         // in case the player has autoswitch enabled do the following:
  45         // if the player is using their best weapon before items are given, they
  46         // probably want to switch to an even better weapon after items are given
  47         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  48
  49         if (cvar("g_minstagib"))
  50         {
  51                 if (self.ammo_cells)
  52                 {
  53                         // play some cool sounds ;)
  54                         centerprint(other, "\n");
  55                         if(other.health <= 5)
  56                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  57                         else if(other.health < 50)
  58                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  59                         // sound not available
  60                         // else if(self.items == IT_CELLS)
  61                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  62
  63                         if (self.items & IT_NEX)
  64                                 W_GiveWeapon (other, IT_NEX, "Nex");
  65                         if (self.ammo_cells)
  66                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  67                         other.health = 100;
  68                 }
  69
  70                 // extralife powerup
  71                 if (self.max_health)
  72                 {
  73                         // sound not available
  74                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  75                         other.extralives = other.extralives + cvar("g_minstagib_extralives");
  76                         other.armorvalue = other.extralives;
  77                         sprint(other, "^3You picked up some extra lives\n");
  78                 }
  79
  80                 // invis powerup
  81                 if (self.strength_finished)
  82                 {
  83                         // sound not available
  84                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  85                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  86                 }
  87
  88                 // speed powerup
  89                 if (self.invincible_finished)
  90                 {
  91                         // sound not available
  92                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  93                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  94                 }
  95         }
  96         else
  97         {
  98                 if (cvar("deathmatch") != 2 || !self.flags & FL_WEAPON || !other.items & self.items || self.classname == "droppedweapon")
  99                 {
 100                         if (self.ammo_shells)
 101                                 other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 102                         if (self.ammo_nails)
 103                                 other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 104                         if (self.ammo_rockets)
 105                                 other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 106                         if (self.ammo_cells)
 107                                 other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 108
 109                         if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, "Machine gun");
 110                         if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, "Shotgun");
 111                         if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, "Mortar");
 112                         if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, "Electro");
 113                         if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, "Nex");
 114                         if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, "Hagar");
 115                         if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, "Rocket Launcher");
 116                         if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, "Crylink");
 117                 }
 118
 119                 if (self.strength_finished)
 120                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 121                 if (self.invincible_finished)
 122                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 123                 //if (self.speed_finished)
 124                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 125                 //if (self.slowmo_finished)
 126                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 127
 128                 if (self.max_health)
 129                 {
 130                         other.health = other.health + self.max_health;
 131                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + 5);
 132                 }
 133                 if (self.health && other.health < other.max_health)
 134                         other.health = min(other.health + self.health, other.max_health);
 135                 if (self.armorvalue)
 136                 {
 137                         other.armorvalue = other.armorvalue + self.armorvalue;
 138                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + 5);
 139                 }
 140         }
 141
 142         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 143
 144         oldself = self;
 145         self = other;
 146
 147         if (_switchweapon)
 148                 self.switchweapon = w_getbestweapon(self);
 149         if (self.switchweapon != self.weapon)
 150                 self.cnt = self.weapon;
 151
 152         //w_updateweapon ();
 153         //w_updateammo ();
 154         weapon_action(self.weapon, WR_UPDATECOUNTS);
 155
 156         self = oldself;
 157
 158         if (self.classname == "droppedweapon")
 159                 remove (self);
 160         else if (cvar("deathmatch") != 2 || !self.flags & FL_WEAPON)
 161         {
 162                 self.solid = SOLID_NOT;
 163                 self.model = string_null;
 164                 self.nextthink = time + self.respawntime;
 165                 self.think = Item_Respawn;
 166                 setorigin (self, self.origin);
 167         }
 168 }
 169
 170 // Savage: used for item garbage-collection
 171 // TODO: perhaps nice special effect?
 172 void RemoveItem(void) = {
 173         remove(self);
 174 }
 175
 176
 177 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags)
 178 {
 179         if (!cvar("g_pickup_items") && !cvar("g_minstagib") &&
 180                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemname != "100 Health")
 181         {
 182                 remove (self);
 183                 return;
 184         }
 185
 186         if (cvar("g_minstagib"))
 187         {
 188                 // don't remove dropped items and powerups
 189                 if (self.classname != "droppedweapon" &&
 190                     self.classname != "minstagib")
 191                 {
 192                         remove (self);
 193                         return;
 194                 }
 195         }
 196
 197         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 198         {
 199                 remove(self);
 200                 return;
 201         }
 202
 203         if(cvar("g_instagib") || cvar("g_rocketarena"))
 204         {
 205                 remove(self);
 206                 return;
 207         }
 208
 209         if (self.classname == "droppedweapon")
 210         {
 211                 // don't drop if in a NODROP zone (such as lava)
 212                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 213                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 214                 {
 215                         remove(self);
 216                         return;
 217                 }
 218         }
 219
 220         self.mdl = itemmodel;
 221         //self.noise = pickupsound;
 222         self.item_pickupsound = pickupsound;
 223         // let mappers override respawntime
 224         if (!self.respawntime)
 225                 self.respawntime = defaultrespawntime;
 226         self.netname = itemname;
 227         self.items = itemid;
 228         self.flags = FL_ITEM | itemflags;
 229         setmodel (self, self.mdl);
 230         if (itemflags & FL_WEAPON)
 231         {
 232                 setorigin (self, self.origin + '0 0 23');
 233                 setsize (self, '-12 -12 -12', '12 12 12');
 234
 235                 // neutral team color for pickup weapons
 236                 self.colormap = 160 * 1024 + 160;
 237         }
 238         else
 239         {
 240                 setorigin (self, self.origin + '0 0 1' * other.maxs_z + '0 0 18');
 241         //      setsize (self, '-8 -8 -5', '8 8 8');
 242         }
 243         self.movetype = MOVETYPE_TOSS;
 244         self.solid = SOLID_TRIGGER;
 245         self.touch = Item_Touch;
 246
 247         // Savage: remove thrown items after a certain period of time ("garbage collection")
 248         if (self.classname == "droppedweapon")
 249         {
 250                 self.think = RemoveItem;
 251                 self.nextthink = time + 60;
 252         }
 253
 254         if (cvar("g_fullbrightitems"))
 255                 self.effects = self.effects | EF_FULLBRIGHT;
 256
 257 }
 258
 259 /* replace items in minstagib
 260  * IT_STRENGTH   = invisibility
 261  * IT_NAILS      = extra lives
 262  * IT_INVINCIBLE = speed
 263  */
 264 void minstagib_items (float itemid)
 265 {
 266         // we don't want to replace dropped weapons ;)
 267         if (self.classname == "droppedweapon")
 268         {
 269                 self.ammo_cells = 25;
 270                 StartItem ("models/weapons/g_nex.md3",
 271                         "weapons/weaponpickup.ogg", 15,
 272                         "Nex Gun", IT_NEX, FL_WEAPON);
 273                 return;
 274         }
 275
 276         local float rnd;
 277         self.classname = "minstagib";
 278
 279         // replace rocket launchers and nex guns with ammo cells
 280         if (itemid == IT_CELLS)
 281         {
 282                 self.ammo_cells = 1;
 283                 StartItem ("models/items/a_cells.md3",
 284                         "misc/itempickup.ogg", 45,
 285                         "Nex Ammo", IT_CELLS, 0);
 286                 return;
 287         }
 288
 289         // randomize
 290         rnd = random() * 3;
 291         if (rnd <= 1)
 292                 itemid = IT_STRENGTH;
 293         else if (rnd <= 2)
 294                 itemid = IT_NAILS;
 295         else
 296                 itemid = IT_INVINCIBLE;
 297
 298         // replace with invis
 299         if (itemid == IT_STRENGTH)
 300         {
 301                 self.effects = EF_ADDITIVE;
 302                 self.strength_finished = 30;
 303                 StartItem ("models/items/g_strength.md3",
 304                         "misc/powerup.ogg", 120,
 305                         "Invisibility", IT_STRENGTH, FL_POWERUP);
 306         }
 307         // replace with extra lives
 308         if (itemid == IT_NAILS)
 309         {
 310                 self.max_health = 1;
 311                 StartItem ("models/items/g_h100.md3",
 312                         "misc/megahealth.ogg", 120,
 313                         "Extralife", IT_NAILS, FL_POWERUP);
 314
 315         }
 316         // replace with ammo
 317         if (itemid == IT_INVINCIBLE)
 318         {
 319                 self.effects = EF_ADDITIVE;
 320                 self.invincible_finished = 30;
 321                 StartItem ("models/items/g_invincible.md3",
 322                         "misc/powerup_shield.ogg", 120,
 323                         "Speed", IT_INVINCIBLE, FL_POWERUP);
 324         }
 325
 326 }
 327
 328 void weapon_uzi (void) {
 329         self.ammo_nails = 120;
 330         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, "Uzi", IT_UZI, FL_WEAPON);
 331 }
 332
 333 void weapon_shotgun (void) {
 334         self.ammo_shells = 15;
 335         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, "Shotgun", IT_SHOTGUN, FL_WEAPON);
 336 }
 337
 338 void weapon_grenadelauncher (void) {
 339         self.ammo_rockets = 15;
 340         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, "Grenade Launcher", IT_GRENADE_LAUNCHER, FL_WEAPON);
 341 }
 342
 343 void weapon_electro (void) {
 344         self.ammo_cells = 25;
 345         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, "Electro", IT_ELECTRO, FL_WEAPON);
 346 }
 347
 348 void weapon_crylink (void) {
 349         self.ammo_cells = 25;
 350         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, "Crylink", IT_CRYLINK, FL_WEAPON);
 351 }
 352
 353 void weapon_nex (void) {
 354         if (cvar("g_minstagib")) {
 355                 minstagib_items(IT_CELLS);
 356         } else {
 357                 self.ammo_cells = 25;
 358                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", 15, "Nex Gun", IT_NEX, FL_WEAPON);
 359         }
 360 }
 361
 362 void weapon_hagar (void) {
 363         self.ammo_rockets = 15;
 364         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, "Hagar", IT_HAGAR, FL_WEAPON);
 365 }
 366
 367 void weapon_rocketlauncher (void) {
 368         if (cvar("g_minstagib")) {
 369                 minstagib_items(IT_CELLS);
 370         } else {
 371                 self.ammo_rockets = 15;
 372                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, "Rocket Launcher", IT_ROCKET_LAUNCHER, FL_WEAPON);
 373         }
 374 }
 375
 376 void item_rockets (void) {
 377         self.ammo_rockets = 15;
 378         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0);
 379 }
 380
 381 void item_bullets (void) {
 382         self.ammo_nails = 120;
 383         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0);
 384 }
 385
 386 void item_cells (void) {
 387         self.ammo_cells = 25;
 388         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0);
 389 }
 390
 391 void item_shells (void) {
 392         self.ammo_shells = 15;
 393         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0);
 394 }
 395
 396 void item_armor1 (void) {
 397         self.armorvalue = 5;
 398         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", 0, 0);
 399 }
 400
 401 void item_armor25 (void) {
 402         self.armorvalue = 100;
 403         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", 0, 0);
 404 }
 405
 406 void item_health1 (void) {
 407         self.max_health = 5;
 408         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", 0, 0);
 409 }
 410
 411 void item_health25 (void) {
 412         self.max_health = 25;
 413         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", 0, 0);
 414 }
 415
 416 void item_health100 (void) {
 417         if(!cvar("g_powerup_superhealth"))
 418                 return;
 419
 420         if(cvar("g_minstagib")) {
 421                 minstagib_items(IT_NAILS);
 422         } else {
 423                 self.max_health = 100;
 424                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", 0, 0);
 425         }
 426 }
 427
 428 void item_strength (void) {
 429         if(!cvar("g_powerup_strength"))
 430                 return;
 431
 432         if(cvar("g_minstagib")) {
 433                 minstagib_items(IT_STRENGTH);
 434         } else {
 435                 self.strength_finished = 30;
 436                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP);
 437         }
 438 }
 439
 440 void item_invincible (void) {
 441         if(!cvar("g_powerup_shield"))
 442                 return;
 443
 444         if(cvar("g_minstagib")) {
 445                 minstagib_items(IT_INVINCIBLE);
 446         } else {
 447                 self.invincible_finished = 30;
 448                 self.effects = EF_ADDITIVE;
 449                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP);
 450         }
 451 }
 452 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP);}
 453 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP);}
 454
 455 void misc_models (void)
 456 {
 457         precache_model (self.model);
 458         setmodel (self, self.model);
 459         setsize (self, self.mins, self.maxs);
 460 }
 461
 462