data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2
   3 string GetMapname();
   4 void GotoNextMap();
   5 void HandleMaplistShuffleCommands();
   6 float() DoNextMapOverride;
   7
   8 void SetDefaultAlpha()
   9 {
  10         if(cvar("g_running_guns"))
  11         {
  12                 default_player_alpha = -1;
  13                 default_weapon_alpha = +1;
  14         }
  15         else if(cvar("g_cloaked"))
  16         {
  17                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  18                 default_weapon_alpha = default_player_alpha;
  19         }
  20         else
  21         {
  22                 default_player_alpha = cvar("g_player_alpha");
  23                 if(default_player_alpha <= 0)
  24                         default_player_alpha = 1;
  25                 default_weapon_alpha = default_player_alpha;
  26         }
  27 }
  28
  29 void fteqcc_testbugs()
  30 {
  31         float a, b;
  32
  33         if(!cvar("developer_fteqccbugs"))
  34                 return;
  35
  36         dprint("*** fteqcc test: checking for bugs...\n");
  37
  38         a = 1;
  39         b = 5;
  40         if(sqrt(a) - sqrt(b - a) == 0)
  41                 dprint("*** fteqcc test: found same-function-twice bug\n");
  42         else
  43                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  44
  45         world.frags = -10;
  46         world.enemy = world;
  47         world.enemy.frags += 10;
  48         if(world.frags > 0.2 || world.frags < -0.2) // don't error out if it's just roundoff errors
  49                 dprint("*** fteqcc test: found += bug\n");
  50         else
  51                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  52         world.frags = 0;
  53 }
  54
  55 void GotoFirstMap()
  56 {
  57         if(cvar("_sv_init"))
  58         {
  59                 cvar_set("_sv_init", "0");
  60                 HandleMaplistShuffleCommands();
  61                 tokenize(cvar_string("g_maplist"));
  62                 if(argv(0) != GetMapname())
  63                 {
  64                         cvar_set("nextmap", argv(0));
  65                         if(!DoNextMapOverride())
  66                                 GotoNextMap();
  67                 }
  68         }
  69 }
  70
  71 float world_already_spawned;
  72 void worldspawn (void)
  73 {
  74         if(world_already_spawned)
  75                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
  76         world_already_spawned = TRUE;
  77         // Precache all player models
  78         // Workaround for "invisible players"
  79         precache_model("models/player/carni.zym");
  80         precache_model("models/player/crash.zym");
  81         precache_model("models/player/grunt.zym");
  82         precache_model("models/player/headhunter.zym");
  83         precache_model("models/player/insurrectionist.zym");
  84         precache_model("models/player/jeandarc.zym");
  85         precache_model("models/player/lurk.zym");
  86         precache_model("models/player/lycanthrope.zym");
  87         precache_model("models/player/marine.zym");
  88         precache_model("models/player/nexus.zym");
  89         precache_model("models/player/pyria.zym");
  90         precache_model("models/player/shock.zym");
  91         precache_model("models/player/skadi.zym");
  92         precache_model("models/player/specop.zym");
  93         precache_model("models/player/visitant.zym");
  94
  95         //precache_model ("progs/beam.mdl");
  96         precache_model ("models/bullet.mdl");
  97         precache_model ("models/casing_bronze.mdl");
  98         precache_model ("models/casing_shell.mdl");
  99         precache_model ("models/casing_steel.mdl");
 100         precache_model ("models/ebomb.mdl");
 101         precache_model ("models/elaser.mdl");
 102         precache_model ("models/flash.md3");
 103         precache_model ("models/gibs/bloodyskull.md3");
 104         precache_model ("models/gibs/chunk.mdl");
 105         precache_model ("models/gibs/eye.md3");
 106         precache_model ("models/gibs/gib1.md3");
 107         //precache_model ("models/gibs/gib2.md3");
 108         //precache_model ("models/gibs/gib3.md3");
 109         //precache_model ("models/gibs/gib4.md3");
 110         precache_model ("models/gibs/gib5.md3");
 111         //precache_model ("models/gibs/gib6.md3");
 112         precache_model ("models/gibs/gib1.mdl");
 113         precache_model ("models/gibs/gib2.mdl");
 114         precache_model ("models/gibs/gib3.mdl");
 115         precache_model ("models/grenademodel.md3");
 116         precache_model ("models/hagarmissile.mdl");
 117         precache_model ("models/items/a_bullets.mdl");
 118         precache_model ("models/items/a_cells.md3");
 119         precache_model ("models/items/a_rockets.md3");
 120         precache_model ("models/items/a_shells.md3");
 121         precache_model ("models/items/g_a1.md3");
 122         precache_model ("models/items/g_a25.md3");
 123         precache_model ("models/items/g_h1.md3");
 124         precache_model ("models/items/g_h25.md3");
 125         precache_model ("models/items/g_h100.md3");
 126         precache_model ("models/items/g_invincible.md3");
 127         precache_model ("models/items/g_strength.md3");
 128         precache_model ("models/laser.mdl");
 129         precache_model ("models/misc/chatbubble.spr");
 130         precache_model ("models/misc/teambubble.spr");
 131         precache_model ("models/nexflash.md3");
 132         precache_model ("models/plasma.mdl");
 133         precache_model ("models/plasmatrail.mdl");
 134         precache_model ("models/rocket.md3");
 135         //precache_model ("models/sprites/grenexpl.spr");
 136         precache_model ("models/runematch/rune.mdl");
 137         precache_model ("models/runematch/curse.mdl");
 138         //precache_model ("models/sprites/hagar.spr");
 139         //precache_model ("models/sprites/muzzleflash.spr32");
 140         //precache_model ("models/sprites/electrocombo.spr32");
 141         //precache_model ("models/sprites/plasmahitwall.spr32");
 142         //precache_model ("models/sprites/plasmashot.spr32");
 143         //precache_model ("models/sprites/rockexpl.spr");
 144         precache_model ("models/tracer.mdl");
 145         precache_model ("models/uziflash.md3");
 146         precache_model ("models/weapons/g_crylink.md3");
 147         precache_model ("models/weapons/g_electro.md3");
 148         precache_model ("models/weapons/g_gl.md3");
 149         precache_model ("models/weapons/g_hagar.md3");
 150         precache_model ("models/weapons/g_nex.md3");
 151         precache_model ("models/weapons/g_rl.md3");
 152         precache_model ("models/weapons/g_shotgun.md3");
 153         precache_model ("models/weapons/g_uzi.md3");
 154         precache_model ("models/weapons/v_crylink.md3");
 155         precache_model ("models/weapons/v_electro.md3");
 156         precache_model ("models/weapons/v_gl.md3");
 157         precache_model ("models/weapons/v_hagar.md3");
 158         precache_model ("models/weapons/v_laser.md3");
 159         precache_model ("models/weapons/v_nex.md3");
 160         precache_model ("models/weapons/v_rl.md3");
 161         precache_model ("models/weapons/v_shotgun.md3");
 162         precache_model ("models/weapons/v_uzi.md3");
 163         precache_model ("models/weapons/w_crylink.zym");
 164         precache_model ("models/weapons/w_electro.zym");
 165         precache_model ("models/weapons/w_gl.zym");
 166         precache_model ("models/weapons/w_hagar.zym");
 167         precache_model ("models/weapons/w_laser.zym");
 168         precache_model ("models/weapons/w_nex.zym");
 169         precache_model ("models/weapons/w_rl.zym");
 170         precache_model ("models/weapons/w_shotgun.zym");
 171         precache_model ("models/weapons/w_uzi.zym");
 172
 173         // laser for laser-guided weapons
 174         precache_model ("models/laser_dot.mdl");
 175
 176         precache_sound ("misc/null.wav");
 177         precache_sound ("misc/armor1.wav");
 178         precache_sound ("misc/armor25.wav");
 179         precache_sound ("misc/armorimpact.wav");
 180         precache_sound ("misc/bodyimpact1.wav");
 181         precache_sound ("misc/bodyimpact2.wav");
 182         precache_sound ("misc/gib.wav");
 183         precache_sound ("misc/gib_splat01.wav");
 184         precache_sound ("misc/gib_splat02.wav");
 185         precache_sound ("misc/gib_splat03.wav");
 186         precache_sound ("misc/gib_splat04.wav");
 187         //precache_sound ("misc/h2ohit.wav");
 188         precache_sound ("misc/hit.wav");
 189         precache_sound ("misc/footstep01.wav");
 190         precache_sound ("misc/footstep02.wav");
 191         precache_sound ("misc/footstep03.wav");
 192         precache_sound ("misc/footstep04.wav");
 193         precache_sound ("misc/footstep05.wav");
 194         precache_sound ("misc/footstep06.wav");
 195         precache_sound ("misc/hitground1.ogg");
 196         precache_sound ("misc/hitground2.ogg");
 197         precache_sound ("misc/hitground3.ogg");
 198         precache_sound ("misc/hitground4.ogg");
 199         precache_sound ("misc/itempickup.ogg");
 200         precache_sound ("misc/itemrespawn.ogg");
 201         precache_sound ("misc/jumppad.ogg");
 202         precache_sound ("misc/mediumhealth.ogg");
 203         precache_sound ("misc/megahealth.ogg");
 204         precache_sound ("misc/minihealth.ogg");
 205         precache_sound ("misc/powerup.ogg");
 206         precache_sound ("misc/powerup_shield.ogg");
 207         precache_sound ("misc/talk.wav");
 208         precache_sound ("misc/teleport.ogg");
 209         precache_sound ("plats/medplat1.wav");
 210         precache_sound ("plats/medplat2.wav");
 211         precache_sound ("player/lava.wav");
 212         precache_sound ("player/slime.wav");
 213         precache_sound ("weapons/crylink_fire.ogg");
 214         precache_sound ("weapons/electro_bounce.ogg");
 215         precache_sound ("weapons/electro_fire.ogg");
 216         precache_sound ("weapons/electro_fire2.ogg");
 217         precache_sound ("weapons/electro_fly.wav");
 218         precache_sound ("weapons/electro_impact.ogg");
 219         precache_sound ("weapons/electro_impact_combo.ogg");
 220         //precache_sound ("weapons/grenade_bounce.ogg");
 221         precache_sound ("weapons/grenade_bounce1.ogg");
 222         precache_sound ("weapons/grenade_bounce2.ogg");
 223         precache_sound ("weapons/grenade_bounce3.ogg");
 224         precache_sound ("weapons/grenade_fire.ogg");
 225         precache_sound ("weapons/grenade_impact.ogg");
 226         precache_sound ("weapons/hagar_fire.ogg");
 227         precache_sound ("weapons/hagexp1.ogg");
 228         precache_sound ("weapons/hagexp2.ogg");
 229         precache_sound ("weapons/hagexp3.ogg");
 230         precache_sound ("weapons/hook_fire.ogg");
 231         precache_sound ("weapons/hook_impact.ogg");
 232         precache_sound ("weapons/lasergun_fire.ogg");
 233         precache_sound ("weapons/laserimpact.ogg");
 234         precache_sound ("weapons/nexfire.ogg");
 235         precache_sound ("weapons/neximpact.ogg");
 236         precache_sound ("weapons/ric1.ogg");
 237         precache_sound ("weapons/ric2.ogg");
 238         precache_sound ("weapons/ric3.ogg");
 239         precache_sound ("weapons/rocket_fire.ogg");
 240         precache_sound ("weapons/rocket_fly.wav");
 241         precache_sound ("weapons/rocket_impact.ogg");
 242         precache_sound ("weapons/rocket_det.ogg");
 243         precache_sound ("weapons/shotgun_fire.ogg");
 244         precache_sound ("weapons/tink1.ogg");
 245         precache_sound ("weapons/uzi_fire.ogg");
 246         precache_sound ("weapons/weapon_switch.ogg");
 247         precache_sound ("weapons/weaponpickup.ogg");
 248         precache_sound ("weapons/strength_fire.ogg");
 249
 250         //precache_sound ("announce/male/kill10.ogg");
 251         //precache_sound ("announce/male/kill15.ogg");
 252         //precache_sound ("announce/male/kill20.ogg");
 253         //precache_sound ("announce/male/kill25.ogg");
 254         //precache_sound ("announce/male/kill3.ogg");
 255         //precache_sound ("announce/male/kill30.ogg");
 256         //precache_sound ("announce/male/kill4.ogg");
 257         //precache_sound ("announce/male/kill5.ogg");
 258         //precache_sound ("announce/male/kill6.ogg");
 259         //precache_sound ("announce/male/mapkill1.ogg");
 260         //precache_sound ("announce/robotic/last_second_save.ogg");
 261         //precache_sound ("announce/robotic/narrowly_averted.ogg");
 262         //precache_sound ("minstagib/mockery.ogg");
 263
 264         // announcer sounds - male
 265         precache_sound ("announcer/male/03kills.ogg");
 266         precache_sound ("announcer/male/05kills.ogg");
 267         precache_sound ("announcer/male/10kills.ogg");
 268         precache_sound ("announcer/male/15kills.ogg");
 269         precache_sound ("announcer/male/20kills.ogg");
 270         precache_sound ("announcer/male/25kills.ogg");
 271         precache_sound ("announcer/male/30kills.ogg");
 272         precache_sound ("announcer/male/botlike.ogg");
 273         precache_sound ("announcer/male/electrobitch.ogg");
 274         precache_sound ("announcer/male/welcome.ogg");
 275         precache_sound ("announcer/male/yoda.ogg");
 276
 277         // announcer sounds - robotic
 278         precache_sound ("announcer/robotic/1fragleft.ogg");
 279         precache_sound ("announcer/robotic/1minuteremains.ogg");
 280         precache_sound ("announcer/robotic/2fragsleft.ogg");
 281         precache_sound ("announcer/robotic/3fragsleft.ogg");
 282         precache_sound ("announcer/robotic/lastsecond.ogg");
 283         precache_sound ("announcer/robotic/narrowly.ogg");
 284         precache_sound ("announcer/robotic/1.ogg");
 285         precache_sound ("announcer/robotic/2.ogg");
 286         precache_sound ("announcer/robotic/3.ogg");
 287         precache_sound ("announcer/robotic/4.ogg");
 288         precache_sound ("announcer/robotic/5.ogg");
 289         precache_sound ("announcer/robotic/6.ogg");
 290         precache_sound ("announcer/robotic/7.ogg");
 291         precache_sound ("announcer/robotic/8.ogg");
 292         precache_sound ("announcer/robotic/9.ogg");
 293         precache_sound ("announcer/robotic/10.ogg");
 294
 295         // plays music for the level if there is any
 296         if (self.noise)
 297         {
 298                 precache_sound (self.noise);
 299                 ambientsound ('0 0 0', self.noise, 1.00, ATTN_NONE);
 300         }
 301
 302         // 0 normal
 303         lightstyle(0, "m");
 304
 305         // 1 FLICKER (first variety)
 306         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 307
 308         // 2 SLOW STRONG PULSE
 309         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 310
 311         // 3 CANDLE (first variety)
 312         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 313
 314         // 4 FAST STROBE
 315         lightstyle(4, "mamamamamama");
 316
 317         // 5 GENTLE PULSE 1
 318         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 319
 320         // 6 FLICKER (second variety)
 321         lightstyle(6, "nmonqnmomnmomomno");
 322
 323         // 7 CANDLE (second variety)
 324         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 325
 326         // 8 CANDLE (third variety)
 327         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 328
 329         // 9 SLOW STROBE (fourth variety)
 330         lightstyle(9, "aaaaaaaazzzzzzzz");
 331
 332         // 10 FLUORESCENT FLICKER
 333         lightstyle(10, "mmamammmmammamamaaamammma");
 334
 335         // 11 SLOW PULSE NOT FADE TO BLACK
 336         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 337
 338         // styles 32-62 are assigned by the light program for switchable lights
 339
 340         // 63 testing
 341         lightstyle(63, "a");
 342
 343         registercvar("_g_maplist_shufflenow", "0");
 344         registercvar("_g_maplist_have_shuffled", "0");
 345         registercvar("_g_maplist_add", "");
 346         registercvar("_g_maplist_remove", "");
 347         registercvar("_g_maplist_putfirst", "");
 348
 349         player_count = 0;
 350         lms_lowest_lives = 0;
 351         lms_next_place = 0;
 352
 353         GotoFirstMap();
 354
 355         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 356         if(bot_waypoints_for_items == 1)
 357                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 358                         bot_waypoints_for_items = 0;
 359
 360         if(cvar("g_campaign"))
 361                 CampaignPreInit();
 362
 363         InitGameplayMode();
 364         //if (cvar("g_domination"))
 365         //      dom_init();
 366
 367         local entity head;
 368         head = nextent(world);
 369         maxclients = 0;
 370         while(head)
 371         {
 372                 maxclients++;
 373                 head = nextent(head);
 374         }
 375
 376         GameLogInit(); // prepare everything
 377         if(cvar("sv_eventlog"))
 378         {
 379                 local string s;
 380                 GameLogEcho(":logversion:2", FALSE);
 381                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 382                 s = strcat(s, ftos(random()));
 383                 GameLogEcho(strcat(":gamestart:", GetMapname(), ":", s), FALSE);
 384                 s = ":gameinfo:mutators:LIST";
 385                 if(cvar("g_grappling_hook"))
 386                         s = strcat(s, ":grappling_hook");
 387                 if(!cvar("g_use_ammunition"))
 388                         s = strcat(s, ":no_use_ammunition");
 389                 if(!cvar("g_pickup_items"))
 390                         s = strcat(s, ":no_pickup_items");
 391                 if(cvar("g_instagib"))
 392                         s = strcat(s, ":instagib");
 393                 if(cvar("g_rocketarena"))
 394                         s = strcat(s, ":rockerarena");
 395                 if(cvar("g_nixnex"))
 396                         s = strcat(s, ":nixnex");
 397                 if(cvar("g_vampire"))
 398                         s = strcat(s, ":vampire");
 399                 if(cvar("g_laserguided_missile"))
 400                         s = strcat(s, ":laserguided_missile");
 401                 if(cvar("g_norecoil"))
 402                         s = strcat(s, ":norecoil");
 403                 if(cvar("g_midair"))
 404                         s = strcat(s, ":midair");
 405                 if(cvar("g_minstagib"))
 406                         s = strcat(s, ":minstagib");
 407                 GameLogEcho(s, FALSE);
 408                 GameLogEcho(":gameinfo:end", FALSE);
 409         }
 410
 411         cvar_set("nextmap", "");
 412
 413         SetDefaultAlpha();
 414
 415         if(cvar("g_campaign"))
 416                 CampaignPostInit();
 417
 418         // fteqcc_testbugs();
 419 }
 420
 421 void light (void)
 422 {
 423         //makestatic (self); // Who the f___ did that?
 424         remove(self);
 425 }
 426
 427 float( string pFilename ) TryFile =
 428 {
 429         local float lHandle;
 430         dprint("TryFile(\"", pFilename, "\")\n");
 431         lHandle = fopen( pFilename, FILE_READ );
 432         if( lHandle != -1 ) {
 433                 fclose( lHandle );
 434                 return TRUE;
 435         } else {
 436                 return FALSE;
 437         }
 438 };
 439
 440 string GetGametype()
 441 {
 442         if (game == GAME_DEATHMATCH)
 443                 return "dm";
 444         else if (game == GAME_TEAM_DEATHMATCH)
 445                 return "tdm";
 446         else if (game == GAME_DOMINATION)
 447                 return "dom";
 448         else if (game == GAME_CTF)
 449                 return "ctf";
 450         else if (game == GAME_RUNEMATCH)
 451                 return "rune";
 452         else if (game == GAME_LMS)
 453                 return "lms";
 454         return "dm";
 455 }
 456
 457 string getmapname_stored;
 458 string GetMapname()
 459 {
 460         if(getmapname_stored == "")
 461                 getmapname_stored = strzone(strcat(GetGametype(), "_", mapname));
 462         return getmapname_stored;
 463 }
 464
 465 float Map_Count, Map_Current;
 466 string Map_Current_Name;
 467
 468 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 469 float GetMaplistPosition()
 470 {
 471         float pos, idx;
 472         string map;
 473
 474         map = GetMapname();
 475         idx = cvar("g_maplist_index");
 476
 477         if(idx >= 0)
 478                 if(idx < Map_Count)
 479                         if(map == argv(idx))
 480                                 return idx;
 481
 482         for(pos = 0; pos < Map_Count; ++pos)
 483                 if(map == argv(pos))
 484                         return pos;
 485
 486         // resume normal maplist rotation if current map is not in g_maplist
 487         return idx;
 488 }
 489
 490 float MapHasRightSize(string map)
 491 {
 492         // open map size restriction file
 493         float fh;
 494         dprint("opensize "); dprint(map);
 495         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 496         if(fh >= 0)
 497         {
 498                 float mapmin, mapmax;
 499                 dprint(": ok, ");
 500                 mapmin = stof(fgets(fh));
 501                 mapmax = stof(fgets(fh));
 502                 fclose(fh);
 503                 if(player_count < mapmin)
 504                 {
 505                         dprint("not enough\n");
 506                         return FALSE;
 507                 }
 508                 if(player_count > mapmax)
 509                 {
 510                         dprint("too many\n");
 511                         return FALSE;
 512                 }
 513                 dprint("right size\n");
 514                 return TRUE;
 515         }
 516         dprint(": not found\n");
 517         return TRUE;
 518 }
 519
 520 string Map_Filename(float position)
 521 {
 522         // FIXME unused
 523         return strcat("maps/", argv(position), ".mapcfg");
 524 }
 525
 526 float(float position, float pass) Map_Check =
 527 {
 528         string filename;
 529         string map_next;
 530         map_next = argv(position);
 531         if(pass <= 1)
 532                 if(map_next == Map_Current_Name) // same map again in first pass?
 533                         return 0;
 534         filename = Map_Filename(position);
 535         if(TryFile(filename))
 536         {
 537                 if(pass == 2)
 538                         return 1;
 539                 if(MapHasRightSize(argv(position)))
 540                         return 1;
 541                 return 0;
 542         }
 543         else
 544                 dprint( "Couldn't find '", filename, "'..\n" );
 545
 546         return 0;
 547 }
 548
 549 void(string nextmapname) Map_Goto_SetStr =
 550 {
 551         if(getmapname_stored != "")
 552                 strunzone(getmapname_stored);
 553         if(nextmapname == "")
 554                 getmapname_stored = "";
 555         else
 556                 getmapname_stored = strzone(nextmapname);
 557 }
 558
 559 void(float position) Map_Goto_SetFloat =
 560 {
 561         cvar_set("g_maplist_index", ftos(position));
 562         Map_Goto_SetStr(argv(position));
 563 }
 564
 565 void() GameResetCfg =
 566 {
 567         // if an exit cfg is defined by exiting map, exec it.
 568         string exit_cfg;
 569         exit_cfg = cvar_string("exit_cfg");
 570         if(exit_cfg != "")
 571                 localcmd(strcat("exec \"", exit_cfg, "\"\n"));
 572
 573         localcmd("exec game_reset.cfg\n");
 574 };
 575
 576 void() Map_Goto =
 577 {
 578         GameResetCfg();
 579         localcmd(strcat("exec \"maps/", getmapname_stored ,".mapcfg\"\n"));
 580 }
 581
 582 // return codes of map selectors:
 583 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 584 //   -2 = permanent failure
 585 float() MaplistMethod_Iterate = // usual method
 586 {
 587         float pass, i;
 588
 589         for(pass = 1; pass <= 2; ++pass)
 590         {
 591                 for(i = 1; i < Map_Count; ++i)
 592                 {
 593                         float mapindex;
 594                         mapindex = math_mod(i + Map_Current, Map_Count);
 595                         if(Map_Check(mapindex, pass))
 596                                 return mapindex;
 597                 }
 598         }
 599         return -1;
 600 }
 601
 602 float() MaplistMethod_Repeat = // fallback method
 603 {
 604         if(Map_Check(Map_Current, 2))
 605                 return Map_Current;
 606         return -2;
 607 }
 608
 609 float() MaplistMethod_Random = // random map selection
 610 {
 611         float i, imax;
 612
 613         imax = 42;
 614
 615         for(i = 0; i <= imax; ++i)
 616         {
 617                 float mapindex;
 618                 mapindex = math_mod(Map_Current + ceil(random() * (Map_Count - 1)), Map_Count); // any OTHER map
 619                 if(Map_Check(mapindex, 1))
 620                         return mapindex;
 621         }
 622         return -1;
 623 }
 624
 625 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 626 // the exponent sets a bias on the map selection:
 627 // the higher the exponent, the
 628 {
 629         float i, j, imax, insertpos;
 630
 631         imax = 42;
 632
 633         if(Map_Count <= 1)
 634                 return 0; // only one map, then always play this one
 635
 636         for(i = 0; i <= imax; ++i)
 637         {
 638                 string newlist;
 639
 640                 // now reinsert this at another position
 641                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 642                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 643                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 644                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 645
 646                 // insert the current map there
 647                 newlist = "";
 648                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 649                         newlist = strcat(newlist, "'", argv(j), "'");
 650                 newlist = strcat(newlist, "'", argv(0), "'");  // now insert the just selected map
 651                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 652                         newlist = strcat(newlist, "'", argv(j), "'");
 653                 cvar_set("g_maplist", newlist);
 654                 Map_Count = tokenize(newlist);
 655
 656                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 657                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 658                 if(Map_Check(Map_Current, 1))
 659                         return Map_Current;
 660         }
 661         return -1;
 662 }
 663
 664 void() Maplist_Init =
 665 {
 666         string temp;
 667         temp = cvar_string("g_maplist");
 668         Map_Count = tokenize(temp);
 669         if(Map_Count == 0)
 670         {
 671                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 672                 cvar_set("g_maplist", temp = cvar_string("g_maplist_defaultlist"));
 673                 Map_Count = tokenize(temp);
 674         }
 675         if(Map_Count == 0)
 676                 error("empty maplist, cannot select a new map");
 677         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 678
 679         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 680         // this may or may not be correct, but who cares, in the worst case a map
 681         // isn't chosen in the first pass that should have been
 682 }
 683
 684 string() GetNextMap =
 685 {
 686         float nextMap;
 687
 688         Maplist_Init();
 689         nextMap = -1;
 690
 691         if(nextMap == -1)
 692                 if(cvar("g_maplist_shuffle") > 0)
 693                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 694
 695         if(nextMap == -1)
 696                 if(cvar("g_maplist_selectrandom"))
 697                         nextMap = MaplistMethod_Random();
 698
 699         if(nextMap == -1)
 700                 nextMap = MaplistMethod_Iterate();
 701
 702         if(nextMap == -1)
 703                 nextMap = MaplistMethod_Repeat();
 704
 705         if(nextMap >= 0)
 706         {
 707                 Map_Goto_SetFloat(nextMap);
 708                 return getmapname_stored;
 709         }
 710
 711         return "";
 712 };
 713
 714 float() DoNextMapOverride =
 715 {
 716         if(cvar("g_campaign"))
 717         {
 718                 CampaignPostIntermission();
 719                 return TRUE;
 720         }
 721         if(cvar("quit_when_empty"))
 722         {
 723                 if(player_count <= currentbots)
 724                 {
 725                         localcmd("quit\n");
 726                         return TRUE;
 727                 }
 728         }
 729         if (cvar("samelevel")) // if samelevel is set, stay on same level
 730         {
 731                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 732                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 733                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 734                 localcmd("restart\n");
 735                 //changelevel (mapname);
 736                 return TRUE;
 737         }
 738         if(cvar_string("nextmap") != "")
 739                 if(TryFile(strcat("maps/", cvar_string("nextmap"), ".mapcfg")))
 740                 {
 741                         Map_Goto_SetStr(cvar_string("nextmap"));
 742                         Map_Goto();
 743                         return TRUE;
 744                 }
 745         if(cvar("lastlevel"))
 746         {
 747                 GameResetCfg();
 748                 localcmd(strcat("set lastlevel 0\n"));
 749                 localcmd(strcat("togglemenu\n"));
 750                 return TRUE;
 751         }
 752         return FALSE;
 753 };
 754
 755 void() GotoNextMap =
 756 {
 757         //local string nextmap;
 758         //local float n, nummaps;
 759         //local string s;
 760         if (alreadychangedlevel)
 761                 return;
 762         alreadychangedlevel = TRUE;
 763
 764         {
 765                 string nextMap;
 766                 float allowReset;
 767
 768                 for(allowReset = 1; allowReset >= 0; --allowReset)
 769                 {
 770                         nextMap = GetNextMap();
 771                         if(nextMap != "")
 772                                 break;
 773
 774                         if(allowReset)
 775                         {
 776                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 777                                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
 778                         }
 779                         else
 780                         {
 781                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 782                         }
 783                 }
 784                 Map_Goto();
 785         }
 786 };
 787
 788
 789 /*
 790 ============
 791 IntermissionThink
 792
 793 When the player presses attack or jump, change to the next level
 794 ============
 795 */
 796 .float autoscreenshot;
 797 void() MapVote_Think;
 798 float mapvote_initialized;
 799 void() IntermissionThink =
 800 {
 801         FixIntermissionClient(self);
 802
 803         if(cvar("sv_autoscreenshot"))
 804         if(self.autoscreenshot)
 805         if(time > self.autoscreenshot)
 806         {
 807                 self.autoscreenshot = FALSE;
 808                 if(clienttype(self) == CLIENTTYPE_REAL)
 809                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 810                 return;
 811         }
 812
 813         if (time < intermission_exittime)
 814                 return;
 815
 816         if(!mapvote_initialized)
 817                 if (time < intermission_exittime + 10 && !self.button0 && !self.button2 && !self.button3 && !self.button6 && !self.buttonuse)
 818                         return;
 819
 820         if(intermission_exittime >= 0)
 821                 MapVote_Think();
 822 };
 823
 824 /*
 825 ============
 826 FindIntermission
 827
 828 Returns the entity to view from
 829 ============
 830 */
 831 /*
 832 entity() FindIntermission =
 833 {
 834         local   entity spot;
 835         local   float cyc;
 836
 837 // look for info_intermission first
 838         spot = find (world, classname, "info_intermission");
 839         if (spot)
 840         {       // pick a random one
 841                 cyc = random() * 4;
 842                 while (cyc > 1)
 843                 {
 844                         spot = find (spot, classname, "info_intermission");
 845                         if (!spot)
 846                                 spot = find (spot, classname, "info_intermission");
 847                         cyc = cyc - 1;
 848                 }
 849                 return spot;
 850         }
 851
 852 // then look for the start position
 853         spot = find (world, classname, "info_player_start");
 854         if (spot)
 855                 return spot;
 856
 857 // testinfo_player_start is only found in regioned levels
 858         spot = find (world, classname, "testplayerstart");
 859         if (spot)
 860                 return spot;
 861
 862 // then look for the start position
 863         spot = find (world, classname, "info_player_deathmatch");
 864         if (spot)
 865                 return spot;
 866
 867         //objerror ("FindIntermission: no spot");
 868         return world;
 869 };
 870 */
 871
 872 /*
 873 ===============================================================================
 874
 875 RULES
 876
 877 ===============================================================================
 878 */
 879
 880 void() DumpStats =
 881 {
 882         local float file;
 883         local string s;
 884
 885         if(cvar("_printstats"))
 886                 cvar_set("_printstats", "0");
 887         else if(!gameover)
 888                 return;
 889
 890         if(gameover)
 891                 s = ":scores:";
 892         else
 893                 s = ":status:";
 894
 895         s = strcat(s, GetMapname(), ":", ftos(rint(time)));
 896
 897         if(cvar("sv_eventlog") && gameover)
 898                 GameLogEcho(s, FALSE);
 899         else if(cvar("sv_logscores_console"))
 900                 ServerConsoleEcho(s, FALSE);
 901         if(cvar("sv_logscores_file"))
 902         {
 903                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
 904                 fputs(file, strcat(s, "\n"));
 905         }
 906
 907         FOR_EACH_CLIENT(other)
 908         {
 909                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
 910                 {
 911                         s = strcat(":player:", ftos(other.frags), ":");
 912                         s = strcat(s, ftos(other.deaths), ":");
 913                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
 914                         s = strcat(s, ftos(other.team), ":");
 915
 916                         if(cvar("sv_logscores_file"))
 917                                 fputs(file, strcat(s, other.netname, "\n"));
 918                         if(cvar("sv_eventlog") && gameover)
 919                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname), TRUE);
 920                         else if(cvar("sv_logscores_console"))
 921                                 ServerConsoleEcho(strcat(s, other.netname), TRUE);
 922                 }
 923         }
 924
 925         if(cvar("sv_eventlog") && gameover)
 926                 GameLogEcho(":end", FALSE);
 927         else if(cvar("sv_logscores_console"))
 928                 ServerConsoleEcho(":end", FALSE);
 929         if(cvar("sv_logscores_file"))
 930         {
 931                 fputs(file, ":end\n");
 932                 fclose(file);
 933         }
 934 }
 935
 936 void FixIntermissionClient(entity e)
 937 {
 938         if(!e.autoscreenshot) // initial call
 939         {
 940                 e.angles = e.v_angle;
 941                 e.angles_x = -e.angles_x;
 942                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
 943                 e.health = -2342;
 944                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
 945                 e.solid = SOLID_NOT;
 946                 e.movetype = MOVETYPE_NONE;
 947                 e.takedamage = DAMAGE_NO;
 948                 if(e.weaponentity)
 949                         e.weaponentity.effects = EF_NODRAW;
 950                 stuffcmd(e, "\nscr_printspeed 1000000\n");
 951                 if(clienttype(e) == CLIENTTYPE_REAL)
 952                 {
 953                         msg_entity = e;
 954                         WriteByte(MSG_ONE, SVC_INTERMISSION);
 955                 }
 956         }
 957
 958         //e.velocity = '0 0 0';
 959         //e.fixangle = TRUE;
 960
 961         // TODO halt weapon animation
 962 }
 963
 964
 965 /*
 966 go to the next level for deathmatch
 967 only called if a time or frag limit has expired
 968 */
 969 void() NextLevel =
 970 {
 971         float minTotalFrags;
 972         float maxTotalFrags;
 973         float score;
 974         float f;
 975
 976         gameover = TRUE;
 977
 978         intermission_running = 1;
 979
 980 // enforce a wait time before allowing changelevel
 981         if(player_count > 0)
 982                 intermission_exittime = time + cvar("sv_mapchange_delay");
 983         else
 984                 intermission_exittime = -60;
 985
 986         WriteByte (MSG_ALL, SVC_CDTRACK);
 987         WriteByte (MSG_ALL, 3);
 988         WriteByte (MSG_ALL, 3);
 989
 990         //pos = FindIntermission ();
 991
 992         VoteReset();
 993
 994         DumpStats();
 995
 996         if(cvar("sv_eventlog"))
 997                 GameLogEcho(":gameover", FALSE);
 998
 999         GameLogClose();
1000
1001         maxTotalFrags = 0;
1002         FOR_EACH_CLIENT(other)
1003         {
1004                 if(maxTotalFrags < other.totalfrags)
1005                         maxTotalFrags = other.totalfrags;
1006                 if(minTotalFrags > other.totalfrags)
1007                         minTotalFrags = other.totalfrags;
1008         }
1009
1010         FOR_EACH_CLIENT(other)
1011         {
1012                 FixIntermissionClient(other);
1013
1014                 self = other;
1015
1016                 if(other.winning)
1017                         bprint(strcat(other.netname, " ^7wins.\n"));
1018
1019                 if(!currentbots)
1020                 {
1021                         score = (other.frags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1022                         f = bound(0, other.play_time / max(time, 1), 1);
1023                         // store some statistics?
1024                 }
1025         }
1026
1027         if(cvar("g_campaign"))
1028                 CampaignPreIntermission();
1029
1030         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1031 };
1032
1033 /*
1034 ============
1035 CheckRules_Player
1036
1037 Exit deathmatch games upon conditions
1038 ============
1039 */
1040 void() CheckRules_Player =
1041 {
1042         if (gameover)   // someone else quit the game already
1043                 return;
1044
1045         if(self.deadflag == DEAD_NO)
1046                 self.play_time += frametime;
1047
1048         // fixme: don't check players; instead check dom_team and ctf_team entities
1049         //   (div0: and that in CheckRules_World please)
1050 };
1051
1052 float checkrules_oneminutewarning;
1053 float checkrules_leaderfrags;
1054 float tdm_max_score, tdm_old_score;
1055
1056 float checkrules_equality;
1057 float checkrules_overtimewarning;
1058 float checkrules_overtimeend;
1059
1060 void() InitiateOvertime =
1061 {
1062         if(!checkrules_overtimeend)
1063                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1064 }
1065
1066 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1067 float WINNING_YES = 1; // winner found
1068 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1069 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1070
1071 float(float fraglimitreached, float equality) GetWinningCode =
1072 {
1073         if(equality)
1074                 if(fraglimitreached)
1075                         return WINNING_STARTOVERTIME;
1076                 else
1077                         return WINNING_NEVER;
1078         else
1079                 if(fraglimitreached)
1080                         return WINNING_YES;
1081                 else
1082                         return WINNING_NO;
1083 }
1084
1085 // set the .winning flag for exactly those players with a given field value
1086 void(.float field, float value) SetWinners =
1087 {
1088         entity head;
1089         FOR_EACH_PLAYER(head)
1090                 head.winning = (head.field == value);
1091 }
1092
1093 // set the .winning flag for those players with a given field value
1094 void(.float field, float value) AddWinners =
1095 {
1096         entity head;
1097         FOR_EACH_PLAYER(head)
1098                 if(head.field == value)
1099                         head.winning = 1;
1100 }
1101
1102 // clear the .winning flags
1103 void(void) ClearWinners =
1104 {
1105         entity head;
1106         FOR_EACH_PLAYER(head)
1107                 head.winning = 0;
1108 }
1109
1110 float() LMS_NewPlayerLives =
1111 {
1112         float fl;
1113         fl = cvar("fraglimit");
1114         if(fl == 0)
1115                 fl = 999;
1116
1117         // first player has left the game for dying too much? Nobody else can get in.
1118         if(lms_lowest_lives < 1)
1119                 return FALSE;
1120
1121         if(!cvar("g_lms_join_anytime"))
1122                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1123                         return FALSE;
1124
1125         return bound(1, lms_lowest_lives, fl);
1126 }
1127
1128 // LMS winning condition: game terminates if and only if there's at most one
1129 // one player who's living lives. Top two scores being equal cancels the time
1130 // limit.
1131 float() WinningCondition_LMS =
1132 {
1133         entity head;
1134         float have_player;
1135         float have_players;
1136         float l;
1137
1138         have_player = FALSE;
1139         have_players = FALSE;
1140         l = LMS_NewPlayerLives();
1141
1142         head = find(world, classname, "player");
1143         if(head)
1144                 have_player = TRUE;
1145         head = find(head, classname, "player");
1146         if(head)
1147                 have_players = TRUE;
1148
1149         if(have_player)
1150         {
1151                 // we have at least one player
1152                 if(have_players)
1153                 {
1154                         // two or more active players - continue with the game
1155                 }
1156                 else
1157                 {
1158                         // exactly one player?
1159                         if(l)
1160                         {
1161                                 // but no game has taken place yet
1162                         }
1163                         else
1164                         {
1165                                 // a winner!
1166                                 ClearWinners(); SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1167                                 dprint("Have a winner, ending game.\n");
1168                                 return WINNING_YES;
1169                         }
1170                 }
1171         }
1172         else
1173         {
1174                 // nobody is playing at all...
1175                 if(l)
1176                 {
1177                         // wait for players...
1178                 }
1179                 else
1180                 {
1181                         // SNAFU (maybe a draw game?)
1182                         ClearWinners();
1183                         dprint("No players, ending game.\n");
1184                         return WINNING_YES;
1185                 }
1186         }
1187
1188         // When we get here, we have at least two players who are actually LIVING,
1189         // or one player who is still waiting for a victim to join the server. Now
1190         // check if the top two players have equal score.
1191
1192         checkrules_leaderfrags = 0;
1193         checkrules_equality = FALSE;
1194         FOR_EACH_PLAYER(head)
1195         {
1196                 if(head.frags > checkrules_leaderfrags)
1197                 {
1198                         checkrules_leaderfrags = head.frags;
1199                         checkrules_equality = FALSE;
1200                 }
1201                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
1202                         checkrules_equality = TRUE;
1203         }
1204
1205         SetWinners(frags, checkrules_leaderfrags);
1206
1207         // The top two players have the same amount of lives? No timelimit then,
1208         // enter overtime...
1209
1210         if(checkrules_equality)
1211                 return WINNING_NEVER;
1212
1213         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1214         return WINNING_NO;
1215 }
1216
1217 // DM winning condition: game terminates if a player reached the fraglimit,
1218 // unless the first two players have the same score. The latter case also
1219 // breaks the time limit.
1220 float(float fraglimit) WinningCondition_MaxIndividualScore =
1221 {
1222         float checkrules_oldleaderfrags;
1223         entity head;
1224
1225         checkrules_oldleaderfrags = checkrules_leaderfrags;
1226         checkrules_leaderfrags = 0;
1227         checkrules_equality = FALSE;
1228         FOR_EACH_PLAYER(head)
1229         {
1230                 if(head.frags > checkrules_leaderfrags)
1231                 {
1232                         checkrules_leaderfrags = head.frags;
1233                         checkrules_equality = FALSE;
1234                 }
1235                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
1236                         checkrules_equality = TRUE;
1237         }
1238
1239         if(checkrules_leaderfrags > 0)
1240                 SetWinners(frags, checkrules_leaderfrags);
1241         else
1242                 ClearWinners();
1243
1244         if (!cvar("g_runematch"))
1245                 if (checkrules_leaderfrags != checkrules_oldleaderfrags)
1246                 {
1247                         if (checkrules_leaderfrags == fraglimit - 1)
1248                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.ogg", 1, ATTN_NONE);
1249                         else if (checkrules_leaderfrags == fraglimit - 2)
1250                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.ogg", 1, ATTN_NONE);
1251                         else if (checkrules_leaderfrags == fraglimit - 3)
1252                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.ogg", 1, ATTN_NONE);
1253                 }
1254
1255         return GetWinningCode(fraglimit && checkrules_leaderfrags >= fraglimit, checkrules_equality);
1256 }
1257
1258 float(float fraglimit) WinningConditionBase_Teamplay =
1259 {
1260         tdm_old_score = tdm_max_score;
1261         tdm_max_score = max(team1_score, team2_score, team3_score, team4_score);
1262
1263         checkrules_equality =
1264         (
1265                 (tdm_max_score > 0)
1266                 &&
1267                 (
1268                           (team1_score == tdm_max_score)
1269                         + (team2_score == tdm_max_score)
1270                         + (team3_score == tdm_max_score)
1271                         + (team4_score == tdm_max_score)
1272                         >= 2));
1273
1274         ClearWinners();
1275         if(tdm_max_score > 0)
1276         {
1277                 if(team1_score == tdm_max_score)
1278                         AddWinners(team, COLOR_TEAM1);
1279                 if(team2_score == tdm_max_score)
1280                         AddWinners(team, COLOR_TEAM2);
1281                 if(team3_score == tdm_max_score)
1282                         AddWinners(team, COLOR_TEAM3);
1283                 if(team4_score == tdm_max_score)
1284                         AddWinners(team, COLOR_TEAM4);
1285         }
1286
1287         if(!cvar("g_runematch") && !cvar("g_domination"))
1288                 if(tdm_max_score != tdm_old_score)
1289                 {
1290                         if(tdm_max_score == fraglimit - 1)
1291                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.ogg", 1, ATTN_NONE);
1292                         else if(tdm_max_score == fraglimit - 2)
1293                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.ogg", 1, ATTN_NONE);
1294                         else if(tdm_max_score == fraglimit - 3)
1295                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.ogg", 1, ATTN_NONE);
1296                 }
1297
1298         return GetWinningCode(fraglimit && tdm_max_score >= fraglimit, checkrules_equality);
1299 }
1300
1301 // TDM winning condition: game terminates if a team's score sum reached the
1302 // fraglimit, unless the first two teams have the same total score. The latter
1303 // case also breaks the time limit.
1304 float(float fraglimit) WinningCondition_MaxTeamSum =
1305 {
1306         entity head;
1307
1308         team1_score = team2_score = team3_score = team4_score = 0;
1309
1310         FOR_EACH_PLAYER(head)
1311         {
1312                 if(head.team == COLOR_TEAM1)
1313                         team1_score += head.frags;
1314                 else if(head.team == COLOR_TEAM2)
1315                         team2_score += head.frags;
1316                 else if(head.team == COLOR_TEAM3)
1317                         team3_score += head.frags;
1318                 else if(head.team == COLOR_TEAM4)
1319                         team4_score += head.frags;
1320         }
1321
1322         return WinningConditionBase_Teamplay(fraglimit);
1323 }
1324
1325 // DOM/CTF winning condition: game terminates if the max of a team's players'
1326 // score reached the fraglimit, unless the first two teams have the same
1327 // maximum score. The latter case also breaks the time limit.
1328 float(float fraglimit) WinningCondition_MaxTeamMax =
1329 {
1330         entity head;
1331
1332         team1_score = team2_score = team3_score = team4_score = 0;
1333
1334         FOR_EACH_PLAYER(head)
1335         {
1336                 if(head.team == COLOR_TEAM1)
1337                 {
1338                         if(head.frags > team1_score)
1339                                 team1_score = head.frags;
1340                 }
1341                 else if(head.team == COLOR_TEAM2)
1342                 {
1343                         if(head.frags > team2_score)
1344                                 team2_score = head.frags;
1345                 }
1346                 else if(head.team == COLOR_TEAM3)
1347                 {
1348                         if(head.frags > team3_score)
1349                                 team3_score = head.frags;
1350                 }
1351                 else if(head.team == COLOR_TEAM4)
1352                 {
1353                         if(head.frags > team4_score)
1354                                 team4_score = head.frags;
1355                 }
1356         }
1357
1358         return WinningConditionBase_Teamplay(fraglimit);
1359 }
1360
1361 void print_to(entity e, string s)
1362 {
1363         if(e)
1364                 sprint(e, strcat(s, "\n"));
1365         else
1366                 ServerConsoleEcho(s, TRUE);
1367 }
1368
1369 void PrintScoreboardFor(entity e, string name, string colorcode, float whichteam)
1370 {
1371         entity head;
1372         float v;
1373         float teamvalue;
1374         float fragtotal;
1375         string s;
1376         float found;
1377         found = FALSE;
1378         teamvalue = 0;
1379         FOR_EACH_PLAYER(head)
1380         {
1381                 if(!whichteam || head.team == whichteam)
1382                 {
1383                         if(name != "")
1384                                 if(!found)
1385                                         print_to(e, strcat(" ", colorcode, name, ":"));
1386                         found = TRUE;
1387                         fragtotal = fragtotal + head.frags;
1388                         s = ftos(head.frags);
1389                         s = strcat(s, "/", ftos(head.deaths));
1390                         s = strcat(s, " @ ", ftos(head.ping));
1391                         if(clienttype(head) == CLIENTTYPE_BOT)
1392                                 s = strcat(s, "botms");
1393                         else
1394                                 s = strcat(s, "ms");
1395                         v = PlayerValue(head);
1396                         teamvalue += v;
1397                         s = strcat(s, " / ", ftos(v));
1398                         print_to(e, strcat("  ", colorcode, head.netname, colorcode, " (", s, ")"));
1399                 }
1400         }
1401         if(whichteam && found)
1402         {
1403                 s = ftos(fragtotal);
1404                 s = strcat(s, " / ", ftos(teamvalue));
1405                 print_to(e, strcat(colorcode, "  (total: ", s, ")"));
1406         }
1407 }
1408
1409 void PrintScoreboard(entity e)
1410 {
1411         print_to(e, strcat("Time:      ", ftos(time / 60)));
1412         print_to(e, strcat("Timelimit: ", ftos(cvar("timelimit"))));
1413         print_to(e, strcat("Fraglimit: ", ftos(cvar("fraglimit"))));
1414         print_to(e, "Scoreboard:");
1415         if(teams_matter)
1416         {
1417                 PrintScoreboardFor(e, "Red", "^1", COLOR_TEAM1);
1418                 PrintScoreboardFor(e, "Blue", "^4", COLOR_TEAM2);
1419                 PrintScoreboardFor(e, "Pink", "^6", COLOR_TEAM3);
1420                 PrintScoreboardFor(e, "Yellow", "^3", COLOR_TEAM4);
1421         }
1422         else
1423         {
1424                 PrintScoreboardFor(e, "", "^7", 0);
1425         }
1426         print_to(e, ".");
1427 }
1428
1429 void RemoveFromMaplist(string m)
1430 {
1431         string result;
1432         float litems;
1433         float i;
1434         float found;
1435
1436         litems = tokenize(cvar_string("g_maplist"));
1437         found = 0;
1438         result = "";
1439         for(i = 0; i < litems; ++i)
1440         {
1441                 m = strcat(m);
1442                 result = strcat(result);
1443                 if(argv(i) == m)
1444                         found += 1;
1445                 else
1446                         result = strcat(result, "'", argv(i), "'");
1447         }
1448         if(found)
1449                 cvar_set("g_maplist", result);
1450         ServerConsoleEcho(strcat("Removed ", ftos(found), " items."), FALSE);
1451 }
1452
1453 void AddToMaplist(string m)
1454 {
1455         string result;
1456         float found;
1457         float litems;
1458         float i;
1459         float ipos;
1460         float inserted;
1461
1462         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1463         {
1464                 ServerConsoleEcho("Map not found.", FALSE);
1465                 return;
1466         }
1467
1468         litems = tokenize(cvar_string("g_maplist"));
1469         if(cvar("g_maplist_shuffle"))
1470                 ipos = ceil(random() * (litems + 1)) - 1;
1471         else
1472                 ipos = litems;
1473         found = 0;
1474         inserted = 0;
1475         for(i = 0; i < litems; ++i)
1476         {
1477                 m = strcat(m);
1478                 if(i == ipos)
1479                 {
1480                         result = strcat(result, "'", m, "'");
1481                         inserted = 1;
1482                 }
1483                 result = strcat(result, "'", argv(i), "'");
1484                 if(argv(i) == m)
1485                         found += 1;
1486         }
1487         if(!inserted)
1488                 result = strcat(result, "'", m, "'");
1489         if(!found)
1490         {
1491                 cvar_set("g_maplist", result);
1492                 ServerConsoleEcho("Map added.", FALSE);
1493         }
1494         else
1495                 ServerConsoleEcho("Map already in list.", FALSE);
1496 }
1497
1498 void MakeFirstInMaplist(string m)
1499 {
1500         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1501         {
1502                 ServerConsoleEcho("Map not found.", FALSE);
1503                 return;
1504         }
1505
1506         m = strzone(m);
1507         RemoveFromMaplist(m);
1508         cvar_set("g_maplist", strcat("'", m, "'", cvar_string("g_maplist")));
1509         strunzone(m);
1510
1511         ServerConsoleEcho("Map added as first one.", FALSE);
1512 }
1513
1514 void ShuffleMaplist()
1515 {
1516         string result;
1517         float start;
1518         float litems;
1519         float selected;
1520         float i;
1521
1522         result = cvar_string("g_maplist");
1523         litems = tokenize(result);
1524
1525         for(start = 0; start < litems - 1; ++start)
1526         {
1527                 result = "";
1528
1529                 // select a random item
1530                 selected = ceil(random() * (litems - start) + start) - 1;
1531
1532                 // shift this item to the place start
1533                 for(i = 0; i < start; ++i)
1534                         result = strcat(result, "'", argv(i), "'");
1535                 result = strcat(result, "'", argv(selected), "'");
1536                 for(i = start; i < litems; ++i)
1537                         if(i != selected)
1538                                 result = strcat(result, "'", argv(i), "'");
1539
1540                 litems = tokenize(result);
1541
1542                 //dprint(result, "\n");
1543         }
1544
1545         cvar_set("g_maplist", result);
1546 }
1547
1548 void() HandleMaplistShuffleCommands =
1549 {
1550         // automatically shuffle when setting g_maplist_shuffle
1551         if(cvar_string("_g_maplist_add") != "")
1552         {
1553                 AddToMaplist(cvar_string("_g_maplist_add"));
1554                 cvar_set("_g_maplist_add", "");
1555         }
1556         if(cvar_string("_g_maplist_remove") != "")
1557         {
1558                 RemoveFromMaplist(cvar_string("_g_maplist_remove"));
1559                 cvar_set("_g_maplist_remove", "");
1560         }
1561         if(cvar_string("_g_maplist_putfirst") != "")
1562         {
1563                 MakeFirstInMaplist(cvar_string("_g_maplist_putfirst"));
1564                 cvar_set("_g_maplist_putfirst", "");
1565         }
1566         if(cvar("_g_maplist_shufflenow") || (cvar("g_maplist_shuffle") && !cvar("_g_maplist_have_shuffled")))
1567         {
1568                 ShuffleMaplist();
1569                 cvar_set("_g_maplist_shufflenow", "0");
1570                 cvar_set("_g_maplist_have_shuffled", "1");
1571                 ServerConsoleEcho("Shuffled map list.", FALSE);
1572         }
1573         if(cvar("_g_maplist_have_shuffled"))
1574                 if(!cvar("g_maplist_shuffle"))
1575                         cvar_set("_g_maplist_have_shuffled", "0");
1576 }
1577
1578 /*
1579 ============
1580 CheckRules_World
1581
1582 Exit deathmatch games upon conditions
1583 ============
1584 */
1585 void() CheckRules_World =
1586 {
1587         local float status;
1588         local float timelimit;
1589         local float fraglimit;
1590
1591         VoteThink();
1592
1593         SetDefaultAlpha();
1594
1595         if (intermission_running)
1596                 if (time >= intermission_exittime + 60)
1597                 {
1598                         if(!DoNextMapOverride())
1599                                 GotoNextMap();
1600                         return;
1601                 }
1602
1603         if (gameover)   // someone else quit the game already
1604                 return;
1605
1606         DumpStats();
1607
1608         if(cvar("_scoreboard"))
1609         {
1610                 cvar_set("_scoreboard", "0");
1611                 PrintScoreboard(world);
1612         }
1613
1614         HandleMaplistShuffleCommands();
1615
1616         timelimit = cvar("timelimit") * 60;
1617         fraglimit = cvar("fraglimit");
1618
1619         if(checkrules_overtimeend)
1620         {
1621                 if(!checkrules_overtimewarning)
1622                 {
1623                         checkrules_overtimewarning = TRUE;
1624                         //sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.ogg", 1, ATTN_NONE);
1625                         bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1626                 }
1627         }
1628         else
1629         {
1630                 if (timelimit && time >= timelimit)
1631                         InitiateOvertime();
1632         }
1633
1634         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1635         {
1636                 NextLevel();
1637                 return;
1638         }
1639
1640         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1641         {
1642                 checkrules_oneminutewarning = TRUE;
1643                 sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.ogg", 1, ATTN_NONE);
1644         }
1645
1646         status = WINNING_NO;
1647         if(cvar("g_lms"))
1648         {
1649                 status = WinningCondition_LMS();
1650         }
1651         else
1652         {
1653                 if(teams_matter)
1654                 {
1655                         if(cvar("g_tdm") || cvar("g_runematch") || cvar("g_ctf") || cvar("g_domination"))
1656                                 status = WinningCondition_MaxTeamSum(fraglimit);
1657                         //else if()
1658                         //      status = WinningCondition_MaxTeamMax(fraglimit);
1659                         else
1660                         {
1661                                 dprint("div0: How can this happen?\n");
1662                                 status = WinningCondition_MaxTeamMax(fraglimit);
1663                         }
1664                 }
1665                 else
1666                         status = WinningCondition_MaxIndividualScore(fraglimit);
1667         }
1668
1669         if(status == WINNING_STARTOVERTIME)
1670         {
1671                 status = WINNING_NEVER;
1672                 InitiateOvertime();
1673         }
1674
1675         if(status == WINNING_NEVER)
1676                 // equality cases! Nobody wins if the overtime ends in a draw.
1677                 ClearWinners();
1678
1679         if(checkrules_overtimeend)
1680                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1681                         status = WINNING_YES;
1682
1683         if(status == WINNING_YES)
1684                 NextLevel();
1685 };
1686
1687 float randsel_value;
1688 float randsel_priority;
1689 float randsel_count;
1690 void RandSel_Init()
1691 {
1692         randsel_value = -1;
1693         randsel_priority = -1;
1694         randsel_count = -1;
1695 }
1696 void RandSel_Add(float priority, float value)
1697 {
1698         if(priority > randsel_priority)
1699         {
1700                 randsel_priority = priority;
1701                 randsel_value = value;
1702                 randsel_count = 1;
1703         }
1704         else if(priority == randsel_priority)
1705         {
1706                 randsel_count += 1;
1707                 if(ceil(random() * randsel_count) == 1)
1708                         randsel_value = value;
1709         }
1710 }
1711
1712 float mapvote_nextthink;
1713 float mapvote_initialized;
1714 float mapvote_keeptwotime;
1715 float mapvote_timeout;
1716 string mapvote_message;
1717
1718 #define MAPVOTE_COUNT 10
1719 float mapvote_count;
1720 string mapvote_maps[MAPVOTE_COUNT];
1721 float mapvote_maps_suggested[MAPVOTE_COUNT];
1722 string mapvote_suggestions[MAPVOTE_COUNT];
1723 float mapvote_suggestion_ptr;
1724 string mapvote_fillstr;
1725 float mapvote_maxlen;
1726 float mapvote_voters;
1727 float mapvote_votes[MAPVOTE_COUNT];
1728 .float mapvote;
1729
1730 void MapVote_ClearAllVotes()
1731 {
1732         FOR_EACH_CLIENT(other)
1733                 other.mapvote = 0;
1734 }
1735
1736 string MapVote_Suggest(string m)
1737 {
1738         float i;
1739         if(m == "")
1740                 return "That's not how to use this command.";
1741         if(!cvar("g_maplist_votable_suggestions"))
1742                 return "Suggestions are not accepted on this server.";
1743         if(mapvote_initialized)
1744                 return "Can't suggest - voting is already in progress!";
1745         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1746                 return "The map you suggested is not available on this server.";
1747         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1748                 if(mapvote_suggestions[i] == m)
1749                         return "This map was already suggested.";
1750         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1751         {
1752                 i = ceil(random() * mapvote_suggestion_ptr) - 1;
1753         }
1754         else
1755         {
1756                 i = mapvote_suggestion_ptr;
1757                 mapvote_suggestion_ptr += 1;
1758         }
1759         if(mapvote_suggestions[i] != "")
1760                 strunzone(mapvote_suggestions[i]);
1761         mapvote_suggestions[i] = strzone(m);
1762         GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid), ":", self.netname), TRUE);
1763         return "Suggestion accepted.";
1764 }
1765
1766 void MapVote_AddVotable(string nextMap, float isSuggestion)
1767 {
1768         float j;
1769         if(nextMap == "")
1770                 return;
1771         for(j = 0; j < mapvote_count; ++j)
1772                 if(mapvote_maps[j] == nextMap)
1773                         return;
1774         if(strlen(nextMap) > mapvote_maxlen)
1775                 mapvote_maxlen = strlen(nextMap);
1776         mapvote_maps[mapvote_count] = strzone(nextMap);
1777         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1778         mapvote_count += 1;
1779 }
1780
1781 void MapVote_Init()
1782 {
1783         float i;
1784         float nmax, smax;
1785
1786         MapVote_ClearAllVotes();
1787
1788         nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
1789         smax = min(nmax, cvar("g_maplist_votable_suggestions"));
1790         mapvote_count = 0;
1791
1792         for(i = 0; i < 100 && mapvote_count < smax; ++i)
1793                 MapVote_AddVotable(mapvote_suggestions[ceil(random() * mapvote_suggestion_ptr) - 1], TRUE);
1794
1795         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1796                 MapVote_AddVotable(GetNextMap(), FALSE);
1797
1798         if(mapvote_count == 0)
1799         {
1800                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1801                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
1802                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1803                         MapVote_AddVotable(GetNextMap(), FALSE);
1804         }
1805
1806         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
1807
1808         mapvote_fillstr = " ";
1809         while(strlen(mapvote_fillstr) < mapvote_maxlen + 16)
1810                 mapvote_fillstr = strcat(mapvote_fillstr, mapvote_fillstr);
1811         mapvote_fillstr = strzone(mapvote_fillstr);
1812
1813         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
1814         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
1815         if(mapvote_count < 3 || mapvote_keeptwotime <= time)
1816                 mapvote_keeptwotime = 0;
1817         mapvote_message = "Choose a map and press its key!";
1818 }
1819 float MapVote_Finished(float mappos)
1820 {
1821         string result;
1822         float i;
1823
1824         result = strcat(":vote:finished:", mapvote_maps[mappos]);
1825         result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
1826         for(i = 0; i < mapvote_count; ++i)
1827                 if(i != mappos)
1828                         if(mapvote_maps[i] != "")
1829                         {
1830                                 result = strcat(result, ":", mapvote_maps[i]);
1831                                 result = strcat(result, ":", ftos(mapvote_votes[i]));
1832                         }
1833         GameLogEcho(result, FALSE);
1834         if(mapvote_maps_suggested[mappos])
1835                 GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]), FALSE);
1836
1837         FOR_EACH_REALCLIENT(other)
1838                 FixClientCvars(other);
1839
1840         Map_Goto_SetStr(mapvote_maps[mappos]);
1841         Map_Goto();
1842         return TRUE;
1843 }
1844 void MapVote_CheckRules_1()
1845 {
1846         float i;
1847
1848         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1849         {
1850                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
1851                 mapvote_votes[i] = 0;
1852         }
1853
1854         mapvote_voters = 0;
1855         FOR_EACH_REALCLIENT(other)
1856         {
1857                 ++mapvote_voters;
1858                 if(other.mapvote)
1859                 {
1860                         i = other.mapvote - 1;
1861                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
1862                         mapvote_votes[i] = mapvote_votes[i] + 1;
1863                 }
1864         }
1865 }
1866
1867 float MapVote_CheckRules_2()
1868 {
1869         float i;
1870         float firstPlace, secondPlace;
1871         float firstPlaceVotes, secondPlaceVotes;
1872         string result;
1873
1874         RandSel_Init();
1875         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1876                 RandSel_Add(mapvote_votes[i], i);
1877         firstPlace = randsel_value;
1878         firstPlaceVotes = randsel_priority;
1879         //dprint("First place: ", ftos(firstPlace), "\n");
1880         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
1881
1882         RandSel_Init();
1883         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1884                 if(i != firstPlace)
1885                         RandSel_Add(mapvote_votes[i], i);
1886         secondPlace = randsel_value;
1887         secondPlaceVotes = randsel_priority;
1888         //dprint("Second place: ", ftos(secondPlace), "\n");
1889         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
1890
1891         if(firstPlace == -1)
1892                 error("No first place in map vote... WTF?");
1893
1894         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters - firstPlaceVotes) < firstPlaceVotes)
1895                 return MapVote_Finished(firstPlace);
1896
1897         if(mapvote_keeptwotime)
1898                 if(time > mapvote_keeptwotime || (mapvote_voters - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
1899                 {
1900                         mapvote_message = "Now decide between the TOP TWO!";
1901                         mapvote_keeptwotime = 0;
1902                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
1903                         result = strcat(result, ":", ftos(firstPlaceVotes));
1904                         result = strcat(result, ":", mapvote_maps[secondPlace]);
1905                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
1906                         for(i = 0; i < mapvote_count; ++i)
1907                                 if(i != firstPlace)
1908                                         if(i != secondPlace)
1909                                                 if(mapvote_maps[i] != "")
1910                                                 {
1911                                                         result = strcat(result, ":", mapvote_maps[i]);
1912                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
1913                                                         strunzone(mapvote_maps[i]);
1914                                                         mapvote_maps[i] = "";
1915                                                 }
1916                         GameLogEcho(result, FALSE);
1917                 }
1918
1919         return FALSE;
1920 }
1921 void MapVote_Tick()
1922 {
1923         string msgstr;
1924         string tmp;
1925         float i;
1926         float keeptwo;
1927
1928         keeptwo = mapvote_keeptwotime;
1929         MapVote_CheckRules_1(); // count
1930         if(MapVote_CheckRules_2()) // decide
1931                 return;
1932
1933         FOR_EACH_REALCLIENT(other)
1934         {
1935                 // hide scoreboard again
1936                 if(other.health != 2342)
1937                 {
1938                         other.health = 2342;
1939                         other.impulse = 0;
1940                         if(clienttype(other) == CLIENTTYPE_REAL)
1941                         {
1942                                 stuffcmd(other, "\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
1943                                 msg_entity = other;
1944                                 WriteByte(MSG_ONE, SVC_FINALE);
1945                                 WriteString(MSG_ONE, "");
1946                         }
1947                 }
1948
1949                 // notify about keep-two
1950                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
1951                         stuffcmd(other, "\nplay2 misc/invshot.wav\n");
1952
1953                 // clear possibly invalid votes
1954                 if(mapvote_maps[other.mapvote - 1] == "")
1955                         other.mapvote = 0;
1956                 // use impulses as new vote
1957                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
1958                         if(mapvote_maps[other.impulse - 1] != "")
1959                                 other.mapvote = other.impulse;
1960                 other.impulse = 0;
1961         }
1962
1963         MapVote_CheckRules_1(); // just count
1964
1965         FOR_EACH_REALCLIENT(other)
1966         {
1967                 // display voting screen
1968                 msgstr = "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n";
1969                 msgstr = substring(msgstr, 0, strlen(msgstr) - mapvote_count);
1970                 msgstr = strcat(msgstr, mapvote_message);
1971                 msgstr = strcat(msgstr, "\n\n");
1972                 for(i = 0; i < mapvote_count; ++i)
1973                         if(mapvote_maps[i] == "")
1974                                 msgstr = strcat(msgstr, "\n");
1975                         else
1976                         {
1977                                 tmp = mapvote_maps[i];
1978                                 tmp = strcat(tmp, substring(mapvote_fillstr, 0, mapvote_maxlen  - strlen(tmp)));
1979                                 tmp = strcat(ftos(math_mod(i + 1, 10)), ": ", tmp);
1980                                 tmp = strcat(tmp, " ^2(", ftos(mapvote_votes[i]), " vote");
1981                                 if(mapvote_votes[i] != 1)
1982                                         tmp = strcat(tmp, "s");
1983                                 tmp = strcat(tmp, ")");
1984                                 tmp = strcat(tmp, substring(mapvote_fillstr, 0, mapvote_maxlen + 15 - strlen(tmp)));
1985                                 if(other.mapvote == i + 1)
1986                                         msgstr = strcat(msgstr, "^3> ", tmp, "\n");
1987                                 else
1988                                         msgstr = strcat(msgstr, "^7  ", tmp, "\n");
1989                         }
1990                 i = ceil(mapvote_timeout - time);
1991                 msgstr = strcat(msgstr, "\n\n", ftos(i), " second");
1992                 if(i != 1)
1993                         msgstr = strcat(msgstr, "s");
1994                 msgstr = strcat(msgstr, " left");
1995
1996                 centerprint_atprio(other, CENTERPRIO_MAPVOTE, msgstr);
1997         }
1998 }
1999 void MapVote_Think()
2000 {
2001         if(alreadychangedlevel)
2002                 return;
2003
2004         if(time < mapvote_nextthink)
2005                 return;
2006         //dprint("tick\n");
2007
2008         mapvote_nextthink = time + 0.5;
2009
2010         if(!mapvote_initialized)
2011         {
2012                 mapvote_initialized = TRUE;
2013                 if(DoNextMapOverride())
2014                 {
2015                         alreadychangedlevel = TRUE;
2016                         return;
2017                 }
2018                 if(!cvar("g_maplist_votable"))
2019                 {
2020                         GotoNextMap();
2021                         return;
2022                 }
2023                 MapVote_Init();
2024         }
2025
2026         MapVote_Tick();
2027 };