data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3
   4 string GetMapname();
   5 void GotoNextMap();
   6 void ShuffleMaplist()
   7 float() DoNextMapOverride;
   8
   9 void SetDefaultAlpha()
  10 {
  11         if(cvar("g_running_guns"))
  12         {
  13                 default_player_alpha = -1;
  14                 default_weapon_alpha = +1;
  15         }
  16         else if(cvar("g_cloaked"))
  17         {
  18                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  19                 default_weapon_alpha = default_player_alpha;
  20         }
  21         else
  22         {
  23                 default_player_alpha = cvar("g_player_alpha");
  24                 if(default_player_alpha <= 0)
  25                         default_player_alpha = 1;
  26                 default_weapon_alpha = default_player_alpha;
  27         }
  28 }
  29
  30 void fteqcc_testbugs()
  31 {
  32         float a, b;
  33
  34         if(!cvar("developer_fteqccbugs"))
  35                 return;
  36
  37         dprint("*** fteqcc test: checking for bugs...\n");
  38
  39         a = 1;
  40         b = 5;
  41         if(sqrt(a) - sqrt(b - a) == 0)
  42                 dprint("*** fteqcc test: found same-function-twice bug\n");
  43         else
  44                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  45
  46         world.frags = -10;
  47         world.enemy = world;
  48         world.enemy.frags += 10;
  49         if(world.frags > 0.2 || world.frags < -0.2) // don't error out if it's just roundoff errors
  50                 dprint("*** fteqcc test: found += bug\n");
  51         else
  52                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  53         world.frags = 0;
  54 }
  55
  56 void GotoFirstMap()
  57 {
  58         if(cvar("_sv_init"))
  59         {
  60                 cvar_set("_sv_init", "0");
  61                 if(cvar("g_maplist_shuffle"))
  62                         ShuffleMaplist();
  63                 tokenize(cvar_string("g_maplist"));
  64                 if(argv(0) != GetMapname())
  65                 {
  66                         cvar_set("nextmap", argv(0));
  67                         if(!DoNextMapOverride())
  68                                 GotoNextMap();
  69                 }
  70         }
  71 }
  72
  73 float world_already_spawned;
  74 void worldspawn (void)
  75 {
  76         float globhandle, i, n;
  77
  78         dprint_load(); // load dprint status from cvar
  79
  80         if(world_already_spawned)
  81                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
  82         world_already_spawned = TRUE;
  83
  84         sv_cheats = cvar("sv_cheats");
  85
  86         /*
  87         TODO sound pack system
  88         // initialize sound pack system
  89         soundpack = cvar_string("g_soundpack");
  90         if(soundpack != "")
  91                 soundpack = strcat(soundpack, "/");
  92         soundpack = strzone(soundpack);
  93         */
  94
  95         // gamemode related things
  96         precache_model ("models/misc/chatbubble.spr");
  97         precache_model ("models/misc/teambubble.spr");
  98         if (cvar("g_runematch"))
  99         {
 100                 precache_model ("models/runematch/curse.mdl");
 101                 precache_model ("models/runematch/rune.mdl");
 102         }
 103
 104         // Precache all player models if desired
 105         if (cvar("sv_precacheplayermodels"))
 106         {
 107                 globhandle = search_begin("models/player/*.zym", TRUE, FALSE);
 108                 n = search_getsize(globhandle);
 109                 for(i = 0; i < n; ++i)
 110                 {
 111                         //print(search_getfilename(globhandle, i), "\n");
 112                         precache_model(search_getfilename(globhandle, i));
 113                 }
 114                 search_end(globhandle);
 115                 //precache_model("models/player/carni.zym");
 116                 //precache_model("models/player/crash.zym");
 117                 //precache_model("models/player/grunt.zym");
 118                 //precache_model("models/player/headhunter.zym");
 119                 //precache_model("models/player/insurrectionist.zym");
 120                 //precache_model("models/player/jeandarc.zym");
 121                 //precache_model("models/player/lurk.zym");
 122                 //precache_model("models/player/lycanthrope.zym");
 123                 //precache_model("models/player/marine.zym");
 124                 //precache_model("models/player/nexus.zym");
 125                 //precache_model("models/player/pyria.zym");
 126                 //precache_model("models/player/shock.zym");
 127                 //precache_model("models/player/skadi.zym");
 128                 //precache_model("models/player/specop.zym");
 129                 //precache_model("models/player/visitant.zym");
 130         }
 131
 132         if (cvar("g_footsteps"))
 133         {
 134                 precache_sound ("misc/footstep01.wav");
 135                 precache_sound ("misc/footstep02.wav");
 136                 precache_sound ("misc/footstep03.wav");
 137                 precache_sound ("misc/footstep04.wav");
 138                 precache_sound ("misc/footstep05.wav");
 139                 precache_sound ("misc/footstep06.wav");
 140         }
 141
 142         // gore and miscellaneous sounds
 143         //precache_sound ("misc/h2ohit.wav");
 144         precache_model ("models/gibs/bloodyskull.md3");
 145         precache_model ("models/gibs/chunk.mdl");
 146         precache_model ("models/gibs/eye.md3");
 147         precache_model ("models/gibs/gib1.md3");
 148         precache_model ("models/gibs/gib1.mdl");
 149         precache_model ("models/gibs/gib2.mdl");
 150         precache_model ("models/gibs/gib3.mdl");
 151         precache_model ("models/gibs/gib5.md3");
 152         precache_model ("models/hook.md3");
 153         precache_sound ("misc/armorimpact.wav");
 154         precache_sound ("misc/bodyimpact1.wav");
 155         precache_sound ("misc/bodyimpact2.wav");
 156         precache_sound ("misc/gib.wav");
 157         precache_sound ("misc/gib_splat01.wav");
 158         precache_sound ("misc/gib_splat02.wav");
 159         precache_sound ("misc/gib_splat03.wav");
 160         precache_sound ("misc/gib_splat04.wav");
 161         precache_sound ("misc/hit.wav");
 162         precache_sound ("misc/hitground1.wav");
 163         precache_sound ("misc/hitground2.wav");
 164         precache_sound ("misc/hitground3.wav");
 165         precache_sound ("misc/hitground4.wav");
 166         precache_sound ("misc/null.wav");
 167         precache_sound ("misc/spawn.wav");
 168         precache_sound ("misc/talk.wav");
 169         precache_sound ("misc/teleport.wav");
 170         precache_sound ("player/lava.wav");
 171         precache_sound ("player/slime.wav");
 172
 173         // announcer sounds - male
 174         //precache_sound ("announcer/male/electrobitch.wav");
 175         precache_sound ("announcer/male/03kills.wav");
 176         precache_sound ("announcer/male/05kills.wav");
 177         precache_sound ("announcer/male/10kills.wav");
 178         precache_sound ("announcer/male/15kills.wav");
 179         precache_sound ("announcer/male/20kills.wav");
 180         precache_sound ("announcer/male/25kills.wav");
 181         precache_sound ("announcer/male/30kills.wav");
 182         precache_sound ("announcer/male/botlike.wav");
 183         precache_sound ("announcer/male/yoda.wav");
 184
 185         // announcer sounds - robotic
 186         precache_sound ("announcer/robotic/1fragleft.wav");
 187         precache_sound ("announcer/robotic/1minuteremains.wav");
 188         precache_sound ("announcer/robotic/2fragsleft.wav");
 189         precache_sound ("announcer/robotic/3fragsleft.wav");
 190         if (cvar("g_minstagib"))
 191         {
 192                 precache_sound ("announcer/robotic/lastsecond.wav");
 193                 precache_sound ("announcer/robotic/narrowly.wav");
 194                 precache_sound ("announcer/robotic/1.wav");
 195                 precache_sound ("announcer/robotic/2.wav");
 196                 precache_sound ("announcer/robotic/3.wav");
 197                 precache_sound ("announcer/robotic/4.wav");
 198                 precache_sound ("announcer/robotic/5.wav");
 199                 precache_sound ("announcer/robotic/6.wav");
 200                 precache_sound ("announcer/robotic/7.wav");
 201                 precache_sound ("announcer/robotic/8.wav");
 202                 precache_sound ("announcer/robotic/9.wav");
 203                 precache_sound ("announcer/robotic/10.wav");
 204         }
 205
 206         // common weapon precaches
 207         precache_sound ("weapons/weapon_switch.wav");
 208         precache_sound ("weapons/weaponpickup.wav");
 209         if (cvar("g_grappling_hook"))
 210         {
 211                 precache_sound ("weapons/hook_fire.wav"); // hook
 212                 precache_sound ("weapons/hook_impact.wav"); // hook
 213         }
 214
 215         if (cvar("sv_precacheweapons") || cvar("g_nixnex"))
 216         {
 217                 //precache weapon models/sounds
 218                 local float wep;
 219                 wep = WEP_FIRST;
 220                 while (wep <= WEP_LAST)
 221                 {
 222                         weapon_action(wep, WR_PRECACHE);
 223                         wep = wep + 1;
 224                 }
 225         }
 226
 227         // plays music for the level if there is any
 228         if (self.noise)
 229         {
 230                 precache_sound (self.noise);
 231                 ambientsound ('0 0 0', self.noise, 1.00, ATTN_NONE);
 232         }
 233
 234         // 0 normal
 235         lightstyle(0, "m");
 236
 237         // 1 FLICKER (first variety)
 238         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 239
 240         // 2 SLOW STRONG PULSE
 241         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 242
 243         // 3 CANDLE (first variety)
 244         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 245
 246         // 4 FAST STROBE
 247         lightstyle(4, "mamamamamama");
 248
 249         // 5 GENTLE PULSE 1
 250         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 251
 252         // 6 FLICKER (second variety)
 253         lightstyle(6, "nmonqnmomnmomomno");
 254
 255         // 7 CANDLE (second variety)
 256         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 257
 258         // 8 CANDLE (third variety)
 259         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 260
 261         // 9 SLOW STROBE (fourth variety)
 262         lightstyle(9, "aaaaaaaazzzzzzzz");
 263
 264         // 10 FLUORESCENT FLICKER
 265         lightstyle(10, "mmamammmmammamamaaamammma");
 266
 267         // 11 SLOW PULSE NOT FADE TO BLACK
 268         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 269
 270         // styles 32-62 are assigned by the light program for switchable lights
 271
 272         // 63 testing
 273         lightstyle(63, "a");
 274
 275         player_count = 0;
 276         lms_lowest_lives = 0;
 277         lms_next_place = 0;
 278
 279         GotoFirstMap();
 280
 281         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 282         if(bot_waypoints_for_items == 1)
 283                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 284                         bot_waypoints_for_items = 0;
 285
 286         if(cvar("g_campaign"))
 287                 CampaignPreInit();
 288
 289         InitGameplayMode();
 290
 291         WaypointSprite_Init();
 292
 293         //if (cvar("g_domination"))
 294         //      dom_init();
 295
 296         local entity head;
 297         head = nextent(world);
 298         maxclients = 0;
 299         while(head)
 300         {
 301                 maxclients++;
 302                 head = nextent(head);
 303         }
 304
 305         GameLogInit(); // prepare everything
 306         if(cvar("sv_eventlog"))
 307         {
 308                 local string s;
 309                 GameLogEcho(":logversion:2", FALSE);
 310                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 311                 s = strcat(s, ftos(random()));
 312                 GameLogEcho(strcat(":gamestart:", GetMapname(), ":", s), FALSE);
 313                 s = ":gameinfo:mutators:LIST";
 314                 if(cvar("g_grappling_hook"))
 315                         s = strcat(s, ":grappling_hook");
 316                 if(!cvar("g_use_ammunition"))
 317                         s = strcat(s, ":no_use_ammunition");
 318                 if(!cvar("g_pickup_items"))
 319                         s = strcat(s, ":no_pickup_items");
 320                 if(cvar("g_instagib"))
 321                         s = strcat(s, ":instagib");
 322                 if(cvar("g_rocketarena"))
 323                         s = strcat(s, ":rockerarena");
 324                 if(cvar("g_nixnex"))
 325                         s = strcat(s, ":nixnex");
 326                 if(cvar("g_vampire"))
 327                         s = strcat(s, ":vampire");
 328                 if(cvar("g_laserguided_missile"))
 329                         s = strcat(s, ":laserguided_missile");
 330                 if(cvar("g_norecoil"))
 331                         s = strcat(s, ":norecoil");
 332                 if(cvar("g_midair"))
 333                         s = strcat(s, ":midair");
 334                 if(cvar("g_minstagib"))
 335                         s = strcat(s, ":minstagib");
 336                 GameLogEcho(s, FALSE);
 337                 GameLogEcho(":gameinfo:end", FALSE);
 338         }
 339
 340         cvar_set("nextmap", "");
 341
 342         SetDefaultAlpha();
 343
 344         if(cvar("g_campaign"))
 345                 CampaignPostInit();
 346
 347         fteqcc_testbugs();
 348
 349         readlevelcvars();
 350
 351         Ban_LoadBans();
 352 }
 353
 354 void light (void)
 355 {
 356         //makestatic (self); // Who the f___ did that?
 357         remove(self);
 358 }
 359
 360 float( string pFilename ) TryFile =
 361 {
 362         local float lHandle;
 363         dprint("TryFile(\"", pFilename, "\")\n");
 364         lHandle = fopen( pFilename, FILE_READ );
 365         if( lHandle != -1 ) {
 366                 fclose( lHandle );
 367                 return TRUE;
 368         } else {
 369                 return FALSE;
 370         }
 371 };
 372
 373 string GetGametype()
 374 {
 375         if (game == GAME_DEATHMATCH)
 376                 return "dm";
 377         else if (game == GAME_TEAM_DEATHMATCH)
 378                 return "tdm";
 379         else if (game == GAME_DOMINATION)
 380                 return "dom";
 381         else if (game == GAME_CTF)
 382                 return "ctf";
 383         else if (game == GAME_RUNEMATCH)
 384                 return "rune";
 385         else if (game == GAME_LMS)
 386                 return "lms";
 387         else if (game == GAME_KEYHUNT)
 388                 return "kh";
 389         else if (game == GAME_ONSLAUGHT)
 390                 return "ons";
 391         else if (game == GAME_ASSAULT)
 392                 return "as";
 393         return "dm";
 394 }
 395
 396 float IsSameGametype(string mapcfgname)
 397 {
 398         string gt;
 399         gt = GetGametype();
 400         if(substring(mapcfgname, 0, strlen(gt) + 1) == strcat(gt, "_"))
 401                 return TRUE;
 402         return FALSE;
 403 }
 404
 405 string getmapname_stored;
 406 string GetMapname()
 407 {
 408         if(getmapname_stored == "")
 409                 getmapname_stored = strzone(strcat(GetGametype(), "_", mapname));
 410         return getmapname_stored;
 411 }
 412
 413 float Map_Count, Map_Current;
 414 string Map_Current_Name;
 415
 416 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 417 float GetMaplistPosition()
 418 {
 419         float pos, idx;
 420         string map;
 421
 422         map = GetMapname();
 423         idx = cvar("g_maplist_index");
 424
 425         if(idx >= 0)
 426                 if(idx < Map_Count)
 427                         if(map == argv(idx))
 428                                 return idx;
 429
 430         for(pos = 0; pos < Map_Count; ++pos)
 431                 if(map == argv(pos))
 432                         return pos;
 433
 434         // resume normal maplist rotation if current map is not in g_maplist
 435         return idx;
 436 }
 437
 438 float MapHasRightSize(string map)
 439 {
 440         // open map size restriction file
 441         float fh;
 442         dprint("opensize "); dprint(map);
 443         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 444         if(fh >= 0)
 445         {
 446                 float mapmin, mapmax;
 447                 dprint(": ok, ");
 448                 mapmin = stof(fgets(fh));
 449                 mapmax = stof(fgets(fh));
 450                 fclose(fh);
 451                 if(player_count < mapmin)
 452                 {
 453                         dprint("not enough\n");
 454                         return FALSE;
 455                 }
 456                 if(player_count > mapmax)
 457                 {
 458                         dprint("too many\n");
 459                         return FALSE;
 460                 }
 461                 dprint("right size\n");
 462                 return TRUE;
 463         }
 464         dprint(": not found\n");
 465         return TRUE;
 466 }
 467
 468 string Map_Filename(float position)
 469 {
 470         // FIXME unused
 471         return strcat("maps/", argv(position), ".mapcfg");
 472 }
 473
 474 string strwords(string s, float w)
 475 {
 476         float endpos;
 477         for(endpos = 0; w && endpos >= 0; --w)
 478                 endpos = strstrofs(s, " ", endpos + 1);
 479         if(endpos < 0)
 480                 return s;
 481         else
 482                 return substring(s, 0, endpos);
 483 }
 484
 485 float strhasword(string s, string w)
 486 {
 487         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 488 }
 489
 490 void Map_MarkAsRecent(string m)
 491 {
 492         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 493 }
 494
 495 float Map_IsRecent(string m)
 496 {
 497         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 498 }
 499
 500 float(float position, float pass) Map_Check =
 501 {
 502         string filename;
 503         string map_next;
 504         map_next = argv(position);
 505         if(pass <= 1)
 506         {
 507                 if(map_next == Map_Current_Name) // same map again in first pass?
 508                         return 0;
 509                 if(Map_IsRecent(map_next))
 510                         return 0;
 511         }
 512         filename = Map_Filename(position);
 513         if(TryFile(filename))
 514         {
 515                 if(pass == 2)
 516                         return 1;
 517                 if(MapHasRightSize(argv(position)))
 518                         return 1;
 519                 return 0;
 520         }
 521         else
 522                 dprint( "Couldn't find '", filename, "'..\n" );
 523
 524         return 0;
 525 }
 526
 527 void(string nextmapname) Map_Goto_SetStr =
 528 {
 529         if(getmapname_stored != "")
 530                 strunzone(getmapname_stored);
 531         if(nextmapname == "")
 532                 getmapname_stored = "";
 533         else
 534                 getmapname_stored = strzone(nextmapname);
 535 }
 536
 537 void(float position) Map_Goto_SetFloat =
 538 {
 539         cvar_set("g_maplist_index", ftos(position));
 540         Map_Goto_SetStr(argv(position));
 541 }
 542
 543 void() GameResetCfg =
 544 {
 545         // if an exit cfg is defined by exiting map, exec it.
 546         string exit_cfg;
 547         exit_cfg = cvar_string("exit_cfg");
 548         if(exit_cfg != "")
 549                 localcmd(strcat("exec \"", exit_cfg, "\"\n"));
 550
 551         localcmd("exec game_reset.cfg\n");
 552
 553         Ban_SaveBans();
 554 };
 555
 556 void() Map_Goto =
 557 {
 558         Map_MarkAsRecent(getmapname_stored);
 559         GameResetCfg();
 560         localcmd(strcat("exec \"maps/", getmapname_stored ,".mapcfg\"\n"));
 561 }
 562
 563 // return codes of map selectors:
 564 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 565 //   -2 = permanent failure
 566 float() MaplistMethod_Iterate = // usual method
 567 {
 568         float pass, i;
 569
 570         for(pass = 1; pass <= 2; ++pass)
 571         {
 572                 for(i = 1; i < Map_Count; ++i)
 573                 {
 574                         float mapindex;
 575                         mapindex = math_mod(i + Map_Current, Map_Count);
 576                         if(Map_Check(mapindex, pass))
 577                                 return mapindex;
 578                 }
 579         }
 580         return -1;
 581 }
 582
 583 float() MaplistMethod_Repeat = // fallback method
 584 {
 585         if(Map_Check(Map_Current, 2))
 586                 return Map_Current;
 587         return -2;
 588 }
 589
 590 float() MaplistMethod_Random = // random map selection
 591 {
 592         float i, imax;
 593
 594         imax = 42;
 595
 596         for(i = 0; i <= imax; ++i)
 597         {
 598                 float mapindex;
 599                 mapindex = math_mod(Map_Current + ceil(random() * (Map_Count - 1)), Map_Count); // any OTHER map
 600                 if(Map_Check(mapindex, 1))
 601                         return mapindex;
 602         }
 603         return -1;
 604 }
 605
 606 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 607 // the exponent sets a bias on the map selection:
 608 // the higher the exponent, the less likely "shortly repeated" same maps are
 609 {
 610         float i, j, imax, insertpos;
 611
 612         imax = 42;
 613
 614         if(Map_Count <= 1)
 615                 return 0; // only one map, then always play this one
 616
 617         for(i = 0; i <= imax; ++i)
 618         {
 619                 string newlist;
 620
 621                 // now reinsert this at another position
 622                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 623                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 624                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 625                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 626
 627                 // insert the current map there
 628                 newlist = "";
 629                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 630                         newlist = strcat(newlist, "'", argv(j), "'");
 631                 newlist = strcat(newlist, "'", argv(0), "'");  // now insert the just selected map
 632                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 633                         newlist = strcat(newlist, "'", argv(j), "'");
 634                 cvar_set("g_maplist", newlist);
 635                 Map_Count = tokenize(newlist);
 636
 637                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 638                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 639                 if(Map_Check(Map_Current, 1))
 640                         return Map_Current;
 641         }
 642         return -1;
 643 }
 644
 645 void() Maplist_Init =
 646 {
 647         string temp;
 648         temp = cvar_string("g_maplist");
 649         Map_Count = tokenize(temp);
 650         if(Map_Count == 0)
 651         {
 652                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 653                 cvar_set("g_maplist", temp = cvar_string("g_maplist_defaultlist"));
 654                 Map_Count = tokenize(temp);
 655         }
 656         if(Map_Count == 0)
 657                 error("empty maplist, cannot select a new map");
 658         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 659
 660         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 661         // this may or may not be correct, but who cares, in the worst case a map
 662         // isn't chosen in the first pass that should have been
 663 }
 664
 665 string() GetNextMap =
 666 {
 667         float nextMap;
 668
 669         Maplist_Init();
 670         nextMap = -1;
 671
 672         if(nextMap == -1)
 673                 if(cvar("g_maplist_shuffle") > 0)
 674                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 675
 676         if(nextMap == -1)
 677                 if(cvar("g_maplist_selectrandom"))
 678                         nextMap = MaplistMethod_Random();
 679
 680         if(nextMap == -1)
 681                 nextMap = MaplistMethod_Iterate();
 682
 683         if(nextMap == -1)
 684                 nextMap = MaplistMethod_Repeat();
 685
 686         if(nextMap >= 0)
 687         {
 688                 Map_Goto_SetFloat(nextMap);
 689                 return getmapname_stored;
 690         }
 691
 692         return "";
 693 };
 694
 695 float() DoNextMapOverride =
 696 {
 697         Ban_SaveBans();
 698
 699         if(cvar("g_campaign"))
 700         {
 701                 CampaignPostIntermission();
 702                 return TRUE;
 703         }
 704         if(cvar("quit_when_empty"))
 705         {
 706                 if(player_count <= currentbots)
 707                 {
 708                         localcmd("quit\n");
 709                         return TRUE;
 710                 }
 711         }
 712         if(cvar_string("quit_and_redirect") != "")
 713         {
 714                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 715                 return TRUE;
 716         }
 717         if (cvar("samelevel")) // if samelevel is set, stay on same level
 718         {
 719                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 720                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 721                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 722                 localcmd("restart\n");
 723                 //changelevel (mapname);
 724                 return TRUE;
 725         }
 726         if(cvar_string("nextmap") != "")
 727                 if(TryFile(strcat("maps/", cvar_string("nextmap"), ".mapcfg")))
 728                 {
 729                         Map_Goto_SetStr(cvar_string("nextmap"));
 730                         Map_Goto();
 731                         return TRUE;
 732                 }
 733         if(cvar("lastlevel"))
 734         {
 735                 GameResetCfg();
 736                 localcmd("set lastlevel 0\ntogglemenu\n");
 737                 return TRUE;
 738         }
 739         return FALSE;
 740 };
 741
 742 void() GotoNextMap =
 743 {
 744         //local string nextmap;
 745         //local float n, nummaps;
 746         //local string s;
 747         if (alreadychangedlevel)
 748                 return;
 749         alreadychangedlevel = TRUE;
 750
 751         {
 752                 string nextMap;
 753                 float allowReset;
 754
 755                 for(allowReset = 1; allowReset >= 0; --allowReset)
 756                 {
 757                         nextMap = GetNextMap();
 758                         if(nextMap != "")
 759                                 break;
 760
 761                         if(allowReset)
 762                         {
 763                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 764                                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
 765                         }
 766                         else
 767                         {
 768                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 769                         }
 770                 }
 771                 Map_Goto();
 772         }
 773 };
 774
 775
 776 /*
 777 ============
 778 IntermissionThink
 779
 780 When the player presses attack or jump, change to the next level
 781 ============
 782 */
 783 .float autoscreenshot;
 784 void() MapVote_Start;
 785 void() MapVote_Think;
 786 float mapvote_initialized;
 787 void() IntermissionThink =
 788 {
 789         FixIntermissionClient(self);
 790
 791         if(cvar("sv_autoscreenshot"))
 792         if(self.autoscreenshot > 0)
 793         if(time > self.autoscreenshot)
 794         {
 795                 self.autoscreenshot = -1;
 796                 if(clienttype(self) == CLIENTTYPE_REAL)
 797                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 798                 return;
 799         }
 800
 801         if (time < intermission_exittime)
 802                 return;
 803
 804         if(!mapvote_initialized)
 805                 if (time < intermission_exittime + 10 && !self.button0 && !self.button2 && !self.button3 && !self.button6 && !self.buttonuse)
 806                         return;
 807
 808         MapVote_Start();
 809 };
 810
 811 /*
 812 ============
 813 FindIntermission
 814
 815 Returns the entity to view from
 816 ============
 817 */
 818 /*
 819 entity() FindIntermission =
 820 {
 821         local   entity spot;
 822         local   float cyc;
 823
 824 // look for info_intermission first
 825         spot = find (world, classname, "info_intermission");
 826         if (spot)
 827         {       // pick a random one
 828                 cyc = random() * 4;
 829                 while (cyc > 1)
 830                 {
 831                         spot = find (spot, classname, "info_intermission");
 832                         if (!spot)
 833                                 spot = find (spot, classname, "info_intermission");
 834                         cyc = cyc - 1;
 835                 }
 836                 return spot;
 837         }
 838
 839 // then look for the start position
 840         spot = find (world, classname, "info_player_start");
 841         if (spot)
 842                 return spot;
 843
 844 // testinfo_player_start is only found in regioned levels
 845         spot = find (world, classname, "testplayerstart");
 846         if (spot)
 847                 return spot;
 848
 849 // then look for the start position
 850         spot = find (world, classname, "info_player_deathmatch");
 851         if (spot)
 852                 return spot;
 853
 854         //objerror ("FindIntermission: no spot");
 855         return world;
 856 };
 857 */
 858
 859 /*
 860 ===============================================================================
 861
 862 RULES
 863
 864 ===============================================================================
 865 */
 866
 867 void(float final) DumpStats =
 868 {
 869         local float file;
 870         local string s;
 871         local float to_console;
 872         local float to_eventlog;
 873         local float to_file;
 874
 875         to_console = cvar("sv_logscores_console");
 876         to_eventlog = cvar("sv_eventlog");
 877         to_file = cvar("sv_logscores_file");
 878
 879         if(!final)
 880         {
 881                 to_console = TRUE; // always print printstats replies
 882                 to_eventlog = FALSE; // but never print them to the event log
 883         }
 884
 885         if(to_eventlog)
 886                 if(cvar("sv_eventlog_console"))
 887                         to_console = FALSE; // otherwise we get the output twice
 888
 889         if(final)
 890                 s = ":scores:";
 891         else
 892                 s = ":status:";
 893         s = strcat(s, GetMapname(), ":", ftos(rint(time)));
 894
 895         if(to_console)
 896                 ServerConsoleEcho(s, FALSE);
 897         if(to_eventlog)
 898                 GameLogEcho(s, FALSE);
 899         if(to_file)
 900         {
 901                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
 902                 if(file == -1)
 903                         to_file = FALSE;
 904                 else
 905                         fputs(file, strcat(s, "\n"));
 906         }
 907
 908         FOR_EACH_CLIENT(other)
 909         {
 910                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
 911                 {
 912                         s = strcat(":player:", ftos(other.frags), ":");
 913                         s = strcat(s, ftos(other.deaths), ":");
 914                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
 915                         s = strcat(s, ftos(other.team), ":");
 916
 917                         if(to_console)
 918                                 ServerConsoleEcho(strcat(s, other.netname), TRUE);
 919                         if(to_eventlog)
 920                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname), TRUE);
 921                         if(to_file)
 922                                 fputs(file, strcat(s, other.netname, "\n"));
 923                 }
 924         }
 925
 926         if(to_console)
 927                 ServerConsoleEcho(":end", FALSE);
 928         if(to_eventlog)
 929                 GameLogEcho(":end", FALSE);
 930         if(to_file)
 931         {
 932                 fputs(file, ":end\n");
 933                 fclose(file);
 934         }
 935 }
 936
 937 void FixIntermissionClient(entity e)
 938 {
 939         if(!e.autoscreenshot) // initial call
 940         {
 941                 e.angles = e.v_angle;
 942                 e.angles_x = -e.angles_x;
 943                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
 944                 e.health = -2342;
 945                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
 946                 e.solid = SOLID_NOT;
 947                 e.movetype = MOVETYPE_NONE;
 948                 e.takedamage = DAMAGE_NO;
 949                 if(e.weaponentity)
 950                         e.weaponentity.effects = EF_NODRAW;
 951                 stuffcmd(e, "\nscr_printspeed 1000000\n");
 952                 if(clienttype(e) == CLIENTTYPE_REAL)
 953                 {
 954                         msg_entity = e;
 955                         WriteByte(MSG_ONE, SVC_INTERMISSION);
 956                 }
 957         }
 958
 959         //e.velocity = '0 0 0';
 960         //e.fixangle = TRUE;
 961
 962         // TODO halt weapon animation
 963 }
 964
 965
 966 /*
 967 go to the next level for deathmatch
 968 only called if a time or frag limit has expired
 969 */
 970 void() NextLevel =
 971 {
 972         float minTotalFrags;
 973         float maxTotalFrags;
 974         float score;
 975         float f;
 976
 977         gameover = TRUE;
 978
 979         intermission_running = 1;
 980
 981 // enforce a wait time before allowing changelevel
 982         if(player_count > 0)
 983                 intermission_exittime = time + cvar("sv_mapchange_delay");
 984         else
 985                 intermission_exittime = -1;
 986
 987         WriteByte (MSG_ALL, SVC_CDTRACK);
 988         WriteByte (MSG_ALL, 3);
 989         WriteByte (MSG_ALL, 3);
 990
 991         //pos = FindIntermission ();
 992
 993         VoteReset();
 994
 995         DumpStats(TRUE);
 996
 997         if(cvar("sv_eventlog"))
 998                 GameLogEcho(":gameover", FALSE);
 999
1000         GameLogClose();
1001
1002         FOR_EACH_CLIENT(other)
1003         {
1004                 FixIntermissionClient(other);
1005
1006                 if(other.winning)
1007                         bprint(other.netname, " ^7wins.\n");
1008         }
1009
1010         minTotalFrags = 0;
1011         maxTotalFrags = 0;
1012         FOR_EACH_PLAYER(other)
1013         {
1014                 if(maxTotalFrags < other.totalfrags)
1015                         maxTotalFrags = other.totalfrags;
1016                 if(minTotalFrags > other.totalfrags)
1017                         minTotalFrags = other.totalfrags;
1018         }
1019
1020         if(!currentbots)
1021         {
1022                 FOR_EACH_PLAYER(other)
1023                 {
1024                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1025                         f = bound(0, other.play_time / max(time, 1), 1);
1026                         // store some statistics?
1027                 }
1028         }
1029
1030         if(cvar("g_campaign"))
1031                 CampaignPreIntermission();
1032
1033         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1034 };
1035
1036 /*
1037 ============
1038 CheckRules_Player
1039
1040 Exit deathmatch games upon conditions
1041 ============
1042 */
1043 void() CheckRules_Player =
1044 {
1045         if (gameover)   // someone else quit the game already
1046                 return;
1047
1048         if(self.deadflag == DEAD_NO)
1049                 self.play_time += frametime;
1050
1051         // fixme: don't check players; instead check dom_team and ctf_team entities
1052         //   (div0: and that in CheckRules_World please)
1053 };
1054
1055 float checkrules_oneminutewarning;
1056 float checkrules_leaderfrags;
1057 float tdm_max_score, tdm_old_score;
1058
1059 float checkrules_equality;
1060 float checkrules_overtimewarning;
1061 float checkrules_overtimeend;
1062
1063 void() InitiateOvertime =
1064 {
1065         if(!checkrules_overtimeend)
1066                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1067 }
1068
1069 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1070 float WINNING_YES = 1; // winner found
1071 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1072 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1073
1074 float(float fraglimitreached, float equality) GetWinningCode =
1075 {
1076         if(equality)
1077                 if(fraglimitreached)
1078                         return WINNING_STARTOVERTIME;
1079                 else
1080                         return WINNING_NEVER;
1081         else
1082                 if(fraglimitreached)
1083                         return WINNING_YES;
1084                 else
1085                         return WINNING_NO;
1086 }
1087
1088 // set the .winning flag for exactly those players with a given field value
1089 void(.float field, float value) SetWinners =
1090 {
1091         entity head;
1092         FOR_EACH_PLAYER(head)
1093                 head.winning = (head.field == value);
1094 }
1095
1096 // set the .winning flag for those players with a given field value
1097 void(.float field, float value) AddWinners =
1098 {
1099         entity head;
1100         FOR_EACH_PLAYER(head)
1101                 if(head.field == value)
1102                         head.winning = 1;
1103 }
1104
1105 // clear the .winning flags
1106 void(void) ClearWinners =
1107 {
1108         entity head;
1109         FOR_EACH_PLAYER(head)
1110                 head.winning = 0;
1111 }
1112
1113 // Onslaught winning condition:
1114 // game terminates if only one team has a working generator (or none)
1115 float() WinningCondition_Onslaught =
1116 {
1117         entity head;
1118         local float t1, t2, t3, t4;
1119         // first check if the game has ended
1120         t1 = t2 = t3 = t4 = 0;
1121         head = find(world, classname, "onslaught_generator");
1122         while (head)
1123         {
1124                 if (head.health > 0)
1125                 {
1126                         if (head.team == COLOR_TEAM1) t1 = 1;
1127                         if (head.team == COLOR_TEAM2) t2 = 1;
1128                         if (head.team == COLOR_TEAM3) t3 = 1;
1129                         if (head.team == COLOR_TEAM4) t4 = 1;
1130                 }
1131                 head = find(head, classname, "onslaught_generator");
1132         }
1133         if (t1 + t2 + t3 + t4 < 2)
1134         {
1135                 // game over, only one team remains (or none)
1136                 ClearWinners();
1137                 if (t1) SetWinners(team, COLOR_TEAM1);
1138                 if (t2) SetWinners(team, COLOR_TEAM2);
1139                 if (t3) SetWinners(team, COLOR_TEAM3);
1140                 if (t4) SetWinners(team, COLOR_TEAM4);
1141                 dprint("Have a winner, ending game.\n");
1142                 return WINNING_YES;
1143         }
1144
1145         // Two or more teams remain
1146         return WINNING_NO;
1147 }
1148
1149 float() LMS_NewPlayerLives =
1150 {
1151         float fl;
1152         fl = cvar("fraglimit");
1153         if(fl == 0)
1154                 fl = 999;
1155
1156         // first player has left the game for dying too much? Nobody else can get in.
1157         if(lms_lowest_lives < 1)
1158                 return FALSE;
1159
1160         if(!cvar("g_lms_join_anytime"))
1161                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1162                         return FALSE;
1163
1164         return bound(1, lms_lowest_lives, fl);
1165 }
1166
1167 // LMS winning condition: game terminates if and only if there's at most one
1168 // one player who's living lives. Top two scores being equal cancels the time
1169 // limit.
1170 float() WinningCondition_LMS =
1171 {
1172         entity head;
1173         float have_player;
1174         float have_players;
1175         float l;
1176
1177         have_player = FALSE;
1178         have_players = FALSE;
1179         l = LMS_NewPlayerLives();
1180
1181         head = find(world, classname, "player");
1182         if(head)
1183                 have_player = TRUE;
1184         head = find(head, classname, "player");
1185         if(head)
1186                 have_players = TRUE;
1187
1188         if(have_player)
1189         {
1190                 // we have at least one player
1191                 if(have_players)
1192                 {
1193                         // two or more active players - continue with the game
1194                 }
1195                 else
1196                 {
1197                         // exactly one player?
1198                         if(l)
1199                         {
1200                                 // but no game has taken place yet
1201                         }
1202                         else
1203                         {
1204                                 // a winner!
1205                                 ClearWinners(); SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1206                                 dprint("Have a winner, ending game.\n");
1207                                 return WINNING_YES;
1208                         }
1209                 }
1210         }
1211         else
1212         {
1213                 // nobody is playing at all...
1214                 if(l)
1215                 {
1216                         // wait for players...
1217                 }
1218                 else
1219                 {
1220                         // SNAFU (maybe a draw game?)
1221                         ClearWinners();
1222                         dprint("No players, ending game.\n");
1223                         return WINNING_YES;
1224                 }
1225         }
1226
1227         // When we get here, we have at least two players who are actually LIVING,
1228         // or one player who is still waiting for a victim to join the server. Now
1229         // check if the top two players have equal score.
1230
1231         checkrules_leaderfrags = 0;
1232         checkrules_equality = FALSE;
1233         FOR_EACH_PLAYER(head)
1234         {
1235                 if(head.frags > checkrules_leaderfrags)
1236                 {
1237                         checkrules_leaderfrags = head.frags;
1238                         checkrules_equality = FALSE;
1239                 }
1240                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
1241                         checkrules_equality = TRUE;
1242         }
1243
1244         SetWinners(frags, checkrules_leaderfrags);
1245
1246         // The top two players have the same amount of lives? No timelimit then,
1247         // enter overtime...
1248
1249         if(checkrules_equality)
1250                 return WINNING_NEVER;
1251
1252         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1253         return WINNING_NO;
1254 }
1255
1256 // DM winning condition: game terminates if a player reached the fraglimit,
1257 // unless the first two players have the same score. The latter case also
1258 // breaks the time limit.
1259 float(float fraglimit) WinningCondition_MaxIndividualScore =
1260 {
1261         float checkrules_oldleaderfrags;
1262         entity head;
1263
1264         checkrules_oldleaderfrags = checkrules_leaderfrags;
1265         checkrules_leaderfrags = 0;
1266         checkrules_equality = FALSE;
1267         FOR_EACH_PLAYER(head)
1268         {
1269                 if(head.frags > checkrules_leaderfrags)
1270                 {
1271                         checkrules_leaderfrags = head.frags;
1272                         checkrules_equality = FALSE;
1273                 }
1274                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
1275                         checkrules_equality = TRUE;
1276         }
1277
1278         if(checkrules_leaderfrags > 0)
1279                 SetWinners(frags, checkrules_leaderfrags);
1280         else
1281                 ClearWinners();
1282
1283         if (!cvar("g_runematch"))
1284                 if (checkrules_leaderfrags != checkrules_oldleaderfrags)
1285                 {
1286                         if (checkrules_leaderfrags == fraglimit - 1)
1287                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.wav", 1, ATTN_NONE);
1288                         else if (checkrules_leaderfrags == fraglimit - 2)
1289                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.wav", 1, ATTN_NONE);
1290                         else if (checkrules_leaderfrags == fraglimit - 3)
1291                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.wav", 1, ATTN_NONE);
1292                 }
1293
1294         return GetWinningCode(fraglimit && checkrules_leaderfrags >= fraglimit, checkrules_equality);
1295 }
1296
1297 float(float fraglimit) WinningConditionBase_Teamplay =
1298 {
1299         tdm_old_score = tdm_max_score;
1300         tdm_max_score = max4(team1_score, team2_score, team3_score, team4_score);
1301
1302         checkrules_equality =
1303         (
1304                 (tdm_max_score > 0)
1305                 &&
1306                 (
1307                           (team1_score == tdm_max_score)
1308                         + (team2_score == tdm_max_score)
1309                         + (team3_score == tdm_max_score)
1310                         + (team4_score == tdm_max_score)
1311                         >= 2));
1312
1313         ClearWinners();
1314         if(tdm_max_score > 0)
1315         {
1316                 if(team1_score == tdm_max_score)
1317                         AddWinners(team, COLOR_TEAM1);
1318                 if(team2_score == tdm_max_score)
1319                         AddWinners(team, COLOR_TEAM2);
1320                 if(team3_score == tdm_max_score)
1321                         AddWinners(team, COLOR_TEAM3);
1322                 if(team4_score == tdm_max_score)
1323                         AddWinners(team, COLOR_TEAM4);
1324         }
1325
1326         if(!cvar("g_runematch") && !cvar("g_domination"))
1327                 if(tdm_max_score != tdm_old_score)
1328                 {
1329                         if(tdm_max_score == fraglimit - 1)
1330                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.wav", 1, ATTN_NONE);
1331                         else if(tdm_max_score == fraglimit - 2)
1332                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.wav", 1, ATTN_NONE);
1333                         else if(tdm_max_score == fraglimit - 3)
1334                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.wav", 1, ATTN_NONE);
1335                 }
1336
1337         return GetWinningCode(fraglimit && tdm_max_score >= fraglimit, checkrules_equality);
1338 }
1339
1340 // TDM winning condition: game terminates if a team's score sum reached the
1341 // fraglimit, unless the first two teams have the same total score. The latter
1342 // case also breaks the time limit.
1343 float(float fraglimit) WinningCondition_MaxTeamSum =
1344 {
1345         entity head;
1346
1347         team1_score = team2_score = team3_score = team4_score = 0;
1348
1349         FOR_EACH_PLAYER(head)
1350         {
1351                 if(head.team == COLOR_TEAM1)
1352                         team1_score += head.frags;
1353                 else if(head.team == COLOR_TEAM2)
1354                         team2_score += head.frags;
1355                 else if(head.team == COLOR_TEAM3)
1356                         team3_score += head.frags;
1357                 else if(head.team == COLOR_TEAM4)
1358                         team4_score += head.frags;
1359         }
1360
1361         return WinningConditionBase_Teamplay(fraglimit);
1362 }
1363
1364 // DOM/CTF winning condition: game terminates if the max of a team's players'
1365 // score reached the fraglimit, unless the first two teams have the same
1366 // maximum score. The latter case also breaks the time limit.
1367 float(float fraglimit) WinningCondition_MaxTeamMax =
1368 {
1369         entity head;
1370
1371         team1_score = team2_score = team3_score = team4_score = 0;
1372
1373         FOR_EACH_PLAYER(head)
1374         {
1375                 if(head.team == COLOR_TEAM1)
1376                 {
1377                         if(head.frags > team1_score)
1378                                 team1_score = head.frags;
1379                 }
1380                 else if(head.team == COLOR_TEAM2)
1381                 {
1382                         if(head.frags > team2_score)
1383                                 team2_score = head.frags;
1384                 }
1385                 else if(head.team == COLOR_TEAM3)
1386                 {
1387                         if(head.frags > team3_score)
1388                                 team3_score = head.frags;
1389                 }
1390                 else if(head.team == COLOR_TEAM4)
1391                 {
1392                         if(head.frags > team4_score)
1393                                 team4_score = head.frags;
1394                 }
1395         }
1396
1397         return WinningConditionBase_Teamplay(fraglimit);
1398 }
1399
1400 void print_to(entity e, string s)
1401 {
1402         if(e)
1403                 sprint(e, strcat(s, "\n"));
1404         else
1405                 ServerConsoleEcho(s, TRUE);
1406 }
1407
1408 void PrintScoreboardFor(entity e, string name, string colorcode, float whichteam)
1409 {
1410         entity head;
1411         float v;
1412         float teamvalue;
1413         float fragtotal;
1414         string s;
1415         float found;
1416         found = FALSE;
1417         teamvalue = 0;
1418         FOR_EACH_PLAYER(head)
1419         {
1420                 if(!whichteam || head.team == whichteam)
1421                 {
1422                         if(name != "")
1423                                 if(!found)
1424                                         print_to(e, strcat(" ", colorcode, name, ":"));
1425                         found = TRUE;
1426                         fragtotal = fragtotal + head.frags;
1427                         s = ftos(head.frags);
1428                         s = strcat(s, "/", ftos(head.deaths));
1429                         s = strcat(s, " @ ", ftos(head.ping));
1430                         if(clienttype(head) == CLIENTTYPE_BOT)
1431                                 s = strcat(s, "botms");
1432                         else
1433                                 s = strcat(s, "ms");
1434                         v = PlayerValue(head);
1435                         teamvalue += v;
1436                         s = strcat(s, " / ", ftos(v));
1437                         print_to(e, strcat("  ", colorcode, head.netname, colorcode, " (", s, ")"));
1438                 }
1439         }
1440         if(whichteam && found)
1441         {
1442                 s = ftos(fragtotal);
1443                 s = strcat(s, " / ", ftos(teamvalue));
1444                 print_to(e, strcat(colorcode, "  (total: ", s, ")"));
1445         }
1446 }
1447
1448 void PrintScoreboard(entity e)
1449 {
1450         print_to(e, strcat("Time:      ", ftos(time / 60)));
1451         print_to(e, strcat("Timelimit: ", ftos(cvar("timelimit"))));
1452         print_to(e, strcat("Fraglimit: ", ftos(cvar("fraglimit"))));
1453         print_to(e, "Scoreboard:");
1454         if(teams_matter)
1455         {
1456                 PrintScoreboardFor(e, "Red", "^1", COLOR_TEAM1);
1457                 PrintScoreboardFor(e, "Blue", "^4", COLOR_TEAM2);
1458                 PrintScoreboardFor(e, "Yellow", "^3", COLOR_TEAM3);
1459                 PrintScoreboardFor(e, "Pink", "^6", COLOR_TEAM4);
1460         }
1461         else
1462         {
1463                 PrintScoreboardFor(e, "", "^7", 0);
1464         }
1465         print_to(e, ".");
1466 }
1467
1468 void ShuffleMaplist()
1469 {
1470         string result;
1471         float start;
1472         float litems;
1473         float selected;
1474         float i;
1475
1476         result = cvar_string("g_maplist");
1477         litems = tokenize(result);
1478
1479         for(start = 0; start < litems - 1; ++start)
1480         {
1481                 result = "";
1482
1483                 // select a random item
1484                 selected = ceil(random() * (litems - start) + start) - 1;
1485
1486                 // shift this item to the place start
1487                 for(i = 0; i < start; ++i)
1488                         result = strcat(result, "'", argv(i), "'");
1489                 result = strcat(result, "'", argv(selected), "'");
1490                 for(i = start; i < litems; ++i)
1491                         if(i != selected)
1492                                 result = strcat(result, "'", argv(i), "'");
1493
1494                 litems = tokenize(result);
1495
1496                 //dprint(result, "\n");
1497         }
1498
1499         cvar_set("g_maplist", result);
1500 }
1501
1502 /*
1503 ============
1504 CheckRules_World
1505
1506 Exit deathmatch games upon conditions
1507 ============
1508 */
1509 void() CheckRules_World =
1510 {
1511         local float status;
1512         local float timelimit;
1513         local float fraglimit;
1514
1515         VoteThink();
1516         MapVote_Think();
1517
1518         SetDefaultAlpha();
1519
1520         /*
1521         MapVote_Think should now do that part
1522         if (intermission_running)
1523                 if (time >= intermission_exittime + 60)
1524                 {
1525                         if(!DoNextMapOverride())
1526                                 GotoNextMap();
1527                         return;
1528                 }
1529         */
1530
1531         if (gameover)   // someone else quit the game already
1532         {
1533                 if(player_count == 0) // Nobody there? Then let's go to the next map
1534                         MapVote_Start();
1535                         // this will actually check the player count in the next frame
1536                         // again, but this shouldn't hurt
1537                 return;
1538         }
1539
1540         timelimit = cvar("timelimit") * 60;
1541         fraglimit = cvar("fraglimit");
1542
1543         if(checkrules_overtimeend)
1544         {
1545                 if(!checkrules_overtimewarning)
1546                 {
1547                         checkrules_overtimewarning = TRUE;
1548                         //sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", 1, ATTN_NONE);
1549                         bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1550                 }
1551         }
1552         else
1553         {
1554                 if (timelimit && time >= timelimit)
1555                         InitiateOvertime();
1556         }
1557
1558         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1559         {
1560                 NextLevel();
1561                 return;
1562         }
1563
1564         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1565         {
1566                 checkrules_oneminutewarning = TRUE;
1567                 sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", 1, ATTN_NONE);
1568         }
1569
1570         status = WINNING_NO;
1571         if(cvar("g_lms"))
1572         {
1573                 status = WinningCondition_LMS();
1574         }
1575         else if (cvar("g_onslaught"))
1576         {
1577                 status = WinningCondition_Onslaught();
1578         }
1579         else
1580         {
1581                 if(teams_matter)
1582                 {
1583                         if(cvar("g_tdm") || cvar("g_runematch") || cvar("g_ctf") || cvar("g_domination") || cvar("g_keyhunt"))
1584                                 status = WinningCondition_MaxTeamSum(fraglimit);
1585                         //else if()
1586                         //      status = WinningCondition_MaxTeamMax(fraglimit);
1587                         else
1588                         {
1589                                 dprint("div0: How can this happen?\n");
1590                                 status = WinningCondition_MaxTeamMax(fraglimit);
1591                         }
1592                 }
1593                 else
1594                         status = WinningCondition_MaxIndividualScore(fraglimit);
1595         }
1596
1597         if(status == WINNING_STARTOVERTIME)
1598         {
1599                 status = WINNING_NEVER;
1600                 InitiateOvertime();
1601         }
1602
1603         if(status == WINNING_NEVER)
1604                 // equality cases! Nobody wins if the overtime ends in a draw.
1605                 ClearWinners();
1606
1607         if(checkrules_overtimeend)
1608                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1609                         status = WINNING_YES;
1610
1611         if(status == WINNING_YES)
1612                 NextLevel();
1613 };
1614
1615 float randsel_value;
1616 float randsel_priority;
1617 float randsel_count;
1618 void RandSel_Init()
1619 {
1620         randsel_value = -1;
1621         randsel_priority = -1;
1622         randsel_count = -1;
1623 }
1624 void RandSel_Add(float priority, float value)
1625 {
1626         if(priority > randsel_priority)
1627         {
1628                 randsel_priority = priority;
1629                 randsel_value = value;
1630                 randsel_count = 1;
1631         }
1632         else if(priority == randsel_priority)
1633         {
1634                 randsel_count += 1;
1635                 if(ceil(random() * randsel_count) == 1)
1636                         randsel_value = value;
1637         }
1638 }
1639
1640 float mapvote_nextthink;
1641 float mapvote_initialized;
1642 float mapvote_keeptwotime;
1643 float mapvote_timeout;
1644 string mapvote_message;
1645
1646 #define MAPVOTE_COUNT 10
1647 float mapvote_count;
1648 string mapvote_maps[MAPVOTE_COUNT];
1649 float mapvote_maps_suggested[MAPVOTE_COUNT];
1650 string mapvote_suggestions[MAPVOTE_COUNT];
1651 float mapvote_suggestion_ptr;
1652 float mapvote_maxlen;
1653 float mapvote_voters;
1654 float mapvote_votes[MAPVOTE_COUNT];
1655 float mapvote_run;
1656 .float mapvote;
1657
1658 void MapVote_ClearAllVotes()
1659 {
1660         FOR_EACH_CLIENT(other)
1661                 other.mapvote = 0;
1662 }
1663
1664 string MapVote_Suggest(string m)
1665 {
1666         float i;
1667         if(m == "")
1668                 return "That's not how to use this command.";
1669         if(!cvar("g_maplist_votable_suggestions"))
1670                 return "Suggestions are not accepted on this server.";
1671         if(mapvote_initialized)
1672                 return "Can't suggest - voting is already in progress!";
1673         if(!cvar("g_maplist_votable_suggestions_change_gametype"))
1674                 if(!IsSameGametype(m))
1675                         return "This server does not allow changing the game type by map suggestions.";
1676         if(!cvar("g_maplist_votable_override_mostrecent"))
1677                 if(Map_IsRecent(m))
1678                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1679
1680         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1681                 return "The map you suggested is not available on this server.";
1682         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1683                 if(mapvote_suggestions[i] == m)
1684                         return "This map was already suggested.";
1685         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1686         {
1687                 i = ceil(random() * mapvote_suggestion_ptr) - 1;
1688         }
1689         else
1690         {
1691                 i = mapvote_suggestion_ptr;
1692                 mapvote_suggestion_ptr += 1;
1693         }
1694         if(mapvote_suggestions[i] != "")
1695                 strunzone(mapvote_suggestions[i]);
1696         mapvote_suggestions[i] = strzone(m);
1697         GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid), ":", self.netname), TRUE);
1698         return "Suggestion accepted.";
1699 }
1700
1701 void MapVote_AddVotable(string nextMap, float isSuggestion)
1702 {
1703         float j;
1704         if(nextMap == "")
1705                 return;
1706         for(j = 0; j < mapvote_count; ++j)
1707                 if(mapvote_maps[j] == nextMap)
1708                         return;
1709         if(strlen(nextMap) > mapvote_maxlen)
1710                 mapvote_maxlen = strlen(nextMap);
1711         mapvote_maps[mapvote_count] = strzone(nextMap);
1712         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1713         mapvote_count += 1;
1714 }
1715
1716 void MapVote_Init()
1717 {
1718         float i;
1719         float nmax, smax;
1720
1721         MapVote_ClearAllVotes();
1722
1723         nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
1724         smax = min(nmax, cvar("g_maplist_votable_suggestions"));
1725         mapvote_count = 0;
1726
1727         for(i = 0; i < 100 && mapvote_count < smax; ++i)
1728                 MapVote_AddVotable(mapvote_suggestions[ceil(random() * mapvote_suggestion_ptr) - 1], TRUE);
1729
1730         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1731                 MapVote_AddVotable(GetNextMap(), FALSE);
1732
1733         if(mapvote_count == 0)
1734         {
1735                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1736                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
1737                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1738                         MapVote_AddVotable(GetNextMap(), FALSE);
1739         }
1740
1741         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
1742
1743         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
1744         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
1745         if(mapvote_count < 3 || mapvote_keeptwotime <= time)
1746                 mapvote_keeptwotime = 0;
1747         mapvote_message = "Choose a map and press its key!";
1748 }
1749 float MapVote_Finished(float mappos)
1750 {
1751         string result;
1752         float i;
1753
1754         result = strcat(":vote:finished:", mapvote_maps[mappos]);
1755         result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
1756         for(i = 0; i < mapvote_count; ++i)
1757                 if(i != mappos)
1758                         if(mapvote_maps[i] != "")
1759                         {
1760                                 result = strcat(result, ":", mapvote_maps[i]);
1761                                 result = strcat(result, ":", ftos(mapvote_votes[i]));
1762                         }
1763         GameLogEcho(result, FALSE);
1764         if(mapvote_maps_suggested[mappos])
1765                 GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]), FALSE);
1766
1767         FOR_EACH_REALCLIENT(other)
1768                 FixClientCvars(other);
1769
1770         Map_Goto_SetStr(mapvote_maps[mappos]);
1771         Map_Goto();
1772         return TRUE;
1773 }
1774 void MapVote_CheckRules_1()
1775 {
1776         float i;
1777
1778         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1779         {
1780                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
1781                 mapvote_votes[i] = 0;
1782         }
1783
1784         mapvote_voters = 0;
1785         FOR_EACH_REALCLIENT(other)
1786         {
1787                 ++mapvote_voters;
1788                 if(other.mapvote)
1789                 {
1790                         i = other.mapvote - 1;
1791                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
1792                         mapvote_votes[i] = mapvote_votes[i] + 1;
1793                 }
1794         }
1795 }
1796
1797 float MapVote_CheckRules_2()
1798 {
1799         float i;
1800         float firstPlace, secondPlace;
1801         float firstPlaceVotes, secondPlaceVotes;
1802         string result;
1803
1804         RandSel_Init();
1805         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1806                 RandSel_Add(mapvote_votes[i], i);
1807         firstPlace = randsel_value;
1808         firstPlaceVotes = randsel_priority;
1809         //dprint("First place: ", ftos(firstPlace), "\n");
1810         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
1811
1812         RandSel_Init();
1813         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1814                 if(i != firstPlace)
1815                         RandSel_Add(mapvote_votes[i], i);
1816         secondPlace = randsel_value;
1817         secondPlaceVotes = randsel_priority;
1818         //dprint("Second place: ", ftos(secondPlace), "\n");
1819         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
1820
1821         if(firstPlace == -1)
1822                 error("No first place in map vote... WTF?");
1823
1824         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters - firstPlaceVotes) < firstPlaceVotes)
1825                 return MapVote_Finished(firstPlace);
1826
1827         if(mapvote_keeptwotime)
1828                 if(time > mapvote_keeptwotime || (mapvote_voters - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
1829                 {
1830                         mapvote_message = "Now decide between the TOP TWO!";
1831                         mapvote_keeptwotime = 0;
1832                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
1833                         result = strcat(result, ":", ftos(firstPlaceVotes));
1834                         result = strcat(result, ":", mapvote_maps[secondPlace]);
1835                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
1836                         for(i = 0; i < mapvote_count; ++i)
1837                                 if(i != firstPlace)
1838                                         if(i != secondPlace)
1839                                                 if(mapvote_maps[i] != "")
1840                                                 {
1841                                                         result = strcat(result, ":", mapvote_maps[i]);
1842                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
1843                                                         strunzone(mapvote_maps[i]);
1844                                                         mapvote_maps[i] = "";
1845                                                 }
1846                         GameLogEcho(result, FALSE);
1847                 }
1848
1849         return FALSE;
1850 }
1851 void MapVote_Tick()
1852 {
1853         string msgstr;
1854         string tmp;
1855         float i;
1856         float keeptwo;
1857
1858         keeptwo = mapvote_keeptwotime;
1859         MapVote_CheckRules_1(); // count
1860         if(MapVote_CheckRules_2()) // decide
1861                 return;
1862
1863         FOR_EACH_REALCLIENT(other)
1864         {
1865                 // hide scoreboard again
1866                 if(other.health != 2342)
1867                 {
1868                         other.health = 2342;
1869                         other.impulse = 0;
1870                         if(clienttype(other) == CLIENTTYPE_REAL)
1871                         {
1872                                 stuffcmd(other, "\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
1873                                 msg_entity = other;
1874                                 WriteByte(MSG_ONE, SVC_FINALE);
1875                                 WriteString(MSG_ONE, "");
1876                                 for(i = 0; i < mapvote_count; ++i)
1877                                         if(mapvote_maps[i] != "")
1878                                         {
1879                                                 tmp = mapvote_maps[i];
1880                                                 sprint(other, strcat("map voting: type ^1impulse ", ftos(i), "^7 to vote for ", tmp, "\n"));
1881                                         }
1882                         }
1883                 }
1884
1885                 // notify about keep-two
1886                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
1887                         play2(other, "misc/invshot.wav");
1888
1889                 // clear possibly invalid votes
1890                 if(mapvote_maps[other.mapvote - 1] == "")
1891                         other.mapvote = 0;
1892                 // use impulses as new vote
1893                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
1894                         if(mapvote_maps[other.impulse - 1] != "")
1895                                 other.mapvote = other.impulse;
1896                 other.impulse = 0;
1897         }
1898
1899         MapVote_CheckRules_1(); // just count
1900
1901         FOR_EACH_REALCLIENT(other)
1902         {
1903                 // display voting screen
1904                 msgstr = "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n";
1905                 msgstr = substring(msgstr, 0, strlen(msgstr) - mapvote_count);
1906                 msgstr = strcat(msgstr, mapvote_message);
1907                 msgstr = strcat(msgstr, "\n\n");
1908                 for(i = 0; i < mapvote_count; ++i)
1909                         if(mapvote_maps[i] == "")
1910                                 msgstr = strcat(msgstr, "\n");
1911                         else
1912                         {
1913                                 tmp = mapvote_maps[i];
1914                                 tmp = strpad(mapvote_maxlen, tmp);
1915                                 tmp = strcat(ftos(math_mod(i + 1, 10)), ": ", tmp);
1916                                 tmp = strcat(tmp, " ^2(", ftos(mapvote_votes[i]), " vote");
1917                                 if(mapvote_votes[i] != 1)
1918                                         tmp = strcat(tmp, "s");
1919                                 tmp = strcat(tmp, ")");
1920                                 tmp = strpad(mapvote_maxlen + 15, tmp);
1921                                 if(other.mapvote == i + 1)
1922                                         msgstr = strcat(msgstr, "^3> ", tmp, "\n");
1923                                 else
1924                                         msgstr = strcat(msgstr, "^7  ", tmp, "\n");
1925                         }
1926                 i = ceil(mapvote_timeout - time);
1927                 msgstr = strcat(msgstr, "\n\n", ftos(i), " second");
1928                 if(i != 1)
1929                         msgstr = strcat(msgstr, "s");
1930                 msgstr = strcat(msgstr, " left");
1931
1932                 centerprint_atprio(other, CENTERPRIO_MAPVOTE, msgstr);
1933         }
1934 }
1935 void MapVote_Start()
1936 {
1937         mapvote_run = TRUE;
1938 }
1939 void MapVote_Think()
1940 {
1941         if(!mapvote_run)
1942                 return;
1943
1944         if(alreadychangedlevel)
1945                 return;
1946
1947         if(time < mapvote_nextthink)
1948                 return;
1949         //dprint("tick\n");
1950
1951         mapvote_nextthink = time + 0.5;
1952
1953         if(!mapvote_initialized)
1954         {
1955                 mapvote_initialized = TRUE;
1956                 if(DoNextMapOverride())
1957                 {
1958                         alreadychangedlevel = TRUE;
1959                         return;
1960                 }
1961                 if(!cvar("g_maplist_votable") || player_count <= 0)
1962                 {
1963                         GotoNextMap();
1964                         return;
1965                 }
1966                 MapVote_Init();
1967         }
1968
1969         MapVote_Tick();
1970 };
1971
1972 string GotoMap(string m)
1973 {
1974         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1975                 return "The map you chose is not available on this server.";
1976         cvar_set("nextmap", m);
1977         cvar_set("timelimit", "-1");
1978         if(mapvote_initialized || alreadychangedlevel)
1979         {
1980                 if(DoNextMapOverride())
1981                         return "Map switch initiated.";
1982                 else
1983                         return "Hm... no. For some reason I like THIS map more.";
1984         }
1985         else
1986                 return "Map switch will happen after scoreboard.";
1987 }
1988
1989
1990 void EndFrame()
1991 {
1992         FOR_EACH_REALCLIENT(self)
1993         {
1994                 if(self.classname == "spectator")
1995                 {
1996                         if(self.enemy.hitsound)
1997                                 play2(self, "misc/hit.wav");
1998                 }
1999                 else
2000                 {
2001                         if(self.hitsound)
2002                                 play2(self, "misc/hit.wav");
2003                 }
2004         }
2005         FOR_EACH_CLIENT(self)
2006                 self.hitsound = FALSE;
2007 }
2008
2009
2010 /*
2011  * RedirectionThink:
2012  * returns TRUE if redirecting
2013  */
2014 float redirection_timeout;
2015 float redirection_nextthink;
2016 float RedirectionThink()
2017 {
2018         float clients_found;
2019
2020         if(redirection_target == "")
2021                 return FALSE;
2022
2023         if(!redirection_timeout)
2024         {
2025                 cvar_set("sv_public", "-2");
2026                 redirection_timeout = time + 0.5; // this will only try twice... should be able to keep more clients
2027                 if(redirection_target == "self")
2028                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2029                 else
2030                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2031         }
2032
2033         if(time < redirection_nextthink)
2034                 return TRUE;
2035
2036         redirection_nextthink = time + 1;
2037
2038         clients_found = 0;
2039         FOR_EACH_REALCLIENT(self)
2040         {
2041                 ServerConsoleEcho(strcat("Redirecting: sending connect command to ", self.netname), FALSE);
2042                 if(redirection_target == "self")
2043                         stuffcmd(self, "\ndisconnect; reconnect\n");
2044                 else
2045                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2046                 ++clients_found;
2047         }
2048
2049         ServerConsoleEcho(strcat("Redirecting: ", ftos(clients_found), " clients left."), FALSE);
2050
2051         if(time > redirection_timeout || clients_found == 0)
2052                 localcmd("\nwait; wait; wait; quit\n");
2053
2054         return TRUE;
2055 }