data/qcsrc/server/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8 }
   9
  10 float spawn_allbad;
  11 float spawn_allgood;
  12 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  13 {
  14         local entity spot, player, nextspot, previousspot, newfirstspot;
  15         local float pcount;
  16         spot = firstspot;
  17         newfirstspot = world;
  18         previousspot = world;
  19         spawn_allgood = TRUE;
  20         spawn_allbad = TRUE;
  21         while (spot)
  22         {
  23                 nextspot = spot.chain;
  24                 // count team mismatches as bad spots
  25                 if (spot.team == teamcheck)
  26                 {
  27                         pcount = 0;
  28                         player = playerlist;
  29                         while (player)
  30                         {
  31                                 if (player != self)
  32                                 if (vlen(player.origin - spot.origin) < mindist)
  33                                         pcount = pcount + 1;
  34                                 player = player.chain;
  35                         }
  36                         if (!pcount)
  37                         {
  38                                 spawn_allbad = FALSE;
  39                                 if (newfirstspot)
  40                                         previousspot.chain = spot;
  41                                 else
  42                                         newfirstspot = spot;
  43                                 previousspot = spot;
  44                                 spot.chain = world;
  45                         }
  46                         else
  47                                 spawn_allgood = FALSE;
  48                 }
  49                 spot = nextspot;
  50         }
  51         // if we couldn't find ANY good points, return the original list
  52         if (!newfirstspot)
  53                 newfirstspot = firstspot;
  54         return newfirstspot;
  55 }
  56
  57 entity Spawn_RandomPoint(entity firstspot)
  58 {
  59         local entity spot;
  60         local float numspots;
  61         // count number of spots
  62         numspots = 0;
  63         spot = firstspot;
  64         while (spot)
  65         {
  66                 numspots = numspots + 1;
  67                 spot = spot.chain;
  68         }
  69         // pick a random one
  70         numspots = numspots * random();
  71         spot = firstspot;
  72         while (spot.chain && numspots >= 1)
  73         {
  74                 numspots = numspots - 1;
  75                 spot = spot.chain;
  76         }
  77         return spot;
  78 }
  79
  80 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  81 {
  82         local entity best, spot, player;
  83         local float bestrating, rating;
  84         best = world;
  85         bestrating = -1000000;
  86         spot = firstspot;
  87         while (spot)
  88         {
  89                 rating = 1000000000;
  90                 player = playerlist;
  91                 while (player)
  92                 {
  93                         if (player != self)
  94                                 rating = min(rating, vlen(player.origin - spot.origin));
  95                         player = player.chain;
  96                 }
  97                 rating = rating + random() * 16;
  98                 if (bestrating < rating)
  99                 {
 100                         best = spot;
 101                         bestrating = rating;
 102                 }
 103                 spot = spot.chain;
 104         }
 105         return best;
 106 }
 107
 108 /*
 109 =============
 110 SelectSpawnPoint
 111
 112 Finds a point to respawn
 113 =============
 114 */
 115 entity SelectSpawnPoint (float anypoint)
 116 {
 117         local float teamcheck;
 118         local entity spot, firstspot, playerlist;
 119         string spotname;
 120
 121         spot = find (world, classname, "testplayerstart");
 122         if (spot)
 123                 return spot;
 124
 125         spotname = "info_player_deathmatch";
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (random() > 0.5 || spawn_allbad || spawn_allgood)
 143                 spot = Spawn_RandomPoint(firstspot);
 144         else
 145                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 146
 147         if (!spot)
 148                 error ("PutClientInServer: no start points on level");
 149
 150         return spot;
 151 }
 152
 153 /*
 154 =============
 155 CheckPlayerModel
 156
 157 Checks if the argument string can be a valid playermodel.
 158 Returns a valid one in doubt.
 159 =============
 160 */
 161 string CheckPlayerModel(string plyermodel) {
 162         if( substring(plyermodel,0,14) != "models/player/") plyermodel = "models/player/marine.zym";
 163
 164         /* Possible Fixme: Check if server can open the model?
 165            This would kill custom models, however. */
 166
 167         return plyermodel;
 168 }
 169
 170 /*
 171 =============
 172 PutObserverInServer
 173
 174 putting a client as observer in the server
 175 =============
 176 */
 177 void PutObserverInServer (void)
 178 {
 179         entity  spot;
 180         spot = SelectSpawnPoint (FALSE);
 181         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 182
 183         if(self.frags == 0 && cvar("g_lms") && self.killcount != -666)
 184                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 185         else if(self.killcount != -666)
 186                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 187
 188         self.classname = "observer";
 189         self.health = -666;
 190         self.takedamage = DAMAGE_NO;
 191         self.solid = SOLID_NOT;
 192         self.movetype = MOVETYPE_NOCLIP;
 193         self.flags = FL_CLIENT | FL_NOTARGET;
 194         self.armorvalue = 666;
 195         self.effects = 0;
 196         self.armorvalue = cvar("g_balance_armor_start");
 197         self.pauserotarmor_finished = 0;
 198         self.pauserothealth_finished = 0;
 199         self.pauseregen_finished = 0;
 200         self.damageforcescale = 0;
 201         self.death_time = 0;
 202         self.dead_time = 0;
 203         self.dead_frame = 0;
 204         self.die_frame = 0;
 205         self.deaths = 0;
 206         self.alpha = 0;
 207         self.scale = 0;
 208         self.fade_time = 0;
 209         self.pain_frame = 0;
 210         self.pain_finished = 0;
 211         self.strength_finished = 0;
 212         self.invincible_finished = 0;
 213         self.pushltime = 0;
 214         self.think = SUB_Null;
 215         self.nextthink = 0;
 216         self.hook_time = 0;
 217         self.runes = 0;
 218         self.deadflag = DEAD_NO;
 219         self.angles = spot.angles;
 220         self.angles_z = 0;
 221         self.fixangle = TRUE;
 222         self.crouch = FALSE;
 223         self.view_ofs = PL_VIEW_OFS;
 224         setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 14));
 225         self.oldorigin = self.origin;
 226         self.items = 0;
 227         self.model = "";
 228         self.modelindex = 0;
 229         self.weapon = 0;
 230         self.weaponmodel = "";
 231         self.weaponframe = 0;
 232         self.weaponentity = world;
 233         self.killcount = -666;
 234         if(!cvar("g_lms"))
 235                 self.frags = -666;
 236         //stuffcmd(self, "set viewsize 120 \n");
 237 //      bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 238 }
 239
 240
 241 /*
 242 =============
 243 PutClientInServer
 244
 245 Called when a client spawns in the server
 246 =============
 247 */
 248 void PutClientInServer (void)
 249 {
 250         if(clienttype(self) ==  CLIENTTYPE_BOT)
 251         {
 252                 self.classname = "player";
 253         }
 254
 255         // player is dead and becomes observer
 256         if(cvar("g_lms") && self.frags < 1)
 257                 self.classname = "observer";
 258
 259         if(self.classname == "player") {
 260                 entity  spot;
 261
 262                 spot = SelectSpawnPoint (FALSE);
 263
 264                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 265
 266                 self.classname = "player";
 267                 self.iscreature = TRUE;
 268                 self.movetype = MOVETYPE_WALK;
 269                 self.solid = SOLID_SLIDEBOX;
 270                 self.flags = FL_CLIENT;
 271                 self.takedamage = DAMAGE_AIM;
 272                 self.effects = 0;
 273                 self.health = cvar("g_balance_health_start");
 274                 self.armorvalue = cvar("g_balance_armor_start");
 275                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 276                 self.pauserotarmor_finished = time + 10;
 277                 self.pauserothealth_finished = time + 10;
 278                 self.pauseregen_finished = 0;
 279                 self.damageforcescale = 2;
 280                 self.death_time = 0;
 281                 self.dead_time = 0;
 282                 self.dead_frame = 0;
 283                 self.die_frame = 0;
 284                 self.alpha = 0;
 285                 self.scale = 0;
 286                 self.fade_time = 0;
 287                 self.pain_frame = 0;
 288                 self.pain_finished = 0;
 289                 self.strength_finished = 0;
 290                 self.invincible_finished = 0;
 291                 self.pushltime = 0;
 292                 //self.speed_finished = 0;
 293                 //self.slowmo_finished = 0;
 294                 // players have no think function
 295                 self.think = SUB_Null;
 296                 self.nextthink = 0;
 297                 self.weapon = 0;
 298                 self.switchweapon = 0;
 299                 self.hook_time = 0;
 300
 301                 self.runes = 0;
 302
 303                 self.deadflag = DEAD_NO;
 304
 305                 self.angles = spot.angles;
 306
 307                 self.angles_z = 0; // never spawn tilted even if the spot says to
 308                 self.fixangle = TRUE; // turn this way immediately
 309                 self.velocity = '0 0 0';
 310                 self.avelocity = '0 0 0';
 311                 self.punchangle = '0 0 0';
 312                 self.punchvector = '0 0 0';
 313                 self.oldvelocity = self.velocity;
 314
 315                 self.viewzoom = 0.6;
 316
 317                 if(cvar("sv_defaultcharacter") == 1) {
 318                         local string defaultmodel;
 319                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 320
 321                         precache_model (defaultmodel);
 322                         setmodel (self, defaultmodel);
 323                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 324                 } else {
 325                         self.playermodel = CheckPlayerModel(self.playermodel);
 326
 327                         precache_model (self.playermodel);
 328                         setmodel (self, self.playermodel);
 329                         self.skin = stof(self.playerskin);
 330
 331                 }
 332
 333                 self.crouch = FALSE;
 334                 self.view_ofs = PL_VIEW_OFS;
 335                 setsize (self, PL_MIN, PL_MAX);
 336                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 337                 // don't reset back to last position, even if new position is stuck in solid
 338                 self.oldorigin = self.origin;
 339
 340                 if(cvar("g_lms"))
 341                 {
 342                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 343                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 344                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 345                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 346                         self.health = cvar("g_lms_start_health");
 347                         self.armorvalue = cvar("g_lms_start_armor");
 348                 }
 349                 else if (cvar("g_use_ammunition")) {
 350                         self.ammo_shells = cvar("g_start_ammo_shells");
 351                         self.ammo_nails = cvar("g_start_ammo_nails");
 352                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 353                         self.ammo_cells = cvar("g_start_ammo_cells");
 354                 } else {
 355                         self.ammo_shells = 999;
 356                         self.ammo_nails = 999;
 357                         self.ammo_rockets = 999;
 358                         self.ammo_cells = 999;
 359                 }
 360
 361                 self.items = 0;
 362                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 363                 {
 364                         self.items = self.items | IT_LASER;
 365                         self.switchweapon = WEP_LASER;
 366                 }
 367                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 368                 {
 369                         self.items = self.items | IT_SHOTGUN;
 370                         self.switchweapon = WEP_SHOTGUN;
 371                 }
 372                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 373                 {
 374                         self.items = self.items | IT_UZI;
 375                         self.switchweapon = WEP_UZI;
 376                 }
 377                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 378                 {
 379                         self.items = self.items | IT_GRENADE_LAUNCHER;
 380                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 381                 }
 382                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 383                 {
 384                         self.items = self.items | IT_ELECTRO;
 385                         self.switchweapon = WEP_ELECTRO;
 386                 }
 387                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 388                 {
 389                         self.items = self.items | IT_CRYLINK;
 390                         self.switchweapon = WEP_CRYLINK;
 391                 }
 392                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 393                 {
 394                         self.items = self.items | IT_NEX;
 395                         self.switchweapon = WEP_NEX;
 396                 }
 397                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 398                 {
 399                         self.items = self.items | IT_HAGAR;
 400                         self.switchweapon = WEP_HAGAR;
 401                 }
 402                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 403                 {
 404                         self.items = self.items | IT_ROCKET_LAUNCHER;
 405                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 406                 }
 407
 408                 if(cvar("g_instagib"))
 409                 {
 410                         self.items = IT_NEX;
 411                         self.switchweapon = WEP_NEX;
 412                         self.ammo_cells = 999;
 413                 }
 414
 415                 if(cvar("g_rocketarena"))
 416                 {
 417                         self.items = IT_ROCKET_LAUNCHER;
 418                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 419                         self.ammo_rockets = 999;
 420                 }
 421
 422                 if(cvar("g_nixnex"))
 423                 {
 424                         self.items = 0;
 425                         // will be done later
 426                 }
 427
 428                 if(cvar("g_minstagib"))
 429                 {
 430                         self.health = 100;
 431                         self.armorvalue = 0;
 432                         self.items = IT_NEX;
 433                         self.switchweapon = WEP_NEX;
 434                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 435                         self.extralives = 0;
 436                         self.jump_interval = time;
 437                 }
 438
 439                 self.event_damage = PlayerDamage;
 440
 441                 self.statdraintime = time + 5;
 442                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 443
 444                 if(self.killcount == -666) {
 445                         self.killcount = 0;
 446                         self.frags = 0;
 447                 }
 448
 449                 self.cnt = WEP_LASER;
 450                 self.nixnex_lastchange_id = -1;
 451
 452                 /*
 453                 W_UpdateWeapon();
 454                 W_UpdateAmmo();
 455                 */
 456                 CL_SpawnWeaponentity();
 457                 self.alpha = 1;
 458                 self.exteriorweaponentity.alpha = 1;
 459
 460                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 461                 self.lms_traveled_distance = 0;
 462
 463                 if(cvar("spawn_debug"))
 464                 {
 465                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 466                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 467                 }
 468
 469                 //stuffcmd(self, "chase_active 0");
 470                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 471         } else if(self.classname == "observer") {
 472                 PutObserverInServer ();
 473         }
 474 }
 475
 476 /*
 477 =============
 478 SetNewParms
 479 =============
 480 */
 481 void SetNewParms (void)
 482 {
 483
 484 }
 485
 486 /*
 487 =============
 488 SetChangeParms
 489 =============
 490 */
 491 void SetChangeParms (void)
 492 {
 493
 494 }
 495
 496 /*
 497 =============
 498 ClientKill
 499
 500 Called when a client types 'kill' in the console
 501 =============
 502 */
 503 void ClientKill (void)
 504 {
 505         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 506 }
 507
 508 /*
 509 =============
 510 ClientConnect
 511
 512 Called when a client connects to the server
 513 =============
 514 */
 515 string ColoredTeamName(float t);
 516 //void dom_player_join_team(entity pl);
 517 void ClientConnect (void)
 518 {
 519         self.classname = "player_joining";
 520
 521         if(player_count<0) player_count = 0;
 522
 523         //if(cvar("g_domination"))
 524         //      dom_player_join_team(self);
 525
 526         //JoinBestTeam(self, FALSE);
 527
 528         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 529                 self.classname = "observer";
 530         } else {
 531                 self.classname = "player";
 532         }
 533
 534         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 535
 536         bprint ("^4",self.netname);
 537         bprint ("^4 connected");
 538
 539         if(cvar("g_domination") || cvar("g_ctf"))
 540         {
 541                 bprint(" and joined the ");
 542                 bprint(ColoredTeamName(self.team));
 543         }
 544
 545         bprint("\n");
 546
 547         self.welcomemessage_time = time + cvar("welcome_message_time");
 548         self.welcomemessage_time2 = 0;
 549
 550         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 551         // send prediction settings to the client
 552         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 553         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 554         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 555         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 556         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 557         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 558         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 559         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 560         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 561         // Wazat's grappling hook
 562         SetGrappleHookBindings();
 563
 564         // get autoswitch state from player
 565         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 566         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 567
 568         // get version info from player
 569         stuffcmd(self, "cmd clientversion $gameversion\n");
 570
 571         // set cvar for team scoreboard
 572         stuffcmd(self, strcat("set teamplay ", ftos(teams_matter), "\n"));
 573
 574         if(cvar("g_lms"))
 575         {
 576                 self.frags = cvar("fraglimit");
 577                 // no fraglimit was set, so player gets 999 lives
 578                 if(self.frags < 1)
 579                         self.frags = 999;
 580
 581                 // disallow player to join after the worst player has lost g_lms_last_join lives
 582                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 583                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 584                 {
 585                         self.frags = -1;
 586                         lms_dead_count += 1;
 587                 }
 588                 else if(cvar("fraglimit") > lms_lowest_lives)
 589                 {
 590                         self.frags = lms_lowest_lives;
 591                 }
 592         }
 593
 594         player_count += 1;
 595         self.jointime = time;
 596 }
 597
 598 /*
 599 =============
 600 ClientDisconnect
 601
 602 Called when a client disconnects from the server
 603 =============
 604 */
 605 void(entity e) DropFlag;
 606 .entity chatbubbleentity;
 607 .entity teambubbleentity;
 608 void ClientDisconnect (void)
 609 {
 610         bprint ("^4",self.netname);
 611         bprint ("^4 disconnected\n");
 612
 613         if (self.chatbubbleentity)
 614         {
 615                 remove (self.chatbubbleentity);
 616                 self.chatbubbleentity = world;
 617         }
 618
 619         if (self.teambubbleentity)
 620         {
 621                 remove (self.teambubbleentity);
 622                 self.teambubbleentity = world;
 623         }
 624
 625         DropAllRunes(self);
 626
 627         if(self.flagcarried)
 628                 DropFlag(self.flagcarried);
 629
 630         // decrease player count for lms
 631         player_count -= 1;
 632         // player was dead, decrease dead count
 633         if(cvar("g_lms") && self.frags < 1)
 634                 lms_dead_count -= 1;
 635         //stuffcmd(self, "set viewsize $tmpviewsize \n");
 636 }
 637
 638 .float buttonchat;
 639 void() ChatBubbleThink =
 640 {
 641         self.nextthink = time;
 642         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 643         {
 644                 remove(self);
 645                 return;
 646         }
 647         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 648         if (self.owner.buttonchat && !self.owner.deadflag)
 649                 self.model = self.mdl;
 650         else
 651                 self.model = "";
 652 };
 653
 654 void() UpdateChatBubble =
 655 {
 656         if (!self.modelindex)
 657                 return;
 658         // spawn a chatbubble entity if needed
 659         if (!self.chatbubbleentity)
 660         {
 661                 self.chatbubbleentity = spawn();
 662                 self.chatbubbleentity.owner = self;
 663                 self.chatbubbleentity.exteriormodeltoclient = self;
 664                 self.chatbubbleentity.think = ChatBubbleThink;
 665                 self.chatbubbleentity.nextthink = time;
 666                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 667                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 668                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 669                 self.chatbubbleentity.model = "";
 670         }
 671 }
 672
 673
 674 void() TeamBubbleThink =
 675 {
 676         self.nextthink = time;
 677         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 678         {
 679                 remove(self);
 680                 return;
 681         }
 682 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 683         if (self.owner.buttonchat || self.owner.deadflag)
 684                 self.model = "";
 685         else
 686                 self.model = self.mdl;
 687
 688 };
 689
 690 .float() customizeentityforclient;
 691 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 692
 693 void() UpdateTeamBubble =
 694 {
 695         if (!self.modelindex || !cvar("teamplay"))
 696                 return;
 697         // spawn a teambubble entity if needed
 698         if (!self.teambubbleentity && cvar("teamplay"))
 699         {
 700                 self.teambubbleentity = spawn();
 701                 self.teambubbleentity.owner = self;
 702                 self.teambubbleentity.exteriormodeltoclient = self;
 703                 self.teambubbleentity.think = TeamBubbleThink;
 704                 self.teambubbleentity.nextthink = time;
 705                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 706 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 707                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 708                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 709                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 710                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 711                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 712         }
 713 }
 714
 715 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 716 // added to the model skins
 717 /*void() UpdateColorModHack =
 718 {
 719         local float c;
 720         c = self.clientcolors & 15;
 721         // LordHavoc: only bothering to support white, green, red, yellow, blue
 722              if (teamplay == 0) self.colormod = '0 0 0';
 723         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 724         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 725         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 726         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 727         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 728         else self.colormod = '1 1 1';
 729 };*/
 730
 731 void UpdatePlayerColors () {
 732         if(self.weaponentity) {
 733                 self.weaponentity.colormap = self.colormap;
 734                 self.exteriorweaponentity.colormap = self.colormap;
 735         }
 736 }
 737 /*
 738 =============
 739 PlayerJump
 740
 741 When you press the jump key
 742 =============
 743 */
 744 void PlayerJump (void)
 745 {
 746         float mjumpheight;
 747
 748         mjumpheight = cvar("g_balance_jumpheight");
 749         if (self.waterlevel >= 2)
 750         {
 751                 if (self.watertype == CONTENT_WATER)
 752                         self.velocity_z = 200;
 753                 else if (self.watertype == CONTENT_SLIME)
 754                         self.velocity_z = 80;
 755                 else
 756                         self.velocity_z = 50;
 757
 758                 return;
 759         }
 760
 761
 762         if (!(self.flags & FL_ONGROUND))
 763                 return;
 764
 765         if (!(self.flags & FL_JUMPRELEASED))
 766                 return;
 767
 768         if(cvar("g_runematch"))
 769         {
 770                 if(self.runes & RUNE_SPEED)
 771                 {
 772                         if(self.runes & CURSE_SLOW)
 773                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 774                         else
 775                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 776                 }
 777                 else if(self.runes & CURSE_SLOW)
 778                 {
 779                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 780                 }
 781         }
 782
 783         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 784         {
 785                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 786         }
 787
 788         self.velocity_z = self.velocity_z + mjumpheight;
 789         self.oldvelocity_z = self.velocity_z;
 790
 791         self.flags = self.flags - FL_ONGROUND;
 792         self.flags = self.flags - FL_JUMPRELEASED;
 793 }
 794
 795 void() CheckWaterJump =
 796 {
 797         local vector start, end;
 798
 799 // check for a jump-out-of-water
 800         makevectors (self.angles);
 801         start = self.origin;
 802         start_z = start_z + 8;
 803         v_forward_z = 0;
 804         normalize(v_forward);
 805         end = start + v_forward*24;
 806         traceline (start, end, TRUE, self);
 807         if (trace_fraction < 1)
 808         {       // solid at waist
 809                 start_z = start_z + self.maxs_z - 8;
 810                 end = start + v_forward*24;
 811                 self.movedir = trace_plane_normal * -50;
 812                 traceline (start, end, TRUE, self);
 813                 if (trace_fraction == 1)
 814                 {       // open at eye level
 815                         self.flags = self.flags | FL_WATERJUMP;
 816                         self.velocity_z = 225;
 817                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 818                         self.teleport_time = time + 2;  // safety net
 819                         return;
 820                 }
 821         }
 822 };
 823
 824
 825 void respawn(void)
 826 {
 827         CopyBody(1);
 828         PutClientInServer();
 829 }
 830
 831 void player_powerups (void)
 832 {
 833         if (cvar("g_minstagib"))
 834         {
 835                 self.effects = EF_FULLBRIGHT;
 836                 if (self.items & IT_STRENGTH)
 837                 {
 838                         if (time > self.strength_finished)
 839                         {
 840                                 self.alpha = 1;
 841                                 self.exteriorweaponentity.alpha = 1;
 842                                 self.items = self.items - (self.items & IT_STRENGTH);
 843                                 sprint(self, "^3Invisibility has worn off\n");
 844                         }
 845                 }
 846                 else
 847                 {
 848                         if (time < self.strength_finished)
 849                         {
 850                                 self.alpha = cvar("g_minstagib_invis_alpha");
 851                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 852                                 self.items = self.items | IT_STRENGTH;
 853                                 sprint(self, "^3You are invisible\n");
 854                         }
 855                 }
 856
 857                 if (self.items & IT_INVINCIBLE)
 858                 {
 859                         if (time > self.invincible_finished)
 860                         {
 861                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 862                                 sprint(self, "^3Speed has worn off\n");
 863                         }
 864                 }
 865                 else
 866                 {
 867                         if (time < self.invincible_finished)
 868                         {
 869                                 self.items = self.items | IT_INVINCIBLE;
 870                                 sprint(self, "^3You are on speed\n");
 871                         }
 872                 }
 873                 return;
 874         }
 875
 876         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 877         if (self.items & IT_STRENGTH)
 878         {
 879                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 880                 if (time > self.strength_finished)
 881                 {
 882                         self.items = self.items - (self.items & IT_STRENGTH);
 883                         sprint(self, "^3Strength has worn off\n");
 884                 }
 885         }
 886         else
 887         {
 888                 if (time < self.strength_finished)
 889                 {
 890                         self.items = self.items | IT_STRENGTH;
 891                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
 892                 }
 893         }
 894         if (self.items & IT_INVINCIBLE)
 895         {
 896                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 897                 if (time > self.invincible_finished)
 898                 {
 899                         self.items = self.items - (self.items & IT_INVINCIBLE);
 900                         sprint(self, "^3Shield has worn off\n");
 901                 }
 902         }
 903         else
 904         {
 905                 if (time < self.invincible_finished)
 906                 {
 907                         self.items = self.items | IT_INVINCIBLE;
 908                         sprint(self, "^3Shield surrounds you\n");
 909                 }
 910         }
 911
 912         if (cvar("g_fullbrightplayers"))
 913                 self.effects = self.effects | EF_FULLBRIGHT;
 914
 915         // midair gamemode: damage only while in the air
 916         // if in midair mode, being on ground grants temporary invulnerability
 917         // (this is so that multishot weapon don't clear the ground flag on the
 918         // first damage in the frame, leaving the player vulnerable to the
 919         // remaining hits in the same frame)
 920         if (self.flags & FL_ONGROUND)
 921         if (cvar("g_midair"))
 922                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
 923
 924         if (time < self.spawnshieldtime)
 925                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
 926 }
 927
 928 void player_regen (void)
 929 {
 930         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
 931         maxh = cvar("g_balance_health_stable");
 932         maxa = cvar("g_balance_armor_stable");
 933         limith = cvar("g_balance_health_limit");
 934         limita = cvar("g_balance_armor_limit");
 935
 936         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
 937                 return;
 938
 939         if(cvar("g_runematch"))
 940         {
 941                 max_mod = regen_mod = rot_mod = limit_mod = 1;
 942                 if (self.runes & RUNE_REGEN)
 943                 {
 944                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
 945                         {
 946                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
 947                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
 948                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
 949                         }
 950                         else
 951                         {
 952                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
 953                                 max_mod = cvar("g_balance_rune_regen_hpmod");
 954                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
 955                         }
 956                 }
 957                 else if (self.runes & CURSE_VENOM)
 958                 {
 959                         max_mod = cvar("g_balance_curse_venom_hpmod");
 960                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
 961                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
 962                         else
 963                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
 964                         limit_mod = cvar("g_balance_curse_venom_limitmod");
 965                         //if (!self.runes & RUNE_REGEN)
 966                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
 967                 }
 968                 maxh = maxh * max_mod;
 969                 //maxa = maxa * max_mod;
 970
 971                 if (time > self.pauserotarmor_finished)
 972                 {
 973                         if (self.armorvalue > maxa)
 974                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 975                 }
 976                 if (time > self.pauserothealth_finished)
 977                 {
 978                         if (self.health > maxh)
 979                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
 980                 }
 981                 if (time > self.pauseregen_finished)
 982                 {
 983                         if (self.health < maxh)
 984                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime, 1000);
 985                         if (self.armorvalue < maxa)
 986                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 987                 }
 988         }
 989         else
 990         {
 991                 if (time > self.pauserothealth_finished)
 992                 if (self.health > maxh)
 993                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
 994                 if (time > self.pauserotarmor_finished)
 995                 if (self.armorvalue > maxa)
 996                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 997                 if (time > self.pauseregen_finished)
 998                 {
 999                         if (self.health < maxh)
1000                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1001                         if (self.armorvalue < maxa)
1002                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1003                 }
1004         }
1005         if (self.health > limith)
1006                 self.health = limith;
1007         if (self.armorvalue > limita)
1008                 self.armorvalue = limita;
1009 }
1010
1011 /*
1012 ======================
1013 spectate mode routines
1014 ======================
1015 */
1016 void SpectateCopy(entity spectatee) {
1017         self.armortype = spectatee.armortype;
1018         self.armorvalue = spectatee.armorvalue;
1019         self.currentammo = spectatee.currentammo;
1020         self.effects = spectatee.effects;
1021         self.health = spectatee.health;
1022         self.impulse = 0;
1023         self.items = spectatee.items;
1024         self.punchangle = spectatee.punchangle;
1025         self.view_ofs = spectatee.view_ofs;
1026         self.v_angle = spectatee.v_angle;
1027         self.viewzoom = spectatee.viewzoom;
1028         setorigin(self, spectatee.origin);
1029         setsize(self, spectatee.mins, spectatee.maxs);
1030 }
1031
1032 void SpectateUpdate() {
1033         if (self != self.enemy) {
1034                 SpectateCopy(self.enemy);
1035                 msg_entity = self;
1036                 WriteByte(MSG_ONE, SVC_SETANGLE);
1037                 WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1038                 WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1039                 WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1040         }
1041 }
1042
1043 float SpectateNext() {
1044         other = find(self.enemy, classname, "player");
1045         if (!other) {
1046                 other = find(other, classname, "player");
1047         }
1048         if (other) {
1049                 self.enemy = other;
1050         }
1051         if(self.enemy.classname == "player") {
1052                 msg_entity = self;
1053                 WriteByte(MSG_ONE, SVC_SETVIEW);
1054                 WriteEntity(MSG_ONE, self.enemy);
1055                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1056                 SpectateUpdate();
1057                 return 1;
1058         } else {
1059                 return 0;
1060         }
1061 }
1062
1063 /*
1064 =============
1065 PlayerPreThink
1066
1067 Called every frame for each client before the physics are run
1068 =============
1069 */
1070 void PlayerPreThink (void)
1071 {
1072         if(self.classname == "player") {
1073                 local vector m1, m2;
1074
1075 //              MauveBot_AI();
1076
1077 //              if(self.netname == "Wazat")
1078 //                      bprint(strcat(self.classname, "\n"));
1079
1080                 CheckRules_Player();
1081
1082                 if(self.button7)
1083                         PrintWelcomeMessage(self);
1084
1085                 if(cvar("g_lms") || !cvar("sv_spectate"))
1086                 if((time - self.jointime) <= cvar("welcome_message_time"))
1087                         PrintWelcomeMessage(self);
1088
1089                 if (intermission_running)
1090                 {
1091                         IntermissionThink ();   // otherwise a button could be missed between
1092                         return;                                 // the think tics
1093                 }
1094
1095                 if (self.deadflag != DEAD_NO)
1096                 {
1097                         player_anim();
1098                         weapon_freeze();
1099                         if (self.deadflag == DEAD_DYING)
1100                         {
1101                                 if (time > self.dead_time)
1102                                         self.deadflag = DEAD_DEAD;
1103                         }
1104                         else if (self.deadflag == DEAD_DEAD)
1105                         {
1106                                 if (cvar("g_lms") || cvar("g_forced_respawn"))
1107                                         self.button0 = self.button2 = self.button3 = 0;
1108
1109                                 if (!self.button0 && !self.button2 && !self.button3)
1110                                         self.deadflag = DEAD_RESPAWNABLE;
1111                         }
1112                         else if (self.deadflag == DEAD_RESPAWNABLE)
1113                         {
1114                                 if (self.button0  ||
1115                                     self.button2  ||
1116                                     self.button3  ||
1117                                     self.button4  ||
1118                                     cvar("g_lms") ||
1119                                     cvar("g_forced_respawn"))
1120                                         respawn();
1121                         }
1122                         return;
1123                 }
1124
1125                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1126                 {
1127                         vector dist;
1128
1129                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1130                         dist = self.oldorigin - self.origin;
1131                         dist_z = 0;
1132                         self.lms_traveled_distance += fabs(vlen(dist));
1133
1134                         if(time > self.lms_nextcheck)
1135                         {
1136                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1137                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1138                                 {
1139                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1140                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1141                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1142                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1143                                 }
1144                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1145                                 self.lms_traveled_distance = 0;
1146                         }
1147                 }
1148
1149                 if (self.button5)
1150                 {
1151                         if (!self.crouch)
1152                         {
1153                                 self.crouch = TRUE;
1154                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1155                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1156                         }
1157                 }
1158                 else
1159                 {
1160                         if (self.crouch)
1161                         {
1162                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1163                                 if (!trace_startsolid)
1164                                 {
1165                                         self.crouch = FALSE;
1166                                         self.view_ofs = PL_VIEW_OFS;
1167                                         setsize (self, PL_MIN, PL_MAX);
1168                                 }
1169                         }
1170                 }
1171
1172                 if(cvar("sv_defaultcharacter") == 1) {
1173                         local string defaultmodel;
1174                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1175
1176                         if (defaultmodel != self.model)
1177                         {
1178                                 m1 = self.mins;
1179                                 m2 = self.maxs;
1180                                 precache_model (defaultmodel);
1181                                 setmodel (self, defaultmodel);
1182                                 setsize (self, m1, m2);
1183                         }
1184
1185                         if (self.skin != stof(cvar_string("sv_defaultplayerskin")))
1186                                 self.skin = stof(cvar_string("sv_defaultplayerskin"));
1187                 } else {
1188                         if (self.playermodel != self.model)
1189                         {
1190                                 self.playermodel = CheckPlayerModel(self.playermodel);
1191                                 m1 = self.mins;
1192                                 m2 = self.maxs;
1193                                 precache_model (self.playermodel);
1194                                 setmodel (self, self.playermodel);
1195                                 setsize (self, m1, m2);
1196                         }
1197
1198                         if (self.skin != stof(self.playerskin))
1199                                 self.skin = stof(self.playerskin);
1200                 }
1201                 // Savage: Check for nameless players
1202                 if (strlen(self.netname) < 1) {
1203                         self.netname = "Player";
1204                         stuffcmd(self, "name Player\n");
1205                 }
1206
1207                 GrapplingHookFrame();
1208
1209                 W_WeaponFrame();
1210
1211                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1212                 {
1213                         if (cvar("g_minstagib") && self.button3)
1214                         {
1215                                 if (self.jump_interval <= (time + 0.1))
1216                                 {
1217                                         self.jump_interval = time + 1;
1218                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1219                                 }
1220                         }
1221                         else if (self.viewzoom > 0.4)
1222                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1223                 }
1224                 else if (self.viewzoom < 1.0)
1225                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1226
1227
1228                 if (self.button2)
1229                         PlayerJump ();
1230                 else
1231                         self.flags = self.flags | FL_JUMPRELEASED;
1232
1233                 player_powerups();
1234                 player_regen();
1235                 player_anim();
1236
1237                 //self.angles_y=self.v_angle_y + 90;   // temp
1238
1239                 if (self.waterlevel == 2)
1240                         CheckWaterJump ();
1241
1242                 //if (TetrisPreFrame()) return;
1243         } else if(gameover) {
1244                 if (intermission_running)
1245                         IntermissionThink ();   // otherwise a button could be missed between
1246                 return;
1247         } else if(self.classname == "observer") {
1248
1249                 if (self.flags & FL_JUMPRELEASED) {
1250                         if (self.button2 && self.version == cvar("gameversion")) {
1251                                 if(!cvar("teamplay")) {
1252                                         self.flags = self.flags & !FL_JUMPRELEASED;
1253                                         self.classname = "player";
1254                                         if(!cvar("g_lms"))
1255                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1256                                         PutClientInServer();
1257                                         centerprint(self,"");
1258                                         return;
1259                                 } else {
1260                                         self.flags = self.flags & !FL_JUMPRELEASED;
1261                                         stuffcmd(self,"menu_showteamselect\n");
1262                                         return;
1263                                 }
1264                         } else if(self.button0 && self.version == cvar("gameversion")) {
1265                                 self.flags = self.flags & !FL_JUMPRELEASED;
1266                                 if(SpectateNext() == 1) {
1267                                         self.classname = "spectator";
1268                                 }
1269                         }
1270                 } else {
1271                         if (!(self.button0 || self.button2)) {
1272                                 self.flags = self.flags | FL_JUMPRELEASED;
1273                         }
1274                 }
1275                 if(cvar("g_lms") && self.frags == 0)
1276                         centerprint(self, "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n^1You have no more lives left\nwait for next round\n\n\n^7press attack to spectate other players");
1277                 else if(cvar("g_lms") && self.frags == -1)
1278                         centerprint(self, "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n^1Match has already begun\nwait for next round\n\n\n^7press attack to spectate other players");
1279                 else
1280                         PrintWelcomeMessage(self);
1281                         //centerprint(self, "\n\n\npress jump to play\npress attack to spectate other players");
1282         } else if(self.classname == "spectator") {
1283
1284                 if (self.flags & FL_JUMPRELEASED) {
1285                         if (self.button2 && self.version == cvar("gameversion")) {
1286                                 if(!cvar("teamplay")) {
1287                                         self.flags = self.flags & !FL_JUMPRELEASED;
1288                                         self.classname = "player";
1289                                         if(!cvar("g_lms"))
1290                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1291
1292                                         msg_entity = self;
1293                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1294                                         WriteEntity(MSG_ONE, self);
1295                                         PutClientInServer();
1296                                         centerprint(self,"");
1297                                         return;
1298                                 } else {
1299                                         self.flags = self.flags & !FL_JUMPRELEASED;
1300                                         stuffcmd(self,"menu_showteamselect\n");
1301                                         return;
1302                                 }
1303                         } else if(self.button0) {
1304                                 self.flags = self.flags & !FL_JUMPRELEASED;
1305                                 if(SpectateNext() == 1) {
1306                                         self.classname = "spectator";
1307                                 } else {
1308                                         self.classname = "observer";
1309                                         msg_entity = self;
1310                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1311                                         WriteEntity(MSG_ONE, self);
1312                                         PutClientInServer();
1313                                 }
1314                         } else if (self.button3) {
1315                                 self.flags = self.flags & !FL_JUMPRELEASED;
1316                                 self.classname = "observer";
1317                                 msg_entity = self;
1318                                 WriteByte(MSG_ONE, SVC_SETVIEW);
1319                                 WriteEntity(MSG_ONE, self);
1320                                 PutClientInServer();
1321                         } else {
1322                                 SpectateUpdate();
1323                         }
1324         } else {
1325                 if (!(self.button0 || self.button3)) {
1326                         self.flags = self.flags | FL_JUMPRELEASED;
1327                 }
1328                 }
1329                 if (cvar("g_lms") && self.frags < 1)
1330                         centerprint(self, strcat("\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\nspectating ", self.enemy.netname, "\n\n\n^7press attack for next player\npress attack2 for free fly mode"));
1331                 else
1332                         centerprint(self, strcat("\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\nspectating ", self.enemy.netname, "\n\n\n^7press jump to play\n^7press attack for next player\npress attack2 for free fly mode"));
1333
1334         }
1335 }
1336
1337
1338 /*
1339 =============
1340 PlayerPostThink
1341
1342 Called every frame for each client after the physics are run
1343 =============
1344 */
1345 void PlayerPostThink (void)
1346 {
1347         if(self.classname == "player") {
1348                 CheckRules_Player();
1349                 UpdateChatBubble();
1350                 UpdateTeamBubble();
1351                 UpdatePlayerColors();
1352                 if (self.deadflag == DEAD_NO)
1353                 if (self.impulse)
1354                         ImpulseCommands ();
1355                 if (intermission_running)
1356                         return;         // intermission or finale
1357
1358                 //PrintWelcomeMessage(self);
1359                 //if (TetrisPostFrame()) return;
1360         } else if (self.classname == "observer") {
1361                 //do nothing
1362         } else if (self.classname == "spectator") {
1363                 //do nothing
1364         }
1365 }