data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 float GotoFirstMap()
 135 {
 136         if(cvar("_sv_init"))
 137         {
 138                 cvar_set("_sv_init", "0");
 139                 if(cvar("g_maplist_shuffle"))
 140                         ShuffleMaplist();
 141                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 142                 {
 143                         cvar_set("nextmap", argv(0));
 144
 145                         MapInfo_Enumerate();
 146                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 147
 148                         if(!DoNextMapOverride())
 149                                 GotoNextMap();
 150
 151                         return 1;
 152                 }
 153         }
 154         return 0;
 155 }
 156
 157 void cvar_changes_init()
 158 {
 159         float h;
 160         string k, v, d;
 161         float n, i;
 162
 163         if(cvar_changes)
 164                 strunzone(cvar_changes);
 165         cvar_changes = string_null;
 166
 167         h = buf_create();
 168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 169         n = buf_getsize(h);
 170
 171         for(i = 0; i < n; ++i)
 172         {
 173                 k = bufstr_get(h, i);
 174
 175 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 176 #define BADCVAR(p) if(k == p) continue
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184
 185                 // client
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("g_campaign");
 189                 BADPREFIX("gl_");
 190                 BADPREFIX("joy");
 191                 BADPREFIX("menu_");
 192                 BADPREFIX("net_slist_");
 193                 BADPREFIX("r_");
 194                 BADPREFIX("sbar_");
 195                 BADPREFIX("scr_");
 196                 BADPREFIX("userbind");
 197                 BADPREFIX("v_");
 198                 BADPREFIX("vid_");
 199                 BADCVAR("mod_q3bsp_lightmapmergepower");
 200                 BADCVAR("mod_q3bsp_nolightmaps");
 201
 202                 // private
 203                 BADPREFIX("g_ban_");
 204                 BADPREFIX("g_chat_flood_");
 205                 BADPREFIX("rcon_");
 206                 BADPREFIX("settemp_");
 207                 BADPREFIX("sv_allowdownloads_");
 208                 BADPREFIX("sv_autodemo");
 209                 BADPREFIX("sv_curl_");
 210                 BADPREFIX("sv_eventlog");
 211                 BADPREFIX("sv_logscores_");
 212                 BADPREFIX("sv_master");
 213                 BADCVAR("g_banned_list");
 214                 BADCVAR("log_dest_udp");
 215                 BADCVAR("log_file");
 216                 BADCVAR("net_address");
 217                 BADCVAR("port");
 218                 BADCVAR("savedgamecfg");
 219                 BADCVAR("sv_heartbeatperoid");
 220                 BADCVAR("sv_vote_master_password");
 221                 BADCVAR("sys_colortranslation");
 222                 BADCVAR("sys_specialcharactertranslation");
 223                 BADCVAR("timestamps");
 224
 225                 // mapinfo
 226                 BADCVAR("timelimit");
 227                 BADCVAR("fraglimit");
 228                 BADCVAR("g_arena");
 229                 BADCVAR("g_assault");
 230                 BADCVAR("g_ctf");
 231                 BADCVAR("g_dm");
 232                 BADCVAR("g_domination");
 233                 BADCVAR("g_keyhunt");
 234                 BADCVAR("g_keyhunt_teams");
 235                 BADCVAR("g_onslaught");
 236                 BADCVAR("g_race");
 237                 BADCVAR("g_runematch");
 238                 BADCVAR("g_tdm");
 239                 BADCVAR("teamplay");
 240
 241                 // long
 242                 BADCVAR("hostname");
 243                 BADCVAR("g_maplist");
 244                 BADCVAR("g_maplist_mostrecent");
 245                 BADCVAR("sv_motd");
 246 #undef BADPREFIX
 247 #undef BADCVAR
 248
 249                 v = cvar_string(k);
 250                 d = cvar_defstring(k);
 251                 if(v != d)
 252                 {
 253                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 254                         if(strlen(cvar_changes) > 16384)
 255                         {
 256                                 cvar_changes = "// too many settings have been changed to show them here\n";
 257                                 break;
 258                         }
 259                 }
 260         }
 261         buf_del(h);
 262         if(cvar_changes == "")
 263                 cvar_changes = "// this server runs at default settings\n";
 264         else
 265                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 266         cvar_changes = strzone(cvar_changes);
 267 }
 268
 269 void detect_maptype()
 270 {
 271 #if 0
 272         vector o, v;
 273         float i;
 274
 275         for(;;)
 276         {
 277                 o = world.mins;
 278                 o_x += random() * (world.maxs_x - world.mins_x);
 279                 o_y += random() * (world.maxs_y - world.mins_y);
 280                 o_z += random() * (world.maxs_z - world.mins_z);
 281
 282                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 283                 if(trace_fraction == 1)
 284                         continue;
 285
 286                 v = trace_endpos;
 287
 288                 for(i = 0; i < 64; i += 4)
 289                 {
 290                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 291         if(trace_fraction == 1)
 292                 continue;
 293                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 294                 }
 295
 296                 break;
 297         }
 298 #endif
 299 }
 300
 301 entity randomseed;
 302 float RandomSeed_Send(entity to, float sf)
 303 {
 304         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 305         WriteShort(MSG_ENTITY, self.cnt);
 306 }
 307 void RandomSeed_Think()
 308 {
 309         self.cnt = bound(0, floor(random() * 65536), 65535);
 310         self.nextthink = time + 5;
 311 }
 312 void RandomSeed_Spawn()
 313 {
 314         randomseed = spawn();
 315         randomseed.think = RandomSeed_Think;
 316         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 317
 318         entity oldself;
 319         oldself = self;
 320         self = randomseed;
 321         self.think(); // sets random seed and nextthink
 322         self = oldself;
 323 }
 324
 325 float world_already_spawned;
 326 void RegisterWeapons();
 327 void Nagger_Init();
 328 void ClientInit_Spawn();
 329 void spawnfunc_worldspawn (void)
 330 {
 331         float fd, l, i, j, n;
 332         string s, col;
 333
 334         dprint_load(); // load dprint status from cvar
 335
 336         if(world_already_spawned)
 337                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 338         world_already_spawned = TRUE;
 339
 340         remove = remove_safely; // during spawning, watch what you remove!
 341
 342         if(cvar_string("cvar_check_default") != "bypass")
 343         {
 344                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 345                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code!");
 346
 347                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 348                         error("Config file mismatch! Please update weapons.cfg and weaponsPro.cfg to match the QuakeC code!");
 349         }
 350
 351         compressShortVector_init();
 352
 353         local entity head;
 354         head = nextent(world);
 355         maxclients = 0;
 356         while(head)
 357         {
 358                 ++maxclients;
 359                 head = nextent(head);
 360         }
 361
 362         // needs to be done so early as they would still spawn
 363         RegisterWeapons();
 364
 365         if(GotoFirstMap())
 366         {
 367                 world_initialized = -1; // don't complain
 368                 return;
 369         }
 370
 371         if(sv_cheats)
 372                 ServerProgsDB = db_create();
 373         else
 374                 ServerProgsDB = db_load("server.db");
 375
 376         TemporaryDB = db_create();
 377
 378         /*
 379         TODO sound pack system
 380         // initialize sound pack system
 381         soundpack = cvar_string("g_soundpack");
 382         if(soundpack != "")
 383                 soundpack = strcat(soundpack, "/");
 384         soundpack = strzone(soundpack);
 385         */
 386
 387         // 0 normal
 388         lightstyle(0, "m");
 389
 390         // 1 FLICKER (first variety)
 391         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 392
 393         // 2 SLOW STRONG PULSE
 394         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 395
 396         // 3 CANDLE (first variety)
 397         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 398
 399         // 4 FAST STROBE
 400         lightstyle(4, "mamamamamama");
 401
 402         // 5 GENTLE PULSE 1
 403         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 404
 405         // 6 FLICKER (second variety)
 406         lightstyle(6, "nmonqnmomnmomomno");
 407
 408         // 7 CANDLE (second variety)
 409         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 410
 411         // 8 CANDLE (third variety)
 412         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 413
 414         // 9 SLOW STROBE (fourth variety)
 415         lightstyle(9, "aaaaaaaazzzzzzzz");
 416
 417         // 10 FLUORESCENT FLICKER
 418         lightstyle(10, "mmamammmmammamamaaamammma");
 419
 420         // 11 SLOW PULSE NOT FADE TO BLACK
 421         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 422
 423         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 424
 425         // 63 testing
 426         lightstyle(63, "a");
 427
 428         if(cvar("g_campaign"))
 429                 CampaignPreInit();
 430
 431         InitGameplayMode();
 432         readlevelcvars();
 433         GrappleHookInit();
 434
 435         player_count = 0;
 436         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 437         if(bot_waypoints_for_items == 1)
 438                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 439                         bot_waypoints_for_items = 0;
 440
 441         // for setting by mapinfo
 442         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 443         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 444
 445         precache();
 446
 447         WaypointSprite_Init();
 448
 449         //if (g_domination)
 450         //      dom_init();
 451
 452         GameLogInit(); // prepare everything
 453         if(cvar("sv_eventlog"))
 454         {
 455                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 456                 s = strcat(s, ftos(random()));
 457                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 458                 s = ":gameinfo:mutators:LIST";
 459                 if(cvar("g_grappling_hook"))
 460                         s = strcat(s, ":grappling_hook");
 461                 if(!cvar("g_use_ammunition"))
 462                         s = strcat(s, ":no_use_ammunition");
 463                 if(!cvar("g_pickup_items"))
 464                         s = strcat(s, ":no_pickup_items");
 465                 if(cvar("g_instagib"))
 466                         s = strcat(s, ":instagib");
 467                 if(cvar_string("g_weaponarena") != "0")
 468                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 469                 if(cvar("g_nixnex"))
 470                         s = strcat(s, ":nixnex");
 471                 if(cvar("g_vampire"))
 472                         s = strcat(s, ":vampire");
 473                 if(cvar("g_laserguided_missile"))
 474                         s = strcat(s, ":laserguided_missile");
 475                 if(cvar("g_norecoil"))
 476                         s = strcat(s, ":norecoil");
 477                 if(cvar("g_midair"))
 478                         s = strcat(s, ":midair");
 479                 if(cvar("g_minstagib"))
 480                         s = strcat(s, ":minstagib");
 481                 GameLogEcho(s);
 482                 GameLogEcho(":gameinfo:end");
 483         }
 484
 485         cvar_set("nextmap", "");
 486
 487         SetDefaultAlpha();
 488
 489         if(cvar("g_campaign"))
 490                 CampaignPostInit();
 491
 492         fteqcc_testbugs();
 493
 494         Ban_LoadBans();
 495
 496         //initialise globals related to sv_timeout
 497         sys_ticrate = cvar("sys_ticrate");
 498         orig_slowmo = cvar("slowmo");
 499
 500         MapInfo_Enumerate();
 501         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
 502
 503         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 504         {
 505                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 506                 if(fd != -1)
 507                 {
 508                         while((s = fgets(fd)))
 509                         {
 510                                 l = tokenize_sane(s);
 511                                 if(l < 2)
 512                                         continue;
 513                                 if(argv(0) == "cd")
 514                                 {
 515                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 516                                         print("  cdtrack ", argv(2), "\n");
 517                                 }
 518                                 else if(argv(0) == "fog")
 519                                 {
 520                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 521                                         print("  \"fog\" \"", s, "\"\n");
 522                                 }
 523                                 else if(argv(0) == "set")
 524                                 {
 525                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 526                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 527                                 }
 528                                 else if(argv(0) != "//")
 529                                 {
 530                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 531                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 532                                 }
 533                         }
 534                         fclose(fd);
 535                 }
 536         }
 537
 538         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 539         addstat(STAT_WEAPONS, AS_INT, weapons);
 540         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 541         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 542         Nagger_Init();
 543
 544         next_pingtime = time + 5;
 545         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 546
 547         detect_maptype();
 548
 549         lsmaps_reply = "^7Maps available: ";
 550         for(i = 0, j = 0; i < MapInfo_count; ++i)
 551         {
 552                 if(MapInfo_Get_ByID(i))
 553                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 554                         {
 555                                 if(mod(i, 2))
 556                                         col = "^2";
 557                                 else
 558                                         col = "^3";
 559                                 ++j;
 560                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 561                         }
 562         }
 563         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 564
 565         maplist_reply = "^7Maps in list: ";
 566         n = tokenize_sane(cvar_string("g_maplist"));
 567         for(i = 0, j = 0; i < n; ++i)
 568         {
 569                 if(MapInfo_CheckMap(argv(i)))
 570                 {
 571                         if(mod(j, 2))
 572                                 col = "^2";
 573                         else
 574                                 col = "^3";
 575                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 576                         ++j;
 577                 }
 578         }
 579         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 580
 581         records_reply = strzone(getrecords());
 582
 583         ClientInit_Spawn();
 584         RandomSeed_Spawn();
 585
 586         world_initialized = 1;
 587 }
 588
 589 void spawnfunc_light (void)
 590 {
 591         //makestatic (self); // Who the f___ did that?
 592         remove(self);
 593 }
 594
 595 float TryFile( string pFilename )
 596 {
 597         local float lHandle;
 598         dprint("TryFile(\"", pFilename, "\")\n");
 599         lHandle = fopen( pFilename, FILE_READ );
 600         if( lHandle != -1 ) {
 601                 fclose( lHandle );
 602                 return TRUE;
 603         } else {
 604                 return FALSE;
 605         }
 606 };
 607
 608 string GetGametype()
 609 {
 610         return GametypeNameFromType(game);
 611 }
 612
 613 string getmapname_stored;
 614 string GetMapname()
 615 {
 616         return mapname;
 617 }
 618
 619 float Map_Count, Map_Current;
 620 string Map_Current_Name;
 621
 622 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 623 float GetMaplistPosition()
 624 {
 625         float pos, idx;
 626         string map;
 627
 628         map = GetMapname();
 629         idx = cvar("g_maplist_index");
 630
 631         if(idx >= 0)
 632                 if(idx < Map_Count)
 633                         if(map == argv(idx))
 634                                 return idx;
 635
 636         for(pos = 0; pos < Map_Count; ++pos)
 637                 if(map == argv(pos))
 638                         return pos;
 639
 640         // resume normal maplist rotation if current map is not in g_maplist
 641         return idx;
 642 }
 643
 644 float MapHasRightSize(string map)
 645 {
 646         float fh;
 647         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 648         if(cvar("g_maplist_check_waypoints"))
 649         {
 650                 dprint("checkwp "); dprint(map);
 651                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 652                 if(fh < 0)
 653                 {
 654                         dprint(": no waypoints\n");
 655                         return FALSE;
 656                 }
 657                 dprint(": has waypoints\n");
 658                 fclose(fh);
 659         }
 660
 661         // open map size restriction file
 662         dprint("opensize "); dprint(map);
 663         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 664         if(fh >= 0)
 665         {
 666                 float mapmin, mapmax;
 667                 dprint(": ok, ");
 668                 mapmin = stof(fgets(fh));
 669                 mapmax = stof(fgets(fh));
 670                 fclose(fh);
 671                 if(player_count < mapmin)
 672                 {
 673                         dprint("not enough\n");
 674                         return FALSE;
 675                 }
 676                 if(player_count > mapmax)
 677                 {
 678                         dprint("too many\n");
 679                         return FALSE;
 680                 }
 681                 dprint("right size\n");
 682                 return TRUE;
 683         }
 684         dprint(": not found\n");
 685         return TRUE;
 686 }
 687
 688 string Map_Filename(float position)
 689 {
 690         return strcat("maps/", argv(position), ".bsp");
 691 }
 692
 693 string strwords(string s, float w)
 694 {
 695         float endpos;
 696         for(endpos = 0; w && endpos >= 0; --w)
 697                 endpos = strstrofs(s, " ", endpos + 1);
 698         if(endpos < 0)
 699                 return s;
 700         else
 701                 return substring(s, 0, endpos);
 702 }
 703
 704 float strhasword(string s, string w)
 705 {
 706         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 707 }
 708
 709 void Map_MarkAsRecent(string m)
 710 {
 711         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 712 }
 713
 714 float Map_IsRecent(string m)
 715 {
 716         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 717 }
 718
 719 float Map_Check(float position, float pass)
 720 {
 721         string filename;
 722         string map_next;
 723         map_next = argv(position);
 724         if(pass <= 1)
 725         {
 726                 if(map_next == Map_Current_Name) // same map again in first pass?
 727                         return 0;
 728                 if(Map_IsRecent(map_next))
 729                         return 0;
 730         }
 731         filename = Map_Filename(position);
 732         if(MapInfo_CheckMap(map_next))
 733         {
 734                 if(pass == 2)
 735                         return 1;
 736                 if(MapHasRightSize(map_next))
 737                         return 1;
 738                 return 0;
 739         }
 740         else
 741                 dprint( "Couldn't select '", filename, "'..\n" );
 742
 743         return 0;
 744 }
 745
 746 void Map_Goto_SetStr(string nextmapname)
 747 {
 748         if(getmapname_stored != "")
 749                 strunzone(getmapname_stored);
 750         if(nextmapname == "")
 751                 getmapname_stored = "";
 752         else
 753                 getmapname_stored = strzone(nextmapname);
 754 }
 755
 756 void Map_Goto_SetFloat(float position)
 757 {
 758         cvar_set("g_maplist_index", ftos(position));
 759         Map_Goto_SetStr(argv(position));
 760 }
 761
 762 void GameResetCfg()
 763 {
 764         // settings persist, except...
 765         if(cvar("g_campaign"))
 766                 localcmd("\nexec mutator_reset.cfg\n");
 767         localcmd("\nsettemp_restore\n");
 768 };
 769
 770 void Map_Goto()
 771 {
 772         Map_MarkAsRecent(getmapname_stored);
 773         GameResetCfg();
 774         MapInfo_LoadMap(getmapname_stored);
 775 }
 776
 777 // return codes of map selectors:
 778 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 779 //   -2 = permanent failure
 780 float() MaplistMethod_Iterate = // usual method
 781 {
 782         float pass, i;
 783
 784         for(pass = 1; pass <= 2; ++pass)
 785         {
 786                 for(i = 1; i < Map_Count; ++i)
 787                 {
 788                         float mapindex;
 789                         mapindex = mod(i + Map_Current, Map_Count);
 790                         if(Map_Check(mapindex, pass))
 791                                 return mapindex;
 792                 }
 793         }
 794         return -1;
 795 }
 796
 797 float() MaplistMethod_Repeat = // fallback method
 798 {
 799         if(Map_Check(Map_Current, 2))
 800                 return Map_Current;
 801         return -2;
 802 }
 803
 804 float() MaplistMethod_Random = // random map selection
 805 {
 806         float i, imax;
 807
 808         imax = 42;
 809
 810         for(i = 0; i <= imax; ++i)
 811         {
 812                 float mapindex;
 813                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 814                 if(Map_Check(mapindex, 1))
 815                         return mapindex;
 816         }
 817         return -1;
 818 }
 819
 820 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 821 // the exponent sets a bias on the map selection:
 822 // the higher the exponent, the less likely "shortly repeated" same maps are
 823 {
 824         float i, j, imax, insertpos;
 825
 826         imax = 42;
 827
 828         for(i = 0; i <= imax; ++i)
 829         {
 830                 string newlist;
 831
 832                 // now reinsert this at another position
 833                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 834                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 835                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 836                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 837
 838                 // insert the current map there
 839                 newlist = "";
 840                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 841                         newlist = strcat(newlist, " ", argv(j));
 842                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 843                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 844                         newlist = strcat(newlist, " ", argv(j));
 845                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 846                 cvar_set("g_maplist", newlist);
 847                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 848
 849                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 850                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 851                 if(Map_Check(Map_Current, 1))
 852                         return Map_Current;
 853         }
 854         return -1;
 855 }
 856
 857 void Maplist_Init()
 858 {
 859         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 860         if(Map_Count == 0)
 861         {
 862                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 863                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 864                 if(cvar("g_maplist_shuffle"))
 865                         ShuffleMaplist();
 866                 localcmd("\nmenu_cmd sync\n");
 867                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 868         }
 869         if(Map_Count == 0)
 870                 error("empty maplist, cannot select a new map");
 871         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 872
 873         if(Map_Current_Name)
 874                 strunzone(Map_Current_Name);
 875         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 876         // this may or may not be correct, but who cares, in the worst case a map
 877         // isn't chosen in the first pass that should have been
 878 }
 879
 880 string GetNextMap()
 881 {
 882         float nextMap;
 883
 884         Maplist_Init();
 885         nextMap = -1;
 886
 887         if(nextMap == -1)
 888                 if(cvar("g_maplist_shuffle") > 0)
 889                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 890
 891         if(nextMap == -1)
 892                 if(cvar("g_maplist_selectrandom"))
 893                         nextMap = MaplistMethod_Random();
 894
 895         if(nextMap == -1)
 896                 nextMap = MaplistMethod_Iterate();
 897
 898         if(nextMap == -1)
 899                 nextMap = MaplistMethod_Repeat();
 900
 901         if(nextMap >= 0)
 902         {
 903                 Map_Goto_SetFloat(nextMap);
 904                 return getmapname_stored;
 905         }
 906
 907         return "";
 908 };
 909
 910 float DoNextMapOverride()
 911 {
 912         if(cvar("g_campaign"))
 913         {
 914                 CampaignPostIntermission();
 915                 alreadychangedlevel = TRUE;
 916                 return TRUE;
 917         }
 918         if(cvar("quit_when_empty"))
 919         {
 920                 if(player_count <= currentbots)
 921                 {
 922                         localcmd("quit\n");
 923                         alreadychangedlevel = TRUE;
 924                         return TRUE;
 925                 }
 926         }
 927         if(cvar_string("quit_and_redirect") != "")
 928         {
 929                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 930                 alreadychangedlevel = TRUE;
 931                 return TRUE;
 932         }
 933         if (cvar("samelevel")) // if samelevel is set, stay on same level
 934         {
 935                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 936                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 937                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 938                 localcmd("restart\n");
 939                 //changelevel (mapname);
 940                 alreadychangedlevel = TRUE;
 941                 return TRUE;
 942         }
 943         if(cvar_string("nextmap") != "")
 944                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 945                 {
 946                         Map_Goto_SetStr(cvar_string("nextmap"));
 947                         Map_Goto();
 948                         alreadychangedlevel = TRUE;
 949                         return TRUE;
 950                 }
 951         if(cvar("lastlevel"))
 952         {
 953                 GameResetCfg();
 954                 localcmd("set lastlevel 0\ntogglemenu\n");
 955                 alreadychangedlevel = TRUE;
 956                 return TRUE;
 957         }
 958         return FALSE;
 959 };
 960
 961 void GotoNextMap()
 962 {
 963         //local string nextmap;
 964         //local float n, nummaps;
 965         //local string s;
 966         if (alreadychangedlevel)
 967                 return;
 968         alreadychangedlevel = TRUE;
 969
 970         {
 971                 string nextMap;
 972                 float allowReset;
 973
 974                 for(allowReset = 1; allowReset >= 0; --allowReset)
 975                 {
 976                         nextMap = GetNextMap();
 977                         if(nextMap != "")
 978                                 break;
 979
 980                         if(allowReset)
 981                         {
 982                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 983                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 984                                 if(cvar("g_maplist_shuffle"))
 985                                         ShuffleMaplist();
 986                                 localcmd("\nmenu_cmd sync\n");
 987                         }
 988                         else
 989                         {
 990                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 991                         }
 992                 }
 993                 Map_Goto();
 994         }
 995 };
 996
 997
 998 /*
 999 ============
1000 IntermissionThink
1001
1002 When the player presses attack or jump, change to the next level
1003 ============
1004 */
1005 .float autoscreenshot;
1006 void() MapVote_Start;
1007 void() MapVote_Think;
1008 float mapvote_initialized;
1009 void IntermissionThink()
1010 {
1011         FixIntermissionClient(self);
1012
1013         if(cvar("sv_autoscreenshot"))
1014         if(self.autoscreenshot > 0)
1015         if(time > self.autoscreenshot)
1016         {
1017                 self.autoscreenshot = -1;
1018                 if(clienttype(self) == CLIENTTYPE_REAL)
1019                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1020                 return;
1021         }
1022
1023         if (time < intermission_exittime)
1024                 return;
1025
1026         if(!mapvote_initialized)
1027                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1028                         return;
1029
1030         MapVote_Start();
1031 };
1032
1033 /*
1034 ============
1035 FindIntermission
1036
1037 Returns the entity to view from
1038 ============
1039 */
1040 /*
1041 entity FindIntermission()
1042 {
1043         local   entity spot;
1044         local   float cyc;
1045
1046 // look for info_intermission first
1047         spot = find (world, classname, "info_intermission");
1048         if (spot)
1049         {       // pick a random one
1050                 cyc = random() * 4;
1051                 while (cyc > 1)
1052                 {
1053                         spot = find (spot, classname, "info_intermission");
1054                         if (!spot)
1055                                 spot = find (spot, classname, "info_intermission");
1056                         cyc = cyc - 1;
1057                 }
1058                 return spot;
1059         }
1060
1061 // then look for the start position
1062         spot = find (world, classname, "info_player_start");
1063         if (spot)
1064                 return spot;
1065
1066 // testinfo_player_start is only found in regioned levels
1067         spot = find (world, classname, "testplayerstart");
1068         if (spot)
1069                 return spot;
1070
1071 // then look for the start position
1072         spot = find (world, classname, "info_player_deathmatch");
1073         if (spot)
1074                 return spot;
1075
1076         //objerror ("FindIntermission: no spot");
1077         return world;
1078 };
1079 */
1080
1081 /*
1082 ===============================================================================
1083
1084 RULES
1085
1086 ===============================================================================
1087 */
1088
1089 void DumpStats(float final)
1090 {
1091         local float file;
1092         local string s;
1093         local float to_console;
1094         local float to_eventlog;
1095         local float to_file;
1096         local float i;
1097
1098         to_console = cvar("sv_logscores_console");
1099         to_eventlog = cvar("sv_eventlog");
1100         to_file = cvar("sv_logscores_file");
1101
1102         if(!final)
1103         {
1104                 to_console = TRUE; // always print printstats replies
1105                 to_eventlog = FALSE; // but never print them to the event log
1106         }
1107
1108         if(to_eventlog)
1109                 if(cvar("sv_eventlog_console"))
1110                         to_console = FALSE; // otherwise we get the output twice
1111
1112         if(final)
1113                 s = ":scores:";
1114         else
1115                 s = ":status:";
1116         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1117
1118         if(to_console)
1119                 print(s, "\n");
1120         if(to_eventlog)
1121                 GameLogEcho(s);
1122         if(to_file)
1123         {
1124                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1125                 if(file == -1)
1126                         to_file = FALSE;
1127                 else
1128                         fputs(file, strcat(s, "\n"));
1129         }
1130
1131         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1132         if(to_console)
1133                 print(s, "\n");
1134         if(to_eventlog)
1135                 GameLogEcho(s);
1136         if(to_file)
1137                 fputs(file, strcat(s, "\n"));
1138
1139         FOR_EACH_CLIENT(other)
1140         {
1141                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1142                 {
1143                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1144                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1145                         if(other.classname == "player" || g_arena || g_lms)
1146                                 s = strcat(s, ftos(other.team), ":");
1147                         else
1148                                 s = strcat(s, "spectator:");
1149
1150                         if(to_console)
1151                                 print(s, other.netname, "\n");
1152                         if(to_eventlog)
1153                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1154                         if(to_file)
1155                                 fputs(file, strcat(s, other.netname, "\n"));
1156                 }
1157         }
1158
1159         if(teamplay)
1160         {
1161                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1162                 if(to_console)
1163                         print(s, "\n");
1164                 if(to_eventlog)
1165                         GameLogEcho(s);
1166                 if(to_file)
1167                         fputs(file, strcat(s, "\n"));
1168
1169                 for(i = 1; i < 16; ++i)
1170                 {
1171                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1172                         s = strcat(s, ":", ftos(i));
1173                         if(to_console)
1174                                 print(s, "\n");
1175                         if(to_eventlog)
1176                                 GameLogEcho(s);
1177                         if(to_file)
1178                                 fputs(file, strcat(s, "\n"));
1179                 }
1180         }
1181
1182         if(to_console)
1183                 print(":end\n");
1184         if(to_eventlog)
1185                 GameLogEcho(":end");
1186         if(to_file)
1187         {
1188                 fputs(file, ":end\n");
1189                 fclose(file);
1190         }
1191 }
1192
1193 void FixIntermissionClient(entity e)
1194 {
1195         string s;
1196         if(!e.autoscreenshot) // initial call
1197         {
1198                 e.angles = e.v_angle;
1199                 e.angles_x = -e.angles_x;
1200                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1201                 e.health = -2342;
1202                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1203                 e.solid = SOLID_NOT;
1204                 e.movetype = MOVETYPE_NONE;
1205                 e.takedamage = DAMAGE_NO;
1206                 if(e.weaponentity)
1207                         e.weaponentity.effects = EF_NODRAW;
1208                 if(clienttype(e) == CLIENTTYPE_REAL)
1209                 {
1210                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1211                         s = cvar_string("sv_intermission_cdtrack");
1212                         if(s != "")
1213                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1214                         msg_entity = e;
1215                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1216                 }
1217         }
1218
1219         //e.velocity = '0 0 0';
1220         //e.fixangle = TRUE;
1221
1222         // TODO halt weapon animation
1223 }
1224
1225
1226 /*
1227 go to the next level for deathmatch
1228 only called if a time or frag limit has expired
1229 */
1230 void NextLevel()
1231 {
1232         float minTotalFrags;
1233         float maxTotalFrags;
1234         float score;
1235         float f;
1236
1237         gameover = TRUE;
1238
1239         intermission_running = 1;
1240
1241 // enforce a wait time before allowing changelevel
1242         if(player_count > 0)
1243                 intermission_exittime = time + cvar("sv_mapchange_delay");
1244         else
1245                 intermission_exittime = -1;
1246
1247         /*
1248         WriteByte (MSG_ALL, SVC_CDTRACK);
1249         WriteByte (MSG_ALL, 3);
1250         WriteByte (MSG_ALL, 3);
1251         // done in FixIntermission
1252         */
1253
1254         //pos = FindIntermission ();
1255
1256         VoteReset();
1257
1258         DumpStats(TRUE);
1259
1260         if(cvar("sv_eventlog"))
1261                 GameLogEcho(":gameover");
1262
1263         GameLogClose();
1264
1265         FOR_EACH_CLIENT(other)
1266         {
1267                 FixIntermissionClient(other);
1268
1269                 if(other.winning)
1270                         bprint(other.netname, " ^7wins.\n");
1271         }
1272
1273         minTotalFrags = 0;
1274         maxTotalFrags = 0;
1275         FOR_EACH_PLAYER(other)
1276         {
1277                 if(maxTotalFrags < other.totalfrags)
1278                         maxTotalFrags = other.totalfrags;
1279                 if(minTotalFrags > other.totalfrags)
1280                         minTotalFrags = other.totalfrags;
1281         }
1282
1283         if(!currentbots)
1284         {
1285                 FOR_EACH_PLAYER(other)
1286                 {
1287                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1288                         f = bound(0, other.play_time / max(time, 1), 1);
1289                         // store some statistics?
1290                 }
1291         }
1292
1293         if(cvar("g_campaign"))
1294                 CampaignPreIntermission();
1295
1296         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1297 };
1298
1299 /*
1300 ============
1301 CheckRules_Player
1302
1303 Exit deathmatch games upon conditions
1304 ============
1305 */
1306 void CheckRules_Player()
1307 {
1308         if (gameover)   // someone else quit the game already
1309                 return;
1310
1311         if(self.deadflag == DEAD_NO)
1312                 self.play_time += frametime;
1313
1314         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1315         //   (div0: and that in CheckRules_World please)
1316 };
1317
1318 float checkrules_oneminutewarning;
1319
1320 float checkrules_equality;
1321 float checkrules_overtimewarning;
1322 float checkrules_overtimeend;
1323
1324 void InitiateOvertime()
1325 {
1326         if(!checkrules_overtimeend)
1327                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1328 }
1329
1330 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1331 float WINNING_YES = 1; // winner found
1332 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1333 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1334
1335 float GetWinningCode(float fraglimitreached, float equality)
1336 {
1337         if(equality)
1338                 if(fraglimitreached)
1339                         return WINNING_STARTOVERTIME;
1340                 else
1341                         return WINNING_NEVER;
1342         else
1343                 if(fraglimitreached)
1344                         return WINNING_YES;
1345                 else
1346                         return WINNING_NO;
1347 }
1348
1349 // set the .winning flag for exactly those players with a given field value
1350 void SetWinners(.float field, float value)
1351 {
1352         entity head;
1353         FOR_EACH_PLAYER(head)
1354                 head.winning = (head.field == value);
1355 }
1356
1357 // set the .winning flag for those players with a given field value
1358 void AddWinners(.float field, float value)
1359 {
1360         entity head;
1361         FOR_EACH_PLAYER(head)
1362                 if(head.field == value)
1363                         head.winning = 1;
1364 }
1365
1366 // clear the .winning flags
1367 void ClearWinners(void)
1368 {
1369         entity head;
1370         FOR_EACH_PLAYER(head)
1371                 head.winning = 0;
1372 }
1373
1374 // Onslaught winning condition:
1375 // game terminates if only one team has a working generator (or none)
1376 float WinningCondition_Onslaught()
1377 {
1378         entity head;
1379         local float t1, t2, t3, t4;
1380
1381         WinningConditionHelper(); // set worldstatus
1382
1383         // first check if the game has ended
1384         t1 = t2 = t3 = t4 = 0;
1385         head = find(world, classname, "onslaught_generator");
1386         while (head)
1387         {
1388                 if (head.health > 0)
1389                 {
1390                         if (head.team == COLOR_TEAM1) t1 = 1;
1391                         if (head.team == COLOR_TEAM2) t2 = 1;
1392                         if (head.team == COLOR_TEAM3) t3 = 1;
1393                         if (head.team == COLOR_TEAM4) t4 = 1;
1394                 }
1395                 head = find(head, classname, "onslaught_generator");
1396         }
1397         if (t1 + t2 + t3 + t4 < 2)
1398         {
1399                 // game over, only one team remains (or none)
1400                 ClearWinners();
1401                 if (t1) SetWinners(team, COLOR_TEAM1);
1402                 if (t2) SetWinners(team, COLOR_TEAM2);
1403                 if (t3) SetWinners(team, COLOR_TEAM3);
1404                 if (t4) SetWinners(team, COLOR_TEAM4);
1405                 dprint("Have a winner, ending game.\n");
1406                 return WINNING_YES;
1407         }
1408
1409         // Two or more teams remain
1410         return WINNING_NO;
1411 }
1412
1413 float LMS_NewPlayerLives()
1414 {
1415         float fl;
1416         fl = cvar("fraglimit");
1417         if(fl == 0)
1418                 fl = 999;
1419
1420         // first player has left the game for dying too much? Nobody else can get in.
1421         if(lms_lowest_lives < 1)
1422                 return 0;
1423
1424         if(!cvar("g_lms_join_anytime"))
1425                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1426                         return 0;
1427
1428         return bound(1, lms_lowest_lives, fl);
1429 }
1430
1431 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1432 // they win. Otherwise the defending team wins once the timelimit passes.
1433 void assault_new_round();
1434 float WinningCondition_Assault()
1435 {
1436         local float status;
1437
1438         WinningConditionHelper(); // set worldstatus
1439
1440         status = WINNING_NO;
1441         // as the timelimit has not yet passed just assume the defending team will win
1442         if(assault_attacker_team == COLOR_TEAM1)
1443         {
1444                 SetWinners(team, COLOR_TEAM2);
1445         }
1446         else
1447         {
1448                 SetWinners(team, COLOR_TEAM1);
1449         }
1450
1451         local entity ent;
1452         ent = find(world, classname, "target_assault_roundend");
1453         if(ent)
1454         {
1455                 if(ent.winning) // round end has been triggered by attacking team
1456                 {
1457                         bprint("ASSAULT: round completed...\n");
1458                         SetWinners(team, assault_attacker_team);
1459
1460                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1461
1462                         if(ent.cnt == 1) // this was the second round
1463                         {
1464                                 status = WINNING_YES;
1465                         }
1466                         else
1467                         {
1468                                 local entity oldself;
1469                                 oldself = self;
1470                                 self = ent;
1471                                 assault_new_round();
1472                                 self = oldself;
1473                         }
1474                 }
1475         }
1476
1477         return status;
1478 }
1479
1480 // LMS winning condition: game terminates if and only if there's at most one
1481 // one player who's living lives. Top two scores being equal cancels the time
1482 // limit.
1483 float WinningCondition_LMS()
1484 {
1485         entity head, head2;
1486         float have_player;
1487         float have_players;
1488         float l;
1489
1490         have_player = FALSE;
1491         have_players = FALSE;
1492         l = LMS_NewPlayerLives();
1493
1494         head = find(world, classname, "player");
1495         if(head)
1496                 have_player = TRUE;
1497         head2 = find(head, classname, "player");
1498         if(head2)
1499                 have_players = TRUE;
1500
1501         if(have_player)
1502         {
1503                 // we have at least one player
1504                 if(have_players)
1505                 {
1506                         // two or more active players - continue with the game
1507                 }
1508                 else
1509                 {
1510                         // exactly one player?
1511
1512                         ClearWinners();
1513                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1514
1515                         if(l)
1516                         {
1517                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1518                                 return WINNING_NO;
1519                         }
1520                         else
1521                         {
1522                                 // a winner!
1523                                 // and assign him his first place
1524                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1525                                 return WINNING_YES;
1526                         }
1527                 }
1528         }
1529         else
1530         {
1531                 // nobody is playing at all...
1532                 if(l)
1533                 {
1534                         // wait for players...
1535                 }
1536                 else
1537                 {
1538                         // SNAFU (maybe a draw game?)
1539                         ClearWinners();
1540                         dprint("No players, ending game.\n");
1541                         return WINNING_YES;
1542                 }
1543         }
1544
1545         // When we get here, we have at least two players who are actually LIVING,
1546         // now check if the top two players have equal score.
1547         WinningConditionHelper();
1548
1549         ClearWinners();
1550         if(WinningConditionHelper_winner)
1551                 WinningConditionHelper_winner.winning = TRUE;
1552         if(WinningConditionHelper_equality)
1553                 return WINNING_NEVER;
1554
1555         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1556         return WINNING_NO;
1557 }
1558
1559 void ShuffleMaplist()
1560 {
1561         string result;
1562         float start;
1563         float litems;
1564         float selected;
1565         float i;
1566
1567         result = cvar_string("g_maplist");
1568         litems = tokenizebyseparator(result, " ");
1569
1570         for(start = 0; start < litems - 1; ++start)
1571         {
1572                 result = "";
1573
1574                 // select a random item
1575                 selected = floor(random() * (litems - start) + start);
1576
1577                 // shift this item to the place start
1578                 for(i = 0; i < start; ++i)
1579                         result = strcat(result, " ", argv(i));
1580                 result = strcat(result, " ", argv(selected));
1581                 for(i = start; i < litems; ++i)
1582                         if(i != selected)
1583                                 result = strcat(result, " ", argv(i));
1584                 result = substring(result, 1, strlen(result) - 1);
1585
1586                 litems = tokenizebyseparator(result, " ");
1587
1588                 //dprint(result, "\n");
1589         }
1590
1591         cvar_set("g_maplist", result);
1592 }
1593
1594 float leaderfrags;
1595 float WinningCondition_Scores(float limit)
1596 {
1597         // TODO make everything use THIS winning condition (except LMS)
1598         WinningConditionHelper();
1599
1600         if(teams_matter)
1601         {
1602                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1603                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1604                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1605                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1606         }
1607
1608         ClearWinners();
1609         if(WinningConditionHelper_winner)
1610                 WinningConditionHelper_winner.winning = 1;
1611         if(WinningConditionHelper_winnerteam >= 0)
1612                 SetWinners(team, WinningConditionHelper_winnerteam);
1613
1614         if(WinningConditionHelper_lowerisbetter)
1615         {
1616                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1617                 limit = -limit;
1618         }
1619
1620         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1621         // these modes always score in increments of 1, thus this makes sense
1622         {
1623                 if(leaderfrags != WinningConditionHelper_topscore)
1624                 {
1625                         leaderfrags = WinningConditionHelper_topscore;
1626
1627                         if (limit)
1628                         if (leaderfrags == limit - 1)
1629                                 play2all("announcer/robotic/1fragleft.wav");
1630                         else if (leaderfrags == limit - 2)
1631                                 play2all("announcer/robotic/2fragsleft.wav");
1632                         else if (leaderfrags == limit - 3)
1633                                 play2all("announcer/robotic/3fragsleft.wav");
1634                 }
1635         }
1636
1637         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1638 }
1639
1640 float WinningCondition_Race(float fraglimit)
1641 {
1642         float wc;
1643         entity p;
1644         wc = WinningCondition_Scores(fraglimit);
1645
1646         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1647         if(wc == WINNING_YES || wc == WINNING_STARTOVERTIME)
1648         // do NOT support equality when the laps are all raced!
1649         {
1650                 FOR_EACH_PLAYER(p)
1651                         if not(p.race_completed)
1652                                 return WINNING_STARTOVERTIME;
1653                 return WINNING_YES;
1654         }
1655         return wc;
1656 }
1657
1658 void ReadyRestart();
1659 float WinningCondition_QualifyingThenRace(float limit)
1660 {
1661         float wc;
1662         wc = WinningCondition_Scores(limit);
1663
1664         // NEVER initiate overtime
1665         if(wc == WINNING_YES || wc == WINNING_STARTOVERTIME)
1666         {
1667                 return WINNING_YES;
1668         }
1669
1670         return wc;
1671 }
1672
1673 float WinningCondition_RanOutOfSpawns()
1674 {
1675         entity head;
1676
1677         if(!have_team_spawns)
1678                 return WINNING_NO;
1679
1680         if(!some_spawn_has_been_used)
1681                 return WINNING_NO;
1682
1683         team1_score = team2_score = team3_score = team4_score = 0;
1684
1685         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1686         {
1687                 if(head.team == COLOR_TEAM1)
1688                         team1_score = 1;
1689                 else if(head.team == COLOR_TEAM2)
1690                         team2_score = 1;
1691                 else if(head.team == COLOR_TEAM3)
1692                         team3_score = 1;
1693                 else if(head.team == COLOR_TEAM4)
1694                         team4_score = 1;
1695         }
1696
1697         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1698         {
1699                 if(head.team == COLOR_TEAM1)
1700                         team1_score = 1;
1701                 else if(head.team == COLOR_TEAM2)
1702                         team2_score = 1;
1703                 else if(head.team == COLOR_TEAM3)
1704                         team3_score = 1;
1705                 else if(head.team == COLOR_TEAM4)
1706                         team4_score = 1;
1707         }
1708
1709         ClearWinners();
1710         if(team1_score + team2_score + team3_score + team4_score == 0)
1711         {
1712                 checkrules_equality = TRUE;
1713                 return WINNING_YES;
1714         }
1715         else if(team1_score + team2_score + team3_score + team4_score == 1)
1716         {
1717                 float t, i;
1718                 if(team1_score) t = COLOR_TEAM1;
1719                 if(team2_score) t = COLOR_TEAM2;
1720                 if(team3_score) t = COLOR_TEAM3;
1721                 if(team4_score) t = COLOR_TEAM4;
1722                 CheckAllowedTeams(world);
1723                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1724                 {
1725                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1726                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1727                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1728                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1729                 }
1730
1731                 AddWinners(team, t);
1732                 return WINNING_YES;
1733         }
1734         else
1735                 return WINNING_NO;
1736 }
1737
1738 /*
1739 ============
1740 CheckRules_World
1741
1742 Exit deathmatch games upon conditions
1743 ============
1744 */
1745 void CheckRules_World()
1746 {
1747         local float status;
1748         local float timelimit;
1749         local float fraglimit;
1750
1751         VoteThink();
1752         MapVote_Think();
1753
1754         SetDefaultAlpha();
1755
1756         /*
1757         MapVote_Think should now do that part
1758         if (intermission_running)
1759                 if (time >= intermission_exittime + 60)
1760                 {
1761                         if(!DoNextMapOverride())
1762                                 GotoNextMap();
1763                         return;
1764                 }
1765         */
1766
1767         if (gameover)   // someone else quit the game already
1768         {
1769                 if(player_count == 0) // Nobody there? Then let's go to the next map
1770                         MapVote_Start();
1771                         // this will actually check the player count in the next frame
1772                         // again, but this shouldn't hurt
1773                 return;
1774         }
1775
1776         timelimit = cvar("timelimit") * 60;
1777         fraglimit = cvar("fraglimit");
1778
1779         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1780         {
1781                 if(timelimit > 0)
1782                         timelimit = 0; // timelimit is not made for warmup
1783                 if(fraglimit > 0)
1784                         fraglimit = 0; // no fraglimit for now
1785         }
1786
1787         if(timelimit > 0)
1788         {
1789                 timelimit += game_starttime;
1790         }
1791         else if (timelimit < 0)
1792         {
1793                 // endmatch
1794                 NextLevel();
1795                 return;
1796         }
1797
1798         if(checkrules_overtimeend)
1799         {
1800                 if(!checkrules_overtimewarning)
1801                 {
1802                         checkrules_overtimewarning = TRUE;
1803                         //announceall("announcer/robotic/1minuteremains.wav");
1804                         if(g_race && !g_race_qualifying)
1805                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1806                         else
1807                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1808                 }
1809         }
1810         else
1811         {
1812                 if (timelimit && time >= timelimit)
1813                 {
1814                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1815                         {
1816                                 float totalplayers;
1817                                 float playerswithlaps;
1818                                 float readyplayers;
1819                                 entity head;
1820                                 totalplayers = playerswithlaps = readyplayers = 0;
1821                                 FOR_EACH_PLAYER(head)
1822                                 {
1823                                         ++totalplayers;
1824                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1825                                                 ++playerswithlaps;
1826                                         if(head.ready)
1827                                                 ++readyplayers;
1828                                 }
1829
1830                                 // at least 2/3 of the players have completed a lap: start the RACE
1831                                 // otherwise, the players should end the qualifying on their own
1832                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1833                                 {
1834                                         checkrules_overtimeend = 0;
1835                                         ReadyRestart(); // go to race
1836                                 }
1837                                 else
1838                                         InitiateOvertime();
1839                         }
1840                         else
1841                                 InitiateOvertime();
1842                 }
1843         }
1844
1845         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1846         {
1847                 NextLevel();
1848                 return;
1849         }
1850
1851         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1852         {
1853                 checkrules_oneminutewarning = TRUE;
1854                 play2all("announcer/robotic/1minuteremains.wav");
1855         }
1856
1857         status = WinningCondition_RanOutOfSpawns();
1858         if(status == WINNING_YES)
1859         {
1860                 bprint("Hey! Someone ran out of spawns!\n");
1861         }
1862         else if(g_race && !g_race_qualifying && timelimit >= 0)
1863         {
1864                 status = WinningCondition_Race(fraglimit);
1865         }
1866         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1867         {
1868                 status = WinningCondition_QualifyingThenRace(fraglimit);
1869         }
1870         else if(g_assault)
1871         {
1872                 status = WinningCondition_Assault(); // TODO remove this?
1873         }
1874         else if(g_lms)
1875         {
1876                 status = WinningCondition_LMS();
1877         }
1878         else if (g_onslaught)
1879         {
1880                 status = WinningCondition_Onslaught(); // TODO remove this?
1881         }
1882         else
1883         {
1884                 status = WinningCondition_Scores(fraglimit);
1885         }
1886
1887         if(status == WINNING_STARTOVERTIME)
1888         {
1889                 status = WINNING_NEVER;
1890                 InitiateOvertime();
1891         }
1892
1893         if(status == WINNING_NEVER)
1894                 // equality cases! Nobody wins if the overtime ends in a draw.
1895                 ClearWinners();
1896
1897         if(checkrules_overtimeend)
1898                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1899                         status = WINNING_YES;
1900
1901         if(status == WINNING_YES)
1902                 NextLevel();
1903 };
1904
1905 float mapvote_nextthink;
1906 float mapvote_initialized;
1907 float mapvote_keeptwotime;
1908 float mapvote_timeout;
1909 string mapvote_message;
1910 string mapvote_screenshot_dir;
1911
1912 float mapvote_count;
1913 float mapvote_count_real;
1914 string mapvote_maps[MAPVOTE_COUNT];
1915 float mapvote_maps_suggested[MAPVOTE_COUNT];
1916 string mapvote_suggestions[MAPVOTE_COUNT];
1917 float mapvote_suggestion_ptr;
1918 float mapvote_maxlen;
1919 float mapvote_voters;
1920 float mapvote_votes[MAPVOTE_COUNT];
1921 float mapvote_run;
1922 float mapvote_detail;
1923 float mapvote_abstain;
1924 .float mapvote;
1925
1926 void MapVote_ClearAllVotes()
1927 {
1928         FOR_EACH_CLIENT(other)
1929                 other.mapvote = 0;
1930 }
1931
1932 string MapVote_Suggest(string m)
1933 {
1934         float i;
1935         if(m == "")
1936                 return "That's not how to use this command.";
1937         if(!cvar("g_maplist_votable_suggestions"))
1938                 return "Suggestions are not accepted on this server.";
1939         if(mapvote_initialized)
1940                 return "Can't suggest - voting is already in progress!";
1941         m = MapInfo_FixName(m);
1942         if(!m)
1943                 return "The map you suggested is not available on this server.";
1944         if(!cvar("g_maplist_votable_override_mostrecent"))
1945                 if(Map_IsRecent(m))
1946                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1947
1948         if(!MapInfo_CheckMap(m))
1949                 return "The map you suggested does not support the current game mode.";
1950         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1951                 if(mapvote_suggestions[i] == m)
1952                         return "This map was already suggested.";
1953         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1954         {
1955                 i = floor(random() * mapvote_suggestion_ptr);
1956         }
1957         else
1958         {
1959                 i = mapvote_suggestion_ptr;
1960                 mapvote_suggestion_ptr += 1;
1961         }
1962         if(mapvote_suggestions[i] != "")
1963                 strunzone(mapvote_suggestions[i]);
1964         mapvote_suggestions[i] = strzone(m);
1965         if(cvar("sv_eventlog"))
1966                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
1967         return strcat("Suggestion of ", m, " accepted.");
1968 }
1969
1970 void MapVote_AddVotable(string nextMap, float isSuggestion)
1971 {
1972         float j;
1973         if(nextMap == "")
1974                 return;
1975         for(j = 0; j < mapvote_count; ++j)
1976                 if(mapvote_maps[j] == nextMap)
1977                         return;
1978         if(strlen(nextMap) > mapvote_maxlen)
1979                 mapvote_maxlen = strlen(nextMap);
1980         mapvote_maps[mapvote_count] = strzone(nextMap);
1981         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1982         mapvote_count += 1;
1983 }
1984
1985 void MapVote_Spawn();
1986 void MapVote_Init()
1987 {
1988         float i;
1989         float nmax, smax;
1990
1991         MapVote_ClearAllVotes();
1992
1993         mapvote_count = 0;
1994         mapvote_detail = !cvar("g_maplist_votable_nodetail");
1995         mapvote_abstain = cvar("g_maplist_votable_abstain");
1996
1997         if(mapvote_abstain)
1998                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
1999         else
2000                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2001         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2002
2003         if(mapvote_suggestion_ptr)
2004                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2005                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2006
2007         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2008                 MapVote_AddVotable(GetNextMap(), FALSE);
2009
2010         if(mapvote_count == 0)
2011         {
2012                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2013                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
2014                 if(cvar("g_maplist_shuffle"))
2015                         ShuffleMaplist();
2016                 localcmd("\nmenu_cmd sync\n");
2017                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2018                         MapVote_AddVotable(GetNextMap(), FALSE);
2019         }
2020
2021         mapvote_count_real = mapvote_count;
2022         if(mapvote_abstain)
2023                 MapVote_AddVotable("don't care", 0);
2024
2025         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2026
2027         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2028         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2029         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2030                 mapvote_keeptwotime = 0;
2031         mapvote_message = "Choose a map and press its key!";
2032
2033         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2034         if(mapvote_screenshot_dir == "")
2035                 mapvote_screenshot_dir = "maps";
2036         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2037
2038         MapVote_Spawn();
2039 }
2040
2041 void MapVote_SendPicture(float id)
2042 {
2043         msg_entity = self;
2044         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2045         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2046         WriteByte(MSG_ONE, id);
2047         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2048 }
2049
2050 float GameCommand_MapVote(string cmd)
2051 {
2052         if(!intermission_running)
2053                 return FALSE;
2054
2055         if(cmd == "mv_getpic")
2056         {
2057                 MapVote_SendPicture(stof(argv(1)));
2058                 return TRUE;
2059         }
2060
2061         return FALSE;
2062 }
2063
2064 float MapVote_GetMapMask()
2065 {
2066         float mask, i, power;
2067         mask = 0;
2068         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2069                 if(mapvote_maps[i] != "")
2070                         mask |= power;
2071         return mask;
2072 }
2073
2074 entity mapvote_ent;
2075 float MapVote_SendEntity(entity to, float sf)
2076 {
2077         string mapfile, pakfile;
2078         float i, o;
2079
2080         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2081         WriteByte(MSG_ENTITY, sf);
2082
2083         if(sf & 1)
2084         {
2085                 // flag 1 == initialization
2086                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2087                 WriteByte(MSG_ENTITY, mapvote_count);
2088                 WriteByte(MSG_ENTITY, mapvote_abstain);
2089                 WriteByte(MSG_ENTITY, mapvote_detail);
2090                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2091                 if(mapvote_count <= 8)
2092                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2093                 else
2094                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2095                 for(i = 0; i < mapvote_count; ++i)
2096                         if(mapvote_maps[i] != "")
2097                         {
2098                                 WriteString(MSG_ENTITY, mapvote_maps[i]);
2099                                 mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2100                                 pakfile = whichpack(strcat(mapfile, ".tga"));
2101                                 if(pakfile == "")
2102                                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2103                                 if(pakfile == "")
2104                                         pakfile = whichpack(strcat(mapfile, ".png"));
2105                                 print("pakfile is ", pakfile, "\n");
2106                                 for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2107                                         pakfile = substring(pakfile, o, 999);
2108                                 WriteString(MSG_ENTITY, pakfile);
2109                         }
2110         }
2111
2112         if(sf & 2)
2113         {
2114                 // flag 2 == update of mask
2115                 if(mapvote_count <= 8)
2116                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2117                 else
2118                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2119         }
2120
2121         if(sf & 4)
2122         {
2123                 if(mapvote_detail)
2124                         for(i = 0; i < mapvote_count; ++i)
2125                                 if(mapvote_maps[i] != "")
2126                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2127
2128                 WriteByte(MSG_ENTITY, to.mapvote);
2129         }
2130
2131         return TRUE;
2132 }
2133
2134 void MapVote_Spawn()
2135 {
2136         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2137 }
2138
2139 void MapVote_TouchMask()
2140 {
2141         mapvote_ent.SendFlags |= 2;
2142 }
2143
2144 void MapVote_TouchVotes(entity voter)
2145 {
2146         mapvote_ent.SendFlags |= 4;
2147 }
2148
2149 float MapVote_Finished(float mappos)
2150 {
2151         string result;
2152         float i;
2153         float didntvote;
2154
2155         if(cvar("sv_eventlog"))
2156         {
2157                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2158                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2159                 didntvote = mapvote_voters;
2160                 for(i = 0; i < mapvote_count; ++i)
2161                         if(mapvote_maps[i] != "")
2162                         {
2163                                 didntvote -= mapvote_votes[i];
2164                                 if(i != mappos)
2165                                 {
2166                                         result = strcat(result, ":", mapvote_maps[i]);
2167                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2168                                 }
2169                         }
2170                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2171
2172                 GameLogEcho(result);
2173                 if(mapvote_maps_suggested[mappos])
2174                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2175         }
2176
2177         FOR_EACH_REALCLIENT(other)
2178                 FixClientCvars(other);
2179
2180         Map_Goto_SetStr(mapvote_maps[mappos]);
2181         Map_Goto();
2182         alreadychangedlevel = TRUE;
2183         return TRUE;
2184 }
2185 void MapVote_CheckRules_1()
2186 {
2187         float i;
2188
2189         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2190         {
2191                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2192                 mapvote_votes[i] = 0;
2193         }
2194
2195         mapvote_voters = 0;
2196         FOR_EACH_REALCLIENT(other)
2197         {
2198                 ++mapvote_voters;
2199                 if(other.mapvote)
2200                 {
2201                         i = other.mapvote - 1;
2202                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2203                         mapvote_votes[i] = mapvote_votes[i] + 1;
2204                 }
2205         }
2206 }
2207
2208 float MapVote_CheckRules_2()
2209 {
2210         float i;
2211         float firstPlace, secondPlace;
2212         float firstPlaceVotes, secondPlaceVotes;
2213         float mapvote_voters_real;
2214         string result;
2215
2216         mapvote_voters_real = mapvote_voters;
2217         if(mapvote_abstain)
2218                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2219
2220         RandomSelection_Init();
2221         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2222                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2223         firstPlace = RandomSelection_chosen_float;
2224         firstPlaceVotes = RandomSelection_best_priority;
2225         //dprint("First place: ", ftos(firstPlace), "\n");
2226         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2227
2228         RandomSelection_Init();
2229         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2230                 if(i != firstPlace)
2231                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2232         secondPlace = RandomSelection_chosen_float;
2233         secondPlaceVotes = RandomSelection_best_priority;
2234         //dprint("Second place: ", ftos(secondPlace), "\n");
2235         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2236
2237         if(firstPlace == -1)
2238                 error("No first place in map vote... WTF?");
2239
2240         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2241                 return MapVote_Finished(firstPlace);
2242
2243         if(mapvote_keeptwotime)
2244                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2245                 {
2246                         float didntvote;
2247                         MapVote_TouchMask();
2248                         mapvote_message = "Now decide between the TOP TWO!";
2249                         mapvote_keeptwotime = 0;
2250                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2251                         result = strcat(result, ":", ftos(firstPlaceVotes));
2252                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2253                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2254                         didntvote = mapvote_voters;
2255                         for(i = 0; i < mapvote_count; ++i)
2256                                 if(mapvote_maps[i] != "")
2257                                 {
2258                                         didntvote -= mapvote_votes[i];
2259                                         if(i != firstPlace)
2260                                                 if(i != secondPlace)
2261                                                 {
2262                                                         result = strcat(result, ":", mapvote_maps[i]);
2263                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2264                                                         if(i < mapvote_count_real)
2265                                                         {
2266                                                                 strunzone(mapvote_maps[i]);
2267                                                                 mapvote_maps[i] = "";
2268                                                         }
2269                                                 }
2270                                 }
2271                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2272                         if(cvar("sv_eventlog"))
2273                                 GameLogEcho(result);
2274                 }
2275
2276         return FALSE;
2277 }
2278 void MapVote_Tick()
2279 {
2280         float keeptwo;
2281         float totalvotes;
2282
2283         keeptwo = mapvote_keeptwotime;
2284         MapVote_CheckRules_1(); // count
2285         if(MapVote_CheckRules_2()) // decide
2286                 return;
2287
2288         totalvotes = 0;
2289         FOR_EACH_REALCLIENT(other)
2290         {
2291                 // hide scoreboard again
2292                 if(other.health != 2342)
2293                 {
2294                         other.health = 2342;
2295                         other.impulse = 0;
2296                         if(clienttype(other) == CLIENTTYPE_REAL)
2297                         {
2298                                 msg_entity = other;
2299                                 WriteByte(MSG_ONE, SVC_FINALE);
2300                                 WriteString(MSG_ONE, "");
2301                         }
2302                 }
2303
2304                 // notify about keep-two
2305                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2306                         play2(other, "misc/invshot.wav");
2307
2308                 // clear possibly invalid votes
2309                 if(mapvote_maps[other.mapvote - 1] == "")
2310                         other.mapvote = 0;
2311                 // use impulses as new vote
2312                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2313                         if(mapvote_maps[other.impulse - 1] != "")
2314                         {
2315                                 other.mapvote = other.impulse;
2316                                 MapVote_TouchVotes(other);
2317                         }
2318                 other.impulse = 0;
2319
2320                 if(other.mapvote)
2321                         ++totalvotes;
2322         }
2323
2324         MapVote_CheckRules_1(); // just count
2325 }
2326 void MapVote_Start()
2327 {
2328         if(mapvote_run)
2329                 return;
2330
2331         MapInfo_Enumerate();
2332         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1))
2333                 mapvote_run = TRUE;
2334 }
2335 void MapVote_Think()
2336 {
2337         if(!mapvote_run)
2338                 return;
2339
2340         if(alreadychangedlevel)
2341                 return;
2342
2343         if(time < mapvote_nextthink)
2344                 return;
2345         //dprint("tick\n");
2346
2347         mapvote_nextthink = time + 0.5;
2348
2349         if(!mapvote_initialized)
2350         {
2351                 mapvote_initialized = TRUE;
2352                 if(DoNextMapOverride())
2353                         return;
2354                 if(!cvar("g_maplist_votable") || player_count <= 0)
2355                 {
2356                         GotoNextMap();
2357                         return;
2358                 }
2359                 MapVote_Init();
2360         }
2361
2362         MapVote_Tick();
2363 };
2364
2365 string GotoMap(string m)
2366 {
2367         if(!MapInfo_CheckMap(m))
2368                 return "The map you chose is not available on this server.";
2369         cvar_set("nextmap", m);
2370         cvar_set("timelimit", "-1");
2371         if(mapvote_initialized || alreadychangedlevel)
2372         {
2373                 if(DoNextMapOverride())
2374                         return "Map switch initiated.";
2375                 else
2376                         return "Hm... no. For some reason I like THIS map more.";
2377         }
2378         else
2379                 return "Map switch will happen after scoreboard.";
2380 }
2381
2382
2383 void EndFrame()
2384 {
2385         FOR_EACH_REALCLIENT(self)
2386         {
2387                 if(self.classname == "spectator")
2388                 {
2389                         if(self.enemy.typehitsound)
2390                                 play2(self, "misc/typehit.wav");
2391                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2392                                 play2(self, "misc/hit.wav");
2393                 }
2394                 else
2395                 {
2396                         if(self.typehitsound)
2397                                 play2(self, "misc/typehit.wav");
2398                         else if(self.hitsound && self.cvar_cl_hitsound)
2399                                 play2(self, "misc/hit.wav");
2400                 }
2401         }
2402         FOR_EACH_CLIENT(self)
2403         {
2404                 self.hitsound = FALSE;
2405                 self.typehitsound = FALSE;
2406         }
2407 }
2408
2409
2410 /*
2411  * RedirectionThink:
2412  * returns TRUE if redirecting
2413  */
2414 float redirection_timeout;
2415 float redirection_nextthink;
2416 float RedirectionThink()
2417 {
2418         float clients_found;
2419
2420         if(redirection_target == "")
2421                 return FALSE;
2422
2423         if(!redirection_timeout)
2424         {
2425                 cvar_set("sv_public", "-2");
2426                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2427                 if(redirection_target == "self")
2428                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2429                 else
2430                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2431         }
2432
2433         if(time < redirection_nextthink)
2434                 return TRUE;
2435
2436         redirection_nextthink = time + 1;
2437
2438         clients_found = 0;
2439         FOR_EACH_REALCLIENT(self)
2440         {
2441                 print("Redirecting: sending connect command to ", self.netname, "\n");
2442                 if(redirection_target == "self")
2443                         stuffcmd(self, "\ndisconnect; reconnect\n");
2444                 else
2445                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2446                 ++clients_found;
2447         }
2448
2449         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2450
2451         if(time > redirection_timeout || clients_found == 0)
2452                 localcmd("\nwait; wait; wait; quit\n");
2453
2454         return TRUE;
2455 }
2456
2457 void RestoreGame()
2458 {
2459         // Loaded from a save game
2460         // some things then break, so let's work around them...
2461
2462         // Progs DB (capture records)
2463         if(sv_cheats)
2464                 ServerProgsDB = db_create();
2465         else
2466                 ServerProgsDB = db_load("server.db");
2467
2468         // Mapinfo
2469         MapInfo_Shutdown();
2470         MapInfo_Enumerate();
2471         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
2472 }
2473
2474 void SV_Shutdown()
2475 {
2476         if(world_initialized > 0)
2477         {
2478                 world_initialized = 0;
2479                 print("Saving persistent data...\n");
2480                 Ban_SaveBans();
2481                 if(!sv_cheats)
2482                         db_save(ServerProgsDB, "server.db");
2483                 if(cvar("developer"))
2484                         db_save(TemporaryDB, "server-temp.db");
2485                 db_close(ServerProgsDB);
2486                 db_close(TemporaryDB);
2487                 print("done!\n");
2488                 // tell the bot system the game is ending now
2489                 bot_endgame();
2490
2491                 MapInfo_Shutdown();
2492         }
2493         else if(world_initialized == 0)
2494         {
2495                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2496         }
2497 }