data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 void GotoFirstMap()
 135 {
 136         float n;
 137         if(cvar("_sv_init"))
 138         {
 139                 // cvar_set("_sv_init", "0");
 140                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 141                 // to this "init" map on a dedicated server will cause no permanent
 142                 // harm
 143                 if(cvar("g_maplist_shuffle"))
 144                         ShuffleMaplist();
 145                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 146                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 147
 148                 MapInfo_Enumerate();
 149                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 150
 151                 if(!DoNextMapOverride())
 152                         GotoNextMap();
 153
 154                 return;
 155         }
 156
 157         if(time < 5)
 158         {
 159                 self.nextthink = time;
 160         }
 161         else
 162         {
 163                 self.nextthink = time + 1;
 164                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 165         }
 166 }
 167
 168 void cvar_changes_init()
 169 {
 170         float h;
 171         string k, v, d;
 172         float n, i;
 173
 174         if(cvar_changes)
 175                 strunzone(cvar_changes);
 176         cvar_changes = string_null;
 177
 178         h = buf_create();
 179         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 180         n = buf_getsize(h);
 181
 182         for(i = 0; i < n; ++i)
 183         {
 184                 k = bufstr_get(h, i);
 185
 186 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 187 #define BADCVAR(p) if(k == p) continue
 188                 // internal
 189                 BADPREFIX("csqc_");
 190                 BADPREFIX("cvar_check_");
 191                 BADCVAR("gamecfg");
 192                 BADCVAR("g_configversion");
 193                 BADCVAR("g_maplist_index");
 194                 BADCVAR("halflifebsp");
 195
 196                 // client
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("g_campaign");
 200                 BADPREFIX("gl_");
 201                 BADPREFIX("joy");
 202                 BADPREFIX("menu_");
 203                 BADPREFIX("net_slist_");
 204                 BADPREFIX("r_");
 205                 BADPREFIX("sbar_");
 206                 BADPREFIX("scr_");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213
 214                 // private
 215                 BADPREFIX("g_ban_");
 216                 BADPREFIX("g_chat_flood_");
 217                 BADPREFIX("rcon_");
 218                 BADPREFIX("settemp_");
 219                 BADPREFIX("sv_allowdownloads_");
 220                 BADPREFIX("sv_autodemo");
 221                 BADPREFIX("sv_curl_");
 222                 BADPREFIX("sv_eventlog");
 223                 BADPREFIX("sv_logscores_");
 224                 BADPREFIX("sv_master");
 225                 BADCVAR("g_banned_list");
 226                 BADCVAR("log_dest_udp");
 227                 BADCVAR("log_file");
 228                 BADCVAR("net_address");
 229                 BADCVAR("port");
 230                 BADCVAR("savedgamecfg");
 231                 BADCVAR("sv_heartbeatperoid");
 232                 BADCVAR("sv_vote_master_password");
 233                 BADCVAR("sys_colortranslation");
 234                 BADCVAR("sys_specialcharactertranslation");
 235                 BADCVAR("timestamps");
 236
 237                 // mapinfo
 238                 BADCVAR("timelimit");
 239                 BADCVAR("fraglimit");
 240                 BADCVAR("g_arena");
 241                 BADCVAR("g_assault");
 242                 BADCVAR("g_ctf");
 243                 BADCVAR("g_dm");
 244                 BADCVAR("g_domination");
 245                 BADCVAR("g_keyhunt");
 246                 BADCVAR("g_keyhunt_teams");
 247                 BADCVAR("g_onslaught");
 248                 BADCVAR("g_race");
 249                 BADCVAR("g_runematch");
 250                 BADCVAR("g_tdm");
 251                 BADCVAR("teamplay");
 252
 253                 // long
 254                 BADCVAR("hostname");
 255                 BADCVAR("g_maplist");
 256                 BADCVAR("g_maplist_mostrecent");
 257                 BADCVAR("sv_motd");
 258 #undef BADPREFIX
 259 #undef BADCVAR
 260
 261                 v = cvar_string(k);
 262                 d = cvar_defstring(k);
 263                 if(v != d)
 264                 {
 265                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 266                         if(strlen(cvar_changes) > 16384)
 267                         {
 268                                 cvar_changes = "// too many settings have been changed to show them here\n";
 269                                 break;
 270                         }
 271                 }
 272         }
 273         buf_del(h);
 274         if(cvar_changes == "")
 275                 cvar_changes = "// this server runs at default settings\n";
 276         else
 277                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 278         cvar_changes = strzone(cvar_changes);
 279 }
 280
 281 void detect_maptype()
 282 {
 283 #if 0
 284         vector o, v;
 285         float i;
 286
 287         for(;;)
 288         {
 289                 o = world.mins;
 290                 o_x += random() * (world.maxs_x - world.mins_x);
 291                 o_y += random() * (world.maxs_y - world.mins_y);
 292                 o_z += random() * (world.maxs_z - world.mins_z);
 293
 294                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 295                 if(trace_fraction == 1)
 296                         continue;
 297
 298                 v = trace_endpos;
 299
 300                 for(i = 0; i < 64; i += 4)
 301                 {
 302                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 303         if(trace_fraction == 1)
 304                 continue;
 305                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 306                 }
 307
 308                 break;
 309         }
 310 #endif
 311 }
 312
 313 entity randomseed;
 314 float RandomSeed_Send(entity to, float sf)
 315 {
 316         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 317         WriteShort(MSG_ENTITY, self.cnt);
 318         return TRUE;
 319 }
 320 void RandomSeed_Think()
 321 {
 322         self.cnt = bound(0, floor(random() * 65536), 65535);
 323         self.nextthink = time + 5;
 324
 325         self.SendFlags |= 1;
 326 }
 327 void RandomSeed_Spawn()
 328 {
 329         randomseed = spawn();
 330         randomseed.think = RandomSeed_Think;
 331         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 332
 333         entity oldself;
 334         oldself = self;
 335         self = randomseed;
 336         self.think(); // sets random seed and nextthink
 337         self = oldself;
 338 }
 339
 340 void spawnfunc___init_dedicated_server(void)
 341 {
 342         // handler for _init/_init map (only for dedicated server initialization)
 343
 344         dprint_load(); // load dprint status from cvar
 345         world_initialized = -1; // don't complain
 346         remove = remove_unsafely;
 347
 348         entity e;
 349         e = spawn();
 350         e.think = GotoFirstMap;
 351         e.nextthink = time; // this is usually 1 at this point
 352
 353         e = spawn();
 354         e.classname = "info_player_deathmatch"; // safeguard against player joining
 355
 356         self.classname = "worldspawn"; // safeguard against various stuff ;)
 357
 358         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 359         MapInfo_Enumerate();
 360         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 361 }
 362
 363 void Map_MarkAsRecent(string m);
 364 float world_already_spawned;
 365 void RegisterWeapons();
 366 void Nagger_Init();
 367 void ClientInit_Spawn();
 368 void spawnfunc_worldspawn (void)
 369 {
 370         float fd, l, i, j, n;
 371         string s, col;
 372
 373         dprint_load(); // load dprint status from cvar
 374
 375         if(world_already_spawned)
 376                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 377         world_already_spawned = TRUE;
 378
 379         remove = remove_safely; // during spawning, watch what you remove!
 380
 381         if(cvar_string("cvar_check_default") != "bypass")
 382         {
 383                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 384                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code!");
 385
 386                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 387                         error("Config file mismatch! Please update weapons.cfg and weaponsPro.cfg to match the QuakeC code!");
 388         }
 389
 390         compressShortVector_init();
 391
 392         local entity head;
 393         head = nextent(world);
 394         maxclients = 0;
 395         while(head)
 396         {
 397                 ++maxclients;
 398                 head = nextent(head);
 399         }
 400
 401         // needs to be done so early as they would still spawn
 402         RegisterWeapons();
 403
 404         if(sv_cheats)
 405                 ServerProgsDB = db_create();
 406         else
 407                 ServerProgsDB = db_load("server.db");
 408
 409         TemporaryDB = db_create();
 410
 411         /*
 412         TODO sound pack system
 413         // initialize sound pack system
 414         soundpack = cvar_string("g_soundpack");
 415         if(soundpack != "")
 416                 soundpack = strcat(soundpack, "/");
 417         soundpack = strzone(soundpack);
 418         */
 419
 420         // 0 normal
 421         lightstyle(0, "m");
 422
 423         // 1 FLICKER (first variety)
 424         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 425
 426         // 2 SLOW STRONG PULSE
 427         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 428
 429         // 3 CANDLE (first variety)
 430         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 431
 432         // 4 FAST STROBE
 433         lightstyle(4, "mamamamamama");
 434
 435         // 5 GENTLE PULSE 1
 436         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 437
 438         // 6 FLICKER (second variety)
 439         lightstyle(6, "nmonqnmomnmomomno");
 440
 441         // 7 CANDLE (second variety)
 442         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 443
 444         // 8 CANDLE (third variety)
 445         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 446
 447         // 9 SLOW STROBE (fourth variety)
 448         lightstyle(9, "aaaaaaaazzzzzzzz");
 449
 450         // 10 FLUORESCENT FLICKER
 451         lightstyle(10, "mmamammmmammamamaaamammma");
 452
 453         // 11 SLOW PULSE NOT FADE TO BLACK
 454         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 455
 456         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 457
 458         // 63 testing
 459         lightstyle(63, "a");
 460
 461         if(cvar("g_campaign"))
 462                 CampaignPreInit();
 463
 464         Map_MarkAsRecent(mapname);
 465
 466         precache_model ("null"); // we need this one before InitGameplayMode
 467         InitGameplayMode();
 468         readlevelcvars();
 469         GrappleHookInit();
 470
 471         player_count = 0;
 472         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 473         if(bot_waypoints_for_items == 1)
 474                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 475                         bot_waypoints_for_items = 0;
 476
 477         // for setting by mapinfo
 478         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 479         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 480
 481         precache();
 482
 483         WaypointSprite_Init();
 484
 485         //if (g_domination)
 486         //      dom_init();
 487
 488         GameLogInit(); // prepare everything
 489         if(cvar("sv_eventlog"))
 490         {
 491                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 492                 s = strcat(s, ftos(random()));
 493                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 494                 s = ":gameinfo:mutators:LIST";
 495                 if(cvar("g_grappling_hook"))
 496                         s = strcat(s, ":grappling_hook");
 497                 if(!cvar("g_use_ammunition"))
 498                         s = strcat(s, ":no_use_ammunition");
 499                 if(!cvar("g_pickup_items"))
 500                         s = strcat(s, ":no_pickup_items");
 501                 if(cvar("g_instagib"))
 502                         s = strcat(s, ":instagib");
 503                 if(cvar_string("g_weaponarena") != "0")
 504                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 505                 if(cvar("g_nixnex"))
 506                         s = strcat(s, ":nixnex");
 507                 if(cvar("g_vampire"))
 508                         s = strcat(s, ":vampire");
 509                 if(cvar("g_laserguided_missile"))
 510                         s = strcat(s, ":laserguided_missile");
 511                 if(cvar("g_norecoil"))
 512                         s = strcat(s, ":norecoil");
 513                 if(cvar("g_midair"))
 514                         s = strcat(s, ":midair");
 515                 if(cvar("g_minstagib"))
 516                         s = strcat(s, ":minstagib");
 517                 GameLogEcho(s);
 518                 GameLogEcho(":gameinfo:end");
 519         }
 520
 521         cvar_set("nextmap", "");
 522
 523         SetDefaultAlpha();
 524
 525         if(cvar("g_campaign"))
 526                 CampaignPostInit();
 527
 528         fteqcc_testbugs();
 529
 530         Ban_LoadBans();
 531
 532         //initialise globals related to sv_timeout
 533         sys_ticrate = cvar("sys_ticrate");
 534         orig_slowmo = cvar("slowmo");
 535
 536         MapInfo_Enumerate();
 537         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
 538
 539         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 540         {
 541                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 542                 if(fd != -1)
 543                 {
 544                         while((s = fgets(fd)))
 545                         {
 546                                 l = tokenize_sane(s);
 547                                 if(l < 2)
 548                                         continue;
 549                                 if(argv(0) == "cd")
 550                                 {
 551                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 552                                         print("  cdtrack ", argv(2), "\n");
 553                                 }
 554                                 else if(argv(0) == "fog")
 555                                 {
 556                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 557                                         print("  \"fog\" \"", s, "\"\n");
 558                                 }
 559                                 else if(argv(0) == "set")
 560                                 {
 561                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 562                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 563                                 }
 564                                 else if(argv(0) != "//")
 565                                 {
 566                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 567                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 568                                 }
 569                         }
 570                         fclose(fd);
 571                 }
 572         }
 573
 574         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 575         addstat(STAT_WEAPONS, AS_INT, weapons);
 576         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 577         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 578         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 579         Nagger_Init();
 580
 581         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 582         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 583
 584         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 585
 586         next_pingtime = time + 5;
 587         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 588
 589         detect_maptype();
 590
 591         lsmaps_reply = "^7Maps available: ";
 592         for(i = 0, j = 0; i < MapInfo_count; ++i)
 593         {
 594                 if(MapInfo_Get_ByID(i))
 595                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 596                         {
 597                                 if(mod(i, 2))
 598                                         col = "^2";
 599                                 else
 600                                         col = "^3";
 601                                 ++j;
 602                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 603                         }
 604         }
 605         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 606
 607         maplist_reply = "^7Maps in list: ";
 608         n = tokenize_sane(cvar_string("g_maplist"));
 609         for(i = 0, j = 0; i < n; ++i)
 610         {
 611                 if(MapInfo_CheckMap(argv(i)))
 612                 {
 613                         if(mod(j, 2))
 614                                 col = "^2";
 615                         else
 616                                 col = "^3";
 617                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 618                         ++j;
 619                 }
 620         }
 621         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 622
 623         records_reply = strzone(getrecords());
 624
 625         ClientInit_Spawn();
 626         RandomSeed_Spawn();
 627
 628         world_initialized = 1;
 629 }
 630
 631 void spawnfunc_light (void)
 632 {
 633         //makestatic (self); // Who the f___ did that?
 634         remove(self);
 635 }
 636
 637 float TryFile( string pFilename )
 638 {
 639         local float lHandle;
 640         dprint("TryFile(\"", pFilename, "\")\n");
 641         lHandle = fopen( pFilename, FILE_READ );
 642         if( lHandle != -1 ) {
 643                 fclose( lHandle );
 644                 return TRUE;
 645         } else {
 646                 return FALSE;
 647         }
 648 };
 649
 650 string GetGametype()
 651 {
 652         return GametypeNameFromType(game);
 653 }
 654
 655 string getmapname_stored;
 656 string GetMapname()
 657 {
 658         return mapname;
 659 }
 660
 661 float Map_Count, Map_Current;
 662 string Map_Current_Name;
 663
 664 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 665 float GetMaplistPosition()
 666 {
 667         float pos, idx;
 668         string map;
 669
 670         map = GetMapname();
 671         idx = cvar("g_maplist_index");
 672
 673         if(idx >= 0)
 674                 if(idx < Map_Count)
 675                         if(map == argv(idx))
 676                                 return idx;
 677
 678         for(pos = 0; pos < Map_Count; ++pos)
 679                 if(map == argv(pos))
 680                         return pos;
 681
 682         // resume normal maplist rotation if current map is not in g_maplist
 683         return idx;
 684 }
 685
 686 float MapHasRightSize(string map)
 687 {
 688         float fh;
 689         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 690         if(cvar("g_maplist_check_waypoints"))
 691         {
 692                 dprint("checkwp "); dprint(map);
 693                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 694                 if(fh < 0)
 695                 {
 696                         dprint(": no waypoints\n");
 697                         return FALSE;
 698                 }
 699                 dprint(": has waypoints\n");
 700                 fclose(fh);
 701         }
 702
 703         // open map size restriction file
 704         dprint("opensize "); dprint(map);
 705         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 706         if(fh >= 0)
 707         {
 708                 float mapmin, mapmax;
 709                 dprint(": ok, ");
 710                 mapmin = stof(fgets(fh));
 711                 mapmax = stof(fgets(fh));
 712                 fclose(fh);
 713                 if(player_count < mapmin)
 714                 {
 715                         dprint("not enough\n");
 716                         return FALSE;
 717                 }
 718                 if(player_count > mapmax)
 719                 {
 720                         dprint("too many\n");
 721                         return FALSE;
 722                 }
 723                 dprint("right size\n");
 724                 return TRUE;
 725         }
 726         dprint(": not found\n");
 727         return TRUE;
 728 }
 729
 730 string Map_Filename(float position)
 731 {
 732         return strcat("maps/", argv(position), ".bsp");
 733 }
 734
 735 string strwords(string s, float w)
 736 {
 737         float endpos;
 738         for(endpos = 0; w && endpos >= 0; --w)
 739                 endpos = strstrofs(s, " ", endpos + 1);
 740         if(endpos < 0)
 741                 return s;
 742         else
 743                 return substring(s, 0, endpos);
 744 }
 745
 746 float strhasword(string s, string w)
 747 {
 748         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 749 }
 750
 751 void Map_MarkAsRecent(string m)
 752 {
 753         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 754 }
 755
 756 float Map_IsRecent(string m)
 757 {
 758         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 759 }
 760
 761 float Map_Check(float position, float pass)
 762 {
 763         string filename;
 764         string map_next;
 765         map_next = argv(position);
 766         if(pass <= 1)
 767         {
 768                 if(Map_IsRecent(map_next))
 769                         return 0;
 770         }
 771         filename = Map_Filename(position);
 772         if(MapInfo_CheckMap(map_next))
 773         {
 774                 if(pass == 2)
 775                         return 1;
 776                 if(MapHasRightSize(map_next))
 777                         return 1;
 778                 return 0;
 779         }
 780         else
 781                 dprint( "Couldn't select '", filename, "'..\n" );
 782
 783         return 0;
 784 }
 785
 786 void Map_Goto_SetStr(string nextmapname)
 787 {
 788         if(getmapname_stored != "")
 789                 strunzone(getmapname_stored);
 790         if(nextmapname == "")
 791                 getmapname_stored = "";
 792         else
 793                 getmapname_stored = strzone(nextmapname);
 794 }
 795
 796 void Map_Goto_SetFloat(float position)
 797 {
 798         cvar_set("g_maplist_index", ftos(position));
 799         Map_Goto_SetStr(argv(position));
 800 }
 801
 802 void GameResetCfg()
 803 {
 804         // settings persist, except...
 805         if(cvar("g_campaign"))
 806                 localcmd("\nexec mutator_reset.cfg\n");
 807         localcmd("\nsettemp_restore\n");
 808 };
 809
 810 void Map_Goto()
 811 {
 812         GameResetCfg();
 813         MapInfo_LoadMap(getmapname_stored);
 814 }
 815
 816 // return codes of map selectors:
 817 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 818 //   -2 = permanent failure
 819 float() MaplistMethod_Iterate = // usual method
 820 {
 821         float pass, i;
 822
 823         for(pass = 1; pass <= 2; ++pass)
 824         {
 825                 for(i = 1; i < Map_Count; ++i)
 826                 {
 827                         float mapindex;
 828                         mapindex = mod(i + Map_Current, Map_Count);
 829                         if(Map_Check(mapindex, pass))
 830                                 return mapindex;
 831                 }
 832         }
 833         return -1;
 834 }
 835
 836 float() MaplistMethod_Repeat = // fallback method
 837 {
 838         if(Map_Check(Map_Current, 2))
 839                 return Map_Current;
 840         return -2;
 841 }
 842
 843 float() MaplistMethod_Random = // random map selection
 844 {
 845         float i, imax;
 846
 847         imax = 42;
 848
 849         for(i = 0; i <= imax; ++i)
 850         {
 851                 float mapindex;
 852                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 853                 if(Map_Check(mapindex, 1))
 854                         return mapindex;
 855         }
 856         return -1;
 857 }
 858
 859 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 860 // the exponent sets a bias on the map selection:
 861 // the higher the exponent, the less likely "shortly repeated" same maps are
 862 {
 863         float i, j, imax, insertpos;
 864
 865         imax = 42;
 866
 867         for(i = 0; i <= imax; ++i)
 868         {
 869                 string newlist;
 870
 871                 // now reinsert this at another position
 872                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 873                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 874                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 875                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 876
 877                 // insert the current map there
 878                 newlist = "";
 879                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 880                         newlist = strcat(newlist, " ", argv(j));
 881                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 882                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 883                         newlist = strcat(newlist, " ", argv(j));
 884                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 885                 cvar_set("g_maplist", newlist);
 886                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 887
 888                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 889                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 890                 if(Map_Check(Map_Current, 1))
 891                         return Map_Current;
 892         }
 893         return -1;
 894 }
 895
 896 void Maplist_Init()
 897 {
 898         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 899         if(Map_Count == 0)
 900         {
 901                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 902                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 903                 if(cvar("g_maplist_shuffle"))
 904                         ShuffleMaplist();
 905                 localcmd("\nmenu_cmd sync\n");
 906                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 907         }
 908         if(Map_Count == 0)
 909                 error("empty maplist, cannot select a new map");
 910         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 911
 912         if(Map_Current_Name)
 913                 strunzone(Map_Current_Name);
 914         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 915         // this may or may not be correct, but who cares, in the worst case a map
 916         // isn't chosen in the first pass that should have been
 917 }
 918
 919 string GetNextMap()
 920 {
 921         float nextMap;
 922
 923         Maplist_Init();
 924         nextMap = -1;
 925
 926         if(nextMap == -1)
 927                 if(cvar("g_maplist_shuffle") > 0)
 928                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 929
 930         if(nextMap == -1)
 931                 if(cvar("g_maplist_selectrandom"))
 932                         nextMap = MaplistMethod_Random();
 933
 934         if(nextMap == -1)
 935                 nextMap = MaplistMethod_Iterate();
 936
 937         if(nextMap == -1)
 938                 nextMap = MaplistMethod_Repeat();
 939
 940         if(nextMap >= 0)
 941         {
 942                 Map_Goto_SetFloat(nextMap);
 943                 return getmapname_stored;
 944         }
 945
 946         return "";
 947 };
 948
 949 float DoNextMapOverride()
 950 {
 951         if(cvar("g_campaign"))
 952         {
 953                 CampaignPostIntermission();
 954                 alreadychangedlevel = TRUE;
 955                 return TRUE;
 956         }
 957         if(cvar("quit_when_empty"))
 958         {
 959                 if(player_count <= currentbots)
 960                 {
 961                         localcmd("quit\n");
 962                         alreadychangedlevel = TRUE;
 963                         return TRUE;
 964                 }
 965         }
 966         if(cvar_string("quit_and_redirect") != "")
 967         {
 968                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 969                 alreadychangedlevel = TRUE;
 970                 return TRUE;
 971         }
 972         if (cvar("samelevel")) // if samelevel is set, stay on same level
 973         {
 974                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 975                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 976                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 977                 localcmd("restart\n");
 978                 //changelevel (mapname);
 979                 alreadychangedlevel = TRUE;
 980                 return TRUE;
 981         }
 982         if(cvar_string("nextmap") != "")
 983                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 984                 {
 985                         Map_Goto_SetStr(cvar_string("nextmap"));
 986                         Map_Goto();
 987                         alreadychangedlevel = TRUE;
 988                         return TRUE;
 989                 }
 990         if(cvar("lastlevel"))
 991         {
 992                 GameResetCfg();
 993                 localcmd("set lastlevel 0\ntogglemenu\n");
 994                 alreadychangedlevel = TRUE;
 995                 return TRUE;
 996         }
 997         return FALSE;
 998 };
 999
