data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 void W_SwitchWeapon_Force(entity e, float w)
  11 {
  12         e.cnt = e.switchweapon;
  13         e.switchweapon = w;
  14 }
  15
  16 .float antilag_debug;
  17
  18 // VorteX: static frame globals
  19 float WFRAME_DONTCHANGE = -1;
  20 float WFRAME_FIRE1 = 0;
  21 float WFRAME_FIRE2 = 1;
  22 float WFRAME_IDLE = 2;
  23 float WFRAME_RELOAD = 3;
  24 .float wframe;
  25
  26 void(float fr, float t, void() func) weapon_thinkf;
  27
  28 vector w_shotorg;
  29 vector w_shotdir;
  30
  31 // this function calculates w_shotorg and w_shotdir based on the weapon model
  32 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  33 // make sure you call makevectors first (FIXME?)
  34 void W_SetupShot(entity ent, float antilag, float recoil, string snd)
  35 {
  36         float nudge = 1; // added to traceline target and subtracted from result
  37         local vector trueaimpoint;
  38         local float oldsolid;
  39         vector vecs;
  40         oldsolid = self.dphitcontentsmask;
  41         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  42         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, self);
  43         trueaimpoint = trace_endpos;
  44
  45         if(ent.weaponentity.movedir_x > 0)
  46         {
  47                 vecs = ent.weaponentity.movedir;
  48                 vecs_y = -vecs_y;
  49         }
  50         else
  51                 vecs = '0 0 0';
  52
  53         if(debug_shotorg != '0 0 0')
  54                 vecs = debug_shotorg;
  55
  56         w_shotorg = ent.origin + ent.view_ofs + v_right * vecs_y + v_up * vecs_z;
  57
  58         // now move the shotorg forward as much as requested if possible
  59         traceline(w_shotorg, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, self);
  60         w_shotorg = trace_endpos - v_forward * nudge;
  61         // calculate the shotdir from the chosen shotorg
  62         w_shotdir = normalize(trueaimpoint - w_shotorg);
  63
  64 #if 0
  65         // explanation of g_antilag:
  66         // if client reports it was aiming at a player, and the serverside trace
  67         // says it would miss, change the aim point to the player's new origin,
  68         // but only if the shot at the player's new origin would hit of course
  69         //
  70         // FIXME: a much better method for bullet weapons would be to leave a
  71         // trail of lagged 'ghosts' behind players, and see if the bullet hits the
  72         // ghost corresponding to this player's ping time, and if so it would do
  73         // damage to the real player
  74         if (antilag)
  75         if (self.cursor_trace_ent)                 // client was aiming at someone
  76         if (self.cursor_trace_ent != self)         // just to make sure
  77         if (self.cursor_trace_ent.takedamage)      // and that person is killable
  78         if (self.cursor_trace_ent.classname == "player") // and actually a player
  79         if (cvar("g_antilag") == 1)
  80         {
  81                 // verify that the shot would miss without antilag
  82                 // (avoids an issue where guns would always shoot at their origin)
  83                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  84                 if (!trace_ent.takedamage)
  85                 {
  86                         // verify that the shot would hit if altered
  87                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
  88                         if (trace_ent == self.cursor_trace_ent)
  89                         {
  90                                 // verify that the shot would hit in the past
  91                                 if(self.antilag_debug)
  92                                         antilag_takeback(self.cursor_trace_ent, time - self.antilag_debug);
  93                                 else
  94                                         antilag_takeback(self.cursor_trace_ent, time - ANTILAG_LATENCY(self));
  95
  96                                 traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  97                                 antilag_restore(self.cursor_trace_ent);
  98
  99                                 if(trace_ent == self.cursor_trace_ent)
 100                                 {
 101                                         // HIT!
 102                                         w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
 103                                         dprint("ANTILAG HIT for ", self.netname, "\n");
 104                                 }
 105                                 else
 106                                 {
 107                                         // prydon cursor aimbot or odd network conditions
 108                                         dprint("WARNING: antilag ghost trace for ", self.netname, " failed!\n");
 109                                 }
 110
 111                                 if(cvar("developer") >= 2)
 112                                 {
 113                                         vector v, vplus, vel;
 114                                         float X;
 115                                         v     = antilag_takebackorigin(self.cursor_trace_ent, time - (ANTILAG_LATENCY(self)       ));
 116                                         vplus = antilag_takebackorigin(self.cursor_trace_ent, time - (ANTILAG_LATENCY(self) + 0.01));
 117                                         vel = (vplus - v) * (1 / 0.01);
 118                                         // solve: v + X * vel = closest to self.origin + self.view_ofs, v_forward axis
 119                                         v     -= (self.origin + self.view_ofs);
 120                                         // solve: v + X * vel = closest to v_forward axis
 121                                         // project into 2D by subtracting v_forward components:
 122                                         v   -= (v   * v_forward) * v_forward;
 123                                         vel -= (vel * v_forward) * v_forward;
 124                                         // solve: v + X * vel = closest to origin
 125                                         // (v + X * vel)^2 closest to 0
 126                                         // v^2 + 2 * X * (v * vel) + X^2 * vel^2 closest to 0
 127                                         X = -(v * vel) / (vel * vel);
 128                                         dprint("dead center needs adjustment of ", ftos(X), " (that is, ", ftos(ANTILAG_LATENCY(self) + X), " instead of ", ftos(ANTILAG_LATENCY(self)), "\n");
 129                                 }
 130                         }
 131                 }
 132         }
 133 #else
 134         if (antilag)
 135         {
 136                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 137                 {
 138                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 139                         if (!trace_ent.takedamage)
 140                         {
 141                                 traceline_antilag_force (self, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self, ANTILAG_LATENCY(self));
 142                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 143                                 {
 144                                         entity e;
 145                                         e = trace_ent;
 146                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, self);
 147                                         if(trace_ent == e)
 148                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 149                                 }
 150                         }
 151                 }
 152                 else if(cvar("g_antilag") == 3) // client side hitscan
 153                 {
 154                         if (self.cursor_trace_ent)                 // client was aiming at someone
 155                         if (self.cursor_trace_ent != self)         // just to make sure
 156                         if (self.cursor_trace_ent.takedamage)      // and that person is killable
 157                         if (self.cursor_trace_ent.classname == "player") // and actually a player
 158                         {
 159                                 // verify that the shot would miss without antilag
 160                                 // (avoids an issue where guns would always shoot at their origin)
 161                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 162                                 if (!trace_ent.takedamage)
 163                                 {
 164                                         // verify that the shot would hit if altered
 165                                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
 166                                         if (trace_ent == self.cursor_trace_ent)
 167                                                 w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
 168                                         else
 169                                                 print("antilag fail\n");
 170                                 }
 171                         }
 172                 }
 173         }
 174 #endif
 175
 176         self.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 177
 178         if (!g_norecoil)
 179                 self.punchangle_x = recoil * -1;
 180
 181         if (snd != "")
 182         {
 183                 sound (self, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 184         }
 185
 186         if (self.items & IT_STRENGTH)
 187         if (!g_minstagib)
 188                 sound (self, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 189 };
 190
 191 void LaserTarget_Think()
 192 {
 193         entity e;
 194         vector offset;
 195         float uselaser;
 196         uselaser = 0;
 197
 198         // list of weapons that will use the laser, and the options that enable it
 199         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 200                 uselaser = 1;
 201         // example
 202         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 203         //      uselaser = 1;
 204
 205
 206
 207         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 208         if(!uselaser)
 209         {
 210                 // rocket launcher isn't selected, so no laser target.
 211                 if(self.lasertarget != world)
 212                 {
 213                         remove(self.lasertarget);
 214                         self.lasertarget = world;
 215                 }
 216                 return;
 217         }
 218
 219         if(!self.lasertarget)
 220         {
 221                 // we don't have a lasertarget entity, so spawn one
 222                 //bprint("create laser target\n");
 223                 e = self.lasertarget = spawn();
 224                 e.owner = self.owner;                   // Its owner is my owner
 225                 e.classname = "laser_target";
 226                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 227                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 228                 e.scale = 1.25;                         // make it larger
 229                 e.alpha = 0.25;                         // transparency
 230                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 231                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 232                 // make it dynamically glow
 233                 // you should avoid over-using this, as it can slow down the player's computer.
 234                 e.glow_color = 251; // red color
 235                 e.glow_size = 12;
 236         }
 237         else
 238                 e = self.lasertarget;
 239
 240         // move the laser dot to where the player is looking
 241
 242         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 243         offset = '0 0 26' + v_right*3;
 244         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 245         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 246         if(trace_plane_normal != '0 0 0')
 247                 e.angles = vectoangles(trace_plane_normal);
 248         else
 249                 e.angles = vectoangles(v_forward);
 250 }
 251
 252 float CL_Weaponentity_CustomizeEntityForClient()
 253 {
 254         self.viewmodelforclient = self.owner;
 255         if(other.classname == "spectator")
 256                 if(other.enemy == self.owner)
 257                         self.viewmodelforclient = other;
 258         return TRUE;
 259 }
 260
 261 float qcweaponanimation;
 262 vector weapon_offset = '0 -10 0';
 263 vector weapon_adjust = '10 0 -15';
 264 .vector weapon_morph0origin;
 265 .vector weapon_morph0angles;
 266 .float  weapon_morph0time;
 267 .vector weapon_morph1origin;
 268 .vector weapon_morph1angles;
 269 .float  weapon_morph1time;
 270 .vector weapon_morph2origin;
 271 .vector weapon_morph2angles;
 272 .float  weapon_morph2time;
 273 .vector weapon_morph3origin;
 274 .vector weapon_morph3angles;
 275 .float  weapon_morph3time;
 276 .vector weapon_morph4origin;
 277 .vector weapon_morph4angles;
 278 .float  weapon_morph4time;
 279 .string weaponname;
 280 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 281
 282 void CL_Weaponentity_Think()
 283 {
 284         float tb;
 285         self.nextthink = time;
 286         if (intermission_running)
 287                 self.frame = self.anim_idle_x;
 288         if (self.owner.weaponentity != self)
 289         {
 290                 if (self.weaponentity)
 291                         remove(self.weaponentity);
 292                 remove(self);
 293                 return;
 294         }
 295         if (self.owner.deadflag != DEAD_NO)
 296         {
 297                 self.model = "";
 298                 if (self.weaponentity)
 299                         self.weaponentity.model = "";
 300                 return;
 301         }
 302         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 303         {
 304                 self.cnt = self.owner.weapon;
 305                 self.dmg = self.owner.modelindex;
 306                 self.deadflag = self.owner.deadflag;
 307
 308                 string animfilename;
 309                 float animfile;
 310                 float modelfile;
 311                 if (self.owner.weaponname != "")
 312                 {
 313                         // if there is a child entity, hide it until we're sure we use it
 314                         if (self.weaponentity)
 315                                 self.weaponentity.model = "";
 316                         if (qcweaponanimation)
 317                                 setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 318                         else
 319                         {
 320                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".zym");
 321                                 modelfile = fopen(animfilename, FILE_READ);
 322                                 if (modelfile >= 0)
 323                                 {
 324                                         fclose(modelfile);
 325                                         self.anim_fire1  = '0 1 0.01';
 326                                         self.anim_fire2  = '1 1 0.01';
 327                                         self.anim_idle   = '2 1 0.01';
 328                                         self.anim_reload = '3 1 0.01';
 329                                         if (!self.weaponentity)
 330                                                 self.weaponentity = spawn();
 331                                         setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".zym")); // precision set below
 332                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 333                                         setattachment(self.weaponentity, self, "weapon");
 334                                 }
 335                                 else
 336                                 {
 337                                         animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".dpm.animinfo");
 338                                         animfile = fopen(animfilename, FILE_READ);
 339                                         if (animfile >= 0)
 340                                         {
 341                                                 if (!self.weaponentity)
 342                                                         self.weaponentity = spawn();
 343                                                 setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".dpm")); // precision set below
 344                                                 setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 345                                                 setattachment(self.weaponentity, self, "weapon");
 346                                         }
 347                                         else
 348                                         {
 349                                                 animfilename = strcat("models/weapons/w_", self.owner.weaponname, ".dpm.animinfo");
 350                                                 animfile = fopen(animfilename, FILE_READ);
 351                                                 if (animfile >= 0)
 352                                                         setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".dpm")); // precision set below
 353                                         }
 354                                         if (animfile >= 0)
 355                                         {
 356                                                 animparseerror = FALSE;
 357                                                 self.anim_fire1  = animparseline(animfile);
 358                                                 self.anim_fire2  = animparseline(animfile);
 359                                                 self.anim_idle   = animparseline(animfile);
 360                                                 self.anim_reload = animparseline(animfile);
 361                                                 fclose(animfile);
 362                                                 if (animparseerror)
 363                                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 364                                         }
 365                                         else
 366                                         {
 367                                                 self.anim_fire1  = '0 1 0.01';
 368                                                 self.anim_fire2  = '1 1 0.01';
 369                                                 self.anim_idle   = '2 1 0.01';
 370                                                 self.anim_reload = '3 1 0.01';
 371                                                 setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".zym")); // precision set below
 372                                         }
 373                                 }
 374                         }
 375                 }
 376                 else
 377                         self.model = "";
 378
 379                 if(qcweaponanimation)
 380                 {
 381                         self.angles = '0 0 0';
 382                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 383                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 384                         self.movedir_x += 30;
 385                         self.spawnorigin = self.movedir;
 386                 }
 387                 else
 388                 {
 389                         self.origin = '0 0 0';
 390                         self.angles = '0 0 0';
 391                         self.frame = 0;
 392                         self.viewmodelforclient = world;
 393
 394                         float idx;
 395                         idx = gettagindex(self, "shot");
 396                         if(idx)
 397                         {
 398                                 self.movedir = gettaginfo(self, idx);
 399                         }
 400                         else
 401                         {
 402                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag\n");
 403                                 self.movedir = '0 0 0';
 404                         }
 405
 406                         idx = gettagindex(self, "shell");
 407                         if(idx)
 408                         {
 409                                 self.spawnorigin = gettaginfo(self, idx);
 410                         }
 411                         else
 412                         {
 413                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag\n");
 414                                 self.spawnorigin = self.movedir;
 415                         }
 416
 417                         self.viewmodelforclient = self.owner;
 418                 }
 419
 420                 self.view_ofs = '0 0 0';
 421
 422                 if(self.movedir_x >= 0)
 423                 {
 424                         vector v0;
 425                         v0 = self.movedir;
 426                         self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 427                         self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 428                 }
 429
 430                 self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 431
 432                 // check if an instant weapon switch occurred
 433                 if (qcweaponanimation)
 434                 {
 435                         if (self.state == WS_READY)
 436                         {
 437                                 self.angles = '0 0 0';
 438                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 439                                 setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 440                         }
 441                 }
 442                 else
 443                         setorigin(self, self.view_ofs);
 444                 // reset animstate now
 445                 self.wframe = WFRAME_IDLE;
 446                 self.weapon_morph0time = 0;
 447                 self.weapon_morph1time = 0;
 448                 self.weapon_morph2time = 0;
 449                 self.weapon_morph3time = 0;
 450                 self.weapon_morph4time = 0;
 451                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 452         }
 453
 454         tb = (self.effects & EF_TELEPORT_BIT);
 455         self.effects = self.owner.effects - (self.owner.effects & EF_LOWPRECISION);// | EF_LOWPRECISION;
 456         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 457         self.effects &~= EF_TELEPORT_BIT;
 458         self.effects |= tb;
 459
 460         if(self.owner.alpha != 0)
 461                 self.alpha = self.owner.alpha;
 462         else
 463                 self.alpha = 1;
 464
 465         self.colormap = self.owner.colormap;
 466         if (self.weaponentity)
 467         {
 468                 self.weaponentity.effects = self.effects & EF_ADDITIVE;
 469                 self.weaponentity.alpha = self.alpha;
 470                 self.weaponentity.colormap = self.colormap;
 471         }
 472
 473         self.angles = '0 0 0';
 474         local float f;
 475         f = 0;
 476         if (self.state == WS_RAISE)
 477         {
 478                 f = (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 479                 self.angles_x = -90 * f * f;
 480                 if (qcweaponanimation)
 481                 {
 482                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 483                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 484                 }
 485         }
 486         else if (self.state == WS_DROP)
 487         {
 488                 f = 1 - (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 489                 self.angles_x = -90 * f * f;
 490                 if (qcweaponanimation)
 491                 {
 492                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 493                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 494                 }
 495         }
 496         else if (self.state == WS_CLEAR)
 497         {
 498                 f = 1;
 499                 self.angles_x = -90 * f * f;
 500                 if (qcweaponanimation)
 501                 {
 502                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 503                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 504                 }
 505         }
 506         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 507         {
 508                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 509                 f = 1 - pow(1 - f, 3);
 510                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 511                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 512         }
 513         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 514         {
 515                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 516                 f = 1 - pow(1 - f, 3);
 517                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 518                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 519         }
 520         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 521         {
 522                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 523                 f = 1 - pow(1 - f, 3);
 524                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 525                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 526         }
 527         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 528         {
 529                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 530                 f = 1 - pow(1 - f, 3);
 531                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 532                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 533         }
 534         else if (qcweaponanimation)
 535         {
 536                 // begin a new idle morph
 537                 self.owner.weapon_morph0time   = time;
 538                 self.owner.weapon_morph0angles = self.angles;
 539                 self.owner.weapon_morph0origin = self.origin;
 540
 541                 float r;
 542                 float t;
 543
 544                 r = random();
 545                 if (r < 0.1)
 546                 {
 547                         // turn gun to the left to look at it
 548                         t = 2;
 549                         self.owner.weapon_morph1time   = time + t * 0.2;
 550                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 551                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 552                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 553
 554                         self.owner.weapon_morph2time   = time + t * 0.6;
 555                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 556                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 557                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 558
 559                         self.owner.weapon_morph3time   = time + t;
 560                         self.owner.weapon_morph3angles = '0 0 0';
 561                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 562                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 563                 }
 564                 else if (r < 0.2)
 565                 {
 566                         // raise the gun a bit
 567                         t = 2;
 568                         self.owner.weapon_morph1time   = time + t * 0.2;
 569                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 570                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 571                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 572
 573                         self.owner.weapon_morph2time   = time + t * 0.5;
 574                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 575                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 576                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 577
 578                         self.owner.weapon_morph3time   = time + t;
 579                         self.owner.weapon_morph3angles = '0 0 0';
 580                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 581                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 582                 }
 583                 else if (r < 0.3)
 584                 {
 585                         // tweak it a bit
 586                         t = 5;
 587                         self.owner.weapon_morph1time   = time + t * 0.3;
 588                         self.owner.weapon_morph1angles = randomvec() * 6;
 589                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 590                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 591
 592                         self.owner.weapon_morph2time   = time + t * 0.7;
 593                         self.owner.weapon_morph2angles = randomvec() * 6;
 594                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 595                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 596
 597                         self.owner.weapon_morph3time   = time + t;
 598                         self.owner.weapon_morph3angles = '0 0 0';
 599                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 600                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 601                 }
 602                 else
 603                 {
 604                         // hold it mostly steady
 605                         t = random() * 6 + 4;
 606                         self.owner.weapon_morph1time   = time + t * 0.2;
 607                         self.owner.weapon_morph1angles = randomvec() * 1;
 608                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 609                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 610
 611                         self.owner.weapon_morph2time   = time + t * 0.5;
 612                         self.owner.weapon_morph2angles = randomvec() * 1;
 613                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 614                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 615
 616                         self.owner.weapon_morph3time   = time + t * 0.7;
 617                         self.owner.weapon_morph3angles = randomvec() * 1;
 618                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 619                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 620                 }
 621
 622                 self.owner.weapon_morph4time   = time + t;
 623                 self.owner.weapon_morph4angles = '0 0 0';
 624                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 625                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 626
 627         }
 628
 629         // create or update the lasertarget entity
 630         LaserTarget_Think();
 631 };
 632
 633 void CL_ExteriorWeaponentity_Think()
 634 {
 635         float tag_found;
 636         self.nextthink = time;
 637         if (self.owner.exteriorweaponentity != self)
 638         {
 639                 remove(self);
 640                 return;
 641         }
 642         if (self.owner.deadflag != DEAD_NO)
 643         {
 644                 self.model = "";
 645                 return;
 646         }
 647         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 648         {
 649                 self.cnt = self.owner.weapon;
 650                 self.dmg = self.owner.modelindex;
 651                 self.deadflag = self.owner.deadflag;
 652                 if (self.owner.weaponname != "")
 653                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 654                 else
 655                         self.model = "";
 656
 657                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 658                 {
 659                         self.tag_index = tag_found;
 660                         self.tag_entity = self.owner;
 661                 }
 662                 else
 663                         setattachment(self, self.owner, "bip01 r hand");
 664
 665                 // if that didn't find a tag, hide the exterior weapon model
 666                 if (!self.tag_index)
 667                         self.model = "";
 668         }
 669         self.effects = self.owner.effects | EF_LOWPRECISION;
 670         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 671         if(self.owner.alpha != 0)
 672                 self.alpha = self.owner.alpha;
 673         else
 674                 self.alpha = 1;
 675
 676         self.colormap = self.owner.colormap;
 677 };
 678
 679 // spawning weaponentity for client
 680 void CL_SpawnWeaponentity()
 681 {
 682         self.weaponentity = spawn();
 683         self.weaponentity.classname = "weaponentity";
 684         self.weaponentity.solid = SOLID_NOT;
 685         self.weaponentity.owner = self;
 686         setmodel(self.weaponentity, ""); // precision set when changed
 687         self.weaponentity.origin = '0 0 0';
 688         self.weaponentity.angles = '0 0 0';
 689         self.weaponentity.viewmodelforclient = self;
 690         self.weaponentity.flags = 0;
 691         self.weaponentity.think = CL_Weaponentity_Think;
 692         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 693         self.weaponentity.nextthink = time;
 694
 695         self.exteriorweaponentity = spawn();
 696         self.exteriorweaponentity.classname = "exteriorweaponentity";
 697         self.exteriorweaponentity.solid = SOLID_NOT;
 698         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 699         self.exteriorweaponentity.owner = self;
 700         self.exteriorweaponentity.origin = '0 0 0';
 701         self.exteriorweaponentity.angles = '0 0 0';
 702         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 703         self.exteriorweaponentity.nextthink = time;
 704 };
 705
 706 .float hasweapon_complain_spam;
 707
 708 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 709 {
 710         local float weaponbit, f;
 711         local entity oldself;
 712
 713         if(time < self.hasweapon_complain_spam)
 714                 complain = 0;
 715         if(complain)
 716                 self.hasweapon_complain_spam = time + 0.2;
 717
 718         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 719         {
 720                 if (complain)
 721                         sprint(self, "Invalid weapon\n");
 722                 return FALSE;
 723         }
 724         weaponbit = W_WeaponBit(wpn);
 725         if (cl.weapons & weaponbit)
 726         {
 727                 if (andammo)
 728                 {
 729                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 730                         {
 731                                 f = 1;
 732                         }
 733                         else
 734                         {
 735                                 oldself = self;
 736                                 self = cl;
 737                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 738                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 739                                 self = oldself;
 740                         }
 741                         if (!f)
 742                         {
 743                                 if (complain)
 744                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 745                                 return FALSE;
 746                         }
 747                 }
 748                 return TRUE;
 749         }
 750         if (complain)
 751         {
 752                 // DRESK - 3/16/07
 753                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 754                 if(weaponsInMap & weaponbit)
 755                 {
 756                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 757
 758                         if(cvar("g_showweaponspawns"))
 759                         {
 760                                 entity e;
 761                                 string s;
 762
 763                                 e = get_weaponinfo(wpn);
 764                                 s = e.model2;
 765
 766                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 767                                 {
 768                                         if(e.classname == "droppedweapon")
 769                                                 continue;
 770                                         if not(e.flags & FL_ITEM)
 771                                                 continue;
 772                                         WaypointSprite_Spawn(
 773                                                 s,
 774                                                 1, 0,
 775                                                 world, e.origin,
 776                                                 self, 0,
 777                                                 world, enemy,
 778                                                 0
 779                                         );
 780                                 }
 781                         }
 782                 }
 783                 else
 784                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 785         }
 786         return FALSE;
 787 };
 788
 789 // Weapon subs
 790 void w_clear()
 791 {
 792         if (self.weapon != -1)
 793                 self.weapon = 0;
 794         if (self.weaponentity)
 795         {
 796                 self.weaponentity.state = WS_CLEAR;
 797                 self.weaponentity.effects = 0;
 798         }
 799 };
 800
 801 void w_ready()
 802 {
 803         if (self.weaponentity)
 804                 self.weaponentity.state = WS_READY;
 805         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 806 };
 807
 808 // Setup weapon for client (after this raise frame will be launched)
 809 void weapon_setup(float windex)
 810 {
 811         entity e;
 812         qcweaponanimation = cvar("sv_qcweaponanimation");
 813         e = get_weaponinfo(windex);
 814         self.items &~= IT_AMMO;
 815         self.items = self.items | e.items;
 816
 817         // the two weapon entities will notice this has changed and update their models
 818         self.weapon = windex;
 819         self.weaponname = e.mdl;
 820         self.bulletcounter = 0;
 821 };
 822
 823 // perform weapon to attack (weaponstate and attack_finished check is here)
 824 .float race_penalty;
 825 float weapon_prepareattack(float secondary, float attacktime)
 826 {
 827         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 828         //if all players readied up and the countdown is running
 829         if (cvar("sv_ready_restart_after_countdown"))
 830                 if(time < game_starttime || time < self.race_penalty) {
 831                         return FALSE;
 832                 }
 833
 834         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 835         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 836         {
 837                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 838                 return FALSE;
 839         }
 840
 841         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 842                 return FALSE;
 843
 844         // do not even think about shooting if switching
 845         if(self.switchweapon != self.weapon)
 846                 return FALSE;
 847
 848         // don't fire if previous attack is not finished
 849         if(attacktime >= 0)
 850                 if (ATTACK_FINISHED(self) > time + frametime * 0.5)
 851                         return FALSE;
 852         // don't fire while changing weapon
 853         if (self.weaponentity.state != WS_READY)
 854                 return FALSE;
 855         self.weaponentity.state = WS_INUSE;
 856
 857         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 858
 859         // if the weapon hasn't been firing continuously, reset the timer
 860         if(attacktime >= 0)
 861         {
 862                 if (ATTACK_FINISHED(self) < time - frametime * 1.5)
 863                 {
 864                         ATTACK_FINISHED(self) = time;
 865                         //dprint("resetting attack finished to ", ftos(time), "\n");
 866                 }
 867                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime;
 868         }
 869         self.bulletcounter += 1;
 870         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 871         return TRUE;
 872 };
 873
 874 void weapon_thinkf(float fr, float t, void() func)
 875 {
 876         vector a;
 877         vector of, or, ou;
 878         float restartanim;
 879
 880         if(fr == WFRAME_DONTCHANGE)
 881         {
 882                 fr = self.weaponentity.wframe;
 883                 restartanim = FALSE;
 884         }
 885         else if (fr == WFRAME_IDLE)
 886                 restartanim = FALSE;
 887         else
 888                 restartanim = TRUE;
 889
 890         of = v_forward;
 891         or = v_right;
 892         ou = v_up;
 893
 894         if (self.weaponentity)
 895         {
 896                 self.weaponentity.wframe = fr;
 897                 if (qcweaponanimation)
 898                 {
 899                         if (fr != WFRAME_IDLE)
 900                         {
 901                                 self.weapon_morph0time = time;
 902                                 self.weapon_morph0angles = self.weaponentity.angles;
 903                                 self.weapon_morph0origin = self.weaponentity.origin;
 904
 905                                 self.weapon_morph1angles = '0 0 0';
 906                                 self.weapon_morph1time = time + t;
 907                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 908                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 909
 910                                 self.weapon_morph2angles = '0 0 0';
 911                                 self.weapon_morph2time = time + t;
 912                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
 913                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 914
 915                                 self.weapon_morph3angles = '0 0 0';
 916                                 self.weapon_morph3time = time + t;
 917                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
 918                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 919
 920                                 self.weapon_morph4angles = '0 0 0';
 921                                 self.weapon_morph4time = time + t;
 922                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
 923                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 924
 925                                 if (fr == WFRAME_FIRE1)
 926                                 {
 927                                         self.weapon_morph1angles = '5 0 0';
 928                                         self.weapon_morph1time = time + t * 0.1;
 929                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 930                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 931                                         self.weapon_morph4time = time + t + 1; // delay idle effect
 932                                 }
 933                                 else if (fr == WFRAME_FIRE2)
 934                                 {
 935                                         self.weapon_morph1angles = '10 0 0';
 936                                         self.weapon_morph1time = time + t * 0.1;
 937                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 938                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 939                                         self.weapon_morph4time = time + t + 1; // delay idle effect
 940                                 }
 941                                 else if (fr == WFRAME_RELOAD)
 942                                 {
 943                                         self.weapon_morph1time = time + t * 0.05;
 944                                         self.weapon_morph1angles = '-10 40 0';
 945                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 946                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 947
 948                                         self.weapon_morph2time = time + t * 0.15;
 949                                         self.weapon_morph2angles = '-10 40 5';
 950                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
 951                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 952
 953                                         self.weapon_morph3time = time + t * 0.25;
 954                                         self.weapon_morph3angles = '-10 40 0';
 955                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
 956                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 957                                 }
 958                         }
 959                 }
 960                 else
 961                 {
 962                         if (fr == WFRAME_IDLE)
 963                                 a = self.weaponentity.anim_idle;
 964                         else if (fr == WFRAME_FIRE1)
 965                                 a = self.weaponentity.anim_fire1;
 966                         else if (fr == WFRAME_FIRE2)
 967                                 a = self.weaponentity.anim_fire2;
 968                         else if (fr == WFRAME_RELOAD)
 969                                 a = self.weaponentity.anim_reload;
 970                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 971                 }
 972
 973                 if(restartanim)
 974                 {
 975                         BITXOR_ASSIGN(self.weaponentity.effects, EF_TELEPORT_BIT);
 976                 }
 977         }
 978
 979         v_forward = of;
 980         v_right = or;
 981         v_up = ou;
 982
 983         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 984         {
 985                 backtrace("Tried to override initial weapon think function - should this really happen?");
 986         }
 987
 988         if(g_runematch)
 989         {
 990                 if(self.runes & RUNE_SPEED)
 991                 {
 992                         if(self.runes & CURSE_SLOW)
 993                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
 994                         else
 995                                 t = t * cvar("g_balance_rune_speed_atkrate");
 996                 }
 997                 else if(self.runes & CURSE_SLOW)
 998                 {
 999                         t = t * cvar("g_balance_curse_slow_atkrate");
1000                 }
1001         }
1002
1003         // VorteX: haste can be added here
1004         if (self.weapon_think == w_ready)
1005         {
1006                 self.weapon_nextthink = time;
1007                 //dprint("started firing at ", ftos(time), "\n");
1008         }
1009         if (self.weapon_nextthink < time - frametime * 1.5 || self.weapon_nextthink > time + frametime * 1.5)
1010         {
1011                 self.weapon_nextthink = time;
1012                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1013         }
1014         self.weapon_nextthink = self.weapon_nextthink + t;
1015         self.weapon_think = func;
1016         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1017
1018         if (restartanim)
1019         if (t)
1020         if (!self.crouch) // shoot anim stands up, this looks bad
1021         {
1022                 local vector anim;
1023                 anim = self.anim_shoot;
1024                 anim_z = anim_y / t;
1025                 setanim(self, anim, FALSE, TRUE, TRUE);
1026         }
1027 };
1028
1029 void weapon_boblayer1(float spd, vector org)
1030 {
1031         // VorteX: haste can be added here
1032 };
1033
1034 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1035 {
1036         vector mdirection;
1037         float mspeed;
1038         float outspeed;
1039         float nstyle;
1040         vector outvelocity;
1041
1042         mdirection = normalize(mvelocity);
1043         mspeed = vlen(mvelocity);
1044
1045         nstyle = cvar("g_projectiles_newton_style");
1046         if(nstyle == 0)
1047         {
1048                 // absolute velocity
1049                 outvelocity = mvelocity;
1050         }
1051         else if(nstyle == 1)
1052         {
1053                 // true Newtonian projectiles
1054                 outvelocity = pvelocity + mvelocity;
1055         }
1056         else if(nstyle == 2)
1057         {
1058                 // true Newtonian projectiles with automatic aim adjustment
1059                 //
1060                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1061                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1062                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1063                 // PLUS SIGN!
1064                 // not defined?
1065                 // then...
1066                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1067                 // velocity without mdirection component > mspeed
1068                 // fire at smallest possible mspeed that works?
1069                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1070
1071                 float D;
1072                 float p;
1073                 float q;
1074                 p = mdirection * pvelocity;
1075                 q = pvelocity * pvelocity - mspeed * mspeed;
1076                 D = p * p - q;
1077                 if(D < 0)
1078                 {
1079                         //dprint("impossible shot, adjusting\n");
1080                         D = 0;
1081                 }
1082                 outspeed = p + sqrt(D);
1083                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1084                 outvelocity = mdirection * outspeed;
1085         }
1086         else if(nstyle == 3)
1087         {
1088                 // pseudo-Newtonian:
1089                 outspeed = mspeed + mdirection * pvelocity;
1090                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1091                 outvelocity = mdirection * outspeed;
1092         }
1093         else if(nstyle == 4)
1094         {
1095                 // tZorkian:
1096                 outspeed = mspeed + vlen(pvelocity);
1097                 outvelocity = mdirection * outspeed;
1098         }
1099         else
1100                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1101
1102         return outvelocity;
1103 }
1104
1105 void W_SetupProjectileVelocity(entity missile)
1106 {
1107         if(missile.owner == world)
1108                 error("Unowned missile");
1109
1110         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, missile.velocity);
1111 }