data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 .string fog;
  12
  13 void SetDefaultAlpha()
  14 {
  15         if(cvar("g_running_guns"))
  16         {
  17                 default_player_alpha = -1;
  18                 default_weapon_alpha = +1;
  19         }
  20         else if(g_cloaked)
  21         {
  22                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  23                 default_weapon_alpha = default_player_alpha;
  24         }
  25         else
  26         {
  27                 default_player_alpha = cvar("g_player_alpha");
  28                 if(default_player_alpha <= 0)
  29                         default_player_alpha = 1;
  30                 default_weapon_alpha = default_player_alpha;
  31         }
  32 }
  33
  34 void fteqcc_testbugs()
  35 {
  36         float a, b;
  37
  38         if(!cvar("developer_fteqccbugs"))
  39                 return;
  40
  41         dprint("*** fteqcc test: checking for bugs...\n");
  42
  43         a = 1;
  44         b = 5;
  45         if(sqrt(a) - sqrt(b - a) == 0)
  46                 dprint("*** fteqcc test: found same-function-twice bug\n");
  47         else
  48                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  49
  50         world.cnt = -10;
  51         world.enemy = world;
  52         world.enemy.cnt += 10;
  53         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  54                 dprint("*** fteqcc test: found += bug\n");
  55         else
  56                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  57         world.cnt = 0;
  58 }
  59
  60 /**
  61  * Takes care of pausing and unpausing the game.
  62  * Centerprints the information about an upcoming or active timeout to all active
  63  * players. Also plays reminder sounds.
  64  */
  65 void timeoutHandler_Think() {
  66         local string timeStr;
  67         local entity plr;
  68         if (timeoutStatus == 1) {
  69                 if (remainingLeadTime > 0) {
  70                         //centerprint the information to every player
  71                         timeStr = getTimeoutText(0);
  72                         FOR_EACH_REALCLIENT(plr) {
  73                                 if(plr.classname == "player") {
  74                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  75                                 }
  76                         }
  77                         remainingLeadTime -= 1;
  78                         //think again in 1 second:
  79                         self.nextthink = time + 1;
  80                 }
  81                 else {
  82                         //now pause the game:
  83                         timeoutStatus = 2;
  84                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  85                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  86                         FOR_EACH_REALPLAYER(plr) {
  87                                 plr.lastV_angle = plr.v_angle;
  88                         }
  89                         self.nextthink = time;
  90                 }
  91         }
  92         else if (timeoutStatus == 2) {
  93                 if (remainingTimeoutTime > 0) {
  94                         timeStr = getTimeoutText(0);
  95                         FOR_EACH_REALCLIENT(plr) {
  96                                 if(plr.classname == "player") {
  97                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  98                                 }
  99                         }
 100                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 101                                 sound(world, CHAN_AUTO, "announcer/robotic/prepareforbattle.wav", 1, ATTN_NONE);
 102                         }
 103                         remainingTimeoutTime -= 1;
 104                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 105                 }
 106                 else {
 107                         //unpause the game again
 108                         remainingTimeoutTime = timeoutStatus = 0;
 109                         cvar_set("slowmo", ftos(orig_slowmo));
 110                         //and unlock the fixed view again once there is no timeout active anymore
 111                         FOR_EACH_REALPLAYER(plr) {
 112                                 plr.fixangle = FALSE;
 113                         }
 114                         //get rid of the countdown message
 115                         FOR_EACH_REALCLIENT(plr) {
 116                                 if(plr.classname == "player") {
 117                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 118                                 }
 119                         }
 120                         remove(self);
 121                         return;
 122                 }
 123
 124         }
 125         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 126                 FOR_EACH_REALCLIENT(plr) {
 127                         if(plr.classname == "player") {
 128                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 129                         }
 130                 }
 131                 remove(self);
 132                 return;
 133         }
 134 }
 135
 136 float GotoFirstMap()
 137 {
 138         if(cvar("_sv_init"))
 139         {
 140                 cvar_set("_sv_init", "0");
 141                 if(cvar("g_maplist_shuffle"))
 142                         ShuffleMaplist();
 143 #ifdef MAPINFO
 144                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 145 #else
 146                 tokenize(cvar_string("g_maplist"));
 147                 if(argv(0) != GetMapname())
 148 #endif
 149                 {
 150                         cvar_set("nextmap", argv(0));
 151
 152 #ifdef MAPINFO
 153                         MapInfo_Enumerate();
 154                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 155 #endif
 156
 157                         if(!DoNextMapOverride())
 158                                 GotoNextMap();
 159
 160                         return 1;
 161                 }
 162         }
 163         return 0;
 164 }
 165
 166 float world_already_spawned;
 167 void spawnfunc_worldspawn (void)
 168 {
 169         float fd, l;
 170         string s;
 171
 172         dprint_load(); // load dprint status from cvar
 173
 174         if(world_already_spawned)
 175                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 176         world_already_spawned = TRUE;
 177
 178         local entity head;
 179         head = nextent(world);
 180         maxclients = 0;
 181         while(head)
 182         {
 183                 ++maxclients;
 184                 head = nextent(head);
 185         }
 186
 187         if(GotoFirstMap())
 188                 return;
 189
 190 #ifdef MAPINFO
 191         MapInfo_LoadMapSettings(mapname);
 192 #endif
 193
 194         if(sv_cheats)
 195                 ServerProgsDB = db_create();
 196         else
 197                 ServerProgsDB = db_load("server.db");
 198
 199         /*
 200         TODO sound pack system
 201         // initialize sound pack system
 202         soundpack = cvar_string("g_soundpack");
 203         if(soundpack != "")
 204                 soundpack = strcat(soundpack, "/");
 205         soundpack = strzone(soundpack);
 206         */
 207
 208         // 0 normal
 209         lightstyle(0, "m");
 210
 211         // 1 FLICKER (first variety)
 212         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 213
 214         // 2 SLOW STRONG PULSE
 215         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 216
 217         // 3 CANDLE (first variety)
 218         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 219
 220         // 4 FAST STROBE
 221         lightstyle(4, "mamamamamama");
 222
 223         // 5 GENTLE PULSE 1
 224         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 225
 226         // 6 FLICKER (second variety)
 227         lightstyle(6, "nmonqnmomnmomomno");
 228
 229         // 7 CANDLE (second variety)
 230         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 231
 232         // 8 CANDLE (third variety)
 233         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 234
 235         // 9 SLOW STROBE (fourth variety)
 236         lightstyle(9, "aaaaaaaazzzzzzzz");
 237
 238         // 10 FLUORESCENT FLICKER
 239         lightstyle(10, "mmamammmmammamamaaamammma");
 240
 241         // 11 SLOW PULSE NOT FADE TO BLACK
 242         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 243
 244         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 245
 246         // 63 testing
 247         lightstyle(63, "a");
 248
 249         // for setting by mapinfo
 250         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 251         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 252
 253         player_count = 0;
 254         lms_lowest_lives = 0;
 255         lms_next_place = 0;
 256
 257         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 258         if(bot_waypoints_for_items == 1)
 259                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 260                         bot_waypoints_for_items = 0;
 261
 262         if(cvar("g_campaign"))
 263                 CampaignPreInit();
 264
 265         InitGameplayMode();
 266         readlevelcvars();
 267         precache();
 268
 269         WaypointSprite_Init();
 270
 271         //if (g_domination)
 272         //      dom_init();
 273
 274         GameLogInit(); // prepare everything
 275         if(cvar("sv_eventlog"))
 276         {
 277                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 278                 s = strcat(s, ftos(random()));
 279 #ifdef MAPINFO
 280                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s), FALSE);
 281 #else
 282                 GameLogEcho(strcat(":gamestart:", GetMapname(), ":", s), FALSE);
 283 #endif
 284                 s = ":gameinfo:mutators:LIST";
 285                 if(cvar("g_grappling_hook"))
 286                         s = strcat(s, ":grappling_hook");
 287                 if(!cvar("g_use_ammunition"))
 288                         s = strcat(s, ":no_use_ammunition");
 289                 if(!cvar("g_pickup_items"))
 290                         s = strcat(s, ":no_pickup_items");
 291                 if(cvar("g_instagib"))
 292                         s = strcat(s, ":instagib");
 293                 if(cvar("g_rocketarena"))
 294                         s = strcat(s, ":rockerarena");
 295                 if(cvar("g_nixnex"))
 296                         s = strcat(s, ":nixnex");
 297                 if(cvar("g_vampire"))
 298                         s = strcat(s, ":vampire");
 299                 if(cvar("g_laserguided_missile"))
 300                         s = strcat(s, ":laserguided_missile");
 301                 if(cvar("g_norecoil"))
 302                         s = strcat(s, ":norecoil");
 303                 if(cvar("g_midair"))
 304                         s = strcat(s, ":midair");
 305                 if(cvar("g_minstagib"))
 306                         s = strcat(s, ":minstagib");
 307                 GameLogEcho(s, FALSE);
 308                 GameLogEcho(":gameinfo:end", FALSE);
 309         }
 310
 311         cvar_set("nextmap", "");
 312
 313         SetDefaultAlpha();
 314
 315         if(cvar("g_campaign"))
 316                 CampaignPostInit();
 317
 318         fteqcc_testbugs();
 319
 320         Ban_LoadBans();
 321
 322         //initialise globals related to sv_timeout
 323         sys_ticrate = cvar("sys_ticrate");
 324         orig_slowmo = cvar("slowmo");
 325
 326 #ifdef MAPINFO
 327         MapInfo_Enumerate();
 328         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 1);
 329 #endif
 330
 331         //if tourney is used map starts in warmup mode. if this mode shall stay unlimited, reset timelimit, but save the original one
 332         if(g_tourney && cvar("g_tourney_warmup_unlimited_time")) {
 333                 timelimit_orig = cvar("timelimit");
 334                 cvar_set("timelimit", "0");
 335         }
 336
 337         fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 338         if(fd != -1)
 339         {
 340                 while((s = fgets(fd)))
 341                 {
 342                         l = tokenize(s);
 343                         if(l < 2)
 344                                 continue;
 345                         if(argv(0) != "fog")
 346                                 continue;
 347                         s = "";
 348                         while(l >= 2)
 349                         {
 350                                 --l;
 351                                 s = strcat(argv(l), " ", s);
 352                         }
 353                         s = substring(s, 0, strlen(s) - 1);
 354                         print("Found ^1DEPRECATED^7 fog command in .cfg file: ", s, "\n");
 355                         world.fog = strzone(s);
 356                 }
 357                 fclose(fd);
 358         }
 359
 360         next_pingtime = time + 5;
 361         world_initialized = 1;
 362 }
 363
 364 void spawnfunc_light (void)
 365 {
 366         //makestatic (self); // Who the f___ did that?
 367         remove(self);
 368 }
 369
 370 float TryFile( string pFilename )
 371 {
 372         local float lHandle;
 373         dprint("TryFile(\"", pFilename, "\")\n");
 374         lHandle = fopen( pFilename, FILE_READ );
 375         if( lHandle != -1 ) {
 376                 fclose( lHandle );
 377                 return TRUE;
 378         } else {
 379                 return FALSE;
 380         }
 381 };
 382
 383 string GetGametype()
 384 {
 385         return GametypeNameFromType(game);
 386 }
 387
 388 float IsSameGametype(string mapcfgname)
 389 {
 390 #ifdef MAPINFO
 391         return TRUE; // can't change game type by map name here
 392 #else
 393         string gt;
 394         gt = GetGametype();
 395         if(substring(mapcfgname, 0, strlen(gt) + 1) == strcat(gt, "_"))
 396                 return TRUE;
 397         return FALSE;
 398 #endif
 399 }
 400
 401 string getmapname_stored;
 402 string GetMapname()
 403 {
 404 #ifdef MAPINFO
 405         return mapname;
 406 #else
 407         if(getmapname_stored == "")
 408                 getmapname_stored = strzone(strcat(GetGametype(), "_", mapname));
 409         return getmapname_stored;
 410 #endif
 411 }
 412
 413 float Map_Count, Map_Current;
 414 string Map_Current_Name;
 415
 416 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 417 float GetMaplistPosition()
 418 {
 419         float pos, idx;
 420         string map;
 421
 422         map = GetMapname();
 423         idx = cvar("g_maplist_index");
 424
 425         if(idx >= 0)
 426                 if(idx < Map_Count)
 427                         if(map == argv(idx))
 428                                 return idx;
 429
 430         for(pos = 0; pos < Map_Count; ++pos)
 431                 if(map == argv(pos))
 432                         return pos;
 433
 434         // resume normal maplist rotation if current map is not in g_maplist
 435         return idx;
 436 }
 437
 438 float MapHasRightSize(string map)
 439 {
 440         float fh;
 441         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 442         if(cvar("g_maplist_check_waypoints"))
 443         {
 444                 dprint("checkwp "); dprint(map);
 445                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 446                 if(fh < 0)
 447                 {
 448                         dprint(": no waypoints\n");
 449                         return FALSE;
 450                 }
 451                 dprint(": has waypoints\n");
 452                 fclose(fh);
 453         }
 454
 455         // open map size restriction file
 456         dprint("opensize "); dprint(map);
 457         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 458         if(fh >= 0)
 459         {
 460                 float mapmin, mapmax;
 461                 dprint(": ok, ");
 462                 mapmin = stof(fgets(fh));
 463                 mapmax = stof(fgets(fh));
 464                 fclose(fh);
 465                 if(player_count < mapmin)
 466                 {
 467                         dprint("not enough\n");
 468                         return FALSE;
 469                 }
 470                 if(player_count > mapmax)
 471                 {
 472                         dprint("too many\n");
 473                         return FALSE;
 474                 }
 475                 dprint("right size\n");
 476                 return TRUE;
 477         }
 478         dprint(": not found\n");
 479         return TRUE;
 480 }
 481
 482 string Map_Filename(float position)
 483 {
 484 #ifdef MAPINFO
 485         return strcat("maps/", argv(position), ".bsp");
 486 #else
 487         return strcat("maps/", argv(position), ".mapcfg");
 488 #endif
 489 }
 490
 491 string strwords(string s, float w)
 492 {
 493         float endpos;
 494         for(endpos = 0; w && endpos >= 0; --w)
 495                 endpos = strstrofs(s, " ", endpos + 1);
 496         if(endpos < 0)
 497                 return s;
 498         else
 499                 return substring(s, 0, endpos);
 500 }
 501
 502 float strhasword(string s, string w)
 503 {
 504         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 505 }
 506
 507 void Map_MarkAsRecent(string m)
 508 {
 509         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 510 }
 511
 512 float Map_IsRecent(string m)
 513 {
 514         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 515 }
 516
 517 float Map_Check(float position, float pass)
 518 {
 519         string filename;
 520         string map_next;
 521         map_next = argv(position);
 522         if(pass <= 1)
 523         {
 524                 if(map_next == Map_Current_Name) // same map again in first pass?
 525                         return 0;
 526                 if(Map_IsRecent(map_next))
 527                         return 0;
 528         }
 529         filename = Map_Filename(position);
 530 #ifdef MAPINFO
 531         if(MapInfo_CheckMap(map_next))
 532 #else
 533         if(TryFile(filename))
 534 #endif
 535         {
 536                 if(pass == 2)
 537                         return 1;
 538                 if(MapHasRightSize(map_next))
 539                         return 1;
 540                 return 0;
 541         }
 542         else
 543                 dprint( "Couldn't select '", filename, "'..\n" );
 544
 545         return 0;
 546 }
 547
 548 void Map_Goto_SetStr(string nextmapname)
 549 {
 550         if(getmapname_stored != "")
 551                 strunzone(getmapname_stored);
 552         if(nextmapname == "")
 553                 getmapname_stored = "";
 554         else
 555                 getmapname_stored = strzone(nextmapname);
 556 }
 557
 558 void Map_Goto_SetFloat(float position)
 559 {
 560         cvar_set("g_maplist_index", ftos(position));
 561         Map_Goto_SetStr(argv(position));
 562 }
 563
 564 void GameResetCfg()
 565 {
 566 #ifdef MAPINFO
 567         // settings persist, except...
 568         if(cvar("g_campaign"))
 569                 localcmd("\nexec mutator_reset.cfg\n");
 570         localcmd("\nsettemp_restore\n");
 571 #else
 572         // if an exit cfg is defined by exiting map, exec it.
 573         string exit_cfg;
 574         exit_cfg = cvar_string("exit_cfg");
 575         if(exit_cfg != "")
 576                 localcmd(strcat("exec \"", exit_cfg, "\"\n"));
 577
 578         localcmd("exec game_reset.cfg\n");
 579 #endif
 580 };
 581
 582 void Map_Goto()
 583 {
 584         Map_MarkAsRecent(getmapname_stored);
 585         GameResetCfg();
 586 #ifdef MAPINFO
 587         MapInfo_LoadMap(getmapname_stored);
 588 #else
 589         localcmd(strcat("exec \"maps/", getmapname_stored ,".mapcfg\"\n"));
 590 #endif
 591 }
 592
 593 // return codes of map selectors:
 594 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 595 //   -2 = permanent failure
 596 float() MaplistMethod_Iterate = // usual method
 597 {
 598         float pass, i;
 599
 600         for(pass = 1; pass <= 2; ++pass)
 601         {
 602                 for(i = 1; i < Map_Count; ++i)
 603                 {
 604                         float mapindex;
 605                         mapindex = mod(i + Map_Current, Map_Count);
 606                         if(Map_Check(mapindex, pass))
 607                                 return mapindex;
 608                 }
 609         }
 610         return -1;
 611 }
 612
 613 float() MaplistMethod_Repeat = // fallback method
 614 {
 615         if(Map_Check(Map_Current, 2))
 616                 return Map_Current;
 617         return -2;
 618 }
 619
 620 float() MaplistMethod_Random = // random map selection
 621 {
 622         float i, imax;
 623
 624         imax = 42;
 625
 626         for(i = 0; i <= imax; ++i)
 627         {
 628                 float mapindex;
 629                 mapindex = mod(Map_Current + ceil(random() * (Map_Count - 1)), Map_Count); // any OTHER map
 630                 if(Map_Check(mapindex, 1))
 631                         return mapindex;
 632         }
 633         return -1;
 634 }
 635
 636 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 637 // the exponent sets a bias on the map selection:
 638 // the higher the exponent, the less likely "shortly repeated" same maps are
 639 {
 640         float i, j, imax, insertpos;
 641
 642         imax = 42;
 643
 644         for(i = 0; i <= imax; ++i)
 645         {
 646                 string newlist;
 647
 648                 // now reinsert this at another position
 649                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 650                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 651                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 652                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 653
 654                 // insert the current map there
 655                 newlist = "";
 656 #ifdef MAPINFO
 657                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 658                         newlist = strcat(newlist, " ", argv(j));
 659                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 660                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 661                         newlist = strcat(newlist, " ", argv(j));
 662                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 663 #else
 664                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 665                         newlist = strcat(newlist, "'", argv(j), "'");
 666                 newlist = strcat(newlist, "'", argv(0), "'");  // now insert the just selected map
 667                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 668                         newlist = strcat(newlist, "'", argv(j), "'");
 669 #endif
 670                 cvar_set("g_maplist", newlist);
 671 #ifdef MAPINFO
 672                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 673 #else
 674                 Map_Count = tokenize(newlist);
 675 #endif
 676
 677                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 678                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 679                 if(Map_Check(Map_Current, 1))
 680                         return Map_Current;
 681         }
 682         return -1;
 683 }
 684
 685 void Maplist_Init()
 686 {
 687         string temp;
 688         temp = cvar_string("g_maplist");
 689 #ifdef MAPINFO
 690         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 691 #else
 692         Map_Count = tokenize(temp);
 693 #endif
 694         if(Map_Count == 0)
 695         {
 696                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 697 #ifdef MAPINFO
 698                 cvar_set("g_maplist", temp = MapInfo_ListAllowedMaps());
 699                 localcmd("\nmenu_cmd sync\n");
 700                 Map_Count = tokenizebyseparator(temp, " ");
 701 #else
 702                 cvar_set("g_maplist", temp = cvar_string("g_maplist_defaultlist"));
 703                 Map_Count = tokenize(temp);
 704 #endif
 705         }
 706         if(Map_Count == 0)
 707                 error("empty maplist, cannot select a new map");
 708         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 709
 710         if(Map_Current_Name)
 711                 strunzone(Map_Current_Name);
 712         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 713         // this may or may not be correct, but who cares, in the worst case a map
 714         // isn't chosen in the first pass that should have been
 715 }
 716
 717 string GetNextMap()
 718 {
 719         float nextMap;
 720
 721         Maplist_Init();
 722         nextMap = -1;
 723
 724         if(nextMap == -1)
 725                 if(cvar("g_maplist_shuffle") > 0)
 726                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 727
 728         if(nextMap == -1)
 729                 if(cvar("g_maplist_selectrandom"))
 730                         nextMap = MaplistMethod_Random();
 731
 732         if(nextMap == -1)
 733                 nextMap = MaplistMethod_Iterate();
 734
 735         if(nextMap == -1)
 736                 nextMap = MaplistMethod_Repeat();
 737
 738         if(nextMap >= 0)
 739         {
 740                 Map_Goto_SetFloat(nextMap);
 741                 return getmapname_stored;
 742         }
 743
 744         return "";
 745 };
 746
 747 float DoNextMapOverride()
 748 {
 749         if(cvar("g_campaign"))
 750         {
 751                 CampaignPostIntermission();
 752                 alreadychangedlevel = TRUE;
 753                 return TRUE;
 754         }
 755         if(cvar("quit_when_empty"))
 756         {
 757                 if(player_count <= currentbots)
 758                 {
 759                         localcmd("quit\n");
 760                         alreadychangedlevel = TRUE;
 761                         return TRUE;
 762                 }
 763         }
 764         if(cvar_string("quit_and_redirect") != "")
 765         {
 766                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 767                 alreadychangedlevel = TRUE;
 768                 return TRUE;
 769         }
 770         if (cvar("samelevel")) // if samelevel is set, stay on same level
 771         {
 772                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 773                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 774                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 775                 localcmd("restart\n");
 776                 //changelevel (mapname);
 777                 alreadychangedlevel = TRUE;
 778                 return TRUE;
 779         }
 780         if(cvar_string("nextmap") != "")
 781 #ifdef MAPINFO
 782                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 783 #else
 784                 if(TryFile(strcat("maps/", cvar_string("nextmap"), ".mapcfg")))
 785 #endif
 786                 {
 787                         Map_Goto_SetStr(cvar_string("nextmap"));
 788                         Map_Goto();
 789                         alreadychangedlevel = TRUE;
 790                         return TRUE;
 791                 }
 792         if(cvar("lastlevel"))
 793         {
 794                 GameResetCfg();
 795                 localcmd("set lastlevel 0\ntogglemenu\n");
 796                 alreadychangedlevel = TRUE;
 797                 return TRUE;
 798         }
 799         return FALSE;
 800 };
 801
 802 void GotoNextMap()
 803 {
 804         //local string nextmap;
 805         //local float n, nummaps;
 806         //local string s;
 807         if (alreadychangedlevel)
 808                 return;
 809         alreadychangedlevel = TRUE;
 810
 811         {
 812                 string nextMap;
 813                 float allowReset;
 814
 815                 for(allowReset = 1; allowReset >= 0; --allowReset)
 816                 {
 817                         nextMap = GetNextMap();
 818                         if(nextMap != "")
 819                                 break;
 820
 821                         if(allowReset)
 822                         {
 823                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 824 #ifdef MAPINFO
 825                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps());
 826                                 localcmd("\nmenu_cmd sync\n");
 827 #else
 828                                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
 829 #endif
 830                         }
 831                         else
 832                         {
 833                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 834                         }
 835                 }
 836                 Map_Goto();
 837         }
 838 };
 839
 840
 841 /*
 842 ============
 843 IntermissionThink
 844
 845 When the player presses attack or jump, change to the next level
 846 ============
 847 */
 848 .float autoscreenshot;
 849 void() MapVote_Start;
 850 void() MapVote_Think;
 851 float mapvote_initialized;
 852 void IntermissionThink()
 853 {
 854         FixIntermissionClient(self);
 855
 856         if(cvar("sv_autoscreenshot"))
 857         if(self.autoscreenshot > 0)
 858         if(time > self.autoscreenshot)
 859         {
 860                 self.autoscreenshot = -1;
 861                 if(clienttype(self) == CLIENTTYPE_REAL)
 862                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 863                 return;
 864         }
 865
 866         if (time < intermission_exittime)
 867                 return;
 868
 869         if(!mapvote_initialized)
 870                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
 871                         return;
 872
 873         MapVote_Start();
 874 };
 875
 876 /*
 877 ============
 878 FindIntermission
 879
 880 Returns the entity to view from
 881 ============
 882 */
 883 /*
 884 entity FindIntermission()
 885 {
 886         local   entity spot;
 887         local   float cyc;
 888
 889 // look for info_intermission first
 890         spot = find (world, classname, "info_intermission");
 891         if (spot)
 892         {       // pick a random one
 893                 cyc = random() * 4;
 894                 while (cyc > 1)
 895                 {
 896                         spot = find (spot, classname, "info_intermission");
 897                         if (!spot)
 898                                 spot = find (spot, classname, "info_intermission");
 899                         cyc = cyc - 1;
 900                 }
 901                 return spot;
 902         }
 903
 904 // then look for the start position
 905         spot = find (world, classname, "info_player_start");
 906         if (spot)
 907                 return spot;
 908
 909 // testinfo_player_start is only found in regioned levels
 910         spot = find (world, classname, "testplayerstart");
 911         if (spot)
 912                 return spot;
 913
 914 // then look for the start position
 915         spot = find (world, classname, "info_player_deathmatch");
 916         if (spot)
 917                 return spot;
 918
 919         //objerror ("FindIntermission: no spot");
 920         return world;
 921 };
 922 */
 923
 924 /*
 925 ===============================================================================
 926
 927 RULES
 928
 929 ===============================================================================
 930 */
 931
 932 void DumpStats(float final)
 933 {
 934         local float file;
 935         local string s;
 936         local float to_console;
 937         local float to_eventlog;
 938         local float to_file;
 939         local float i;
 940
 941         to_console = cvar("sv_logscores_console");
 942         to_eventlog = cvar("sv_eventlog");
 943         to_file = cvar("sv_logscores_file");
 944
 945         if(!final)
 946         {
 947                 to_console = TRUE; // always print printstats replies
 948                 to_eventlog = FALSE; // but never print them to the event log
 949         }
 950
 951         if(to_eventlog)
 952                 if(cvar("sv_eventlog_console"))
 953                         to_console = FALSE; // otherwise we get the output twice
 954
 955         if(final)
 956                 s = ":scores:";
 957         else
 958                 s = ":status:";
 959 #ifdef MAPINFO
 960         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
 961 #else
 962         s = strcat(s, GetMapname(), ":", ftos(rint(time)));
 963 #endif
 964
 965         if(to_console)
 966                 ServerConsoleEcho(s, FALSE);
 967         if(to_eventlog)
 968                 GameLogEcho(s, FALSE);
 969         if(to_file)
 970         {
 971                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
 972                 if(file == -1)
 973                         to_file = FALSE;
 974                 else
 975                         fputs(file, strcat(s, "\n"));
 976         }
 977
 978         s = strcat(":labels:player:", GetPlayerScoreString(world));
 979         if(to_console)
 980                 ServerConsoleEcho(s, TRUE);
 981         if(to_eventlog)
 982                 GameLogEcho(s, TRUE);
 983         if(to_file)
 984                 fputs(file, strcat(s, "\n"));
 985
 986         FOR_EACH_CLIENT(other)
 987         {
 988                 // FIXME make this use the new score system
 989                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
 990                 {
 991                         s = strcat(":player:see-labels:", GetPlayerScoreString(other), ":");
 992                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
 993                         s = strcat(s, ftos(other.team), ":");
 994
 995                         if(to_console)
 996                                 ServerConsoleEcho(strcat(s, other.netname), TRUE);
 997                         if(to_eventlog)
 998                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname), TRUE);
 999                         if(to_file)
1000                                 fputs(file, strcat(s, other.netname, "\n"));
1001                 }
1002         }
1003
1004         if(teamplay)
1005         {
1006                 s = strcat(":labels:teamscores:", GetTeamScoreString(0));
1007                 if(to_console)
1008                         ServerConsoleEcho(s, TRUE);
1009                 if(to_eventlog)
1010                         GameLogEcho(s, TRUE);
1011                 if(to_file)
1012                         fputs(file, strcat(s, "\n"));
1013
1014                 for(i = 1; i < 16; ++i)
1015                 {
1016                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i));
1017                         s = strcat(s, ":", ftos(i));
1018                         if(to_console)
1019                                 ServerConsoleEcho(s, TRUE);
1020                         if(to_eventlog)
1021                                 GameLogEcho(s, TRUE);
1022                         if(to_file)
1023                                 fputs(file, strcat(s, "\n"));
1024                 }
1025         }
1026
1027         if(to_console)
1028                 ServerConsoleEcho(":end", FALSE);
1029         if(to_eventlog)
1030                 GameLogEcho(":end", FALSE);
1031         if(to_file)
1032         {
1033                 fputs(file, ":end\n");
1034                 fclose(file);
1035         }
1036 }
1037
1038 void FixIntermissionClient(entity e)
1039 {
1040         string s;
1041         if(!e.autoscreenshot) // initial call
1042         {
1043                 e.angles = e.v_angle;
1044                 e.angles_x = -e.angles_x;
1045                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1046                 e.health = -2342;
1047                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1048                 e.solid = SOLID_NOT;
1049                 e.movetype = MOVETYPE_NONE;
1050                 e.takedamage = DAMAGE_NO;
1051                 if(e.weaponentity)
1052                         e.weaponentity.effects = EF_NODRAW;
1053                 if(clienttype(e) == CLIENTTYPE_REAL)
1054                 {
1055                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1056                         s = cvar_string("sv_intermission_cdtrack");
1057                         if(s != "")
1058                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1059                         msg_entity = e;
1060                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1061                 }
1062         }
1063
1064         //e.velocity = '0 0 0';
1065         //e.fixangle = TRUE;
1066
1067         // TODO halt weapon animation
1068 }
1069
1070
1071 /*
1072 go to the next level for deathmatch
1073 only called if a time or frag limit has expired
1074 */
1075 void NextLevel()
1076 {
1077         float minTotalFrags;
1078         float maxTotalFrags;
1079         float score;
1080         float f;
1081
1082         gameover = TRUE;
1083
1084         intermission_running = 1;
1085
1086 // enforce a wait time before allowing changelevel
1087         if(player_count > 0)
1088                 intermission_exittime = time + cvar("sv_mapchange_delay");
1089         else
1090                 intermission_exittime = -1;
1091
1092         /*
1093         WriteByte (MSG_ALL, SVC_CDTRACK);
1094         WriteByte (MSG_ALL, 3);
1095         WriteByte (MSG_ALL, 3);
1096         // done in FixIntermission
1097         */
1098
1099         //pos = FindIntermission ();
1100
1101         VoteReset();
1102
1103         DumpStats(TRUE);
1104
1105         if(cvar("sv_eventlog"))
1106                 GameLogEcho(":gameover", FALSE);
1107
1108         GameLogClose();
1109
1110         FOR_EACH_CLIENT(other)
1111         {
1112                 FixIntermissionClient(other);
1113
1114                 if(other.winning)
1115                         bprint(other.netname, " ^7wins.\n");
1116         }
1117
1118         minTotalFrags = 0;
1119         maxTotalFrags = 0;
1120         FOR_EACH_PLAYER(other)
1121         {
1122                 if(maxTotalFrags < other.totalfrags)
1123                         maxTotalFrags = other.totalfrags;
1124                 if(minTotalFrags > other.totalfrags)
1125                         minTotalFrags = other.totalfrags;
1126         }
1127
1128         if(!currentbots)
1129         {
1130                 FOR_EACH_PLAYER(other)
1131                 {
1132                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1133                         f = bound(0, other.play_time / max(time, 1), 1);
1134                         // store some statistics?
1135                 }
1136         }
1137
1138         if(cvar("g_campaign"))
1139                 CampaignPreIntermission();
1140
1141         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1142 };
1143
1144 /*
1145 ============
1146 CheckRules_Player
1147
1148 Exit deathmatch games upon conditions
1149 ============
1150 */
1151 .float fogtime;
1152 void CheckRules_Player()
1153 {
1154         if (gameover)   // someone else quit the game already
1155                 return;
1156
1157         if(self.deadflag == DEAD_NO)
1158                 self.play_time += frametime;
1159
1160         if(sv_foginterval)
1161         if(world.fog)
1162         if(time > self.fogtime)
1163         {
1164                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1165                 self.fogtime = time + sv_foginterval;
1166         }
1167
1168         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1169         //   (div0: and that in CheckRules_World please)
1170 };
1171
1172 float checkrules_oneminutewarning;
1173 float checkrules_leaderfrags;
1174 float tdm_max_score, tdm_old_score;
1175
1176 float checkrules_equality;
1177 float checkrules_overtimewarning;
1178 float checkrules_overtimeend;
1179
1180 void InitiateOvertime()
1181 {
1182         if(!checkrules_overtimeend)
1183                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1184 }
1185
1186 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1187 float WINNING_YES = 1; // winner found
1188 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1189 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1190
1191 float GetWinningCode(float fraglimitreached, float equality)
1192 {
1193         if(equality)
1194                 if(fraglimitreached)
1195                         return WINNING_STARTOVERTIME;
1196                 else
1197                         return WINNING_NEVER;
1198         else
1199                 if(fraglimitreached)
1200                         return WINNING_YES;
1201                 else
1202                         return WINNING_NO;
1203 }
1204
1205 // set the .winning flag for exactly those players with a given field value
1206 void SetWinners(.float field, float value)
1207 {
1208         entity head;
1209         FOR_EACH_PLAYER(head)
1210                 head.winning = (head.field == value);
1211 }
1212
1213 // set the .winning flag for those players with a given field value
1214 void AddWinners(.float field, float value)
1215 {
1216         entity head;
1217         FOR_EACH_PLAYER(head)
1218                 if(head.field == value)
1219                         head.winning = 1;
1220 }
1221
1222 // clear the .winning flags
1223 void ClearWinners(void)
1224 {
1225         entity head;
1226         FOR_EACH_PLAYER(head)
1227                 head.winning = 0;
1228 }
1229
1230 // Onslaught winning condition:
1231 // game terminates if only one team has a working generator (or none)
1232 float WinningCondition_Onslaught()
1233 {
1234         entity head;
1235         local float t1, t2, t3, t4;
1236         // first check if the game has ended
1237         t1 = t2 = t3 = t4 = 0;
1238         head = find(world, classname, "onslaught_generator");
1239         while (head)
1240         {
1241                 if (head.health > 0)
1242                 {
1243                         if (head.team == COLOR_TEAM1) t1 = 1;
1244                         if (head.team == COLOR_TEAM2) t2 = 1;
1245                         if (head.team == COLOR_TEAM3) t3 = 1;
1246                         if (head.team == COLOR_TEAM4) t4 = 1;
1247                 }
1248                 head = find(head, classname, "onslaught_generator");
1249         }
1250         if (t1 + t2 + t3 + t4 < 2)
1251         {
1252                 // game over, only one team remains (or none)
1253                 ClearWinners();
1254                 if (t1) SetWinners(team, COLOR_TEAM1);
1255                 if (t2) SetWinners(team, COLOR_TEAM2);
1256                 if (t3) SetWinners(team, COLOR_TEAM3);
1257                 if (t4) SetWinners(team, COLOR_TEAM4);
1258                 dprint("Have a winner, ending game.\n");
1259                 return WINNING_YES;
1260         }
1261
1262         // Two or more teams remain
1263         return WINNING_NO;
1264 }
1265
1266 float LMS_NewPlayerLives()
1267 {
1268         float fl;
1269         fl = cvar("fraglimit");
1270         if(fl == 0)
1271                 fl = 999;
1272
1273         // first player has left the game for dying too much? Nobody else can get in.
1274         if(lms_lowest_lives < 1)
1275                 return 0;
1276
1277         if(!cvar("g_lms_join_anytime"))
1278                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1279                         return 0;
1280
1281         return bound(1, lms_lowest_lives, fl);
1282 }
1283
1284 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1285 // they win. Otherwise the defending team wins once the timelimit passes.
1286 void assault_new_round();
1287 float WinningCondition_Assault()
1288 {
1289         local float status;
1290         status = WINNING_NO;
1291
1292         // as the timelimit has not yet passed just assume the defending team will win
1293         if(assault_attacker_team == COLOR_TEAM1)
1294         {
1295                 SetWinners(team, COLOR_TEAM2);
1296         }
1297         else
1298         {
1299                 SetWinners(team, COLOR_TEAM1);
1300         }
1301
1302         local entity ent;
1303         ent = find(world, classname, "target_assault_roundend");
1304         if(ent)
1305         {
1306                 if(ent.winning) // round end has been triggered by attacking team
1307                 {
1308                         SetWinners(team, assault_attacker_team);
1309                         if(assault_attacker_team == COLOR_TEAM1)
1310                         {
1311                                 team1_score = team1_score + 50;
1312                         }
1313                         else
1314                         {
1315                                 team2_score = team2_score + 50;
1316                         }
1317
1318                         if(ent.cnt == 1) // this was the second round
1319                         {
1320                                 status = WINNING_YES;
1321                         }
1322                         else
1323                         {
1324                                 local entity oldself;
1325                                 oldself = self;
1326                                 self = ent;
1327                                 cvar_set("timelimit", ftos((2*time)/60));
1328                                 assault_new_round();
1329                                 self = oldself;
1330                         }
1331                 }
1332         }
1333
1334         return status;
1335
1336 }
1337
1338 // LMS winning condition: game terminates if and only if there's at most one
1339 // one player who's living lives. Top two scores being equal cancels the time
1340 // limit.
1341 float WinningCondition_LMS()
1342 {
1343         entity head, head2;
1344         float have_player;
1345         float have_players;
1346         float l;
1347
1348         have_player = FALSE;
1349         have_players = FALSE;
1350         l = LMS_NewPlayerLives();
1351
1352         head = find(world, classname, "player");
1353         if(head)
1354                 have_player = TRUE;
1355         head2 = find(head, classname, "player");
1356         if(head2)
1357                 have_players = TRUE;
1358
1359         if(have_player)
1360         {
1361                 // we have at least one player
1362                 if(have_players)
1363                 {
1364                         // two or more active players - continue with the game
1365                 }
1366                 else
1367                 {
1368                         // exactly one player?
1369
1370                         ClearWinners();
1371                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1372
1373                         if(l)
1374                         {
1375                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1376                                 return WINNING_NO;
1377                         }
1378                         else
1379                         {
1380                                 // a winner!
1381                                 // and assign him his first place
1382                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1383                                 return WINNING_YES;
1384                         }
1385                 }
1386         }
1387         else
1388         {
1389                 // nobody is playing at all...
1390                 if(l)
1391                 {
1392                         // wait for players...
1393                 }
1394                 else
1395                 {
1396                         // SNAFU (maybe a draw game?)
1397                         ClearWinners();
1398                         dprint("No players, ending game.\n");
1399                         return WINNING_YES;
1400                 }
1401         }
1402
1403         // When we get here, we have at least two players who are actually LIVING,
1404         // now check if the top two players have equal score.
1405         WinningConditionHelper();
1406
1407         ClearWinners();
1408         if(WinningConditionHelper_winner)
1409                 WinningConditionHelper_winner.winning = TRUE;
1410         if(WinningConditionHelper_equality)
1411                 return WINNING_NEVER;
1412
1413         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1414         return WINNING_NO;
1415 }
1416
1417 void print_to(entity e, string s)
1418 {
1419         if(e)
1420                 sprint(e, strcat(s, "\n"));
1421         else
1422                 ServerConsoleEcho(s, TRUE);
1423 }
1424
1425 void ShuffleMaplist()
1426 {
1427         string result;
1428         float start;
1429         float litems;
1430         float selected;
1431         float i;
1432
1433         result = cvar_string("g_maplist");
1434 #ifdef MAPINFO
1435         litems = tokenizebyseparator(result, " ");
1436 #else
1437         litems = tokenize(result);
1438 #endif
1439
1440         for(start = 0; start < litems - 1; ++start)
1441         {
1442                 result = "";
1443
1444                 // select a random item
1445                 selected = ceil(random() * (litems - start) + start) - 1;
1446
1447                 // shift this item to the place start
1448 #ifdef MAPINFO
1449                 for(i = 0; i < start; ++i)
1450                         result = strcat(result, " ", argv(i));
1451                 result = strcat(result, " ", argv(selected));
1452                 for(i = start; i < litems; ++i)
1453                         if(i != selected)
1454                                 result = strcat(result, " ", argv(i));
1455                 result = substring(result, 1, strlen(result) - 1);
1456
1457                 litems = tokenizebyseparator(result, " ");
1458 #else
1459                 for(i = 0; i < start; ++i)
1460                         result = strcat(result, "'", argv(i), "'");
1461                 result = strcat(result, "'", argv(selected), "'");
1462                 for(i = start; i < litems; ++i)
1463                         if(i != selected)
1464                                 result = strcat(result, "'", argv(i), "'");
1465
1466                 litems = tokenize(result);
1467 #endif
1468
1469                 //dprint(result, "\n");
1470         }
1471
1472         cvar_set("g_maplist", result);
1473 }
1474
1475 float WinningCondition_Scores(float limit)
1476 {
1477         // TODO make everything use THIS winning condition (except LMS)
1478         WinningConditionHelper();
1479
1480         ClearWinners();
1481         if(WinningConditionHelper_winner)
1482                 WinningConditionHelper_winner.winning = 1;
1483         if(WinningConditionHelper_winnerteam >= 0)
1484                 SetWinners(team, WinningConditionHelper_winnerteam);
1485
1486         if(WinningConditionHelper_topscore == 0)
1487                 WinningConditionHelper_equality = 0;
1488
1489         return GetWinningCode(limit && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1490 }
1491
1492 float WinningCondition_RanOutOfSpawns()
1493 {
1494         entity head;
1495
1496         if(!have_team_spawns)
1497                 return WINNING_NO;
1498
1499         if(!some_spawn_has_been_used)
1500                 return WINNING_NO;
1501
1502         team1_score = team2_score = team3_score = team4_score = 0;
1503
1504         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1505         {
1506                 if(head.team == COLOR_TEAM1)
1507                         team1_score = 1;
1508                 else if(head.team == COLOR_TEAM2)
1509                         team2_score = 1;
1510                 else if(head.team == COLOR_TEAM3)
1511                         team3_score = 1;
1512                 else if(head.team == COLOR_TEAM4)
1513                         team4_score = 1;
1514         }
1515
1516         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1517         {
1518                 if(head.team == COLOR_TEAM1)
1519                         team1_score = 1;
1520                 else if(head.team == COLOR_TEAM2)
1521                         team2_score = 1;
1522                 else if(head.team == COLOR_TEAM3)
1523                         team3_score = 1;
1524                 else if(head.team == COLOR_TEAM4)
1525                         team4_score = 1;
1526         }
1527
1528         ClearWinners();
1529         if(team1_score + team2_score + team3_score + team4_score == 0)
1530         {
1531                 checkrules_equality = TRUE;
1532                 return WINNING_YES;
1533         }
1534         else if(team1_score + team2_score + team3_score + team4_score == 1)
1535         {
1536                 float t, i;
1537                 if(team1_score) t = COLOR_TEAM1;
1538                 if(team2_score) t = COLOR_TEAM2;
1539                 if(team3_score) t = COLOR_TEAM3;
1540                 if(team4_score) t = COLOR_TEAM4;
1541                 CheckAllowedTeams(world);
1542                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1543                 {
1544                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1545                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1546                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1547                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1548                 }
1549
1550                 AddWinners(team, t);
1551                 return WINNING_YES;
1552         }
1553         else
1554                 return WINNING_NO;
1555 }
1556
1557 /*
1558 ============
1559 CheckRules_World
1560
1561 Exit deathmatch games upon conditions
1562 ============
1563 */
1564 void CheckRules_World()
1565 {
1566         local float status;
1567         local float timelimit;
1568         local float fraglimit;
1569
1570         VoteThink();
1571         MapVote_Think();
1572
1573         SetDefaultAlpha();
1574
1575         /*
1576         MapVote_Think should now do that part
1577         if (intermission_running)
1578                 if (time >= intermission_exittime + 60)
1579                 {
1580                         if(!DoNextMapOverride())
1581                                 GotoNextMap();
1582                         return;
1583                 }
1584         */
1585
1586         if (gameover)   // someone else quit the game already
1587         {
1588                 if(player_count == 0) // Nobody there? Then let's go to the next map
1589                         MapVote_Start();
1590                         // this will actually check the player count in the next frame
1591                         // again, but this shouldn't hurt
1592                 return;
1593         }
1594
1595         timelimit = cvar("timelimit") * 60;
1596         fraglimit = cvar("fraglimit");
1597
1598         if(checkrules_overtimeend)
1599         {
1600                 if(!checkrules_overtimewarning)
1601                 {
1602                         checkrules_overtimewarning = TRUE;
1603                         //sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", 1, ATTN_NONE);
1604                         bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1605                 }
1606         }
1607         else
1608         {
1609                 if (timelimit && time >= timelimit)
1610                         InitiateOvertime();
1611         }
1612
1613         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1614         {
1615                 NextLevel();
1616                 return;
1617         }
1618
1619         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1620         {
1621                 checkrules_oneminutewarning = TRUE;
1622                 sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", 1, ATTN_NONE);
1623         }
1624
1625         status = WinningCondition_RanOutOfSpawns();
1626         if(status == WINNING_YES)
1627         {
1628                 bprint("Hey! Someone ran out of spawns!\n");
1629         }
1630         else if(g_assault)
1631         {
1632                 status = WinningCondition_Assault(); // TODO remove this?
1633         }
1634         else if(g_lms)
1635         {
1636                 status = WinningCondition_LMS();
1637         }
1638         else if (g_onslaught)
1639         {
1640                 status = WinningCondition_Onslaught(); // TODO remove this?
1641         }
1642         else
1643         {
1644                 status = WinningCondition_Scores(fraglimit);
1645         }
1646
1647         if(status == WINNING_STARTOVERTIME)
1648         {
1649                 status = WINNING_NEVER;
1650                 InitiateOvertime();
1651         }
1652
1653         if(status == WINNING_NEVER)
1654                 // equality cases! Nobody wins if the overtime ends in a draw.
1655                 ClearWinners();
1656
1657         if(checkrules_overtimeend)
1658                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1659                         status = WINNING_YES;
1660
1661         if(status == WINNING_YES)
1662                 NextLevel();
1663 };
1664
1665 float mapvote_nextthink;
1666 float mapvote_initialized;
1667 float mapvote_keeptwotime;
1668 float mapvote_timeout;
1669 string mapvote_message;
1670 string mapvote_screenshot_dir;
1671
1672 float mapvote_count;
1673 float mapvote_count_real;
1674 string mapvote_maps[MAPVOTE_COUNT];
1675 float mapvote_maps_suggested[MAPVOTE_COUNT];
1676 string mapvote_suggestions[MAPVOTE_COUNT];
1677 float mapvote_suggestion_ptr;
1678 float mapvote_maxlen;
1679 float mapvote_voters;
1680 float mapvote_votes[MAPVOTE_COUNT];
1681 float mapvote_run;
1682 float mapvote_detail;
1683 float mapvote_abstain;
1684 float mapvote_dirty;
1685 .float mapvote;
1686
1687 void MapVote_ClearAllVotes()
1688 {
1689         FOR_EACH_CLIENT(other)
1690                 other.mapvote = 0;
1691 }
1692
1693 string MapVote_Suggest(string m)
1694 {
1695         float i;
1696         if(m == "")
1697                 return "That's not how to use this command.";
1698         if(!cvar("g_maplist_votable_suggestions"))
1699                 return "Suggestions are not accepted on this server.";
1700         if(mapvote_initialized)
1701                 return "Can't suggest - voting is already in progress!";
1702 #ifdef MAPINFO
1703         m = MapInfo_FixName(m);
1704         if(!m)
1705                 return "The map you suggested is not available on this server.";
1706 #else
1707         if(!cvar("g_maplist_votable_suggestions_change_gametype"))
1708                 if(!IsSameGametype(m))
1709                         return "This server does not allow changing the game type by map suggestions.";
1710 #endif
1711         if(!cvar("g_maplist_votable_override_mostrecent"))
1712                 if(Map_IsRecent(m))
1713                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1714
1715 #ifdef MAPINFO
1716         if(!MapInfo_CheckMap(m))
1717                 return "The map you suggested does not support the current game mode.";
1718 #else
1719         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1720                 return "The map you suggested is not available on this server.";
1721 #endif
1722         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1723                 if(mapvote_suggestions[i] == m)
1724                         return "This map was already suggested.";
1725         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1726         {
1727                 i = ceil(random() * mapvote_suggestion_ptr) - 1;
1728         }
1729         else
1730         {
1731                 i = mapvote_suggestion_ptr;
1732                 mapvote_suggestion_ptr += 1;
1733         }
1734         if(mapvote_suggestions[i] != "")
1735                 strunzone(mapvote_suggestions[i]);
1736         mapvote_suggestions[i] = strzone(m);
1737         if(cvar("sv_eventlog"))
1738                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)), TRUE);
1739         return strcat("Suggestion of ", m, " accepted.");
1740 }
1741
1742 void MapVote_AddVotable(string nextMap, float isSuggestion)
1743 {
1744         float j;
1745         if(nextMap == "")
1746                 return;
1747         for(j = 0; j < mapvote_count; ++j)
1748                 if(mapvote_maps[j] == nextMap)
1749                         return;
1750         if(strlen(nextMap) > mapvote_maxlen)
1751                 mapvote_maxlen = strlen(nextMap);
1752         mapvote_maps[mapvote_count] = strzone(nextMap);
1753         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1754         mapvote_count += 1;
1755 }
1756
1757 void MapVote_SendData(float target);
1758 void MapVote_Init()
1759 {
1760         float i;
1761         float nmax, smax;
1762
1763         MapVote_ClearAllVotes();
1764
1765         mapvote_count = 0;
1766         mapvote_detail = !cvar("g_maplist_votable_nodetail");
1767         mapvote_abstain = cvar("g_maplist_votable_abstain");
1768
1769         if(mapvote_abstain)
1770                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
1771         else
1772                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
1773         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
1774
1775         if(mapvote_suggestion_ptr)
1776                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
1777                         MapVote_AddVotable(mapvote_suggestions[ceil(random() * mapvote_suggestion_ptr) - 1], TRUE);
1778
1779         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1780                 MapVote_AddVotable(GetNextMap(), FALSE);
1781
1782         if(mapvote_count == 0)
1783         {
1784                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1785 #ifdef MAPINFO
1786                 cvar_set("g_maplist", MapInfo_ListAllowedMaps());
1787                 localcmd("\nmenu_cmd sync\n");
1788 #else
1789                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
1790 #endif
1791                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1792                         MapVote_AddVotable(GetNextMap(), FALSE);
1793         }
1794
1795         mapvote_count_real = mapvote_count;
1796         if(mapvote_abstain)
1797                 MapVote_AddVotable("don't care", 0);
1798
1799         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
1800
1801         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
1802         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
1803         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
1804                 mapvote_keeptwotime = 0;
1805         mapvote_message = "Choose a map and press its key!";
1806
1807         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
1808         if(mapvote_screenshot_dir == "")
1809                 mapvote_screenshot_dir = "maps";
1810         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
1811
1812         if(!cvar("g_maplist_textonly"))
1813                 MapVote_SendData(MSG_ALL);
1814 }
1815
1816 void MapVote_SendPicture(float id)
1817 {
1818         msg_entity = self;
1819         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1820         WriteByte(MSG_ONE, TE_CSQC_MAPVOTE);
1821         WriteByte(MSG_ONE, MAPVOTE_NET_PIC);
1822         WriteByte(MSG_ONE, id);
1823         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
1824 }
1825
1826 float GameCommand_MapVote(string cmd)
1827 {
1828         if(!intermission_running)
1829                 return FALSE;
1830         if(!cvar("g_maplist_textonly"))
1831         {
1832                 if(cmd == "mv_getpic")
1833                 {
1834                         MapVote_SendPicture(stof(argv(1)));
1835                         return TRUE;
1836                 }
1837         }
1838
1839         return FALSE;
1840 }
1841
1842 float MapVote_GetMapMask()
1843 {
1844         float mask, i, power;
1845         mask = 0;
1846         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
1847                 if(mapvote_maps[i] != "")
1848                         mask |= power;
1849         return mask;
1850 }
1851
1852 void MapVote_SendData(float targ)
1853 {
1854         string mapfile, pakfile;
1855         float i, o;
1856         WriteByte(targ, SVC_TEMPENTITY);
1857         WriteByte(targ, TE_CSQC_CONFIG);
1858         WriteString(targ, "mv_screenshot_dir");
1859         WriteString(targ, mapvote_screenshot_dir);
1860
1861         WriteByte(targ, SVC_TEMPENTITY);
1862         WriteByte(targ, TE_CSQC_MAPVOTE);
1863         WriteByte(targ, MAPVOTE_NET_INIT);
1864
1865         WriteByte(targ, mapvote_count);
1866         WriteByte(targ, mapvote_abstain);
1867         WriteByte(targ, mapvote_detail);
1868         WriteCoord(targ, mapvote_timeout);
1869         if(mapvote_count <= 8)
1870                 WriteByte(targ, MapVote_GetMapMask());
1871         else
1872                 WriteShort(targ, MapVote_GetMapMask());
1873         for(i = 0; i < mapvote_count; ++i)
1874                 if(mapvote_maps[i] != "")
1875                 {
1876                         WriteString(targ, mapvote_maps[i]);
1877                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
1878                         pakfile = whichpack(strcat(mapfile, ".tga"));
1879                         if(pakfile == "")
1880                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
1881                         if(pakfile == "")
1882                                 pakfile = whichpack(strcat(mapfile, ".png"));
1883                         print("pakfile is ", pakfile, "\n");
1884                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
1885                                 pakfile = substring(pakfile, o, 999);
1886                         WriteString(targ, pakfile);
1887                 }
1888 }
1889
1890 void MapVote_UpdateData(float targ)
1891 {
1892         float i;
1893         WriteByte(targ, SVC_TEMPENTITY);
1894         WriteByte(targ, TE_CSQC_MAPVOTE);
1895         WriteByte(targ, MAPVOTE_NET_UPDATE);
1896         if(mapvote_count <= 8)
1897                 WriteByte(targ, MapVote_GetMapMask());
1898         else
1899                 WriteShort(targ, MapVote_GetMapMask());
1900         if(mapvote_detail)
1901                 for(i = 0; i < mapvote_count; ++i)
1902                         if(mapvote_maps[i] != "")
1903                                 WriteByte(targ, mapvote_votes[i]);
1904 }
1905
1906 void MapVote_TellVote(float targ, float vote)
1907 {
1908         WriteByte(targ, SVC_TEMPENTITY);
1909         WriteByte(targ, TE_CSQC_MAPVOTE);
1910         WriteByte(targ, MAPVOTE_NET_OWNVOTE);
1911         WriteByte(targ, vote);
1912 }
1913
1914 float MapVote_Finished(float mappos)
1915 {
1916         string result;
1917         float i;
1918         float didntvote;
1919
1920         if(cvar("sv_eventlog"))
1921         {
1922                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
1923                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
1924                 didntvote = mapvote_voters;
1925                 for(i = 0; i < mapvote_count; ++i)
1926                         if(mapvote_maps[i] != "")
1927                         {
1928                                 didntvote -= mapvote_votes[i];
1929                                 if(i != mappos)
1930                                 {
1931                                         result = strcat(result, ":", mapvote_maps[i]);
1932                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
1933                                 }
1934                         }
1935                 result = strcat(result, ":didn't vote:", ftos(didntvote));
1936
1937                 GameLogEcho(result, FALSE);
1938                 if(mapvote_maps_suggested[mappos])
1939                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]), FALSE);
1940         }
1941
1942         FOR_EACH_REALCLIENT(other)
1943                 FixClientCvars(other);
1944
1945         Map_Goto_SetStr(mapvote_maps[mappos]);
1946         Map_Goto();
1947         alreadychangedlevel = TRUE;
1948         return TRUE;
1949 }
1950 void MapVote_CheckRules_1()
1951 {
1952         float i;
1953
1954         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1955         {
1956                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
1957                 mapvote_votes[i] = 0;
1958         }
1959
1960         mapvote_voters = 0;
1961         FOR_EACH_REALCLIENT(other)
1962         {
1963                 ++mapvote_voters;
1964                 if(other.mapvote)
1965                 {
1966                         i = other.mapvote - 1;
1967                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
1968                         mapvote_votes[i] = mapvote_votes[i] + 1;
1969                 }
1970         }
1971 }
1972
1973 float MapVote_CheckRules_2()
1974 {
1975         float i;
1976         float firstPlace, secondPlace;
1977         float firstPlaceVotes, secondPlaceVotes;
1978         float mapvote_voters_real;
1979         string result;
1980
1981         mapvote_voters_real = mapvote_voters;
1982         if(mapvote_abstain)
1983                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
1984
1985         RandomSelection_Init();
1986         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
1987                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
1988         firstPlace = RandomSelection_chosen_float;
1989         firstPlaceVotes = RandomSelection_best_priority;
1990         //dprint("First place: ", ftos(firstPlace), "\n");
1991         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
1992
1993         RandomSelection_Init();
1994         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
1995                 if(i != firstPlace)
1996                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
1997         secondPlace = RandomSelection_chosen_float;
1998         secondPlaceVotes = RandomSelection_best_priority;
1999         //dprint("Second place: ", ftos(secondPlace), "\n");
2000         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2001
2002         if(firstPlace == -1)
2003                 error("No first place in map vote... WTF?");
2004
2005         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2006                 return MapVote_Finished(firstPlace);
2007
2008         if(mapvote_keeptwotime)
2009                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2010                 {
2011                         float didntvote;
2012                         mapvote_dirty = TRUE;
2013                         mapvote_message = "Now decide between the TOP TWO!";
2014                         mapvote_keeptwotime = 0;
2015                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2016                         result = strcat(result, ":", ftos(firstPlaceVotes));
2017                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2018                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2019                         didntvote = mapvote_voters;
2020                         for(i = 0; i < mapvote_count; ++i)
2021                                 if(mapvote_maps[i] != "")
2022                                 {
2023                                         didntvote -= mapvote_votes[i];
2024                                         if(i != firstPlace)
2025                                                 if(i != secondPlace)
2026                                                 {
2027                                                         result = strcat(result, ":", mapvote_maps[i]);
2028                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2029                                                         if(i < mapvote_count_real)
2030                                                         {
2031                                                                 strunzone(mapvote_maps[i]);
2032                                                                 mapvote_maps[i] = "";
2033                                                         }
2034                                                 }
2035                                 }
2036                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2037                         if(cvar("sv_eventlog"))
2038                                 GameLogEcho(result, FALSE);
2039                 }
2040
2041         return FALSE;
2042 }
2043 void MapVote_Tick()
2044 {
2045         string msgstr;
2046         string tmp;
2047         float i;
2048         float keeptwo;
2049         float totalvotes;
2050
2051         keeptwo = mapvote_keeptwotime;
2052         MapVote_CheckRules_1(); // count
2053         if(MapVote_CheckRules_2()) // decide
2054                 return;
2055
2056         totalvotes = 0;
2057         FOR_EACH_REALCLIENT(other)
2058         {
2059                 // hide scoreboard again
2060                 if(other.health != 2342)
2061                 {
2062                         other.health = 2342;
2063                         other.impulse = 0;
2064                         if(clienttype(other) == CLIENTTYPE_REAL)
2065                         {
2066                                 if(cvar("g_maplist_textonly"))
2067                                         stuffcmd(other, "\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
2068
2069                                 msg_entity = other;
2070                                 WriteByte(MSG_ONE, SVC_FINALE);
2071                                 WriteString(MSG_ONE, "");
2072                         }
2073                 }
2074
2075                 // notify about keep-two
2076                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2077                         play2(other, "misc/invshot.wav");
2078
2079                 // clear possibly invalid votes
2080                 if(mapvote_maps[other.mapvote - 1] == "")
2081                         other.mapvote = 0;
2082                 // use impulses as new vote
2083                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2084                         if(mapvote_maps[other.impulse - 1] != "")
2085                         {
2086                                 other.mapvote = other.impulse;
2087                                 if(mapvote_detail)
2088                                         mapvote_dirty = TRUE;
2089
2090                                 msg_entity = other;
2091                                 MapVote_TellVote(MSG_ONE, other.mapvote);
2092                         }
2093                 other.impulse = 0;
2094
2095                 if(other.mapvote)
2096                         ++totalvotes;
2097         }
2098
2099         MapVote_CheckRules_1(); // just count
2100
2101         if(!cvar("g_maplist_textonly"))
2102         if(mapvote_dirty) // 1 if "keeptwo" or "impulse" happened before
2103         {
2104                 MapVote_UpdateData(MSG_BROADCAST);
2105                 mapvote_dirty = FALSE;
2106         }
2107
2108         if(cvar("g_maplist_textonly"))
2109         {
2110                 FOR_EACH_REALCLIENT(other)
2111                 {
2112                         // display voting screen
2113                         msgstr = "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n";
2114                         msgstr = substring(msgstr, 0, strlen(msgstr) - mapvote_count);
2115                         if(mapvote_abstain)
2116                                 msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2117                         msgstr = strcat(msgstr, mapvote_message);
2118                         msgstr = strcat(msgstr, "\n\n");
2119                         for(i = 0; i < mapvote_count; ++i)
2120                                 if(mapvote_maps[i] == "")
2121                                         msgstr = strcat(msgstr, "\n");
2122                                 else
2123                                 {
2124                                         tmp = mapvote_maps[i];
2125                                         tmp = strpad(mapvote_maxlen, tmp);
2126                                         tmp = strcat(ftos(mod(i + 1, 10)), ": ", tmp);
2127                                         if(mapvote_detail)
2128                                         {
2129                                                 tmp = strcat(tmp, " ^2(", ftos(mapvote_votes[i]), " vote");
2130                                                 if(mapvote_votes[i] != 1)
2131                                                         tmp = strcat(tmp, "s");
2132                                                 tmp = strcat(tmp, ")");
2133                                                 tmp = strpad(mapvote_maxlen + 15, tmp);
2134                                         }
2135                                         if(mapvote_abstain)
2136                                                 if(i == mapvote_count - 1)
2137                                                         msgstr = strcat(msgstr, "\n");
2138                                         if(other.mapvote == i + 1)
2139                                                 msgstr = strcat(msgstr, "^3> ", tmp, "\n");
2140                                         else
2141                                                 msgstr = strcat(msgstr, "^7  ", tmp, "\n");
2142                                 }
2143
2144                         msgstr = strcat(msgstr, "\n\n^2", ftos(totalvotes), " vote");
2145                         if(totalvotes != 1)
2146                                 msgstr = strcat(msgstr, "s");
2147                         msgstr = strcat(msgstr, " cast");
2148                         i = ceil(mapvote_timeout - time);
2149                         msgstr = strcat(msgstr, "\n", ftos(i), " second");
2150                         if(i != 1)
2151                                 msgstr = strcat(msgstr, "s");
2152                         msgstr = strcat(msgstr, " left");
2153
2154                         centerprint_atprio(other, CENTERPRIO_MAPVOTE, msgstr);
2155                 }
2156         }
2157 }
2158 void MapVote_Start()
2159 {
2160         if(mapvote_run)
2161                 return;
2162
2163 #ifdef MAPINFO
2164         MapInfo_Enumerate();
2165         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 1))
2166 #endif
2167                 mapvote_run = TRUE;
2168 }
2169 void MapVote_Think()
2170 {
2171         if(!mapvote_run)
2172                 return;
2173
2174         if(alreadychangedlevel)
2175                 return;
2176
2177         if(time < mapvote_nextthink)
2178                 return;
2179         //dprint("tick\n");
2180
2181         mapvote_nextthink = time + 0.5;
2182
2183         if(!mapvote_initialized)
2184         {
2185                 mapvote_initialized = TRUE;
2186                 if(DoNextMapOverride())
2187                         return;
2188                 if(!cvar("g_maplist_votable") || player_count <= 0)
2189                 {
2190                         GotoNextMap();
2191                         return;
2192                 }
2193                 MapVote_Init();
2194         }
2195
2196         MapVote_Tick();
2197 };
2198
2199 string GotoMap(string m)
2200 {
2201 #ifdef MAPINFO
2202         if(!MapInfo_CheckMap(m))
2203 #else
2204         if(!TryFile(strcat("maps/", m, ".mapcfg")))
2205 #endif
2206                 return "The map you chose is not available on this server.";
2207         cvar_set("nextmap", m);
2208         cvar_set("timelimit", "-1");
2209         if(mapvote_initialized || alreadychangedlevel)
2210         {
2211                 if(DoNextMapOverride())
2212                         return "Map switch initiated.";
2213                 else
2214                         return "Hm... no. For some reason I like THIS map more.";
2215         }
2216         else
2217                 return "Map switch will happen after scoreboard.";
2218 }
2219
2220
2221 void EndFrame()
2222 {
2223         FOR_EACH_REALCLIENT(self)
2224         {
2225                 if(self.classname == "spectator")
2226                 {
2227                         if(self.enemy.hitsound)
2228                                 play2(self, "misc/hit.wav");
2229                 }
2230                 else
2231                 {
2232                         if(self.hitsound)
2233                                 play2(self, "misc/hit.wav");
2234                 }
2235         }
2236         FOR_EACH_CLIENT(self)
2237                 self.hitsound = FALSE;
2238 }
2239
2240
2241 /*
2242  * RedirectionThink:
2243  * returns TRUE if redirecting
2244  */
2245 float redirection_timeout;
2246 float redirection_nextthink;
2247 float RedirectionThink()
2248 {
2249         float clients_found;
2250
2251         if(redirection_target == "")
2252                 return FALSE;
2253
2254         if(!redirection_timeout)
2255         {
2256                 cvar_set("sv_public", "-2");
2257                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2258                 if(redirection_target == "self")
2259                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2260                 else
2261                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2262         }
2263
2264         if(time < redirection_nextthink)
2265                 return TRUE;
2266
2267         redirection_nextthink = time + 1;
2268
2269         clients_found = 0;
2270         FOR_EACH_REALCLIENT(self)
2271         {
2272                 ServerConsoleEcho(strcat("Redirecting: sending connect command to ", self.netname), FALSE);
2273                 if(redirection_target == "self")
2274                         stuffcmd(self, "\ndisconnect; reconnect\n");
2275                 else
2276                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2277                 ++clients_found;
2278         }
2279
2280         ServerConsoleEcho(strcat("Redirecting: ", ftos(clients_found), " clients left."), FALSE);
2281
2282         if(time > redirection_timeout || clients_found == 0)
2283                 localcmd("\nwait; wait; wait; quit\n");
2284
2285         return TRUE;
2286 }
2287
2288 void RestoreGame()
2289 {
2290         // Loaded from a save game
2291         // some things then break, so let's work around them...
2292
2293         // Progs DB (capture records)
2294         if(sv_cheats)
2295                 ServerProgsDB = db_create();
2296         else
2297                 ServerProgsDB = db_load("server.db");
2298
2299         // Mapinfo
2300 #ifdef MAPINFO
2301         MapInfo_Shutdown();
2302         MapInfo_Enumerate();
2303         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 1);
2304 #endif
2305 }
2306
2307 void SV_Shutdown()
2308 {
2309         if(world_initialized)
2310         {
2311                 world_initialized = 0;
2312                 print("Saving persistent data...\n");
2313                 Ban_SaveBans();
2314                 if(!sv_cheats)
2315                         db_save(ServerProgsDB, "server.db");
2316                 db_close(ServerProgsDB);
2317                 print("done!\n");
2318                 // tell the bot system the game is ending now
2319                 bot_endgame();
2320
2321                 MapInfo_Shutdown();
2322         }
2323         else
2324         {
2325                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2326         }
2327 }