data/qcsrc/server/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121         string spotname;
 122
 123         spot = find (world, classname, "testplayerstart");
 124         if (spot)
 125                 return spot;
 126
 127         spotname = "info_player_deathmatch";
 128         teamcheck = 0;
 129
 130         if(!anypoint && cvar("g_ctf") )
 131                 teamcheck = self.team;
 132
 133         // get the list of players
 134         playerlist = findchain(classname, "player");
 135         // get the entire list of spots
 136         firstspot = findchain(classname, "info_player_deathmatch");
 137         // filter out the bad ones
 138         // (note this returns the original list if none survived)
 139         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 140
 141         // there is 50/50 chance of choosing a random spot or the furthest spot
 142         // (this means that roughly every other spawn will be furthest, so you
 143         // usually won't get fragged at spawn twice in a row)
 144         if (random() > 0.5 || spawn_allbad || spawn_allgood)
 145                 spot = Spawn_RandomPoint(firstspot);
 146         else
 147                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 148
 149         if (!spot)
 150         {
 151                 if(cvar("spawn_debug"))
 152                         GotoNextMap();
 153                 else
 154                         error ("PutClientInServer: no start points on level");
 155         }
 156
 157         return spot;
 158 }
 159
 160 /*
 161 =============
 162 CheckPlayerModel
 163
 164 Checks if the argument string can be a valid playermodel.
 165 Returns a valid one in doubt.
 166 =============
 167 */
 168 string FallbackPlayerModel = "models/player/marine.zym";
 169 string CheckPlayerModel(string plyermodel) {
 170         if(strlen(plyermodel) < 4)
 171                 return FallbackPlayerModel;
 172         if( substring(plyermodel,0,14) != "models/player/")
 173                 return FallbackPlayerModel;
 174         else if(cvar("sv_servermodelsonly"))
 175         {
 176                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 177                         return FallbackPlayerModel;
 178                 if(!fexists(plyermodel))
 179                         return FallbackPlayerModel;
 180         }
 181         return plyermodel;
 182 }
 183
 184 /*
 185 =============
 186 Client_customizeentityforclient
 187
 188 LOD reduction
 189 =============
 190 */
 191 float Client_customizeentityforclient()
 192 {
 193 #ifdef ALLOW_VARIABLE_LOD
 194         // self: me
 195         // other: the player viewing me
 196         float distance;
 197         float f;
 198
 199         if(other.cvar_cl_playerdetailreduction <= 0)
 200         {
 201                 if(other.cvar_cl_playerdetailreduction <= -2)
 202                         self.modelindex = self.modelindex_lod2;
 203                 else if(other.cvar_cl_playerdetailreduction <= -1)
 204                         self.modelindex = self.modelindex_lod1;
 205                 else
 206                         self.modelindex = self.modelindex_lod0;
 207         }
 208         else
 209         {
 210                 distance = vlen(self.origin - other.origin);
 211                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 212                 if(f > 10000)
 213                         self.modelindex = self.modelindex_lod2;
 214                 else if(f > 5000)
 215                         self.modelindex = self.modelindex_lod1;
 216                 else
 217                         self.modelindex = self.modelindex_lod0;
 218         }
 219 #endif
 220
 221         return TRUE;
 222 }
 223
 224 void setmodel_lod(entity e, string modelname)
 225 {
 226 #ifdef ALLOW_VARIABLE_LOD
 227         string s;
 228
 229         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 230         if(fexists(s))
 231         {
 232                 precache_model(s);
 233                 setmodel(e, s);
 234                 self.modelindex_lod1 = self.modelindex;
 235         }
 236         else
 237                 self.modelindex_lod1 = -1;
 238
 239         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 240         if(fexists(s))
 241         {
 242                 precache_model(s);
 243                 setmodel(e, s);
 244                 self.modelindex_lod2 = self.modelindex;
 245         }
 246         else
 247                 self.modelindex_lod2 = -1;
 248
 249         precache_model(modelname);
 250         setmodel(e, modelname);
 251         self.modelindex_lod0 = self.modelindex;
 252
 253         if(self.modelindex_lod1 < 0)
 254                 self.modelindex_lod1 = self.modelindex;
 255
 256         if(self.modelindex_lod2 < 0)
 257                 self.modelindex_lod2 = self.modelindex;
 258 #else
 259         precache_model(modelname);
 260         setmodel(e, modelname);
 261 #endif
 262 }
 263
 264 /*
 265 =============
 266 PutObserverInServer
 267
 268 putting a client as observer in the server
 269 =============
 270 */
 271 void PutObserverInServer (void)
 272 {
 273         entity  spot;
 274         spot = SelectSpawnPoint (FALSE);
 275         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 276
 277         if(clienttype(self) == CLIENTTYPE_REAL)
 278         {
 279                 msg_entity = self;
 280                 WriteByte(MSG_ONE, SVC_SETVIEW);
 281                 WriteEntity(MSG_ONE, self);
 282         }
 283
 284         if (cvar("g_runematch"))
 285                 DropAllRunes(self);
 286
 287         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 288                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 289         else if(self.killcount != -666)
 290                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 291
 292         self.classname = "observer";
 293         self.health = -666;
 294         self.takedamage = DAMAGE_NO;
 295         self.solid = SOLID_NOT;
 296         self.movetype = MOVETYPE_NOCLIP;
 297         self.flags = FL_CLIENT | FL_NOTARGET;
 298         self.armorvalue = 666;
 299         self.effects = 0;
 300         self.armorvalue = cvar("g_balance_armor_start");
 301         self.pauserotarmor_finished = 0;
 302         self.pauserothealth_finished = 0;
 303         self.pauseregen_finished = 0;
 304         self.damageforcescale = 0;
 305         self.death_time = 0;
 306         self.dead_time = 0;
 307         self.dead_frame = 0;
 308         self.die_frame = 0;
 309         self.deaths = 0;
 310         self.alpha = 0;
 311         self.scale = 0;
 312         self.fade_time = 0;
 313         self.pain_frame = 0;
 314         self.pain_finished = 0;
 315         self.strength_finished = 0;
 316         self.invincible_finished = 0;
 317         self.pushltime = 0;
 318         self.think = SUB_Null;
 319         self.nextthink = 0;
 320         self.hook_time = 0;
 321         self.runes = 0;
 322         self.deadflag = DEAD_NO;
 323         self.angles = spot.angles;
 324         self.angles_z = 0;
 325         self.fixangle = TRUE;
 326         self.crouch = FALSE;
 327         self.view_ofs = PL_VIEW_OFS;
 328         setorigin (self, spot.origin);
 329         setsize (self, '0 0 0', '0 0 0');
 330         self.oldorigin = self.origin;
 331         self.items = 0;
 332         self.model = "";
 333         self.modelindex = 0;
 334         self.weapon = 0;
 335         self.weaponmodel = "";
 336         self.weaponframe = 0;
 337         self.weaponentity = world;
 338         self.killcount = -666;
 339         self.velocity = '0 0 0';
 340         self.avelocity = '0 0 0';
 341         self.punchangle = '0 0 0';
 342         self.punchvector = '0 0 0';
 343         self.oldvelocity = self.velocity;
 344
 345         if(cvar("g_arena"))
 346         {
 347                 if(self.frags != -2)
 348                 {
 349                         Spawnqueue_Insert(self);
 350                 }
 351                 else
 352                 {
 353                         Spawnqueue_Unmark(self);
 354                         Spawnqueue_Remove(self);
 355                 }
 356         }
 357         else if(!cvar("g_lms"))
 358                 self.frags = -666;
 359 }
 360
 361
 362 /*
 363 =============
 364 PutClientInServer
 365
 366 Called when a client spawns in the server
 367 =============
 368 */
 369 void PutClientInServer (void)
 370 {
 371         if(clienttype(self) == CLIENTTYPE_BOT)
 372         {
 373                 self.classname = "player";
 374         }
 375         else if(clienttype(self) == CLIENTTYPE_REAL)
 376         {
 377                 msg_entity = self;
 378                 WriteByte(MSG_ONE, SVC_SETVIEW);
 379                 WriteEntity(MSG_ONE, self);
 380         }
 381
 382         // player is dead and becomes observer
 383         if(cvar("g_lms") && self.frags < 1)
 384                 self.classname = "observer";
 385
 386         if(cvar("g_arena"))
 387         if(!self.spawned)
 388                 self.classname = "observer";
 389
 390         if(self.classname == "player") {
 391                 entity  spot;
 392
 393                 spot = SelectSpawnPoint (FALSE);
 394
 395                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397                 self.classname = "player";
 398                 self.iscreature = TRUE;
 399                 self.movetype = MOVETYPE_WALK;
 400                 self.solid = SOLID_SLIDEBOX;
 401                 self.flags = FL_CLIENT;
 402                 self.takedamage = DAMAGE_AIM;
 403                 self.effects = 0;
 404                 self.health = cvar("g_balance_health_start");
 405                 self.armorvalue = cvar("g_balance_armor_start");
 406                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 407                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 408                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 409                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 410                 self.damageforcescale = 2;
 411                 self.death_time = 0;
 412                 self.dead_time = 0;
 413                 self.dead_frame = 0;
 414                 self.die_frame = 0;
 415                 self.alpha = 0;
 416                 self.scale = 0;
 417                 self.fade_time = 0;
 418                 self.pain_frame = 0;
 419                 self.pain_finished = 0;
 420                 self.strength_finished = 0;
 421                 self.invincible_finished = 0;
 422                 self.pushltime = 0;
 423                 //self.speed_finished = 0;
 424                 //self.slowmo_finished = 0;
 425                 // players have no think function
 426                 self.think = SUB_Null;
 427                 self.nextthink = 0;
 428                 self.weapon = 0;
 429                 self.switchweapon = 0;
 430                 self.hook_time = 0;
 431
 432                 self.runes = 0;
 433
 434                 self.deadflag = DEAD_NO;
 435
 436                 self.angles = spot.angles;
 437
 438                 self.angles_z = 0; // never spawn tilted even if the spot says to
 439                 self.fixangle = TRUE; // turn this way immediately
 440                 self.velocity = '0 0 0';
 441                 self.avelocity = '0 0 0';
 442                 self.punchangle = '0 0 0';
 443                 self.punchvector = '0 0 0';
 444                 self.oldvelocity = self.velocity;
 445
 446                 self.viewzoom = 0.6;
 447
 448                 self.customizeentityforclient = Client_customizeentityforclient;
 449
 450                 if(cvar("sv_defaultcharacter") == 1) {
 451                         local string defaultmodel;
 452                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 453                         setmodel_lod (self, defaultmodel);
 454                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 455                 } else {
 456                         self.playermodel = CheckPlayerModel(self.playermodel);
 457                         setmodel_lod (self, self.playermodel);
 458                         self.skin = stof(self.playerskin);
 459
 460                 }
 461
 462                 self.crouch = FALSE;
 463                 self.view_ofs = PL_VIEW_OFS;
 464                 setsize (self, PL_MIN, PL_MAX);
 465                 self.spawnorigin = spot.origin;
 466                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 467                 // don't reset back to last position, even if new position is stuck in solid
 468                 self.oldorigin = self.origin;
 469
 470                 if(cvar("g_lms"))
 471                 {
 472                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 473                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 474                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 475                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 476                         self.health = cvar("g_lms_start_health");
 477                         self.armorvalue = cvar("g_lms_start_armor");
 478                 }
 479                 else if (cvar("g_use_ammunition")) {
 480                         self.ammo_shells = cvar("g_start_ammo_shells");
 481                         self.ammo_nails = cvar("g_start_ammo_nails");
 482                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 483                         self.ammo_cells = cvar("g_start_ammo_cells");
 484                 } else {
 485                         self.ammo_shells = 999;
 486                         self.ammo_nails = 999;
 487                         self.ammo_rockets = 999;
 488                         self.ammo_cells = 999;
 489                 }
 490
 491                 self.items = 0;
 492                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 493                 {
 494                         self.items = self.items | IT_LASER;
 495                         self.switchweapon = WEP_LASER;
 496                 }
 497                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 498                 {
 499                         self.items = self.items | IT_SHOTGUN;
 500                         self.switchweapon = WEP_SHOTGUN;
 501                 }
 502                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 503                 {
 504                         self.items = self.items | IT_UZI;
 505                         self.switchweapon = WEP_UZI;
 506                 }
 507                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 508                 {
 509                         self.items = self.items | IT_GRENADE_LAUNCHER;
 510                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 511                 }
 512                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 513                 {
 514                         self.items = self.items | IT_ELECTRO;
 515                         self.switchweapon = WEP_ELECTRO;
 516                 }
 517                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 518                 {
 519                         self.items = self.items | IT_CRYLINK;
 520                         self.switchweapon = WEP_CRYLINK;
 521                 }
 522                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 523                 {
 524                         self.items = self.items | IT_NEX;
 525                         self.switchweapon = WEP_NEX;
 526                 }
 527                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 528                 {
 529                         self.items = self.items | IT_HAGAR;
 530                         self.switchweapon = WEP_HAGAR;
 531                 }
 532                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 533                 {
 534                         self.items = self.items | IT_ROCKET_LAUNCHER;
 535                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 536                 }
 537
 538                 if(cvar("g_instagib"))
 539                 {
 540                         self.items = IT_NEX;
 541                         self.switchweapon = WEP_NEX;
 542                         self.ammo_cells = 999;
 543                 }
 544
 545                 if(cvar("g_rocketarena"))
 546                 {
 547                         self.items = IT_ROCKET_LAUNCHER;
 548                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 549                         self.ammo_rockets = 999;
 550                 }
 551
 552                 if(cvar("g_nixnex"))
 553                 {
 554                         self.items = 0;
 555                         // will be done later
 556                 }
 557
 558                 if(cvar("g_minstagib"))
 559                 {
 560                         self.health = 100;
 561                         self.armorvalue = 0;
 562                         self.items = IT_NEX;
 563                         self.switchweapon = WEP_NEX;
 564                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 565                         self.extralives = 0;
 566                         self.jump_interval = time;
 567                 }
 568
 569                 if(cvar("g_arena"))
 570                         Spawnqueue_Remove(self);
 571
 572                 self.event_damage = PlayerDamage;
 573
 574                 self.bot_attack = TRUE;
 575
 576                 self.statdraintime = time + 5;
 577                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 578
 579                 if(self.killcount == -666) {
 580                         self.killcount = 0;
 581                         if(!cvar("g_arena"))
 582                                 self.frags = 0;
 583                 }
 584
 585                 self.cnt = WEP_LASER;
 586                 self.nixnex_lastchange_id = -1;
 587
 588                 /*
 589                 W_UpdateWeapon();
 590                 W_UpdateAmmo();
 591                 */
 592                 CL_SpawnWeaponentity();
 593                 self.alpha = default_player_alpha;
 594                 self.exteriorweaponentity.alpha = default_player_alpha;
 595
 596                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 597                 self.lms_traveled_distance = 0;
 598
 599                 if(cvar("spawn_debug"))
 600                 {
 601                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 602                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 603                 }
 604
 605                 //stuffcmd(self, "chase_active 0");
 606                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 607         } else if(self.classname == "observer") {
 608                 PutObserverInServer ();
 609         }
 610 }
 611
 612 /*
 613 =============
 614 SetNewParms
 615 =============
 616 */
 617 void SetNewParms (void)
 618 {
 619
 620 }
 621
 622 /*
 623 =============
 624 SetChangeParms
 625 =============
 626 */
 627 void SetChangeParms (void)
 628 {
 629
 630 }
 631
 632 /*
 633 =============
 634 ClientKill
 635
 636 Called when a client types 'kill' in the console
 637 =============
 638 */
 639 void ClientKill (void)
 640 {
 641         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 642 }
 643
 644 /*
 645 =============
 646 ClientConnect
 647
 648 Called when a client connects to the server
 649 =============
 650 */
 651 string ColoredTeamName(float t);
 652 //void dom_player_join_team(entity pl);
 653 void ClientConnect (void)
 654 {
 655         self.classname = "player_joining";
 656         self.flags = self.flags | FL_CLIENT;
 657
 658         if(player_count<0) player_count = 0;
 659
 660         bot_clientconnect();
 661
 662         //if(cvar("g_domination"))
 663         //      dom_player_join_team(self);
 664
 665         //JoinBestTeam(self, FALSE);
 666
 667         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 668                 self.classname = "observer";
 669         } else {
 670                 self.classname = "player";
 671                 campaign_bots_may_start = 1;
 672         }
 673
 674         self.playerid = (playerid_last = playerid_last + 1);
 675         if(cvar("sv_eventlog"))
 676         {
 677                 string s;
 678                 if(clienttype(self) == CLIENTTYPE_REAL)
 679                         s = "player";
 680                 else
 681                         s = "bot";
 682                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 683                 s = strcat(":team:", ftos(self.playerid), ":");
 684                 s = strcat(s, ftos(self.team));
 685                 GameLogEcho(s, FALSE);
 686         }
 687
 688         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 689
 690         bprint ("^4",self.netname);
 691         bprint ("^4 connected");
 692
 693         if(cvar("g_domination") || cvar("g_ctf"))
 694         {
 695                 bprint(" and joined the ");
 696                 bprint(ColoredTeamName(self.team));
 697         }
 698
 699         bprint("\n");
 700
 701         self.welcomemessage_time = time + cvar("welcome_message_time");
 702         self.welcomemessage_time2 = 0;
 703
 704         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 705         // send prediction settings to the client
 706         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 707         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 708         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 709         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 710         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 711         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 712         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 713         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 714         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 715         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 716         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 717         // Wazat's grappling hook
 718         SetGrappleHookBindings();
 719
 720         // get autoswitch state from player
 721         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 722         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 723
 724         // get version info from player
 725         stuffcmd(self, "cmd clientversion $gameversion\n");
 726
 727         // get other cvars from player
 728         GetCvars(0);
 729
 730         // set cvar for team scoreboard
 731         stuffcmd(self, strcat("set teamplay ", ftos(teams_matter), "\n"));
 732
 733         if(cvar("g_lms"))
 734         {
 735                 self.frags = cvar("fraglimit");
 736                 // no fraglimit was set, so player gets 999 lives
 737                 if(self.frags < 1)
 738                         self.frags = 999;
 739
 740                 // disallow player to join after the worst player has lost g_lms_last_join lives
 741                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 742                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 743                 {
 744                         self.frags = -666;
 745                         lms_dead_count += 1;
 746                 }
 747                 else if(cvar("fraglimit") > lms_lowest_lives)
 748                 {
 749                         self.frags = lms_lowest_lives;
 750                 }
 751         }
 752         else if(cvar("g_arena"))
 753         {
 754                 self.classname = "observer";
 755                 Spawnqueue_Insert(self);
 756         }
 757
 758         bot_relinkplayerlist();
 759
 760         self.jointime = time;
 761 }
 762
 763 /*
 764 =============
 765 ClientDisconnect
 766
 767 Called when a client disconnects from the server
 768 =============
 769 */
 770 void(entity e) DropFlag;
 771 .entity chatbubbleentity;
 772 .entity teambubbleentity;
 773 void ClientDisconnect (void)
 774 {
 775         float save;
 776         if(cvar("sv_eventlog"))
 777                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 778         bprint ("^4",self.netname);
 779         bprint ("^4 disconnected\n");
 780
 781         if (self.chatbubbleentity)
 782         {
 783                 remove (self.chatbubbleentity);
 784                 self.chatbubbleentity = world;
 785         }
 786
 787         if (self.teambubbleentity)
 788         {
 789                 remove (self.teambubbleentity);
 790                 self.teambubbleentity = world;
 791         }
 792
 793         DropAllRunes(self);
 794
 795         if(self.flagcarried)
 796                 DropFlag(self.flagcarried);
 797
 798         save = self.flags;
 799         self.flags = self.flags - (self.flags & FL_CLIENT);
 800         bot_relinkplayerlist();
 801         self.flags = save;
 802
 803         // player was dead, decrease dead count
 804         if(cvar("g_lms") && self.frags < 1)
 805                 lms_dead_count -= 1;
 806         else if(cvar("g_arena"))
 807         {
 808                 Spawnqueue_Unmark(self);
 809                 Spawnqueue_Remove(self);
 810         }
 811 }
 812
 813 .float buttonchat;
 814 void() ChatBubbleThink =
 815 {
 816         self.nextthink = time;
 817         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 818         {
 819                 remove(self);
 820                 return;
 821         }
 822         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 823         if (self.owner.buttonchat && !self.owner.deadflag)
 824                 self.model = self.mdl;
 825         else
 826                 self.model = "";
 827 };
 828
 829 void() UpdateChatBubble =
 830 {
 831         if (!self.modelindex)
 832                 return;
 833         // spawn a chatbubble entity if needed
 834         if (!self.chatbubbleentity)
 835         {
 836                 self.chatbubbleentity = spawn();
 837                 self.chatbubbleentity.owner = self;
 838                 self.chatbubbleentity.exteriormodeltoclient = self;
 839                 self.chatbubbleentity.think = ChatBubbleThink;
 840                 self.chatbubbleentity.nextthink = time;
 841                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 842                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 843                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 844                 self.chatbubbleentity.model = "";
 845         }
 846 }
 847
 848
 849 void() TeamBubbleThink =
 850 {
 851         self.nextthink = time;
 852         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 853         {
 854                 remove(self);
 855                 return;
 856         }
 857 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 858         if (self.owner.buttonchat || self.owner.deadflag)
 859                 self.model = "";
 860         else
 861                 self.model = self.mdl;
 862
 863 };
 864
 865 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 866
 867 void() UpdateTeamBubble =
 868 {
 869         if (!self.modelindex || !cvar("teamplay"))
 870                 return;
 871         // spawn a teambubble entity if needed
 872         if (!self.teambubbleentity && cvar("teamplay"))
 873         {
 874                 self.teambubbleentity = spawn();
 875                 self.teambubbleentity.owner = self;
 876                 self.teambubbleentity.exteriormodeltoclient = self;
 877                 self.teambubbleentity.think = TeamBubbleThink;
 878                 self.teambubbleentity.nextthink = time;
 879                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 880 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 881                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 882                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 883                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 884                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 885                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 886         }
 887 }
 888
 889 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 890 // added to the model skins
 891 /*void() UpdateColorModHack =
 892 {
 893         local float c;
 894         c = self.clientcolors & 15;
 895         // LordHavoc: only bothering to support white, green, red, yellow, blue
 896              if (teamplay == 0) self.colormod = '0 0 0';
 897         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 898         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 899         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 900         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 901         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 902         else self.colormod = '1 1 1';
 903 };*/
 904
 905 void UpdatePlayerColors () {
 906         if(self.weaponentity) {
 907                 self.weaponentity.colormap = self.colormap;
 908                 self.exteriorweaponentity.colormap = self.colormap;
 909         }
 910 }
 911 /*
 912 =============
 913 PlayerJump
 914
 915 When you press the jump key
 916 =============
 917 */
 918 void PlayerJump (void)
 919 {
 920         float mjumpheight;
 921
 922         mjumpheight = cvar("g_balance_jumpheight");
 923         if (self.waterlevel >= 2)
 924         {
 925                 if (self.watertype == CONTENT_WATER)
 926                         self.velocity_z = 200;
 927                 else if (self.watertype == CONTENT_SLIME)
 928                         self.velocity_z = 80;
 929                 else
 930                         self.velocity_z = 50;
 931
 932                 return;
 933         }
 934
 935
 936         if (!(self.flags & FL_ONGROUND))
 937                 return;
 938
 939         if (!(self.flags & FL_JUMPRELEASED))
 940                 return;
 941
 942         if(cvar("g_runematch"))
 943         {
 944                 if(self.runes & RUNE_SPEED)
 945                 {
 946                         if(self.runes & CURSE_SLOW)
 947                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 948                         else
 949                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 950                 }
 951                 else if(self.runes & CURSE_SLOW)
 952                 {
 953                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 954                 }
 955         }
 956
 957         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 958         {
 959                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 960         }
 961
 962         self.velocity_z = self.velocity_z + mjumpheight;
 963         self.oldvelocity_z = self.velocity_z;
 964
 965         self.flags = self.flags - FL_ONGROUND;
 966         self.flags = self.flags - FL_JUMPRELEASED;
 967 }
 968
 969 void() CheckWaterJump =
 970 {
 971         local vector start, end;
 972
 973 // check for a jump-out-of-water
 974         makevectors (self.angles);
 975         start = self.origin;
 976         start_z = start_z + 8;
 977         v_forward_z = 0;
 978         normalize(v_forward);
 979         end = start + v_forward*24;
 980         traceline (start, end, TRUE, self);
 981         if (trace_fraction < 1)
 982         {       // solid at waist
 983                 start_z = start_z + self.maxs_z - 8;
 984                 end = start + v_forward*24;
 985                 self.movedir = trace_plane_normal * -50;
 986                 traceline (start, end, TRUE, self);
 987                 if (trace_fraction == 1)
 988                 {       // open at eye level
 989                         self.flags = self.flags | FL_WATERJUMP;
 990                         self.velocity_z = 225;
 991                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 992                         self.teleport_time = time + 2;  // safety net
 993                         return;
 994                 }
 995         }
 996 };
 997
 998
 999 void respawn(void)
