data/qcsrc/server/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 144         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 145                 spot = Spawn_RandomPoint(firstspot);
 146         else
 147                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 148
 149         if (!spot)
 150         {
 151                 if(cvar("spawn_debug"))
 152                         GotoNextMap();
 153                 else
 154                         error ("PutClientInServer: no start points on level");
 155         }
 156
 157         return spot;
 158 }
 159
 160 /*
 161 =============
 162 CheckPlayerModel
 163
 164 Checks if the argument string can be a valid playermodel.
 165 Returns a valid one in doubt.
 166 =============
 167 */
 168 string FallbackPlayerModel = "models/player/marine.zym";
 169 string CheckPlayerModel(string plyermodel) {
 170         if(strlen(plyermodel) < 4)
 171                 return FallbackPlayerModel;
 172         if( substring(plyermodel,0,14) != "models/player/")
 173                 return FallbackPlayerModel;
 174         else if(cvar("sv_servermodelsonly"))
 175         {
 176                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 177                         return FallbackPlayerModel;
 178                 if(!fexists(plyermodel))
 179                         return FallbackPlayerModel;
 180         }
 181         return plyermodel;
 182 }
 183
 184 /*
 185 =============
 186 Client_customizeentityforclient
 187
 188 LOD reduction
 189 =============
 190 */
 191 float Client_customizeentityforclient()
 192 {
 193 #ifdef ALLOW_VARIABLE_LOD
 194         // self: me
 195         // other: the player viewing me
 196         float distance;
 197         float f;
 198
 199         if(other.cvar_cl_playerdetailreduction <= 0)
 200         {
 201                 if(other.cvar_cl_playerdetailreduction <= -2)
 202                         self.modelindex = self.modelindex_lod2;
 203                 else if(other.cvar_cl_playerdetailreduction <= -1)
 204                         self.modelindex = self.modelindex_lod1;
 205                 else
 206                         self.modelindex = self.modelindex_lod0;
 207         }
 208         else
 209         {
 210                 distance = vlen(self.origin - other.origin);
 211                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 212                 if(f > 10000)
 213                         self.modelindex = self.modelindex_lod2;
 214                 else if(f > 5000)
 215                         self.modelindex = self.modelindex_lod1;
 216                 else
 217                         self.modelindex = self.modelindex_lod0;
 218         }
 219 #endif
 220
 221         return TRUE;
 222 }
 223
 224 void setmodel_lod(entity e, string modelname)
 225 {
 226 #ifdef ALLOW_VARIABLE_LOD
 227         string s;
 228
 229         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 230         if(fexists(s))
 231         {
 232                 precache_model(s);
 233                 setmodel(e, s);
 234                 self.modelindex_lod1 = self.modelindex;
 235         }
 236         else
 237                 self.modelindex_lod1 = -1;
 238
 239         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 240         if(fexists(s))
 241         {
 242                 precache_model(s);
 243                 setmodel(e, s);
 244                 self.modelindex_lod2 = self.modelindex;
 245         }
 246         else
 247                 self.modelindex_lod2 = -1;
 248
 249         precache_model(modelname);
 250         setmodel(e, modelname);
 251         self.modelindex_lod0 = self.modelindex;
 252
 253         if(self.modelindex_lod1 < 0)
 254                 self.modelindex_lod1 = self.modelindex;
 255
 256         if(self.modelindex_lod2 < 0)
 257                 self.modelindex_lod2 = self.modelindex;
 258 #else
 259         precache_model(modelname);
 260         setmodel(e, modelname);
 261 #endif
 262 }
 263
 264 /*
 265 =============
 266 PutObserverInServer
 267
 268 putting a client as observer in the server
 269 =============
 270 */
 271 void PutObserverInServer (void)
 272 {
 273         entity  spot;
 274         spot = SelectSpawnPoint (FALSE);
 275         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 276
 277         if(clienttype(self) == CLIENTTYPE_REAL)
 278         {
 279                 msg_entity = self;
 280                 WriteByte(MSG_ONE, SVC_SETVIEW);
 281                 WriteEntity(MSG_ONE, self);
 282         }
 283
 284         if (cvar("g_runematch"))
 285                 DropAllRunes(self);
 286
 287         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 288                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 289         else if(self.killcount != -666)
 290                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 291
 292         self.classname = "observer";
 293         self.health = -666;
 294         self.takedamage = DAMAGE_NO;
 295         self.solid = SOLID_NOT;
 296         self.movetype = MOVETYPE_NOCLIP;
 297         self.flags = FL_CLIENT | FL_NOTARGET;
 298         self.armorvalue = 666;
 299         self.effects = 0;
 300         self.armorvalue = cvar("g_balance_armor_start");
 301         self.pauserotarmor_finished = 0;
 302         self.pauserothealth_finished = 0;
 303         self.pauseregen_finished = 0;
 304         self.damageforcescale = 0;
 305         self.death_time = 0;
 306         self.dead_time = 0;
 307         self.dead_frame = 0;
 308         self.die_frame = 0;
 309         self.deaths = 0;
 310         self.alpha = 0;
 311         self.scale = 0;
 312         self.fade_time = 0;
 313         self.pain_frame = 0;
 314         self.pain_finished = 0;
 315         self.strength_finished = 0;
 316         self.invincible_finished = 0;
 317         self.pushltime = 0;
 318         self.think = SUB_Null;
 319         self.nextthink = 0;
 320         self.hook_time = 0;
 321         self.runes = 0;
 322         self.deadflag = DEAD_NO;
 323         self.angles = spot.angles;
 324         self.angles_z = 0;
 325         self.fixangle = TRUE;
 326         self.crouch = FALSE;
 327         self.view_ofs = PL_VIEW_OFS;
 328         setorigin (self, spot.origin);
 329         setsize (self, '0 0 0', '0 0 0');
 330         self.oldorigin = self.origin;
 331         self.items = 0;
 332         self.model = "";
 333         self.modelindex = 0;
 334         self.weapon = 0;
 335         self.weaponmodel = "";
 336         self.weaponframe = 0;
 337         self.weaponentity = world;
 338         self.killcount = -666;
 339         self.velocity = '0 0 0';
 340         self.avelocity = '0 0 0';
 341         self.punchangle = '0 0 0';
 342         self.punchvector = '0 0 0';
 343         self.oldvelocity = self.velocity;
 344
 345         if(cvar("g_arena"))
 346         {
 347                 if(self.frags != -2)
 348                 {
 349                         Spawnqueue_Insert(self);
 350                 }
 351                 else
 352                 {
 353                         Spawnqueue_Unmark(self);
 354                         Spawnqueue_Remove(self);
 355                 }
 356         }
 357         else if(!cvar("g_lms"))
 358                 self.frags = -666;
 359 }
 360
 361
 362 /*
 363 =============
 364 PutClientInServer
 365
 366 Called when a client spawns in the server
 367 =============
 368 */
 369 void PutClientInServer (void)
 370 {
 371         if(clienttype(self) == CLIENTTYPE_BOT)
 372         {
 373                 self.classname = "player";
 374         }
 375         else if(clienttype(self) == CLIENTTYPE_REAL)
 376         {
 377                 msg_entity = self;
 378                 WriteByte(MSG_ONE, SVC_SETVIEW);
 379                 WriteEntity(MSG_ONE, self);
 380         }
 381
 382         // player is dead and becomes observer
 383         if(cvar("g_lms") && self.frags < 1)
 384                 self.classname = "observer";
 385
 386         if(cvar("g_arena"))
 387         if(!self.spawned)
 388                 self.classname = "observer";
 389
 390         if(self.classname == "player") {
 391                 entity  spot;
 392
 393                 spot = SelectSpawnPoint (FALSE);
 394
 395                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397                 self.classname = "player";
 398                 self.iscreature = TRUE;
 399                 self.movetype = MOVETYPE_WALK;
 400                 self.solid = SOLID_SLIDEBOX;
 401                 self.flags = FL_CLIENT;
 402                 self.takedamage = DAMAGE_AIM;
 403                 self.effects = 0;
 404                 self.health = cvar("g_balance_health_start");
 405                 self.armorvalue = cvar("g_balance_armor_start");
 406                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 407                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 408                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 409                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 410                 self.damageforcescale = 2;
 411                 self.death_time = 0;
 412                 self.dead_time = 0;
 413                 self.dead_frame = 0;
 414                 self.die_frame = 0;
 415                 self.alpha = 0;
 416                 self.scale = 0;
 417                 self.fade_time = 0;
 418                 self.pain_frame = 0;
 419                 self.pain_finished = 0;
 420                 self.strength_finished = 0;
 421                 self.invincible_finished = 0;
 422                 self.pushltime = 0;
 423                 //self.speed_finished = 0;
 424                 //self.slowmo_finished = 0;
 425                 // players have no think function
 426                 self.think = SUB_Null;
 427                 self.nextthink = 0;
 428                 self.weapon = 0;
 429                 self.switchweapon = 0;
 430                 self.hook_time = 0;
 431
 432                 self.runes = 0;
 433
 434                 self.deadflag = DEAD_NO;
 435
 436                 self.angles = spot.angles;
 437
 438                 self.angles_z = 0; // never spawn tilted even if the spot says to
 439                 self.fixangle = TRUE; // turn this way immediately
 440                 self.velocity = '0 0 0';
 441                 self.avelocity = '0 0 0';
 442                 self.punchangle = '0 0 0';
 443                 self.punchvector = '0 0 0';
 444                 self.oldvelocity = self.velocity;
 445
 446                 self.viewzoom = 0.6;
 447
 448                 self.customizeentityforclient = Client_customizeentityforclient;
 449
 450                 if(cvar("sv_defaultcharacter") == 1) {
 451                         local string defaultmodel;
 452                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 453                         setmodel_lod (self, defaultmodel);
 454                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 455                 } else {
 456                         self.playermodel = CheckPlayerModel(self.playermodel);
 457                         setmodel_lod (self, self.playermodel);
 458                         self.skin = stof(self.playerskin);
 459
 460                 }
 461
 462                 self.crouch = FALSE;
 463                 self.view_ofs = PL_VIEW_OFS;
 464                 setsize (self, PL_MIN, PL_MAX);
 465                 self.spawnorigin = spot.origin;
 466                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 467                 // don't reset back to last position, even if new position is stuck in solid
 468                 self.oldorigin = self.origin;
 469
 470                 if(cvar("g_lms"))
 471                 {
 472                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 473                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 474                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 475                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 476                         self.health = cvar("g_lms_start_health");
 477                         self.armorvalue = cvar("g_lms_start_armor");
 478                 }
 479                 else if (cvar("g_use_ammunition")) {
 480                         self.ammo_shells = cvar("g_start_ammo_shells");
 481                         self.ammo_nails = cvar("g_start_ammo_nails");
 482                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 483                         self.ammo_cells = cvar("g_start_ammo_cells");
 484                 } else {
 485                         self.ammo_shells = 999;
 486                         self.ammo_nails = 999;
 487                         self.ammo_rockets = 999;
 488                         self.ammo_cells = 999;
 489                 }
 490
 491                 self.items = 0;
 492                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 493                 {
 494                         self.items = self.items | IT_LASER;
 495                         self.switchweapon = WEP_LASER;
 496                 }
 497                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 498                 {
 499                         self.items = self.items | IT_SHOTGUN;
 500                         self.switchweapon = WEP_SHOTGUN;
 501                 }
 502                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 503                 {
 504                         self.items = self.items | IT_UZI;
 505                         self.switchweapon = WEP_UZI;
 506                 }
 507                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 508                 {
 509                         self.items = self.items | IT_GRENADE_LAUNCHER;
 510                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 511                 }
 512                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 513                 {
 514                         self.items = self.items | IT_ELECTRO;
 515                         self.switchweapon = WEP_ELECTRO;
 516                 }
 517                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 518                 {
 519                         self.items = self.items | IT_CRYLINK;
 520                         self.switchweapon = WEP_CRYLINK;
 521                 }
 522                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 523                 {
 524                         self.items = self.items | IT_NEX;
 525                         self.switchweapon = WEP_NEX;
 526                 }
 527                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 528                 {
 529                         self.items = self.items | IT_HAGAR;
 530                         self.switchweapon = WEP_HAGAR;
 531                 }
 532                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 533                 {
 534                         self.items = self.items | IT_ROCKET_LAUNCHER;
 535                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 536                 }
 537
 538                 if(cvar("g_instagib"))
 539                 {
 540                         self.items = IT_NEX;
 541                         self.switchweapon = WEP_NEX;
 542                         self.ammo_cells = 999;
 543                 }
 544
 545                 if(cvar("g_rocketarena"))
 546                 {
 547                         self.items = IT_ROCKET_LAUNCHER;
 548                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 549                         self.ammo_rockets = 999;
 550                 }
 551
 552                 if(cvar("g_nixnex"))
 553                 {
 554                         self.items = 0;
 555                         // will be done later
 556                 }
 557
 558                 if(cvar("g_minstagib"))
 559                 {
 560                         self.health = 100;
 561                         self.armorvalue = 0;
 562                         self.items = IT_NEX;
 563                         self.switchweapon = WEP_NEX;
 564                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 565                         self.extralives = 0;
 566                         self.jump_interval = time;
 567                 }
 568
 569                 if(cvar("g_arena"))
 570                         Spawnqueue_Remove(self);
 571
 572                 self.event_damage = PlayerDamage;
 573
 574                 self.bot_attack = TRUE;
 575
 576                 self.statdraintime = time + 5;
 577                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 578
 579                 if(self.killcount == -666) {
 580                         self.killcount = 0;
 581                         if(!cvar("g_arena"))
 582                                 self.frags = 0;
 583                 }
 584
 585                 self.cnt = WEP_LASER;
 586                 self.nixnex_lastchange_id = -1;
 587
 588                 /*
 589                 W_UpdateWeapon();
 590                 W_UpdateAmmo();
 591                 */
 592                 CL_SpawnWeaponentity();
 593                 self.alpha = default_player_alpha;
 594                 self.exteriorweaponentity.alpha = default_player_alpha;
 595
 596                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 597                 self.lms_traveled_distance = 0;
 598
 599                 if(cvar("spawn_debug"))
 600                 {
 601                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 602                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 603                 }
 604
 605                 //stuffcmd(self, "chase_active 0");
 606                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 607         } else if(self.classname == "observer") {
 608                 PutObserverInServer ();
 609         }
 610 }
 611
 612 /*
 613 =============
 614 SetNewParms
 615 =============
 616 */
 617 void SetNewParms (void)
 618 {
 619
 620 }
 621
 622 /*
 623 =============
 624 SetChangeParms
 625 =============
 626 */
 627 void SetChangeParms (void)
 628 {
 629
 630 }
 631
 632 /*
 633 =============
 634 ClientKill
 635
 636 Called when a client types 'kill' in the console
 637 =============
 638 */
 639 void ClientKill (void)
 640 {
 641         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 642 }
 643
 644 /*
 645 =============
 646 ClientConnect
 647
 648 Called when a client connects to the server
 649 =============
 650 */
 651 string ColoredTeamName(float t);
 652 //void dom_player_join_team(entity pl);
 653 void ClientConnect (void)
 654 {
 655         self.classname = "player_joining";
 656         self.flags = self.flags | FL_CLIENT;
 657
 658         if(player_count<0) player_count = 0;
 659
 660         bot_clientconnect();
 661
 662         //if(cvar("g_domination"))
 663         //      dom_player_join_team(self);
 664
 665         //JoinBestTeam(self, FALSE);
 666
 667         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 668                 self.classname = "observer";
 669         } else {
 670                 self.classname = "player";
 671                 campaign_bots_may_start = 1;
 672         }
 673
 674         self.playerid = (playerid_last = playerid_last + 1);
 675         if(cvar("sv_eventlog"))
 676         {
 677                 string s;
 678                 if(clienttype(self) == CLIENTTYPE_REAL)
 679                         s = "player";
 680                 else
 681                         s = "bot";
 682                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 683                 s = strcat(":team:", ftos(self.playerid), ":");
 684                 s = strcat(s, ftos(self.team));
 685                 GameLogEcho(s, FALSE);
 686         }
 687
 688         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 689
 690         bprint ("^4",self.netname);
 691         bprint ("^4 connected");
 692
 693         if(cvar("g_domination") || cvar("g_ctf"))
 694         {
 695                 bprint(" and joined the ");
 696                 bprint(ColoredTeamName(self.team));
 697         }
 698
 699         bprint("\n");
 700
 701         self.welcomemessage_time = time + cvar("welcome_message_time");
 702         self.welcomemessage_time2 = 0;
 703
 704         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 705         // send prediction settings to the client
 706         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 707         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 708         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 709         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 710         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 711         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 712         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 713         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 714         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 715         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 716         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 717         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 718         // Wazat's grappling hook
 719         SetGrappleHookBindings();
 720
 721         // get autoswitch state from player
 722         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 723         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 724
 725         // get version info from player
 726         stuffcmd(self, "cmd clientversion $gameversion\n");
 727
 728         // get other cvars from player
 729         GetCvars(0);
 730
 731         // set cvar for team scoreboard
 732         stuffcmd(self, strcat("set teamplay ", ftos(teams_matter), "\n"));
 733
 734         if(cvar("g_lms"))
 735         {
 736                 self.frags = cvar("fraglimit");
 737                 // no fraglimit was set, so player gets 999 lives
 738                 if(self.frags < 1)
 739                         self.frags = 999;
 740
 741                 // disallow player to join after the worst player has lost g_lms_last_join lives
 742                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 743                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 744                 {
 745                         self.frags = -666;
 746                         lms_dead_count += 1;
 747                 }
 748                 else if(cvar("fraglimit") > lms_lowest_lives)
 749                 {
 750                         self.frags = lms_lowest_lives;
 751                 }
 752         }
 753         else if(cvar("g_arena"))
 754         {
 755                 self.classname = "observer";
 756                 Spawnqueue_Insert(self);
 757         }
 758
 759         bot_relinkplayerlist();
 760
 761         self.jointime = time;
 762 }
 763
 764 /*
 765 =============
 766 ClientDisconnect
 767
 768 Called when a client disconnects from the server
 769 =============
 770 */
 771 void(entity e) DropFlag;
 772 .entity chatbubbleentity;
 773 .entity teambubbleentity;
 774 void ClientDisconnect (void)
 775 {
 776         float save;
 777         if(cvar("sv_eventlog"))
 778                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 779         bprint ("^4",self.netname);
 780         bprint ("^4 disconnected\n");
 781
 782         if (self.chatbubbleentity)
 783         {
 784                 remove (self.chatbubbleentity);
 785                 self.chatbubbleentity = world;
 786         }
 787
 788         if (self.teambubbleentity)
 789         {
 790                 remove (self.teambubbleentity);
 791                 self.teambubbleentity = world;
 792         }
 793
 794         DropAllRunes(self);
 795
 796         if(self.flagcarried)
 797                 DropFlag(self.flagcarried);
 798
 799         save = self.flags;
 800         self.flags = self.flags - (self.flags & FL_CLIENT);
 801         bot_relinkplayerlist();
 802         self.flags = save;
 803
 804         // player was dead, decrease dead count
 805         if(cvar("g_lms") && self.frags < 1)
 806                 lms_dead_count -= 1;
 807         else if(cvar("g_arena"))
 808         {
 809                 Spawnqueue_Unmark(self);
 810                 Spawnqueue_Remove(self);
 811         }
 812 }
 813
 814 .float buttonchat;
 815 void() ChatBubbleThink =
 816 {
 817         self.nextthink = time;
 818         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 819         {
 820                 remove(self);
 821                 return;
 822         }
 823         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 824         if (self.owner.buttonchat && !self.owner.deadflag)
 825                 self.model = self.mdl;
 826         else
 827                 self.model = "";
 828 };
 829
 830 void() UpdateChatBubble =
 831 {
 832         if (!self.modelindex)
 833                 return;
 834         // spawn a chatbubble entity if needed
 835         if (!self.chatbubbleentity)
 836         {
 837                 self.chatbubbleentity = spawn();
 838                 self.chatbubbleentity.owner = self;
 839                 self.chatbubbleentity.exteriormodeltoclient = self;
 840                 self.chatbubbleentity.think = ChatBubbleThink;
 841                 self.chatbubbleentity.nextthink = time;
 842                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 843                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 844                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 845                 self.chatbubbleentity.model = "";
 846         }
 847 }
 848
 849
 850 void() TeamBubbleThink =
 851 {
 852         self.nextthink = time;
 853         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 854         {
 855                 remove(self);
 856                 return;
 857         }
 858 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 859         if (self.owner.buttonchat || self.owner.deadflag)
 860                 self.model = "";
 861         else
 862                 self.model = self.mdl;
 863
 864 };
 865
 866 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 867
 868 void() UpdateTeamBubble =
 869 {
 870         if (!self.modelindex || !cvar("teamplay"))
 871                 return;
 872         // spawn a teambubble entity if needed
 873         if (!self.teambubbleentity && cvar("teamplay"))
 874         {
 875                 self.teambubbleentity = spawn();
 876                 self.teambubbleentity.owner = self;
 877                 self.teambubbleentity.exteriormodeltoclient = self;
 878                 self.teambubbleentity.think = TeamBubbleThink;
 879                 self.teambubbleentity.nextthink = time;
 880                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 881 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 882                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 883                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 884                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 885                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 886                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 887         }
 888 }
 889
 890 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 891 // added to the model skins
 892 /*void() UpdateColorModHack =
 893 {
 894         local float c;
 895         c = self.clientcolors & 15;
 896         // LordHavoc: only bothering to support white, green, red, yellow, blue
 897              if (teamplay == 0) self.colormod = '0 0 0';
 898         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 899         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 900         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 901         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 902         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 903         else self.colormod = '1 1 1';
 904 };*/
 905
 906 void UpdatePlayerColors () {
 907         if(self.weaponentity) {
 908                 self.weaponentity.colormap = self.colormap;
 909                 self.exteriorweaponentity.colormap = self.colormap;
 910         }
 911 }
 912 /*
 913 =============
 914 PlayerJump
 915
 916 When you press the jump key
 917 =============
 918 */
 919 void PlayerJump (void)
 920 {
 921         float mjumpheight;
 922
 923         mjumpheight = cvar("g_balance_jumpheight");
 924         if (self.waterlevel >= 2)
 925         {
 926                 if (self.watertype == CONTENT_WATER)
 927                         self.velocity_z = 200;
 928                 else if (self.watertype == CONTENT_SLIME)
 929                         self.velocity_z = 80;
 930                 else
 931                         self.velocity_z = 50;
 932
 933                 return;
 934         }
 935
 936
 937         if (!(self.flags & FL_ONGROUND))
 938                 return;
 939
 940         if (!(self.flags & FL_JUMPRELEASED))
 941                 return;
 942
 943         if(cvar("g_runematch"))
 944         {
 945                 if(self.runes & RUNE_SPEED)
 946                 {
 947                         if(self.runes & CURSE_SLOW)
 948                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 949                         else
 950                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 951                 }
 952                 else if(self.runes & CURSE_SLOW)
 953                 {
 954                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 955                 }
 956         }
 957
 958         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 959         {
 960                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 961         }
 962
 963         self.velocity_z = self.velocity_z + mjumpheight;
 964         self.oldvelocity_z = self.velocity_z;
 965
 966         self.flags = self.flags - FL_ONGROUND;
 967         self.flags = self.flags - FL_JUMPRELEASED;
 968 }
 969
 970 void() CheckWaterJump =
 971 {
 972         local vector start, end;
 973
 974 // check for a jump-out-of-water
 975         makevectors (self.angles);
 976         start = self.origin;
 977         start_z = start_z + 8;
 978         v_forward_z = 0;
 979         normalize(v_forward);
 980         end = start + v_forward*24;
 981         traceline (start, end, TRUE, self);
 982         if (trace_fraction < 1)
 983         {       // solid at waist
 984                 start_z = start_z + self.maxs_z - 8;
 985                 end = start + v_forward*24;
 986                 self.movedir = trace_plane_normal * -50;
 987                 traceline (start, end, TRUE, self);
 988                 if (trace_fraction == 1)
 989                 {       // open at eye level
 990                         self.flags = self.flags | FL_WATERJUMP;
 991                         self.velocity_z = 225;
 992                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 993                         self.teleport_time = time + 2;  // safety net
 994                         return;
 995                 }
 996         }
 997 };
 998
 999