1000 void GotoNextMap()
1001 {
1002         //local string nextmap;
1003         //local float n, nummaps;
1004         //local string s;
1005         if (alreadychangedlevel)
1006                 return;
1007         alreadychangedlevel = TRUE;
1008
1009         {
1010                 string nextMap;
1011                 float allowReset;
1012
1013                 for(allowReset = 1; allowReset >= 0; --allowReset)
1014                 {
1015                         nextMap = GetNextMap();
1016                         if(nextMap != "")
1017                                 break;
1018
1019                         if(allowReset)
1020                         {
1021                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1022                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
1023                                 if(cvar("g_maplist_shuffle"))
1024                                         ShuffleMaplist();
1025                                 localcmd("\nmenu_cmd sync\n");
1026                         }
1027                         else
1028                         {
1029                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1030                         }
1031                 }
1032                 Map_Goto();
1033         }
1034 };
1035
1036
1037 /*
1038 ============
1039 IntermissionThink
1040
1041 When the player presses attack or jump, change to the next level
1042 ============
1043 */
1044 .float autoscreenshot;
1045 void() MapVote_Start;
1046 void() MapVote_Think;
1047 float mapvote_initialized;
1048 void IntermissionThink()
1049 {
1050         FixIntermissionClient(self);
1051
1052         if(cvar("sv_autoscreenshot"))
1053         if(self.autoscreenshot > 0)
1054         if(time > self.autoscreenshot)
1055         {
1056                 self.autoscreenshot = -1;
1057                 if(clienttype(self) == CLIENTTYPE_REAL)
1058                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1059                 return;
1060         }
1061
1062         if (time < intermission_exittime)
1063                 return;
1064
1065         if(!mapvote_initialized)
1066                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1067                         return;
1068
1069         MapVote_Start();
1070 };
1071
1072 /*
1073 ============
1074 FindIntermission
1075
1076 Returns the entity to view from
1077 ============
1078 */
1079 /*
1080 entity FindIntermission()
1081 {
1082         local   entity spot;
1083         local   float cyc;
1084
1085 // look for info_intermission first
1086         spot = find (world, classname, "info_intermission");
1087         if (spot)
1088         {       // pick a random one
1089                 cyc = random() * 4;
1090                 while (cyc > 1)
1091                 {
1092                         spot = find (spot, classname, "info_intermission");
1093                         if (!spot)
1094                                 spot = find (spot, classname, "info_intermission");
1095                         cyc = cyc - 1;
1096                 }
1097                 return spot;
1098         }
1099
1100 // then look for the start position
1101         spot = find (world, classname, "info_player_start");
1102         if (spot)
1103                 return spot;
1104
1105 // testinfo_player_start is only found in regioned levels
1106         spot = find (world, classname, "testplayerstart");
1107         if (spot)
1108                 return spot;
1109
1110 // then look for the start position
1111         spot = find (world, classname, "info_player_deathmatch");
1112         if (spot)
1113                 return spot;
1114
1115         //objerror ("FindIntermission: no spot");
1116         return world;
1117 };
1118 */
1119
1120 /*
1121 ===============================================================================
1122
1123 RULES
1124
1125 ===============================================================================
1126 */
1127
1128 void DumpStats(float final)
1129 {
1130         local float file;
1131         local string s;
1132         local float to_console;
1133         local float to_eventlog;
1134         local float to_file;
1135         local float i;
1136
1137         to_console = cvar("sv_logscores_console");
1138         to_eventlog = cvar("sv_eventlog");
1139         to_file = cvar("sv_logscores_file");
1140
1141         if(!final)
1142         {
1143                 to_console = TRUE; // always print printstats replies
1144                 to_eventlog = FALSE; // but never print them to the event log
1145         }
1146
1147         if(to_eventlog)
1148                 if(cvar("sv_eventlog_console"))
1149                         to_console = FALSE; // otherwise we get the output twice
1150
1151         if(final)
1152                 s = ":scores:";
1153         else
1154                 s = ":status:";
1155         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1156
1157         if(to_console)
1158                 print(s, "\n");
1159         if(to_eventlog)
1160                 GameLogEcho(s);
1161         if(to_file)
1162         {
1163                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1164                 if(file == -1)
1165                         to_file = FALSE;
1166                 else
1167                         fputs(file, strcat(s, "\n"));
1168         }
1169
1170         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1171         if(to_console)
1172                 print(s, "\n");
1173         if(to_eventlog)
1174                 GameLogEcho(s);
1175         if(to_file)
1176                 fputs(file, strcat(s, "\n"));
1177
1178         FOR_EACH_CLIENT(other)
1179         {
1180                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1181                 {
1182                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1183                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1184                         if(other.classname == "player" || g_arena || g_lms)
1185                                 s = strcat(s, ftos(other.team), ":");
1186                         else
1187                                 s = strcat(s, "spectator:");
1188
1189                         if(to_console)
1190                                 print(s, other.netname, "\n");
1191                         if(to_eventlog)
1192                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1193                         if(to_file)
1194                                 fputs(file, strcat(s, other.netname, "\n"));
1195                 }
1196         }
1197
1198         if(teams_matter)
1199         {
1200                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1201                 if(to_console)
1202                         print(s, "\n");
1203                 if(to_eventlog)
1204                         GameLogEcho(s);
1205                 if(to_file)
1206                         fputs(file, strcat(s, "\n"));
1207
1208                 for(i = 1; i < 16; ++i)
1209                 {
1210                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1211                         s = strcat(s, ":", ftos(i));
1212                         if(to_console)
1213                                 print(s, "\n");
1214                         if(to_eventlog)
1215                                 GameLogEcho(s);
1216                         if(to_file)
1217                                 fputs(file, strcat(s, "\n"));
1218                 }
1219         }
1220
1221         if(to_console)
1222                 print(":end\n");
1223         if(to_eventlog)
1224                 GameLogEcho(":end");
1225         if(to_file)
1226         {
1227                 fputs(file, ":end\n");
1228                 fclose(file);
1229         }
1230 }
1231
1232 void FixIntermissionClient(entity e)
1233 {
1234         string s;
1235         if(!e.autoscreenshot) // initial call
1236         {
1237                 e.angles = e.v_angle;
1238                 e.angles_x = -e.angles_x;
1239                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1240                 e.health = -2342;
1241                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1242                 e.solid = SOLID_NOT;
1243                 e.movetype = MOVETYPE_NONE;
1244                 e.takedamage = DAMAGE_NO;
1245                 if(e.weaponentity)
1246                         e.weaponentity.effects = EF_NODRAW;
1247                 if(clienttype(e) == CLIENTTYPE_REAL)
1248                 {
1249                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1250                         s = cvar_string("sv_intermission_cdtrack");
1251                         if(s != "")
1252                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1253                         msg_entity = e;
1254                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1255                 }
1256         }
1257
1258         //e.velocity = '0 0 0';
1259         //e.fixangle = TRUE;
1260
1261         // TODO halt weapon animation
1262 }
1263
1264
1265 /*
1266 go to the next level for deathmatch
1267 only called if a time or frag limit has expired
1268 */
1269 void NextLevel()
1270 {
1271         float minTotalFrags;
1272         float maxTotalFrags;
1273         float score;
1274         float f;
1275
1276         gameover = TRUE;
1277
1278         intermission_running = 1;
1279
1280 // enforce a wait time before allowing changelevel
1281         if(player_count > 0)
1282                 intermission_exittime = time + cvar("sv_mapchange_delay");
1283         else
1284                 intermission_exittime = -1;
1285
1286         /*
1287         WriteByte (MSG_ALL, SVC_CDTRACK);
1288         WriteByte (MSG_ALL, 3);
1289         WriteByte (MSG_ALL, 3);
1290         // done in FixIntermission
1291         */
1292
1293         //pos = FindIntermission ();
1294
1295         VoteReset();
1296
1297         DumpStats(TRUE);
1298
1299         if(cvar("sv_eventlog"))
1300                 GameLogEcho(":gameover");
1301
1302         GameLogClose();
1303
1304         FOR_EACH_CLIENT(other)
1305         {
1306                 FixIntermissionClient(other);
1307
1308                 if(other.winning)
1309                         bprint(other.netname, " ^7wins.\n");
1310         }
1311
1312         minTotalFrags = 0;
1313         maxTotalFrags = 0;
1314         FOR_EACH_PLAYER(other)
1315         {
1316                 if(maxTotalFrags < other.totalfrags)
1317                         maxTotalFrags = other.totalfrags;
1318                 if(minTotalFrags > other.totalfrags)
1319                         minTotalFrags = other.totalfrags;
1320         }
1321
1322         if(!currentbots)
1323         {
1324                 FOR_EACH_PLAYER(other)
1325                 {
1326                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1327                         f = bound(0, other.play_time / max(time, 1), 1);
1328                         // store some statistics?
1329                 }
1330         }
1331
1332         if(cvar("g_campaign"))
1333                 CampaignPreIntermission();
1334
1335         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1336 };
1337
1338 /*
1339 ============
1340 CheckRules_Player
1341
1342 Exit deathmatch games upon conditions
1343 ============
1344 */
1345 void CheckRules_Player()
1346 {
1347         if (gameover)   // someone else quit the game already
1348                 return;
1349
1350         if(self.deadflag == DEAD_NO)
1351                 self.play_time += frametime;
1352
1353         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1354         //   (div0: and that in CheckRules_World please)
1355 };
1356
1357 float checkrules_oneminutewarning;
1358
1359 float checkrules_equality;
1360 float checkrules_suddendeathwarning;
1361 float checkrules_suddendeathend;
1362 float checkrules_overtimesadded; //how many overtimes have been already added
1363 float checkrules_status;
1364
1365 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1366 float WINNING_YES = 1; // winner found
1367 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1368 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1369
1370 void InitiateOvertime()
1371 {
1372         // Check first whether normal overtimes could be added before initiating suddendeath mode
1373         // - for this timelimit_overtime needs to be >0 of course
1374         // - also check the winning condition calculated in the previous frame and only add normal overtime
1375         //   again, if at the point at which timelimit would be extended again, still no winner was found
1376         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1377         {
1378                 ++checkrules_overtimesadded;
1379                 //add one more overtime by simply extending the timelimit
1380                 float tl;
1381                 tl = cvar("timelimit");
1382                 tl += cvar("timelimit_overtime");
1383                 cvar_set("timelimit", ftos(tl));
1384                 string minutesPlural;
1385                 if (cvar("timelimit_overtime") == 1)
1386                         minutesPlural = " ^3minute";
1387                 else
1388                         minutesPlural = " ^3minutes";
1389
1390                 bcenterprint(
1391                         strcat(
1392                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1393                                 ftos(cvar("timelimit_overtime")),
1394                                 minutesPlural,
1395                                 " to the game!"
1396                         )
1397                 );
1398         }
1399         else
1400         {
1401                 if(!checkrules_suddendeathend)
1402                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1403         }
1404 }
1405
1406 float GetWinningCode(float fraglimitreached, float equality)
1407 {
1408         if(equality)
1409                 if(fraglimitreached)
1410                         return WINNING_STARTSUDDENDEATHOVERTIME;
1411                 else
1412                         return WINNING_NEVER;
1413         else
1414                 if(fraglimitreached)
1415                         return WINNING_YES;
1416                 else
1417                         return WINNING_NO;
1418 }
1419
1420 // set the .winning flag for exactly those players with a given field value
1421 void SetWinners(.float field, float value)
1422 {
1423         entity head;
1424         FOR_EACH_PLAYER(head)
1425                 head.winning = (head.field == value);
1426 }
1427
1428 // set the .winning flag for those players with a given field value
1429 void AddWinners(.float field, float value)
1430 {
1431         entity head;
1432         FOR_EACH_PLAYER(head)
1433                 if(head.field == value)
1434                         head.winning = 1;
1435 }
1436
1437 // clear the .winning flags
1438 void ClearWinners(void)
1439 {
1440         entity head;
1441         FOR_EACH_PLAYER(head)
1442                 head.winning = 0;
1443 }
1444
1445 // Onslaught winning condition:
1446 // game terminates if only one team has a working generator (or none)
1447 float WinningCondition_Onslaught()
1448 {
1449         entity head;
1450         local float t1, t2, t3, t4;
1451
1452         WinningConditionHelper(); // set worldstatus
1453
1454         // first check if the game has ended
1455         t1 = t2 = t3 = t4 = 0;
1456         head = find(world, classname, "onslaught_generator");
1457         while (head)
1458         {
1459                 if (head.health > 0)
1460                 {
1461                         if (head.team == COLOR_TEAM1) t1 = 1;
1462                         if (head.team == COLOR_TEAM2) t2 = 1;
1463                         if (head.team == COLOR_TEAM3) t3 = 1;
1464                         if (head.team == COLOR_TEAM4) t4 = 1;
1465                 }
1466                 head = find(head, classname, "onslaught_generator");
1467         }
1468         if (t1 + t2 + t3 + t4 < 2)
1469         {
1470                 // game over, only one team remains (or none)
1471                 ClearWinners();
1472                 if (t1) SetWinners(team, COLOR_TEAM1);
1473                 if (t2) SetWinners(team, COLOR_TEAM2);
1474                 if (t3) SetWinners(team, COLOR_TEAM3);
1475                 if (t4) SetWinners(team, COLOR_TEAM4);
1476                 dprint("Have a winner, ending game.\n");
1477                 return WINNING_YES;
1478         }
1479
1480         // Two or more teams remain
1481         return WINNING_NO;
1482 }
1483
1484 float LMS_NewPlayerLives()
1485 {
1486         float fl;
1487         fl = cvar("fraglimit");
1488         if(fl == 0)
1489                 fl = 999;
1490
1491         // first player has left the game for dying too much? Nobody else can get in.
1492         if(lms_lowest_lives < 1)
1493                 return 0;
1494
1495         if(!cvar("g_lms_join_anytime"))
1496                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1497                         return 0;
1498
1499         return bound(1, lms_lowest_lives, fl);
1500 }
1501
1502 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1503 // they win. Otherwise the defending team wins once the timelimit passes.
1504 void assault_new_round();
1505 float WinningCondition_Assault()
1506 {
1507         local float status;
1508
1509         WinningConditionHelper(); // set worldstatus
1510
1511         status = WINNING_NO;
1512         // as the timelimit has not yet passed just assume the defending team will win
1513         if(assault_attacker_team == COLOR_TEAM1)
1514         {
1515                 SetWinners(team, COLOR_TEAM2);
1516         }
1517         else
1518         {
1519                 SetWinners(team, COLOR_TEAM1);
1520         }
1521
1522         local entity ent;
1523         ent = find(world, classname, "target_assault_roundend");
1524         if(ent)
1525         {
1526                 if(ent.winning) // round end has been triggered by attacking team
1527                 {
1528                         bprint("ASSAULT: round completed...\n");
1529                         SetWinners(team, assault_attacker_team);
1530
1531                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1532
1533                         if(ent.cnt == 1) // this was the second round
1534                         {
1535                                 status = WINNING_YES;
1536                         }
1537                         else
1538                         {
1539                                 local entity oldself;
1540                                 oldself = self;
1541                                 self = ent;
1542                                 assault_new_round();
1543                                 self = oldself;
1544                         }
1545                 }
1546         }
1547
1548         return status;
1549 }
1550
1551 // LMS winning condition: game terminates if and only if there's at most one
1552 // one player who's living lives. Top two scores being equal cancels the time
1553 // limit.
1554 float WinningCondition_LMS()
1555 {
1556         entity head, head2;
1557         float have_player;
1558         float have_players;
1559         float l;
1560
1561         have_player = FALSE;
1562         have_players = FALSE;
1563         l = LMS_NewPlayerLives();
1564
1565         head = find(world, classname, "player");
1566         if(head)
1567                 have_player = TRUE;
1568         head2 = find(head, classname, "player");
1569         if(head2)
1570                 have_players = TRUE;
1571
1572         if(have_player)
1573         {
1574                 // we have at least one player
1575                 if(have_players)
1576                 {
1577                         // two or more active players - continue with the game
1578                 }
1579                 else
1580                 {
1581                         // exactly one player?
1582
1583                         ClearWinners();
1584                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1585
1586                         if(l)
1587                         {
1588                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1589                                 return WINNING_NO;
1590                         }
1591                         else
1592                         {
1593                                 // a winner!
1594                                 // and assign him his first place
1595                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1596                                 return WINNING_YES;
1597                         }
1598                 }
1599         }
1600         else
1601         {
1602                 // nobody is playing at all...
1603                 if(l)
1604                 {
1605                         // wait for players...
1606                 }
1607                 else
1608                 {
1609                         // SNAFU (maybe a draw game?)
1610                         ClearWinners();
1611                         dprint("No players, ending game.\n");
1612                         return WINNING_YES;
1613                 }
1614         }
1615
1616         // When we get here, we have at least two players who are actually LIVING,
1617         // now check if the top two players have equal score.
1618         WinningConditionHelper();
1619
1620         ClearWinners();
1621         if(WinningConditionHelper_winner)
1622                 WinningConditionHelper_winner.winning = TRUE;
1623         if(WinningConditionHelper_equality)
1624                 return WINNING_NEVER;
1625
1626         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1627         return WINNING_NO;
1628 }
1629
1630 void ShuffleMaplist()
1631 {
1632         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1633 }
1634
1635 float leaderfrags;
1636 float WinningCondition_Scores(float limit)
1637 {
1638         // TODO make everything use THIS winning condition (except LMS)
1639         WinningConditionHelper();
1640
1641         if(teams_matter)
1642         {
1643                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1644                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1645                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1646                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1647         }
1648
1649         ClearWinners();
1650         if(WinningConditionHelper_winner)
1651                 WinningConditionHelper_winner.winning = 1;
1652         if(WinningConditionHelper_winnerteam >= 0)
1653                 SetWinners(team, WinningConditionHelper_winnerteam);
1654
1655         if(WinningConditionHelper_lowerisbetter)
1656         {
1657                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1658                 limit = -limit;
1659         }
1660
1661         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1662         // these modes always score in increments of 1, thus this makes sense
1663         {
1664                 if(leaderfrags != WinningConditionHelper_topscore)
1665                 {
1666                         leaderfrags = WinningConditionHelper_topscore;
1667
1668                         if (limit)
1669                         if (leaderfrags == limit - 1)
1670                                 play2all("announcer/robotic/1fragleft.wav");
1671                         else if (leaderfrags == limit - 2)
1672                                 play2all("announcer/robotic/2fragsleft.wav");
1673                         else if (leaderfrags == limit - 3)
1674                                 play2all("announcer/robotic/3fragsleft.wav");
1675                 }
1676         }
1677
1678         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1679 }
1680
1681 float WinningCondition_Race(float fraglimit)
1682 {
1683         float wc;
1684         entity p;
1685         wc = WinningCondition_Scores(fraglimit);
1686
1687         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1688         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1689         // do NOT support equality when the laps are all raced!
1690         {
1691                 FOR_EACH_PLAYER(p)
1692                         if not(p.race_completed)
1693                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1694                 return WINNING_YES;
1695         }
1696         return wc;
1697 }
1698
1699 void ReadyRestart();
1700 float WinningCondition_QualifyingThenRace(float limit)
1701 {
1702         float wc;
1703         wc = WinningCondition_Scores(limit);
1704
1705         // NEVER initiate overtime
1706         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1707         {
1708                 return WINNING_YES;
1709         }
1710
1711         return wc;
1712 }
1713
1714 float WinningCondition_RanOutOfSpawns()
1715 {
1716         entity head;
1717
1718         if(!have_team_spawns)
1719                 return WINNING_NO;
1720
1721         if(!some_spawn_has_been_used)
1722                 return WINNING_NO;
1723
1724         team1_score = team2_score = team3_score = team4_score = 0;
1725
1726         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1727         {
1728                 if(head.team == COLOR_TEAM1)
1729                         team1_score = 1;
1730                 else if(head.team == COLOR_TEAM2)
1731                         team2_score = 1;
1732                 else if(head.team == COLOR_TEAM3)
1733                         team3_score = 1;
1734                 else if(head.team == COLOR_TEAM4)
1735                         team4_score = 1;
1736         }
1737
1738         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1739         {
1740                 if(head.team == COLOR_TEAM1)
1741                         team1_score = 1;
1742                 else if(head.team == COLOR_TEAM2)
1743                         team2_score = 1;
1744                 else if(head.team == COLOR_TEAM3)
1745                         team3_score = 1;
1746                 else if(head.team == COLOR_TEAM4)
1747                         team4_score = 1;
1748         }
1749
1750         ClearWinners();
1751         if(team1_score + team2_score + team3_score + team4_score == 0)
1752         {
1753                 checkrules_equality = TRUE;
1754                 return WINNING_YES;
1755         }
1756         else if(team1_score + team2_score + team3_score + team4_score == 1)
1757         {
1758                 float t, i;
1759                 if(team1_score) t = COLOR_TEAM1;
1760                 if(team2_score) t = COLOR_TEAM2;
1761                 if(team3_score) t = COLOR_TEAM3;
1762                 if(team4_score) t = COLOR_TEAM4;
1763                 CheckAllowedTeams(world);
1764                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1765                 {
1766                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1767                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1768                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1769                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1770                 }
1771
1772                 AddWinners(team, t);
1773                 return WINNING_YES;
1774         }
1775         else
1776                 return WINNING_NO;
1777 }
1778
1779 /*
1780 ============
1781 CheckRules_World
1782
1783 Exit deathmatch games upon conditions
1784 ============
1785 */
1786 void CheckRules_World()
1787 {
1788         local float timelimit;
1789         local float fraglimit;
1790
1791         VoteThink();
1792         MapVote_Think();
1793
1794         SetDefaultAlpha();
1795
1796         /*
1797         MapVote_Think should now do that part
1798         if (intermission_running)
1799                 if (time >= intermission_exittime + 60)
1800                 {
1801                         if(!DoNextMapOverride())
1802                                 GotoNextMap();
1803                         return;
1804                 }
1805         */
1806
1807         if (gameover)   // someone else quit the game already
1808         {
1809                 if(player_count == 0) // Nobody there? Then let's go to the next map
1810                         MapVote_Start();
1811                         // this will actually check the player count in the next frame
1812                         // again, but this shouldn't hurt
1813                 return;
1814         }
1815
1816         timelimit = cvar("timelimit") * 60;
1817         fraglimit = cvar("fraglimit");
1818
1819         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1820         {
1821                 if(timelimit > 0)
1822                         timelimit = 0; // timelimit is not made for warmup
1823                 if(fraglimit > 0)
1824                         fraglimit = 0; // no fraglimit for now
1825         }
1826
1827         if(timelimit > 0)
1828         {
1829                 timelimit += game_starttime;
1830         }
1831         else if (timelimit < 0)
1832         {
1833                 // endmatch
1834                 NextLevel();
1835                 return;
1836         }
1837
1838         if(checkrules_suddendeathend)
1839         {
1840                 if(!checkrules_suddendeathwarning)
1841                 {
1842                         checkrules_suddendeathwarning = TRUE;
1843                         if(g_race && !g_race_qualifying)
1844                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1845                         else
1846                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1847                 }
1848         }
1849         else
1850         {
1851                 if (timelimit && time >= timelimit)
1852                 {
1853                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1854                         {
1855                                 float totalplayers;
1856                                 float playerswithlaps;
1857                                 float readyplayers;
1858                                 entity head;
1859                                 totalplayers = playerswithlaps = readyplayers = 0;
1860                                 FOR_EACH_PLAYER(head)
1861                                 {
1862                                         ++totalplayers;
1863                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1864                                                 ++playerswithlaps;
1865                                         if(head.ready)
1866                                                 ++readyplayers;
1867                                 }
1868
1869                                 // at least 2/3 of the players have completed a lap: start the RACE
1870                                 // otherwise, the players should end the qualifying on their own
1871                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1872                                 {
1873                                         checkrules_suddendeathend = 0;
1874                                         ReadyRestart(); // go to race
1875                                 }
1876                                 else
1877                                         InitiateOvertime();
1878                         }
1879                         else
1880                                 InitiateOvertime();
1881                 }
1882         }
1883
1884         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1885         {
1886                 NextLevel();
1887                 return;
1888         }
1889
1890         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1891         {
1892                 checkrules_oneminutewarning = TRUE;
1893                 play2all("announcer/robotic/1minuteremains.wav");
1894         }
1895
1896         checkrules_status = WinningCondition_RanOutOfSpawns();
1897         if(checkrules_status == WINNING_YES)
1898         {
1899                 bprint("Hey! Someone ran out of spawns!\n");
1900         }
1901         else if(g_race && !g_race_qualifying && timelimit >= 0)
1902         {
1903                 checkrules_status = WinningCondition_Race(fraglimit);
1904         }
1905         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1906         {
1907                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1908         }
1909         else if(g_assault)
1910         {
1911                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1912         }
1913         else if(g_lms)
1914         {
1915                 checkrules_status = WinningCondition_LMS();
1916         }
1917         else if (g_onslaught)
1918         {
1919                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1920         }
1921         else
1922         {
1923                 checkrules_status = WinningCondition_Scores(fraglimit);
1924         }
1925
1926         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1927         {
1928                 checkrules_status = WINNING_NEVER;
1929                 InitiateOvertime();
1930         }
1931
1932         if(checkrules_status == WINNING_NEVER)
1933                 // equality cases! Nobody wins if the overtime ends in a draw.
1934                 ClearWinners();
1935
1936         if(checkrules_suddendeathend)
1937                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1938                         checkrules_status = WINNING_YES;
1939
1940         if(checkrules_status == WINNING_YES)
1941                 NextLevel();
1942 };
1943
1944 float mapvote_nextthink;
1945 float mapvote_initialized;
1946 float mapvote_keeptwotime;
1947 float mapvote_timeout;
1948 string mapvote_message;
1949 string mapvote_screenshot_dir;
1950
1951 float mapvote_count;
1952 float mapvote_count_real;
1953 string mapvote_maps[MAPVOTE_COUNT];
1954 float mapvote_maps_suggested[MAPVOTE_COUNT];
1955 string mapvote_suggestions[MAPVOTE_COUNT];
1956 float mapvote_suggestion_ptr;
1957 float mapvote_maxlen;
1958 float mapvote_voters;
1959 float mapvote_votes[MAPVOTE_COUNT];
1960 float mapvote_run;
1961 float mapvote_detail;
1962 float mapvote_abstain;
1963 .float mapvote;
1964
1965 void MapVote_ClearAllVotes()
1966 {
1967         FOR_EACH_CLIENT(other)
1968                 other.mapvote = 0;
1969 }
1970
1971 string MapVote_Suggest(string m)
1972 {
1973         float i;
1974         if(m == "")
1975                 return "That's not how to use this command.";
1976         if(!cvar("g_maplist_votable_suggestions"))
1977                 return "Suggestions are not accepted on this server.";
1978         if(mapvote_initialized)
1979                 return "Can't suggest - voting is already in progress!";
1980         m = MapInfo_FixName(m);
1981         if(!m)
1982                 return "The map you suggested is not available on this server.";
1983         if(!cvar("g_maplist_votable_override_mostrecent"))
1984                 if(Map_IsRecent(m))
1985                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1986
1987         if(!MapInfo_CheckMap(m))
1988                 return "The map you suggested does not support the current game mode.";
1989         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1990                 if(mapvote_suggestions[i] == m)
1991                         return "This map was already suggested.";
1992         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1993         {
1994                 i = floor(random() * mapvote_suggestion_ptr);
1995         }
1996         else
1997         {
1998                 i = mapvote_suggestion_ptr;
1999                 mapvote_suggestion_ptr += 1;
2000         }
2001         if(mapvote_suggestions[i] != "")
2002                 strunzone(mapvote_suggestions[i]);
2003         mapvote_suggestions[i] = strzone(m);
2004         if(cvar("sv_eventlog"))
2005                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2006         return strcat("Suggestion of ", m, " accepted.");
2007 }
2008
2009 void MapVote_AddVotable(string nextMap, float isSuggestion)
2010 {
2011         float j;
2012         if(nextMap == "")
2013                 return;
2014         for(j = 0; j < mapvote_count; ++j)
2015                 if(mapvote_maps[j] == nextMap)
2016                         return;
2017         if(strlen(nextMap) > mapvote_maxlen)
2018                 mapvote_maxlen = strlen(nextMap);
2019         mapvote_maps[mapvote_count] = strzone(nextMap);
2020         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2021         mapvote_count += 1;
2022 }
2023
2024 void MapVote_Spawn();
2025 void MapVote_Init()
2026 {
2027         float i;
2028         float nmax, smax;
2029
2030         MapVote_ClearAllVotes();
2031
2032         mapvote_count = 0;
2033         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2034         mapvote_abstain = cvar("g_maplist_votable_abstain");
2035
2036         if(mapvote_abstain)
2037                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2038         else
2039                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2040         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2041
2042         if(mapvote_suggestion_ptr)
2043                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2044                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2045
2046         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2047                 MapVote_AddVotable(GetNextMap(), FALSE);
2048
2049         if(mapvote_count == 0)
2050         {
2051                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2052                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
2053                 if(cvar("g_maplist_shuffle"))
2054                         ShuffleMaplist();
2055                 localcmd("\nmenu_cmd sync\n");
2056                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2057                         MapVote_AddVotable(GetNextMap(), FALSE);
2058         }
2059
2060         mapvote_count_real = mapvote_count;
2061         if(mapvote_abstain)
2062                 MapVote_AddVotable("don't care", 0);
2063
2064         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2065
2066         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2067         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2068         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2069                 mapvote_keeptwotime = 0;
2070         mapvote_message = "Choose a map and press its key!";
2071
2072         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2073         if(mapvote_screenshot_dir == "")
2074                 mapvote_screenshot_dir = "maps";
2075         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2076
2077         MapVote_Spawn();
2078 }
2079
2080 void MapVote_SendPicture(float id)
2081 {
2082         msg_entity = self;
2083         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2084         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2085         WriteByte(MSG_ONE, id);
2086         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2087 }
2088
2089 float GameCommand_MapVote(string cmd)
2090 {
2091         if(!intermission_running)
2092                 return FALSE;
2093
2094         if(cmd == "mv_getpic")
2095         {
2096                 MapVote_SendPicture(stof(argv(1)));
2097                 return TRUE;
2098         }
2099
2100         return FALSE;
2101 }
2102
2103 float MapVote_GetMapMask()
2104 {
2105         float mask, i, power;
2106         mask = 0;
2107         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2108                 if(mapvote_maps[i] != "")
2109                         mask |= power;
2110         return mask;
2111 }
2112
2113 entity mapvote_ent;
2114 float MapVote_SendEntity(entity to, float sf)
2115 {
2116         string mapfile, pakfile;
2117         float i, o;
2118
2119         if(sf & 1)
2120                 sf &~= 2; // if we send 1, we don't need to also send 2
2121
2122         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2123         WriteByte(MSG_ENTITY, sf);
2124
2125         if(sf & 1)
2126         {
2127                 // flag 1 == initialization
2128                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2129                 WriteByte(MSG_ENTITY, mapvote_count);
2130                 WriteByte(MSG_ENTITY, mapvote_abstain);
2131                 WriteByte(MSG_ENTITY, mapvote_detail);
2132                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2133                 if(mapvote_count <= 8)
2134                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2135                 else
2136                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2137                 for(i = 0; i < mapvote_count; ++i)
2138                         if(mapvote_maps[i] != "")
2139                         {
2140                                 if(mapvote_abstain && i == mapvote_count - 1)
2141                                 {
2142                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2143                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2144                                 }
2145                                 else
2146                                 {
2147                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2148                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2149                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2150                                         if(pakfile == "")
2151                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2152                                         if(pakfile == "")
2153                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2154                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2155                                                 pakfile = substring(pakfile, o, 999);
2156                                         WriteString(MSG_ENTITY, pakfile);
2157                                 }
2158                         }
2159         }
2160
2161         if(sf & 2)
2162         {
2163                 // flag 2 == update of mask
2164                 if(mapvote_count <= 8)
2165                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2166                 else
2167                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2168         }
2169
2170         if(sf & 4)
2171         {
2172                 if(mapvote_detail)
2173                         for(i = 0; i < mapvote_count; ++i)
2174                                 if(mapvote_maps[i] != "")
2175                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2176
2177                 WriteByte(MSG_ENTITY, to.mapvote);
2178         }
2179
2180         return TRUE;
2181 }
2182
2183 void MapVote_Spawn()
2184 {
2185         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2186 }
2187
2188 void MapVote_TouchMask()
2189 {
2190         mapvote_ent.SendFlags |= 2;
2191 }
2192
2193 void MapVote_TouchVotes(entity voter)
2194 {
2195         mapvote_ent.SendFlags |= 4;
2196 }
2197
2198 float MapVote_Finished(float mappos)
2199 {
2200         string result;
2201         float i;
2202         float didntvote;
2203
2204         if(cvar("sv_eventlog"))
2205         {
2206                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2207                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2208                 didntvote = mapvote_voters;
2209                 for(i = 0; i < mapvote_count; ++i)
2210                         if(mapvote_maps[i] != "")
2211                         {
2212                                 didntvote -= mapvote_votes[i];
2213                                 if(i != mappos)
2214                                 {
2215                                         result = strcat(result, ":", mapvote_maps[i]);
2216                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2217                                 }
2218                         }
2219                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2220
2221                 GameLogEcho(result);
2222                 if(mapvote_maps_suggested[mappos])
2223                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2224         }
2225
2226         FOR_EACH_REALCLIENT(other)
2227                 FixClientCvars(other);
2228
2229         Map_Goto_SetStr(mapvote_maps[mappos]);
2230         Map_Goto();
2231         alreadychangedlevel = TRUE;
2232         return TRUE;
2233 }
2234 void MapVote_CheckRules_1()
2235 {
2236         float i;
2237
2238         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2239         {
2240                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2241                 mapvote_votes[i] = 0;
2242         }
2243
2244         mapvote_voters = 0;
2245         FOR_EACH_REALCLIENT(other)
2246         {
2247                 ++mapvote_voters;
2248                 if(other.mapvote)
2249                 {
2250                         i = other.mapvote - 1;
2251                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2252                         mapvote_votes[i] = mapvote_votes[i] + 1;
2253                 }
2254         }
2255 }
2256
2257 float MapVote_CheckRules_2()
2258 {
2259         float i;
2260         float firstPlace, secondPlace;
2261         float firstPlaceVotes, secondPlaceVotes;
2262         float mapvote_voters_real;
2263         string result;
2264
2265         mapvote_voters_real = mapvote_voters;
2266         if(mapvote_abstain)
2267                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2268
2269         RandomSelection_Init();
2270         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2271                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2272         firstPlace = RandomSelection_chosen_float;
2273         firstPlaceVotes = RandomSelection_best_priority;
2274         //dprint("First place: ", ftos(firstPlace), "\n");
2275         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2276
2277         RandomSelection_Init();
2278         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2279                 if(i != firstPlace)
2280                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2281         secondPlace = RandomSelection_chosen_float;
2282         secondPlaceVotes = RandomSelection_best_priority;
2283         //dprint("Second place: ", ftos(secondPlace), "\n");
2284         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2285
2286         if(firstPlace == -1)
2287                 error("No first place in map vote... WTF?");
2288
2289         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2290                 return MapVote_Finished(firstPlace);
2291
2292         if(mapvote_keeptwotime)
2293                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2294                 {
2295                         float didntvote;
2296                         MapVote_TouchMask();
2297                         mapvote_message = "Now decide between the TOP TWO!";
2298                         mapvote_keeptwotime = 0;
2299                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2300                         result = strcat(result, ":", ftos(firstPlaceVotes));
2301                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2302                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2303                         didntvote = mapvote_voters;
2304                         for(i = 0; i < mapvote_count; ++i)
2305                                 if(mapvote_maps[i] != "")
2306                                 {
2307                                         didntvote -= mapvote_votes[i];
2308                                         if(i != firstPlace)
2309                                                 if(i != secondPlace)
2310                                                 {
2311                                                         result = strcat(result, ":", mapvote_maps[i]);
2312                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2313                                                         if(i < mapvote_count_real)
2314                                                         {
2315                                                                 strunzone(mapvote_maps[i]);
2316                                                                 mapvote_maps[i] = "";
2317                                                         }
2318                                                 }
2319                                 }
2320                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2321                         if(cvar("sv_eventlog"))
2322                                 GameLogEcho(result);
2323                 }
2324
2325         return FALSE;
2326 }
2327 void MapVote_Tick()
2328 {
2329         float keeptwo;
2330         float totalvotes;
2331
2332         keeptwo = mapvote_keeptwotime;
2333         MapVote_CheckRules_1(); // count
2334         if(MapVote_CheckRules_2()) // decide
2335                 return;
2336
2337         totalvotes = 0;
2338         FOR_EACH_REALCLIENT(other)
2339         {
2340                 // hide scoreboard again
2341                 if(other.health != 2342)
2342                 {
2343                         other.health = 2342;
2344                         other.impulse = 0;
2345                         if(clienttype(other) == CLIENTTYPE_REAL)
2346                         {
2347                                 msg_entity = other;
2348                                 WriteByte(MSG_ONE, SVC_FINALE);
2349                                 WriteString(MSG_ONE, "");
2350                         }
2351                 }
2352
2353                 // clear possibly invalid votes
2354                 if(mapvote_maps[other.mapvote - 1] == "")
2355                         other.mapvote = 0;
2356                 // use impulses as new vote
2357                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2358                         if(mapvote_maps[other.impulse - 1] != "")
2359                         {
2360                                 other.mapvote = other.impulse;
2361                                 MapVote_TouchVotes(other);
2362                         }
2363                 other.impulse = 0;
2364
2365                 if(other.mapvote)
2366                         ++totalvotes;
2367         }
2368
2369         MapVote_CheckRules_1(); // just count
2370 }
2371 void MapVote_Start()
2372 {
2373         if(mapvote_run)
2374                 return;
2375
2376         MapInfo_Enumerate();
2377         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1))
2378                 mapvote_run = TRUE;
2379 }
2380 void MapVote_Think()
2381 {
2382         if(!mapvote_run)
2383                 return;
2384
2385         if(alreadychangedlevel)
2386                 return;
2387
2388         if(time < mapvote_nextthink)
2389                 return;
2390         //dprint("tick\n");
2391
2392         mapvote_nextthink = time + 0.5;
2393
2394         if(!mapvote_initialized)
2395         {
2396                 mapvote_initialized = TRUE;
2397                 if(DoNextMapOverride())
2398                         return;
2399                 if(!cvar("g_maplist_votable") || player_count <= 0)
2400                 {
2401                         GotoNextMap();
2402                         return;
2403                 }
2404                 MapVote_Init();
2405         }
2406
2407         MapVote_Tick();
2408 };
2409
2410 string GotoMap(string m)
2411 {
2412         if(!MapInfo_CheckMap(m))
2413                 return "The map you chose is not available on this server.";
2414         cvar_set("nextmap", m);
2415         cvar_set("timelimit", "-1");
2416         if(mapvote_initialized || alreadychangedlevel)
2417         {
2418                 if(DoNextMapOverride())
2419                         return "Map switch initiated.";
2420                 else
2421                         return "Hm... no. For some reason I like THIS map more.";
2422         }
2423         else
2424                 return "Map switch will happen after scoreboard.";
2425 }
2426
2427
2428 void EndFrame()
2429 {
2430         FOR_EACH_REALCLIENT(self)
2431         {
2432                 if(self.classname == "spectator")
2433                 {
2434                         if(self.enemy.typehitsound)
2435                                 play2(self, "misc/typehit.wav");
2436                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2437                                 play2(self, "misc/hit.wav");
2438                 }
2439                 else
2440                 {
2441                         if(self.typehitsound)
2442                                 play2(self, "misc/typehit.wav");
2443                         else if(self.hitsound && self.cvar_cl_hitsound)
2444                                 play2(self, "misc/hit.wav");
2445                 }
2446         }
2447         FOR_EACH_CLIENT(self)
2448         {
2449                 self.hitsound = FALSE;
2450                 self.typehitsound = FALSE;
2451         }
2452 }
2453
2454
2455 /*
2456  * RedirectionThink:
2457  * returns TRUE if redirecting
2458  */
2459 float redirection_timeout;
2460 float redirection_nextthink;
2461 float RedirectionThink()
2462 {
2463         float clients_found;
2464
2465         if(redirection_target == "")
2466                 return FALSE;
2467
2468         if(!redirection_timeout)
2469         {
2470                 cvar_set("sv_public", "-2");
2471                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2472                 if(redirection_target == "self")
2473                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2474                 else
2475                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2476         }
2477
2478         if(time < redirection_nextthink)
2479                 return TRUE;
2480
2481         redirection_nextthink = time + 1;
2482
2483         clients_found = 0;
2484         FOR_EACH_REALCLIENT(self)
2485         {
2486                 print("Redirecting: sending connect command to ", self.netname, "\n");
2487                 if(redirection_target == "self")
2488                         stuffcmd(self, "\ndisconnect; reconnect\n");
2489                 else
2490                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2491                 ++clients_found;
2492         }
2493
2494         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2495
2496         if(time > redirection_timeout || clients_found == 0)
2497                 localcmd("\nwait; wait; wait; quit\n");
2498
2499         return TRUE;
2500 }
2501
2502 void RestoreGame()
2503 {
2504         // Loaded from a save game
2505         // some things then break, so let's work around them...
2506
2507         // Progs DB (capture records)
2508         if(sv_cheats)
2509                 ServerProgsDB = db_create();
2510         else
2511                 ServerProgsDB = db_load("server.db");
2512
2513         // Mapinfo
2514         MapInfo_Shutdown();
2515         MapInfo_Enumerate();
2516         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
2517 }
2518
2519 void SV_Shutdown()
2520 {
2521         if(world_initialized > 0)
2522         {
2523                 world_initialized = 0;
2524                 print("Saving persistent data...\n");
2525                 Ban_SaveBans();
2526                 if(!sv_cheats)
2527                         db_save(ServerProgsDB, "server.db");
2528                 if(cvar("developer"))
2529                         db_save(TemporaryDB, "server-temp.db");
2530                 db_close(ServerProgsDB);
2531                 db_close(TemporaryDB);
2532                 print("done!\n");
2533                 // tell the bot system the game is ending now
2534                 bot_endgame();
2535
2536                 MapInfo_Shutdown();
2537         }
2538         else if(world_initialized == 0)
2539         {
2540                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2541         }
2542 }