data/qcsrc/server/clientcommands.qc

   1 void ReadyCount();
   2 string ValidateMap(string vote);
   3 void(entity e) DropFlag;
   4 string MapVote_Suggest(string m);
   5
   6 .float floodcontrol_chat;
   7 .float floodcontrol_team;
   8 void Say(entity source, float teamsay, string msgin)
   9 {
  10         string msgstr, colorstr, cmsgstr, namestr;
  11         float flood;
  12         entity head;
  13
  14         if(!teamsay)
  15                 if(substring(msgin, 0, 1) == " ")
  16                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
  17
  18         msgin = formatmessage(msgin);
  19
  20         if(msgin == "")
  21                 return;
  22
  23         if(source.classname != "player")
  24                 colorstr = "^0"; // black for spectators
  25         else if(teams_matter)
  26                 colorstr = Team_ColorCode(source.team);
  27         else
  28                 teamsay = FALSE;
  29
  30         if(intermission_running)
  31                 teamsay = FALSE;
  32
  33         /*
  34          * using bprint solves this... me stupid
  35         // how can we prevent the message from appearing in a listen server?
  36         // for now, just give "say" back and only handle say_team
  37         if(!teamsay)
  38         {
  39                 clientcommand(self, strcat("say ", msgin));
  40                 return;
  41         }
  42         */
  43
  44         if(cvar("g_chat_teamcolors"))
  45                 namestr = playername(source);
  46         else
  47                 namestr = source.netname;
  48         if(teamsay)
  49         {
  50                 msgstr = strzone(strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin, "\n"));
  51                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", wordwrap(msgin, 50));
  52         }
  53         else
  54                 msgstr = strzone(strcat("\{1}", namestr, "^7: ", msgin, "\n"));
  55
  56         // FLOOD CONTROL
  57         flood = 0;
  58         {
  59                 float flood_spl;
  60                 float flood_burst;
  61                 float flood_lmax;
  62                 var .float flood_field;
  63                 float lines;
  64                 if(teamsay)
  65                 {
  66                         flood_spl = cvar("g_chat_flood_spl_team");
  67                         flood_burst = cvar("g_chat_flood_burst_team");
  68                         flood_lmax = cvar("g_chat_flood_lmax_team");
  69                         flood_field = floodcontrol_team;
  70                 }
  71                 else
  72                 {
  73                         flood_spl = cvar("g_chat_flood_spl");
  74                         flood_burst = cvar("g_chat_flood_burst");
  75                         flood_lmax = cvar("g_chat_flood_lmax");
  76                         flood_field = floodcontrol_chat;
  77                 }
  78                 flood_burst = max(0, flood_burst - 1);
  79                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
  80                 lines = ceil(strlennocol(msgstr) / 75);
  81                 if(flood_lmax && lines > flood_lmax)
  82                         flood = 2;
  83                 else if(time >= self.flood_field)
  84                         self.flood_field = max(time - flood_burst * flood_spl, self.flood_field) + lines * flood_spl;
  85                 else
  86                         flood = 1;
  87         }
  88
  89         if(flood)
  90         {
  91                 if(cvar("g_chat_flood_notify_flooder"))
  92                 {
  93                         if(flood == 1)
  94                                 sprint(self, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(self.flood_field - time), "^3 seconds\n"));
  95                         else if(flood == 2)
  96                                 sprint(self, "^3FLOOD CONTROL: ^7message too long\n");
  97                 }
  98                 else
  99                         sprint(self, msgstr);
 100                 ServerConsoleEcho(strcat("NOTE: ", playername(self), "^7 is flooding."), TRUE);
 101         }
 102         else if(teamsay)
 103         {
 104                 if(source.classname == "player")
 105                 {
 106                         FOR_EACH_REALPLAYER(head)
 107                         {
 108                                 if(head.team == source.team)
 109                                 {
 110                                         sprint(head, msgstr);
 111                                         centerprint(head, cmsgstr);
 112                                 }
 113                         }
 114                 }
 115                 else
 116                 {
 117                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 118                         {
 119                                 sprint(head, msgstr);
 120                                 centerprint(head, cmsgstr);
 121                         }
 122                 }
 123         }
 124         else
 125         {
 126                 bprint(msgstr);
 127                 //ServerConsoleEcho(substring(msgstr, 1, strlen(msgstr) - 2), TRUE);
 128         }
 129
 130         strunzone(msgstr);
 131 }
 132
 133 string GetKickVoteVictim_newcommand;
 134 entity GetKickVoteVictim(string vote, string cmd)
 135 {
 136         float tokens;
 137         float i, n;
 138         string ns;
 139         entity e;
 140
 141         tokens = tokenize(vote);
 142         ns = "";
 143
 144         if(tokens == 2)
 145                 if(substring(argv(1), 0, 1) == "#")
 146                         ns = substring(argv(1), 1, 999);
 147
 148         if(tokens == 3)
 149                 if(argv(1) == "#")
 150                         ns = argv(2);
 151
 152         if(ns != "")
 153         {
 154                 n = stof(ns);
 155                 if(ns == ftos(n)) if(n >= 1) if(n <= maxclients)
 156                 {
 157                         for((e = world), (i = 0); i < n; ++i, (e = nextent(e)))
 158                                 ;
 159                         if(clienttype(e) == CLIENTTYPE_REAL)
 160                         {
 161                                 GetKickVoteVictim_newcommand = strcat(argv(0), " # ", ns);
 162                                 return e;
 163                         }
 164                 }
 165         }
 166
 167         sprint(self, strcat("Usage: ", cmd, " ", argv(0), " #playernumber (as in \"status\")\n"));
 168         return world;
 169 }
 170
 171 void SV_ParseClientCommand(string s) {
 172         local string cmd;
 173         local entity e;
 174
 175         tokenize(s);
 176
 177         if(argv(0) == "vote") {
 178                 if(argv(1) == "help") {
 179                         local string vmasterdis;
 180                         if(!cvar("sv_vote_master")) {
 181                                 vmasterdis = " ^1(disabled)";
 182                         }
 183                         local string vcalldis;
 184                         if(!cvar("sv_vote_call")) {
 185                                 vcalldis = " ^1(disabled)";
 186                         }
 187                         sprint(self, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\".\n");
 188                         sprint(self, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\".\n");
 189                         sprint(self, "^7\"^2help^7\" shows this info.\n");
 190                         sprint(self, "^7\"^2status^7\" shows if there is a vote called and who called it.\n");
 191                         sprint(self, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7\n"));
 192                         sprint(self, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.\n");
 193                         sprint(self, strcat("^7\"^2master^7\" is used to call a vote to become a master.", vmasterdis, "^7\n"));
 194                         sprint(self, "^7\"^2do^7\" If you are a master you can execute a command without a vote. See the list of allowed commands.\n");
 195                         sprint(self, "^7\"^2yes^7\" and \"^2no^7\" to make your vote.\n");
 196                         sprint(self, "^7If more then 50% of the players vote yes the vote is accepted.\n");
 197                         sprint(self, "^7If more then 50% of the players vote no the vote is rejected.\n");
 198                         sprint(self, strcat("^7The vote will end after ", cvar_string("sv_vote_timeout"), "^7 seconds.\n"));
 199                         sprint(self, "^7You can call a vote for or execute these commands:\n");
 200                         sprint(self, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7\n"));
 201                 } else if(argv(1) == "status") {
 202                         if(votecalled) {
 203                                 sprint(self, strcat("^7Vote for ", votecalledvote_display, "^7 called by ^7", votecaller.netname, "^7.\n"));
 204                         } else {
 205                                 sprint(self, "^1No vote called.\n");
 206                         }
 207                 } else if(argv(1) == "call") {
 208                         if(cvar("sv_vote_call")) {
 209                                 if(votecalled) {
 210                                         sprint(self, "^1There is already a vote called.\n");
 211                                 } else {
 212                                         local string vote;
 213                                         vote = VoteParse();
 214                                         if(vote == "") {
 215                                                 sprint(self, "^1Your vote is empty. See help for more info.\n");
 216                                         } else if(time < self.vote_next) {
 217                                                 sprint(self, strcat("^1You have to wait ^2", ftos(self.vote_next - time), "^1 seconds before you can again call a vote.\n"));
 218                                         } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
 219                                                 // remap chmap to gotomap (forces intermission)
 220                                                 if(substring(vote, 0, 6) == "chmap ")
 221                                                         vote = strcat("gotomap ", substring(vote, 6, strlen(vote) - 6));
 222                                                 if(substring(vote, 0, 8) == "gotomap ")
 223                                                 {
 224                                                         if(!(vote = ValidateMap(substring(vote, 8, strlen(vote) - 8))))
 225                                                                 return;
 226                                                         vote = strcat("gotomap ", vote);
 227                                                 }
 228
 229                                                 // make kick and kickban votes a bit nicer (and reject them if formatted badly)
 230                                                 if(substring(vote, 0, 5) == "kick " || substring(vote, 0, 8) == "kickban ")
 231                                                 {
 232                                                         if(!(e = GetKickVoteVictim(vote, "vcall")))
 233                                                                 return;
 234                                                         votecalledvote_display = strzone(strcat("^1", vote, " (^7", e.netname, "^1)"));
 235                                                         vote = GetKickVoteVictim_newcommand;
 236                                                 }
 237                                                 else
 238                                                 {
 239                                                         votecalledvote_display = strzone(strcat("^1", vote));
 240                                                 }
 241                                                 votecalledvote = strzone(vote);
 242                                                 votecalled = TRUE;
 243                                                 votecalledmaster = FALSE;
 244                                                 votecaller = self; // remember who called the vote
 245                                                 votefinished = time + cvar("sv_vote_timeout");
 246                                                 votecaller.vote_vote = 1; // of course you vote yes
 247                                                 votecaller.vote_next = time + cvar("sv_vote_wait");
 248                                                 bprint("\{1}^2* ^3", votecaller.netname, "^2 calls a vote for ", votecalledvote_display, "\n");
 249                                                 VoteCount(); // needed if you are the only one
 250                                         } else {
 251                                                 sprint(self, "^1This vote is not ok. See help for more info.\n");
 252                                         }
 253                                 }
 254                         } else {
 255                                 sprint(self, "^1Vote calling is NOT allowed.\n");
 256                         }
 257                 } else if(argv(1) == "stop") {
 258                         if(!votecalled) {
 259                                 sprint(self, "^1No vote called.\n");
 260                         } else if(self == votecaller) { // the votecaller can stop a vote
 261                                 VoteStop(self);
 262                         } else if(self.vote_master) { // masters can, too
 263                                 VoteStop(self);
 264                         } else {
 265                                 sprint(self, "^1You are not allowed to stop that Vote.\n");
 266                         }
 267                 } else if(argv(1) == "master") {
 268                         if(cvar("sv_vote_master")) {
 269                                 if(votecalled) {
 270                                         sprint(self, "^1There is already a vote called.\n");
 271                                 } else {
 272                                         votecalled = TRUE;
 273                                         votecalledmaster = TRUE;
 274                                         votecalledvote = strzone("XXX");
 275                                         votecalledvote_display = strzone("^3master");
 276                                         votecaller = self; // remember who called the vote
 277                                         votefinished = time + cvar("sv_vote_timeout");
 278                                         votecaller.vote_vote = 1; // of course you vote yes
 279                                         votecaller.vote_next = time + cvar("sv_vote_wait");
 280                                         bprint("\{1}^2* ^3", votecaller.netname, "^2 calls a vote to become ^3master^2.\n");
 281                                         VoteCount(); // needed if you are the only one
 282                                 }
 283                         } else {
 284                                 sprint(self, "^1Vote to become master is NOT allowed.\n");
 285                         }
 286                 } else if(argv(1) == "do") {
 287                         if(argv(2) == "login") {
 288                                 local string masterpwd;
 289                                 masterpwd = cvar_string("sv_vote_master_password");
 290                                 if(masterpwd != "") {
 291                                         self.vote_master = (masterpwd == argv(3));
 292                                         if(self.vote_master) {
 293                                                 ServerConsoleEcho(strcat("Accepted master login from ", self.netname), TRUE);
 294                                                 bprint("\{1}^2* ^3", self.netname, "^2 logged in as ^3master^2\n");
 295                                         }
 296                                         else
 297                                                 ServerConsoleEcho(strcat("REJECTED master login from ", self.netname), TRUE);
 298                                 }
 299                                 else
 300                                         sprint(self, "^1You are NOT a master.\n");
 301                         } else if(self.vote_master) {
 302                                 local string dovote, dovote_display;
 303                                 dovote = VoteParse();
 304                                 if(dovote == "") {
 305                                         sprint(self, "^1Your command was empty. See help for more info.\n");
 306                                 } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
 307                                         if(substring(dovote, 0, 6) == "chmap ")
 308                                                 dovote = strcat("gotomap ", substring(dovote, 6, strlen(dovote) - 6));
 309                                         if(substring(dovote, 0, 8) == "gotomap ")
 310                                         {
 311                                                 if(!(dovote = ValidateMap(substring(dovote, 8, strlen(dovote) - 8))))
 312                                                         return;
 313                                                 dovote = strcat("gotomap ", dovote);
 314                                         }
 315
 316                                         dovote_display = dovote;
 317                                         if(substring(dovote, 0, 5) == "kick " || substring(dovote, 0, 8) == "kickban ")
 318                                         {
 319                                                 if(!(e = GetKickVoteVictim(dovote, "vdo")))
 320                                                         return;
 321                                                 dovote_display = strzone(strcat("^1", dovote, " (^7", e.netname, "^1)"));
 322                                                 dovote = GetKickVoteVictim_newcommand;
 323                                         }
 324                                         bprint("\{1}^2* ^3", self.netname, "^2 used his ^3master^2 status to do \"^2", dovote_display, "^2\".\n");
 325                                         localcmd(strcat(dovote, "\n"));
 326                                 } else {
 327                                         sprint(self, "^1This command is not ok. See help for more info.\n");
 328                                 }
 329                         } else {
 330                                 sprint(self, "^1You are NOT a master.\n");
 331                         }
 332                 } else if(argv(1) == "yes") {
 333                         if(!votecalled) {
 334                                 sprint(self, "^1No vote called.\n");
 335                         } else if(self.vote_vote == 0
 336                                   || cvar("sv_vote_change")) {
 337                                 sprint(self, "^1You accepted the vote.\n");
 338                                 self.vote_vote = 1;
 339                                 if(!cvar("sv_vote_singlecount")) {
 340                                         VoteCount();
 341                                 }
 342                         } else {
 343                                 sprint(self, "^1You have already voted.\n");
 344                         }
 345                 } else if(argv(1) == "no") {
 346                         if(!votecalled) {
 347                                 sprint(self, "^1No vote called.\n");
 348                         } else if(self.vote_vote == 0
 349                                   || cvar("sv_vote_change")) {
 350                                 sprint(self, "^1You rejected the vote.\n");
 351                                 self.vote_vote = -1;
 352                                 if(!cvar("sv_vote_singlecount")) {
 353                                         VoteCount();
 354                                 }
 355                         } else {
 356                                 sprint(self, "^1You have already voted.\n");
 357                         }
 358                 } else {
 359                         // ignore this?
 360                         sprint(self, "^1Unknown vote command.\n");
 361                 }
 362         } else if(argv(0) == "autoswitch") {
 363                 // be backwards compatible with older clients (enabled)
 364                 self.autoswitch = ("0" != argv(1));
 365                 local string autoswitchmsg;
 366                 if (self.autoswitch) {
 367                         autoswitchmsg = "on";
 368                 } else {
 369                         autoswitchmsg = "off";
 370                 }
 371                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 372         } else if(argv(0) == "clientversion") {
 373                 if (argv(1) == "$gameversion") {
 374                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 375                         // either that or someone wants to be funny
 376                         self.version = 1;
 377                 } else {
 378                         self.version = stof(argv(1));
 379                 }
 380                 if(self.version != cvar("gameversion"))
 381                 {
 382                         self.classname = "observer";
 383                         self.frags = -2;
 384                         PutClientInServer();
 385                 } else if(cvar("g_campaign") || cvar("g_balance_teams")) {
 386                         //JoinBestTeam(self, 0);
 387                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 388                         self.classname = "observer";
 389                         stuffcmd(self,"menu_showteamselect\n");
 390                 }
 391         } else if(argv(0) == "reportcvar") { // old system
 392                 GetCvars(1);
 393         } else if(argv(0) == "sentcvar") { // new system
 394                 GetCvars(1);
 395         } else if(argv(0) == "spectate") {
 396                 if(g_lms || g_arena)
 397                         return; // don't allow spectating in lms, unless player runs out of lives
 398                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 399                         if(self.flagcarried)
 400                                 DropFlag(self.flagcarried);
 401                         kh_Key_DropAll(self, TRUE);
 402                         WaypointSprite_PlayerDead();
 403                         DistributeFragsAmongTeam(self, self.team, 1.0);
 404                         self.classname = "observer";
 405                         PutClientInServer();
 406                 }
 407         } else if(argv(0) == "join") {
 408                 if(!g_arena)
 409                 if (self.classname != "player")
 410                 {
 411                         self.classname = "player";
 412                         self.frags = 0;
 413                         bprint ("^4", self.netname, "^4 is playing now\n");
 414                         PutClientInServer();
 415                 }
 416         } else if( argv(0) == "selectteam" ) {
 417                 if( !cvar("teamplay") ) {
 418                         sprint( self, "selecteam can only be used in teamgames\n");
 419                 } else if(cvar("g_campaign")) {
 420                         //JoinBestTeam(self, 0);
 421                 } else if( argv(1) == "none" ) {
 422                         SV_ChangeTeam( 0 );
 423                 } else if( argv(1) == "red" ) {
 424                         SV_ChangeTeam( COLOR_TEAM1 - 1 );
 425                 } else if( argv(1) == "blue" ) {
 426                         SV_ChangeTeam( COLOR_TEAM2 - 1 );
 427                 } else if( argv(1) == "yellow" ) {
 428                         SV_ChangeTeam( COLOR_TEAM3 - 1 );
 429                 } else if( argv(1) == "pink" ) {
 430                         SV_ChangeTeam( COLOR_TEAM4 - 1 );
 431                 } else if( argv(1) == "auto" ) {
 432                         self.team = -1;
 433                         JoinBestTeam( self, 0 );
 434                 } else {
 435                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 436                 }
 437         } else if(argv(0) == "ready") {
 438                 if(cvar("sv_ready_restart"))
 439                 {
 440                         if(!restart_countdown)
 441                         {
 442                                 self.ready = TRUE;
 443                                 bprint(self.netname, "^2 is ready\n");
 444                                 ReadyCount();
 445                         } else {
 446                                 sprint(self, "^1game has already been restarted\n");
 447                         }
 448                 }
 449         } else if(argv(0) == "maplist") {
 450                 local float i, n;
 451                 local string col;
 452                 n = tokenize(cvar_string("g_maplist"));
 453                 sprint(self, "^7Maps in list: ");
 454                 for(i = 0; i < n; ++i)
 455                 {
 456                         if(math_mod(i, 2))
 457                                 col = "^2";
 458                         else
 459                                 col = "^3";
 460                         sprint(self, strcat(col, argv(i), " "));
 461                 }
 462                 sprint(self, "\n");
 463         } else if(argv(0) == "teamstatus") {
 464                 PrintScoreboard(self);
 465         } else if(argv(0) == "voice") {
 466                 VoiceMessage(argv(1));
 467         } else if(argv(0) == "say") {
 468                 Say(self, FALSE, substring(s, 4, strlen(s) - 4));
 469                 //clientcommand(self, formatmessage(s));
 470         } else if(argv(0) == "say_team") {
 471                 Say(self, TRUE, substring(s, 9, strlen(s) - 9));
 472                 //clientcommand(self, formatmessage(s));
 473         } else if(argv(0) == "info") {
 474                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 475                 if(cmd == "")
 476                         sprint(self, "ERROR: unsupported info command\n");
 477                 else
 478                         wordwrap_sprint(cmd, 1111);
 479         } else if(argv(0) == "suggestmap") {
 480                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 481         } else {
 482                 cmd = argv(0);
 483                 /* checks not needed any more since DP has separated clientcommands and regular commands
 484                 if(cmd != "status")
 485                 if(cmd != "name")
 486                 //if(cmd != "say") // handled above
 487                 //if(cmd != "say_team") // handled above
 488                 if(cmd != "tell")
 489                 if(cmd != "color")
 490                 if(cmd != "kill")
 491                 if(cmd != "pause")
 492                 if(cmd != "kick")
 493                 if(cmd != "ping")
 494                 if(cmd != "pings")
 495                 if(cmd != "ban")
 496                 if(cmd != "pmodel")
 497                 if(cmd != "rate")
 498                 if(cmd != "playermodel")
 499                 if(cmd != "playerskin")
 500                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
 501                 {
 502                         ServerConsoleEcho(strcat("WARNING: Invalid clientcommand by ", self.netname, ": ", s), TRUE);
 503                         return;
 504                 }
 505                 */
 506                 clientcommand(self,s);
 507         }
 508 }
 509
 510 string ValidateMap(string m)
 511 {
 512 #ifdef MAPINFO
 513         m = MapInfo_FixName(m);
 514         if(!m)
 515         {
 516                 sprint(self, "This map is not available on this server.\n");
 517                 return string_null;
 518         }
 519 #endif
 520         if(!cvar("sv_vote_change_gametype"))
 521                 if(!IsSameGametype(m))
 522                 {
 523                         sprint(self, "This server does not allow changing the game type by map votes.\n");
 524                         return string_null;
 525                 }
 526         if(!cvar("sv_vote_override_mostrecent"))
 527                 if(Map_IsRecent(m))
 528                 {
 529                         sprint(self, "This server does not allow for recent maps to be played again. Please be patient for some rounds.\n");
 530                         return string_null;
 531                 }
 532 #ifdef MAPINFO
 533         if(!MapInfo_CheckMap(m))
 534         {
 535                 sprint(self, strcat("^1Invalid mapname, \"^3", m, "^1\" does not support the current game mode.\n"));
 536                 return string_null;
 537         }
 538 #else
 539         if(!TryFile(strcat("maps/", m, ".mapcfg")))
 540         {
 541                 sprint(self, strcat("^1Invalid mapname, \"^3", m, "^1\" does not exist on this server.\n"));
 542                 return string_null;
 543         }
 544 #endif
 545
 546         return m;
 547 }
 548
 549
 550 void VoteThink() {
 551         if(votefinished > 0 // a vote was called
 552             && time > votefinished) // time is up
 553         {
 554                 VoteCount();
 555         }
 556 }
 557
 558 string VoteParse() {
 559         local float index;
 560         index = 3;
 561         local string vote;
 562         vote = argv(2);
 563         while(argv(index) != "") {
 564                 vote = strcat(vote, " ", argv(index));
 565                 index++;
 566         }
 567
 568         // necessary for some of the string operations
 569         vote = strzone(vote);
 570
 571         // now we remove some things that could be misused
 572         index = 0;
 573         local float found;
 574         found = FALSE;
 575         local float votelength;
 576         votelength = strlen(vote);
 577         while(!found && index < votelength)
 578         {
 579                 local string badchar;
 580                 badchar = substring(vote, index, 1);
 581                 if(badchar == ";"
 582                    || badchar == "\r"
 583                    || badchar == "\n")
 584                 {
 585                         found = TRUE;
 586                 } else {
 587                         index++;
 588                 }
 589         }
 590         return substring(vote, 0, index);
 591 }
 592
 593 float VoteAllowed(string votecommand) {
 594         tokenize(cvar_string("sv_vote_commands"));
 595         local float index;
 596         index = 0;
 597         while(argv(index) != "") {
 598                 local string allowed;
 599                 allowed = argv(index);
 600                 if(votecommand == allowed) {
 601                         return TRUE;
 602                 }
 603                 index++;
 604         }
 605         return FALSE;
 606 }
 607
 608 void VoteReset() {
 609         local entity player;
 610
 611         FOR_EACH_CLIENT(player)
 612         {
 613                 player.vote_vote = 0;
 614                 centerprint_expire(player, CENTERPRIO_VOTE);
 615         }
 616
 617         if(votecalled)
 618         {
 619                 strunzone(votecalledvote);
 620                 strunzone(votecalledvote_display);
 621         }
 622
 623         votecalled = FALSE;
 624         votecalledmaster = FALSE;
 625         votefinished = 0;
 626 }
 627
 628 void VoteAccept() {
 629         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ^1", votecalledvote_display, "^2 was accepted\n");
 630         if(votecalledmaster)
 631         {
 632                 votecaller.vote_master = 1;
 633         } else {
 634                 localcmd(strcat(votecalledvote, "\n"));
 635         }
 636         votecaller.vote_next = 0; // people like your votes, no wait for next vote
 637         VoteReset();
 638 }
 639
 640 void VoteReject() {
 641         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ", votecalledvote_display, "^2 was rejected\n");
 642         VoteReset();
 643 }
 644
 645 void VoteTimeout() {
 646         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ", votecalledvote_display, "^2 timed out\n");
 647         VoteReset();
 648 }
 649
 650 void VoteStop(entity stopper) {
 651         bprint("\{1}^2* ^3", stopper.netname, "^2 stopped ^3", votecaller.netname, "^2's vote\n");
 652         if(stopper == votecaller) {
 653                 // no wait for next vote so you can correct your vote
 654                 votecaller.vote_next = 0;
 655         }
 656         VoteReset();
 657 }
 658
 659 void VoteNag() {
 660         if(votecalled)
 661                 if(self.vote_vote == 0)
 662                         centerprint_atprio(self, CENTERPRIO_VOTE, strcat("^7^3", votecaller.netname, "^2 called a vote for ", votecalledvote_display, "\n\n^2You have not voted yet!\n^2HINT: By default, F1 is yes and F2 is no."));
 663 }
 664
 665 void VoteCount() {
 666         local float playercount;
 667         playercount = 0;
 668         local float yescount;
 669         yescount = 0;
 670         local float nocount;
 671         nocount = 0;
 672         local entity player;
 673
 674         FOR_EACH_REALCLIENT(player)
 675         {
 676                 if(player.vote_vote < 0) {
 677                         nocount++;
 678                 } else if(player.vote_vote > 0) {
 679                         yescount++;
 680                 }
 681                 playercount++;
 682         }
 683
 684         if((playercount == 1) && votecalledmaster) {
 685                 // if only one player is on the server becoming vote
 686                 // master is not allowed.  This could be used for
 687                 // trolling or worse. 'self' is the user who has
 688                 // called the vote because this function is called
 689                 // by SV_ParseClientCommand. Maybe all voting should
 690                 // be disabled for a single player?
 691                 sprint(self, "^1You are the only player on this server so you can not become vote master.\n");
 692                 votecaller.vote_next = 0;
 693                 VoteReset();
 694         } else if((playercount / 2) < yescount) { // vote accepted
 695                 VoteAccept();
 696         } else if((playercount / 2) < nocount) { // vote rejected
 697                 VoteReject();
 698         } else if(time > votefinished) { // vote timedout
 699                 if(cvar("sv_vote_simple_majority"))
 700                         if(yescount > nocount)
 701                                 VoteAccept();
 702                         else if(nocount > yescount)
 703                                 VoteReject();
 704                         else
 705                                 VoteTimeout();
 706                 else
 707                         VoteTimeout();
 708         } // else still running
 709 }
 710
 711 float timelimit_orig;
 712
 713 void ReadyCount()
 714 {
 715         local entity e;
 716         local float r, p;
 717
 718         FOR_EACH_REALPLAYER(e)
 719         {
 720                 p += 1;
 721                 if(e.ready)
 722                         r += 1;
 723         }
 724
 725         if(!p || r < p)
 726                 return;
 727
 728         bprint("^1Server is restarting...\n");
 729
 730         // no arena, assault & onslaught support yet...
 731         if(g_arena | g_assault | g_onslaught | gameover | intermission_running)
 732                 localcmd("restart\n");
 733
 734         restart_countdown = time + RESTART_COUNTDOWN;
 735         if(0<cvar("timelimit"))
 736         {
 737                 // remember original timelimit on first restart
 738                 if(!timelimit_orig)
 739                         timelimit_orig = cvar("timelimit");
 740                 cvar_set("timelimit", ftos(timelimit_orig + ceil(restart_countdown)/60));
 741         }
 742
 743         reset_map();
 744
 745         if(cvar("sv_eventlog"))
 746                 GameLogEcho(":restart", FALSE);
 747 }