1000 void respawn(void)
1001 {
1002         CopyBody(1);
1003         PutClientInServer();
1004 }
1005
1006 void player_powerups (void)
1007 {
1008         if (cvar("g_minstagib"))
1009         {
1010                 self.effects = EF_FULLBRIGHT;
1011                 if (self.items & IT_STRENGTH)
1012                 {
1013                         if (time > self.strength_finished)
1014                         {
1015                                 self.alpha = default_player_alpha;
1016                                 self.exteriorweaponentity.alpha = default_player_alpha;
1017                                 self.items = self.items - (self.items & IT_STRENGTH);
1018                                 sprint(self, "^3Invisibility has worn off\n");
1019                         }
1020                 }
1021                 else
1022                 {
1023                         if (time < self.strength_finished)
1024                         {
1025                                 self.alpha = cvar("g_minstagib_invis_alpha");
1026                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1027                                 self.items = self.items | IT_STRENGTH;
1028                                 sprint(self, "^3You are invisible\n");
1029                         }
1030                 }
1031
1032                 if (self.items & IT_INVINCIBLE)
1033                 {
1034                         if (time > self.invincible_finished)
1035                         {
1036                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1037                                 sprint(self, "^3Speed has worn off\n");
1038                         }
1039                 }
1040                 else
1041                 {
1042                         if (time < self.invincible_finished)
1043                         {
1044                                 self.items = self.items | IT_INVINCIBLE;
1045                                 sprint(self, "^3You are on speed\n");
1046                         }
1047                 }
1048                 return;
1049         }
1050
1051         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1052         if (self.items & IT_STRENGTH)
1053         {
1054                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1055                 if (time > self.strength_finished)
1056                 {
1057                         self.items = self.items - (self.items & IT_STRENGTH);
1058                         sprint(self, "^3Strength has worn off\n");
1059                 }
1060         }
1061         else
1062         {
1063                 if (time < self.strength_finished)
1064                 {
1065                         self.items = self.items | IT_STRENGTH;
1066                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1067                 }
1068         }
1069         if (self.items & IT_INVINCIBLE)
1070         {
1071                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1072                 if (time > self.invincible_finished)
1073                 {
1074                         self.items = self.items - (self.items & IT_INVINCIBLE);
1075                         sprint(self, "^3Shield has worn off\n");
1076                 }
1077         }
1078         else
1079         {
1080                 if (time < self.invincible_finished)
1081                 {
1082                         self.items = self.items | IT_INVINCIBLE;
1083                         sprint(self, "^3Shield surrounds you\n");
1084                 }
1085         }
1086
1087         if (cvar("g_fullbrightplayers"))
1088                 self.effects = self.effects | EF_FULLBRIGHT;
1089
1090         // midair gamemode: damage only while in the air
1091         // if in midair mode, being on ground grants temporary invulnerability
1092         // (this is so that multishot weapon don't clear the ground flag on the
1093         // first damage in the frame, leaving the player vulnerable to the
1094         // remaining hits in the same frame)
1095         if (self.flags & FL_ONGROUND)
1096         if (cvar("g_midair"))
1097                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1098
1099         if (time < self.spawnshieldtime)
1100                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1101 }
1102
1103 void player_regen (void)
1104 {
1105         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1106         maxh = cvar("g_balance_health_stable");
1107         maxa = cvar("g_balance_armor_stable");
1108         limith = cvar("g_balance_health_limit");
1109         limita = cvar("g_balance_armor_limit");
1110
1111         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1112                 return;
1113
1114         if(cvar("g_runematch"))
1115         {
1116                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1117                 if (self.runes & RUNE_REGEN)
1118                 {
1119                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1120                         {
1121                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1122                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1123                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1124                         }
1125                         else
1126                         {
1127                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1128                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1129                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1130                         }
1131                 }
1132                 else if (self.runes & CURSE_VENOM)
1133                 {
1134                         max_mod = cvar("g_balance_curse_venom_hpmod");
1135                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1136                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1137                         else
1138                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1139                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1140                         //if (!self.runes & RUNE_REGEN)
1141                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1142                 }
1143                 maxh = maxh * max_mod;
1144                 //maxa = maxa * max_mod;
1145
1146                 if (time > self.pauserotarmor_finished)
1147                 {
1148                         if (self.armorvalue > maxa)
1149                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1150                 }
1151                 if (time > self.pauserothealth_finished)
1152                 {
1153                         if (self.health > maxh)
1154                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1155                 }
1156                 if (time > self.pauseregen_finished)
1157                 {
1158                         if (self.health < maxh)
1159                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1160                         if (self.armorvalue < maxa)
1161                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1162                 }
1163         }
1164         else
1165         {
1166                 if (time > self.pauserothealth_finished)
1167                 if (self.health > maxh)
1168                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1169                 if (time > self.pauserotarmor_finished)
1170                 if (self.armorvalue > maxa)
1171                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1172                 if (time > self.pauseregen_finished)
1173                 {
1174                         if (self.health < maxh)
1175                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1176                         if (self.armorvalue < maxa)
1177                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1178                 }
1179         }
1180
1181         if (self.health > limith)
1182                 self.health = limith;
1183         if(self.health < 1)
1184                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1185         if (self.armorvalue > limita)
1186                 self.armorvalue = limita;
1187 }
1188
1189 /*
1190 ======================
1191 spectate mode routines
1192 ======================
1193 */
1194 void SpectateCopy(entity spectatee) {
1195         self.armortype = spectatee.armortype;
1196         self.armorvalue = spectatee.armorvalue;
1197         self.currentammo = spectatee.currentammo;
1198         self.effects = spectatee.effects;
1199         self.health = spectatee.health;
1200         self.impulse = 0;
1201         self.items = spectatee.items;
1202         self.punchangle = spectatee.punchangle;
1203         self.view_ofs = spectatee.view_ofs;
1204         self.v_angle = spectatee.v_angle;
1205         self.viewzoom = spectatee.viewzoom;
1206         setorigin(self, spectatee.origin);
1207         setsize(self, spectatee.mins, spectatee.maxs);
1208 }
1209
1210 void SpectateUpdate() {
1211         if (self != self.enemy) {
1212                 if(self.enemy.flags & FL_NOTARGET)
1213                         PutObserverInServer();
1214                 SpectateCopy(self.enemy);
1215                 self.dmg_take = self.enemy.dmg_take;
1216                 self.dmg_save = self.enemy.dmg_save;
1217                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1218                 self.fixangle = TRUE;
1219                 self.angles = self.enemy.v_angle;
1220                 //msg_entity = self;
1221                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1222                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1223                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1224                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1225         }
1226 }
1227
1228 float SpectateNext() {
1229         other = find(self.enemy, classname, "player");
1230         if (!other) {
1231                 other = find(other, classname, "player");
1232         }
1233         if (other) {
1234                 self.enemy = other;
1235         }
1236         if(self.enemy.classname == "player") {
1237                 msg_entity = self;
1238                 WriteByte(MSG_ONE, SVC_SETVIEW);
1239                 WriteEntity(MSG_ONE, self.enemy);
1240                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1241                 SpectateUpdate();
1242                 return 1;
1243         } else {
1244                 return 0;
1245         }
1246 }
1247
1248 /*
1249 =============
1250 PlayerPreThink
1251
1252 Called every frame for each client before the physics are run
1253 =============
1254 */
1255 void PlayerPreThink (void)
1256 {
1257         if(self.classname == "player") {
1258                 local vector m1, m2;
1259
1260 //              if(self.netname == "Wazat")
1261 //                      bprint(strcat(self.classname, "\n"));
1262
1263                 CheckRules_Player();
1264
1265                 Nixnex_GiveCurrentWeapon();
1266
1267                 if(self.button7)
1268                         PrintWelcomeMessage(self);
1269
1270                 if(cvar("g_lms") || !cvar("sv_spectate"))
1271                 if((time - self.jointime) <= cvar("welcome_message_time"))
1272                         PrintWelcomeMessage(self);
1273
1274                 if (intermission_running)
1275                 {
1276                         IntermissionThink ();   // otherwise a button could be missed between
1277                         return;                                 // the think tics
1278                 }
1279
1280                 if (self.deadflag != DEAD_NO)
1281                 {
1282                         player_anim();
1283                         weapon_freeze();
1284                         if (self.deadflag == DEAD_DYING)
1285                         {
1286                                 if (time > self.dead_time)
1287                                         self.deadflag = DEAD_DEAD;
1288                         }
1289                         else if (self.deadflag == DEAD_DEAD)
1290                         {
1291                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1292                                         self.deadflag = DEAD_RESPAWNABLE;
1293                                 else if (!self.button0 && !self.button2 && !self.button3)
1294                                         self.deadflag = DEAD_RESPAWNABLE;
1295                         }
1296                         else if (self.deadflag == DEAD_RESPAWNABLE)
1297                         {
1298                                 if (self.button0  ||
1299                                     self.button2  ||
1300                                     self.button3  ||
1301                                     self.button4  ||
1302                                     self.button5  ||
1303                                     self.button6  ||
1304                                     self.button7  ||
1305                                     self.button8  ||
1306                                     self.buttonuse ||
1307                                     cvar("g_lms") ||
1308                                     cvar("g_forced_respawn"))
1309                                         respawn();
1310                         }
1311                         return;
1312                 }
1313
1314                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1315                 {
1316                         vector dist;
1317
1318                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1319                         dist = self.oldorigin - self.origin;
1320                         dist_z = 0;
1321                         self.lms_traveled_distance += fabs(vlen(dist));
1322
1323                         if(time > self.lms_nextcheck)
1324                         {
1325                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1326                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1327                                 {
1328                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1329                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1330                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1331                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1332                                 }
1333                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1334                                 self.lms_traveled_distance = 0;
1335                         }
1336                 }
1337
1338                 if (self.button5 && !self.hook.state)
1339                 {
1340                         if (!self.crouch)
1341                         {
1342                                 self.crouch = TRUE;
1343                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1344                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1345                         }
1346                 }
1347                 else
1348                 {
1349                         if (self.crouch)
1350                         {
1351                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1352                                 if (!trace_startsolid)
1353                                 {
1354                                         self.crouch = FALSE;
1355                                         self.view_ofs = PL_VIEW_OFS;
1356                                         setsize (self, PL_MIN, PL_MAX);
1357                                 }
1358                         }
1359                 }
1360
1361                 if(cvar("sv_defaultcharacter") == 1) {
1362                         local string defaultmodel;
1363                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1364
1365                         if (defaultmodel != self.model)
1366                         {
1367                                 m1 = self.mins;
1368                                 m2 = self.maxs;
1369                                 setmodel_lod (self, defaultmodel);
1370                                 setsize (self, m1, m2);
1371                         }
1372
1373                         if (self.skin != cvar("sv_defaultplayerskin"))
1374                                 self.skin = cvar("sv_defaultplayerskin");
1375                 } else {
1376                         if (self.playermodel != self.model)
1377                         {
1378                                 self.playermodel = CheckPlayerModel(self.playermodel);
1379                                 m1 = self.mins;
1380                                 m2 = self.maxs;
1381                                 setmodel_lod (self, self.playermodel);
1382                                 setsize (self, m1, m2);
1383                         }
1384
1385                         if (self.skin != stof(self.playerskin))
1386                                 self.skin = stof(self.playerskin);
1387                 }
1388                 // Savage: Check for nameless players
1389                 if (strlen(self.netname) < 1) {
1390                         self.netname = "Player";
1391                         stuffcmd(self, "name Player\n");
1392                 }
1393
1394                 GrapplingHookFrame();
1395
1396                 W_WeaponFrame();
1397
1398                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1399                 {
1400                         if (cvar("g_minstagib") && self.button3)
1401                         {
1402                                 if (self.jump_interval <= (time + 0.1))
1403                                 {
1404                                         self.jump_interval = time + 1;
1405                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1406                                 }
1407                         }
1408                         else if (self.viewzoom > 0.4)
1409                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1410                 }
1411                 else if (self.viewzoom < 1.0)
1412                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1413
1414
1415                 if (self.button2)
1416                         PlayerJump ();
1417                 else
1418                         self.flags = self.flags | FL_JUMPRELEASED;
1419
1420                 player_powerups();
1421                 player_regen();
1422                 player_anim();
1423
1424                 //self.angles_y=self.v_angle_y + 90;   // temp
1425
1426                 if (self.waterlevel == 2)
1427                         CheckWaterJump ();
1428
1429                 //if (TetrisPreFrame()) return;
1430         } else if(gameover) {
1431                 if (intermission_running)
1432                         IntermissionThink ();   // otherwise a button could be missed between
1433                 return;
1434         } else if(self.classname == "observer") {
1435
1436                 if (self.flags & FL_JUMPRELEASED) {
1437                         if (self.button2 && self.version == cvar("gameversion")) {
1438                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1439                                         self.flags = self.flags & !FL_JUMPRELEASED;
1440                                         self.classname = "player";
1441                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1442                                                 JoinBestTeam(self, 0);
1443                                         if(cvar("g_campaign"))
1444                                                 campaign_bots_may_start = 1;
1445                                         PutClientInServer();
1446                                         if(self.flags & !FL_NOTARGET)
1447                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1448                                         centerprint(self,"");
1449                                         return;
1450                                 } else {
1451                                         self.flags = self.flags & !FL_JUMPRELEASED;
1452                                         stuffcmd(self,"menu_showteamselect\n");
1453                                         return;
1454                                 }
1455                         } else if(self.button0 && self.version == cvar("gameversion")) {
1456                                 self.flags = self.flags & !FL_JUMPRELEASED;
1457                                 if(SpectateNext() == 1) {
1458                                         self.classname = "spectator";
1459                                 }
1460                         }
1461                 } else {
1462                         if (!(self.button0 || self.button2)) {
1463                                 self.flags = self.flags | FL_JUMPRELEASED;
1464                         }
1465                 }
1466                 PrintWelcomeMessage(self);
1467         } else if(self.classname == "spectator") {
1468
1469                 if (self.flags & FL_JUMPRELEASED) {
1470                         if (self.button2 && self.version == cvar("gameversion")) {
1471                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1472                                         self.flags = self.flags & !FL_JUMPRELEASED;
1473                                         self.classname = "player";
1474                                         if(!cvar("g_lms"))
1475                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1476
1477                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1478                                                 JoinBestTeam(self, 0);
1479                                         if(cvar("g_campaign"))
1480                                                 campaign_bots_may_start = 1;
1481                                         PutClientInServer();
1482                                         centerprint(self,"");
1483                                         return;
1484                                 } else {
1485                                         self.flags = self.flags & !FL_JUMPRELEASED;
1486                                         stuffcmd(self,"menu_showteamselect\n");
1487                                         return;
1488                                 }
1489                         } else if(self.button0) {
1490                                 self.flags = self.flags & !FL_JUMPRELEASED;
1491                                 if(SpectateNext() == 1) {
1492                                         self.classname = "spectator";
1493                                 } else {
1494                                         self.classname = "observer";
1495                                         PutClientInServer();
1496                                 }
1497                         } else if (self.button3) {
1498                                 self.flags = self.flags & !FL_JUMPRELEASED;
1499                                 self.classname = "observer";
1500                                 PutClientInServer();
1501                         } else {
1502                                 SpectateUpdate();
1503                         }
1504         } else {
1505                 if (!(self.button0 || self.button3)) {
1506                         self.flags = self.flags | FL_JUMPRELEASED;
1507                 }
1508                 }
1509                 PrintWelcomeMessage(self);
1510         }
1511 }
1512
1513
1514 /*
1515 =============
1516 PlayerPostThink
1517
1518 Called every frame for each client after the physics are run
1519 =============
1520 */
1521 void PlayerPostThink (void)
1522 {
1523         if(self.classname == "player") {
1524                 CheckRules_Player();
1525                 UpdateChatBubble();
1526                 UpdateTeamBubble();
1527                 UpdatePlayerColors();
1528                 if (self.deadflag == DEAD_NO)
1529                 if (self.impulse)
1530                         ImpulseCommands ();
1531                 if (intermission_running)
1532                         return;         // intermission or finale
1533
1534                 //PrintWelcomeMessage(self);
1535                 //if (TetrisPostFrame()) return;
1536         } else if (self.classname == "observer") {
1537                 //do nothing
1538         } else if (self.classname == "spectator") {
1539                 //do nothing
1540         }
1541         Arena_Warmup();
1542 }