data/qcsrc/server/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 144         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 145                 spot = Spawn_RandomPoint(firstspot);
 146         else
 147                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 148
 149         if (!spot)
 150         {
 151                 if(cvar("spawn_debug"))
 152                         GotoNextMap();
 153                 else
 154                         error ("PutClientInServer: no start points on level");
 155         }
 156
 157         return spot;
 158 }
 159
 160 /*
 161 =============
 162 CheckPlayerModel
 163
 164 Checks if the argument string can be a valid playermodel.
 165 Returns a valid one in doubt.
 166 =============
 167 */
 168 string FallbackPlayerModel = "models/player/marine.zym";
 169 string CheckPlayerModel(string plyermodel) {
 170         if(strlen(plyermodel) < 4)
 171                 return FallbackPlayerModel;
 172         if( substring(plyermodel,0,14) != "models/player/")
 173                 return FallbackPlayerModel;
 174         else if(cvar("sv_servermodelsonly"))
 175         {
 176                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 177                         return FallbackPlayerModel;
 178                 if(!fexists(plyermodel))
 179                         return FallbackPlayerModel;
 180         }
 181         return plyermodel;
 182 }
 183
 184 /*
 185 =============
 186 Client_customizeentityforclient
 187
 188 LOD reduction
 189 =============
 190 */
 191 float Client_customizeentityforclient()
 192 {
 193 #ifdef ALLOW_VARIABLE_LOD
 194         // self: me
 195         // other: the player viewing me
 196         float distance;
 197         float f;
 198
 199         if(other.cvar_cl_playerdetailreduction <= 0)
 200         {
 201                 if(other.cvar_cl_playerdetailreduction <= -2)
 202                         self.modelindex = self.modelindex_lod2;
 203                 else if(other.cvar_cl_playerdetailreduction <= -1)
 204                         self.modelindex = self.modelindex_lod1;
 205                 else
 206                         self.modelindex = self.modelindex_lod0;
 207         }
 208         else
 209         {
 210                 distance = vlen(self.origin - other.origin);
 211                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 212                 if(f > 10000)
 213                         self.modelindex = self.modelindex_lod2;
 214                 else if(f > 5000)
 215                         self.modelindex = self.modelindex_lod1;
 216                 else
 217                         self.modelindex = self.modelindex_lod0;
 218         }
 219 #endif
 220
 221         return TRUE;
 222 }
 223
 224 void setmodel_lod(entity e, string modelname)
 225 {
 226 #ifdef ALLOW_VARIABLE_LOD
 227         string s;
 228
 229         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 230         if(fexists(s))
 231         {
 232                 precache_model(s);
 233                 setmodel(e, s);
 234                 self.modelindex_lod1 = self.modelindex;
 235         }
 236         else
 237                 self.modelindex_lod1 = -1;
 238
 239         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 240         if(fexists(s))
 241         {
 242                 precache_model(s);
 243                 setmodel(e, s);
 244                 self.modelindex_lod2 = self.modelindex;
 245         }
 246         else
 247                 self.modelindex_lod2 = -1;
 248
 249         precache_model(modelname);
 250         setmodel(e, modelname);
 251         self.modelindex_lod0 = self.modelindex;
 252
 253         if(self.modelindex_lod1 < 0)
 254                 self.modelindex_lod1 = self.modelindex;
 255
 256         if(self.modelindex_lod2 < 0)
 257                 self.modelindex_lod2 = self.modelindex;
 258 #else
 259         precache_model(modelname);
 260         setmodel(e, modelname);
 261 #endif
 262 }
 263
 264 /*
 265 =============
 266 PutObserverInServer
 267
 268 putting a client as observer in the server
 269 =============
 270 */
 271 void PutObserverInServer (void)
 272 {
 273         entity  spot;
 274         spot = SelectSpawnPoint (FALSE);
 275         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 276
 277         if(clienttype(self) == CLIENTTYPE_REAL)
 278         {
 279                 msg_entity = self;
 280                 WriteByte(MSG_ONE, SVC_SETVIEW);
 281                 WriteEntity(MSG_ONE, self);
 282         }
 283
 284         if (cvar("g_runematch"))
 285                 DropAllRunes(self);
 286
 287         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 288                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 289         else if(self.killcount != -666)
 290                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 291
 292         self.classname = "observer";
 293         self.health = -666;
 294         self.takedamage = DAMAGE_NO;
 295         self.solid = SOLID_NOT;
 296         self.movetype = MOVETYPE_NOCLIP;
 297         self.flags = FL_CLIENT | FL_NOTARGET;
 298         self.armorvalue = 666;
 299         self.effects = 0;
 300         self.armorvalue = cvar("g_balance_armor_start");
 301         self.pauserotarmor_finished = 0;
 302         self.pauserothealth_finished = 0;
 303         self.pauseregen_finished = 0;
 304         self.damageforcescale = 0;
 305         self.death_time = 0;
 306         self.dead_time = 0;
 307         self.dead_frame = 0;
 308         self.die_frame = 0;
 309         self.deaths = 0;
 310         self.alpha = 0;
 311         self.scale = 0;
 312         self.fade_time = 0;
 313         self.pain_frame = 0;
 314         self.pain_finished = 0;
 315         self.strength_finished = 0;
 316         self.invincible_finished = 0;
 317         self.pushltime = 0;
 318         self.think = SUB_Null;
 319         self.nextthink = 0;
 320         self.hook_time = 0;
 321         self.runes = 0;
 322         self.deadflag = DEAD_NO;
 323         self.angles = spot.angles;
 324         self.angles_z = 0;
 325         self.fixangle = TRUE;
 326         self.crouch = FALSE;
 327         self.view_ofs = PL_VIEW_OFS;
 328         setorigin (self, spot.origin);
 329         setsize (self, '0 0 0', '0 0 0');
 330         self.oldorigin = self.origin;
 331         self.items = 0;
 332         self.model = "";
 333         self.modelindex = 0;
 334         self.weapon = 0;
 335         self.weaponmodel = "";
 336         self.weaponentity = world;
 337         self.killcount = -666;
 338         self.velocity = '0 0 0';
 339         self.avelocity = '0 0 0';
 340         self.punchangle = '0 0 0';
 341         self.punchvector = '0 0 0';
 342         self.oldvelocity = self.velocity;
 343
 344         if(cvar("g_arena"))
 345         {
 346                 if(self.frags != -2)
 347                 {
 348                         Spawnqueue_Insert(self);
 349                 }
 350                 else
 351                 {
 352                         Spawnqueue_Unmark(self);
 353                         Spawnqueue_Remove(self);
 354                 }
 355         }
 356         else if(!cvar("g_lms"))
 357                 self.frags = -666;
 358 }
 359
 360
 361 /*
 362 =============
 363 PutClientInServer
 364
 365 Called when a client spawns in the server
 366 =============
 367 */
 368 void PutClientInServer (void)
 369 {
 370         if(clienttype(self) == CLIENTTYPE_BOT)
 371         {
 372                 self.classname = "player";
 373         }
 374         else if(clienttype(self) == CLIENTTYPE_REAL)
 375         {
 376                 msg_entity = self;
 377                 WriteByte(MSG_ONE, SVC_SETVIEW);
 378                 WriteEntity(MSG_ONE, self);
 379         }
 380
 381         // player is dead and becomes observer
 382         if(cvar("g_lms") && self.frags < 1)
 383                 self.classname = "observer";
 384
 385         if(cvar("g_arena"))
 386         if(!self.spawned)
 387                 self.classname = "observer";
 388
 389         if(self.classname == "player") {
 390                 entity  spot;
 391
 392                 spot = SelectSpawnPoint (FALSE);
 393
 394                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 395
 396                 self.classname = "player";
 397                 self.iscreature = TRUE;
 398                 self.movetype = MOVETYPE_WALK;
 399                 self.solid = SOLID_SLIDEBOX;
 400                 self.flags = FL_CLIENT;
 401                 self.takedamage = DAMAGE_AIM;
 402                 self.effects = 0;
 403                 self.health = cvar("g_balance_health_start");
 404                 self.armorvalue = cvar("g_balance_armor_start");
 405                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 406                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 407                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 408                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 409                 self.damageforcescale = 2;
 410                 self.death_time = 0;
 411                 self.dead_time = 0;
 412                 self.dead_frame = 0;
 413                 self.die_frame = 0;
 414                 self.alpha = 0;
 415                 self.scale = 0;
 416                 self.fade_time = 0;
 417                 self.pain_frame = 0;
 418                 self.pain_finished = 0;
 419                 self.strength_finished = 0;
 420                 self.invincible_finished = 0;
 421                 self.pushltime = 0;
 422                 //self.speed_finished = 0;
 423                 //self.slowmo_finished = 0;
 424                 // players have no think function
 425                 self.think = SUB_Null;
 426                 self.nextthink = 0;
 427                 self.weapon = 0;
 428                 self.switchweapon = 0;
 429                 self.hook_time = 0;
 430
 431                 self.runes = 0;
 432
 433                 self.deadflag = DEAD_NO;
 434
 435                 self.angles = spot.angles;
 436
 437                 self.angles_z = 0; // never spawn tilted even if the spot says to
 438                 self.fixangle = TRUE; // turn this way immediately
 439                 self.velocity = '0 0 0';
 440                 self.avelocity = '0 0 0';
 441                 self.punchangle = '0 0 0';
 442                 self.punchvector = '0 0 0';
 443                 self.oldvelocity = self.velocity;
 444
 445                 self.viewzoom = 0.6;
 446
 447                 self.customizeentityforclient = Client_customizeentityforclient;
 448
 449                 if(cvar("sv_defaultcharacter") == 1) {
 450                         local string defaultmodel;
 451                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 452                         setmodel_lod (self, defaultmodel);
 453                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 454                 } else {
 455                         self.playermodel = CheckPlayerModel(self.playermodel);
 456                         setmodel_lod (self, self.playermodel);
 457                         self.skin = stof(self.playerskin);
 458
 459                 }
 460
 461                 self.crouch = FALSE;
 462                 self.view_ofs = PL_VIEW_OFS;
 463                 setsize (self, PL_MIN, PL_MAX);
 464                 self.spawnorigin = spot.origin;
 465                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 466                 // don't reset back to last position, even if new position is stuck in solid
 467                 self.oldorigin = self.origin;
 468
 469                 if(cvar("g_lms"))
 470                 {
 471                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 472                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 473                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 474                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 475                         self.health = cvar("g_lms_start_health");
 476                         self.armorvalue = cvar("g_lms_start_armor");
 477                 }
 478                 else if (cvar("g_use_ammunition")) {
 479                         self.ammo_shells = cvar("g_start_ammo_shells");
 480                         self.ammo_nails = cvar("g_start_ammo_nails");
 481                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 482                         self.ammo_cells = cvar("g_start_ammo_cells");
 483                 } else {
 484                         self.ammo_shells = 999;
 485                         self.ammo_nails = 999;
 486                         self.ammo_rockets = 999;
 487                         self.ammo_cells = 999;
 488                 }
 489
 490                 self.items = 0;
 491                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 492                 {
 493                         self.items = self.items | IT_LASER;
 494                         self.switchweapon = WEP_LASER;
 495                 }
 496                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 497                 {
 498                         self.items = self.items | IT_SHOTGUN;
 499                         self.switchweapon = WEP_SHOTGUN;
 500                 }
 501                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 502                 {
 503                         self.items = self.items | IT_UZI;
 504                         self.switchweapon = WEP_UZI;
 505                 }
 506                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 507                 {
 508                         self.items = self.items | IT_GRENADE_LAUNCHER;
 509                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 510                 }
 511                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 512                 {
 513                         self.items = self.items | IT_ELECTRO;
 514                         self.switchweapon = WEP_ELECTRO;
 515                 }
 516                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 517                 {
 518                         self.items = self.items | IT_CRYLINK;
 519                         self.switchweapon = WEP_CRYLINK;
 520                 }
 521                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 522                 {
 523                         self.items = self.items | IT_NEX;
 524                         self.switchweapon = WEP_NEX;
 525                 }
 526                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 527                 {
 528                         self.items = self.items | IT_HAGAR;
 529                         self.switchweapon = WEP_HAGAR;
 530                 }
 531                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 532                 {
 533                         self.items = self.items | IT_ROCKET_LAUNCHER;
 534                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 535                 }
 536
 537                 if(cvar("g_instagib"))
 538                 {
 539                         self.items = IT_NEX;
 540                         self.switchweapon = WEP_NEX;
 541                         self.ammo_cells = 999;
 542                 }
 543
 544                 if(cvar("g_rocketarena"))
 545                 {
 546                         self.items = IT_ROCKET_LAUNCHER;
 547                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 548                         self.ammo_rockets = 999;
 549                 }
 550
 551                 if(cvar("g_nixnex"))
 552                 {
 553                         self.items = 0;
 554                         // will be done later
 555                 }
 556
 557                 if(cvar("g_minstagib"))
 558                 {
 559                         self.health = 100;
 560                         self.armorvalue = 0;
 561                         self.items = IT_NEX;
 562                         self.switchweapon = WEP_NEX;
 563                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 564                         self.extralives = 0;
 565                         self.jump_interval = time;
 566                 }
 567
 568                 if(cvar("g_arena"))
 569                         Spawnqueue_Remove(self);
 570
 571                 self.event_damage = PlayerDamage;
 572
 573                 self.bot_attack = TRUE;
 574
 575                 self.statdraintime = time + 5;
 576                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 577
 578                 if(self.killcount == -666) {
 579                         self.killcount = 0;
 580                         if(!cvar("g_arena"))
 581                                 self.frags = 0;
 582                 }
 583
 584                 self.cnt = WEP_LASER;
 585                 self.nixnex_lastchange_id = -1;
 586
 587                 CL_SpawnWeaponentity();
 588                 self.alpha = default_player_alpha;
 589                 self.exteriorweaponentity.alpha = default_player_alpha;
 590
 591                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 592                 self.lms_traveled_distance = 0;
 593
 594                 if(cvar("spawn_debug"))
 595                 {
 596                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 597                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 598                 }
 599
 600                 //stuffcmd(self, "chase_active 0");
 601                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 602         } else if(self.classname == "observer") {
 603                 PutObserverInServer ();
 604         }
 605 }
 606
 607 /*
 608 =============
 609 SetNewParms
 610 =============
 611 */
 612 void SetNewParms (void)
 613 {
 614
 615 }
 616
 617 /*
 618 =============
 619 SetChangeParms
 620 =============
 621 */
 622 void SetChangeParms (void)
 623 {
 624
 625 }
 626
 627 /*
 628 =============
 629 ClientKill
 630
 631 Called when a client types 'kill' in the console
 632 =============
 633 */
 634 void ClientKill (void)
 635 {
 636         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 637 }
 638
 639 /*
 640 =============
 641 ClientConnect
 642
 643 Called when a client connects to the server
 644 =============
 645 */
 646 string ColoredTeamName(float t);
 647 //void dom_player_join_team(entity pl);
 648 void ClientConnect (void)
 649 {
 650         self.classname = "player_joining";
 651         self.flags = self.flags | FL_CLIENT;
 652
 653         if(player_count<0) player_count = 0;
 654
 655         bot_clientconnect();
 656
 657         //if(cvar("g_domination"))
 658         //      dom_player_join_team(self);
 659
 660         //JoinBestTeam(self, FALSE);
 661
 662         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 663                 self.classname = "observer";
 664         } else {
 665                 self.classname = "player";
 666                 campaign_bots_may_start = 1;
 667         }
 668
 669         self.playerid = (playerid_last = playerid_last + 1);
 670         if(cvar("sv_eventlog"))
 671         {
 672                 string s;
 673                 if(clienttype(self) == CLIENTTYPE_REAL)
 674                         s = "player";
 675                 else
 676                         s = "bot";
 677                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 678                 s = strcat(":team:", ftos(self.playerid), ":");
 679                 s = strcat(s, ftos(self.team));
 680                 GameLogEcho(s, FALSE);
 681         }
 682
 683         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 684
 685         bprint ("^4",self.netname);
 686         bprint ("^4 connected");
 687
 688         if(cvar("g_domination") || cvar("g_ctf"))
 689         {
 690                 bprint(" and joined the ");
 691                 bprint(ColoredTeamName(self.team));
 692         }
 693
 694         bprint("\n");
 695
 696         self.welcomemessage_time = time + cvar("welcome_message_time");
 697         self.welcomemessage_time2 = 0;
 698
 699         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 700         // send prediction settings to the client
 701         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 702         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 703         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 704         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 705         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 706         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 707         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 708         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 709         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 710         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 711         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 712         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 713         // Wazat's grappling hook
 714         SetGrappleHookBindings();
 715
 716         // get autoswitch state from player
 717         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 718         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 719
 720         // get version info from player
 721         stuffcmd(self, "cmd clientversion $gameversion\n");
 722
 723         // get other cvars from player
 724         GetCvars(0);
 725
 726         // set cvar for team scoreboard
 727         stuffcmd(self, strcat("set teamplay ", ftos(teams_matter), "\n"));
 728
 729         if(cvar("g_lms"))
 730         {
 731                 self.frags = cvar("fraglimit");
 732                 // no fraglimit was set, so player gets 999 lives
 733                 if(self.frags < 1)
 734                         self.frags = 999;
 735
 736                 // disallow player to join after the worst player has lost g_lms_last_join lives
 737                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 738                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 739                 {
 740                         self.frags = -666;
 741                         lms_dead_count += 1;
 742                 }
 743                 else if(cvar("fraglimit") > lms_lowest_lives)
 744                 {
 745                         self.frags = lms_lowest_lives;
 746                 }
 747         }
 748         else if(cvar("g_arena"))
 749         {
 750                 self.classname = "observer";
 751                 Spawnqueue_Insert(self);
 752         }
 753
 754         bot_relinkplayerlist();
 755
 756         self.jointime = time;
 757 }
 758
 759 /*
 760 =============
 761 ClientDisconnect
 762
 763 Called when a client disconnects from the server
 764 =============
 765 */
 766 void(entity e) DropFlag;
 767 .entity chatbubbleentity;
 768 .entity teambubbleentity;
 769 void ClientDisconnect (void)
 770 {
 771         float save;
 772         if(cvar("sv_eventlog"))
 773                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 774         bprint ("^4",self.netname);
 775         bprint ("^4 disconnected\n");
 776
 777         if (self.chatbubbleentity)
 778         {
 779                 remove (self.chatbubbleentity);
 780                 self.chatbubbleentity = world;
 781         }
 782
 783         if (self.teambubbleentity)
 784         {
 785                 remove (self.teambubbleentity);
 786                 self.teambubbleentity = world;
 787         }
 788
 789         DropAllRunes(self);
 790
 791         if(self.flagcarried)
 792                 DropFlag(self.flagcarried);
 793
 794         save = self.flags;
 795         self.flags = self.flags - (self.flags & FL_CLIENT);
 796         bot_relinkplayerlist();
 797         self.flags = save;
 798
 799         // player was dead, decrease dead count
 800         if(cvar("g_lms") && self.frags < 1)
 801                 lms_dead_count -= 1;
 802         else if(cvar("g_arena"))
 803         {
 804                 Spawnqueue_Unmark(self);
 805                 Spawnqueue_Remove(self);
 806         }
 807 }
 808
 809 .float buttonchat;
 810 void() ChatBubbleThink =
 811 {
 812         self.nextthink = time;
 813         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 814         {
 815                 remove(self);
 816                 return;
 817         }
 818         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 819         if (self.owner.buttonchat && !self.owner.deadflag)
 820                 self.model = self.mdl;
 821         else
 822                 self.model = "";
 823 };
 824
 825 void() UpdateChatBubble =
 826 {
 827         if (!self.modelindex)
 828                 return;
 829         // spawn a chatbubble entity if needed
 830         if (!self.chatbubbleentity)
 831         {
 832                 self.chatbubbleentity = spawn();
 833                 self.chatbubbleentity.owner = self;
 834                 self.chatbubbleentity.exteriormodeltoclient = self;
 835                 self.chatbubbleentity.think = ChatBubbleThink;
 836                 self.chatbubbleentity.nextthink = time;
 837                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 838                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 839                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 840                 self.chatbubbleentity.model = "";
 841         }
 842 }
 843
 844
 845 void() TeamBubbleThink =
 846 {
 847         self.nextthink = time;
 848         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 849         {
 850                 remove(self);
 851                 return;
 852         }
 853 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 854         if (self.owner.buttonchat || self.owner.deadflag)
 855                 self.model = "";
 856         else
 857                 self.model = self.mdl;
 858
 859 };
 860
 861 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 862
 863 void() UpdateTeamBubble =
 864 {
 865         if (!self.modelindex || !cvar("teamplay"))
 866                 return;
 867         // spawn a teambubble entity if needed
 868         if (!self.teambubbleentity && cvar("teamplay"))
 869         {
 870                 self.teambubbleentity = spawn();
 871                 self.teambubbleentity.owner = self;
 872                 self.teambubbleentity.exteriormodeltoclient = self;
 873                 self.teambubbleentity.think = TeamBubbleThink;
 874                 self.teambubbleentity.nextthink = time;
 875                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 876 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 877                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 878                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 879                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 880                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 881                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 882         }
 883 }
 884
 885 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 886 // added to the model skins
 887 /*void() UpdateColorModHack =
 888 {
 889         local float c;
 890         c = self.clientcolors & 15;
 891         // LordHavoc: only bothering to support white, green, red, yellow, blue
 892              if (teamplay == 0) self.colormod = '0 0 0';
 893         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 894         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 895         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 896         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 897         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 898         else self.colormod = '1 1 1';
 899 };*/
 900
 901 void UpdatePlayerColors () {
 902         if(self.weaponentity) {
 903                 self.weaponentity.colormap = self.colormap;
 904                 self.exteriorweaponentity.colormap = self.colormap;
 905         }
 906 }
 907 /*
 908 =============
 909 PlayerJump
 910
 911 When you press the jump key
 912 =============
 913 */
 914 void PlayerJump (void)
 915 {
 916         float mjumpheight;
 917
 918         mjumpheight = cvar("g_balance_jumpheight");
 919         if (self.waterlevel >= 2)
 920         {
 921                 if (self.watertype == CONTENT_WATER)
 922                         self.velocity_z = 200;
 923                 else if (self.watertype == CONTENT_SLIME)
 924                         self.velocity_z = 80;
 925                 else
 926                         self.velocity_z = 50;
 927
 928                 return;
 929         }
 930
 931
 932         if (!(self.flags & FL_ONGROUND))
 933                 return;
 934
 935         if (!(self.flags & FL_JUMPRELEASED))
 936                 return;
 937
 938         if(cvar("g_runematch"))
 939         {
 940                 if(self.runes & RUNE_SPEED)
 941                 {
 942                         if(self.runes & CURSE_SLOW)
 943                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 944                         else
 945                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 946                 }
 947                 else if(self.runes & CURSE_SLOW)
 948                 {
 949                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 950                 }
 951         }
 952
 953         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 954         {
 955                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 956         }
 957
 958         self.velocity_z = self.velocity_z + mjumpheight;
 959         self.oldvelocity_z = self.velocity_z;
 960
 961         self.flags = self.flags - FL_ONGROUND;
 962         self.flags = self.flags - FL_JUMPRELEASED;
 963 }
 964
 965 void() CheckWaterJump =
 966 {
 967         local vector start, end;
 968
 969 // check for a jump-out-of-water
 970         makevectors (self.angles);
 971         start = self.origin;
 972         start_z = start_z + 8;
 973         v_forward_z = 0;
 974         normalize(v_forward);
 975         end = start + v_forward*24;
 976         traceline (start, end, TRUE, self);
 977         if (trace_fraction < 1)
 978         {       // solid at waist
 979                 start_z = start_z + self.maxs_z - 8;
 980                 end = start + v_forward*24;
 981                 self.movedir = trace_plane_normal * -50;
 982                 traceline (start, end, TRUE, self);
 983                 if (trace_fraction == 1)
 984                 {       // open at eye level
 985                         self.flags = self.flags | FL_WATERJUMP;
 986                         self.velocity_z = 225;
 987                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 988                         self.teleport_time = time + 2;  // safety net
 989                         return;
 990                 }
 991         }
 992 };
 993
 994
 995 void respawn(void)
 996 {
 997         CopyBody(1);
 998         PutClientInServer();
 999 }
