data/qcsrc/server/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8 }
   9
  10 float spawn_allbad;
  11 float spawn_allgood;
  12 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  13 {
  14         local entity spot, player, nextspot, previousspot, newfirstspot;
  15         local float pcount;
  16         spot = firstspot;
  17         newfirstspot = world;
  18         previousspot = world;
  19         spawn_allgood = TRUE;
  20         spawn_allbad = TRUE;
  21         while (spot)
  22         {
  23                 nextspot = spot.chain;
  24                 // count team mismatches as bad spots
  25                 if (spot.team == teamcheck)
  26                 {
  27                         pcount = 0;
  28                         player = playerlist;
  29                         while (player)
  30                         {
  31                                 if (player != self)
  32                                 if (vlen(player.origin - spot.origin) < mindist)
  33                                         pcount = pcount + 1;
  34                                 player = player.chain;
  35                         }
  36                         if (!pcount)
  37                         {
  38                                 spawn_allbad = FALSE;
  39                                 if (newfirstspot)
  40                                         previousspot.chain = spot;
  41                                 else
  42                                         newfirstspot = spot;
  43                                 previousspot = spot;
  44                                 spot.chain = world;
  45                         }
  46                         else
  47                                 spawn_allgood = FALSE;
  48                 }
  49                 spot = nextspot;
  50         }
  51         // if we couldn't find ANY good points, return the original list
  52         if (!newfirstspot)
  53                 newfirstspot = firstspot;
  54         return newfirstspot;
  55 }
  56
  57 entity Spawn_RandomPoint(entity firstspot)
  58 {
  59         local entity spot;
  60         local float numspots;
  61         // count number of spots
  62         numspots = 0;
  63         spot = firstspot;
  64         while (spot)
  65         {
  66                 numspots = numspots + 1;
  67                 spot = spot.chain;
  68         }
  69         // pick a random one
  70         numspots = numspots * random();
  71         spot = firstspot;
  72         while (spot.chain && numspots >= 1)
  73         {
  74                 numspots = numspots - 1;
  75                 spot = spot.chain;
  76         }
  77         return spot;
  78 }
  79
  80 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  81 {
  82         local entity best, spot, player;
  83         local float bestrating, rating;
  84         best = world;
  85         bestrating = -1000000;
  86         spot = firstspot;
  87         while (spot)
  88         {
  89                 rating = 1000000000;
  90                 player = playerlist;
  91                 while (player)
  92                 {
  93                         if (player != self)
  94                                 rating = min(rating, vlen(player.origin - spot.origin));
  95                         player = player.chain;
  96                 }
  97                 rating = rating + random() * 16;
  98                 if (bestrating < rating)
  99                 {
 100                         best = spot;
 101                         bestrating = rating;
 102                 }
 103                 spot = spot.chain;
 104         }
 105         return best;
 106 }
 107
 108 /*
 109 =============
 110 SelectSpawnPoint
 111
 112 Finds a point to respawn
 113 =============
 114 */
 115 entity SelectSpawnPoint (float anypoint)
 116 {
 117         local float teamcheck;
 118         local entity spot, firstspot, playerlist;
 119         string spotname;
 120
 121         spot = find (world, classname, "testplayerstart");
 122         if (spot)
 123                 return spot;
 124
 125         spotname = "info_player_deathmatch";
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (random() > 0.5 || spawn_allbad || spawn_allgood)
 143                 spot = Spawn_RandomPoint(firstspot);
 144         else
 145                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 146
 147         if (!spot)
 148                 error ("PutClientInServer: no start points on level");
 149
 150         return spot;
 151 }
 152
 153 /*
 154 =============
 155 CheckPlayerModel
 156
 157 Checks if the argument string can be a valid playermodel.
 158 Returns a valid one in doubt.
 159 =============
 160 */
 161 string CheckPlayerModel(string plyermodel) {
 162         if( substring(plyermodel,0,14) != "models/player/") plyermodel = "models/player/marine.zym";
 163
 164         /* Possible Fixme: Check if server can open the model?
 165            This would kill custom models, however. */
 166
 167         return plyermodel;
 168 }
 169
 170 /*
 171 =============
 172 PutObserverInServer
 173
 174 putting a client as observer in the server
 175 =============
 176 */
 177 void PutObserverInServer (void)
 178 {
 179         entity  spot;
 180         spot = SelectSpawnPoint (FALSE);
 181         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 182
 183         if(self.frags == 0 && cvar("g_lms") && self.killcount != -666)
 184                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 185         else if(self.killcount != -666)
 186                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 187
 188         self.classname = "observer";
 189         self.health = -666;
 190         self.takedamage = DAMAGE_NO;
 191         self.solid = SOLID_NOT;
 192         self.movetype = MOVETYPE_NOCLIP;
 193         self.flags = FL_CLIENT | FL_NOTARGET;
 194         self.armorvalue = 666;
 195         self.effects = 0;
 196         self.armorvalue = cvar("g_balance_armor_start");
 197         self.pauserotarmor_finished = 0;
 198         self.pauserothealth_finished = 0;
 199         self.pauseregen_finished = 0;
 200         self.damageforcescale = 0;
 201         self.death_time = 0;
 202         self.dead_time = 0;
 203         self.dead_frame = 0;
 204         self.die_frame = 0;
 205         self.deaths = 0;
 206         self.alpha = 0;
 207         self.scale = 0;
 208         self.fade_time = 0;
 209         self.pain_frame = 0;
 210         self.pain_finished = 0;
 211         self.strength_finished = 0;
 212         self.invincible_finished = 0;
 213         self.pushltime = 0;
 214         self.think = SUB_Null;
 215         self.nextthink = 0;
 216         self.hook_time = 0;
 217         self.runes = 0;
 218         self.deadflag = DEAD_NO;
 219         self.angles = spot.angles;
 220         self.angles_z = 0;
 221         self.fixangle = TRUE;
 222         self.crouch = FALSE;
 223         self.view_ofs = PL_VIEW_OFS;
 224         setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 14));
 225         self.oldorigin = self.origin;
 226         self.items = 0;
 227         self.model = "";
 228         self.modelindex = 0;
 229         self.weapon = 0;
 230         self.weaponmodel = "";
 231         self.weaponframe = 0;
 232         self.weaponentity = world;
 233         self.killcount = -666;
 234         if(!cvar("g_lms"))
 235                 self.frags = -666;
 236         //stuffcmd(self, "set viewsize 120 \n");
 237 //      bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 238 }
 239
 240
 241 /*
 242 =============
 243 PutClientInServer
 244
 245 Called when a client spawns in the server
 246 =============
 247 */
 248 void PutClientInServer (void)
 249 {
 250         if(clienttype(self) ==  CLIENTTYPE_BOT)
 251         {
 252                 self.classname = "player";
 253         }
 254
 255         // player is dead and becomes observer
 256         if(cvar("g_lms") && self.frags < 1)
 257                 self.classname = "observer";
 258
 259         if(self.classname == "player") {
 260                 entity  spot;
 261
 262                 spot = SelectSpawnPoint (FALSE);
 263
 264                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 265
 266                 self.classname = "player";
 267                 self.iscreature = TRUE;
 268                 self.movetype = MOVETYPE_WALK;
 269                 self.solid = SOLID_SLIDEBOX;
 270                 self.flags = FL_CLIENT;
 271                 self.takedamage = DAMAGE_AIM;
 272                 self.effects = 0;
 273                 self.health = cvar("g_balance_health_start");
 274                 self.armorvalue = cvar("g_balance_armor_start");
 275                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 276                 self.pauserotarmor_finished = time + 10;
 277                 self.pauserothealth_finished = time + 10;
 278                 self.pauseregen_finished = 0;
 279                 self.damageforcescale = 2;
 280                 self.death_time = 0;
 281                 self.dead_time = 0;
 282                 self.dead_frame = 0;
 283                 self.die_frame = 0;
 284                 self.alpha = 0;
 285                 self.scale = 0;
 286                 self.fade_time = 0;
 287                 self.pain_frame = 0;
 288                 self.pain_finished = 0;
 289                 self.strength_finished = 0;
 290                 self.invincible_finished = 0;
 291                 self.pushltime = 0;
 292                 //self.speed_finished = 0;
 293                 //self.slowmo_finished = 0;
 294                 // players have no think function
 295                 self.think = SUB_Null;
 296                 self.nextthink = 0;
 297                 self.weapon = 0;
 298                 self.switchweapon = 0;
 299                 self.hook_time = 0;
 300
 301                 self.runes = 0;
 302
 303                 self.deadflag = DEAD_NO;
 304
 305                 self.angles = spot.angles;
 306
 307                 self.angles_z = 0; // never spawn tilted even if the spot says to
 308                 self.fixangle = TRUE; // turn this way immediately
 309                 self.velocity = '0 0 0';
 310                 self.avelocity = '0 0 0';
 311                 self.punchangle = '0 0 0';
 312                 self.punchvector = '0 0 0';
 313                 self.oldvelocity = self.velocity;
 314
 315                 self.viewzoom = 0.6;
 316
 317                 if(cvar("sv_defaultcharacter") == 1) {
 318                         local string defaultmodel;
 319                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 320
 321                         precache_model (defaultmodel);
 322                         setmodel (self, defaultmodel);
 323                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 324                 } else {
 325                         self.playermodel = CheckPlayerModel(self.playermodel);
 326
 327                         precache_model (self.playermodel);
 328                         setmodel (self, self.playermodel);
 329                         self.skin = stof(self.playerskin);
 330
 331                 }
 332
 333                 self.crouch = FALSE;
 334                 self.view_ofs = PL_VIEW_OFS;
 335                 setsize (self, PL_MIN, PL_MAX);
 336                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 337                 // don't reset back to last position, even if new position is stuck in solid
 338                 self.oldorigin = self.origin;
 339
 340                 if(cvar("g_lms"))
 341                 {
 342                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 343                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 344                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 345                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 346                         self.health = cvar("g_lms_start_health");
 347                         self.armorvalue = cvar("g_lms_start_armor");
 348                 }
 349                 else if (cvar("g_use_ammunition")) {
 350                         self.ammo_shells = cvar("g_start_ammo_shells");
 351                         self.ammo_nails = cvar("g_start_ammo_nails");
 352                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 353                         self.ammo_cells = cvar("g_start_ammo_cells");
 354                 } else {
 355                         self.ammo_shells = 999;
 356                         self.ammo_nails = 999;
 357                         self.ammo_rockets = 999;
 358                         self.ammo_cells = 999;
 359                 }
 360
 361                 self.items = 0;
 362                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 363                 {
 364                         self.items = self.items | IT_LASER;
 365                         self.switchweapon = WEP_LASER;
 366                 }
 367                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 368                 {
 369                         self.items = self.items | IT_SHOTGUN;
 370                         self.switchweapon = WEP_SHOTGUN;
 371                 }
 372                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 373                 {
 374                         self.items = self.items | IT_UZI;
 375                         self.switchweapon = WEP_UZI;
 376                 }
 377                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 378                 {
 379                         self.items = self.items | IT_GRENADE_LAUNCHER;
 380                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 381                 }
 382                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 383                 {
 384                         self.items = self.items | IT_ELECTRO;
 385                         self.switchweapon = WEP_ELECTRO;
 386                 }
 387                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 388                 {
 389                         self.items = self.items | IT_CRYLINK;
 390                         self.switchweapon = WEP_CRYLINK;
 391                 }
 392                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 393                 {
 394                         self.items = self.items | IT_NEX;
 395                         self.switchweapon = WEP_NEX;
 396                 }
 397                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 398                 {
 399                         self.items = self.items | IT_HAGAR;
 400                         self.switchweapon = WEP_HAGAR;
 401                 }
 402                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 403                 {
 404                         self.items = self.items | IT_ROCKET_LAUNCHER;
 405                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 406                 }
 407
 408                 if(cvar("g_instagib"))
 409                 {
 410                         self.items = IT_NEX;
 411                         self.switchweapon = WEP_NEX;
 412                         self.ammo_cells = 999;
 413                 }
 414
 415                 if(cvar("g_rocketarena"))
 416                 {
 417                         self.items = IT_ROCKET_LAUNCHER;
 418                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 419                         self.ammo_rockets = 999;
 420                 }
 421
 422                 if(cvar("g_minstagib"))
 423                 {
 424                         self.health = 100;
 425                         self.armorvalue = 0;
 426                         self.items = IT_NEX;
 427                         self.switchweapon = WEP_NEX;
 428                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 429                         self.extralives = 0;
 430                         self.jump_interval = time;
 431                 }
 432
 433                 self.event_damage = PlayerDamage;
 434
 435                 self.statdraintime = time + 5;
 436                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 437
 438                 if(self.killcount == -666) {
 439                         self.killcount = 0;
 440                         self.frags = 0;
 441                 }
 442
 443                 self.cnt = WEP_LASER;
 444
 445                 /*
 446                 W_UpdateWeapon();
 447                 W_UpdateAmmo();
 448                 */
 449                 CL_SpawnWeaponentity();
 450                 self.alpha = 1;
 451                 self.exteriorweaponentity.alpha = 1;
 452
 453                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 454                 self.lms_traveled_distance = 0;
 455
 456                 //stuffcmd(self, "chase_active 0");
 457                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 458         } else if(self.classname == "observer") {
 459                 PutObserverInServer ();
 460         }
 461 }
 462
 463 /*
 464 =============
 465 SetNewParms
 466 =============
 467 */
 468 void SetNewParms (void)
 469 {
 470
 471 }
 472
 473 /*
 474 =============
 475 SetChangeParms
 476 =============
 477 */
 478 void SetChangeParms (void)
 479 {
 480
 481 }
 482
 483 /*
 484 =============
 485 ClientKill
 486
 487 Called when a client types 'kill' in the console
 488 =============
 489 */
 490 void ClientKill (void)
 491 {
 492         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 493 }
 494
 495 /*
 496 =============
 497 ClientConnect
 498
 499 Called when a client connects to the server
 500 =============
 501 */
 502 string ColoredTeamName(float t);
 503 //void dom_player_join_team(entity pl);
 504 void ClientConnect (void)
 505 {
 506         self.classname = "player_joining";
 507
 508         if(player_count<0) player_count = 0;
 509
 510         //if(cvar("g_domination"))
 511         //      dom_player_join_team(self);
 512
 513         //JoinBestTeam(self, FALSE);
 514
 515         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 516                 self.classname = "observer";
 517         } else {
 518                 self.classname = "player";
 519         }
 520
 521         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 522
 523         bprint ("^4",self.netname);
 524         bprint ("^4 connected");
 525
 526         if(cvar("g_domination") || cvar("g_ctf"))
 527         {
 528                 bprint(" and joined the ");
 529                 bprint(ColoredTeamName(self.team));
 530         }
 531
 532         bprint("\n");
 533
 534         self.welcomemessage_time = time + cvar("welcome_message_time");
 535         self.welcomemessage_time2 = 0;
 536
 537         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 538         // send prediction settings to the client
 539         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 540         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 541         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 542         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 543         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 544         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 545         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 546         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 547         // Wazat's grappling hook
 548         SetGrappleHookBindings();
 549
 550         // get autoswitch state from player
 551         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 552         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 553
 554         // get version info from player
 555         stuffcmd(self, "cmd clientversion $gameversion\n");
 556
 557         // set cvar for team scoreboard
 558         stuffcmd(self, strcat("set teamplay ", ftos(teams_matter), "\n"));
 559
 560         if(cvar("g_lms"))
 561         {
 562                 self.frags = cvar("fraglimit");
 563                 // no fraglimit was set, so player gets 999 lives
 564                 if(self.frags < 1)
 565                         self.frags = 999;
 566
 567                 // disallow player to join after the worst player has lost g_lms_last_join lives
 568                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 569                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 570                 {
 571                         self.frags = -1;
 572                         lms_dead_count += 1;
 573                 }
 574                 else if(cvar("fraglimit") > lms_lowest_lives)
 575                 {
 576                         self.frags = lms_lowest_lives;
 577                 }
 578         }
 579
 580         player_count += 1;
 581         self.jointime = time;
 582 }
 583
 584 /*
 585 =============
 586 ClientDisconnect
 587
 588 Called when a client disconnects from the server
 589 =============
 590 */
 591 void(entity e) DropFlag;
 592 .entity chatbubbleentity;
 593 .entity teambubbleentity;
 594 void ClientDisconnect (void)
 595 {
 596         bprint ("^4",self.netname);
 597         bprint ("^4 disconnected\n");
 598
 599         if (self.chatbubbleentity)
 600         {
 601                 remove (self.chatbubbleentity);
 602                 self.chatbubbleentity = world;
 603         }
 604
 605         if (self.teambubbleentity)
 606         {
 607                 remove (self.teambubbleentity);
 608                 self.teambubbleentity = world;
 609         }
 610
 611         DropAllRunes(self);
 612
 613         if(self.flagcarried)
 614                 DropFlag(self.flagcarried);
 615
 616         // decrease player count for lms
 617         player_count -= 1;
 618         // player was dead, decrease dead count
 619         if(cvar("g_lms") && self.frags < 1)
 620                 lms_dead_count -= 1;
 621         //stuffcmd(self, "set viewsize $tmpviewsize \n");
 622 }
 623
 624 .float buttonchat;
 625 void() ChatBubbleThink =
 626 {
 627         self.nextthink = time;
 628         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 629         {
 630                 remove(self);
 631                 return;
 632         }
 633         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 634         if (self.owner.buttonchat && !self.owner.deadflag)
 635                 self.model = self.mdl;
 636         else
 637                 self.model = "";
 638 };
 639
 640 void() UpdateChatBubble =
 641 {
 642         if (!self.modelindex)
 643                 return;
 644         // spawn a chatbubble entity if needed
 645         if (!self.chatbubbleentity)
 646         {
 647                 self.chatbubbleentity = spawn();
 648                 self.chatbubbleentity.owner = self;
 649                 self.chatbubbleentity.exteriormodeltoclient = self;
 650                 self.chatbubbleentity.think = ChatBubbleThink;
 651                 self.chatbubbleentity.nextthink = time;
 652                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 653                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 654                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 655                 self.chatbubbleentity.model = "";
 656         }
 657 }
 658
 659
 660 void() TeamBubbleThink =
 661 {
 662         self.nextthink = time;
 663         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 664         {
 665                 remove(self);
 666                 return;
 667         }
 668 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 669         if (self.owner.buttonchat || self.owner.deadflag)
 670                 self.model = "";
 671         else
 672                 self.model = self.mdl;
 673
 674 };
 675
 676 .float() customizeentityforclient;
 677 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 678
 679 void() UpdateTeamBubble =
 680 {
 681         if (!self.modelindex || !cvar("teamplay"))
 682                 return;
 683         // spawn a teambubble entity if needed
 684         if (!self.teambubbleentity && cvar("teamplay"))
 685         {
 686                 self.teambubbleentity = spawn();
 687                 self.teambubbleentity.owner = self;
 688                 self.teambubbleentity.exteriormodeltoclient = self;
 689                 self.teambubbleentity.think = TeamBubbleThink;
 690                 self.teambubbleentity.nextthink = time;
 691                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 692 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 693                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 694                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 695                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 696                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 697                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 698         }
 699 }
 700
 701 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 702 // added to the model skins
 703 /*void() UpdateColorModHack =
 704 {
 705         local float c;
 706         c = self.clientcolors & 15;
 707         // LordHavoc: only bothering to support white, green, red, yellow, blue
 708              if (teamplay == 0) self.colormod = '0 0 0';
 709         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 710         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 711         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 712         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 713         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 714         else self.colormod = '1 1 1';
 715 };*/
 716
 717 void UpdatePlayerColors () {
 718         if(self.weaponentity) {
 719                 self.weaponentity.colormap = self.colormap;
 720                 self.exteriorweaponentity.colormap = self.colormap;
 721         }
 722 }
 723 /*
 724 =============
 725 PlayerJump
 726
 727 When you press the jump key
 728 =============
 729 */
 730 void PlayerJump (void)
 731 {
 732         float mjumpheight;
 733
 734         mjumpheight = cvar("g_balance_jumpheight");
 735         if (self.waterlevel >= 2)
 736         {
 737                 if (self.watertype == CONTENT_WATER)
 738                         self.velocity_z = 200;
 739                 else if (self.watertype == CONTENT_SLIME)
 740                         self.velocity_z = 80;
 741                 else
 742                         self.velocity_z = 50;
 743
 744                 return;
 745         }
 746
 747
 748         if (!(self.flags & FL_ONGROUND))
 749                 return;
 750
 751         if (!(self.flags & FL_JUMPRELEASED))
 752                 return;
 753
 754         if(cvar("g_runematch"))
 755         {
 756                 if(self.runes & RUNE_SPEED)
 757                 {
 758                         if(self.runes & CURSE_SLOW)
 759                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 760                         else
 761                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 762                 }
 763                 else if(self.runes & CURSE_SLOW)
 764                 {
 765                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 766                 }
 767         }
 768
 769         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 770         {
 771                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 772         }
 773
 774         self.velocity_z = self.velocity_z + mjumpheight;
 775         self.oldvelocity_z = self.velocity_z;
 776
 777         self.flags = self.flags - FL_ONGROUND;
 778         self.flags = self.flags - FL_JUMPRELEASED;
 779 }
 780
 781 void() CheckWaterJump =
 782 {
 783         local vector start, end;
 784
 785 // check for a jump-out-of-water
 786         makevectors (self.angles);
 787         start = self.origin;
 788         start_z = start_z + 8;
 789         v_forward_z = 0;
 790         normalize(v_forward);
 791         end = start + v_forward*24;
 792         traceline (start, end, TRUE, self);
 793         if (trace_fraction < 1)
 794         {       // solid at waist
 795                 start_z = start_z + self.maxs_z - 8;
 796                 end = start + v_forward*24;
 797                 self.movedir = trace_plane_normal * -50;
 798                 traceline (start, end, TRUE, self);
 799                 if (trace_fraction == 1)
 800                 {       // open at eye level
 801                         self.flags = self.flags | FL_WATERJUMP;
 802                         self.velocity_z = 225;
 803                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 804                         self.teleport_time = time + 2;  // safety net
 805                         return;
 806                 }
 807         }
 808 };
 809
 810
 811 void respawn(void)
 812 {
 813         CopyBody(1);
 814         PutClientInServer();
 815 }
 816
 817 void player_powerups (void)
 818 {
 819         if (cvar("g_minstagib"))
 820         {
 821                 self.effects = EF_FULLBRIGHT;
 822                 if (self.items & IT_STRENGTH)
 823                 {
 824                         if (time > self.strength_finished)
 825                         {
 826                                 self.alpha = 1;
 827                                 self.exteriorweaponentity.alpha = 1;
 828                                 self.items = self.items - (self.items & IT_STRENGTH);
 829                                 sprint(self, "^3Invisibility has worn off\n");
 830                         }
 831                 }
 832                 else
 833                 {
 834                         if (time < self.strength_finished)
 835                         {
 836                                 self.alpha = cvar("g_minstagib_invis_alpha");
 837                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 838                                 self.items = self.items | IT_STRENGTH;
 839                                 sprint(self, "^3You are invisible\n");
 840                         }
 841                 }
 842
 843                 if (self.items & IT_INVINCIBLE)
 844                 {
 845                         if (time > self.invincible_finished)
 846                         {
 847                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 848                                 sprint(self, "^3Speed has worn off\n");
 849                         }
 850                 }
 851                 else
 852                 {
 853                         if (time < self.invincible_finished)
 854                         {
 855                                 self.items = self.items | IT_INVINCIBLE;
 856                                 sprint(self, "^3You are on speed\n");
 857                         }
 858                 }
 859                 return;
 860         }
 861
 862         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 863         if (self.items & IT_STRENGTH)
 864         {
 865                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 866                 if (time > self.strength_finished)
 867                 {
 868                         self.items = self.items - (self.items & IT_STRENGTH);
 869                         sprint(self, "^3Strength has worn off\n");
 870                 }
 871         }
 872         else
 873         {
 874                 if (time < self.strength_finished)
 875                 {
 876                         self.items = self.items | IT_STRENGTH;
 877                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
 878                 }
 879         }
 880         if (self.items & IT_INVINCIBLE)
 881         {
 882                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 883                 if (time > self.invincible_finished)
 884                 {
 885                         self.items = self.items - (self.items & IT_INVINCIBLE);
 886                         sprint(self, "^3Shield has worn off\n");
 887                 }
 888         }
 889         else
 890         {
 891                 if (time < self.invincible_finished)
 892                 {
 893                         self.items = self.items | IT_INVINCIBLE;
 894                         sprint(self, "^3Shield surrounds you\n");
 895                 }
 896         }
 897
 898         if (cvar("g_fullbrightplayers"))
 899                 self.effects = self.effects | EF_FULLBRIGHT;
 900
 901         // midair gamemode: damage only while in the air
 902         // if in midair mode, being on ground grants temporary invulnerability
 903         // (this is so that multishot weapon don't clear the ground flag on the
 904         // first damage in the frame, leaving the player vulnerable to the
 905         // remaining hits in the same frame)
 906         if (self.flags & FL_ONGROUND)
 907         if (cvar("g_midair"))
 908                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
 909
 910         if (time < self.spawnshieldtime)
 911                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
 912 }
 913
 914 void player_regen (void)
 915 {
 916         float maxh, maxa, max_mod, regen_mod, rot_mod;
 917         maxh = cvar("g_balance_health_stable");
 918         maxa = cvar("g_balance_armor_stable");
 919
 920         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
 921                 return;
 922
 923         if(cvar("g_runematch"))
 924         {
 925                 max_mod = regen_mod = rot_mod = 1;
 926                 if (self.runes & RUNE_REGEN)
 927                 {
 928                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
 929                         {
 930                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
 931                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
 932                         }
 933                         else
 934                         {
 935                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
 936                                 max_mod = cvar("g_balance_rune_regen_hpmod");
 937                         }
 938                 }
 939                 else if (self.runes & CURSE_VENOM)
 940                 {
 941                         max_mod = cvar("g_balance_curse_venom_hpmod");
 942                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
 943                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
 944                         else
 945                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
 946                         //if (!self.runes & RUNE_REGEN)
 947                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
 948                 }
 949                 maxh = maxh * max_mod;
 950                 //maxa = maxa * max_mod;
 951
 952                 if (time > self.pauserotarmor_finished)
 953                 {
 954                         if (self.armorvalue > maxa)
 955                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 956                 }
 957                 if (time > self.pauserothealth_finished)
 958                 {
 959                         if (self.health > maxh)
 960                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
 961                 }
 962                 if (time > self.pauseregen_finished)
 963                 {
 964                         if (self.health < maxh)
 965                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime, 1000);
 966                         if (self.armorvalue < maxa)
 967                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 968                 }
 969         }
 970         else
 971         {
 972                 if (time > self.pauserothealth_finished)
 973                 if (self.health > maxh)
 974                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
 975                 if (time > self.pauserotarmor_finished)
 976                 if (self.armorvalue > maxa)
 977                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 978                 if (time > self.pauseregen_finished)
 979                 {
 980                         if (self.health < maxh)
 981                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
 982                         if (self.armorvalue < maxa)
 983                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
 984                 }
 985         }
 986 }
 987
 988 /*
 989 ======================
 990 spectate mode routines
 991 ======================
 992 */
 993 void SpectateCopy(entity spectatee) {
 994         self.armortype = spectatee.armortype;
 995         self.armorvalue = spectatee.armorvalue;
 996         self.currentammo = spectatee.currentammo;
 997         self.effects = spectatee.effects;
 998         self.health = spectatee.health;
 999         self.impulse = 0;
1000         self.items = spectatee.items;
1001         self.punchangle = spectatee.punchangle;
1002         self.view_ofs = spectatee.view_ofs;
1003         self.v_angle = spectatee.v_angle;
1004         self.viewzoom = spectatee.viewzoom;
1005         setorigin(self, spectatee.origin);
1006         setsize(self, spectatee.mins, spectatee.maxs);
1007 }
1008
1009 void SpectateUpdate() {
1010         if (self != self.enemy) {
1011                 SpectateCopy(self.enemy);
1012                 msg_entity = self;
1013                 WriteByte(MSG_ONE, SVC_SETANGLE);
1014                 WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1015                 WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1016                 WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1017         }
1018 }
1019
1020 float SpectateNext() {
1021         other = find(self.enemy, classname, "player");
1022         if (!other) {
1023                 other = find(other, classname, "player");
1024         }
1025         if (other) {
1026                 self.enemy = other;
1027         }
1028         if(self.enemy.classname == "player") {
1029                 msg_entity = self;
1030                 WriteByte(MSG_ONE, SVC_SETVIEW);
1031                 WriteEntity(MSG_ONE, self.enemy);
1032                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1033                 SpectateUpdate();
1034                 return 1;
1035         } else {
1036                 return 0;
1037         }
1038 }
1039
1040 /*
1041 =============
1042 PlayerPreThink
1043
1044 Called every frame for each client before the physics are run
1045 =============
1046 */
1047 void PlayerPreThink (void)
1048 {
1049         if(self.classname == "player") {
1050                 local vector m1, m2;
1051
1052 //              MauveBot_AI();
1053
1054 //              if(self.netname == "Wazat")
1055 //                      bprint(strcat(self.classname, "\n"));
1056
1057                 CheckRules_Player();
1058
1059                 if(self.button7)
1060                         PrintWelcomeMessage(self);
1061
1062                 if(cvar("g_lms") || !cvar("sv_spectate"))
1063                 if((time - self.jointime) <= cvar("welcome_message_time"))
1064                         PrintWelcomeMessage(self);
1065
1066                 if (intermission_running)
1067                 {
1068                         IntermissionThink ();   // otherwise a button could be missed between
1069                         return;                                 // the think tics
1070                 }
1071
1072                 if (self.deadflag != DEAD_NO)
1073                 {
1074                         player_anim();
1075                         weapon_freeze();
1076                         if (self.deadflag == DEAD_DYING)
1077                         {
1078                                 if (time > self.dead_time)
1079                                         self.deadflag = DEAD_DEAD;
1080                         }
1081                         else if (self.deadflag == DEAD_DEAD)
1082                         {
1083                                 if (cvar("g_lms") || cvar("g_forced_respawn"))
1084                                         self.button0 = self.button2 = self.button3 = 0;
1085
1086                                 if (!self.button0 && !self.button2 && !self.button3)
1087                                         self.deadflag = DEAD_RESPAWNABLE;
1088                         }
1089                         else if (self.deadflag == DEAD_RESPAWNABLE)
1090                         {
1091                                 if (self.button0  ||
1092                                     self.button2  ||
1093                                     self.button3  ||
1094                                     self.button4  ||
1095                                     cvar("g_lms") ||
1096                                     cvar("g_forced_respawn"))
1097                                         respawn();
1098                         }
1099                         return;
1100                 }
1101
1102                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1103                 {
1104                         vector dist;
1105
1106                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1107                         dist = self.oldorigin - self.origin;
1108                         dist_z = 0;
1109                         self.lms_traveled_distance += fabs(vlen(dist));
1110
1111                         if(time > self.lms_nextcheck)
1112                         {
1113                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1114                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1115                                 {
1116                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1117                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1118                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1119                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1120                                 }
1121                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1122                                 self.lms_traveled_distance = 0;
1123                         }
1124                 }
1125
1126                 if (self.button5)
1127                 {
1128                         if (!self.crouch)
1129                         {
1130                                 self.crouch = TRUE;
1131                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1132                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1133                         }
1134                 }
1135                 else
1136                 {
1137                         if (self.crouch)
1138                         {
1139                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1140                                 if (!trace_startsolid)
1141                                 {
1142                                         self.crouch = FALSE;
1143                                         self.view_ofs = PL_VIEW_OFS;
1144                                         setsize (self, PL_MIN, PL_MAX);
1145                                 }
1146                         }
1147                 }
1148
1149                 if(cvar("sv_defaultcharacter") == 1) {
1150                         local string defaultmodel;
1151                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1152
1153                         if (defaultmodel != self.model)
1154                         {
1155                                 m1 = self.mins;
1156                                 m2 = self.maxs;
1157                                 precache_model (defaultmodel);
1158                                 setmodel (self, defaultmodel);
1159                                 setsize (self, m1, m2);
1160                         }
1161
1162                         if (self.skin != stof(cvar_string("sv_defaultplayerskin")))
1163                                 self.skin = stof(cvar_string("sv_defaultplayerskin"));
1164                 } else {
1165                         if (self.playermodel != self.model)
1166                         {
1167                                 self.playermodel = CheckPlayerModel(self.playermodel);
1168                                 m1 = self.mins;
1169                                 m2 = self.maxs;
1170                                 precache_model (self.playermodel);
1171                                 setmodel (self, self.playermodel);
1172                                 setsize (self, m1, m2);
1173                         }
1174
1175                         if (self.skin != stof(self.playerskin))
1176                                 self.skin = stof(self.playerskin);
1177                 }
1178                 // Savage: Check for nameless players
1179                 if (strlen(self.netname) < 1) {
1180                         self.netname = "Player";
1181                         stuffcmd(self, "name Player\n");
1182                 }
1183
1184                 GrapplingHookFrame();
1185
1186                 W_WeaponFrame();
1187
1188                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1189                 {
1190                         if (cvar("g_minstagib") && self.button3)
1191                         {
1192                                 if (self.jump_interval <= (time + 0.1))
1193                                 {
1194                                         self.jump_interval = time + 1;
1195                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1196                                 }
1197                         }
1198                         else if (self.viewzoom > 0.4)
1199                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1200                 }
1201                 else if (self.viewzoom < 1.0)
1202                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1203
1204
1205                 if (self.button2)
1206                         PlayerJump ();
1207                 else
1208                         self.flags = self.flags | FL_JUMPRELEASED;
1209
1210                 player_powerups();
1211                 player_regen();
1212                 player_anim();
1213
1214                 //self.angles_y=self.v_angle_y + 90;   // temp
1215
1216                 if (self.waterlevel == 2)
1217                         CheckWaterJump ();
1218
1219                 //if (TetrisPreFrame()) return;
1220         } else if(gameover) {
1221                 if (intermission_running)
1222                         IntermissionThink ();   // otherwise a button could be missed between
1223                 return;
1224         } else if(self.classname == "observer") {
1225
1226                 if (self.flags & FL_JUMPRELEASED) {
1227                         if (self.button2 && self.version == cvar("gameversion")) {
1228                                 if(!cvar("teamplay")) {
1229                                         self.flags = self.flags & !FL_JUMPRELEASED;
1230                                         self.classname = "player";
1231                                         if(!cvar("g_lms"))
1232                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1233                                         PutClientInServer();
1234                                         centerprint(self,"");
1235                                         return;
1236                                 } else {
1237                                         self.flags = self.flags & !FL_JUMPRELEASED;
1238                                         stuffcmd(self,"menu_showteamselect\n");
1239                                         return;
1240                                 }
1241                         } else if(self.button0 && self.version == cvar("gameversion")) {
1242                                 self.flags = self.flags & !FL_JUMPRELEASED;
1243                                 if(SpectateNext() == 1) {
1244                                         self.classname = "spectator";
1245                                 }
1246                         }
1247                 } else {
1248                         if (!(self.button0 || self.button2)) {
1249                                 self.flags = self.flags | FL_JUMPRELEASED;
1250                         }
1251                 }
1252                 if(cvar("g_lms") && self.frags == 0)
1253                         centerprint(self, "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n^1You have no more lives left\nwait for next round\n\n\n^7press attack to spectate other players");
1254                 else if(cvar("g_lms") && self.frags == -1)
1255                         centerprint(self, "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n^1Match has already begun\nwait for next round\n\n\n^7press attack to spectate other players");
1256                 else
1257                         PrintWelcomeMessage(self);
1258                         //centerprint(self, "\n\n\npress jump to play\npress attack to spectate other players");
1259         } else if(self.classname == "spectator") {
1260
1261                 if (self.flags & FL_JUMPRELEASED) {
1262                         if (self.button2 && self.version == cvar("gameversion")) {
1263                                 if(!cvar("teamplay")) {
1264                                         self.flags = self.flags & !FL_JUMPRELEASED;
1265                                         self.classname = "player";
1266                                         if(!cvar("g_lms"))
1267                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1268
1269                                         msg_entity = self;
1270                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1271                                         WriteEntity(MSG_ONE, self);
1272                                         PutClientInServer();
1273                                         centerprint(self,"");
1274                                         return;
1275                                 } else {
1276                                         self.flags = self.flags & !FL_JUMPRELEASED;
1277                                         stuffcmd(self,"menu_showteamselect\n");
1278                                         return;
1279                                 }
1280                         } else if(self.button0) {
1281                                 self.flags = self.flags & !FL_JUMPRELEASED;
1282                                 if(SpectateNext() == 1) {
1283                                         self.classname = "spectator";
1284                                 } else {
1285                                         self.classname = "observer";
1286                                         msg_entity = self;
1287                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1288                                         WriteEntity(MSG_ONE, self);
1289                                         PutClientInServer();
1290                                 }
1291                         } else if (self.button3) {
1292                                 self.flags = self.flags & !FL_JUMPRELEASED;
1293                                 self.classname = "observer";
1294                                 msg_entity = self;
1295                                 WriteByte(MSG_ONE, SVC_SETVIEW);
1296                                 WriteEntity(MSG_ONE, self);
1297                                 PutClientInServer();
1298                         } else {
1299                                 SpectateUpdate();
1300                         }
1301         } else {
1302                 if (!(self.button0 || self.button3)) {
1303                         self.flags = self.flags | FL_JUMPRELEASED;
1304                 }
1305                 }
1306                 if (cvar("g_lms") && self.frags < 1)
1307                         centerprint(self, strcat("\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\nspectating ", self.enemy.netname, "\n\n\n^7press attack for next player\npress attack2 for free fly mode"));
1308                 else
1309                         centerprint(self, strcat("\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\nspectating ", self.enemy.netname, "\n\n\n^7press jump to play\n^7press attack for next player\npress attack2 for free fly mode"));
1310
1311         }
1312 }
1313
1314 /*
1315 =============
1316 PlayerPostThink
1317
1318 Called every frame for each client after the physics are run
1319 =============
1320 */
1321 void PlayerPostThink (void)
1322 {
1323         if(self.classname == "player") {
1324                 CheckRules_Player();
1325                 UpdateChatBubble();
1326                 UpdateTeamBubble();
1327                 UpdatePlayerColors();
1328                 if (self.deadflag == DEAD_NO)
1329                 if (self.impulse)
1330                         ImpulseCommands ();
1331                 if (intermission_running)
1332                         return;         // intermission or finale
1333
1334                 //PrintWelcomeMessage(self);
1335                 //if (TetrisPostFrame()) return;
1336         } else if (self.classname == "observer") {
1337                 //do nothing
1338         } else if (self.classname == "spectator") {
1339                 //do nothing
1340         }
1341 }