data/qcsrc/server/clientcommands.qc

   1 void ReadyCount();
   2 string ValidateMap(string vote);
   3 void(entity e) DropFlag;
   4 string MapVote_Suggest(string m);
   5
   6 .float floodcontrol_chat;
   7 .float floodcontrol_team;
   8 void Say(entity source, float teamsay, string msgin)
   9 {
  10         string msgstr, colorstr, cmsgstr, namestr;
  11         float flood;
  12         entity head;
  13
  14         if(!teamsay)
  15                 if(substring(msgin, 0, 1) == " ")
  16                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
  17
  18         msgin = formatmessage(msgin);
  19
  20         if(msgin == "")
  21                 return;
  22
  23         if(source.classname != "player")
  24                 colorstr = "^0"; // black for spectators
  25         else if(teams_matter)
  26                 colorstr = Team_ColorCode(source.team);
  27         else
  28                 teamsay = FALSE;
  29
  30         if(intermission_running)
  31                 teamsay = FALSE;
  32
  33         /*
  34          * using bprint solves this... me stupid
  35         // how can we prevent the message from appearing in a listen server?
  36         // for now, just give "say" back and only handle say_team
  37         if(!teamsay)
  38         {
  39                 clientcommand(self, strcat("say ", msgin));
  40                 return;
  41         }
  42         */
  43
  44         if(cvar("g_chat_teamcolors"))
  45                 namestr = playername(source);
  46         else
  47                 namestr = source.netname;
  48         if(teamsay)
  49         {
  50                 msgstr = strzone(strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin, "\n"));
  51                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", wordwrap(msgin, 50));
  52         }
  53         else
  54                 msgstr = strzone(strcat("\{1}", namestr, "^7: ", msgin, "\n"));
  55
  56         // FLOOD CONTROL
  57         flood = 0;
  58         {
  59                 float flood_spl;
  60                 float flood_burst;
  61                 float flood_lmax;
  62                 var .float flood_field;
  63                 float lines;
  64                 if(teamsay)
  65                 {
  66                         flood_spl = cvar("g_chat_flood_spl_team");
  67                         flood_burst = cvar("g_chat_flood_burst_team");
  68                         flood_lmax = cvar("g_chat_flood_lmax_team");
  69                         flood_field = floodcontrol_team;
  70                 }
  71                 else
  72                 {
  73                         flood_spl = cvar("g_chat_flood_spl");
  74                         flood_burst = cvar("g_chat_flood_burst");
  75                         flood_lmax = cvar("g_chat_flood_lmax");
  76                         flood_field = floodcontrol_chat;
  77                 }
  78                 flood_burst = max(0, flood_burst - 1);
  79                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
  80                 lines = ceil(strlennocol(msgstr) / 75);
  81                 if(flood_lmax && lines > flood_lmax)
  82                         flood = 2;
  83                 else if(time >= self.flood_field)
  84                         self.flood_field = max(time - flood_burst * flood_spl, self.flood_field) + lines * flood_spl;
  85                 else
  86                         flood = 1;
  87         }
  88
  89         if(flood)
  90         {
  91                 if(cvar("g_chat_flood_notify_flooder"))
  92                 {
  93                         if(flood == 1)
  94                                 sprint(self, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(self.flood_field - time), "^3 seconds\n"));
  95                         else if(flood == 2)
  96                                 sprint(self, "^3FLOOD CONTROL: ^7message too long\n");
  97                 }
  98                 else
  99                         sprint(self, msgstr);
 100                 ServerConsoleEcho(strcat("NOTE: ", playername(self), "^7 is flooding."), TRUE);
 101         }
 102         else if(teamsay)
 103         {
 104                 if(source.classname == "player")
 105                 {
 106                         FOR_EACH_REALPLAYER(head)
 107                         {
 108                                 if(head.team == source.team)
 109                                 {
 110                                         sprint(head, msgstr);
 111                                         centerprint(head, cmsgstr);
 112                                 }
 113                         }
 114                 }
 115                 else
 116                 {
 117                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 118                         {
 119                                 sprint(head, msgstr);
 120                                 centerprint(head, cmsgstr);
 121                         }
 122                 }
 123         }
 124         else
 125         {
 126                 bprint(msgstr);
 127                 //ServerConsoleEcho(substring(msgstr, 1, strlen(msgstr) - 2), TRUE);
 128         }
 129
 130         strunzone(msgstr);
 131 }
 132
 133 float VoteCheckNasty(string cmd)
 134 {
 135         if(strstrofs(cmd, ";", 0) >= 0)
 136                 return TRUE;
 137         if(strstrofs(cmd, "\n", 0) >= 0)
 138                 return TRUE;
 139         if(strstrofs(cmd, "\r", 0) >= 0)
 140                 return TRUE;
 141         if(strstrofs(cmd, "$", 0) >= 0)
 142                 return TRUE;
 143         return FALSE;
 144 }
 145
 146 string GetKickVoteVictim_newcommand;
 147 string GetKickVoteVictim_reason;
 148 entity GetKickVoteVictim(string vote, string cmd)
 149 {
 150         float tokens;
 151         float i, n, t;
 152         string ns;
 153         entity e;
 154
 155         tokens = tokenize(vote);
 156         ns = "";
 157
 158         if(tokens >= 2)
 159                 if(substring(argv(1), 0, 1) == "#")
 160                 {
 161                         ns = substring(argv(1), 1, 999);
 162                         t = 2;
 163                 }
 164
 165         if(tokens >= 3)
 166                 if(argv(1) == "#")
 167                 {
 168                         ns = argv(2);
 169                         t = 3;
 170                 }
 171
 172         if(ns != "")
 173         {
 174                 GetKickVoteVictim_reason = "";
 175                 for(i = t; i < tokens; ++i)
 176                         GetKickVoteVictim_reason = strcat(GetKickVoteVictim_reason, argv(i), " ");
 177                 GetKickVoteVictim_reason = substring(GetKickVoteVictim_reason, 0, strlen(GetKickVoteVictim_reason) - 1);
 178
 179                 n = stof(ns);
 180                 if(ns == ftos(n)) if(n >= 1) if(n <= maxclients)
 181                 {
 182                         e = edict_num(n);
 183                         if(clienttype(e) == CLIENTTYPE_REAL)
 184                         {
 185                                 GetKickVoteVictim_newcommand = strcat(argv(0), " # ", ns);
 186                                 return e;
 187                         }
 188                 }
 189         }
 190
 191         sprint(self, strcat("Usage: ", cmd, " ", argv(0), " #playernumber (as in \"status\")\n"));
 192         return world;
 193 }
 194
 195 void SV_ParseClientCommand(string s) {
 196         local string cmd;
 197         local entity e;
 198         local float i;
 199
 200         tokenize(s);
 201
 202         if(argv(0) == "vote") {
 203                 if(argv(1) == "help") {
 204                         local string vmasterdis;
 205                         if(!cvar("sv_vote_master")) {
 206                                 vmasterdis = " ^1(disabled)";
 207                         }
 208                         local string vcalldis;
 209                         if(!cvar("sv_vote_call")) {
 210                                 vcalldis = " ^1(disabled)";
 211                         }
 212                         sprint(self, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\" \"^2cmd vote dontcare^7\".\n");
 213                         sprint(self, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\" \"^2vdontcare^7\".\n");
 214                         sprint(self, "^7\"^2help^7\" shows this info.\n");
 215                         sprint(self, "^7\"^2status^7\" shows if there is a vote called and who called it.\n");
 216                         sprint(self, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7\n"));
 217                         sprint(self, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.\n");
 218                         sprint(self, strcat("^7\"^2master^7\" is used to call a vote to become a master.", vmasterdis, "^7\n"));
 219                         sprint(self, "^7\"^2do^7\" If you are a master you can execute a command without a vote. See the list of allowed commands.\n");
 220                         sprint(self, "^7\"^2yes^7\", \"^2no^7\" and \"^2dontcare^7\" to make your vote.\n");
 221                         sprint(self, "^7If enough of the players vote yes the vote is accepted.\n");
 222                         sprint(self, "^7If enough of the players vote no the vote is rejected.\n");
 223                         sprint(self, strcat("^7The vote will end after ", cvar_string("sv_vote_timeout"), "^7 seconds.\n"));
 224                         sprint(self, "^7You can call a vote for or execute these commands:\n");
 225                         sprint(self, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7\n"));
 226                 } else if(argv(1) == "status") {
 227                         if(votecalled) {
 228                                 sprint(self, strcat("^7Vote for ", votecalledvote_display, "^7 called by ^7", votecaller.netname, "^7.\n"));
 229                         } else {
 230                                 sprint(self, "^1No vote called.\n");
 231                         }
 232                 } else if(argv(1) == "call") {
 233                         if(cvar("sv_vote_call")) {
 234                                 if(votecalled) {
 235                                         sprint(self, "^1There is already a vote called.\n");
 236                                 } else {
 237                                         local string vote;
 238                                         vote = VoteParse();
 239                                         if(vote == "") {
 240                                                 sprint(self, "^1Your vote is empty. See help for more info.\n");
 241                                         } else if(time < self.vote_next) {
 242                                                 sprint(self, strcat("^1You have to wait ^2", ftos(self.vote_next - time), "^1 seconds before you can again call a vote.\n"));
 243                                         } else if(VoteCheckNasty(vote)) {
 244                                                 sprint(self, "Syntax error in command.\n");
 245                                         } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
 246                                                 // remap chmap to gotomap (forces intermission)
 247                                                 if(vote == "chmap" || vote == "gotomap") // won't work without arguments
 248                                                         return;
 249                                                 if(substring(vote, 0, 6) == "chmap ")
 250                                                         vote = strcat("gotomap ", substring(vote, 6, strlen(vote) - 6));
 251                                                 if(substring(vote, 0, 8) == "gotomap ")
 252                                                 {
 253                                                         if(!(vote = ValidateMap(substring(vote, 8, strlen(vote) - 8))))
 254                                                                 return;
 255                                                         vote = strcat("gotomap ", vote);
 256                                                 }
 257
 258                                                 // make kick and kickban votes a bit nicer (and reject them if formatted badly)
 259                                                 if(substring(vote, 0, 5) == "kick " || substring(vote, 0, 8) == "kickban ")
 260                                                 {
 261                                                         if(!(e = GetKickVoteVictim(vote, "vcall")))
 262                                                                 return;
 263                                                         vote = GetKickVoteVictim_newcommand;
 264                                                         votecalledvote_display = strzone(strcat("^1", vote, " (^7", e.netname, "^1): ", GetKickVoteVictim_reason));
 265                                                 }
 266                                                 else
 267                                                 {
 268                                                         votecalledvote_display = strzone(strcat("^1", vote));
 269                                                 }
 270                                                 votecalledvote = strzone(vote);
 271                                                 votecalled = TRUE;
 272                                                 votecalledmaster = FALSE;
 273                                                 votecaller = self; // remember who called the vote
 274                                                 votefinished = time + cvar("sv_vote_timeout");
 275                                                 votecaller.vote_vote = 1; // of course you vote yes
 276                                                 votecaller.vote_next = time + cvar("sv_vote_wait");
 277                                                 bprint("\{1}^2* ^3", votecaller.netname, "^2 calls a vote for ", votecalledvote_display, "\n");
 278                                                 VoteCount(); // needed if you are the only one
 279                                         } else {
 280                                                 sprint(self, "^1This vote is not ok. See help for more info.\n");
 281                                         }
 282                                 }
 283                         } else {
 284                                 sprint(self, "^1Vote calling is NOT allowed.\n");
 285                         }
 286                 } else if(argv(1) == "stop") {
 287                         if(!votecalled) {
 288                                 sprint(self, "^1No vote called.\n");
 289                         } else if(self == votecaller) { // the votecaller can stop a vote
 290                                 VoteStop(self);
 291                         } else if(self.vote_master) { // masters can, too
 292                                 VoteStop(self);
 293                         } else {
 294                                 sprint(self, "^1You are not allowed to stop that Vote.\n");
 295                         }
 296                 } else if(argv(1) == "master") {
 297                         if(cvar("sv_vote_master")) {
 298                                 if(votecalled) {
 299                                         sprint(self, "^1There is already a vote called.\n");
 300                                 } else {
 301                                         votecalled = TRUE;
 302                                         votecalledmaster = TRUE;
 303                                         votecalledvote = strzone("XXX");
 304                                         votecalledvote_display = strzone("^3master");
 305                                         votecaller = self; // remember who called the vote
 306                                         votefinished = time + cvar("sv_vote_timeout");
 307                                         votecaller.vote_vote = 1; // of course you vote yes
 308                                         votecaller.vote_next = time + cvar("sv_vote_wait");
 309                                         bprint("\{1}^2* ^3", votecaller.netname, "^2 calls a vote to become ^3master^2.\n");
 310                                         VoteCount(); // needed if you are the only one
 311                                 }
 312                         } else {
 313                                 sprint(self, "^1Vote to become master is NOT allowed.\n");
 314                         }
 315                 } else if(argv(1) == "do") {
 316                         if(argv(2) == "login") {
 317                                 local string masterpwd;
 318                                 masterpwd = cvar_string("sv_vote_master_password");
 319                                 if(masterpwd != "") {
 320                                         self.vote_master = (masterpwd == argv(3));
 321                                         if(self.vote_master) {
 322                                                 ServerConsoleEcho(strcat("Accepted master login from ", self.netname), TRUE);
 323                                                 bprint("\{1}^2* ^3", self.netname, "^2 logged in as ^3master^2\n");
 324                                         }
 325                                         else
 326                                                 ServerConsoleEcho(strcat("REJECTED master login from ", self.netname), TRUE);
 327                                 }
 328                                 else
 329                                         sprint(self, "^1You are NOT a master.\n");
 330                         } else if(self.vote_master) {
 331                                 local string dovote, dovote_display;
 332                                 dovote = VoteParse();
 333                                 if(dovote == "") {
 334                                         sprint(self, "^1Your command was empty. See help for more info.\n");
 335                                 } else if(VoteCheckNasty(dovote)) {
 336                                         sprint(self, "Syntax error in command.\n");
 337                                 } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
 338                                         if(dovote == "chmap" || dovote == "gotomap") // won't work without arguments
 339                                                 return;
 340                                         if(substring(dovote, 0, 6) == "chmap ")
 341                                                 dovote = strcat("gotomap ", substring(dovote, 6, strlen(dovote) - 6));
 342                                         if(substring(dovote, 0, 8) == "gotomap ")
 343                                         {
 344                                                 if(!(dovote = ValidateMap(substring(dovote, 8, strlen(dovote) - 8))))
 345                                                         return;
 346                                                 dovote = strcat("gotomap ", dovote);
 347                                         }
 348
 349                                         dovote_display = dovote;
 350                                         if(substring(dovote, 0, 5) == "kick " || substring(dovote, 0, 8) == "kickban ")
 351                                         {
 352                                                 if(!(e = GetKickVoteVictim(dovote, "vdo")))
 353                                                         return;
 354                                                 dovote = GetKickVoteVictim_newcommand;
 355                                                 dovote_display = strcat("^1", dovote, " (^7", e.netname, "^1): ", GetKickVoteVictim_reason);
 356                                         }
 357                                         bprint("\{1}^2* ^3", self.netname, "^2 used his ^3master^2 status to do \"^2", dovote_display, "^2\".\n");
 358                                         localcmd(strcat(dovote, "\n"));
 359                                 } else {
 360                                         sprint(self, "^1This command is not ok. See help for more info.\n");
 361                                 }
 362                         } else {
 363                                 sprint(self, "^1You are NOT a master.\n");
 364                         }
 365                 } else if(argv(1) == "yes") {
 366                         if(!votecalled) {
 367                                 sprint(self, "^1No vote called.\n");
 368                         } else if(self.vote_vote == 0
 369                                   || cvar("sv_vote_change")) {
 370                                 sprint(self, "^1You accepted the vote.\n");
 371                                 self.vote_vote = 1;
 372                                 centerprint_expire(self, CENTERPRIO_VOTE);
 373                                 if(!cvar("sv_vote_singlecount")) {
 374                                         VoteCount();
 375                                 }
 376                         } else {
 377                                 sprint(self, "^1You have already voted.\n");
 378                         }
 379                 } else if(argv(1) == "no") {
 380                         if(!votecalled) {
 381                                 sprint(self, "^1No vote called.\n");
 382                         } else if(self.vote_vote == 0
 383                                   || cvar("sv_vote_change")) {
 384                                 sprint(self, "^1You rejected the vote.\n");
 385                                 self.vote_vote = -1;
 386                                 centerprint_expire(self, CENTERPRIO_VOTE);
 387                                 if(!cvar("sv_vote_singlecount")) {
 388                                         VoteCount();
 389                                 }
 390                         } else {
 391                                 sprint(self, "^1You have already voted.\n");
 392                         }
 393                 } else if(argv(1) == "abstain" || argv(1) == "dontcare") {
 394                         if(!votecalled) {
 395                                 sprint(self, "^1No vote called.\n");
 396                         } else if(self.vote_vote == 0
 397                                   || cvar("sv_vote_change")) {
 398                                 sprint(self, "^1You abstained from your vote.\n");
 399                                 self.vote_vote = -2;
 400                                 centerprint_expire(self, CENTERPRIO_VOTE);
 401                                 if(!cvar("sv_vote_singlecount")) {
 402                                         VoteCount();
 403                                 }
 404                         } else {
 405                                 sprint(self, "^1You have already voted.\n");
 406                         }
 407                 } else {
 408                         // ignore this?
 409                         sprint(self, "^1Unknown vote command.\n");
 410                 }
 411         } else if(argv(0) == "autoswitch") {
 412                 // be backwards compatible with older clients (enabled)
 413                 self.autoswitch = ("0" != argv(1));
 414                 local string autoswitchmsg;
 415                 if (self.autoswitch) {
 416                         autoswitchmsg = "on";
 417                 } else {
 418                         autoswitchmsg = "off";
 419                 }
 420                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 421         } else if(argv(0) == "clientversion") {
 422                 if (argv(1) == "$gameversion") {
 423                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 424                         // either that or someone wants to be funny
 425                         self.version = 1;
 426                 } else {
 427                         self.version = stof(argv(1));
 428                 }
 429                 if(self.version != cvar("gameversion"))
 430                 {
 431                         self.classname = "observer";
 432                         self.frags = -2;
 433                         PutClientInServer();
 434                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 435                         //JoinBestTeam(self, FALSE, TRUE);
 436                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 437                         self.classname = "observer";
 438                         stuffcmd(self,"menu_showteamselect\n");
 439                 }
 440         } else if(argv(0) == "reportcvar") { // old system
 441                 GetCvars(1);
 442         } else if(argv(0) == "sentcvar") { // new system
 443                 GetCvars(1);
 444         } else if(argv(0) == "spectate") {
 445                 if(g_lms || g_arena)
 446                         return; // don't allow spectating in lms, unless player runs out of lives
 447                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 448                         if(self.flagcarried)
 449                                 DropFlag(self.flagcarried);
 450                         kh_Key_DropAll(self, TRUE);
 451                         WaypointSprite_PlayerDead();
 452                         DistributeFragsAmongTeam(self, self.team, 1.0);
 453                         self.classname = "observer";
 454                         if(blockSpectators)
 455                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 456                         PutClientInServer();
 457                 }
 458         } else if(argv(0) == "join") {
 459                 if(!g_arena)
 460                 if (self.classname != "player" && !lockteams)
 461                 {
 462                         if(isJoinAllowed()) {
 463                                 self.classname = "player";
 464                                 self.frags = 0;
 465                                 bprint ("^4", self.netname, "^4 is playing now\n");
 466                                 PutClientInServer();
 467                         }
 468                         else {
 469                                 //player may not join because of g_maxplayers is set
 470                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 471                         }
 472                 }
 473         } else if( argv(0) == "selectteam" ) {
 474                 if( !cvar("teamplay") ) {
 475                         sprint( self, "selecteam can only be used in teamgames\n");
 476                 } else if(cvar("g_campaign")) {
 477                         //JoinBestTeam(self, 0);
 478                 } else if(lockteams) {
 479                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 480                 } else if( argv(1) == "red" ) {
 481                         DoTeamChange(COLOR_TEAM1);
 482                 } else if( argv(1) == "blue" ) {
 483                         DoTeamChange(COLOR_TEAM2);
 484                 } else if( argv(1) == "yellow" ) {
 485                         DoTeamChange(COLOR_TEAM3);
 486                 } else if( argv(1) == "pink" ) {
 487                         DoTeamChange(COLOR_TEAM4);
 488                 } else if( argv(1) == "auto" ) {
 489                         DoTeamChange(-1);
 490                 } else {
 491                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 492                 }
 493         } else if(argv(0) == "ready") {
 494                 if(cvar("sv_ready_restart"))
 495                 {
 496                         if(!restart_countdown || cvar("sv_ready_restart_repeatable"))
 497                         {
 498                                 self.ready = TRUE;
 499                                 bprint(self.netname, "^2 is ready\n");
 500                                 ReadyCount();
 501                         } else {
 502                                 sprint(self, "^1game has already been restarted\n");
 503                         }
 504                 }
 505         } else if(argv(0) == "maplist") {
 506                 local float n;
 507                 local string col;
 508                 n = tokenize(cvar_string("g_maplist"));
 509                 sprint(self, "^7Maps in list: ");
 510                 for(i = 0; i < n; ++i)
 511                 {
 512                         if(mod(i, 2))
 513                                 col = "^2";
 514                         else
 515                                 col = "^3";
 516                         sprint(self, strcat(col, argv(i), " "));
 517                 }
 518                 sprint(self, "\n");
 519 #ifdef MAPINFO
 520         } else if(argv(0) == "lsmaps") {
 521                 sprint(self, "^7Maps available: ");
 522                 for(i = 0; i < MapInfo_count; ++i)
 523                 {
 524                         if(mod(i, 2))
 525                                 col = "^2";
 526                         else
 527                                 col = "^3";
 528                         sprint(self, strcat(col, MapInfo_BSPName_ByID(i), " "));
 529                 }
 530                 sprint(self, "\n");
 531 #endif
 532         } else if(argv(0) == "teamstatus") {
 533                 PrintScoreboard(self);
 534         } else if(argv(0) == "voice") {
 535                 VoiceMessage(argv(1));
 536         } else if(argv(0) == "say") {
 537                 Say(self, FALSE, substring(s, 4, strlen(s) - 4));
 538                 //clientcommand(self, formatmessage(s));
 539         } else if(argv(0) == "say_team") {
 540                 Say(self, TRUE, substring(s, 9, strlen(s) - 9));
 541                 //clientcommand(self, formatmessage(s));
 542         } else if(argv(0) == "info") {
 543                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 544                 if(cmd == "")
 545                         sprint(self, "ERROR: unsupported info command\n");
 546                 else
 547                         wordwrap_sprint(cmd, 1111);
 548         } else if(argv(0) == "suggestmap") {
 549                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 550         } else {
 551                 cmd = argv(0);
 552                 /* checks not needed any more since DP has separated clientcommands and regular commands
 553                 if(cmd != "status")
 554                 if(cmd != "name")
 555                 //if(cmd != "say") // handled above
 556                 //if(cmd != "say_team") // handled above
 557                 if(cmd != "tell")
 558                 if(cmd != "color")
 559                 if(cmd != "kill")
 560                 if(cmd != "pause")
 561                 if(cmd != "kick")
 562                 if(cmd != "ping")
 563                 if(cmd != "pings")
 564                 if(cmd != "ban")
 565                 if(cmd != "pmodel")
 566                 if(cmd != "rate")
 567                 if(cmd != "playermodel")
 568                 if(cmd != "playerskin")
 569                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
 570                 {
 571                         ServerConsoleEcho(strcat("WARNING: Invalid clientcommand by ", self.netname, ": ", s), TRUE);
 572                         return;
 573                 }
 574                 */
 575                 clientcommand(self,s);
 576         }
 577 }
 578
 579 string ValidateMap(string m)
 580 {
 581 #ifdef MAPINFO
 582         m = MapInfo_FixName(m);
 583         if(!m)
 584         {
 585                 sprint(self, "This map is not available on this server.\n");
 586                 return string_null;
 587         }
 588 #else
 589         if(!cvar("sv_vote_change_gametype"))
 590                 if(!IsSameGametype(m))
 591                 {
 592                         sprint(self, "This server does not allow changing the game type by map votes.\n");
 593                         return string_null;
 594                 }
 595 #endif
 596         if(!cvar("sv_vote_override_mostrecent"))
 597                 if(Map_IsRecent(m))
 598                 {
 599                         sprint(self, "This server does not allow for recent maps to be played again. Please be patient for some rounds.\n");
 600                         return string_null;
 601                 }
 602 #ifdef MAPINFO
 603         if(!MapInfo_CheckMap(m))
 604         {
 605                 sprint(self, strcat("^1Invalid mapname, \"^3", m, "^1\" does not support the current game mode.\n"));
 606                 return string_null;
 607         }
 608 #else
 609         if(!TryFile(strcat("maps/", m, ".mapcfg")))
 610         {
 611                 sprint(self, strcat("^1Invalid mapname, \"^3", m, "^1\" does not exist on this server.\n"));
 612                 return string_null;
 613         }
 614 #endif
 615
 616         return m;
 617 }
 618
 619
 620 void VoteThink() {
 621         if(votefinished > 0 // a vote was called
 622             && time > votefinished) // time is up
 623         {
 624                 VoteCount();
 625         }
 626 }
 627
 628 string VoteParse() {
 629         local float index;
 630         index = 3;
 631         local string vote;
 632         vote = argv(2);
 633         while(argv(index) != "") {
 634                 vote = strcat(vote, " ", argv(index));
 635                 index++;
 636         }
 637
 638         // necessary for some of the string operations
 639         vote = strzone(vote);
 640
 641         // now we remove some things that could be misused
 642         index = 0;
 643         local float found;
 644         found = FALSE;
 645         local float votelength;
 646         votelength = strlen(vote);
 647         while(!found && index < votelength)
 648         {
 649                 local string badchar;
 650                 badchar = substring(vote, index, 1);
 651                 if(badchar == ";"
 652                    || badchar == "\r"
 653                    || badchar == "\n")
 654                 {
 655                         found = TRUE;
 656                 } else {
 657                         index++;
 658                 }
 659         }
 660         return substring(vote, 0, index);
 661 }
 662
 663 float VoteAllowed(string votecommand) {
 664         tokenize(cvar_string("sv_vote_commands"));
 665         local float index;
 666         index = 0;
 667         while(argv(index) != "") {
 668                 local string allowed;
 669                 allowed = argv(index);
 670                 if(votecommand == allowed) {
 671                         return TRUE;
 672                 }
 673                 index++;
 674         }
 675         return FALSE;
 676 }
 677
 678 void VoteReset() {
 679         local entity player;
 680
 681         FOR_EACH_CLIENT(player)
 682         {
 683                 player.vote_vote = 0;
 684                 centerprint_expire(player, CENTERPRIO_VOTE);
 685         }
 686
 687         if(votecalled)
 688         {
 689                 strunzone(votecalledvote);
 690                 strunzone(votecalledvote_display);
 691         }
 692
 693         votecalled = FALSE;
 694         votecalledmaster = FALSE;
 695         votefinished = 0;
 696 }
 697
 698 void VoteAccept() {
 699         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ^1", votecalledvote_display, "^2 was accepted\n");
 700         if(votecalledmaster)
 701         {
 702                 votecaller.vote_master = 1;
 703         } else {
 704                 localcmd(strcat(votecalledvote, "\n"));
 705         }
 706         votecaller.vote_next = 0; // people like your votes, no wait for next vote
 707         VoteReset();
 708 }
 709
 710 void VoteReject() {
 711         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ", votecalledvote_display, "^2 was rejected\n");
 712         VoteReset();
 713 }
 714
 715 void VoteTimeout() {
 716         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ", votecalledvote_display, "^2 timed out\n");
 717         VoteReset();
 718 }
 719
 720 void VoteStop(entity stopper) {
 721         bprint("\{1}^2* ^3", stopper.netname, "^2 stopped ^3", votecaller.netname, "^2's vote\n");
 722         if(stopper == votecaller) {
 723                 // no wait for next vote so you can correct your vote
 724                 votecaller.vote_next = 0;
 725         }
 726         VoteReset();
 727 }
 728
 729 void VoteNag() {
 730         if(votecalled)
 731                 if(self.vote_vote == 0)
 732                         centerprint_atprio(self, CENTERPRIO_VOTE, strcat("^7^3", votecaller.netname, "^2 called a vote for ", votecalledvote_display, "\n\n^2You have not voted yet!\n^2HINT: By default, F1 is yes and F2 is no."));
 733 }
 734
 735 void VoteSpam(float yescount, float nocount, float abstaincount, float notvoters, float mincount)
 736 {
 737         string s;
 738         if(mincount >= 0)
 739         {
 740                 s = strcat("\{1}^2* vote results: ^1", ftos(yescount), "^2:^1");
 741                 s = strcat(s, ftos(nocount), "^2 (^1");
 742                 s = strcat(s, ftos(mincount), "^2 needed), ^1");
 743                 s = strcat(s, ftos(abstaincount), "^2 didn't care, ^1");
 744                 s = strcat(s, ftos(notvoters), "^2 didn't vote\n");
 745         }
 746         else
 747         {
 748                 s = strcat("\{1}^2* vote results: ^1", ftos(yescount), "^2:^1");
 749                 s = strcat(s, ftos(nocount), "^2 (^1");
 750                 s = strcat(s, ftos(abstaincount), "^2 didn't care, ^1");
 751                 s = strcat(s, ftos(notvoters), "^2 didn't have to vote\n");
 752         }
 753         bprint(s);
 754 }
 755
 756 void VoteCount() {
 757         local float playercount;
 758         playercount = 0;
 759         local float yescount;
 760         yescount = 0;
 761         local float nocount;
 762         nocount = 0;
 763         local float abstaincount;
 764         abstaincount = 0;
 765         local entity player;
 766
 767         FOR_EACH_REALCLIENT(player)
 768         {
 769                 if(player.vote_vote == -1) {
 770                         nocount++;
 771                 } else if(player.vote_vote == 1) {
 772                         yescount++;
 773                 } else if(player.vote_vote == -2) {
 774                         abstaincount++;
 775                 }
 776                 playercount++;
 777         }
 778
 779         if((playercount == 1) && votecalledmaster) {
 780                 // if only one player is on the server becoming vote
 781                 // master is not allowed.  This could be used for
 782                 // trolling or worse. 'self' is the user who has
 783                 // called the vote because this function is called
 784                 // by SV_ParseClientCommand. Maybe all voting should
 785                 // be disabled for a single player?
 786                 sprint(self, "^1You are the only player on this server so you can not become vote master.\n");
 787                 votecaller.vote_next = 0;
 788                 VoteReset();
 789         } else {
 790                 float votefactor;
 791                 votefactor = bound(0.5, cvar("sv_vote_majority_factor"), 0.999);
 792                 if(yescount > (playercount - abstaincount) * votefactor)
 793                 {
 794                         VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, -1);
 795                         VoteAccept();
 796                 }
 797                 else if(nocount >= (playercount - abstaincount) * (1 - votefactor)) // that means, yescount cannot reach minyes any more
 798                 {
 799                         VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, -1);
 800                         VoteReject();
 801                 }
 802                 else if(time > votefinished)
 803                 {
 804                         if(cvar("sv_vote_simple_majority"))
 805                         {
 806                                 VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, floor((yescount + nocount) * votefactor) + 1);
 807                                 if(yescount > (yescount + nocount) * votefactor)
 808                                         VoteAccept();
 809                                 else if(yescount + nocount > 0)
 810                                         VoteReject();
 811                                 else
 812                                         VoteTimeout();
 813                         }
 814                         else
 815                         {
 816                                 VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, floor((playercount - abstaincount) * votefactor) + 1);
 817                                 VoteTimeout();
 818                         }
 819                 }
 820         }
 821 }
 822
 823 float timelimit_orig;
 824
 825 /**
 826  * Counts how many players are ready. If not enough players are ready, the function
 827  * does nothing. If all players are ready, the timelimit will be extended and the
 828  * restart_countdown variable is set to allow other functions like PlayerPostThink
 829  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 830  * is not set the map will be resetted.
 831  *
 832  * Function is called after the server receives a 'ready' sign from a player.
 833  */
 834 void ReadyCount()
 835 {
 836         local entity e;
 837         local float r, p;
 838
 839         FOR_EACH_REALPLAYER(e)
 840         {
 841                 p += 1;
 842                 if(e.ready)
 843                         r += 1;
 844         }
 845
 846         if(cvar("sv_ready_restart_nag")) {
 847                 if(!readyNagActive) {
 848                         readyNagger = spawn();
 849                         readyNagger.think = readyNagger_Think;
 850                         readyNagger.cnt = cvar("sv_ready_restart_nag_duration");
 851                         readyNagger.nextthink = time;
 852                         readyNagActive = 1;
 853                 }
 854         }
 855
 856         if(!p || r < p)
 857                 return;
 858
 859         bprint("^1Server is restarting...\n");
 860
 861         // no arena, assault support yet...
 862         if(g_arena | g_assault | gameover | intermission_running)
 863                 localcmd("restart\n");
 864
 865         if(readyNagActive) { //if every player is ready, remove the ready-nagger again
 866                 readyNagActive = 0;
 867                 remove(readyNagger);
 868         }
 869
 870         restart_countdown = time + RESTART_COUNTDOWN;
 871         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 872         //reset the .ready status of all players (also spectators)
 873         FOR_EACH_CLIENT(e)
 874         {
 875                 e.ready = 0;
 876         }
 877         if(0<cvar("timelimit"))
 878         {
 879                 // remember original timelimit on first restart
 880                 if(!timelimit_orig)
 881                         timelimit_orig = cvar("timelimit");
 882                 cvar_set("timelimit", ftos(timelimit_orig + ceil(restart_countdown)/60));
 883         }
 884         if(cvar("teamplay_lockonrestart") && teams_matter) {
 885                 lockteams = 1;
 886                 bprint("^1The teams are now locked.\n");
 887         }
 888
 889         //initiate the restart-countdown-announcer entity
 890         restartAnnouncer = spawn();
 891         restartAnnouncer.think = restartAnnouncer_Think;
 892         restartAnnouncer.nextthink = time;
 893         restartAnnouncer.cnt = RESTART_COUNTDOWN;
 894
 895         //play the prepareforbattle sound to everyone
 896         sound(world, CHAN_AUTO, "announcer/robotic/prepareforbattle.wav", 1, ATTN_NONE);
 897
 898         //reset map immediately if this cvar is not set
 899         if (!cvar("sv_ready_restart_after_countdown"))
 900                 reset_map();
 901
 902         if(cvar("sv_eventlog"))
 903                 GameLogEcho(":restart", FALSE);
 904 }
 905
 906 /**
 907  * Centerprints the information to all players who didn't ready up yet to do so.
 908  */
 909 void readyNagger_Think() {
 910         local entity plr;
 911         if(self.cnt <= 0) { //have a break showing the ready nag
 912                 //make sure that the old ready-nag-centerprint isn't shown too long:
 913                 FOR_EACH_REALCLIENT(plr) {
 914                         if(plr.classname == "player") {
 915                                 if (!plr.ready)
 916                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 917                         }
 918                 }
 919                 self.cnt = cvar("sv_ready_restart_nag_duration");
 920                 self.nextthink = time + cvar("sv_ready_restart_nag_interval");
 921         }
 922         else {
 923                 //show the ready nagging to all players who aren't ready yet
 924                 FOR_EACH_REALCLIENT(plr) {
 925                         if(plr.classname == "player") {
 926                                 if (!plr.ready) {
 927                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "^2Please ready up (F4 by default)!");
 928                                         //play reminder sound once the centerprint appears for the first time after the pause:
 929                                         if (self.cnt == cvar("sv_ready_restart_nag_duration"))
 930                                                 play2(plr, "misc/talk2.wav");
 931                                 }
 932                         }
 933                 }
 934
 935                 self.nextthink = time + 1;
 936                 self.cnt -= 1;
 937         }
 938 }
 939
 940 /**
 941  * Shows the restart countdown for all players.
 942  * Plays the countdown sounds for the seconds 3, 2 1, begin for everyone.
 943  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 944  * is set to 1).
 945  */
 946 void restartAnnouncer_Think() {
 947         local entity plr;
 948         local string s;
 949         if(self.cnt <= 0) { //show the "Begin" message and
 950                 if (cvar("sv_ready_restart_after_countdown")) {
 951                         restart_mapalreadyrestarted = 1;
 952                         reset_map();
 953                 }
 954
 955                 FOR_EACH_REALCLIENT(plr) {
 956                         if(plr.classname == "player") {
 957                                 s = strcat(NEWLINES, "^1Begin!");
 958                                 centerprint(plr, s);
 959                         }
 960                 }
 961                 sound(world, CHAN_AUTO, "announcer/robotic/begin.wav", 1, ATTN_NONE);
 962
 963                 remove(self);
 964                 return;
 965         }
 966         else {
 967                 FOR_EACH_REALCLIENT(plr) {
 968                         if(plr.classname == "player") {
 969                                 s = strcat(NEWLINES, "^1Game starts in ", ftos(self.cnt), " seconds");
 970                                 centerprint(plr, s);
 971                         }
 972                 }
 973
 974                 if(self.cnt <= 3) {
 975                         sound(world, CHAN_AUTO, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"), 1, ATTN_NONE);
 976                 }
 977                 self.nextthink = time + 1;
 978                 self.cnt -= 1;
 979         }
 980 }