data/qcsrc/server/g_triggers.qc

   1
   2 void() SUB_UseTargets;
   3
   4 void DelayThink()
   5 {
   6         activator = self.enemy;
   7         SUB_UseTargets ();
   8         remove(self);
   9 };
  10
  11 /*
  12 ==============================
  13 SUB_UseTargets
  14
  15 the global "activator" should be set to the entity that initiated the firing.
  16
  17 If self.delay is set, a DelayedUse entity will be created that will actually
  18 do the SUB_UseTargets after that many seconds have passed.
  19
  20 Centerprints any self.message to the activator.
  21
  22 Removes all entities with a targetname that match self.killtarget,
  23 and removes them, so some events can remove other triggers.
  24
  25 Search for (string)targetname in all entities that
  26 match (string)self.target and call their .use function
  27
  28 ==============================
  29 */
  30 void SUB_UseTargets()
  31 {
  32         local entity t, stemp, otemp, act;
  33
  34 //
  35 // check for a delay
  36 //
  37         if (self.delay)
  38         {
  39         // create a temp object to fire at a later time
  40                 t = spawn();
  41                 t.classname = "DelayedUse";
  42                 t.nextthink = time + self.delay;
  43                 t.think = DelayThink;
  44                 t.enemy = activator;
  45                 t.message = self.message;
  46                 t.killtarget = self.killtarget;
  47                 t.target = self.target;
  48                 return;
  49         }
  50
  51
  52 //
  53 // print the message
  54 //
  55         if (activator.classname == "player" && self.message != "")
  56         {
  57                 centerprint (activator, self.message);
  58                 if (!self.noise)
  59                         play2(activator, "misc/talk.wav");
  60         }
  61
  62 //
  63 // kill the killtagets
  64 //
  65         if (self.killtarget)
  66         {
  67                 t = world;
  68                 do
  69                 {
  70                         t = find (t, targetname, self.killtarget);
  71                         if (!t)
  72                                 return;
  73                         remove (t);
  74                 } while ( 1 );
  75         }
  76
  77 //
  78 // fire targets
  79 //
  80         if (self.target)
  81         {
  82                 act = activator;
  83                 t = world;
  84                 do
  85                 {
  86                         t = find (t, targetname, self.target);
  87                         if (!t)
  88                         {
  89                                 return;
  90                         }
  91                         stemp = self;
  92                         otemp = other;
  93                         self = t;
  94                         other = stemp;
  95                         if (self.use)
  96                                 self.use ();
  97                         self = stemp;
  98                         other = otemp;
  99                         activator = act;
 100                 } while ( 1 );
 101         }
 102
 103
 104 };
 105
 106
 107 //=============================================================================
 108
 109 float   SPAWNFLAG_NOMESSAGE = 1;
 110 float   SPAWNFLAG_NOTOUCH = 1;
 111
 112 // the wait time has passed, so set back up for another activation
 113 void multi_wait()
 114 {
 115         if (self.max_health)
 116         {
 117                 self.health = self.max_health;
 118                 self.takedamage = DAMAGE_YES;
 119                 self.solid = SOLID_BBOX;
 120         }
 121 };
 122
 123
 124 // the trigger was just touched/killed/used
 125 // self.enemy should be set to the activator so it can be held through a delay
 126 // so wait for the delay time before firing
 127 void multi_trigger()
 128 {
 129         if (self.nextthink > time)
 130         {
 131                 return;         // allready been triggered
 132         }
 133
 134         if (self.classname == "trigger_secret")
 135         {
 136                 if (self.enemy.classname != "player")
 137                         return;
 138                 found_secrets = found_secrets + 1;
 139                 WriteByte (MSG_ALL, SVC_FOUNDSECRET);
 140         }
 141
 142         if (self.noise)
 143                 sound (self.enemy, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 144
 145 // don't trigger again until reset
 146         self.takedamage = DAMAGE_NO;
 147
 148         activator = self.enemy;
 149
 150         SUB_UseTargets();
 151
 152         if (self.wait > 0)
 153         {
 154                 self.think = multi_wait;
 155                 self.nextthink = time + self.wait;
 156         }
 157         else
 158         {       // we can't just remove (self) here, because this is a touch function
 159                 // called wheil C code is looping through area links...
 160                 self.touch = SUB_Null;
 161
 162                 self.nextthink = time + 0.1;
 163                 self.think = SUB_Remove;
 164         }
 165 };
 166
 167 void multi_use()
 168 {
 169         self.enemy = activator;
 170         multi_trigger();
 171 };
 172
 173 void multi_touch()
 174 {
 175         if (other.classname != "player")
 176                 return;
 177
 178     if(self.team)
 179     if(self.team == other.team)
 180         return;
 181
 182 // if the trigger has an angles field, check player's facing direction
 183         if (self.movedir != '0 0 0')
 184         {
 185                 makevectors (other.angles);
 186                 if (v_forward * self.movedir < 0)
 187                         return;         // not facing the right way
 188         }
 189
 190         EXACTTRIGGER_TOUCH;
 191
 192         self.enemy = other;
 193         multi_trigger ();
 194 };
 195
 196 void multi_eventdamage (vector hitloc, float damage, entity inflictor, entity attacker, float deathtype)
 197 {
 198         if (!self.takedamage)
 199                 return;
 200         self.health = self.health - damage;
 201         if (self.health <= 0)
 202         {
 203                 self.enemy = attacker;
 204                 multi_trigger();
 205         }
 206 }
 207
 208 /*QUAKED spawnfunc_trigger_multiple (.5 .5 .5) ? notouch
 209 Variable sized repeatable trigger.  Must be targeted at one or more entities.  If "health" is set, the trigger must be killed to activate each time.
 210 If "delay" is set, the trigger waits some time after activating before firing.
 211 "wait" : Seconds between triggerings. (.2 default)
 212 If notouch is set, the trigger is only fired by other entities, not by touching.
 213 NOTOUCH has been obsoleted by spawnfunc_trigger_relay!
 214 sounds
 215 1)      secret
 216 2)      beep beep
 217 3)      large switch
 218 4)
 219 set "message" to text string
 220 */
 221 void spawnfunc_trigger_multiple()
 222 {
 223         if (self.sounds == 1)
 224         {
 225                 precache_sound ("misc/secret.wav");
 226                 self.noise = "misc/secret.wav";
 227         }
 228         else if (self.sounds == 2)
 229         {
 230                 precache_sound ("misc/talk.wav");
 231                 self.noise = "misc/talk.wav";
 232         }
 233         else if (self.sounds == 3)
 234         {
 235                 precache_sound ("misc/trigger1.wav");
 236                 self.noise = "misc/trigger1.wav";
 237         }
 238
 239         if (!self.wait)
 240                 self.wait = 0.2;
 241         self.use = multi_use;
 242
 243         EXACTTRIGGER_INIT;
 244
 245         if (self.health)
 246         {
 247                 if (self.spawnflags & SPAWNFLAG_NOTOUCH)
 248                         objerror ("health and notouch don't make sense\n");
 249                 self.max_health = self.health;
 250                 self.event_damage = multi_eventdamage;
 251                 self.takedamage = DAMAGE_YES;
 252                 self.solid = SOLID_BBOX;
 253                 setorigin (self, self.origin);  // make sure it links into the world
 254         }
 255         else
 256         {
 257                 if ( !(self.spawnflags & SPAWNFLAG_NOTOUCH) )
 258                 {
 259                         self.touch = multi_touch;
 260                 }
 261         }
 262 };
 263
 264
 265 /*QUAKED spawnfunc_trigger_once (.5 .5 .5) ? notouch
 266 Variable sized trigger. Triggers once, then removes itself.  You must set the key "target" to the name of another object in the level that has a matching
 267 "targetname".  If "health" is set, the trigger must be killed to activate.
 268 If notouch is set, the trigger is only fired by other entities, not by touching.
 269 if "killtarget" is set, any objects that have a matching "target" will be removed when the trigger is fired.
 270 if "angle" is set, the trigger will only fire when someone is facing the direction of the angle.  Use "360" for an angle of 0.
 271 sounds
 272 1)      secret
 273 2)      beep beep
 274 3)      large switch
 275 4)
 276 set "message" to text string
 277 */
 278 void spawnfunc_trigger_once()
 279 {
 280         self.wait = -1;
 281         spawnfunc_trigger_multiple();
 282 };
 283
 284 //=============================================================================
 285
 286 /*QUAKED spawnfunc_trigger_relay (.5 .5 .5) (-8 -8 -8) (8 8 8)
 287 This fixed size trigger cannot be touched, it can only be fired by other events.  It can contain killtargets, targets, delays, and messages.
 288 */
 289 void spawnfunc_trigger_relay()
 290 {
 291         self.use = SUB_UseTargets;
 292 };
 293
 294 void delay_use()
 295 {
 296     self.think = SUB_UseTargets;
 297     self.nextthink = self.wait;
 298 }
 299
 300 void spawnfunc_trigger_delay()
 301 {
 302     if(!self.wait)
 303         self.wait = 1;
 304
 305     self.use = delay_use;
 306 }
 307
 308 //=============================================================================
 309
 310
 311 void counter_use()
 312 {
 313         self.count = self.count - 1;
 314         if (self.count < 0)
 315                 return;
 316
 317         if (self.count != 0)
 318         {
 319                 if (activator.classname == "player"
 320                 && (self.spawnflags & SPAWNFLAG_NOMESSAGE) == 0)
 321                 {
 322                         if (self.count >= 4)
 323                                 centerprint (activator, "There are more to go...");
 324                         else if (self.count == 3)
 325                                 centerprint (activator, "Only 3 more to go...");
 326                         else if (self.count == 2)
 327                                 centerprint (activator, "Only 2 more to go...");
 328                         else
 329                                 centerprint (activator, "Only 1 more to go...");
 330                 }
 331                 return;
 332         }
 333
 334         if (activator.classname == "player"
 335         && (self.spawnflags & SPAWNFLAG_NOMESSAGE) == 0)
 336                 centerprint(activator, "Sequence completed!");
 337         self.enemy = activator;
 338         multi_trigger ();
 339 };
 340
 341 /*QUAKED spawnfunc_trigger_counter (.5 .5 .5) ? nomessage
 342 Acts as an intermediary for an action that takes multiple inputs.
 343
 344 If nomessage is not set, t will print "1 more.. " etc when triggered and "sequence complete" when finished.
 345
 346 After the counter has been triggered "count" times (default 2), it will fire all of it's targets and remove itself.
 347 */
 348 void spawnfunc_trigger_counter()
 349 {
 350         self.wait = -1;
 351         if (!self.count)
 352                 self.count = 2;
 353
 354         self.use = counter_use;
 355 };
 356
 357 .float triggerhurttime;
 358 void trigger_hurt_touch()
 359 {
 360         // only do the EXACTTRIGGER_TOUCH checks when really needed (saves some cpu)
 361         if (!other.owner)
 362         {
 363                 if (other.items & IT_KEY1 || other.items & IT_KEY2)     // reset flag
 364                 {
 365                         EXACTTRIGGER_TOUCH;
 366                         other.pain_finished = min(other.pain_finished, time + 2);
 367                 }
 368                 else if (other.classname == "rune")                     // reset runes
 369                 {
 370                         EXACTTRIGGER_TOUCH;
 371                         other.nextthink = min(other.nextthink, time + 1);
 372                 }
 373         }
 374
 375         if (other.takedamage)
 376         if (other.triggerhurttime < time)
 377         {
 378                 EXACTTRIGGER_TOUCH;
 379                 other.triggerhurttime = time + 1;
 380                 Damage (other, self, self, self.dmg, DEATH_HURTTRIGGER, other.origin, '0 0 0');
 381         }
 382
 383         return;
 384 };
 385
 386 /*QUAKED spawnfunc_trigger_hurt (.5 .5 .5) ?
 387 Any object touching this will be hurt
 388 set dmg to damage amount
 389 defalt dmg = 5
 390 */
 391 .entity trigger_hurt_next;
 392 entity trigger_hurt_last;
 393 entity trigger_hurt_first;
 394 void spawnfunc_trigger_hurt()
 395 {
 396         EXACTTRIGGER_INIT;
 397         self.touch = trigger_hurt_touch;
 398         if (!self.dmg)
 399                 self.dmg = 1000;
 400         if (!self.message)
 401                 self.message = "was in the wrong place.";
 402
 403         if(!trigger_hurt_first)
 404                 trigger_hurt_first = self;
 405         if(trigger_hurt_last)
 406                 trigger_hurt_last.trigger_hurt_next = self;
 407         trigger_hurt_last = self;
 408 };
 409
 410 float trace_hits_box_a0, trace_hits_box_a1;
 411
 412 float trace_hits_box_1d(float end, float thmi, float thma)
 413 {
 414         if(end == 0)
 415         {
 416                 // just check if x is in range
 417                 if(0 < thmi)
 418                         return FALSE;
 419                 if(0 > thma)
 420                         return FALSE;
 421         }
 422         else
 423         {
 424                 // do the trace with respect to x
 425                 // 0 -> end has to stay in thmi -> thma
 426                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
 427                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
 428                 if(trace_hits_box_a0 > trace_hits_box_a1)
 429                         return FALSE;
 430         }
 431         return TRUE;
 432 }
 433
 434 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
 435 {
 436         end -= start;
 437         thmi -= start;
 438         thma -= start;
 439         // now it is a trace from 0 to end
 440
 441         trace_hits_box_a0 = 0;
 442         trace_hits_box_a1 = 1;
 443
 444         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
 445                 return FALSE;
 446         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
 447                 return FALSE;
 448         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
 449                 return FALSE;
 450
 451         return TRUE;
 452 }
 453
 454 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
 455 {
 456         return trace_hits_box(start, end, thmi - ma, thma - mi);
 457 }
 458
 459 float tracebox_hits_trigger_hurt(vector start, vector mi, vector ma, vector end)
 460 {
 461         entity th;
 462
 463         for(th = trigger_hurt_first; th; th = th.trigger_hurt_next)
 464                 if(tracebox_hits_box(start, mi, ma, end, th.absmin, th.absmax))
 465                         return TRUE;
 466
 467         return FALSE;
 468 }
 469
 470
 471 void target_speaker_use() {sound(self, CHAN_TRIGGER, self.noise, VOL_BASE, ATTN_NORM);}
 472
 473 void spawnfunc_target_speaker()
 474 {
 475         if(self.noise)
 476                 precache_sound (self.noise);
 477         if(self.targetname)
 478                 self.use = target_speaker_use;
 479         else
 480                 ambientsound (self.origin, self.noise, VOL_BASE, ATTN_STATIC);
 481 };
 482
 483
 484 void spawnfunc_func_stardust() {
 485         self.effects = EF_STARDUST;
 486 }
 487
 488 float pointparticles_SendEntity(entity to, float fl)
 489 {
 490         WriteByte(MSG_ENTITY, ENT_CLIENT_POINTPARTICLES);
 491         WriteByte(MSG_ENTITY, fl);
 492         if(fl & 2)
 493         {
 494                 if(self.state)
 495                         WriteCoord(MSG_ENTITY, self.impulse);
 496                 else
 497                         WriteCoord(MSG_ENTITY, 0); // off
 498         }
 499         if(fl & 4)
 500         {
 501                 WriteCoord(MSG_ENTITY, self.origin_x);
 502                 WriteCoord(MSG_ENTITY, self.origin_y);
 503                 WriteCoord(MSG_ENTITY, self.origin_z);
 504         }
 505         if(fl & 1)
 506         {
 507                 if(self.modelindex != 4.2)
 508                 {
 509                         WriteShort(MSG_ENTITY, self.modelindex);
 510                         WriteCoord(MSG_ENTITY, self.mins_x);
 511                         WriteCoord(MSG_ENTITY, self.mins_y);
 512                         WriteCoord(MSG_ENTITY, self.mins_z);
 513                         WriteCoord(MSG_ENTITY, self.maxs_x);
 514                         WriteCoord(MSG_ENTITY, self.maxs_y);
 515                         WriteCoord(MSG_ENTITY, self.maxs_z);
 516                 }
 517                 else
 518                 {
 519                         WriteShort(MSG_ENTITY, 0);
 520                         WriteCoord(MSG_ENTITY, self.maxs_x);
 521                         WriteCoord(MSG_ENTITY, self.maxs_y);
 522                         WriteCoord(MSG_ENTITY, self.maxs_z);
 523                 }
 524                 WriteShort(MSG_ENTITY, self.cnt);
 525                 WriteShort(MSG_ENTITY, compressShortVector(self.velocity));
 526                 WriteShort(MSG_ENTITY, compressShortVector(self.movedir));
 527                 WriteCoord(MSG_ENTITY, self.waterlevel);
 528                 WriteCoord(MSG_ENTITY, self.count);
 529                 WriteByte(MSG_ENTITY, self.glow_color);
 530                 WriteString(MSG_ENTITY, self.noise);
 531         }
 532         return 1;
 533 }
 534
 535 void pointparticles_use()
 536 {
 537         self.state = !self.state;
 538         self.SendFlags |= 2;
 539 }
 540
 541 void pointparticles_think()
 542 {
 543         if(self.origin != self.oldorigin)
 544         {
 545                 self.SendFlags |= 4;
 546                 self.oldorigin = self.origin;
 547         }
 548 }
 549
 550 void spawnfunc_func_pointparticles()
 551 {
 552         if(self.model != "")
 553                 setmodel(self, self.model);
 554         if(self.noise != "")
 555                 precache_sound (self.noise);
 556
 557         self.effects = EF_NODEPTHTEST;
 558         self.SendEntity = pointparticles_SendEntity;
 559         self.SendFlags = 3;
 560         if(!self.modelindex)
 561         {
 562                 self.modelindex = 4.2;
 563                 self.origin += self.mins;
 564                 self.maxs -= self.mins;
 565         }
 566         self.model = "net_entity";
 567         if(!self.cnt)
 568                 self.cnt = particleeffectnum(self.mdl);
 569         if(self.targetname != "")
 570         {
 571                 self.use = pointparticles_use;
 572                 if(self.spawnflags & 1)
 573                         self.state = 1;
 574                 else
 575                         self.state = 0;
 576         }
 577         else
 578                 self.state = 1;
 579         self.think = pointparticles_think;
 580         self.nextthink = time;
 581 }
 582
 583 void spawnfunc_func_sparks()
 584 {
 585         // self.cnt is the amount of sparks that one burst will spawn
 586         if(self.cnt < 1) {
 587                 self.cnt = 25.0; // nice default value
 588         }
 589
 590         // self.wait is the probability that a sparkthink will spawn a spark shower
 591         // range: 0 - 1, but 0 makes little sense, so...
 592         if(self.wait < 0.05) {
 593                 self.wait = 0.25; // nice default value
 594         }
 595
 596         self.count = self.cnt;
 597         self.mins = '0 0 0';
 598         self.maxs = '0 0 0';
 599         self.velocity = '0 0 -1';
 600         self.mdl = "func_sparks";
 601         self.impulse = 0.1 / self.wait;
 602         self.wait = 0;
 603
 604         spawnfunc_func_pointparticles();
 605 }
 606
 607 float rainsnow_SendEntity(float to)
 608 {
 609         WriteByte(MSG_ENTITY, ENT_CLIENT_RAINSNOW);
 610         WriteByte(MSG_ENTITY, self.state);
 611         WriteCoord(MSG_ENTITY, self.origin_x + self.mins_x);
 612         WriteCoord(MSG_ENTITY, self.origin_y + self.mins_y);
 613         WriteCoord(MSG_ENTITY, self.origin_z + self.mins_z);
 614         WriteCoord(MSG_ENTITY, self.maxs_x - self.mins_x);
 615         WriteCoord(MSG_ENTITY, self.maxs_y - self.mins_y);
 616         WriteCoord(MSG_ENTITY, self.maxs_z - self.mins_z);
 617         WriteShort(MSG_ENTITY, compressShortVector(self.dest));
 618         WriteShort(MSG_ENTITY, self.count);
 619         WriteByte(MSG_ENTITY, self.cnt);
 620         return 1;
 621 };
 622
 623 /*QUAKED spawnfunc_func_rain (0 .5 .8) ?
 624 This is an invisible area like a trigger, which rain falls inside of.
 625
 626 Keys:
 627 "velocity"
 628  falling direction (should be something like '0 0 -700', use the X and Y velocity for wind)
 629 "cnt"
 630  sets color of rain (default 12 - white)
 631 "count"
 632  adjusts density, this many particles fall every second for a 1024x1024 area, default is 2000
 633 */
 634 void spawnfunc_func_rain()
 635 {
 636         self.dest = self.velocity;
 637         self.velocity = '0 0 0';
 638         if (!self.dest)
 639                 self.dest = '0 0 -700';
 640         self.angles = '0 0 0';
 641         self.movetype = MOVETYPE_NONE;
 642         self.solid = SOLID_NOT;
 643         SetBrushEntityModel();
 644         self.model = "";
 645         if (!self.cnt)
 646                 self.cnt = 12;
 647         if (!self.count)
 648                 self.count = 2000;
 649         self.count = 0.01 * self.count * (self.size_x / 1024) * (self.size_y / 1024);
 650         if (self.count < 1)
 651                 self.count = 1;
 652         if(self.count > 65535)
 653                 self.count = 65535;
 654
 655         self.state = 1; // 1 is rain, 0 is snow
 656         self.effects = EF_NODEPTHTEST;
 657         self.SendEntity = rainsnow_SendEntity;
 658         self.Version = 1;
 659         self.modelindex = 1;
 660         self.model = "net_entity";
 661 };
 662
 663
 664 /*QUAKED spawnfunc_func_snow (0 .5 .8) ?
 665 This is an invisible area like a trigger, which snow falls inside of.
 666
 667 Keys:
 668 "velocity"
 669  falling direction (should be something like '0 0 -300', use the X and Y velocity for wind)
 670 "cnt"
 671  sets color of rain (default 12 - white)
 672 "count"
 673  adjusts density, this many particles fall every second for a 1024x1024 area, default is 2000
 674 */
 675 void spawnfunc_func_snow()
 676 {
 677         self.dest = self.velocity;
 678         self.velocity = '0 0 0';
 679         if (!self.dest)
 680                 self.dest = '0 0 -300';
 681         self.angles = '0 0 0';
 682         self.movetype = MOVETYPE_NONE;
 683         self.solid = SOLID_NOT;
 684         SetBrushEntityModel();
 685         self.model = "";
 686         if (!self.cnt)
 687                 self.cnt = 12;
 688         if (!self.count)
 689                 self.count = 2000;
 690         self.count = 0.01 * self.count * (self.size_x / 1024) * (self.size_y / 1024);
 691         if (self.count < 1)
 692                 self.count = 1;
 693         if(self.count > 65535)
 694                 self.count = 65535;
 695
 696         self.state = 0; // 1 is rain, 0 is snow
 697         self.effects = EF_NODEPTHTEST;
 698         self.SendEntity = rainsnow_SendEntity;
 699         self.Version = 1;
 700         self.modelindex = 1;
 701         self.model = "net_entity";
 702 };
 703
 704
 705 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float deathtype);
 706
 707 void misc_laser_aim()
 708 {
 709         vector a;
 710         if(self.enemy)
 711         {
 712                 a = vectoangles(self.enemy.origin - self.origin);
 713                 a_x = -a_x;
 714                 if(a != self.angles)
 715                 {
 716                         self.angles = a;
 717                         self.SendFlags |= 2;
 718                 }
 719         }
 720         if(self.origin != self.oldorigin)
 721                 self.SendFlags |= 1;
 722 }
 723
 724 void misc_laser_think()
 725 {
 726         vector o;
 727
 728         self.nextthink = time;
 729
 730         if(!self.count)
 731         {
 732                 self.enemy = find(world, targetname, self.target);
 733                 self.count = 1;
 734         }
 735
 736         if(!self.state)
 737                 return;
 738
 739         misc_laser_aim();
 740
 741         makevectors(self.angles);
 742         o = self.origin + 32768 * v_forward;
 743
 744         if(self.dmg)
 745         {
 746                 if(self.dmg < 0)
 747                         FireRailgunBullet(self.origin, o, 100000, 0, DEATH_HURTTRIGGER);
 748                 else
 749                         FireRailgunBullet(self.origin, o, self.dmg * frametime, 0, DEATH_HURTTRIGGER);
 750         }
 751 }
 752
 753 float laser_SendEntity(entity to, float fl)
 754 {
 755         WriteByte(MSG_ENTITY, ENT_CLIENT_LASER);
 756         WriteByte(MSG_ENTITY, fl);
 757         if(fl & 1)
 758         {
 759                 WriteCoord(MSG_ENTITY, self.origin_x);
 760                 WriteCoord(MSG_ENTITY, self.origin_y);
 761                 WriteCoord(MSG_ENTITY, self.origin_z);
 762         }
 763         if(fl & 8)
 764         {
 765                 WriteByte(MSG_ENTITY, self.colormod_x * 255.0);
 766                 WriteByte(MSG_ENTITY, self.colormod_y * 255.0);
 767                 WriteByte(MSG_ENTITY, self.colormod_z * 255.0);
 768                 WriteShort(MSG_ENTITY, self.cnt);
 769         }
 770         if(fl & 2)
 771         {
 772                 WriteCoord(MSG_ENTITY, self.angles_x);
 773                 WriteCoord(MSG_ENTITY, self.angles_y);
 774         }
 775         if(fl & 4)
 776                 WriteByte(MSG_ENTITY, self.state);
 777         return 1;
 778 }
 779
 780 /*QUAKED spawnfunc_misc_laser (.5 .5 .5) ? START_ON
 781 Any object touching the beam will be hurt
 782 Keys:
 783 "target"
 784  spawnfunc_target_position where the laser ends
 785 "mdl"
 786  name of beam end effect to use
 787 "colormod"
 788  color of the beam (default: red)
 789 "dmg"
 790  damage per second (-1 for a laser that kills immediately)
 791 */
 792 void laser_use()
 793 {
 794         self.state = !self.state;
 795         self.SendFlags |= 4;
 796         misc_laser_aim();
 797 }
 798
 799 void spawnfunc_misc_laser()
 800 {
 801         if(self.mdl)
 802         {
 803                 self.cnt = particleeffectnum(strcat(self.mdl, "_end"));
 804                 if(self.cnt < 0)
 805                         self.cnt = particleeffectnum(self.mdl);
 806         }
 807         else
 808         {
 809                 self.cnt = particleeffectnum("misc_laser_beam_end");
 810         }
 811         if(self.colormod == '0 0 0')
 812                 self.colormod = '1 0 0';
 813         if(!self.message)
 814                 self.message = "saw the light";
 815         self.think = misc_laser_think;
 816         self.nextthink = time;
 817
 818         self.effects = EF_NODEPTHTEST;
 819         self.SendEntity = laser_SendEntity;
 820         self.SendFlags = 15;
 821         self.modelindex = 1;
 822         self.model = "net_entity";
 823
 824         if(self.targetname != "")
 825         {
 826                 self.use = laser_use;
 827                 if(self.spawnflags & 1)
 828                         self.state = 1;
 829                 else
 830                         self.state = 0;
 831         }
 832         else
 833                 self.state = 1;
 834 }
 835
 836 // tZorks trigger impulse / gravity
 837 .float radius;
 838 .float falloff;
 839 .float strength;
 840 .float lastpushtime;
 841
 842 // targeted (directional) mode
 843 void trigger_impulse_touch1()
 844 {
 845         entity targ;
 846     float pushdeltatime;
 847     float str;
 848
 849         // FIXME: Better checking for what to push and not.
 850         if (other.classname != "player")
 851         if (other.classname != "corpse")
 852         if (other.classname != "body")
 853         if (other.classname != "gib")
 854         if (other.classname != "missile")
 855         if (other.classname != "casing")
 856         if (other.classname != "grenade")
 857         if (other.classname != "plasma")
 858         if (other.classname != "plasma_prim")
 859         if (other.classname != "plasma_chain")
 860         if (other.classname != "droppedweapon")
 861                 return;
 862
 863         if (other.deadflag && other.classname == "player")
 864                 return;
 865
 866         EXACTTRIGGER_TOUCH;
 867
 868     targ = find(world, targetname, self.target);
 869     if(!targ)
 870     {
 871         objerror("trigger_force without a (valid) .target!\n");
 872         remove(self);
 873         return;
 874     }
 875
 876     if(self.falloff == 1)
 877         str = (str / self.radius) * self.strength;
 878     else if(self.falloff == 2)
 879         str = (1 - (str / self.radius)) * self.strength;
 880     else
 881         str = self.strength;
 882
 883     pushdeltatime = time - other.lastpushtime;
 884     if (pushdeltatime > 0.15) pushdeltatime = 0;
 885     other.lastpushtime = time;
 886     if(!pushdeltatime) return;
 887
 888     other.velocity = other.velocity + normalize(targ.origin - self.origin) * self.strength * pushdeltatime;
 889 }
 890
 891 // Directionless (accelerator/decelerator) mode
 892 void trigger_impulse_touch2()
 893 {
 894     float pushdeltatime;
 895
 896         // FIXME: Better checking for what to push and not.
 897         if (other.classname != "player")
 898         if (other.classname != "corpse")
 899         if (other.classname != "body")
 900         if (other.classname != "gib")
 901         if (other.classname != "missile")
 902         if (other.classname != "casing")
 903         if (other.classname != "grenade")
 904         if (other.classname != "plasma")
 905         if (other.classname != "plasma_prim")
 906         if (other.classname != "plasma_chain")
 907         if (other.classname != "droppedweapon")
 908                 return;
 909
 910         if (other.deadflag && other.classname == "player")
 911                 return;
 912
 913         EXACTTRIGGER_TOUCH;
 914
 915     pushdeltatime = time - other.lastpushtime;
 916     if (pushdeltatime > 0.15) pushdeltatime = 0;
 917     other.lastpushtime = time;
 918     if(!pushdeltatime) return;
 919
 920     //if(self.strength > 1)
 921         other.velocity = other.velocity * (self.strength * pushdeltatime);
 922     //else
 923     //    other.velocity = other.velocity - (other.velocity * self.strength * pushdeltatime);
 924 }
 925
 926 // Spherical (gravity/repulsor) mode
 927 void trigger_impulse_touch3()
 928 {
 929     float pushdeltatime;
 930     float str;
 931
 932         // FIXME: Better checking for what to push and not.
 933         if (other.classname != "player")
 934         if (other.classname != "corpse")
 935         if (other.classname != "body")
 936         if (other.classname != "gib")
 937         if (other.classname != "missile")
 938         if (other.classname != "casing")
 939         if (other.classname != "grenade")
 940         if (other.classname != "plasma")
 941         if (other.classname != "plasma_prim")
 942         if (other.classname != "plasma_chain")
 943         if (other.classname != "droppedweapon")
 944                 return;
 945
 946         if (other.deadflag && other.classname == "player")
 947                 return;
 948
 949         EXACTTRIGGER_TOUCH;
 950
 951     pushdeltatime = time - other.lastpushtime;
 952     if (pushdeltatime > 0.15) pushdeltatime = 0;
 953     other.lastpushtime = time;
 954     if(!pushdeltatime) return;
 955
 956     setsize(self, '-1 -1 -1' * self.radius,'1 1 1' * self.radius);
 957
 958         str = min(self.radius, vlen(self.origin - other.origin));
 959
 960     if(self.falloff == 1)
 961         str = (1 - str / self.radius) * self.strength; // 1 in the inside
 962     else if(self.falloff == 2)
 963         str = (str / self.radius) * self.strength; // 0 in the inside
 964     else
 965         str = self.strength;
 966
 967     other.velocity = other.velocity + normalize(other.origin - self.origin) * str * pushdeltatime;
 968 }
 969
 970 /*QUAKED spawnfunc_trigger_impulse (.5 .5 .5) ?
 971 -------- KEYS --------
 972 target : If this is set, this points to the spawnfunc_target_position to which the player will get pushed.
 973          If not, this trigger acts like a damper/accelerator field.
 974
 975 strength : This is how mutch force to add in the direction of .target each second
 976            when .target is set. If not, this is hoe mutch to slow down/accelerate
 977            someting cought inside this trigger. (1=no change, 0,5 half speed rougthly each tic, 2 = doubble)
 978
 979 radius   : If set, act as a spherical device rather then a liniar one.
 980
 981 falloff : 0 = none, 1 = liniar, 2 = inverted liniar
 982
 983 -------- NOTES --------
 984 Use a brush textured with common/origin in the trigger entity to determine the origin of the force
 985 in directional and sperical mode. For damper/accelerator mode this is not nessesary (and has no effect).
 986 */
 987
 988 void spawnfunc_trigger_impulse()
 989 {
 990         EXACTTRIGGER_INIT;
 991     if(self.radius)
 992     {
 993         if(!self.strength) self.strength = 2000;
 994         setorigin(self, self.origin);
 995         setsize(self, '-1 -1 -1' * self.radius,'1 1 1' * self.radius);
 996         self.touch = trigger_impulse_touch3;
 997     }
 998     else
 999     {
1000         if(self.target)
1001         {
1002             if(!self.strength) self.strength = 950;
1003             self.touch = trigger_impulse_touch1;
1004         }
1005         else
1006         {
1007             if(!self.strength) self.strength = 0.9;
1008             self.touch = trigger_impulse_touch2;
1009         }
1010     }
1011 }
1012
1013 /*QUAKED spawnfunc_trigger_flipflop (.5 .5 .5) (-8 -8 -8) (8 8 8) START_ENABLED
1014 "Flip-flop" trigger gate... lets only every second trigger event through
1015 */
1016 void flipflop_use()
1017 {
1018         self.state = !self.state;
1019         if(self.state)
1020                 SUB_UseTargets();
1021 }
1022
1023 void spawnfunc_trigger_flipflop()
1024 {
1025         if(self.spawnflags & 1)
1026                 self.state = 1;
1027     self.use = flipflop_use;
1028 }
1029
1030 /*QUAKED spawnfunc_trigger_monoflop (.5 .5 .5) (-8 -8 -8) (8 8 8)
1031 "Mono-flop" trigger gate... turns one trigger event into one "on" and one "off" event, separated by a delay of "wait"
1032 */
1033 void monoflop_use()
1034 {
1035         self.nextthink = time + self.wait;
1036         if(self.state)
1037                 return;
1038         self.state = 1;
1039         SUB_UseTargets();
1040 }
1041
1042 void monoflop_think()
1043 {
1044         self.state = 0;
1045         SUB_UseTargets();
1046 }
1047
1048 void spawnfunc_trigger_monoflop()
1049 {
1050         if(!self.wait)
1051                 self.wait = 1;
1052     self.use = monoflop_use;
1053     self.think = monoflop_think;
1054         self.state = 0;
1055 }
1056
1057 void follow_think()
1058 {
1059         entity src, dst;
1060         src = find(world, targetname, self.killtarget);
1061         dst = find(world, targetname, self.target);
1062
1063         if(!src || !dst)
1064         {
1065                 objerror("follow: could not find target/killtarget");
1066                 return;
1067         }
1068
1069         dst.movetype = MOVETYPE_FOLLOW;
1070         dst.aiment = src;
1071         dst.punchangle = src.angles;
1072         dst.view_ofs = dst.origin - src.origin;
1073         dst.v_angle = dst.angles - src.angles;
1074
1075         remove(self);
1076 }
1077
1078 void spawnfunc_misc_follow()
1079 {
1080         self.think = follow_think;
1081         self.nextthink = time;
1082 }