1000 {
1001         CopyBody(1);
1002         PutClientInServer();
1003 }
1004
1005 void player_powerups (void)
1006 {
1007         if (cvar("g_minstagib"))
1008         {
1009                 self.effects = EF_FULLBRIGHT;
1010                 if (self.items & IT_STRENGTH)
1011                 {
1012                         if (time > self.strength_finished)
1013                         {
1014                                 self.alpha = default_player_alpha;
1015                                 self.exteriorweaponentity.alpha = default_player_alpha;
1016                                 self.items = self.items - (self.items & IT_STRENGTH);
1017                                 sprint(self, "^3Invisibility has worn off\n");
1018                         }
1019                 }
1020                 else
1021                 {
1022                         if (time < self.strength_finished)
1023                         {
1024                                 self.alpha = cvar("g_minstagib_invis_alpha");
1025                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1026                                 self.items = self.items | IT_STRENGTH;
1027                                 sprint(self, "^3You are invisible\n");
1028                         }
1029                 }
1030
1031                 if (self.items & IT_INVINCIBLE)
1032                 {
1033                         if (time > self.invincible_finished)
1034                         {
1035                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1036                                 sprint(self, "^3Speed has worn off\n");
1037                         }
1038                 }
1039                 else
1040                 {
1041                         if (time < self.invincible_finished)
1042                         {
1043                                 self.items = self.items | IT_INVINCIBLE;
1044                                 sprint(self, "^3You are on speed\n");
1045                         }
1046                 }
1047                 return;
1048         }
1049
1050         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1051         if (self.items & IT_STRENGTH)
1052         {
1053                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1054                 if (time > self.strength_finished)
1055                 {
1056                         self.items = self.items - (self.items & IT_STRENGTH);
1057                         sprint(self, "^3Strength has worn off\n");
1058                 }
1059         }
1060         else
1061         {
1062                 if (time < self.strength_finished)
1063                 {
1064                         self.items = self.items | IT_STRENGTH;
1065                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
1066                 }
1067         }
1068         if (self.items & IT_INVINCIBLE)
1069         {
1070                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1071                 if (time > self.invincible_finished)
1072                 {
1073                         self.items = self.items - (self.items & IT_INVINCIBLE);
1074                         sprint(self, "^3Shield has worn off\n");
1075                 }
1076         }
1077         else
1078         {
1079                 if (time < self.invincible_finished)
1080                 {
1081                         self.items = self.items | IT_INVINCIBLE;
1082                         sprint(self, "^3Shield surrounds you\n");
1083                 }
1084         }
1085
1086         if (cvar("g_fullbrightplayers"))
1087                 self.effects = self.effects | EF_FULLBRIGHT;
1088
1089         // midair gamemode: damage only while in the air
1090         // if in midair mode, being on ground grants temporary invulnerability
1091         // (this is so that multishot weapon don't clear the ground flag on the
1092         // first damage in the frame, leaving the player vulnerable to the
1093         // remaining hits in the same frame)
1094         if (self.flags & FL_ONGROUND)
1095         if (cvar("g_midair"))
1096                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1097
1098         if (time < self.spawnshieldtime)
1099                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1100 }
1101
1102 void player_regen (void)
1103 {
1104         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1105         maxh = cvar("g_balance_health_stable");
1106         maxa = cvar("g_balance_armor_stable");
1107         limith = cvar("g_balance_health_limit");
1108         limita = cvar("g_balance_armor_limit");
1109
1110         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1111                 return;
1112
1113         if(cvar("g_runematch"))
1114         {
1115                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1116                 if (self.runes & RUNE_REGEN)
1117                 {
1118                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1119                         {
1120                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1121                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1122                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1123                         }
1124                         else
1125                         {
1126                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1127                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1128                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1129                         }
1130                 }
1131                 else if (self.runes & CURSE_VENOM)
1132                 {
1133                         max_mod = cvar("g_balance_curse_venom_hpmod");
1134                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1135                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1136                         else
1137                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1138                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1139                         //if (!self.runes & RUNE_REGEN)
1140                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1141                 }
1142                 maxh = maxh * max_mod;
1143                 //maxa = maxa * max_mod;
1144
1145                 if (time > self.pauserotarmor_finished)
1146                 {
1147                         if (self.armorvalue > maxa)
1148                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1149                 }
1150                 if (time > self.pauserothealth_finished)
1151                 {
1152                         if (self.health > maxh)
1153                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1154                 }
1155                 if (time > self.pauseregen_finished)
1156                 {
1157                         if (self.health < maxh)
1158                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1159                         if (self.armorvalue < maxa)
1160                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1161                 }
1162         }
1163         else
1164         {
1165                 if (time > self.pauserothealth_finished)
1166                 if (self.health > maxh)
1167                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1168                 if (time > self.pauserotarmor_finished)
1169                 if (self.armorvalue > maxa)
1170                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1171                 if (time > self.pauseregen_finished)
1172                 {
1173                         if (self.health < maxh)
1174                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1175                         if (self.armorvalue < maxa)
1176                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1177                 }
1178         }
1179
1180         if (self.health > limith)
1181                 self.health = limith;
1182         if(self.health < 1)
1183                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1184         if (self.armorvalue > limita)
1185                 self.armorvalue = limita;
1186 }
1187
1188 /*
1189 ======================
1190 spectate mode routines
1191 ======================
1192 */
1193 void SpectateCopy(entity spectatee) {
1194         self.armortype = spectatee.armortype;
1195         self.armorvalue = spectatee.armorvalue;
1196         self.currentammo = spectatee.currentammo;
1197         self.effects = spectatee.effects;
1198         self.health = spectatee.health;
1199         self.impulse = 0;
1200         self.items = spectatee.items;
1201         self.punchangle = spectatee.punchangle;
1202         self.view_ofs = spectatee.view_ofs;
1203         self.v_angle = spectatee.v_angle;
1204         self.viewzoom = spectatee.viewzoom;
1205         setorigin(self, spectatee.origin);
1206         setsize(self, spectatee.mins, spectatee.maxs);
1207 }
1208
1209 void SpectateUpdate() {
1210         if (self != self.enemy) {
1211                 if(self.enemy.flags & FL_NOTARGET)
1212                         PutObserverInServer();
1213                 SpectateCopy(self.enemy);
1214                 self.dmg_take = self.enemy.dmg_take;
1215                 self.dmg_save = self.enemy.dmg_save;
1216                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1217                 self.fixangle = TRUE;
1218                 self.angles = self.enemy.v_angle;
1219                 //msg_entity = self;
1220                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1221                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1222                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1223                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1224         }
1225 }
1226
1227 float SpectateNext() {
1228         other = find(self.enemy, classname, "player");
1229         if (!other) {
1230                 other = find(other, classname, "player");
1231         }
1232         if (other) {
1233                 self.enemy = other;
1234         }
1235         if(self.enemy.classname == "player") {
1236                 msg_entity = self;
1237                 WriteByte(MSG_ONE, SVC_SETVIEW);
1238                 WriteEntity(MSG_ONE, self.enemy);
1239                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1240                 SpectateUpdate();
1241                 return 1;
1242         } else {
1243                 return 0;
1244         }
1245 }
1246
1247 /*
1248 =============
1249 PlayerPreThink
1250
1251 Called every frame for each client before the physics are run
1252 =============
1253 */
1254 void PlayerPreThink (void)
1255 {
1256         if(self.classname == "player") {
1257                 local vector m1, m2;
1258
1259 //              if(self.netname == "Wazat")
1260 //                      bprint(strcat(self.classname, "\n"));
1261
1262                 CheckRules_Player();
1263
1264                 Nixnex_GiveCurrentWeapon();
1265
1266                 if(self.button7)
1267                         PrintWelcomeMessage(self);
1268
1269                 if(cvar("g_lms") || !cvar("sv_spectate"))
1270                 if((time - self.jointime) <= cvar("welcome_message_time"))
1271                         PrintWelcomeMessage(self);
1272
1273                 if (intermission_running)
1274                 {
1275                         IntermissionThink ();   // otherwise a button could be missed between
1276                         return;                                 // the think tics
1277                 }
1278
1279                 if (self.deadflag != DEAD_NO)
1280                 {
1281                         player_anim();
1282                         weapon_freeze();
1283                         if (self.deadflag == DEAD_DYING)
1284                         {
1285                                 if (time > self.dead_time)
1286                                         self.deadflag = DEAD_DEAD;
1287                         }
1288                         else if (self.deadflag == DEAD_DEAD)
1289                         {
1290                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1291                                         self.deadflag = DEAD_RESPAWNABLE;
1292                                 else if (!self.button0 && !self.button2 && !self.button3)
1293                                         self.deadflag = DEAD_RESPAWNABLE;
1294                         }
1295                         else if (self.deadflag == DEAD_RESPAWNABLE)
1296                         {
1297                                 if (self.button0  ||
1298                                     self.button2  ||
1299                                     self.button3  ||
1300                                     self.button4  ||
1301                                     self.button5  ||
1302                                     self.button6  ||
1303                                     self.button7  ||
1304                                     self.button8  ||
1305                                     self.buttonuse ||
1306                                     cvar("g_lms") ||
1307                                     cvar("g_forced_respawn"))
1308                                         respawn();
1309                         }
1310                         return;
1311                 }
1312
1313                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1314                 {
1315                         vector dist;
1316
1317                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1318                         dist = self.oldorigin - self.origin;
1319                         dist_z = 0;
1320                         self.lms_traveled_distance += fabs(vlen(dist));
1321
1322                         if(time > self.lms_nextcheck)
1323                         {
1324                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1325                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1326                                 {
1327                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1328                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1329                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1330                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1331                                 }
1332                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1333                                 self.lms_traveled_distance = 0;
1334                         }
1335                 }
1336
1337                 if (self.button5 && !self.hook.state)
1338                 {
1339                         if (!self.crouch)
1340                         {
1341                                 self.crouch = TRUE;
1342                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1343                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1344                         }
1345                 }
1346                 else
1347                 {
1348                         if (self.crouch)
1349                         {
1350                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1351                                 if (!trace_startsolid)
1352                                 {
1353                                         self.crouch = FALSE;
1354                                         self.view_ofs = PL_VIEW_OFS;
1355                                         setsize (self, PL_MIN, PL_MAX);
1356                                 }
1357                         }
1358                 }
1359
1360                 if(cvar("sv_defaultcharacter") == 1) {
1361                         local string defaultmodel;
1362                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1363
1364                         if (defaultmodel != self.model)
1365                         {
1366                                 m1 = self.mins;
1367                                 m2 = self.maxs;
1368                                 setmodel_lod (self, defaultmodel);
1369                                 setsize (self, m1, m2);
1370                         }
1371
1372                         if (self.skin != cvar("sv_defaultplayerskin"))
1373                                 self.skin = cvar("sv_defaultplayerskin");
1374                 } else {
1375                         if (self.playermodel != self.model)
1376                         {
1377                                 self.playermodel = CheckPlayerModel(self.playermodel);
1378                                 m1 = self.mins;
1379                                 m2 = self.maxs;
1380                                 setmodel_lod (self, self.playermodel);
1381                                 setsize (self, m1, m2);
1382                         }
1383
1384                         if (self.skin != stof(self.playerskin))
1385                                 self.skin = stof(self.playerskin);
1386                 }
1387                 // Savage: Check for nameless players
1388                 if (strlen(self.netname) < 1) {
1389                         self.netname = "Player";
1390                         stuffcmd(self, "name Player\n");
1391                 }
1392
1393                 GrapplingHookFrame();
1394
1395                 W_WeaponFrame();
1396
1397                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1398                 {
1399                         if (cvar("g_minstagib") && self.button3)
1400                         {
1401                                 if (self.jump_interval <= (time + 0.1))
1402                                 {
1403                                         self.jump_interval = time + 1;
1404                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1405                                 }
1406                         }
1407                         else if (self.viewzoom > 0.4)
1408                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1409                 }
1410                 else if (self.viewzoom < 1.0)
1411                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1412
1413
1414                 if (self.button2)
1415                         PlayerJump ();
1416                 else
1417                         self.flags = self.flags | FL_JUMPRELEASED;
1418
1419                 player_powerups();
1420                 player_regen();
1421                 player_anim();
1422
1423                 //self.angles_y=self.v_angle_y + 90;   // temp
1424
1425                 if (self.waterlevel == 2)
1426                         CheckWaterJump ();
1427
1428                 //if (TetrisPreFrame()) return;
1429         } else if(gameover) {
1430                 if (intermission_running)
1431                         IntermissionThink ();   // otherwise a button could be missed between
1432                 return;
1433         } else if(self.classname == "observer") {
1434
1435                 if (self.flags & FL_JUMPRELEASED) {
1436                         if (self.button2 && self.version == cvar("gameversion")) {
1437                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1438                                         self.flags = self.flags & !FL_JUMPRELEASED;
1439                                         self.classname = "player";
1440                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1441                                                 JoinBestTeam(self, 0);
1442                                         if(cvar("g_campaign"))
1443                                                 campaign_bots_may_start = 1;
1444                                         PutClientInServer();
1445                                         if(self.flags & !FL_NOTARGET)
1446                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1447                                         centerprint(self,"");
1448                                         return;
1449                                 } else {
1450                                         self.flags = self.flags & !FL_JUMPRELEASED;
1451                                         stuffcmd(self,"menu_showteamselect\n");
1452                                         return;
1453                                 }
1454                         } else if(self.button0 && self.version == cvar("gameversion")) {
1455                                 self.flags = self.flags & !FL_JUMPRELEASED;
1456                                 if(SpectateNext() == 1) {
1457                                         self.classname = "spectator";
1458                                 }
1459                         }
1460                 } else {
1461                         if (!(self.button0 || self.button2)) {
1462                                 self.flags = self.flags | FL_JUMPRELEASED;
1463                         }
1464                 }
1465                 PrintWelcomeMessage(self);
1466         } else if(self.classname == "spectator") {
1467
1468                 if (self.flags & FL_JUMPRELEASED) {
1469                         if (self.button2 && self.version == cvar("gameversion")) {
1470                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1471                                         self.flags = self.flags & !FL_JUMPRELEASED;
1472                                         self.classname = "player";
1473                                         if(!cvar("g_lms"))
1474                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1475
1476                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1477                                                 JoinBestTeam(self, 0);
1478                                         if(cvar("g_campaign"))
1479                                                 campaign_bots_may_start = 1;
1480                                         PutClientInServer();
1481                                         centerprint(self,"");
1482                                         return;
1483                                 } else {
1484                                         self.flags = self.flags & !FL_JUMPRELEASED;
1485                                         stuffcmd(self,"menu_showteamselect\n");
1486                                         return;
1487                                 }
1488                         } else if(self.button0) {
1489                                 self.flags = self.flags & !FL_JUMPRELEASED;
1490                                 if(SpectateNext() == 1) {
1491                                         self.classname = "spectator";
1492                                 } else {
1493                                         self.classname = "observer";
1494                                         PutClientInServer();
1495                                 }
1496                         } else if (self.button3) {
1497                                 self.flags = self.flags & !FL_JUMPRELEASED;
1498                                 self.classname = "observer";
1499                                 PutClientInServer();
1500                         } else {
1501                                 SpectateUpdate();
1502                         }
1503         } else {
1504                 if (!(self.button0 || self.button3)) {
1505                         self.flags = self.flags | FL_JUMPRELEASED;
1506                 }
1507                 }
1508                 PrintWelcomeMessage(self);
1509         }
1510 }
1511
1512
1513 /*
1514 =============
1515 PlayerPostThink
1516
1517 Called every frame for each client after the physics are run
1518 =============
1519 */
1520 void PlayerPostThink (void)
1521 {
1522         if(self.classname == "player") {
1523                 CheckRules_Player();
1524                 UpdateChatBubble();
1525                 UpdateTeamBubble();
1526                 UpdatePlayerColors();
1527                 if (self.deadflag == DEAD_NO)
1528                 if (self.impulse)
1529                         ImpulseCommands ();
1530                 if (intermission_running)
1531                         return;         // intermission or finale
1532
1533                 //PrintWelcomeMessage(self);
1534                 //if (TetrisPostFrame()) return;
1535         } else if (self.classname == "observer") {
1536                 //do nothing
1537         } else if (self.classname == "spectator") {
1538                 //do nothing
1539         }
1540         Arena_Warmup();
1541 }