data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3
   4 string GetMapname();
   5 void GotoNextMap();
   6 void ShuffleMaplist()
   7 float() DoNextMapOverride;
   8
   9 void SetDefaultAlpha()
  10 {
  11         if(cvar("g_running_guns"))
  12         {
  13                 default_player_alpha = -1;
  14                 default_weapon_alpha = +1;
  15         }
  16         else if(cvar("g_cloaked"))
  17         {
  18                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  19                 default_weapon_alpha = default_player_alpha;
  20         }
  21         else
  22         {
  23                 default_player_alpha = cvar("g_player_alpha");
  24                 if(default_player_alpha <= 0)
  25                         default_player_alpha = 1;
  26                 default_weapon_alpha = default_player_alpha;
  27         }
  28 }
  29
  30 void fteqcc_testbugs()
  31 {
  32         float a, b;
  33
  34         if(!cvar("developer_fteqccbugs"))
  35                 return;
  36
  37         dprint("*** fteqcc test: checking for bugs...\n");
  38
  39         a = 1;
  40         b = 5;
  41         if(sqrt(a) - sqrt(b - a) == 0)
  42                 dprint("*** fteqcc test: found same-function-twice bug\n");
  43         else
  44                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  45
  46         world.frags = -10;
  47         world.enemy = world;
  48         world.enemy.frags += 10;
  49         if(world.frags > 0.2 || world.frags < -0.2) // don't error out if it's just roundoff errors
  50                 dprint("*** fteqcc test: found += bug\n");
  51         else
  52                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  53         world.frags = 0;
  54 }
  55
  56 void GotoFirstMap()
  57 {
  58         if(cvar("_sv_init"))
  59         {
  60                 cvar_set("_sv_init", "0");
  61                 if(cvar("g_maplist_shuffle"))
  62                         ShuffleMaplist();
  63                 tokenize(cvar_string("g_maplist"));
  64                 if(argv(0) != GetMapname())
  65                 {
  66                         cvar_set("nextmap", argv(0));
  67                         if(!DoNextMapOverride())
  68                                 GotoNextMap();
  69                 }
  70         }
  71 }
  72
  73 float world_already_spawned;
  74 void worldspawn (void)
  75 {
  76         float globhandle, i, n;
  77
  78         dprint_load(); // load dprint status from cvar
  79
  80         if(world_already_spawned)
  81                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
  82         world_already_spawned = TRUE;
  83
  84         sv_cheats = cvar("sv_cheats");
  85
  86         /*
  87         TODO sound pack system
  88         // initialize sound pack system
  89         soundpack = cvar_string("g_soundpack");
  90         if(soundpack != "")
  91                 soundpack = strcat(soundpack, "/");
  92         soundpack = strzone(soundpack);
  93         */
  94
  95         // gamemode related things
  96         precache_model ("models/misc/chatbubble.spr");
  97         precache_model ("models/misc/teambubble.spr");
  98         if (cvar("g_runematch"))
  99         {
 100                 precache_model ("models/runematch/curse.mdl");
 101                 precache_model ("models/runematch/rune.mdl");
 102         }
 103
 104         // Precache all player models if desired
 105         if (cvar("sv_precacheplayermodels"))
 106         {
 107                 globhandle = search_begin("models/player/*.zym", TRUE, FALSE);
 108                 n = search_getsize(globhandle);
 109                 for(i = 0; i < n; ++i)
 110                 {
 111                         //print(search_getfilename(globhandle, i), "\n");
 112                         precache_model(search_getfilename(globhandle, i));
 113                 }
 114                 search_end(globhandle);
 115                 //precache_model("models/player/carni.zym");
 116                 //precache_model("models/player/crash.zym");
 117                 //precache_model("models/player/grunt.zym");
 118                 //precache_model("models/player/headhunter.zym");
 119                 //precache_model("models/player/insurrectionist.zym");
 120                 //precache_model("models/player/jeandarc.zym");
 121                 //precache_model("models/player/lurk.zym");
 122                 //precache_model("models/player/lycanthrope.zym");
 123                 //precache_model("models/player/marine.zym");
 124                 //precache_model("models/player/nexus.zym");
 125                 //precache_model("models/player/pyria.zym");
 126                 //precache_model("models/player/shock.zym");
 127                 //precache_model("models/player/skadi.zym");
 128                 //precache_model("models/player/specop.zym");
 129                 //precache_model("models/player/visitant.zym");
 130         }
 131
 132         if (cvar("g_footsteps"))
 133         {
 134                 precache_sound ("misc/footstep01.wav");
 135                 precache_sound ("misc/footstep02.wav");
 136                 precache_sound ("misc/footstep03.wav");
 137                 precache_sound ("misc/footstep04.wav");
 138                 precache_sound ("misc/footstep05.wav");
 139                 precache_sound ("misc/footstep06.wav");
 140         }
 141
 142         // gore and miscellaneous sounds
 143         //precache_sound ("misc/h2ohit.wav");
 144         precache_model ("models/gibs/bloodyskull.md3");
 145         precache_model ("models/gibs/chunk.mdl");
 146         precache_model ("models/gibs/eye.md3");
 147         precache_model ("models/gibs/gib1.md3");
 148         precache_model ("models/gibs/gib1.mdl");
 149         precache_model ("models/gibs/gib2.mdl");
 150         precache_model ("models/gibs/gib3.mdl");
 151         precache_model ("models/gibs/gib5.md3");
 152         precache_model ("models/hook.md3");
 153         precache_sound ("misc/armorimpact.wav");
 154         precache_sound ("misc/bodyimpact1.wav");
 155         precache_sound ("misc/bodyimpact2.wav");
 156         precache_sound ("misc/gib.wav");
 157         precache_sound ("misc/gib_splat01.wav");
 158         precache_sound ("misc/gib_splat02.wav");
 159         precache_sound ("misc/gib_splat03.wav");
 160         precache_sound ("misc/gib_splat04.wav");
 161         precache_sound ("misc/hit.wav");
 162         precache_sound ("misc/hitground1.wav");
 163         precache_sound ("misc/hitground2.wav");
 164         precache_sound ("misc/hitground3.wav");
 165         precache_sound ("misc/hitground4.wav");
 166         precache_sound ("misc/null.wav");
 167         precache_sound ("misc/spawn.wav");
 168         precache_sound ("misc/talk.wav");
 169         precache_sound ("misc/teleport.wav");
 170         precache_sound ("player/lava.wav");
 171         precache_sound ("player/slime.wav");
 172
 173         // announcer sounds - male
 174         //precache_sound ("announcer/male/electrobitch.wav");
 175         precache_sound ("announcer/male/03kills.wav");
 176         precache_sound ("announcer/male/05kills.wav");
 177         precache_sound ("announcer/male/10kills.wav");
 178         precache_sound ("announcer/male/15kills.wav");
 179         precache_sound ("announcer/male/20kills.wav");
 180         precache_sound ("announcer/male/25kills.wav");
 181         precache_sound ("announcer/male/30kills.wav");
 182         precache_sound ("announcer/male/botlike.wav");
 183         precache_sound ("announcer/male/yoda.wav");
 184
 185         // announcer sounds - robotic
 186         precache_sound ("announcer/robotic/1fragleft.wav");
 187         precache_sound ("announcer/robotic/1minuteremains.wav");
 188         precache_sound ("announcer/robotic/2fragsleft.wav");
 189         precache_sound ("announcer/robotic/3fragsleft.wav");
 190         if (cvar("g_minstagib"))
 191         {
 192                 precache_sound ("announcer/robotic/lastsecond.wav");
 193                 precache_sound ("announcer/robotic/narrowly.wav");
 194                 precache_sound ("announcer/robotic/1.wav");
 195                 precache_sound ("announcer/robotic/2.wav");
 196                 precache_sound ("announcer/robotic/3.wav");
 197                 precache_sound ("announcer/robotic/4.wav");
 198                 precache_sound ("announcer/robotic/5.wav");
 199                 precache_sound ("announcer/robotic/6.wav");
 200                 precache_sound ("announcer/robotic/7.wav");
 201                 precache_sound ("announcer/robotic/8.wav");
 202                 precache_sound ("announcer/robotic/9.wav");
 203                 precache_sound ("announcer/robotic/10.wav");
 204         }
 205
 206         // common weapon precaches
 207         precache_sound ("weapons/weapon_switch.wav");
 208         precache_sound ("weapons/weaponpickup.wav");
 209         if (cvar("g_grappling_hook"))
 210         {
 211                 precache_sound ("weapons/hook_fire.wav"); // hook
 212                 precache_sound ("weapons/hook_impact.wav"); // hook
 213         }
 214
 215         if (cvar("sv_precacheweapons") || cvar("g_nixnex"))
 216         {
 217                 //precache weapon models/sounds
 218                 local float wep;
 219                 wep = WEP_FIRST;
 220                 while (wep <= WEP_LAST)
 221                 {
 222                         weapon_action(wep, WR_PRECACHE);
 223                         wep = wep + 1;
 224                 }
 225         }
 226
 227         // plays music for the level if there is any
 228         if (self.noise)
 229         {
 230                 precache_sound (self.noise);
 231                 ambientsound ('0 0 0', self.noise, 1.00, ATTN_NONE);
 232         }
 233
 234         // 0 normal
 235         lightstyle(0, "m");
 236
 237         // 1 FLICKER (first variety)
 238         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 239
 240         // 2 SLOW STRONG PULSE
 241         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 242
 243         // 3 CANDLE (first variety)
 244         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 245
 246         // 4 FAST STROBE
 247         lightstyle(4, "mamamamamama");
 248
 249         // 5 GENTLE PULSE 1
 250         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 251
 252         // 6 FLICKER (second variety)
 253         lightstyle(6, "nmonqnmomnmomomno");
 254
 255         // 7 CANDLE (second variety)
 256         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 257
 258         // 8 CANDLE (third variety)
 259         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 260
 261         // 9 SLOW STROBE (fourth variety)
 262         lightstyle(9, "aaaaaaaazzzzzzzz");
 263
 264         // 10 FLUORESCENT FLICKER
 265         lightstyle(10, "mmamammmmammamamaaamammma");
 266
 267         // 11 SLOW PULSE NOT FADE TO BLACK
 268         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 269
 270         // styles 32-62 are assigned by the light program for switchable lights
 271
 272         // 63 testing
 273         lightstyle(63, "a");
 274
 275         player_count = 0;
 276         lms_lowest_lives = 0;
 277         lms_next_place = 0;
 278
 279         GotoFirstMap();
 280
 281         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 282         if(bot_waypoints_for_items == 1)
 283                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 284                         bot_waypoints_for_items = 0;
 285
 286         if(cvar("g_campaign"))
 287                 CampaignPreInit();
 288
 289         InitGameplayMode();
 290
 291         WaypointSprite_Init();
 292
 293         //if (cvar("g_domination"))
 294         //      dom_init();
 295
 296         local entity head;
 297         head = nextent(world);
 298         maxclients = 0;
 299         while(head)
 300         {
 301                 maxclients++;
 302                 head = nextent(head);
 303         }
 304
 305         GameLogInit(); // prepare everything
 306         if(cvar("sv_eventlog"))
 307         {
 308                 local string s;
 309                 GameLogEcho(":logversion:2", FALSE);
 310                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 311                 s = strcat(s, ftos(random()));
 312                 GameLogEcho(strcat(":gamestart:", GetMapname(), ":", s), FALSE);
 313                 s = ":gameinfo:mutators:LIST";
 314                 if(cvar("g_grappling_hook"))
 315                         s = strcat(s, ":grappling_hook");
 316                 if(!cvar("g_use_ammunition"))
 317                         s = strcat(s, ":no_use_ammunition");
 318                 if(!cvar("g_pickup_items"))
 319                         s = strcat(s, ":no_pickup_items");
 320                 if(cvar("g_instagib"))
 321                         s = strcat(s, ":instagib");
 322                 if(cvar("g_rocketarena"))
 323                         s = strcat(s, ":rockerarena");
 324                 if(cvar("g_nixnex"))
 325                         s = strcat(s, ":nixnex");
 326                 if(cvar("g_vampire"))
 327                         s = strcat(s, ":vampire");
 328                 if(cvar("g_laserguided_missile"))
 329                         s = strcat(s, ":laserguided_missile");
 330                 if(cvar("g_norecoil"))
 331                         s = strcat(s, ":norecoil");
 332                 if(cvar("g_midair"))
 333                         s = strcat(s, ":midair");
 334                 if(cvar("g_minstagib"))
 335                         s = strcat(s, ":minstagib");
 336                 GameLogEcho(s, FALSE);
 337                 GameLogEcho(":gameinfo:end", FALSE);
 338         }
 339
 340         cvar_set("nextmap", "");
 341
 342         SetDefaultAlpha();
 343
 344         if(cvar("g_campaign"))
 345                 CampaignPostInit();
 346
 347         fteqcc_testbugs();
 348
 349         readlevelcvars();
 350
 351         Ban_LoadBans();
 352 }
 353
 354 void light (void)
 355 {
 356         //makestatic (self); // Who the f___ did that?
 357         remove(self);
 358 }
 359
 360 float( string pFilename ) TryFile =
 361 {
 362         local float lHandle;
 363         dprint("TryFile(\"", pFilename, "\")\n");
 364         lHandle = fopen( pFilename, FILE_READ );
 365         if( lHandle != -1 ) {
 366                 fclose( lHandle );
 367                 return TRUE;
 368         } else {
 369                 return FALSE;
 370         }
 371 };
 372
 373 string GetGametype()
 374 {
 375         if (game == GAME_DEATHMATCH)
 376                 return "dm";
 377         else if (game == GAME_TEAM_DEATHMATCH)
 378                 return "tdm";
 379         else if (game == GAME_DOMINATION)
 380                 return "dom";
 381         else if (game == GAME_CTF)
 382                 return "ctf";
 383         else if (game == GAME_RUNEMATCH)
 384                 return "rune";
 385         else if (game == GAME_LMS)
 386                 return "lms";
 387         else if (game == GAME_KEYHUNT)
 388                 return "kh";
 389         else if (game == GAME_ONSLAUGHT)
 390                 return "ons";
 391         else if (game == GAME_ASSAULT)
 392                 return "as";
 393         return "dm";
 394 }
 395
 396 float IsSameGametype(string mapcfgname)
 397 {
 398         string gt;
 399         gt = GetGametype();
 400         if(substring(mapcfgname, 0, strlen(gt) + 1) == strcat(gt, "_"))
 401                 return TRUE;
 402         return FALSE;
 403 }
 404
 405 string getmapname_stored;
 406 string GetMapname()
 407 {
 408         if(getmapname_stored == "")
 409                 getmapname_stored = strzone(strcat(GetGametype(), "_", mapname));
 410         return getmapname_stored;
 411 }
 412
 413 float Map_Count, Map_Current;
 414 string Map_Current_Name;
 415
 416 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 417 float GetMaplistPosition()
 418 {
 419         float pos, idx;
 420         string map;
 421
 422         map = GetMapname();
 423         idx = cvar("g_maplist_index");
 424
 425         if(idx >= 0)
 426                 if(idx < Map_Count)
 427                         if(map == argv(idx))
 428                                 return idx;
 429
 430         for(pos = 0; pos < Map_Count; ++pos)
 431                 if(map == argv(pos))
 432                         return pos;
 433
 434         // resume normal maplist rotation if current map is not in g_maplist
 435         return idx;
 436 }
 437
 438 float MapHasRightSize(string map)
 439 {
 440         // open map size restriction file
 441         float fh;
 442         dprint("opensize "); dprint(map);
 443         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 444         if(fh >= 0)
 445         {
 446                 float mapmin, mapmax;
 447                 dprint(": ok, ");
 448                 mapmin = stof(fgets(fh));
 449                 mapmax = stof(fgets(fh));
 450                 fclose(fh);
 451                 if(player_count < mapmin)
 452                 {
 453                         dprint("not enough\n");
 454                         return FALSE;
 455                 }
 456                 if(player_count > mapmax)
 457                 {
 458                         dprint("too many\n");
 459                         return FALSE;
 460                 }
 461                 dprint("right size\n");
 462                 return TRUE;
 463         }
 464         dprint(": not found\n");
 465         return TRUE;
 466 }
 467
 468 string Map_Filename(float position)
 469 {
 470         // FIXME unused
 471         return strcat("maps/", argv(position), ".mapcfg");
 472 }
 473
 474 string strwords(string s, float w)
 475 {
 476         float endpos;
 477         for(endpos = 0; w && endpos >= 0; --w)
 478                 endpos = strstrofs(s, " ", endpos + 1);
 479         if(endpos < 0)
 480                 return s;
 481         else
 482                 return substring(s, 0, endpos);
 483 }
 484
 485 float strhasword(string s, string w)
 486 {
 487         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 488 }
 489
 490 void Map_MarkAsRecent(string m)
 491 {
 492         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 493 }
 494
 495 float Map_IsRecent(string m)
 496 {
 497         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 498 }
 499
 500 float(float position, float pass) Map_Check =
 501 {
 502         string filename;
 503         string map_next;
 504         map_next = argv(position);
 505         if(pass <= 1)
 506         {
 507                 if(map_next == Map_Current_Name) // same map again in first pass?
 508                         return 0;
 509                 if(Map_IsRecent(map_next))
 510                         return 0;
 511         }
 512         filename = Map_Filename(position);
 513         if(TryFile(filename))
 514         {
 515                 if(pass == 2)
 516                         return 1;
 517                 if(MapHasRightSize(argv(position)))
 518                         return 1;
 519                 return 0;
 520         }
 521         else
 522                 dprint( "Couldn't find '", filename, "'..\n" );
 523
 524         return 0;
 525 }
 526
 527 void(string nextmapname) Map_Goto_SetStr =
 528 {
 529         if(getmapname_stored != "")
 530                 strunzone(getmapname_stored);
 531         if(nextmapname == "")
 532                 getmapname_stored = "";
 533         else
 534                 getmapname_stored = strzone(nextmapname);
 535 }
 536
 537 void(float position) Map_Goto_SetFloat =
 538 {
 539         cvar_set("g_maplist_index", ftos(position));
 540         Map_Goto_SetStr(argv(position));
 541 }
 542
 543 void() GameResetCfg =
 544 {
 545         // if an exit cfg is defined by exiting map, exec it.
 546         string exit_cfg;
 547         exit_cfg = cvar_string("exit_cfg");
 548         if(exit_cfg != "")
 549                 localcmd(strcat("exec \"", exit_cfg, "\"\n"));
 550
 551         localcmd("exec game_reset.cfg\n");
 552
 553         Ban_SaveBans();
 554 };
 555
 556 void() Map_Goto =
 557 {
 558         Map_MarkAsRecent(getmapname_stored);
 559         GameResetCfg();
 560         localcmd(strcat("exec \"maps/", getmapname_stored ,".mapcfg\"\n"));
 561 }
 562
 563 // return codes of map selectors:
 564 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 565 //   -2 = permanent failure
 566 float() MaplistMethod_Iterate = // usual method
 567 {
 568         float pass, i;
 569
 570         for(pass = 1; pass <= 2; ++pass)
 571         {
 572                 for(i = 1; i < Map_Count; ++i)
 573                 {
 574                         float mapindex;
 575                         mapindex = math_mod(i + Map_Current, Map_Count);
 576                         if(Map_Check(mapindex, pass))
 577                                 return mapindex;
 578                 }
 579         }
 580         return -1;
 581 }
 582
 583 float() MaplistMethod_Repeat = // fallback method
 584 {
 585         if(Map_Check(Map_Current, 2))
 586                 return Map_Current;
 587         return -2;
 588 }
 589
 590 float() MaplistMethod_Random = // random map selection
 591 {
 592         float i, imax;
 593
 594         imax = 42;
 595
 596         for(i = 0; i <= imax; ++i)
 597         {
 598                 float mapindex;
 599                 mapindex = math_mod(Map_Current + ceil(random() * (Map_Count - 1)), Map_Count); // any OTHER map
 600                 if(Map_Check(mapindex, 1))
 601                         return mapindex;
 602         }
 603         return -1;
 604 }
 605
 606 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 607 // the exponent sets a bias on the map selection:
 608 // the higher the exponent, the less likely "shortly repeated" same maps are
 609 {
 610         float i, j, imax, insertpos;
 611
 612         imax = 42;
 613
 614         if(Map_Count <= 1)
 615                 return 0; // only one map, then always play this one
 616
 617         for(i = 0; i <= imax; ++i)
 618         {
 619                 string newlist;
 620
 621                 // now reinsert this at another position
 622                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 623                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 624                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 625                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 626
 627                 // insert the current map there
 628                 newlist = "";
 629                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 630                         newlist = strcat(newlist, "'", argv(j), "'");
 631                 newlist = strcat(newlist, "'", argv(0), "'");  // now insert the just selected map
 632                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 633                         newlist = strcat(newlist, "'", argv(j), "'");
 634                 cvar_set("g_maplist", newlist);
 635                 Map_Count = tokenize(newlist);
 636
 637                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 638                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 639                 if(Map_Check(Map_Current, 1))
 640                         return Map_Current;
 641         }
 642         return -1;
 643 }
 644
 645 void() Maplist_Init =
 646 {
 647         string temp;
 648         temp = cvar_string("g_maplist");
 649         Map_Count = tokenize(temp);
 650         if(Map_Count == 0)
 651         {
 652                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 653                 cvar_set("g_maplist", temp = cvar_string("g_maplist_defaultlist"));
 654                 Map_Count = tokenize(temp);
 655         }
 656         if(Map_Count == 0)
 657                 error("empty maplist, cannot select a new map");
 658         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 659
 660         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 661         // this may or may not be correct, but who cares, in the worst case a map
 662         // isn't chosen in the first pass that should have been
 663 }
 664
 665 string() GetNextMap =
 666 {
 667         float nextMap;
 668
 669         Maplist_Init();
 670         nextMap = -1;
 671
 672         if(nextMap == -1)
 673                 if(cvar("g_maplist_shuffle") > 0)
 674                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 675
 676         if(nextMap == -1)
 677                 if(cvar("g_maplist_selectrandom"))
 678                         nextMap = MaplistMethod_Random();
 679
 680         if(nextMap == -1)
 681                 nextMap = MaplistMethod_Iterate();
 682
 683         if(nextMap == -1)
 684                 nextMap = MaplistMethod_Repeat();
 685
 686         if(nextMap >= 0)
 687         {
 688                 Map_Goto_SetFloat(nextMap);
 689                 return getmapname_stored;
 690         }
 691
 692         return "";
 693 };
 694
 695 float() DoNextMapOverride =
 696 {
 697         Ban_SaveBans();
 698
 699         if(cvar("g_campaign"))
 700         {
 701                 CampaignPostIntermission();
 702                 alreadychangedlevel = TRUE;
 703                 return TRUE;
 704         }
 705         if(cvar("quit_when_empty"))
 706         {
 707                 if(player_count <= currentbots)
 708                 {
 709                         localcmd("quit\n");
 710                         alreadychangedlevel = TRUE;
 711                         return TRUE;
 712                 }
 713         }
 714         if(cvar_string("quit_and_redirect") != "")
 715         {
 716                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 717                 alreadychangedlevel = TRUE;
 718                 return TRUE;
 719         }
 720         if (cvar("samelevel")) // if samelevel is set, stay on same level
 721         {
 722                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 723                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 724                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 725                 localcmd("restart\n");
 726                 //changelevel (mapname);
 727                 alreadychangedlevel = TRUE;
 728                 return TRUE;
 729         }
 730         if(cvar_string("nextmap") != "")
 731                 if(TryFile(strcat("maps/", cvar_string("nextmap"), ".mapcfg")))
 732                 {
 733                         Map_Goto_SetStr(cvar_string("nextmap"));
 734                         Map_Goto();
 735                         alreadychangedlevel = TRUE;
 736                         return TRUE;
 737                 }
 738         if(cvar("lastlevel"))
 739         {
 740                 GameResetCfg();
 741                 localcmd("set lastlevel 0\ntogglemenu\n");
 742                 alreadychangedlevel = TRUE;
 743                 return TRUE;
 744         }
 745         return FALSE;
 746 };
 747
 748 void() GotoNextMap =
 749 {
 750         //local string nextmap;
 751         //local float n, nummaps;
 752         //local string s;
 753         if (alreadychangedlevel)
 754                 return;
 755         alreadychangedlevel = TRUE;
 756
 757         {
 758                 string nextMap;
 759                 float allowReset;
 760
 761                 for(allowReset = 1; allowReset >= 0; --allowReset)
 762                 {
 763                         nextMap = GetNextMap();
 764                         if(nextMap != "")
 765                                 break;
 766
 767                         if(allowReset)
 768                         {
 769                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 770                                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
 771                         }
 772                         else
 773                         {
 774                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 775                         }
 776                 }
 777                 Map_Goto();
 778         }
 779 };
 780
 781
 782 /*
 783 ============
 784 IntermissionThink
 785
 786 When the player presses attack or jump, change to the next level
 787 ============
 788 */
 789 .float autoscreenshot;
 790 void() MapVote_Start;
 791 void() MapVote_Think;
 792 float mapvote_initialized;
 793 void() IntermissionThink =
 794 {
 795         FixIntermissionClient(self);
 796
 797         if(cvar("sv_autoscreenshot"))
 798         if(self.autoscreenshot > 0)
 799         if(time > self.autoscreenshot)
 800         {
 801                 self.autoscreenshot = -1;
 802                 if(clienttype(self) == CLIENTTYPE_REAL)
 803                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 804                 return;
 805         }
 806
 807         if (time < intermission_exittime)
 808                 return;
 809
 810         if(!mapvote_initialized)
 811                 if (time < intermission_exittime + 10 && !self.button0 && !self.button2 && !self.button3 && !self.button6 && !self.buttonuse)
 812                         return;
 813
 814         MapVote_Start();
 815 };
 816
 817 /*
 818 ============
 819 FindIntermission
 820
 821 Returns the entity to view from
 822 ============
 823 */
 824 /*
 825 entity() FindIntermission =
 826 {
 827         local   entity spot;
 828         local   float cyc;
 829
 830 // look for info_intermission first
 831         spot = find (world, classname, "info_intermission");
 832         if (spot)
 833         {       // pick a random one
 834                 cyc = random() * 4;
 835                 while (cyc > 1)
 836                 {
 837                         spot = find (spot, classname, "info_intermission");
 838                         if (!spot)
 839                                 spot = find (spot, classname, "info_intermission");
 840                         cyc = cyc - 1;
 841                 }
 842                 return spot;
 843         }
 844
 845 // then look for the start position
 846         spot = find (world, classname, "info_player_start");
 847         if (spot)
 848                 return spot;
 849
 850 // testinfo_player_start is only found in regioned levels
 851         spot = find (world, classname, "testplayerstart");
 852         if (spot)
 853                 return spot;
 854
 855 // then look for the start position
 856         spot = find (world, classname, "info_player_deathmatch");
 857         if (spot)
 858                 return spot;
 859
 860         //objerror ("FindIntermission: no spot");
 861         return world;
 862 };
 863 */
 864
 865 /*
 866 ===============================================================================
 867
 868 RULES
 869
 870 ===============================================================================
 871 */
 872
 873 void(float final) DumpStats =
 874 {
 875         local float file;
 876         local string s;
 877         local float to_console;
 878         local float to_eventlog;
 879         local float to_file;
 880
 881         to_console = cvar("sv_logscores_console");
 882         to_eventlog = cvar("sv_eventlog");
 883         to_file = cvar("sv_logscores_file");
 884
 885         if(!final)
 886         {
 887                 to_console = TRUE; // always print printstats replies
 888                 to_eventlog = FALSE; // but never print them to the event log
 889         }
 890
 891         if(to_eventlog)
 892                 if(cvar("sv_eventlog_console"))
 893                         to_console = FALSE; // otherwise we get the output twice
 894
 895         if(final)
 896                 s = ":scores:";
 897         else
 898                 s = ":status:";
 899         s = strcat(s, GetMapname(), ":", ftos(rint(time)));
 900
 901         if(to_console)
 902                 ServerConsoleEcho(s, FALSE);
 903         if(to_eventlog)
 904                 GameLogEcho(s, FALSE);
 905         if(to_file)
 906         {
 907                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
 908                 if(file == -1)
 909                         to_file = FALSE;
 910                 else
 911                         fputs(file, strcat(s, "\n"));
 912         }
 913
 914         FOR_EACH_CLIENT(other)
 915         {
 916                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
 917                 {
 918                         s = strcat(":player:", ftos(other.frags), ":");
 919                         s = strcat(s, ftos(other.deaths), ":");
 920                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
 921                         s = strcat(s, ftos(other.team), ":");
 922
 923                         if(to_console)
 924                                 ServerConsoleEcho(strcat(s, other.netname), TRUE);
 925                         if(to_eventlog)
 926                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname), TRUE);
 927                         if(to_file)
 928                                 fputs(file, strcat(s, other.netname, "\n"));
 929                 }
 930         }
 931
 932         if(to_console)
 933                 ServerConsoleEcho(":end", FALSE);
 934         if(to_eventlog)
 935                 GameLogEcho(":end", FALSE);
 936         if(to_file)
 937         {
 938                 fputs(file, ":end\n");
 939                 fclose(file);
 940         }
 941 }
 942
 943 void FixIntermissionClient(entity e)
 944 {
 945         if(!e.autoscreenshot) // initial call
 946         {
 947                 e.angles = e.v_angle;
 948                 e.angles_x = -e.angles_x;
 949                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
 950                 e.health = -2342;
 951                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
 952                 e.solid = SOLID_NOT;
 953                 e.movetype = MOVETYPE_NONE;
 954                 e.takedamage = DAMAGE_NO;
 955                 if(e.weaponentity)
 956                         e.weaponentity.effects = EF_NODRAW;
 957                 stuffcmd(e, "\nscr_printspeed 1000000\n");
 958                 if(clienttype(e) == CLIENTTYPE_REAL)
 959                 {
 960                         msg_entity = e;
 961                         WriteByte(MSG_ONE, SVC_INTERMISSION);
 962                 }
 963         }
 964
 965         //e.velocity = '0 0 0';
 966         //e.fixangle = TRUE;
 967
 968         // TODO halt weapon animation
 969 }
 970
 971
 972 /*
 973 go to the next level for deathmatch
 974 only called if a time or frag limit has expired
 975 */
 976 void() NextLevel =
 977 {
 978         float minTotalFrags;
 979         float maxTotalFrags;
 980         float score;
 981         float f;
 982
 983         gameover = TRUE;
 984
 985         intermission_running = 1;
 986
 987 // enforce a wait time before allowing changelevel
 988         if(player_count > 0)
 989                 intermission_exittime = time + cvar("sv_mapchange_delay");
 990         else
 991                 intermission_exittime = -1;
 992
 993         WriteByte (MSG_ALL, SVC_CDTRACK);
 994         WriteByte (MSG_ALL, 3);
 995         WriteByte (MSG_ALL, 3);
 996
 997         //pos = FindIntermission ();
 998
 999         VoteReset();
1000
1001         DumpStats(TRUE);
1002
1003         if(cvar("sv_eventlog"))
1004                 GameLogEcho(":gameover", FALSE);
1005
1006         GameLogClose();
1007
1008         FOR_EACH_CLIENT(other)
1009         {
1010                 FixIntermissionClient(other);
1011
1012                 if(other.winning)
1013                         bprint(other.netname, " ^7wins.\n");
1014         }
1015
1016         minTotalFrags = 0;
1017         maxTotalFrags = 0;
1018         FOR_EACH_PLAYER(other)
1019         {
1020                 if(maxTotalFrags < other.totalfrags)
1021                         maxTotalFrags = other.totalfrags;
1022                 if(minTotalFrags > other.totalfrags)
1023                         minTotalFrags = other.totalfrags;
1024         }
1025
1026         if(!currentbots)
1027         {
1028                 FOR_EACH_PLAYER(other)
1029                 {
1030                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1031                         f = bound(0, other.play_time / max(time, 1), 1);
1032                         // store some statistics?
1033                 }
1034         }
1035
1036         if(cvar("g_campaign"))
1037                 CampaignPreIntermission();
1038
1039         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1040 };
1041
1042 /*
1043 ============
1044 CheckRules_Player
1045
1046 Exit deathmatch games upon conditions
1047 ============
1048 */
1049 void() CheckRules_Player =
1050 {
1051         if (gameover)   // someone else quit the game already
1052                 return;
1053
1054         if(self.deadflag == DEAD_NO)
1055                 self.play_time += frametime;
1056
1057         // fixme: don't check players; instead check dom_team and ctf_team entities
1058         //   (div0: and that in CheckRules_World please)
1059 };
1060
1061 float checkrules_oneminutewarning;
1062 float checkrules_leaderfrags;
1063 float tdm_max_score, tdm_old_score;
1064
1065 float checkrules_equality;
1066 float checkrules_overtimewarning;
1067 float checkrules_overtimeend;
1068
1069 void() InitiateOvertime =
1070 {
1071         if(!checkrules_overtimeend)
1072                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1073 }
1074
1075 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1076 float WINNING_YES = 1; // winner found
1077 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1078 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1079
1080 float(float fraglimitreached, float equality) GetWinningCode =
1081 {
1082         if(equality)
1083                 if(fraglimitreached)
1084                         return WINNING_STARTOVERTIME;
1085                 else
1086                         return WINNING_NEVER;
1087         else
1088                 if(fraglimitreached)
1089                         return WINNING_YES;
1090                 else
1091                         return WINNING_NO;
1092 }
1093
1094 // set the .winning flag for exactly those players with a given field value
1095 void(.float field, float value) SetWinners =
1096 {
1097         entity head;
1098         FOR_EACH_PLAYER(head)
1099                 head.winning = (head.field == value);
1100 }
1101
1102 // set the .winning flag for those players with a given field value
1103 void(.float field, float value) AddWinners =
1104 {
1105         entity head;
1106         FOR_EACH_PLAYER(head)
1107                 if(head.field == value)
1108                         head.winning = 1;
1109 }
1110
1111 // clear the .winning flags
1112 void(void) ClearWinners =
1113 {
1114         entity head;
1115         FOR_EACH_PLAYER(head)
1116                 head.winning = 0;
1117 }
1118
1119 // Onslaught winning condition:
1120 // game terminates if only one team has a working generator (or none)
1121 float() WinningCondition_Onslaught =
1122 {
1123         entity head;
1124         local float t1, t2, t3, t4;
1125         // first check if the game has ended
1126         t1 = t2 = t3 = t4 = 0;
1127         head = find(world, classname, "onslaught_generator");
1128         while (head)
1129         {
1130                 if (head.health > 0)
1131                 {
1132                         if (head.team == COLOR_TEAM1) t1 = 1;
1133                         if (head.team == COLOR_TEAM2) t2 = 1;
1134                         if (head.team == COLOR_TEAM3) t3 = 1;
1135                         if (head.team == COLOR_TEAM4) t4 = 1;
1136                 }
1137                 head = find(head, classname, "onslaught_generator");
1138         }
1139         if (t1 + t2 + t3 + t4 < 2)
1140         {
1141                 // game over, only one team remains (or none)
1142                 ClearWinners();
1143                 if (t1) SetWinners(team, COLOR_TEAM1);
1144                 if (t2) SetWinners(team, COLOR_TEAM2);
1145                 if (t3) SetWinners(team, COLOR_TEAM3);
1146                 if (t4) SetWinners(team, COLOR_TEAM4);
1147                 dprint("Have a winner, ending game.\n");
1148                 return WINNING_YES;
1149         }
1150
1151         // Two or more teams remain
1152         return WINNING_NO;
1153 }
1154
1155 float() LMS_NewPlayerLives =
1156 {
1157         float fl;
1158         fl = cvar("fraglimit");
1159         if(fl == 0)
1160                 fl = 999;
1161
1162         // first player has left the game for dying too much? Nobody else can get in.
1163         if(lms_lowest_lives < 1)
1164                 return FALSE;
1165
1166         if(!cvar("g_lms_join_anytime"))
1167                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1168                         return FALSE;
1169
1170         return bound(1, lms_lowest_lives, fl);
1171 }
1172
1173 // LMS winning condition: game terminates if and only if there's at most one
1174 // one player who's living lives. Top two scores being equal cancels the time
1175 // limit.
1176 float() WinningCondition_LMS =
1177 {
1178         entity head;
1179         float have_player;
1180         float have_players;
1181         float l;
1182
1183         have_player = FALSE;
1184         have_players = FALSE;
1185         l = LMS_NewPlayerLives();
1186
1187         head = find(world, classname, "player");
1188         if(head)
1189                 have_player = TRUE;
1190         head = find(head, classname, "player");
1191         if(head)
1192                 have_players = TRUE;
1193
1194         if(have_player)
1195         {
1196                 // we have at least one player
1197                 if(have_players)
1198                 {
1199                         // two or more active players - continue with the game
1200                 }
1201                 else
1202                 {
1203                         // exactly one player?
1204                         if(l)
1205                         {
1206                                 // but no game has taken place yet
1207                         }
1208                         else
1209                         {
1210                                 // a winner!
1211                                 ClearWinners(); SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1212                                 dprint("Have a winner, ending game.\n");
1213                                 return WINNING_YES;
1214                         }
1215                 }
1216         }
1217         else
1218         {
1219                 // nobody is playing at all...
1220                 if(l)
1221                 {
1222                         // wait for players...
1223                 }
1224                 else
1225                 {
1226                         // SNAFU (maybe a draw game?)
1227                         ClearWinners();
1228                         dprint("No players, ending game.\n");
1229                         return WINNING_YES;
1230                 }
1231         }
1232
1233         // When we get here, we have at least two players who are actually LIVING,
1234         // or one player who is still waiting for a victim to join the server. Now
1235         // check if the top two players have equal score.
1236
1237         checkrules_leaderfrags = 0;
1238         checkrules_equality = FALSE;
1239         FOR_EACH_PLAYER(head)
1240         {
1241                 if(head.frags > checkrules_leaderfrags)
1242                 {
1243                         checkrules_leaderfrags = head.frags;
1244                         checkrules_equality = FALSE;
1245                 }
1246                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
1247                         checkrules_equality = TRUE;
1248         }
1249
1250         SetWinners(frags, checkrules_leaderfrags);
1251
1252         // The top two players have the same amount of lives? No timelimit then,
1253         // enter overtime...
1254
1255         if(checkrules_equality)
1256                 return WINNING_NEVER;
1257
1258         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1259         return WINNING_NO;
1260 }
1261
1262 // DM winning condition: game terminates if a player reached the fraglimit,
1263 // unless the first two players have the same score. The latter case also
1264 // breaks the time limit.
1265 float(float fraglimit) WinningCondition_MaxIndividualScore =
1266 {
1267         float checkrules_oldleaderfrags;
1268         entity head;
1269
1270         checkrules_oldleaderfrags = checkrules_leaderfrags;
1271         checkrules_leaderfrags = 0;
1272         checkrules_equality = FALSE;
1273         FOR_EACH_PLAYER(head)
1274         {
1275                 if(head.frags > checkrules_leaderfrags)
1276                 {
1277                         checkrules_leaderfrags = head.frags;
1278                         checkrules_equality = FALSE;
1279                 }
1280                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
1281                         checkrules_equality = TRUE;
1282         }
1283
1284         if(checkrules_leaderfrags > 0)
1285                 SetWinners(frags, checkrules_leaderfrags);
1286         else
1287                 ClearWinners();
1288
1289         if (!cvar("g_runematch"))
1290                 if (checkrules_leaderfrags != checkrules_oldleaderfrags)
1291                 {
1292                         if (checkrules_leaderfrags == fraglimit - 1)
1293                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.wav", 1, ATTN_NONE);
1294                         else if (checkrules_leaderfrags == fraglimit - 2)
1295                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.wav", 1, ATTN_NONE);
1296                         else if (checkrules_leaderfrags == fraglimit - 3)
1297                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.wav", 1, ATTN_NONE);
1298                 }
1299
1300         return GetWinningCode(fraglimit && checkrules_leaderfrags >= fraglimit, checkrules_equality);
1301 }
1302
1303 float(float fraglimit) WinningConditionBase_Teamplay =
1304 {
1305         tdm_old_score = tdm_max_score;
1306         tdm_max_score = max4(team1_score, team2_score, team3_score, team4_score);
1307
1308         checkrules_equality =
1309         (
1310                 (tdm_max_score > 0)
1311                 &&
1312                 (
1313                           (team1_score == tdm_max_score)
1314                         + (team2_score == tdm_max_score)
1315                         + (team3_score == tdm_max_score)
1316                         + (team4_score == tdm_max_score)
1317                         >= 2));
1318
1319         ClearWinners();
1320         if(tdm_max_score > 0)
1321         {
1322                 if(team1_score == tdm_max_score)
1323                         AddWinners(team, COLOR_TEAM1);
1324                 if(team2_score == tdm_max_score)
1325                         AddWinners(team, COLOR_TEAM2);
1326                 if(team3_score == tdm_max_score)
1327                         AddWinners(team, COLOR_TEAM3);
1328                 if(team4_score == tdm_max_score)
1329                         AddWinners(team, COLOR_TEAM4);
1330         }
1331
1332         if(!cvar("g_runematch") && !cvar("g_domination"))
1333                 if(tdm_max_score != tdm_old_score)
1334                 {
1335                         if(tdm_max_score == fraglimit - 1)
1336                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.wav", 1, ATTN_NONE);
1337                         else if(tdm_max_score == fraglimit - 2)
1338                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.wav", 1, ATTN_NONE);
1339                         else if(tdm_max_score == fraglimit - 3)
1340                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.wav", 1, ATTN_NONE);
1341                 }
1342
1343         return GetWinningCode(fraglimit && tdm_max_score >= fraglimit, checkrules_equality);
1344 }
1345
1346 // TDM winning condition: game terminates if a team's score sum reached the
1347 // fraglimit, unless the first two teams have the same total score. The latter
1348 // case also breaks the time limit.
1349 float(float fraglimit) WinningCondition_MaxTeamSum =
1350 {
1351         entity head;
1352
1353         team1_score = team2_score = team3_score = team4_score = 0;
1354
1355         FOR_EACH_PLAYER(head)
1356         {
1357                 if(head.team == COLOR_TEAM1)
1358                         team1_score += head.frags;
1359                 else if(head.team == COLOR_TEAM2)
1360                         team2_score += head.frags;
1361                 else if(head.team == COLOR_TEAM3)
1362                         team3_score += head.frags;
1363                 else if(head.team == COLOR_TEAM4)
1364                         team4_score += head.frags;
1365         }
1366
1367         return WinningConditionBase_Teamplay(fraglimit);
1368 }
1369
1370 // DOM/CTF winning condition: game terminates if the max of a team's players'
1371 // score reached the fraglimit, unless the first two teams have the same
1372 // maximum score. The latter case also breaks the time limit.
1373 float(float fraglimit) WinningCondition_MaxTeamMax =
1374 {
1375         entity head;
1376
1377         team1_score = team2_score = team3_score = team4_score = 0;
1378
1379         FOR_EACH_PLAYER(head)
1380         {
1381                 if(head.team == COLOR_TEAM1)
1382                 {
1383                         if(head.frags > team1_score)
1384                                 team1_score = head.frags;
1385                 }
1386                 else if(head.team == COLOR_TEAM2)
1387                 {
1388                         if(head.frags > team2_score)
1389                                 team2_score = head.frags;
1390                 }
1391                 else if(head.team == COLOR_TEAM3)
1392                 {
1393                         if(head.frags > team3_score)
1394                                 team3_score = head.frags;
1395                 }
1396                 else if(head.team == COLOR_TEAM4)
1397                 {
1398                         if(head.frags > team4_score)
1399                                 team4_score = head.frags;
1400                 }
1401         }
1402
1403         return WinningConditionBase_Teamplay(fraglimit);
1404 }
1405
1406 void print_to(entity e, string s)
1407 {
1408         if(e)
1409                 sprint(e, strcat(s, "\n"));
1410         else
1411                 ServerConsoleEcho(s, TRUE);
1412 }
1413
1414 void PrintScoreboardFor(entity e, string name, string colorcode, float whichteam)
1415 {
1416         entity head;
1417         float v;
1418         float teamvalue;
1419         float fragtotal;
1420         string s;
1421         float found;
1422         found = FALSE;
1423         teamvalue = 0;
1424         FOR_EACH_PLAYER(head)
1425         {
1426                 if(!whichteam || head.team == whichteam)
1427                 {
1428                         if(name != "")
1429                                 if(!found)
1430                                         print_to(e, strcat(" ", colorcode, name, ":"));
1431                         found = TRUE;
1432                         fragtotal = fragtotal + head.frags;
1433                         s = ftos(head.frags);
1434                         s = strcat(s, "/", ftos(head.deaths));
1435                         s = strcat(s, " @ ", ftos(head.ping));
1436                         if(clienttype(head) == CLIENTTYPE_BOT)
1437                                 s = strcat(s, "botms");
1438                         else
1439                                 s = strcat(s, "ms");
1440                         v = PlayerValue(head);
1441                         teamvalue += v;
1442                         s = strcat(s, " / ", ftos(v));
1443                         print_to(e, strcat("  ", colorcode, head.netname, colorcode, " (", s, ")"));
1444                 }
1445         }
1446         if(whichteam && found)
1447         {
1448                 s = ftos(fragtotal);
1449                 s = strcat(s, " / ", ftos(teamvalue));
1450                 print_to(e, strcat(colorcode, "  (total: ", s, ")"));
1451         }
1452 }
1453
1454 void PrintScoreboard(entity e)
1455 {
1456         print_to(e, strcat("Time:      ", ftos(time / 60)));
1457         print_to(e, strcat("Timelimit: ", ftos(cvar("timelimit"))));
1458         print_to(e, strcat("Fraglimit: ", ftos(cvar("fraglimit"))));
1459         print_to(e, "Scoreboard:");
1460         if(teams_matter)
1461         {
1462                 PrintScoreboardFor(e, "Red", "^1", COLOR_TEAM1);
1463                 PrintScoreboardFor(e, "Blue", "^4", COLOR_TEAM2);
1464                 PrintScoreboardFor(e, "Yellow", "^3", COLOR_TEAM3);
1465                 PrintScoreboardFor(e, "Pink", "^6", COLOR_TEAM4);
1466         }
1467         else
1468         {
1469                 PrintScoreboardFor(e, "", "^7", 0);
1470         }
1471         print_to(e, ".");
1472 }
1473
1474 void ShuffleMaplist()
1475 {
1476         string result;
1477         float start;
1478         float litems;
1479         float selected;
1480         float i;
1481
1482         result = cvar_string("g_maplist");
1483         litems = tokenize(result);
1484
1485         for(start = 0; start < litems - 1; ++start)
1486         {
1487                 result = "";
1488
1489                 // select a random item
1490                 selected = ceil(random() * (litems - start) + start) - 1;
1491
1492                 // shift this item to the place start
1493                 for(i = 0; i < start; ++i)
1494                         result = strcat(result, "'", argv(i), "'");
1495                 result = strcat(result, "'", argv(selected), "'");
1496                 for(i = start; i < litems; ++i)
1497                         if(i != selected)
1498                                 result = strcat(result, "'", argv(i), "'");
1499
1500                 litems = tokenize(result);
1501
1502                 //dprint(result, "\n");
1503         }
1504
1505         cvar_set("g_maplist", result);
1506 }
1507
1508 /*
1509 ============
1510 CheckRules_World
1511
1512 Exit deathmatch games upon conditions
1513 ============
1514 */
1515 void() CheckRules_World =
1516 {
1517         local float status;
1518         local float timelimit;
1519         local float fraglimit;
1520
1521         VoteThink();
1522         MapVote_Think();
1523
1524         SetDefaultAlpha();
1525
1526         /*
1527         MapVote_Think should now do that part
1528         if (intermission_running)
1529                 if (time >= intermission_exittime + 60)
1530                 {
1531                         if(!DoNextMapOverride())
1532                                 GotoNextMap();
1533                         return;
1534                 }
1535         */
1536
1537         if (gameover)   // someone else quit the game already
1538         {
1539                 if(player_count == 0) // Nobody there? Then let's go to the next map
1540                         MapVote_Start();
1541                         // this will actually check the player count in the next frame
1542                         // again, but this shouldn't hurt
1543                 return;
1544         }
1545
1546         timelimit = cvar("timelimit") * 60;
1547         fraglimit = cvar("fraglimit");
1548
1549         if(checkrules_overtimeend)
1550         {
1551                 if(!checkrules_overtimewarning)
1552                 {
1553                         checkrules_overtimewarning = TRUE;
1554                         //sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", 1, ATTN_NONE);
1555                         bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1556                 }
1557         }
1558         else
1559         {
1560                 if (timelimit && time >= timelimit)
1561                         InitiateOvertime();
1562         }
1563
1564         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1565         {
1566                 NextLevel();
1567                 return;
1568         }
1569
1570         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1571         {
1572                 checkrules_oneminutewarning = TRUE;
1573                 sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", 1, ATTN_NONE);
1574         }
1575
1576         status = WINNING_NO;
1577         if(cvar("g_lms"))
1578         {
1579                 status = WinningCondition_LMS();
1580         }
1581         else if (cvar("g_onslaught"))
1582         {
1583                 status = WinningCondition_Onslaught();
1584         }
1585         else
1586         {
1587                 if(teams_matter)
1588                 {
1589                         if(cvar("g_tdm") || cvar("g_runematch") || cvar("g_ctf") || cvar("g_domination") || cvar("g_keyhunt"))
1590                                 status = WinningCondition_MaxTeamSum(fraglimit);
1591                         //else if()
1592                         //      status = WinningCondition_MaxTeamMax(fraglimit);
1593                         else
1594                         {
1595                                 dprint("div0: How can this happen?\n");
1596                                 status = WinningCondition_MaxTeamMax(fraglimit);
1597                         }
1598                 }
1599                 else
1600                         status = WinningCondition_MaxIndividualScore(fraglimit);
1601         }
1602
1603         if(status == WINNING_STARTOVERTIME)
1604         {
1605                 status = WINNING_NEVER;
1606                 InitiateOvertime();
1607         }
1608
1609         if(status == WINNING_NEVER)
1610                 // equality cases! Nobody wins if the overtime ends in a draw.
1611                 ClearWinners();
1612
1613         if(checkrules_overtimeend)
1614                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1615                         status = WINNING_YES;
1616
1617         if(status == WINNING_YES)
1618                 NextLevel();
1619 };
1620
1621 float randsel_value;
1622 float randsel_priority;
1623 float randsel_count;
1624 void RandSel_Init()
1625 {
1626         randsel_value = -1;
1627         randsel_priority = -1;
1628         randsel_count = -1;
1629 }
1630 void RandSel_Add(float priority, float value)
1631 {
1632         if(priority > randsel_priority)
1633         {
1634                 randsel_priority = priority;
1635                 randsel_value = value;
1636                 randsel_count = 1;
1637         }
1638         else if(priority == randsel_priority)
1639         {
1640                 randsel_count += 1;
1641                 if(ceil(random() * randsel_count) == 1)
1642                         randsel_value = value;
1643         }
1644 }
1645
1646 float mapvote_nextthink;
1647 float mapvote_initialized;
1648 float mapvote_keeptwotime;
1649 float mapvote_timeout;
1650 string mapvote_message;
1651
1652 #define MAPVOTE_COUNT 10
1653 float mapvote_count;
1654 string mapvote_maps[MAPVOTE_COUNT];
1655 float mapvote_maps_suggested[MAPVOTE_COUNT];
1656 string mapvote_suggestions[MAPVOTE_COUNT];
1657 float mapvote_suggestion_ptr;
1658 float mapvote_maxlen;
1659 float mapvote_voters;
1660 float mapvote_votes[MAPVOTE_COUNT];
1661 float mapvote_run;
1662 .float mapvote;
1663
1664 void MapVote_ClearAllVotes()
1665 {
1666         FOR_EACH_CLIENT(other)
1667                 other.mapvote = 0;
1668 }
1669
1670 string MapVote_Suggest(string m)
1671 {
1672         float i;
1673         if(m == "")
1674                 return "That's not how to use this command.";
1675         if(!cvar("g_maplist_votable_suggestions"))
1676                 return "Suggestions are not accepted on this server.";
1677         if(mapvote_initialized)
1678                 return "Can't suggest - voting is already in progress!";
1679         if(!cvar("g_maplist_votable_suggestions_change_gametype"))
1680                 if(!IsSameGametype(m))
1681                         return "This server does not allow changing the game type by map suggestions.";
1682         if(!cvar("g_maplist_votable_override_mostrecent"))
1683                 if(Map_IsRecent(m))
1684                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1685
1686         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1687                 return "The map you suggested is not available on this server.";
1688         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1689                 if(mapvote_suggestions[i] == m)
1690                         return "This map was already suggested.";
1691         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1692         {
1693                 i = ceil(random() * mapvote_suggestion_ptr) - 1;
1694         }
1695         else
1696         {
1697                 i = mapvote_suggestion_ptr;
1698                 mapvote_suggestion_ptr += 1;
1699         }
1700         if(mapvote_suggestions[i] != "")
1701                 strunzone(mapvote_suggestions[i]);
1702         mapvote_suggestions[i] = strzone(m);
1703         GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid), ":", self.netname), TRUE);
1704         return "Suggestion accepted.";
1705 }
1706
1707 void MapVote_AddVotable(string nextMap, float isSuggestion)
1708 {
1709         float j;
1710         if(nextMap == "")
1711                 return;
1712         for(j = 0; j < mapvote_count; ++j)
1713                 if(mapvote_maps[j] == nextMap)
1714                         return;
1715         if(strlen(nextMap) > mapvote_maxlen)
1716                 mapvote_maxlen = strlen(nextMap);
1717         mapvote_maps[mapvote_count] = strzone(nextMap);
1718         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1719         mapvote_count += 1;
1720 }
1721
1722 void MapVote_Init()
1723 {
1724         float i;
1725         float nmax, smax;
1726
1727         MapVote_ClearAllVotes();
1728
1729         nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
1730         smax = min(nmax, cvar("g_maplist_votable_suggestions"));
1731         mapvote_count = 0;
1732
1733         for(i = 0; i < 100 && mapvote_count < smax; ++i)
1734                 MapVote_AddVotable(mapvote_suggestions[ceil(random() * mapvote_suggestion_ptr) - 1], TRUE);
1735
1736         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1737                 MapVote_AddVotable(GetNextMap(), FALSE);
1738
1739         if(mapvote_count == 0)
1740         {
1741                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1742                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
1743                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1744                         MapVote_AddVotable(GetNextMap(), FALSE);
1745         }
1746
1747         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
1748
1749         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
1750         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
1751         if(mapvote_count < 3 || mapvote_keeptwotime <= time)
1752                 mapvote_keeptwotime = 0;
1753         mapvote_message = "Choose a map and press its key!";
1754 }
1755 float MapVote_Finished(float mappos)
1756 {
1757         string result;
1758         float i;
1759
1760         result = strcat(":vote:finished:", mapvote_maps[mappos]);
1761         result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
1762         for(i = 0; i < mapvote_count; ++i)
1763                 if(i != mappos)
1764                         if(mapvote_maps[i] != "")
1765                         {
1766                                 result = strcat(result, ":", mapvote_maps[i]);
1767                                 result = strcat(result, ":", ftos(mapvote_votes[i]));
1768                         }
1769         GameLogEcho(result, FALSE);
1770         if(mapvote_maps_suggested[mappos])
1771                 GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]), FALSE);
1772
1773         FOR_EACH_REALCLIENT(other)
1774                 FixClientCvars(other);
1775
1776         Map_Goto_SetStr(mapvote_maps[mappos]);
1777         Map_Goto();
1778         alreadychangedlevel = TRUE;
1779         return TRUE;
1780 }
1781 void MapVote_CheckRules_1()
1782 {
1783         float i;
1784
1785         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1786         {
1787                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
1788                 mapvote_votes[i] = 0;
1789         }
1790
1791         mapvote_voters = 0;
1792         FOR_EACH_REALCLIENT(other)
1793         {
1794                 ++mapvote_voters;
1795                 if(other.mapvote)
1796                 {
1797                         i = other.mapvote - 1;
1798                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
1799                         mapvote_votes[i] = mapvote_votes[i] + 1;
1800                 }
1801         }
1802 }
1803
1804 float MapVote_CheckRules_2()
1805 {
1806         float i;
1807         float firstPlace, secondPlace;
1808         float firstPlaceVotes, secondPlaceVotes;
1809         string result;
1810
1811         RandSel_Init();
1812         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1813                 RandSel_Add(mapvote_votes[i], i);
1814         firstPlace = randsel_value;
1815         firstPlaceVotes = randsel_priority;
1816         //dprint("First place: ", ftos(firstPlace), "\n");
1817         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
1818
1819         RandSel_Init();
1820         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1821                 if(i != firstPlace)
1822                         RandSel_Add(mapvote_votes[i], i);
1823         secondPlace = randsel_value;
1824         secondPlaceVotes = randsel_priority;
1825         //dprint("Second place: ", ftos(secondPlace), "\n");
1826         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
1827
1828         if(firstPlace == -1)
1829                 error("No first place in map vote... WTF?");
1830
1831         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters - firstPlaceVotes) < firstPlaceVotes)
1832                 return MapVote_Finished(firstPlace);
1833
1834         if(mapvote_keeptwotime)
1835                 if(time > mapvote_keeptwotime || (mapvote_voters - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
1836                 {
1837                         mapvote_message = "Now decide between the TOP TWO!";
1838                         mapvote_keeptwotime = 0;
1839                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
1840                         result = strcat(result, ":", ftos(firstPlaceVotes));
1841                         result = strcat(result, ":", mapvote_maps[secondPlace]);
1842                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
1843                         for(i = 0; i < mapvote_count; ++i)
1844                                 if(i != firstPlace)
1845                                         if(i != secondPlace)
1846                                                 if(mapvote_maps[i] != "")
1847                                                 {
1848                                                         result = strcat(result, ":", mapvote_maps[i]);
1849                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
1850                                                         strunzone(mapvote_maps[i]);
1851                                                         mapvote_maps[i] = "";
1852                                                 }
1853                         GameLogEcho(result, FALSE);
1854                 }
1855
1856         return FALSE;
1857 }
1858 void MapVote_Tick()
1859 {
1860         string msgstr;
1861         string tmp;
1862         float i;
1863         float keeptwo;
1864
1865         keeptwo = mapvote_keeptwotime;
1866         MapVote_CheckRules_1(); // count
1867         if(MapVote_CheckRules_2()) // decide
1868                 return;
1869
1870         FOR_EACH_REALCLIENT(other)
1871         {
1872                 // hide scoreboard again
1873                 if(other.health != 2342)
1874                 {
1875                         other.health = 2342;
1876                         other.impulse = 0;
1877                         if(clienttype(other) == CLIENTTYPE_REAL)
1878                         {
1879                                 stuffcmd(other, "\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
1880                                 msg_entity = other;
1881                                 WriteByte(MSG_ONE, SVC_FINALE);
1882                                 WriteString(MSG_ONE, "");
1883                                 /*
1884                                 for(i = 0; i < mapvote_count; ++i)
1885                                         if(mapvote_maps[i] != "")
1886                                         {
1887                                                 tmp = mapvote_maps[i];
1888                                                 sprint(other, strcat("map voting: type ^1impulse ", ftos(i+1), "^7 to vote for ", tmp, "\n"));
1889                                         }
1890                                 */
1891                         }
1892                 }
1893
1894                 // notify about keep-two
1895                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
1896                         play2(other, "misc/invshot.wav");
1897
1898                 // clear possibly invalid votes
1899                 if(mapvote_maps[other.mapvote - 1] == "")
1900                         other.mapvote = 0;
1901                 // use impulses as new vote
1902                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
1903                         if(mapvote_maps[other.impulse - 1] != "")
1904                                 other.mapvote = other.impulse;
1905                 other.impulse = 0;
1906         }
1907
1908         MapVote_CheckRules_1(); // just count
1909
1910         FOR_EACH_REALCLIENT(other)
1911         {
1912                 // display voting screen
1913                 msgstr = "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n";
1914                 msgstr = substring(msgstr, 0, strlen(msgstr) - mapvote_count);
1915                 msgstr = strcat(msgstr, mapvote_message);
1916                 msgstr = strcat(msgstr, "\n\n");
1917                 for(i = 0; i < mapvote_count; ++i)
1918                         if(mapvote_maps[i] == "")
1919                                 msgstr = strcat(msgstr, "\n");
1920                         else
1921                         {
1922                                 tmp = mapvote_maps[i];
1923                                 tmp = strpad(mapvote_maxlen, tmp);
1924                                 tmp = strcat(ftos(math_mod(i + 1, 10)), ": ", tmp);
1925                                 tmp = strcat(tmp, " ^2(", ftos(mapvote_votes[i]), " vote");
1926                                 if(mapvote_votes[i] != 1)
1927                                         tmp = strcat(tmp, "s");
1928                                 tmp = strcat(tmp, ")");
1929                                 tmp = strpad(mapvote_maxlen + 15, tmp);
1930                                 if(other.mapvote == i + 1)
1931                                         msgstr = strcat(msgstr, "^3> ", tmp, "\n");
1932                                 else
1933                                         msgstr = strcat(msgstr, "^7  ", tmp, "\n");
1934                         }
1935                 i = ceil(mapvote_timeout - time);
1936                 msgstr = strcat(msgstr, "\n\n", ftos(i), " second");
1937                 if(i != 1)
1938                         msgstr = strcat(msgstr, "s");
1939                 msgstr = strcat(msgstr, " left");
1940
1941                 centerprint_atprio(other, CENTERPRIO_MAPVOTE, msgstr);
1942         }
1943 }
1944 void MapVote_Start()
1945 {
1946         mapvote_run = TRUE;
1947 }
1948 void MapVote_Think()
1949 {
1950         if(!mapvote_run)
1951                 return;
1952
1953         if(alreadychangedlevel)
1954                 return;
1955
1956         if(time < mapvote_nextthink)
1957                 return;
1958         //dprint("tick\n");
1959
1960         mapvote_nextthink = time + 0.5;
1961
1962         if(!mapvote_initialized)
1963         {
1964                 mapvote_initialized = TRUE;
1965                 if(DoNextMapOverride())
1966                         return;
1967                 if(!cvar("g_maplist_votable") || player_count <= 0)
1968                 {
1969                         GotoNextMap();
1970                         return;
1971                 }
1972                 MapVote_Init();
1973         }
1974
1975         MapVote_Tick();
1976 };
1977
1978 string GotoMap(string m)
1979 {
1980         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1981                 return "The map you chose is not available on this server.";
1982         cvar_set("nextmap", m);
1983         cvar_set("timelimit", "-1");
1984         if(mapvote_initialized || alreadychangedlevel)
1985         {
1986                 if(DoNextMapOverride())
1987                         return "Map switch initiated.";
1988                 else
1989                         return "Hm... no. For some reason I like THIS map more.";
1990         }
1991         else
1992                 return "Map switch will happen after scoreboard.";
1993 }
1994
1995
1996 void EndFrame()
1997 {
1998         FOR_EACH_REALCLIENT(self)
1999         {
2000                 if(self.classname == "spectator")
2001                 {
2002                         if(self.enemy.hitsound)
2003                                 play2(self, "misc/hit.wav");
2004                 }
2005                 else
2006                 {
2007                         if(self.hitsound)
2008                                 play2(self, "misc/hit.wav");
2009                 }
2010         }
2011         FOR_EACH_CLIENT(self)
2012                 self.hitsound = FALSE;
2013 }
2014
2015
2016 /*
2017  * RedirectionThink:
2018  * returns TRUE if redirecting
2019  */
2020 float redirection_timeout;
2021 float redirection_nextthink;
2022 float RedirectionThink()
2023 {
2024         float clients_found;
2025
2026         if(redirection_target == "")
2027                 return FALSE;
2028
2029         if(!redirection_timeout)
2030         {
2031                 cvar_set("sv_public", "-2");
2032                 redirection_timeout = time + 0.5; // this will only try twice... should be able to keep more clients
2033                 if(redirection_target == "self")
2034                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2035                 else
2036                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2037         }
2038
2039         if(time < redirection_nextthink)
2040                 return TRUE;
2041
2042         redirection_nextthink = time + 1;
2043
2044         clients_found = 0;
2045         FOR_EACH_REALCLIENT(self)
2046         {
2047                 ServerConsoleEcho(strcat("Redirecting: sending connect command to ", self.netname), FALSE);
2048                 if(redirection_target == "self")
2049                         stuffcmd(self, "\ndisconnect; reconnect\n");
2050                 else
2051                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2052                 ++clients_found;
2053         }
2054
2055         ServerConsoleEcho(strcat("Redirecting: ", ftos(clients_found), " clients left."), FALSE);
2056
2057         if(time > redirection_timeout || clients_found == 0)
2058                 localcmd("\nwait; wait; wait; quit\n");
2059
2060         return TRUE;
2061 }