data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         //reset all the flood variables
  83                         FOR_EACH_CLIENT(plr) {
  84                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
  85                         }
  86                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  87                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  88                         FOR_EACH_REALPLAYER(plr) {
  89                                 plr.lastV_angle = plr.v_angle;
  90                         }
  91                         self.nextthink = time;
  92                 }
  93         }
  94         else if (timeoutStatus == 2) {
  95                 if (remainingTimeoutTime > 0) {
  96                         timeStr = getTimeoutText(0);
  97                         FOR_EACH_REALCLIENT(plr) {
  98                                 if(plr.classname == "player") {
  99                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 100                                 }
 101                         }
 102                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 103                                 play2all("announcer/robotic/prepareforbattle.wav");
 104                         }
 105                         remainingTimeoutTime -= 1;
 106                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 107                 }
 108                 else {
 109                         //unpause the game again
 110                         remainingTimeoutTime = timeoutStatus = 0;
 111                         cvar_set("slowmo", ftos(orig_slowmo));
 112                         //and unlock the fixed view again once there is no timeout active anymore
 113                         FOR_EACH_REALPLAYER(plr) {
 114                                 plr.fixangle = FALSE;
 115                         }
 116                         //get rid of the countdown message
 117                         FOR_EACH_REALCLIENT(plr) {
 118                                 if(plr.classname == "player") {
 119                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 120                                 }
 121                         }
 122                         remove(self);
 123                         return;
 124                 }
 125
 126         }
 127         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 128                 FOR_EACH_REALCLIENT(plr) {
 129                         if(plr.classname == "player") {
 130                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 131                         }
 132                 }
 133                 remove(self);
 134                 return;
 135         }
 136 }
 137
 138 void GotoFirstMap()
 139 {
 140         float n;
 141         if(cvar("_sv_init"))
 142         {
 143                 // cvar_set("_sv_init", "0");
 144                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 145                 // to this "init" map on a dedicated server will cause no permanent
 146                 // harm
 147                 if(cvar("g_maplist_shuffle"))
 148                         ShuffleMaplist();
 149                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 150                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 151
 152                 MapInfo_Enumerate();
 153                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 154
 155                 if(!DoNextMapOverride())
 156                         GotoNextMap();
 157
 158                 return;
 159         }
 160
 161         if(time < 5)
 162         {
 163                 self.nextthink = time;
 164         }
 165         else
 166         {
 167                 self.nextthink = time + 1;
 168                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 169         }
 170 }
 171
 172 void cvar_changes_init()
 173 {
 174         float h;
 175         string k, v, d;
 176         float n, i;
 177
 178         if(cvar_changes)
 179                 strunzone(cvar_changes);
 180         cvar_changes = string_null;
 181
 182         h = buf_create();
 183         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 184         n = buf_getsize(h);
 185
 186         for(i = 0; i < n; ++i)
 187         {
 188                 k = bufstr_get(h, i);
 189
 190 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 191 #define BADCVAR(p) if(k == p) continue
 192                 // internal
 193                 BADPREFIX("csqc_");
 194                 BADPREFIX("cvar_check_");
 195                 BADCVAR("gamecfg");
 196                 BADCVAR("g_configversion");
 197                 BADCVAR("g_maplist_index");
 198                 BADCVAR("halflifebsp");
 199
 200                 // client
 201                 BADPREFIX("cl_");
 202                 BADPREFIX("con_");
 203                 BADPREFIX("g_campaign");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("userbind");
 212                 BADPREFIX("v_");
 213                 BADPREFIX("vid_");
 214                 BADPREFIX("crosshair");
 215                 BADCVAR("mod_q3bsp_lightmapmergepower");
 216                 BADCVAR("mod_q3bsp_nolightmaps");
 217
 218                 // private
 219                 BADPREFIX("g_ban_");
 220                 BADPREFIX("g_chat_flood_");
 221                 BADPREFIX("g_voice_flood_");
 222                 BADPREFIX("rcon_");
 223                 BADPREFIX("settemp_");
 224                 BADPREFIX("sv_allowdownloads_");
 225                 BADPREFIX("sv_autodemo");
 226                 BADPREFIX("sv_curl_");
 227                 BADPREFIX("sv_eventlog");
 228                 BADPREFIX("sv_logscores_");
 229                 BADPREFIX("sv_master");
 230                 BADCVAR("g_banned_list");
 231                 BADCVAR("log_dest_udp");
 232                 BADCVAR("log_file");
 233                 BADCVAR("net_address");
 234                 BADCVAR("port");
 235                 BADCVAR("savedgamecfg");
 236                 BADCVAR("sv_heartbeatperoid");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timestamps");
 241
 242                 // mapinfo
 243                 BADCVAR("timelimit");
 244                 BADCVAR("fraglimit");
 245                 BADCVAR("g_arena");
 246                 BADCVAR("g_assault");
 247                 BADCVAR("g_ctf");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_keyhunt");
 251                 BADCVAR("g_keyhunt_teams");
 252                 BADCVAR("g_onslaught");
 253                 BADCVAR("g_race");
 254                 BADCVAR("g_runematch");
 255                 BADCVAR("g_tdm");
 256                 BADCVAR("teamplay");
 257
 258                 // long
 259                 BADCVAR("hostname");
 260                 BADCVAR("g_maplist");
 261                 BADCVAR("g_maplist_mostrecent");
 262                 BADCVAR("sv_motd");
 263 #undef BADPREFIX
 264 #undef BADCVAR
 265
 266                 v = cvar_string(k);
 267                 d = cvar_defstring(k);
 268                 if(v != d)
 269                 {
 270                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 271                         if(strlen(cvar_changes) > 16384)
 272                         {
 273                                 cvar_changes = "// too many settings have been changed to show them here\n";
 274                                 break;
 275                         }
 276                 }
 277         }
 278         buf_del(h);
 279         if(cvar_changes == "")
 280                 cvar_changes = "// this server runs at default settings\n";
 281         else
 282                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 283         cvar_changes = strzone(cvar_changes);
 284 }
 285
 286 void detect_maptype()
 287 {
 288 #if 0
 289         vector o, v;
 290         float i;
 291
 292         for(;;)
 293         {
 294                 o = world.mins;
 295                 o_x += random() * (world.maxs_x - world.mins_x);
 296                 o_y += random() * (world.maxs_y - world.mins_y);
 297                 o_z += random() * (world.maxs_z - world.mins_z);
 298
 299                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 300                 if(trace_fraction == 1)
 301                         continue;
 302
 303                 v = trace_endpos;
 304
 305                 for(i = 0; i < 64; i += 4)
 306                 {
 307                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 308         if(trace_fraction == 1)
 309                 continue;
 310                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 311                 }
 312
 313                 break;
 314         }
 315 #endif
 316 }
 317
 318 entity randomseed;
 319 float RandomSeed_Send(entity to, float sf)
 320 {
 321         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 322         WriteShort(MSG_ENTITY, self.cnt);
 323         return TRUE;
 324 }
 325 void RandomSeed_Think()
 326 {
 327         self.cnt = bound(0, floor(random() * 65536), 65535);
 328         self.nextthink = time + 5;
 329
 330         self.SendFlags |= 1;
 331 }
 332 void RandomSeed_Spawn()
 333 {
 334         randomseed = spawn();
 335         randomseed.think = RandomSeed_Think;
 336         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 337
 338         entity oldself;
 339         oldself = self;
 340         self = randomseed;
 341         self.think(); // sets random seed and nextthink
 342         self = oldself;
 343 }
 344
 345 void spawnfunc___init_dedicated_server(void)
 346 {
 347         // handler for _init/_init map (only for dedicated server initialization)
 348
 349         world_initialized = -1; // don't complain
 350         cvar = cvar_builtin;
 351         cvar_string = cvar_string_builtin;
 352         cvar_set = cvar_set_builtin;
 353         dprint_load(); // load dprint status from cvar
 354
 355         remove = remove_unsafely;
 356
 357         entity e;
 358         e = spawn();
 359         e.think = GotoFirstMap;
 360         e.nextthink = time; // this is usually 1 at this point
 361
 362         e = spawn();
 363         e.classname = "info_player_deathmatch"; // safeguard against player joining
 364
 365         self.classname = "worldspawn"; // safeguard against various stuff ;)
 366
 367         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 368         MapInfo_Enumerate();
 369         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 370 }
 371
 372 void Map_MarkAsRecent(string m);
 373 float world_already_spawned;
 374 void RegisterWeapons();
 375 void Nagger_Init();
 376 void ClientInit_Spawn();
 377 void spawnfunc_worldspawn (void)
 378 {
 379         float fd, l, i, j, n;
 380         string s, col;
 381
 382         cvar = cvar_builtin;
 383         cvar_string = cvar_string_builtin;
 384         cvar_set = cvar_set_builtin;
 385         dprint_load(); // load dprint status from cvar
 386
 387         if(world_already_spawned)
 388                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 389         world_already_spawned = TRUE;
 390
 391         remove = remove_safely; // during spawning, watch what you remove!
 392
 393         check_unacceptable_compiler_bugs();
 394
 395         if(cvar_string("cvar_check_default") != "bypass")
 396         {
 397                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 398                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 399
 400                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 401                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 402         }
 403
 404         compressShortVector_init();
 405
 406         local entity head;
 407         head = nextent(world);
 408         maxclients = 0;
 409         while(head)
 410         {
 411                 ++maxclients;
 412                 head = nextent(head);
 413         }
 414
 415         // needs to be done so early as they would still spawn
 416         RegisterWeapons();
 417
 418         if(sv_cheats)
 419                 ServerProgsDB = db_create();
 420         else
 421                 ServerProgsDB = db_load("server.db");
 422
 423         TemporaryDB = db_create();
 424
 425         /*
 426         TODO sound pack system
 427         // initialize sound pack system
 428         soundpack = cvar_string("g_soundpack");
 429         if(soundpack != "")
 430                 soundpack = strcat(soundpack, "/");
 431         soundpack = strzone(soundpack);
 432         */
 433
 434         // 0 normal
 435         lightstyle(0, "m");
 436
 437         // 1 FLICKER (first variety)
 438         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 439
 440         // 2 SLOW STRONG PULSE
 441         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 442
 443         // 3 CANDLE (first variety)
 444         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 445
 446         // 4 FAST STROBE
 447         lightstyle(4, "mamamamamama");
 448
 449         // 5 GENTLE PULSE 1
 450         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 451
 452         // 6 FLICKER (second variety)
 453         lightstyle(6, "nmonqnmomnmomomno");
 454
 455         // 7 CANDLE (second variety)
 456         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 457
 458         // 8 CANDLE (third variety)
 459         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 460
 461         // 9 SLOW STROBE (fourth variety)
 462         lightstyle(9, "aaaaaaaazzzzzzzz");
 463
 464         // 10 FLUORESCENT FLICKER
 465         lightstyle(10, "mmamammmmammamamaaamammma");
 466
 467         // 11 SLOW PULSE NOT FADE TO BLACK
 468         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 469
 470         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 471
 472         // 63 testing
 473         lightstyle(63, "a");
 474
 475         if(cvar("g_campaign"))
 476                 CampaignPreInit();
 477
 478         Map_MarkAsRecent(mapname);
 479
 480         precache_model ("null"); // we need this one before InitGameplayMode
 481         InitGameplayMode();
 482         readlevelcvars();
 483         GrappleHookInit();
 484
 485         player_count = 0;
 486         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 487         if(bot_waypoints_for_items == 1)
 488                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 489                         bot_waypoints_for_items = 0;
 490
 491         // for setting by mapinfo
 492         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 493         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 494
 495         precache();
 496
 497         WaypointSprite_Init();
 498
 499         //if (g_domination)
 500         //      dom_init();
 501
 502         GameLogInit(); // prepare everything
 503         if(cvar("sv_eventlog"))
 504         {
 505                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 506                 s = strcat(s, ftos(random()));
 507                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 508                 s = ":gameinfo:mutators:LIST";
 509                 if(cvar("g_grappling_hook"))
 510                         s = strcat(s, ":grappling_hook");
 511                 if(!cvar("g_use_ammunition"))
 512                         s = strcat(s, ":no_use_ammunition");
 513                 if(!cvar("g_pickup_items"))
 514                         s = strcat(s, ":no_pickup_items");
 515                 if(cvar("g_instagib"))
 516                         s = strcat(s, ":instagib");
 517                 if(cvar_string("g_weaponarena") != "0")
 518                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 519                 if(cvar("g_nixnex"))
 520                         s = strcat(s, ":nixnex");
 521                 if(cvar("g_vampire"))
 522                         s = strcat(s, ":vampire");
 523                 if(cvar("g_laserguided_missile"))
 524                         s = strcat(s, ":laserguided_missile");
 525                 if(cvar("g_norecoil"))
 526                         s = strcat(s, ":norecoil");
 527                 if(cvar("g_midair"))
 528                         s = strcat(s, ":midair");
 529                 if(cvar("g_minstagib"))
 530                         s = strcat(s, ":minstagib");
 531                 GameLogEcho(s);
 532                 GameLogEcho(":gameinfo:end");
 533         }
 534
 535         cvar_set("nextmap", "");
 536
 537         SetDefaultAlpha();
 538
 539         if(cvar("g_campaign"))
 540                 CampaignPostInit();
 541
 542         fteqcc_testbugs();
 543
 544         Ban_LoadBans();
 545
 546         //initialise globals related to sv_timeout
 547         sys_ticrate = cvar("sys_ticrate");
 548         orig_slowmo = cvar("slowmo");
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
 552
 553         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 554         {
 555                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 556                 if(fd != -1)
 557                 {
 558                         while((s = fgets(fd)))
 559                         {
 560                                 l = tokenize_console(s);
 561                                 if(l < 2)
 562                                         continue;
 563                                 if(argv(0) == "cd")
 564                                 {
 565                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 566                                         print("  cdtrack ", argv(2), "\n");
 567                                 }
 568                                 else if(argv(0) == "fog")
 569                                 {
 570                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 571                                         print("  \"fog\" \"", s, "\"\n");
 572                                 }
 573                                 else if(argv(0) == "set")
 574                                 {
 575                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 576                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 577                                 }
 578                                 else if(argv(0) != "//")
 579                                 {
 580                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 581                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 582                                 }
 583                         }
 584                         fclose(fd);
 585                 }
 586         }
 587
 588         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 589         addstat(STAT_WEAPONS, AS_INT, weapons);
 590         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 591         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 592         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 593         Nagger_Init();
 594
 595         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 596         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 597         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 598         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 599         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 600
 601         next_pingtime = time + 5;
 602         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 603
 604         detect_maptype();
 605
 606         lsmaps_reply = "^7Maps available: ";
 607         for(i = 0, j = 0; i < MapInfo_count; ++i)
 608         {
 609                 if(MapInfo_Get_ByID(i))
 610                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 611                         {
 612                                 if(mod(i, 2))
 613                                         col = "^2";
 614                                 else
 615                                         col = "^3";
 616                                 ++j;
 617                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 618                         }
 619         }
 620         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 621
 622         maplist_reply = "^7Maps in list: ";
 623         n = tokenize_console(cvar_string("g_maplist"));
 624         for(i = 0, j = 0; i < n; ++i)
 625         {
 626                 if(MapInfo_CheckMap(argv(i)))
 627                 {
 628                         if(mod(j, 2))
 629                                 col = "^2";
 630                         else
 631                                 col = "^3";
 632                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 633                         ++j;
 634                 }
 635         }
 636         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 637         MapInfo_ClearTemps();
 638
 639         records_reply = strzone(getrecords());
 640
 641         ClientInit_Spawn();
 642         RandomSeed_Spawn();
 643
 644         world_initialized = 1;
 645 }
 646
 647 void spawnfunc_light (void)
 648 {
 649         //makestatic (self); // Who the f___ did that?
 650         remove(self);
 651 }
 652
 653 float TryFile( string pFilename )
 654 {
 655         local float lHandle;
 656         dprint("TryFile(\"", pFilename, "\")\n");
 657         lHandle = fopen( pFilename, FILE_READ );
 658         if( lHandle != -1 ) {
 659                 fclose( lHandle );
 660                 return TRUE;
 661         } else {
 662                 return FALSE;
 663         }
 664 };
 665
 666 string GetGametype()
 667 {
 668         return GametypeNameFromType(game);
 669 }
 670
 671 string getmapname_stored;
 672 string GetMapname()
 673 {
 674         return mapname;
 675 }
 676
 677 float Map_Count, Map_Current;
 678 string Map_Current_Name;
 679
 680 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 681 float GetMaplistPosition()
 682 {
 683         float pos, idx;
 684         string map;
 685
 686         map = GetMapname();
 687         idx = cvar("g_maplist_index");
 688
 689         if(idx >= 0)
 690                 if(idx < Map_Count)
 691                         if(map == argv(idx))
 692                                 return idx;
 693
 694         for(pos = 0; pos < Map_Count; ++pos)
 695                 if(map == argv(pos))
 696                         return pos;
 697
 698         // resume normal maplist rotation if current map is not in g_maplist
 699         return idx;
 700 }
 701
 702 float MapHasRightSize(string map)
 703 {
 704         float fh;
 705         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 706         if(cvar("g_maplist_check_waypoints"))
 707         {
 708                 dprint("checkwp "); dprint(map);
 709                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 710                 if(fh < 0)
 711                 {
 712                         dprint(": no waypoints\n");
 713                         return FALSE;
 714                 }
 715                 dprint(": has waypoints\n");
 716                 fclose(fh);
 717         }
 718
 719         // open map size restriction file
 720         dprint("opensize "); dprint(map);
 721         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 722         if(fh >= 0)
 723         {
 724                 float mapmin, mapmax;
 725                 dprint(": ok, ");
 726                 mapmin = stof(fgets(fh));
 727                 mapmax = stof(fgets(fh));
 728                 fclose(fh);
 729                 if(player_count < mapmin)
 730                 {
 731                         dprint("not enough\n");
 732                         return FALSE;
 733                 }
 734                 if(player_count > mapmax)
 735                 {
 736                         dprint("too many\n");
 737                         return FALSE;
 738                 }
 739                 dprint("right size\n");
 740                 return TRUE;
 741         }
 742         dprint(": not found\n");
 743         return TRUE;
 744 }
 745
 746 string Map_Filename(float position)
 747 {
 748         return strcat("maps/", argv(position), ".bsp");
 749 }
 750
 751 string strwords(string s, float w)
 752 {
 753         float endpos;
 754         for(endpos = 0; w && endpos >= 0; --w)
 755                 endpos = strstrofs(s, " ", endpos + 1);
 756         if(endpos < 0)
 757                 return s;
 758         else
 759                 return substring(s, 0, endpos);
 760 }
 761
 762 float strhasword(string s, string w)
 763 {
 764         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 765 }
 766
 767 void Map_MarkAsRecent(string m)
 768 {
 769         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 770 }
 771
 772 float Map_IsRecent(string m)
 773 {
 774         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 775 }
 776
 777 float Map_Check(float position, float pass)
 778 {
 779         string filename;
 780         string map_next;
 781         map_next = argv(position);
 782         if(pass <= 1)
 783         {
 784                 if(Map_IsRecent(map_next))
 785                         return 0;
 786         }
 787         filename = Map_Filename(position);
 788         if(MapInfo_CheckMap(map_next))
 789         {
 790                 if(pass == 2)
 791                         return 1;
 792                 if(MapHasRightSize(map_next))
 793                         return 1;
 794                 return 0;
 795         }
 796         else
 797                 dprint( "Couldn't select '", filename, "'..\n" );
 798
 799         return 0;
 800 }
 801
 802 void Map_Goto_SetStr(string nextmapname)
 803 {
 804         if(getmapname_stored != "")
 805                 strunzone(getmapname_stored);
 806         if(nextmapname == "")
 807                 getmapname_stored = "";
 808         else
 809                 getmapname_stored = strzone(nextmapname);
 810 }
 811
 812 void Map_Goto_SetFloat(float position)
 813 {
 814         cvar_set("g_maplist_index", ftos(position));
 815         Map_Goto_SetStr(argv(position));
 816 }
 817
 818 void GameResetCfg()
 819 {
 820         // settings persist, except...
 821         localcmd("\nsettemp_restore\n");
 822 };
 823
 824 void Map_Goto()
 825 {
 826         GameResetCfg();
 827         MapInfo_LoadMap(getmapname_stored);
 828 }
 829
 830 // return codes of map selectors:
 831 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 832 //   -2 = permanent failure
 833 float() MaplistMethod_Iterate = // usual method
 834 {
 835         float pass, i;
 836
 837         for(pass = 1; pass <= 2; ++pass)
 838         {
 839                 for(i = 1; i < Map_Count; ++i)
 840                 {
 841                         float mapindex;
 842                         mapindex = mod(i + Map_Current, Map_Count);
 843                         if(Map_Check(mapindex, pass))
 844                                 return mapindex;
 845                 }
 846         }
 847         return -1;
 848 }
 849
 850 float() MaplistMethod_Repeat = // fallback method
 851 {
 852         if(Map_Check(Map_Current, 2))
 853                 return Map_Current;
 854         return -2;
 855 }
 856
 857 float() MaplistMethod_Random = // random map selection
 858 {
 859         float i, imax;
 860
 861         imax = 42;
 862
 863         for(i = 0; i <= imax; ++i)
 864         {
 865                 float mapindex;
 866                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 867                 if(Map_Check(mapindex, 1))
 868                         return mapindex;
 869         }
 870         return -1;
 871 }
 872
 873 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 874 // the exponent sets a bias on the map selection:
 875 // the higher the exponent, the less likely "shortly repeated" same maps are
 876 {
 877         float i, j, imax, insertpos;
 878
 879         imax = 42;
 880
 881         for(i = 0; i <= imax; ++i)
 882         {
 883                 string newlist;
 884
 885                 // now reinsert this at another position
 886                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 887                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 888                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 889                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 890
 891                 // insert the current map there
 892                 newlist = "";
 893                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 894                         newlist = strcat(newlist, " ", argv(j));
 895                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 896                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 897                         newlist = strcat(newlist, " ", argv(j));
 898                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 899                 cvar_set("g_maplist", newlist);
 900                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 901
 902                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 903                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 904                 if(Map_Check(Map_Current, 1))
 905                         return Map_Current;
 906         }
 907         return -1;
 908 }
 909
 910 void Maplist_Init()
 911 {
 912         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 913         if(Map_Count == 0)
 914         {
 915                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 916                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
 917                 if(cvar("g_maplist_shuffle"))
 918                         ShuffleMaplist();
 919                 localcmd("\nmenu_cmd sync\n");
 920                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 921         }
 922         if(Map_Count == 0)
 923                 error("empty maplist, cannot select a new map");
 924         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 925
 926         if(Map_Current_Name)
 927                 strunzone(Map_Current_Name);
 928         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 929         // this may or may not be correct, but who cares, in the worst case a map
 930         // isn't chosen in the first pass that should have been
 931 }
 932
 933 string GetNextMap()
 934 {
 935         float nextMap;
 936
 937         Maplist_Init();
 938         nextMap = -1;
 939
 940         if(nextMap == -1)
 941                 if(cvar("g_maplist_shuffle") > 0)
 942                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 943
 944         if(nextMap == -1)
 945                 if(cvar("g_maplist_selectrandom"))
 946                         nextMap = MaplistMethod_Random();
 947
 948         if(nextMap == -1)
 949                 nextMap = MaplistMethod_Iterate();
 950
 951         if(nextMap == -1)
 952                 nextMap = MaplistMethod_Repeat();
 953
 954         if(nextMap >= 0)
 955         {
 956                 Map_Goto_SetFloat(nextMap);
 957                 return getmapname_stored;
 958         }
 959
 960         return "";
 961 };
 962
 963 float DoNextMapOverride()
 964 {
 965         if(cvar("g_campaign"))
 966         {
 967                 CampaignPostIntermission();
 968                 alreadychangedlevel = TRUE;
 969                 return TRUE;
 970         }
 971         if(cvar("quit_when_empty"))
 972         {
 973                 if(player_count <= currentbots)
 974                 {
 975                         localcmd("quit\n");
 976                         alreadychangedlevel = TRUE;
 977                         return TRUE;
 978                 }
 979         }
 980         if(cvar_string("quit_and_redirect") != "")
 981         {
 982                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 983                 alreadychangedlevel = TRUE;
 984                 return TRUE;
 985         }
 986         if (cvar("samelevel")) // if samelevel is set, stay on same level
 987         {
 988                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 989                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 990                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 991                 localcmd("restart\n");
 992                 //changelevel (mapname);
 993                 alreadychangedlevel = TRUE;
 994                 return TRUE;
 995         }
 996         if(cvar_string("nextmap") != "")
 997                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 998                 {
 999                         Map_Goto_SetStr(cvar_string("nextmap"));
1000                         Map_Goto();
1001                         alreadychangedlevel = TRUE;
1002                         return TRUE;
1003                 }
1004         if(cvar("lastlevel"))
1005         {
1006                 GameResetCfg();
1007                 localcmd("set lastlevel 0\ntogglemenu\n");
1008                 alreadychangedlevel = TRUE;
1009                 return TRUE;
1010         }
1011         return FALSE;
1012 };
1013
1014 void GotoNextMap()
1015 {
1016         //local string nextmap;
1017         //local float n, nummaps;
1018         //local string s;
1019         if (alreadychangedlevel)
1020                 return;
1021         alreadychangedlevel = TRUE;
1022
1023         {
1024                 string nextMap;
1025                 float allowReset;
1026
1027                 for(allowReset = 1; allowReset >= 0; --allowReset)
1028                 {
1029                         nextMap = GetNextMap();
1030                         if(nextMap != "")
1031                                 break;
1032
1033                         if(allowReset)
1034                         {
1035                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1036                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
1037                                 if(cvar("g_maplist_shuffle"))
1038                                         ShuffleMaplist();
1039                                 localcmd("\nmenu_cmd sync\n");
1040                         }
1041                         else
1042                         {
1043                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1044                         }
1045                 }
1046                 Map_Goto();
1047         }
1048 };
1049
1050
1051 /*
1052 ============
1053 IntermissionThink
1054
1055 When the player presses attack or jump, change to the next level
1056 ============
1057 */
1058 .float autoscreenshot;
1059 void() MapVote_Start;
1060 void() MapVote_Think;
1061 float mapvote_initialized;
1062 void IntermissionThink()
1063 {
1064         FixIntermissionClient(self);
1065
1066         if(cvar("sv_autoscreenshot"))
1067         if(self.autoscreenshot > 0)
1068         if(time > self.autoscreenshot)
1069         {
1070                 self.autoscreenshot = -1;
1071                 if(clienttype(self) == CLIENTTYPE_REAL)
1072                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1073                 return;
1074         }
1075
1076         if (time < intermission_exittime)
1077                 return;
1078
1079         if(!mapvote_initialized)
1080                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1081                         return;
1082
1083         MapVote_Start();
1084 };
1085
1086 /*
1087 ============
1088 FindIntermission
1089
1090 Returns the entity to view from
1091 ============
1092 */
1093 /*
1094 entity FindIntermission()
1095 {
1096         local   entity spot;
1097         local   float cyc;
1098
1099 // look for info_intermission first
1100         spot = find (world, classname, "info_intermission");
1101         if (spot)
1102         {       // pick a random one
1103                 cyc = random() * 4;
1104                 while (cyc > 1)
1105                 {
1106                         spot = find (spot, classname, "info_intermission");
1107                         if (!spot)
1108                                 spot = find (spot, classname, "info_intermission");
1109                         cyc = cyc - 1;
1110                 }
1111                 return spot;
1112         }
1113
1114 // then look for the start position
1115         spot = find (world, classname, "info_player_start");
1116         if (spot)
1117                 return spot;
1118
1119 // testinfo_player_start is only found in regioned levels
1120         spot = find (world, classname, "testplayerstart");
1121         if (spot)
1122                 return spot;
1123
1124 // then look for the start position
1125         spot = find (world, classname, "info_player_deathmatch");
1126         if (spot)
1127                 return spot;
1128
1129         //objerror ("FindIntermission: no spot");
1130         return world;
1131 };
1132 */
1133
1134 /*
1135 ===============================================================================
1136
1137 RULES
1138
1139 ===============================================================================
1140 */
1141
1142 void DumpStats(float final)
1143 {
1144         local float file;
1145         local string s;
1146         local float to_console;
1147         local float to_eventlog;
1148         local float to_file;
1149         local float i;
1150
1151         to_console = cvar("sv_logscores_console");
1152         to_eventlog = cvar("sv_eventlog");
1153         to_file = cvar("sv_logscores_file");
1154
1155         if(!final)
1156         {
1157                 to_console = TRUE; // always print printstats replies
1158                 to_eventlog = FALSE; // but never print them to the event log
1159         }
1160
1161         if(to_eventlog)
1162                 if(cvar("sv_eventlog_console"))
1163                         to_console = FALSE; // otherwise we get the output twice
1164
1165         if(final)
1166                 s = ":scores:";
1167         else
1168                 s = ":status:";
1169         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1170
1171         if(to_console)
1172                 print(s, "\n");
1173         if(to_eventlog)
1174                 GameLogEcho(s);
1175         if(to_file)
1176         {
1177                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1178                 if(file == -1)
1179                         to_file = FALSE;
1180                 else
1181                         fputs(file, strcat(s, "\n"));
1182         }
1183
1184         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1185         if(to_console)
1186                 print(s, "\n");
1187         if(to_eventlog)
1188                 GameLogEcho(s);
1189         if(to_file)
1190                 fputs(file, strcat(s, "\n"));
1191
1192         FOR_EACH_CLIENT(other)
1193         {
1194                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1195                 {
1196                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1197                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1198                         if(other.classname == "player" || g_arena || g_lms)
1199                                 s = strcat(s, ftos(other.team), ":");
1200                         else
1201                                 s = strcat(s, "spectator:");
1202
1203                         if(to_console)
1204                                 print(s, other.netname, "\n");
1205                         if(to_eventlog)
1206                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1207                         if(to_file)
1208                                 fputs(file, strcat(s, other.netname, "\n"));
1209                 }
1210         }
1211
1212         if(teams_matter)
1213         {
1214                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1215                 if(to_console)
1216                         print(s, "\n");
1217                 if(to_eventlog)
1218                         GameLogEcho(s);
1219                 if(to_file)
1220                         fputs(file, strcat(s, "\n"));
1221
1222                 for(i = 1; i < 16; ++i)
1223                 {
1224                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1225                         s = strcat(s, ":", ftos(i));
1226                         if(to_console)
1227                                 print(s, "\n");
1228                         if(to_eventlog)
1229                                 GameLogEcho(s);
1230                         if(to_file)
1231                                 fputs(file, strcat(s, "\n"));
1232                 }
1233         }
1234
1235         if(to_console)
1236                 print(":end\n");
1237         if(to_eventlog)
1238                 GameLogEcho(":end");
1239         if(to_file)
1240         {
1241                 fputs(file, ":end\n");
1242                 fclose(file);
1243         }
1244 }
1245
1246 void FixIntermissionClient(entity e)
1247 {
1248         string s;
1249         if(!e.autoscreenshot) // initial call
1250         {
1251                 e.angles = e.v_angle;
1252                 e.angles_x = -e.angles_x;
1253                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1254                 e.health = -2342;
1255                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1256                 e.solid = SOLID_NOT;
1257                 e.movetype = MOVETYPE_NONE;
1258                 e.takedamage = DAMAGE_NO;
1259                 if(e.weaponentity)
1260                 {
1261                         e.weaponentity.effects = EF_NODRAW;
1262                         if (e.weaponentity.weaponentity)
1263                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1264                 }
1265                 if(clienttype(e) == CLIENTTYPE_REAL)
1266                 {
1267                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1268                         s = cvar_string("sv_intermission_cdtrack");
1269                         if(s != "")
1270                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1271                         msg_entity = e;
1272                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1273                 }
1274         }
1275
1276         //e.velocity = '0 0 0';
1277         //e.fixangle = TRUE;
1278
1279         // TODO halt weapon animation
1280 }
1281
1282
1283 /*
1284 go to the next level for deathmatch
1285 only called if a time or frag limit has expired
1286 */
1287 void NextLevel()
1288 {
1289         float minTotalFrags;
1290         float maxTotalFrags;
1291         float score;
1292         float f;
1293
1294         gameover = TRUE;
1295
1296         intermission_running = 1;
1297
1298 // enforce a wait time before allowing changelevel
1299         if(player_count > 0)
1300                 intermission_exittime = time + cvar("sv_mapchange_delay");
1301         else
1302                 intermission_exittime = -1;
1303
1304         /*
1305         WriteByte (MSG_ALL, SVC_CDTRACK);
1306         WriteByte (MSG_ALL, 3);
1307         WriteByte (MSG_ALL, 3);
1308         // done in FixIntermission
1309         */
1310
1311         //pos = FindIntermission ();
1312
1313         VoteReset();
1314
1315         DumpStats(TRUE);
1316
1317         if(cvar("sv_eventlog"))
1318                 GameLogEcho(":gameover");
1319
1320         GameLogClose();
1321
1322         FOR_EACH_CLIENT(other)
1323         {
1324                 FixIntermissionClient(other);
1325
1326                 if(other.winning)
1327                         bprint(other.netname, " ^7wins.\n");
1328         }
1329
1330         minTotalFrags = 0;
1331         maxTotalFrags = 0;
1332         FOR_EACH_PLAYER(other)
1333         {
1334                 if(maxTotalFrags < other.totalfrags)
1335                         maxTotalFrags = other.totalfrags;
1336                 if(minTotalFrags > other.totalfrags)
1337                         minTotalFrags = other.totalfrags;
1338         }
1339
1340         if(!currentbots)
1341         {
1342                 FOR_EACH_PLAYER(other)
1343                 {
1344                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1345                         f = bound(0, other.play_time / max(time, 1), 1);
1346                         // store some statistics?
1347                 }
1348         }
1349
1350         if(cvar("g_campaign"))
1351                 CampaignPreIntermission();
1352
1353         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1354 };
1355
1356 /*
1357 ============
1358 CheckRules_Player
1359
1360 Exit deathmatch games upon conditions
1361 ============
1362 */
1363 void CheckRules_Player()
1364 {
1365         if (gameover)   // someone else quit the game already
1366                 return;
1367
1368         if(self.deadflag == DEAD_NO)
1369                 self.play_time += frametime;
1370
1371         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1372         //   (div0: and that in CheckRules_World please)
1373 };
1374
1375 float checkrules_equality;
1376 float checkrules_suddendeathwarning;
1377 float checkrules_suddendeathend;
1378 float checkrules_overtimesadded; //how many overtimes have been already added
1379 float checkrules_status;
1380
1381 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1382 float WINNING_YES = 1; // winner found
1383 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1384 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1385
1386 void InitiateOvertime()
1387 {
1388         // Check first whether normal overtimes could be added before initiating suddendeath mode
1389         // - for this timelimit_overtime needs to be >0 of course
1390         // - also check the winning condition calculated in the previous frame and only add normal overtime
1391         //   again, if at the point at which timelimit would be extended again, still no winner was found
1392         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1393         {
1394                 ++checkrules_overtimesadded;
1395                 //add one more overtime by simply extending the timelimit
1396                 float tl;
1397                 tl = cvar("timelimit");
1398                 tl += cvar("timelimit_overtime");
1399                 cvar_set("timelimit", ftos(tl));
1400                 string minutesPlural;
1401                 if (cvar("timelimit_overtime") == 1)
1402                         minutesPlural = " ^3minute";
1403                 else
1404                         minutesPlural = " ^3minutes";
1405
1406                 bcenterprint(
1407                         strcat(
1408                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1409                                 ftos(cvar("timelimit_overtime")),
1410                                 minutesPlural,
1411                                 " to the game!"
1412                         )
1413                 );
1414         }
1415         else
1416         {
1417                 if(!checkrules_suddendeathend)
1418                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1419         }
1420 }
1421
1422 float GetWinningCode(float fraglimitreached, float equality)
1423 {
1424         if(equality)
1425                 if(fraglimitreached)
1426                         return WINNING_STARTSUDDENDEATHOVERTIME;
1427                 else
1428                         return WINNING_NEVER;
1429         else
1430                 if(fraglimitreached)
1431                         return WINNING_YES;
1432                 else
1433                         return WINNING_NO;
1434 }
1435
1436 // set the .winning flag for exactly those players with a given field value
1437 void SetWinners(.float field, float value)
1438 {
1439         entity head;
1440         FOR_EACH_PLAYER(head)
1441                 head.winning = (head.field == value);
1442 }
1443
1444 // set the .winning flag for those players with a given field value
1445 void AddWinners(.float field, float value)
1446 {
1447         entity head;
1448         FOR_EACH_PLAYER(head)
1449                 if(head.field == value)
1450                         head.winning = 1;
1451 }
1452
1453 // clear the .winning flags
1454 void ClearWinners(void)
1455 {
1456         entity head;
1457         FOR_EACH_PLAYER(head)
1458                 head.winning = 0;
1459 }
1460
1461 // Onslaught winning condition:
1462 // game terminates if only one team has a working generator (or none)
1463 float WinningCondition_Onslaught()
1464 {
1465         entity head;
1466         local float t1, t2, t3, t4;
1467
1468         WinningConditionHelper(); // set worldstatus
1469
1470         // first check if the game has ended
1471         t1 = t2 = t3 = t4 = 0;
1472         head = find(world, classname, "onslaught_generator");
1473         while (head)
1474         {
1475                 if (head.health > 0)
1476                 {
1477                         if (head.team == COLOR_TEAM1) t1 = 1;
1478                         if (head.team == COLOR_TEAM2) t2 = 1;
1479                         if (head.team == COLOR_TEAM3) t3 = 1;
1480                         if (head.team == COLOR_TEAM4) t4 = 1;
1481                 }
1482                 head = find(head, classname, "onslaught_generator");
1483         }
1484         if (t1 + t2 + t3 + t4 < 2)
1485         {
1486                 // game over, only one team remains (or none)
1487                 ClearWinners();
1488                 if (t1) SetWinners(team, COLOR_TEAM1);
1489                 if (t2) SetWinners(team, COLOR_TEAM2);
1490                 if (t3) SetWinners(team, COLOR_TEAM3);
1491                 if (t4) SetWinners(team, COLOR_TEAM4);
1492                 dprint("Have a winner, ending game.\n");
1493                 return WINNING_YES;
1494         }
1495
1496         // Two or more teams remain
1497         return WINNING_NO;
1498 }
1499
1500 float LMS_NewPlayerLives()
1501 {
1502         float fl;
1503         fl = cvar("fraglimit");
1504         if(fl == 0)
1505                 fl = 999;
1506
1507         // first player has left the game for dying too much? Nobody else can get in.
1508         if(lms_lowest_lives < 1)
1509                 return 0;
1510
1511         if(!cvar("g_lms_join_anytime"))
1512                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1513                         return 0;
1514
1515         return bound(1, lms_lowest_lives, fl);
1516 }
1517
1518 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1519 // they win. Otherwise the defending team wins once the timelimit passes.
1520 void assault_new_round();
1521 float WinningCondition_Assault()
1522 {
1523         local float status;
1524
1525         WinningConditionHelper(); // set worldstatus
1526
1527         status = WINNING_NO;
1528         // as the timelimit has not yet passed just assume the defending team will win
1529         if(assault_attacker_team == COLOR_TEAM1)
1530         {
1531                 SetWinners(team, COLOR_TEAM2);
1532         }
1533         else
1534         {
1535                 SetWinners(team, COLOR_TEAM1);
1536         }
1537
1538         local entity ent;
1539         ent = find(world, classname, "target_assault_roundend");
1540         if(ent)
1541         {
1542                 if(ent.winning) // round end has been triggered by attacking team
1543                 {
1544                         bprint("ASSAULT: round completed...\n");
1545                         SetWinners(team, assault_attacker_team);
1546
1547                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1548
1549                         if(ent.cnt == 1) // this was the second round
1550                         {
1551                                 status = WINNING_YES;
1552                         }
1553                         else
1554                         {
1555                                 local entity oldself;
1556                                 oldself = self;
1557                                 self = ent;
1558                                 assault_new_round();
1559                                 self = oldself;
1560                         }
1561                 }
1562         }
1563
1564         return status;
1565 }
1566
1567 // LMS winning condition: game terminates if and only if there's at most one
1568 // one player who's living lives. Top two scores being equal cancels the time
1569 // limit.
1570 float WinningCondition_LMS()
1571 {
1572         entity head, head2;
1573         float have_player;
1574         float have_players;
1575         float l;
1576
1577         have_player = FALSE;
1578         have_players = FALSE;
1579         l = LMS_NewPlayerLives();
1580
1581         head = find(world, classname, "player");
1582         if(head)
1583                 have_player = TRUE;
1584         head2 = find(head, classname, "player");
1585         if(head2)
1586                 have_players = TRUE;
1587
1588         if(have_player)
1589         {
1590                 // we have at least one player
1591                 if(have_players)
1592                 {
1593                         // two or more active players - continue with the game
1594                 }
1595                 else
1596                 {
1597                         // exactly one player?
1598
1599                         ClearWinners();
1600                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1601
1602                         if(l)
1603                         {
1604                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1605                                 return WINNING_NO;
1606                         }
1607                         else
1608                         {
1609                                 // a winner!
1610                                 // and assign him his first place
1611                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1612                                 return WINNING_YES;
1613                         }
1614                 }
1615         }
1616         else
1617         {
1618                 // nobody is playing at all...
1619                 if(l)
1620                 {
1621                         // wait for players...
1622                 }
1623                 else
1624                 {
1625                         // SNAFU (maybe a draw game?)
1626                         ClearWinners();
1627                         dprint("No players, ending game.\n");
1628                         return WINNING_YES;
1629                 }
1630         }
1631
1632         // When we get here, we have at least two players who are actually LIVING,
1633         // now check if the top two players have equal score.
1634         WinningConditionHelper();
1635
1636         ClearWinners();
1637         if(WinningConditionHelper_winner)
1638                 WinningConditionHelper_winner.winning = TRUE;
1639         if(WinningConditionHelper_equality)
1640                 return WINNING_NEVER;
1641
1642         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1643         return WINNING_NO;
1644 }
1645
1646 void ShuffleMaplist()
1647 {
1648         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1649 }
1650
1651 float leaderfrags;
1652 float WinningCondition_Scores(float limit)
1653 {
1654         // TODO make everything use THIS winning condition (except LMS)
1655         WinningConditionHelper();
1656
1657         if(teams_matter)
1658         {
1659                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1660                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1661                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1662                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1663         }
1664
1665         ClearWinners();
1666         if(WinningConditionHelper_winner)
1667                 WinningConditionHelper_winner.winning = 1;
1668         if(WinningConditionHelper_winnerteam >= 0)
1669                 SetWinners(team, WinningConditionHelper_winnerteam);
1670
1671         if(WinningConditionHelper_lowerisbetter)
1672         {
1673                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1674                 limit = -limit;
1675         }
1676
1677         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying) || g_nexball)
1678         // these modes always score in increments of 1, thus this makes sense
1679         {
1680                 if(leaderfrags != WinningConditionHelper_topscore)
1681                 {
1682                         leaderfrags = WinningConditionHelper_topscore;
1683
1684                         if (limit)
1685                         if (leaderfrags == limit - 1)
1686                                 play2all("announcer/robotic/1fragleft.wav");
1687                         else if (leaderfrags == limit - 2)
1688                                 play2all("announcer/robotic/2fragsleft.wav");
1689                         else if (leaderfrags == limit - 3)
1690                                 play2all("announcer/robotic/3fragsleft.wav");
1691                 }
1692         }
1693
1694         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1695 }
1696
1697 float WinningCondition_Race(float fraglimit)
1698 {
1699         float wc;
1700         entity p;
1701         wc = WinningCondition_Scores(fraglimit);
1702
1703         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1704         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1705         // do NOT support equality when the laps are all raced!
1706         {
1707                 FOR_EACH_PLAYER(p)
1708                         if not(p.race_completed)
1709                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1710                 return WINNING_YES;
1711         }
1712         return wc;
1713 }
1714
1715 void ReadyRestart();
1716 float WinningCondition_QualifyingThenRace(float limit)
1717 {
1718         float wc;
1719         wc = WinningCondition_Scores(limit);
1720
1721         // NEVER initiate overtime
1722         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1723         {
1724                 return WINNING_YES;
1725         }
1726
1727         return wc;
1728 }
1729
1730 float WinningCondition_RanOutOfSpawns()
1731 {
1732         entity head;
1733
1734         if(!have_team_spawns)
1735                 return WINNING_NO;
1736
1737         if(!some_spawn_has_been_used)
1738                 return WINNING_NO;
1739
1740         team1_score = team2_score = team3_score = team4_score = 0;
1741
1742         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1743         {
1744                 if(head.team == COLOR_TEAM1)
1745                         team1_score = 1;
1746                 else if(head.team == COLOR_TEAM2)
1747                         team2_score = 1;
1748                 else if(head.team == COLOR_TEAM3)
1749                         team3_score = 1;
1750                 else if(head.team == COLOR_TEAM4)
1751                         team4_score = 1;
1752         }
1753
1754         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1755         {
1756                 if(head.team == COLOR_TEAM1)
1757                         team1_score = 1;
1758                 else if(head.team == COLOR_TEAM2)
1759                         team2_score = 1;
1760                 else if(head.team == COLOR_TEAM3)
1761                         team3_score = 1;
1762                 else if(head.team == COLOR_TEAM4)
1763                         team4_score = 1;
1764         }
1765
1766         ClearWinners();
1767         if(team1_score + team2_score + team3_score + team4_score == 0)
1768         {
1769                 checkrules_equality = TRUE;
1770                 return WINNING_YES;
1771         }
1772         else if(team1_score + team2_score + team3_score + team4_score == 1)
1773         {
1774                 float t, i;
1775                 if(team1_score) t = COLOR_TEAM1;
1776                 if(team2_score) t = COLOR_TEAM2;
1777                 if(team3_score) t = COLOR_TEAM3;
1778                 if(team4_score) t = COLOR_TEAM4;
1779                 CheckAllowedTeams(world);
1780                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1781                 {
1782                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1783                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1784                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1785                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1786                 }
1787
1788                 AddWinners(team, t);
1789                 return WINNING_YES;
1790         }
1791         else
1792                 return WINNING_NO;
1793 }
1794
1795 /*
1796 ============
1797 CheckRules_World
1798
1799 Exit deathmatch games upon conditions
1800 ============
1801 */
1802 void CheckRules_World()
1803 {
1804         local float timelimit;
1805         local float fraglimit;
1806
1807         VoteThink();
1808         MapVote_Think();
1809
1810         SetDefaultAlpha();
1811
1812         /*
1813         MapVote_Think should now do that part
1814         if (intermission_running)
1815                 if (time >= intermission_exittime + 60)
1816                 {
1817                         if(!DoNextMapOverride())
1818                                 GotoNextMap();
1819                         return;
1820                 }
1821         */
1822
1823         if (gameover)   // someone else quit the game already
1824         {
1825                 if(player_count == 0) // Nobody there? Then let's go to the next map
1826                         MapVote_Start();
1827                         // this will actually check the player count in the next frame
1828                         // again, but this shouldn't hurt
1829                 return;
1830         }
1831
1832         timelimit = cvar("timelimit") * 60;
1833         fraglimit = cvar("fraglimit");
1834
1835         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1836         {
1837                 if(timelimit > 0)
1838                         timelimit = 0; // timelimit is not made for warmup
1839                 if(fraglimit > 0)
1840                         fraglimit = 0; // no fraglimit for now
1841         }
1842
1843         if(timelimit > 0)
1844         {
1845                 timelimit += game_starttime;
1846         }
1847         else if (timelimit < 0)
1848         {
1849                 // endmatch
1850                 NextLevel();
1851                 return;
1852         }
1853
1854         if(checkrules_suddendeathend)
1855         {
1856                 if(!checkrules_suddendeathwarning)
1857                 {
1858                         checkrules_suddendeathwarning = TRUE;
1859                         if(g_race && !g_race_qualifying)
1860                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1861                         else
1862                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1863                 }
1864         }
1865         else
1866         {
1867                 if (timelimit && time >= timelimit)
1868                 {
1869                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1870                         {
1871                                 float totalplayers;
1872                                 float playerswithlaps;
1873                                 float readyplayers;
1874                                 entity head;
1875                                 totalplayers = playerswithlaps = readyplayers = 0;
1876                                 FOR_EACH_PLAYER(head)
1877                                 {
1878                                         ++totalplayers;
1879                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1880                                                 ++playerswithlaps;
1881                                         if(head.ready)
1882                                                 ++readyplayers;
1883                                 }
1884
1885                                 // at least 2/3 of the players have completed a lap: start the RACE
1886                                 // otherwise, the players should end the qualifying on their own
1887                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1888                                 {
1889                                         checkrules_suddendeathend = 0;
1890                                         ReadyRestart(); // go to race
1891                                 }
1892                                 else
1893                                         InitiateOvertime();
1894                         }
1895                         else
1896                                 InitiateOvertime();
1897                 }
1898         }
1899
1900         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1901         {
1902                 NextLevel();
1903                 return;
1904         }
1905
1906         checkrules_status = WinningCondition_RanOutOfSpawns();
1907         if(checkrules_status == WINNING_YES)
1908         {
1909                 bprint("Hey! Someone ran out of spawns!\n");
1910         }
1911         else if(g_race && !g_race_qualifying && timelimit >= 0)
1912         {
1913                 checkrules_status = WinningCondition_Race(fraglimit);
1914         }
1915         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1916         {
1917                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1918         }
1919         else if(g_assault)
1920         {
1921                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1922         }
1923         else if(g_lms)
1924         {
1925                 checkrules_status = WinningCondition_LMS();
1926         }
1927         else if (g_onslaught)
1928         {
1929                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1930         }
1931         else
1932         {
1933                 checkrules_status = WinningCondition_Scores(fraglimit);
1934         }
1935
1936         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1937         {
1938                 checkrules_status = WINNING_NEVER;
1939                 InitiateOvertime();
1940         }
1941
1942         if(checkrules_status == WINNING_NEVER)
1943                 // equality cases! Nobody wins if the overtime ends in a draw.
1944                 ClearWinners();
1945
1946         if(checkrules_suddendeathend)
1947                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1948                         checkrules_status = WINNING_YES;
1949
1950         if(checkrules_status == WINNING_YES)
1951                 NextLevel();
1952 };
1953
1954 float mapvote_nextthink;
1955 float mapvote_initialized;
1956 float mapvote_keeptwotime;
1957 float mapvote_timeout;
1958 string mapvote_message;
1959 string mapvote_screenshot_dir;
1960
1961 float mapvote_count;
1962 float mapvote_count_real;
1963 string mapvote_maps[MAPVOTE_COUNT];
1964 float mapvote_maps_suggested[MAPVOTE_COUNT];
1965 string mapvote_suggestions[MAPVOTE_COUNT];
1966 float mapvote_suggestion_ptr;
1967 float mapvote_maxlen;
1968 float mapvote_voters;
1969 float mapvote_votes[MAPVOTE_COUNT];
1970 float mapvote_run;
1971 float mapvote_detail;
1972 float mapvote_abstain;
1973 .float mapvote;
1974
1975 void MapVote_ClearAllVotes()
1976 {
1977         FOR_EACH_CLIENT(other)
1978                 other.mapvote = 0;
1979 }
1980
1981 string MapVote_Suggest(string m)
1982 {
1983         float i;
1984         if(m == "")
1985                 return "That's not how to use this command.";
1986         if(!cvar("g_maplist_votable_suggestions"))
1987                 return "Suggestions are not accepted on this server.";
1988         if(mapvote_initialized)
1989                 return "Can't suggest - voting is already in progress!";
1990         m = MapInfo_FixName(m);
1991         if(!m)
1992                 return "The map you suggested is not available on this server.";
1993         if(!cvar("g_maplist_votable_override_mostrecent"))
1994                 if(Map_IsRecent(m))
1995                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1996
1997         if(!MapInfo_CheckMap(m))
1998                 return "The map you suggested does not support the current game mode.";
1999         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2000                 if(mapvote_suggestions[i] == m)
2001                         return "This map was already suggested.";
2002         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2003         {
2004                 i = floor(random() * mapvote_suggestion_ptr);
2005         }
2006         else
2007         {
2008                 i = mapvote_suggestion_ptr;
2009                 mapvote_suggestion_ptr += 1;
2010         }
2011         if(mapvote_suggestions[i] != "")
2012                 strunzone(mapvote_suggestions[i]);
2013         mapvote_suggestions[i] = strzone(m);
2014         if(cvar("sv_eventlog"))
2015                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2016         return strcat("Suggestion of ", m, " accepted.");
2017 }
2018
2019 void MapVote_AddVotable(string nextMap, float isSuggestion)
2020 {
2021         float j;
2022         if(nextMap == "")
2023                 return;
2024         for(j = 0; j < mapvote_count; ++j)
2025                 if(mapvote_maps[j] == nextMap)
2026                         return;
2027         if(strlen(nextMap) > mapvote_maxlen)
2028                 mapvote_maxlen = strlen(nextMap);
2029         mapvote_maps[mapvote_count] = strzone(nextMap);
2030         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2031         mapvote_count += 1;
2032 }
2033
2034 void MapVote_Spawn();
2035 void MapVote_Init()
2036 {
2037         float i;
2038         float nmax, smax;
2039
2040         MapVote_ClearAllVotes();
2041
2042         mapvote_count = 0;
2043         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2044         mapvote_abstain = cvar("g_maplist_votable_abstain");
2045
2046         if(mapvote_abstain)
2047                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2048         else
2049                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2050         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2051
2052         if(mapvote_suggestion_ptr)
2053                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2054                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2055
2056         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2057                 MapVote_AddVotable(GetNextMap(), FALSE);
2058
2059         if(mapvote_count == 0)
2060         {
2061                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2062                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
2063                 if(cvar("g_maplist_shuffle"))
2064                         ShuffleMaplist();
2065                 localcmd("\nmenu_cmd sync\n");
2066                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2067                         MapVote_AddVotable(GetNextMap(), FALSE);
2068         }
2069
2070         mapvote_count_real = mapvote_count;
2071         if(mapvote_abstain)
2072                 MapVote_AddVotable("don't care", 0);
2073
2074         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2075
2076         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2077         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2078         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2079                 mapvote_keeptwotime = 0;
2080         mapvote_message = "Choose a map and press its key!";
2081
2082         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2083         if(mapvote_screenshot_dir == "")
2084                 mapvote_screenshot_dir = "maps";
2085         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2086
2087         MapVote_Spawn();
2088 }
2089
2090 void MapVote_SendPicture(float id)
2091 {
2092         msg_entity = self;
2093         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2094         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2095         WriteByte(MSG_ONE, id);
2096         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2097 }
2098
2099 float GameCommand_MapVote(string cmd)
2100 {
2101         if(!intermission_running)
2102                 return FALSE;
2103
2104         if(cmd == "mv_getpic")
2105         {
2106                 MapVote_SendPicture(stof(argv(1)));
2107                 return TRUE;
2108         }
2109
2110         return FALSE;
2111 }
2112
2113 float MapVote_GetMapMask()
2114 {
2115         float mask, i, power;
2116         mask = 0;
2117         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2118                 if(mapvote_maps[i] != "")
2119                         mask |= power;
2120         return mask;
2121 }
2122
2123 entity mapvote_ent;
2124 float MapVote_SendEntity(entity to, float sf)
2125 {
2126         string mapfile, pakfile;
2127         float i, o;
2128
2129         if(sf & 1)
2130                 sf &~= 2; // if we send 1, we don't need to also send 2
2131
2132         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2133         WriteByte(MSG_ENTITY, sf);
2134
2135         if(sf & 1)
2136         {
2137                 // flag 1 == initialization
2138                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2139                 WriteByte(MSG_ENTITY, mapvote_count);
2140                 WriteByte(MSG_ENTITY, mapvote_abstain);
2141                 WriteByte(MSG_ENTITY, mapvote_detail);
2142                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2143                 if(mapvote_count <= 8)
2144                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2145                 else
2146                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2147                 for(i = 0; i < mapvote_count; ++i)
2148                         if(mapvote_maps[i] != "")
2149                         {
2150                                 if(mapvote_abstain && i == mapvote_count - 1)
2151                                 {
2152                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2153                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2154                                 }
2155                                 else
2156                                 {
2157                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2158                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2159                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2160                                         if(pakfile == "")
2161                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2162                                         if(pakfile == "")
2163                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2164                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2165                                                 pakfile = substring(pakfile, o, 999);
2166                                         WriteString(MSG_ENTITY, pakfile);
2167                                 }
2168                         }
2169         }
2170
2171         if(sf & 2)
2172         {
2173                 // flag 2 == update of mask
2174                 if(mapvote_count <= 8)
2175                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2176                 else
2177                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2178         }
2179
2180         if(sf & 4)
2181         {
2182                 if(mapvote_detail)
2183                         for(i = 0; i < mapvote_count; ++i)
2184                                 if(mapvote_maps[i] != "")
2185                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2186
2187                 WriteByte(MSG_ENTITY, to.mapvote);
2188         }
2189
2190         return TRUE;
2191 }
2192
2193 void MapVote_Spawn()
2194 {
2195         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2196 }
2197
2198 void MapVote_TouchMask()
2199 {
2200         mapvote_ent.SendFlags |= 2;
2201 }
2202
2203 void MapVote_TouchVotes(entity voter)
2204 {
2205         mapvote_ent.SendFlags |= 4;
2206 }
2207
2208 float MapVote_Finished(float mappos)
2209 {
2210         string result;
2211         float i;
2212         float didntvote;
2213
2214         if(cvar("sv_eventlog"))
2215         {
2216                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2217                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2218                 didntvote = mapvote_voters;
2219                 for(i = 0; i < mapvote_count; ++i)
2220                         if(mapvote_maps[i] != "")
2221                         {
2222                                 didntvote -= mapvote_votes[i];
2223                                 if(i != mappos)
2224                                 {
2225                                         result = strcat(result, ":", mapvote_maps[i]);
2226                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2227                                 }
2228                         }
2229                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2230
2231                 GameLogEcho(result);
2232                 if(mapvote_maps_suggested[mappos])
2233                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2234         }
2235
2236         FOR_EACH_REALCLIENT(other)
2237                 FixClientCvars(other);
2238
2239         Map_Goto_SetStr(mapvote_maps[mappos]);
2240         Map_Goto();
2241         alreadychangedlevel = TRUE;
2242         return TRUE;
2243 }
2244 void MapVote_CheckRules_1()
2245 {
2246         float i;
2247
2248         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2249         {
2250                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2251                 mapvote_votes[i] = 0;
2252         }
2253
2254         mapvote_voters = 0;
2255         FOR_EACH_REALCLIENT(other)
2256         {
2257                 ++mapvote_voters;
2258                 if(other.mapvote)
2259                 {
2260                         i = other.mapvote - 1;
2261                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2262                         mapvote_votes[i] = mapvote_votes[i] + 1;
2263                 }
2264         }
2265 }
2266
2267 float MapVote_CheckRules_2()
2268 {
2269         float i;
2270         float firstPlace, secondPlace;
2271         float firstPlaceVotes, secondPlaceVotes;
2272         float mapvote_voters_real;
2273         string result;
2274
2275         if(mapvote_count_real == 1)
2276                 return MapVote_Finished(0);
2277
2278         mapvote_voters_real = mapvote_voters;
2279         if(mapvote_abstain)
2280                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2281
2282         RandomSelection_Init();
2283         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2284                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2285         firstPlace = RandomSelection_chosen_float;
2286         firstPlaceVotes = RandomSelection_best_priority;
2287         //dprint("First place: ", ftos(firstPlace), "\n");
2288         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2289
2290         RandomSelection_Init();
2291         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2292                 if(i != firstPlace)
2293                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2294         secondPlace = RandomSelection_chosen_float;
2295         secondPlaceVotes = RandomSelection_best_priority;
2296         //dprint("Second place: ", ftos(secondPlace), "\n");
2297         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2298
2299         if(firstPlace == -1)
2300                 error("No first place in map vote... WTF?");
2301
2302         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2303                 return MapVote_Finished(firstPlace);
2304
2305         if(mapvote_keeptwotime)
2306                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2307                 {
2308                         float didntvote;
2309                         MapVote_TouchMask();
2310                         mapvote_message = "Now decide between the TOP TWO!";
2311                         mapvote_keeptwotime = 0;
2312                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2313                         result = strcat(result, ":", ftos(firstPlaceVotes));
2314                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2315                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2316                         didntvote = mapvote_voters;
2317                         for(i = 0; i < mapvote_count; ++i)
2318                                 if(mapvote_maps[i] != "")
2319                                 {
2320                                         didntvote -= mapvote_votes[i];
2321                                         if(i != firstPlace)
2322                                                 if(i != secondPlace)
2323                                                 {
2324                                                         result = strcat(result, ":", mapvote_maps[i]);
2325                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2326                                                         if(i < mapvote_count_real)
2327                                                         {
2328                                                                 strunzone(mapvote_maps[i]);
2329                                                                 mapvote_maps[i] = "";
2330                                                         }
2331                                                 }
2332                                 }
2333                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2334                         if(cvar("sv_eventlog"))
2335                                 GameLogEcho(result);
2336                 }
2337
2338         return FALSE;
2339 }
2340 void MapVote_Tick()
2341 {
2342         float keeptwo;
2343         float totalvotes;
2344
2345         keeptwo = mapvote_keeptwotime;
2346         MapVote_CheckRules_1(); // count
2347         if(MapVote_CheckRules_2()) // decide
2348                 return;
2349
2350         totalvotes = 0;
2351         FOR_EACH_REALCLIENT(other)
2352         {
2353                 // hide scoreboard again
2354                 if(other.health != 2342)
2355                 {
2356                         other.health = 2342;
2357                         other.impulse = 0;
2358                         if(clienttype(other) == CLIENTTYPE_REAL)
2359                         {
2360                                 msg_entity = other;
2361                                 WriteByte(MSG_ONE, SVC_FINALE);
2362                                 WriteString(MSG_ONE, "");
2363                         }
2364                 }
2365
2366                 // clear possibly invalid votes
2367                 if(mapvote_maps[other.mapvote - 1] == "")
2368                         other.mapvote = 0;
2369                 // use impulses as new vote
2370                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2371                         if(mapvote_maps[other.impulse - 1] != "")
2372                         {
2373                                 other.mapvote = other.impulse;
2374                                 MapVote_TouchVotes(other);
2375                         }
2376                 other.impulse = 0;
2377
2378                 if(other.mapvote)
2379                         ++totalvotes;
2380         }
2381
2382         MapVote_CheckRules_1(); // just count
2383 }
2384 void MapVote_Start()
2385 {
2386         if(mapvote_run)
2387                 return;
2388
2389         MapInfo_Enumerate();
2390         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1))
2391                 mapvote_run = TRUE;
2392 }
2393 void MapVote_Think()
2394 {
2395         if(!mapvote_run)
2396                 return;
2397
2398         if(alreadychangedlevel)
2399                 return;
2400
2401         if(time < mapvote_nextthink)
2402                 return;
2403         //dprint("tick\n");
2404
2405         mapvote_nextthink = time + 0.5;
2406
2407         if(!mapvote_initialized)
2408         {
2409                 mapvote_initialized = TRUE;
2410                 if(DoNextMapOverride())
2411                         return;
2412                 if(!cvar("g_maplist_votable") || player_count <= 0)
2413                 {
2414                         GotoNextMap();
2415                         return;
2416                 }
2417                 MapVote_Init();
2418         }
2419
2420         MapVote_Tick();
2421 };
2422
2423 string GotoMap(string m)
2424 {
2425         if(!MapInfo_CheckMap(m))
2426                 return "The map you chose is not available on this server.";
2427         cvar_set("nextmap", m);
2428         cvar_set("timelimit", "-1");
2429         if(mapvote_initialized || alreadychangedlevel)
2430         {
2431                 if(DoNextMapOverride())
2432                         return "Map switch initiated.";
2433                 else
2434                         return "Hm... no. For some reason I like THIS map more.";
2435         }
2436         else
2437                 return "Map switch will happen after scoreboard.";
2438 }
2439
2440
2441 void EndFrame()
2442 {
2443         FOR_EACH_REALCLIENT(self)
2444         {
2445                 if(self.classname == "spectator")
2446                 {
2447                         if(self.enemy.typehitsound)
2448                                 play2(self, "misc/typehit.wav");
2449                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2450                                 play2(self, "misc/hit.wav");
2451                 }
2452                 else
2453                 {
2454                         if(self.typehitsound)
2455                                 play2(self, "misc/typehit.wav");
2456                         else if(self.hitsound && self.cvar_cl_hitsound)
2457                                 play2(self, "misc/hit.wav");
2458                 }
2459         }
2460         FOR_EACH_CLIENT(self)
2461         {
2462                 self.hitsound = FALSE;
2463                 self.typehitsound = FALSE;
2464         }
2465 }
2466
2467
2468 /*
2469  * RedirectionThink:
2470  * returns TRUE if redirecting
2471  */
2472 float redirection_timeout;
2473 float redirection_nextthink;
2474 float RedirectionThink()
2475 {
2476         float clients_found;
2477
2478         if(redirection_target == "")
2479                 return FALSE;
2480
2481         if(!redirection_timeout)
2482         {
2483                 cvar_set("sv_public", "-2");
2484                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2485                 if(redirection_target == "self")
2486                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2487                 else
2488                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2489         }
2490
2491         if(time < redirection_nextthink)
2492                 return TRUE;
2493
2494         redirection_nextthink = time + 1;
2495
2496         clients_found = 0;
2497         FOR_EACH_REALCLIENT(self)
2498         {
2499                 print("Redirecting: sending connect command to ", self.netname, "\n");
2500                 if(redirection_target == "self")
2501                         stuffcmd(self, "\ndisconnect; reconnect\n");
2502                 else
2503                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2504                 ++clients_found;
2505         }
2506
2507         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2508
2509         if(time > redirection_timeout || clients_found == 0)
2510                 localcmd("\nwait; wait; wait; quit\n");
2511
2512         return TRUE;
2513 }
2514
2515 void RestoreGame()
2516 {
2517         // Loaded from a save game
2518         // some things then break, so let's work around them...
2519
2520         // Progs DB (capture records)
2521         if(sv_cheats)
2522                 ServerProgsDB = db_create();
2523         else
2524                 ServerProgsDB = db_load("server.db");
2525
2526         // Mapinfo
2527         MapInfo_Shutdown();
2528         MapInfo_Enumerate();
2529         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
2530 }
2531
2532 void SV_Shutdown()
2533 {
2534         if(world_initialized > 0)
2535         {
2536                 world_initialized = 0;
2537                 print("Saving persistent data...\n");
2538                 Ban_SaveBans();
2539                 if(!sv_cheats)
2540                         db_save(ServerProgsDB, "server.db");
2541                 if(cvar("developer"))
2542                         db_save(TemporaryDB, "server-temp.db");
2543                 db_close(ServerProgsDB);
2544                 db_close(TemporaryDB);
2545                 print("done!\n");
2546                 // tell the bot system the game is ending now
2547                 bot_endgame();
2548
2549                 MapInfo_Shutdown();
2550         }
2551         else if(world_initialized == 0)
2552         {
2553                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2554         }
2555 }