data/qcsrc/server/ctf.qc

   1 .entity sprite;
   2 entity ctf_worldflaglist; // CTF flags in the map
   3 .entity ctf_worldflagnext;
   4 .float dropperid;
   5 .float ctf_droptime;
   6
   7 .float next_take_time;                  // the next time a player can pick up a flag (time + blah)
   8                                                                 /// I used this, in part, to fix the looping score bug. - avirox
   9 //float FLAGSCORE_PICKUP        =  1;
  10 //float FLAGSCORE_RETURN        =  5; // returned by owner team
  11 //float FLAGSCORE_RETURNROGUE   = 10; // returned by rogue team
  12 //float FLAGSCORE_CAPTURE       =  5;
  13
  14 #define FLAG_CARRY_POS '-15 0 7'
  15
  16 .float ctf_captureshielded; // set to 1 if the player is too bad to be allowed to capture
  17
  18 float captureshield_min_negscore; // punish at -20 points
  19 float captureshield_max_ratio; // punish at most 30% of each team
  20 float captureshield_force; // push force of the shield
  21
  22 float ctf_captureshield_shielded(entity p)
  23 {
  24         float s, se;
  25         entity e;
  26         float players_worseeq, players_total;
  27
  28         if(captureshield_max_ratio <= 0)
  29                 return FALSE;
  30
  31         s = PlayerScore_Add(p, SP_SCORE, 0);
  32         if(s >= -captureshield_min_negscore)
  33                 return FALSE;
  34
  35         players_total = players_worseeq = 0;
  36         FOR_EACH_PLAYER(e)
  37         {
  38                 if(e.team != p.team)
  39                         continue;
  40                 se = PlayerScore_Add(e, SP_SCORE, 0);
  41                 if(se <= s)
  42                         ++players_worseeq;
  43                 ++players_total;
  44         }
  45
  46         // player is in the worse half, if >= half the players are better than him, or consequently, if < half of the players are worse
  47         // use this rule here
  48
  49         if(players_worseeq >= players_total * captureshield_max_ratio)
  50                 return FALSE;
  51
  52         return TRUE;
  53 }
  54
  55 void ctf_captureshield_update(entity p, float dir)
  56 {
  57         float should;
  58         if(dir == p.ctf_captureshielded) // 0: shield only, 1: unshield only
  59         {
  60                 should = ctf_captureshield_shielded(p);
  61                 if(should != dir)
  62                 {
  63                         if(should)
  64                         {
  65                                 centerprint_atprio(p, CENTERPRIO_SHIELDING, "^3You are now ^4shielded^3 from the flag\n^3for ^1too many unsuccessful attempts^3 to capture.\n\n^3Make some defensive scores before trying again.");
  66                                 // TODO csqc notifier for this
  67                         }
  68                         else
  69                         {
  70                                 centerprint_atprio(p, CENTERPRIO_SHIELDING, "^3You are now free.\n\n^3Feel free to ^1try to capture^3 the flag again\n^3if you think you will succeed.");
  71                                 // TODO csqc notifier for this
  72                         }
  73                         p.ctf_captureshielded = should;
  74                 }
  75         }
  76 }
  77
  78 float ctf_captureshield_customize()
  79 {
  80         if not(other.ctf_captureshielded)
  81                 return FALSE;
  82         if(self.team == other.team)
  83                 return FALSE;
  84         return TRUE;
  85 }
  86
  87 void ctf_captureshield_touch()
  88 {
  89         if not(other.ctf_captureshielded)
  90                 return;
  91         if(self.team == other.team)
  92                 return;
  93         vector mymid;
  94         vector othermid;
  95         mymid = (self.absmin + self.absmax) * 0.5;
  96         othermid = (other.absmin + other.absmax) * 0.5;
  97         Damage(other, self, self, 0, DEATH_HURTTRIGGER, mymid, normalize(othermid - mymid) * captureshield_force);
  98         centerprint_atprio(other, CENTERPRIO_SHIELDING, "^3You are ^4shielded^3 from the flag\n^3for ^1too many unsuccessful attempts^3 to capture.\n\n^3Get some defensive scores before trying again.");
  99 }
 100
 101 void ctf_captureshield_spawn()
 102 {
 103         entity e;
 104         e = spawn();
 105         e.enemy = self;
 106         e.team = self.team;
 107         e.touch = ctf_captureshield_touch;
 108         e.customizeentityforclient = ctf_captureshield_customize;
 109         e.classname = "ctf_captureshield";
 110         e.effects = EF_ADDITIVE;
 111         e.movetype = MOVETYPE_NOCLIP;
 112         e.solid = SOLID_TRIGGER;
 113         e.avelocity = '7 0 11';
 114         setorigin(e, self.origin);
 115         setmodel(e, "models/onslaught/generator_shield.md3");
 116         e.scale = 0.5;
 117         setsize(e, e.scale * e.mins, e.scale * e.maxs);
 118         print(etos(e), "\n");
 119 }
 120
 121 float ctf_score_value(string parameter)
 122 {
 123         if(g_ctf_win_mode != 2)
 124                 return cvar(strcat("g_ctf_personal", parameter));
 125         else
 126                 return cvar(strcat("g_ctf_flag", parameter));
 127 }
 128
 129 void FakeTimeLimit(entity e, float t)
 130 {
 131         msg_entity = e;
 132         WriteByte(MSG_ONE, 3); // svc_updatestat
 133         WriteByte(MSG_ONE, 236); // STAT_TIMELIMIT
 134         if(t < 0)
 135                 WriteCoord(MSG_ONE, cvar("timelimit"));
 136         else
 137                 WriteCoord(MSG_ONE, (t + 1) / 60);
 138 }
 139
 140 float   flagcaptimerecord;
 141 .float  flagpickuptime;
 142 //.float  iscommander;
 143 //.float  ctf_state;
 144
 145 void() FlagThink;
 146 void() FlagTouch;
 147
 148 void place_flag()
 149 {
 150         if(!self.t_width)
 151                 self.t_width = 0.1; // frame animation rate
 152         if(!self.t_length)
 153                 self.t_length = 119; // maximum frame
 154
 155         setattachment(self, world, "");
 156         self.mdl = self.model;
 157         self.flags = FL_ITEM;
 158         self.solid = SOLID_TRIGGER;
 159         self.movetype = MOVETYPE_NONE;
 160         self.velocity = '0 0 0';
 161         self.origin_z = self.origin_z + 6;
 162         self.think = FlagThink;
 163         self.touch = FlagTouch;
 164         self.nextthink = time + 0.1;
 165         self.cnt = FLAG_BASE;
 166         self.mangle = self.angles;
 167         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 168         //self.effects = self.effects | EF_DIMLIGHT;
 169         if(self.noalign)
 170         {
 171                 self.dropped_origin = self.origin;
 172         }
 173         else
 174         {
 175                 droptofloor();
 176                 self.movetype = MOVETYPE_TOSS;
 177         }
 178         InitializeEntity(self, ctf_captureshield_spawn, INITPRIO_SETLOCATION);
 179 };
 180
 181 void LogCTF(string mode, float flagteam, entity actor)
 182 {
 183         string s;
 184         if(!cvar("sv_eventlog"))
 185                 return;
 186         s = strcat(":ctf:", mode);
 187         s = strcat(s, ":", ftos(flagteam));
 188         if(actor != world)
 189                 s = strcat(s, ":", ftos(actor.playerid));
 190         GameLogEcho(s);
 191 }
 192
 193 void RegenFlag(entity e)
 194 {
 195         setattachment(e, world, "");
 196         e.damageforcescale = 0;
 197         e.movetype = MOVETYPE_NONE;
 198         if(!self.noalign)
 199                 e.movetype = MOVETYPE_TOSS;
 200         e.solid = SOLID_TRIGGER;
 201         // TODO: play a sound here
 202         setorigin(e, e.dropped_origin);
 203         e.angles = e.mangle;
 204         e.cnt = FLAG_BASE;
 205         e.owner = world;
 206         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 207 };
 208
 209 void ReturnFlag(entity e)
 210 {
 211         if (e.owner)
 212         if (e.owner.flagcarried == e)
 213         {
 214                 WaypointSprite_DetachCarrier(e.owner);
 215                 e.owner.flagcarried = world;
 216
 217                 if(e.speedrunning)
 218                         FakeTimeLimit(e.owner, -1);
 219         }
 220         e.owner = world;
 221         RegenFlag(e);
 222 };
 223
 224 void DropFlag(entity e, entity penalty_receiver, entity attacker)
 225 {
 226         local entity p;
 227
 228         if(e.speedrunning)
 229         {
 230                 ReturnFlag(e);
 231                 return;
 232         }
 233
 234         if (!e.owner)
 235         {
 236                 dprint("FLAG: drop - no owner?!?!\n");
 237                 return;
 238         }
 239         p = e.owner;
 240         if (p.flagcarried != e)
 241         {
 242                 dprint("FLAG: drop - owner is not carrying this flag??\n");
 243                 return;
 244         }
 245         bprint(p.netname, "^7 lost the ", e.netname, "\n");
 246
 247         if(penalty_receiver)
 248                 UpdateFrags(penalty_receiver, -ctf_score_value("penalty_suicidedrop"));
 249         else
 250                 UpdateFrags(p, -ctf_score_value("penalty_drop"));
 251         PlayerScore_Add(p, SP_CTF_DROPS, +1);
 252         ctf_captureshield_update(p, 0); // shield only
 253         e.playerid = attacker.playerid;
 254         e.ctf_droptime = time;
 255
 256         if(p.waypointsprite_attachedforcarrier)
 257         {
 258                 WaypointSprite_Ping(p.waypointsprite_attachedforcarrier);
 259                 WaypointSprite_DetachCarrier(p);
 260         }
 261         else
 262         {
 263                 bprint("\{1}^1Flag carrier had no flag sprite?!?\n");
 264                 backtrace("Flag carrier had no flag sprite?!?");
 265         }
 266         LogCTF("dropped", p.team, p);
 267
 268         setattachment(e, world, "");
 269         e.damageforcescale = cvar("g_balance_ctf_damageforcescale");
 270
 271         if (p.flagcarried == e)
 272                 p.flagcarried = world;
 273         e.owner = world;
 274
 275         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 276         e.solid = SOLID_TRIGGER;
 277         e.movetype = MOVETYPE_TOSS;
 278         // setsize(e, '-16 -16 0', '16 16 74');
 279         setorigin(e, p.origin - '0 0 24' + '0 0 37');
 280         e.cnt = FLAG_DROPPED;
 281         e.velocity = '0 0 300';
 282         e.pain_finished = time + cvar("g_ctf_flag_returntime");//30;
 283
 284         trace_startsolid = FALSE;
 285         tracebox(e.origin, e.mins, e.maxs, e.origin, TRUE, e);
 286         if(trace_startsolid)
 287                 dprint("FLAG FALLTHROUGH will happen SOON\n");
 288 };
 289
 290 void AnimateFlag()
 291 {
 292         if(self.delay > time)
 293                 return;
 294         self.delay = time + self.t_width;
 295         if(self.nextthink > self.delay)
 296                 self.nextthink = self.delay;
 297
 298         self.frame = self.frame + 1;
 299         if(self.frame > self.t_length)
 300                 self.frame = 0;
 301 }
 302
 303 void FlagThink()
 304 {
 305         local entity e;
 306
 307         self.nextthink = time + 0.1;
 308
 309         if(self == ctf_worldflaglist) // only for the first flag
 310         {
 311                 FOR_EACH_CLIENT(e)
 312                         ctf_captureshield_update(e, 1); // release shield only
 313         }
 314
 315         AnimateFlag();
 316
 317         if(self.speedrunning)
 318         if(self.cnt == FLAG_CARRY)
 319         {
 320                 if(self.owner)
 321                 if(flagcaptimerecord)
 322                 if(time >= self.flagpickuptime + flagcaptimerecord)
 323                 {
 324                         bprint("The ", self.netname, " became impatient after ", ftos_decimals(flagcaptimerecord, 2), " seconds and returned itself\n");
 325
 326                         self.owner.impulse = 77; // returning!
 327                         e = self;
 328                         self = self.owner;
 329                         ReturnFlag(e);
 330                         ImpulseCommands();
 331                         self = e;
 332                         return;
 333                 }
 334         }
 335
 336         if (self.cnt == FLAG_BASE)
 337                 return;
 338
 339         if (self.cnt == FLAG_DROPPED)
 340         {
 341                 // flag fallthrough? FIXME remove this if bug is really fixed now
 342                 if(self.origin_z < -131072)
 343                 {
 344                         dprint("FLAG FALLTHROUGH just happened\n");
 345                         self.pain_finished = 0;
 346                 }
 347                 setattachment(self, world, "");
 348                 if (time > self.pain_finished)
 349                 {
 350                         bprint("The ", self.netname, " has returned to base\n");
 351                         sound (self, CHAN_TRIGGER, self.noise3, VOL_BASE, ATTN_NONE);
 352                         LogCTF("returned", self.team, world);
 353                         ReturnFlag(self);
 354                 }
 355                 return;
 356         }
 357
 358         e = self.owner;
 359         if (e.classname != "player" || (e.deadflag) || (e.flagcarried != self))
 360         {
 361                 dprint("CANNOT HAPPEN - player dead and STILL had a flag!\n");
 362                 DropFlag(self, world, world);
 363                 return;
 364         }
 365
 366         if(cvar("g_ctf_allow_drop"))
 367         if(e.BUTTON_USE)
 368                 DropFlag(self, e, world);
 369 };
 370
 371 void FlagTouch()
 372 {
 373         if(gameover) return;
 374
 375         local float t;
 376         local entity player;
 377         local string s, s0, h0, h1;
 378         if (other.classname != "player")
 379                 return;
 380         if (other.health < 1) // ignore dead players
 381                 return;
 382
 383         if (self.cnt == FLAG_CARRY)
 384                 return;
 385
 386         if (self.cnt == FLAG_BASE)
 387         if (other.team == self.team)
 388         if (other.flagcarried) // he's got a flag
 389         if (other.flagcarried.team != self.team) // capture
 390         {
 391                 if (other.flagcarried == world)
 392                 {
 393                         return;
 394                 }
 395                 if(player_count - currentbots <= 1) // at most one human
 396                 {
 397                         t = time - other.flagcarried.flagpickuptime;
 398                         s = ftos_decimals(t, 2);
 399                         s0 = ftos_decimals(flagcaptimerecord, 2);
 400                         h0 = db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"));
 401                         h1 = other.netname;
 402                         if(h0 == h1)
 403                                 h0 = "his";
 404                         else
 405                                 h0 = strcat(h0, "^7's"); // h0: display text for previous netname
 406                         if (flagcaptimerecord == 0)
 407                         {
 408                                 bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, " seconds\n");
 409                                 flagcaptimerecord = t;
 410                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(t));
 411                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), h1);
 412                                 GameLogEcho(strcat(":recordset:", ftos(other.playerid), ":", ftos(t)));
 413                         }
 414                         else if (t < flagcaptimerecord)
 415                         {
 416                                 bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, ", breaking ", strcat(h0, " previous record of ", s0, " seconds\n"));
 417                                 flagcaptimerecord = t;
 418                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(t));
 419                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), h1);
 420                                 GameLogEcho(strcat(":recordset:", ftos(other.playerid), ":", ftos(t)));
 421                         }
 422                         else
 423                         {
 424                                 bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, ", failing to break ", strcat(h0, " record of ", s0, " seconds\n"));
 425                         }
 426                 }
 427
 428                 PlayerTeamScore_Add(other, SP_CTF_CAPS, ST_CTF_CAPS, 1);
 429                 LogCTF("capture", other.flagcarried.team, other);
 430                 // give credit to the individual player
 431                 UpdateFrags(other, ctf_score_value("score_capture"));
 432
 433                 sound (other, CHAN_AUTO, self.noise2, VOL_BASE, ATTN_NONE);
 434                 WaypointSprite_DetachCarrier(other);
 435                 if(self.speedrunning)
 436                         FakeTimeLimit(other, -1);
 437                 RegenFlag (other.flagcarried);
 438                 other.flagcarried = world;
 439                 other.next_take_time = time + 1;
 440         }
 441         if (self.cnt == FLAG_BASE)
 442         if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2) // only red and blue team can steal flags
 443         if (other.team != self.team)
 444         if (!other.flagcarried)
 445         if (!other.ctf_captureshielded)
 446         {
 447                 if (other.next_take_time > time)
 448                         return;
 449                 // pick up
 450                 self.flagpickuptime = time; // used for timing runs
 451                 self.speedrunning = other.speedrunning; // if speedrunning, flag will self-return and teleport the owner back after the record
 452                 if(other.speedrunning)
 453                 if(flagcaptimerecord)
 454                         FakeTimeLimit(other, time + flagcaptimerecord);
 455                 self.solid = SOLID_NOT;
 456                 setorigin(self, self.origin); // relink
 457                 self.owner = other;
 458                 other.flagcarried = self;
 459                 self.cnt = FLAG_CARRY;
 460                 self.angles = '0 0 0';
 461                 bprint(other.netname, "^7 got the ", self.netname, "\n");
 462                 UpdateFrags(other, ctf_score_value("score_pickup_base"));
 463                 self.dropperid = other.playerid;
 464                 PlayerScore_Add(other, SP_CTF_PICKUPS, 1);
 465                 LogCTF("steal", self.team, other);
 466                 sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 467
 468                 FOR_EACH_PLAYER(player)
 469                         if(player.team == self.team)
 470                                 centerprint(player, "The enemy got your flag! Retrieve it!");
 471
 472                 self.movetype = MOVETYPE_NONE;
 473                 setorigin(self, FLAG_CARRY_POS);
 474                 setattachment(self, other, "");
 475                 WaypointSprite_AttachCarrier("flagcarrier", other);
 476                 WaypointSprite_UpdateTeamRadar(other.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '1 1 0');
 477                 WaypointSprite_Ping(self.sprite);
 478
 479                 return;
 480         }
 481
 482         if (self.cnt == FLAG_DROPPED)
 483         {
 484                 self.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 485                 if (other.team == self.team || (other.team != COLOR_TEAM1 && other.team != COLOR_TEAM2))
 486                 {
 487                         // return flag
 488                         bprint(other.netname, "^7 returned the ", self.netname, "\n");
 489
 490                         // punish the player who last had it
 491                         FOR_EACH_PLAYER(player)
 492                                 if(player.playerid == self.dropperid)
 493                                 {
 494                                         PlayerScore_Add(player, SP_SCORE, -ctf_score_value("penalty_returned"));
 495                                         ctf_captureshield_update(player, 0); // shield only
 496                                 }
 497
 498                         // punish the team who was last carrying it
 499                         if(self.team == COLOR_TEAM1)
 500                                 TeamScore_AddToTeam(COLOR_TEAM2, ST_SCORE, -ctf_score_value("penalty_returned"));
 501                         else
 502                                 TeamScore_AddToTeam(COLOR_TEAM1, ST_SCORE, -ctf_score_value("penalty_returned"));
 503
 504                         // reward the player who returned it
 505                         if(other.playerid == self.playerid) // is this the guy who killed the FC last?
 506                         {
 507                                 if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2)
 508                                         UpdateFrags(other, ctf_score_value("score_return_by_killer"));
 509                                 else
 510                                         UpdateFrags(other, ctf_score_value("score_return_rogue_by_killer"));
 511                         }
 512                         else
 513                         {
 514                                 if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2)
 515                                         UpdateFrags(other, ctf_score_value("score_return"));
 516                                 else
 517                                         UpdateFrags(other, ctf_score_value("score_return_rogue"));
 518                         }
 519                         PlayerScore_Add(other, SP_CTF_RETURNS, 1);
 520                         LogCTF("return", self.team, other);
 521                         sound (other, CHAN_AUTO, self.noise1, VOL_BASE, ATTN_NONE);
 522                         ReturnFlag(self);
 523                 }
 524                 else if (!other.flagcarried && (other.playerid != self.dropperid || time > self.ctf_droptime + cvar("g_balance_ctf_delay_collect")))
 525                 {
 526                         // pick up
 527                         self.solid = SOLID_NOT;
 528                         setorigin(self, self.origin); // relink
 529                         self.owner = other;
 530                         other.flagcarried = self;
 531                         self.cnt = FLAG_CARRY;
 532                         bprint(other.netname, "^7 picked up the ", self.netname, "\n");
 533
 534                         float f;
 535                         f = bound(0, (self.pain_finished - time) / cvar("g_ctf_flag_returntime"), 1);
 536                         //print("factor is ", ftos(f), "\n");
 537                         f = ctf_score_value("score_pickup_dropped_late") * (1-f)
 538                           + ctf_score_value("score_pickup_dropped_early") * f;
 539                         f = floor(f + 0.5);
 540                         self.dropperid = other.playerid;
 541                         //print("score is ", ftos(f), "\n");
 542
 543                         UpdateFrags(other, f);
 544                         PlayerScore_Add(other, SP_CTF_PICKUPS, 1);
 545                         LogCTF("pickup", self.team, other);
 546                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 547
 548                         FOR_EACH_PLAYER(player)
 549                                 if(player.team == self.team)
 550                                         centerprint(player, "The enemy got your flag! Retrieve it!");
 551
 552                         self.movetype = MOVETYPE_NONE;  // flag must have MOVETYPE_NONE here, otherwise it will drop through the floor...
 553                         setorigin(self, FLAG_CARRY_POS);
 554                         setattachment(self, other, "");
 555                         self.damageforcescale = 0;
 556                         WaypointSprite_AttachCarrier("flagcarrier", other);
 557                         WaypointSprite_UpdateTeamRadar(other.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '1 1 0');
 558                 }
 559         }
 560 };
 561
 562 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 563 CTF Starting point for a player
 564 in team one (Red).
 565
 566 Keys:
 567 "angle"
 568  viewing angle when spawning
 569 */
 570 void spawnfunc_info_player_team1()
 571 {
 572         self.team = COLOR_TEAM1; // red
 573         spawnfunc_info_player_deathmatch();
 574 };
 575 //self.team = 4;self.classname = "info_player_start";spawnfunc_info_player_start();};
 576
 577 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 578 CTF Starting point for a player in
 579 team two (Blue).
 580
 581 Keys:
 582 "angle"
 583  viewing angle when spawning
 584 */
 585 void spawnfunc_info_player_team2()
 586 {
 587         self.team = COLOR_TEAM2; // blue
 588         spawnfunc_info_player_deathmatch();
 589 };
 590 //self.team = 13;self.classname = "info_player_start";spawnfunc_info_player_start();};
 591
 592 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 593 CTF Starting point for a player in
 594 team three (Magenta).
 595
 596 Keys:
 597 "angle"
 598  viewing angle when spawning
 599 */
 600 void spawnfunc_info_player_team3()
 601 {
 602         self.team = COLOR_TEAM3; // purple
 603         spawnfunc_info_player_deathmatch();
 604 };
 605
 606
 607 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 608 CTF Starting point for a player in
 609 team four (Yellow).
 610
 611 Keys:
 612 "angle"
 613  viewing angle when spawning
 614 */
 615 void spawnfunc_info_player_team4()
 616 {
 617         self.team = COLOR_TEAM4; // yellow
 618         spawnfunc_info_player_deathmatch();
 619 };
 620
 621
 622
 623
 624 /*QUAKED spawnfunc_item_flag_team1 (0 0.5 0.8) (-48 -48 -37) (48 48 37)
 625 CTF flag for team one (Red).
 626 Multiple are allowed.
 627
 628 Keys:
 629 "angle"
 630  Angle the flag will point
 631 (minus 90 degrees)
 632 "model"
 633  model to use, note this needs red and blue as skins 0 and 1
 634  (default models/ctf/flag.md3)
 635 "noise"
 636  sound played when flag is picked up
 637  (default ctf/take.wav)
 638 "noise1"
 639  sound played when flag is returned by a teammate
 640  (default ctf/return.wav)
 641 "noise2"
 642  sound played when flag is captured
 643  (default ctf/redcapture.wav)
 644 "noise3"
 645  sound played when flag is lost in the field and respawns itself
 646  (default ctf/respawn.wav)
 647 */
 648
 649 void spawnfunc_item_flag_team1()
 650 {
 651         if (!g_ctf)
 652         {
 653                 remove(self);
 654                 return;
 655         }
 656
 657         //if(!cvar("teamplay"))
 658         //      cvar_set("teamplay", "3");
 659
 660         // link flag into ctf_worldflaglist
 661         self.ctf_worldflagnext = ctf_worldflaglist;
 662         ctf_worldflaglist = self;
 663
 664         self.classname = "item_flag_team";
 665         if(g_ctf_reverse)
 666         {
 667                 self.team = COLOR_TEAM2; // color 13 team (blue)
 668                 self.items = IT_KEY1; // silver key (bluish enough)
 669         }
 670         else
 671         {
 672                 self.team = COLOR_TEAM1; // color 4 team (red)
 673                 self.items = IT_KEY2; // gold key (redish enough)
 674         }
 675         self.netname = "^1RED^7 flag";
 676         self.target = "###item###";
 677         self.skin = 0;
 678         if(self.spawnflags & 1)
 679                 self.noalign = 1;
 680         if (!self.model)
 681                 self.model = "models/ctf/flag_red.md3";
 682         if (!self.noise)
 683                 self.noise = "ctf/take.wav";
 684         if (!self.noise1)
 685                 self.noise1 = "ctf/return.wav";
 686         if (!self.noise2)
 687                 self.noise2 = "ctf/redcapture.wav"; // blue team scores by capturing the red flag
 688         if (!self.noise3)
 689                 self.noise3 = "ctf/respawn.wav";
 690         precache_model (self.model);
 691         setmodel (self, self.model); // precision set below
 692         precache_sound (self.noise);
 693         precache_sound (self.noise1);
 694         precache_sound (self.noise2);
 695         precache_sound (self.noise3);
 696         //setsize(self, '-16 -16 -37', '16 16 37');
 697         setsize(self, PL_MIN + '0 0 -13', PL_MAX + '0 0 -13');
 698         setorigin(self, self.origin + '0 0 37');
 699         self.nextthink = time + 0.2; // start after doors etc
 700         self.think = place_flag;
 701
 702         if(!self.scale)
 703                 self.scale = 0.6;
 704         //if(!self.glow_size)
 705         //      self.glow_size = 50;
 706
 707         self.effects = self.effects | EF_LOWPRECISION;
 708         if(cvar("g_ctf_fullbrightflags"))
 709                 self.effects |= EF_FULLBRIGHT;
 710
 711         waypoint_spawnforitem(self);
 712
 713         WaypointSprite_SpawnFixed("redbase", self.origin + '0 0 37', self, sprite);
 714         WaypointSprite_UpdateTeamRadar(self.sprite, RADARICON_FLAG, '1 0 0');
 715
 716         precache_model("models/onslaught/generator_shield.md3");
 717 };
 718
 719 /*QUAKED spawnfunc_item_flag_team2 (0 0.5 0.8) (-48 -48 -24) (48 48 64)
 720 CTF flag for team two (Blue).
 721 Multiple are allowed.
 722
 723 Keys:
 724 "angle"
 725  Angle the flag will point
 726 (minus 90 degrees)
 727 "model"
 728  model to use, note this needs red and blue as skins 0 and 1
 729  (default models/ctf/flag.md3)
 730 "noise"
 731  sound played when flag is picked up
 732  (default ctf/take.wav)
 733 "noise1"
 734  sound played when flag is returned by a teammate
 735  (default ctf/return.wav)
 736 "noise2"
 737  sound played when flag is captured
 738  (default ctf/bluecapture.wav)
 739 "noise3"
 740  sound played when flag is lost in the field and respawns itself
 741  (default ctf/respawn.wav)
 742 */
 743
 744 void spawnfunc_item_flag_team2()
 745 {
 746         if (!g_ctf)
 747         {
 748                 remove(self);
 749                 return;
 750         }
 751         //if(!cvar("teamplay"))
 752         //      cvar_set("teamplay", "3");
 753
 754         // link flag into ctf_worldflaglist
 755         self.ctf_worldflagnext = ctf_worldflaglist;
 756         ctf_worldflaglist = self;
 757
 758         self.classname = "item_flag_team";
 759         if(g_ctf_reverse)
 760         {
 761                 self.team = COLOR_TEAM1; // color 4 team (red)
 762                 self.items = IT_KEY2; // gold key (redish enough)
 763         }
 764         else
 765         {
 766                 self.team = COLOR_TEAM2; // color 13 team (blue)
 767                 self.items = IT_KEY1; // silver key (bluish enough)
 768         }
 769         self.netname = "^4BLUE^7 flag";
 770         self.target = "###item###";
 771         self.skin = 0;
 772         if(self.spawnflags & 1)
 773                 self.noalign = 1;
 774         if (!self.model)
 775                 self.model = "models/ctf/flag_blue.md3";
 776         if (!self.noise)
 777                 self.noise = "ctf/take.wav";
 778         if (!self.noise1)
 779                 self.noise1 = "ctf/return.wav";
 780         if (!self.noise2)
 781                 self.noise2 = "ctf/bluecapture.wav"; // red team scores by capturing the blue flag
 782         if (!self.noise3)
 783                 self.noise3 = "ctf/respawn.wav";
 784         precache_model (self.model);
 785         setmodel (self, self.model); // precision set below
 786         precache_sound (self.noise);
 787         precache_sound (self.noise1);
 788         precache_sound (self.noise2);
 789         precache_sound (self.noise3);
 790         //setsize(self, '-16 -16 -37', '16 16 37');
 791         setsize(self, PL_MIN + '0 0 -13', PL_MAX + '0 0 -13');
 792         setorigin(self, self.origin + '0 0 37');
 793         self.nextthink = time + 0.2; // start after doors etc
 794         self.think = place_flag;
 795
 796         if(!self.scale)
 797                 self.scale = 0.6;
 798         //if(!self.glow_size)
 799         //      self.glow_size = 50;
 800
 801         self.effects = self.effects | EF_LOWPRECISION;
 802         if(cvar("g_ctf_fullbrightflags"))
 803                 self.effects |= EF_FULLBRIGHT;
 804
 805         waypoint_spawnforitem(self);
 806
 807         WaypointSprite_SpawnFixed("bluebase", self.origin + '0 0 37', self, sprite);
 808         WaypointSprite_UpdateTeamRadar(self.sprite, RADARICON_FLAG, '0 0 1');
 809
 810         precache_model("models/onslaught/generator_shield.md3");
 811 };
 812
 813
 814 /*QUAKED spawnfunc_ctf_team (0 .5 .8) (-16 -16 -24) (16 16 32)
 815 Team declaration for CTF gameplay, this allows you to decide what team
 816 names and control point models are used in your map.
 817
 818 Note: If you use spawnfunc_ctf_team entities you must define at least 2!  However, unlike
 819 domination, you don't need to make a blank one too.
 820
 821 Keys:
 822 "netname"
 823  Name of the team (for example Red, Blue, Green, Yellow, Life, Death, Offense, Defense, etc)
 824 "cnt"
 825  Scoreboard color of the team (for example 4 is red and 13 is blue)
 826
 827 */
 828
 829 void spawnfunc_ctf_team()
 830 {
 831         if (!g_ctf)
 832         {
 833                 remove(self);
 834                 return;
 835         }
 836         self.classname = "ctf_team";
 837         self.team = self.cnt + 1;
 838 };
 839
 840 // code from here on is just to support maps that don't have control point and team entities
 841 void ctf_spawnteam (string teamname, float teamcolor)
 842 {
 843         local entity oldself;
 844         oldself = self;
 845         self = spawn();
 846         self.classname = "ctf_team";
 847         self.netname = teamname;
 848         self.cnt = teamcolor;
 849
 850         spawnfunc_ctf_team();
 851
 852         self = oldself;
 853 };
 854
 855 // spawn some default teams if the map is not set up for ctf
 856 void ctf_spawnteams()
 857 {
 858         float numteams;
 859
 860         numteams = 2;//cvar("g_ctf_default_teams");
 861
 862         ctf_spawnteam("Red", COLOR_TEAM1 - 1);
 863         ctf_spawnteam("Blue", COLOR_TEAM2 - 1);
 864 };
 865
 866 void ctf_delayedinit()
 867 {
 868         // if no teams are found, spawn defaults
 869         if (find(world, classname, "ctf_team") == world)
 870                 ctf_spawnteams();
 871
 872         ScoreRules_ctf();
 873 };
 874
 875 void ctf_init()
 876 {
 877         InitializeEntity(world, ctf_delayedinit, INITPRIO_GAMETYPE);
 878         flagcaptimerecord = stof(db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time")));
 879
 880         captureshield_min_negscore = cvar("g_ctf_shield_min_negscore");
 881         captureshield_max_ratio = cvar("g_ctf_shield_max_ratio");
 882         captureshield_force = cvar("g_ctf_shield_force");
 883 };
 884
 885 void ctf_setstatus2(entity flag, float shift)
 886 {
 887         if (flag.cnt == FLAG_CARRY)
 888                 if (flag.owner == self)
 889                         self.items |= shift * 3;
 890                 else
 891                         self.items |= shift * 1;
 892         else if (flag.cnt == FLAG_DROPPED)
 893                 self.items |= shift * 2;
 894         else
 895         {
 896                 // no status bits
 897         }
 898 };
 899
 900 void ctf_setstatus()
 901 {
 902         self.items (-) IT_RED_FLAG_TAKEN;
 903         self.items (-) IT_RED_FLAG_LOST;
 904         self.items (-) IT_BLUE_FLAG_TAKEN;
 905         self.items (-) IT_BLUE_FLAG_LOST;
 906         self.items (-) IT_CTF_SHIELDED;
 907
 908         if (g_ctf) {
 909                 local entity flag;
 910                 float redflags, blueflags;
 911
 912                 if(self.ctf_captureshielded)
 913                         self.items |= IT_CTF_SHIELDED;
 914
 915                 redflags = 0;
 916                 blueflags = 0;
 917
 918                 for (flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext) if(flag.cnt != FLAG_BASE)
 919                 {
 920                         if(flag.items & IT_KEY2) // blue
 921                                 ++redflags;
 922                         else if(flag.items & IT_KEY1) // red
 923                                 ++blueflags;
 924                 }
 925
 926                 // blinking magic: if there is more than one flag, show one of these in a clever way
 927                 if(redflags)
 928                         redflags = mod(floor(time * redflags * 0.75), redflags);
 929                 if(blueflags)
 930                         blueflags = mod(floor(time * blueflags * 0.75), blueflags);
 931
 932                 for (flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext) if(flag.cnt != FLAG_BASE)
 933                 {
 934                         if(flag.items & IT_KEY2) // blue
 935                         {
 936                                 if(--redflags == -1) // happens exactly once (redflags is in 0..count-1, and will --'ed count times)
 937                                         ctf_setstatus2(flag, IT_RED_FLAG_TAKEN);
 938                         }
 939                         else if(flag.items & IT_KEY1) // red
 940                         {
 941                                 if(--blueflags == -1) // happens exactly once
 942                                         ctf_setstatus2(flag, IT_BLUE_FLAG_TAKEN);
 943                         }
 944                 }
 945         }
 946 };
 947 /*
 948 entity(float cteam) ctf_team_has_commander =
 949 {
 950         entity pl;
 951         if(cteam != COLOR_TEAM1 || cteam != COLOR_TEAM2)
 952                 return world;
 953
 954         FOR_EACH_REALPLAYER(pl) {
 955                 if(pl.team == cteam && pl.iscommander) {
 956                         return pl;
 957                 }
 958         }
 959         return world;
 960 };
 961
 962 void(entity e, float st) ctf_setstate =
 963 {
 964         e.ctf_state = st;
 965         ++e.version;
 966 };
 967
 968 void(float cteam) ctf_new_commander =
 969 {
 970         entity pl, plmax;
 971
 972         plmax = world;
 973         FOR_EACH_REALPLAYER(pl) {
 974                 if(pl.team == cteam) {
 975                         if(pl.iscommander) { // don't reassign if alreay there
 976                                 return;
 977                         }
 978                         if(plmax == world || plmax.frags < pl.frags) <<<<<<<<<<<<<<<<< BROKEN in new scoring system
 979                                 plmax = pl;
 980                 }
 981         }
 982         if(plmax == world) {
 983                 bprint(strcat(ColoredTeamName(cteam), " Team has no Commander!\n"));
 984                 return;
 985         }
 986
 987         plmax.iscommander = TRUE;
 988         ctf_setstate(plmax, 3);
 989         sprint(plmax, "^3You're the commander now!\n");
 990         centerprint(plmax, "^3You're the commander now!\n");
 991 };
 992
 993 void() ctf_clientconnect =
 994 {
 995         self.iscommander = FALSE;
 996
 997         if(!self.team || self.classname != "player") {
 998                 ctf_setstate(self, -1);
 999         } else
1000                 ctf_setstate(self, 0);
1001
1002         self.team_saved = self.team;
1003
1004         if(self.team != 0 && self.classname == "player" && !ctf_team_has_commander(self.team)) {
1005                 ctf_new_commander(self.team);
1006         }
1007 };
1008
1009 void() ctf_playerchanged =
1010 {
1011         if(!self.team || self.classname != "player") {
1012                 ctf_setstate(self, -1);
1013         } else if(self.ctf_state < 0 && self.classname == "player") {
1014                 ctf_setstate(self, 0);
1015         }
1016
1017         if(self.iscommander &&
1018            (self.classname != "player" || self.team != self.team_saved)
1019                 )
1020         {
1021                 self.iscommander = FALSE;
1022                 if(self.classname == "player")
1023                         ctf_setstate(self, 0);
1024                 else
1025                         ctf_setstate(self, -1);
1026                 ctf_new_commander(self.team_saved);
1027         }
1028
1029         self.team_saved = self.team;
1030
1031         ctf_new_commander(self.team);
1032 };
1033
1034 void() ctf_clientdisconnect =
1035 {
1036         if(self.iscommander)
1037         {
1038                 ctf_new_commander(self.team);
1039         }
1040 };
1041
1042 entity GetPlayer(string);
1043 float() ctf_clientcommand =
1044 {
1045         entity e;
1046         if(argv(0) == "order") {
1047                 if(!g_ctf) {
1048                         sprint(self, "This command is not supported in this gamemode.\n");
1049                         return TRUE;
1050                 }
1051                 if(!self.iscommander) {
1052                         sprint(self, "^1You are not the commander!\n");
1053                         return TRUE;
1054                 }
1055                 if(argv(2) == "") {
1056                         sprint(self, "Usage: order #player status   - (playernumber as in status)\n");
1057                         return TRUE;
1058                 }
1059                 e = GetPlayer(argv(1));
1060                 if(e == world) {
1061                         sprint(self, "Invalid player.\nUsage: order #player status   - (playernumber as in status)\n");
1062                         return TRUE;
1063                 }
1064                 if(e.team != self.team) {
1065                         sprint(self, "^3You can only give orders to your own team!\n");
1066                         return TRUE;
1067                 }
1068                 if(argv(2) == "attack") {
1069                         sprint(self, strcat("Ordering ", e.netname, " to attack!\n"));
1070                         sprint(e, "^1Attack!\n");
1071                         centerprint(e, "^7You've been ordered to^9\n^1Attack!\n");
1072                         ctf_setstate(e, 1);
1073                 } else if(argv(2) == "defend") {
1074                         sprint(self, strcat("Ordering ", e.netname, " to defend!\n"));
1075                         sprint(e, "^Defend!\n");
1076                         centerprint(e, "^7You've been ordered to^9\n^2Defend!\n");
1077                         ctf_setstate(e, 2);
1078                 } else {
1079                         sprint(self, "^7Invalid command, use ^3attack^7, or ^3defend^7.\n");
1080                 }
1081                 return TRUE;
1082         }
1083         return FALSE;
1084 };
1085 */