1000
1001 void player_powerups (void)
1002 {
1003         if (cvar("g_minstagib"))
1004         {
1005                 self.effects = EF_FULLBRIGHT;
1006                 if (self.items & IT_STRENGTH)
1007                 {
1008                         if (time > self.strength_finished)
1009                         {
1010                                 self.alpha = default_player_alpha;
1011                                 self.exteriorweaponentity.alpha = default_player_alpha;
1012                                 self.items = self.items - (self.items & IT_STRENGTH);
1013                                 sprint(self, "^3Invisibility has worn off\n");
1014                         }
1015                 }
1016                 else
1017                 {
1018                         if (time < self.strength_finished)
1019                         {
1020                                 self.alpha = cvar("g_minstagib_invis_alpha");
1021                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1022                                 self.items = self.items | IT_STRENGTH;
1023                                 sprint(self, "^3You are invisible\n");
1024                         }
1025                 }
1026
1027                 if (self.items & IT_INVINCIBLE)
1028                 {
1029                         if (time > self.invincible_finished)
1030                         {
1031                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1032                                 sprint(self, "^3Speed has worn off\n");
1033                         }
1034                 }
1035                 else
1036                 {
1037                         if (time < self.invincible_finished)
1038                         {
1039                                 self.items = self.items | IT_INVINCIBLE;
1040                                 sprint(self, "^3You are on speed\n");
1041                         }
1042                 }
1043                 return;
1044         }
1045
1046         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1047         if (self.items & IT_STRENGTH)
1048         {
1049                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1050                 if (time > self.strength_finished)
1051                 {
1052                         self.items = self.items - (self.items & IT_STRENGTH);
1053                         sprint(self, "^3Strength has worn off\n");
1054                 }
1055         }
1056         else
1057         {
1058                 if (time < self.strength_finished)
1059                 {
1060                         self.items = self.items | IT_STRENGTH;
1061                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1062                 }
1063         }
1064         if (self.items & IT_INVINCIBLE)
1065         {
1066                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1067                 if (time > self.invincible_finished)
1068                 {
1069                         self.items = self.items - (self.items & IT_INVINCIBLE);
1070                         sprint(self, "^3Shield has worn off\n");
1071                 }
1072         }
1073         else
1074         {
1075                 if (time < self.invincible_finished)
1076                 {
1077                         self.items = self.items | IT_INVINCIBLE;
1078                         sprint(self, "^3Shield surrounds you\n");
1079                 }
1080         }
1081
1082         if (cvar("g_fullbrightplayers"))
1083                 self.effects = self.effects | EF_FULLBRIGHT;
1084
1085         // midair gamemode: damage only while in the air
1086         // if in midair mode, being on ground grants temporary invulnerability
1087         // (this is so that multishot weapon don't clear the ground flag on the
1088         // first damage in the frame, leaving the player vulnerable to the
1089         // remaining hits in the same frame)
1090         if (self.flags & FL_ONGROUND)
1091         if (cvar("g_midair"))
1092                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1093
1094         if (time < self.spawnshieldtime)
1095                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1096 }
1097
1098 void player_regen (void)
1099 {
1100         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1101         maxh = cvar("g_balance_health_stable");
1102         maxa = cvar("g_balance_armor_stable");
1103         limith = cvar("g_balance_health_limit");
1104         limita = cvar("g_balance_armor_limit");
1105
1106         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1107                 return;
1108
1109         if(cvar("g_runematch"))
1110         {
1111                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1112                 if (self.runes & RUNE_REGEN)
1113                 {
1114                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1115                         {
1116                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1117                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1118                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1119                         }
1120                         else
1121                         {
1122                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1123                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1124                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1125                         }
1126                 }
1127                 else if (self.runes & CURSE_VENOM)
1128                 {
1129                         max_mod = cvar("g_balance_curse_venom_hpmod");
1130                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1131                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1132                         else
1133                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1134                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1135                         //if (!self.runes & RUNE_REGEN)
1136                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1137                 }
1138                 maxh = maxh * max_mod;
1139                 //maxa = maxa * max_mod;
1140
1141                 if (time > self.pauserotarmor_finished)
1142                 {
1143                         if (self.armorvalue > maxa)
1144                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1145                 }
1146                 if (time > self.pauserothealth_finished)
1147                 {
1148                         if (self.health > maxh)
1149                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1150                 }
1151                 if (time > self.pauseregen_finished)
1152                 {
1153                         if (self.health < maxh)
1154                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1155                         if (self.armorvalue < maxa)
1156                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1157                 }
1158         }
1159         else
1160         {
1161                 if (time > self.pauserothealth_finished)
1162                 if (self.health > maxh)
1163                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1164                 if (time > self.pauserotarmor_finished)
1165                 if (self.armorvalue > maxa)
1166                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1167                 if (time > self.pauseregen_finished)
1168                 {
1169                         if (self.health < maxh)
1170                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1171                         if (self.armorvalue < maxa)
1172                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1173                 }
1174         }
1175
1176         if (self.health > limith)
1177                 self.health = limith;
1178         if(self.health < 1)
1179                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1180         if (self.armorvalue > limita)
1181                 self.armorvalue = limita;
1182 }
1183
1184 /*
1185 ======================
1186 spectate mode routines
1187 ======================
1188 */
1189 void SpectateCopy(entity spectatee) {
1190         self.armortype = spectatee.armortype;
1191         self.armorvalue = spectatee.armorvalue;
1192         self.currentammo = spectatee.currentammo;
1193         self.effects = spectatee.effects;
1194         self.health = spectatee.health;
1195         self.impulse = 0;
1196         self.items = spectatee.items;
1197         self.punchangle = spectatee.punchangle;
1198         self.view_ofs = spectatee.view_ofs;
1199         self.v_angle = spectatee.v_angle;
1200         self.viewzoom = spectatee.viewzoom;
1201         setorigin(self, spectatee.origin);
1202         setsize(self, spectatee.mins, spectatee.maxs);
1203 }
1204
1205 void SpectateUpdate() {
1206         if (self != self.enemy) {
1207                 if(self.enemy.flags & FL_NOTARGET)
1208                         PutObserverInServer();
1209                 SpectateCopy(self.enemy);
1210                 self.dmg_take = self.enemy.dmg_take;
1211                 self.dmg_save = self.enemy.dmg_save;
1212                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1213                 self.fixangle = TRUE;
1214                 self.angles = self.enemy.v_angle;
1215                 //msg_entity = self;
1216                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1217                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1218                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1219                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1220         }
1221 }
1222
1223 float SpectateNext() {
1224         other = find(self.enemy, classname, "player");
1225         if (!other) {
1226                 other = find(other, classname, "player");
1227         }
1228         if (other) {
1229                 self.enemy = other;
1230         }
1231         if(self.enemy.classname == "player") {
1232                 msg_entity = self;
1233                 WriteByte(MSG_ONE, SVC_SETVIEW);
1234                 WriteEntity(MSG_ONE, self.enemy);
1235                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1236                 SpectateUpdate();
1237                 return 1;
1238         } else {
1239                 return 0;
1240         }
1241 }
1242
1243 /*
1244 =============
1245 PlayerPreThink
1246
1247 Called every frame for each client before the physics are run
1248 =============
1249 */
1250 void PlayerPreThink (void)
1251 {
1252         if(self.classname == "player") {
1253                 local vector m1, m2;
1254
1255 //              if(self.netname == "Wazat")
1256 //                      bprint(strcat(self.classname, "\n"));
1257
1258                 CheckRules_Player();
1259
1260                 Nixnex_GiveCurrentWeapon();
1261
1262                 if(self.button7)
1263                         PrintWelcomeMessage(self);
1264
1265                 if(cvar("g_lms") || !cvar("sv_spectate"))
1266                 if((time - self.jointime) <= cvar("welcome_message_time"))
1267                         PrintWelcomeMessage(self);
1268
1269                 if (intermission_running)
1270                 {
1271                         IntermissionThink ();   // otherwise a button could be missed between
1272                         return;                                 // the think tics
1273                 }
1274
1275                 if (self.deadflag != DEAD_NO)
1276                 {
1277                         player_anim();
1278                         if (self.deadflag == DEAD_DYING)
1279                         {
1280                                 if (time > self.dead_time)
1281                                         self.deadflag = DEAD_DEAD;
1282                         }
1283                         else if (self.deadflag == DEAD_DEAD)
1284                         {
1285                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1286                                         self.deadflag = DEAD_RESPAWNABLE;
1287                                 else if (!self.button0 && !self.button2 && !self.button3)
1288                                         self.deadflag = DEAD_RESPAWNABLE;
1289                         }
1290                         else if (self.deadflag == DEAD_RESPAWNABLE)
1291                         {
1292                                 if (self.button0  ||
1293                                     self.button2  ||
1294                                     self.button3  ||
1295                                     self.button4  ||
1296                                     self.button5  ||
1297                                     self.button6  ||
1298                                     self.button7  ||
1299                                     self.button8  ||
1300                                     self.buttonuse ||
1301                                     cvar("g_lms") ||
1302                                     cvar("g_forced_respawn"))
1303                                         respawn();
1304                         }
1305                         return;
1306                 }
1307
1308                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1309                 {
1310                         vector dist;
1311
1312                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1313                         dist = self.oldorigin - self.origin;
1314                         dist_z = 0;
1315                         self.lms_traveled_distance += fabs(vlen(dist));
1316
1317                         if(time > self.lms_nextcheck)
1318                         {
1319                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1320                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1321                                 {
1322                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1323                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1324                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1325                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1326                                 }
1327                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1328                                 self.lms_traveled_distance = 0;
1329                         }
1330                 }
1331
1332                 if (self.button5 && !self.hook.state)
1333                 {
1334                         if (!self.crouch)
1335                         {
1336                                 self.crouch = TRUE;
1337                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1338                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1339                         }
1340                 }
1341                 else
1342                 {
1343                         if (self.crouch)
1344                         {
1345                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1346                                 if (!trace_startsolid)
1347                                 {
1348                                         self.crouch = FALSE;
1349                                         self.view_ofs = PL_VIEW_OFS;
1350                                         setsize (self, PL_MIN, PL_MAX);
1351                                 }
1352                         }
1353                 }
1354
1355                 if(cvar("sv_defaultcharacter") == 1) {
1356                         local string defaultmodel;
1357                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1358
1359                         if (defaultmodel != self.model)
1360                         {
1361                                 m1 = self.mins;
1362                                 m2 = self.maxs;
1363                                 setmodel_lod (self, defaultmodel);
1364                                 setsize (self, m1, m2);
1365                         }
1366
1367                         if (self.skin != cvar("sv_defaultplayerskin"))
1368                                 self.skin = cvar("sv_defaultplayerskin");
1369                 } else {
1370                         if (self.playermodel != self.model)
1371                         {
1372                                 self.playermodel = CheckPlayerModel(self.playermodel);
1373                                 m1 = self.mins;
1374                                 m2 = self.maxs;
1375                                 setmodel_lod (self, self.playermodel);
1376                                 setsize (self, m1, m2);
1377                         }
1378
1379                         if (self.skin != stof(self.playerskin))
1380                                 self.skin = stof(self.playerskin);
1381                 }
1382                 // Savage: Check for nameless players
1383                 if (strlen(self.netname) < 1) {
1384                         self.netname = "Player";
1385                         stuffcmd(self, "name Player\n");
1386                 }
1387
1388                 GrapplingHookFrame();
1389
1390                 W_WeaponFrame();
1391
1392                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1393                 {
1394                         if (cvar("g_minstagib") && self.button3)
1395                         {
1396                                 if (self.jump_interval <= (time + 0.1))
1397                                 {
1398                                         self.jump_interval = time + 1;
1399                                         W_Laser_Attack();
1400                                 }
1401                         }
1402                         else if (self.viewzoom > 0.4)
1403                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1404                 }
1405                 else if (self.viewzoom < 1.0)
1406                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1407
1408
1409                 if (self.button2)
1410                         PlayerJump ();
1411                 else
1412                         self.flags = self.flags | FL_JUMPRELEASED;
1413
1414                 player_powerups();
1415                 player_regen();
1416                 player_anim();
1417
1418                 if (cvar("g_minstagib"))
1419                         minstagib_ammocheck();
1420
1421                 //self.angles_y=self.v_angle_y + 90;   // temp
1422
1423                 if (self.waterlevel == 2)
1424                         CheckWaterJump ();
1425
1426                 //if (TetrisPreFrame()) return;
1427         } else if(gameover) {
1428                 if (intermission_running)
1429                         IntermissionThink ();   // otherwise a button could be missed between
1430                 return;
1431         } else if(self.classname == "observer") {
1432
1433                 if (self.flags & FL_JUMPRELEASED) {
1434                         if (self.button2 && self.version == cvar("gameversion")) {
1435                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1436                                         self.flags = self.flags & !FL_JUMPRELEASED;
1437                                         self.classname = "player";
1438                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1439                                                 JoinBestTeam(self, 0);
1440                                         if(cvar("g_campaign"))
1441                                                 campaign_bots_may_start = 1;
1442                                         PutClientInServer();
1443                                         if(self.flags & !FL_NOTARGET)
1444                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1445                                         centerprint(self,"");
1446                                         return;
1447                                 } else {
1448                                         self.flags = self.flags & !FL_JUMPRELEASED;
1449                                         stuffcmd(self,"menu_showteamselect\n");
1450                                         return;
1451                                 }
1452                         } else if(self.button0 && self.version == cvar("gameversion")) {
1453                                 self.flags = self.flags & !FL_JUMPRELEASED;
1454                                 if(SpectateNext() == 1) {
1455                                         self.classname = "spectator";
1456                                 }
1457                         }
1458                 } else {
1459                         if (!(self.button0 || self.button2)) {
1460                                 self.flags = self.flags | FL_JUMPRELEASED;
1461                         }
1462                 }
1463                 PrintWelcomeMessage(self);
1464         } else if(self.classname == "spectator") {
1465
1466                 if (self.flags & FL_JUMPRELEASED) {
1467                         if (self.button2 && self.version == cvar("gameversion")) {
1468                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1469                                         self.flags = self.flags & !FL_JUMPRELEASED;
1470                                         self.classname = "player";
1471                                         if(!cvar("g_lms"))
1472                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1473
1474                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1475                                                 JoinBestTeam(self, 0);
1476                                         if(cvar("g_campaign"))
1477                                                 campaign_bots_may_start = 1;
1478                                         PutClientInServer();
1479                                         centerprint(self,"");
1480                                         return;
1481                                 } else {
1482                                         self.flags = self.flags & !FL_JUMPRELEASED;
1483                                         stuffcmd(self,"menu_showteamselect\n");
1484                                         return;
1485                                 }
1486                         } else if(self.button0) {
1487                                 self.flags = self.flags & !FL_JUMPRELEASED;
1488                                 if(SpectateNext() == 1) {
1489                                         self.classname = "spectator";
1490                                 } else {
1491                                         self.classname = "observer";
1492                                         PutClientInServer();
1493                                 }
1494                         } else if (self.button3) {
1495                                 self.flags = self.flags & !FL_JUMPRELEASED;
1496                                 self.classname = "observer";
1497                                 PutClientInServer();
1498                         } else {
1499                                 SpectateUpdate();
1500                         }
1501         } else {
1502                 if (!(self.button0 || self.button3)) {
1503                         self.flags = self.flags | FL_JUMPRELEASED;
1504                 }
1505                 }
1506                 PrintWelcomeMessage(self);
1507         }
1508 }
1509
1510
1511 /*
1512 =============
1513 PlayerPostThink
1514
1515 Called every frame for each client after the physics are run
1516 =============
1517 */
1518 void PlayerPostThink (void)
1519 {
1520         if(self.classname == "player") {
1521                 CheckRules_Player();
1522                 UpdateChatBubble();
1523                 UpdateTeamBubble();
1524                 UpdatePlayerColors();
1525                 if (self.deadflag == DEAD_NO)
1526                 if (self.impulse)
1527                         ImpulseCommands ();
1528                 if (intermission_running)
1529                         return;         // intermission or finale
1530
1531                 //PrintWelcomeMessage(self);
1532                 //if (TetrisPostFrame()) return;
1533         } else if (self.classname == "observer") {
1534                 //do nothing
1535         } else if (self.classname == "spectator") {
1536                 //do nothing
1537         }
1538         Arena_Warmup();
1539 }