data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 void W_SwitchWeapon_Force(entity e, float w)
  11 {
  12         e.cnt = e.switchweapon;
  13         e.switchweapon = w;
  14 }
  15
  16 .float antilag_debug;
  17
  18 // VorteX: static frame globals
  19 float WFRAME_FIRE1 = 0;
  20 float WFRAME_FIRE2 = 1;
  21 float WFRAME_IDLE = 2;
  22 float WFRAME_RELOAD = 3;
  23 .float wframe;
  24
  25 void(float fr, float t, void() func) weapon_thinkf;
  26
  27 vector w_shotorg;
  28 vector w_shotdir;
  29
  30 // this function calculates w_shotorg and w_shotdir based on the weapon model
  31 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  32 // make sure you call makevectors first (FIXME?)
  33 void W_SetupShot(entity ent, vector vecs, float antilag, float recoil, string snd)
  34 {
  35         float nudge = 1; // added to traceline target and subtracted from result
  36         local vector trueaimpoint;
  37         local float oldsolid;
  38         oldsolid = self.dphitcontentsmask;
  39         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  40         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, self);
  41         trueaimpoint = trace_endpos;
  42
  43         if(debug_shotorg != '0 0 0')
  44                 vecs = debug_shotorg;
  45
  46         if (cvar("g_shootfromeye"))
  47                 w_shotorg = ent.origin + ent.view_ofs;
  48         else if (cvar("g_shootfromcenter"))
  49                 w_shotorg = ent.origin + ent.view_ofs + v_up * vecs_z;
  50         else
  51                 w_shotorg = ent.origin + ent.view_ofs + v_right * vecs_y + v_up * vecs_z;
  52         // now move the shotorg forward as much as requested if possible
  53         traceline(w_shotorg, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, self);
  54         w_shotorg = trace_endpos - v_forward * nudge;
  55         // calculate the shotdir from the chosen shotorg
  56         w_shotdir = normalize(trueaimpoint - w_shotorg);
  57
  58 #if 0
  59         // explanation of g_antilag:
  60         // if client reports it was aiming at a player, and the serverside trace
  61         // says it would miss, change the aim point to the player's new origin,
  62         // but only if the shot at the player's new origin would hit of course
  63         //
  64         // FIXME: a much better method for bullet weapons would be to leave a
  65         // trail of lagged 'ghosts' behind players, and see if the bullet hits the
  66         // ghost corresponding to this player's ping time, and if so it would do
  67         // damage to the real player
  68         if (antilag)
  69         if (self.cursor_trace_ent)                 // client was aiming at someone
  70         if (self.cursor_trace_ent != self)         // just to make sure
  71         if (self.cursor_trace_ent.takedamage)      // and that person is killable
  72         if (self.cursor_trace_ent.classname == "player") // and actually a player
  73         if (cvar("g_antilag") == 1)
  74         {
  75                 // verify that the shot would miss without antilag
  76                 // (avoids an issue where guns would always shoot at their origin)
  77                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  78                 if (!trace_ent.takedamage)
  79                 {
  80                         // verify that the shot would hit if altered
  81                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
  82                         if (trace_ent == self.cursor_trace_ent)
  83                         {
  84                                 // verify that the shot would hit in the past
  85                                 if(self.antilag_debug)
  86                                         antilag_takeback(self.cursor_trace_ent, time - self.antilag_debug);
  87                                 else
  88                                         antilag_takeback(self.cursor_trace_ent, time - ANTILAG_LATENCY(self));
  89
  90                                 traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  91                                 antilag_restore(self.cursor_trace_ent);
  92
  93                                 if(trace_ent == self.cursor_trace_ent)
  94                                 {
  95                                         // HIT!
  96                                         w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
  97                                         dprint("ANTILAG HIT for ", self.netname, "\n");
  98                                 }
  99                                 else
 100                                 {
 101                                         // prydon cursor aimbot or odd network conditions
 102                                         dprint("WARNING: antilag ghost trace for ", self.netname, " failed!\n");
 103                                 }
 104
 105                                 if(cvar("developer") >= 2)
 106                                 {
 107                                         vector v, vplus, vel;
 108                                         float X;
 109                                         v     = antilag_takebackorigin(self.cursor_trace_ent, time - (ANTILAG_LATENCY(self)       ));
 110                                         vplus = antilag_takebackorigin(self.cursor_trace_ent, time - (ANTILAG_LATENCY(self) + 0.01));
 111                                         vel = (vplus - v) * (1 / 0.01);
 112                                         // solve: v + X * vel = closest to self.origin + self.view_ofs, v_forward axis
 113                                         v     -= (self.origin + self.view_ofs);
 114                                         // solve: v + X * vel = closest to v_forward axis
 115                                         // project into 2D by subtracting v_forward components:
 116                                         v   -= (v   * v_forward) * v_forward;
 117                                         vel -= (vel * v_forward) * v_forward;
 118                                         // solve: v + X * vel = closest to origin
 119                                         // (v + X * vel)^2 closest to 0
 120                                         // v^2 + 2 * X * (v * vel) + X^2 * vel^2 closest to 0
 121                                         X = -(v * vel) / (vel * vel);
 122                                         dprint("dead center needs adjustment of ", ftos(X), " (that is, ", ftos(ANTILAG_LATENCY(self) + X), " instead of ", ftos(ANTILAG_LATENCY(self)), "\n");
 123                                 }
 124                         }
 125                 }
 126         }
 127 #else
 128         if (antilag)
 129         {
 130                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 131                 {
 132                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 133                         if (!trace_ent.takedamage)
 134                         {
 135                                 traceline_antilag_force (self, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self, ANTILAG_LATENCY(self));
 136                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 137                                 {
 138                                         entity e;
 139                                         e = trace_ent;
 140                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, self);
 141                                         if(trace_ent == e)
 142                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 143                                 }
 144                         }
 145                 }
 146                 else if(cvar("g_antilag") == 3) // client side hitscan
 147                 {
 148                         if (self.cursor_trace_ent)                 // client was aiming at someone
 149                         if (self.cursor_trace_ent != self)         // just to make sure
 150                         if (self.cursor_trace_ent.takedamage)      // and that person is killable
 151                         if (self.cursor_trace_ent.classname == "player") // and actually a player
 152                         {
 153                                 // verify that the shot would miss without antilag
 154                                 // (avoids an issue where guns would always shoot at their origin)
 155                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 156                                 if (!trace_ent.takedamage)
 157                                 {
 158                                         // verify that the shot would hit if altered
 159                                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
 160                                         if (trace_ent == self.cursor_trace_ent)
 161                                                 w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
 162                                         else
 163                                                 print("antilag fail\n");
 164                                 }
 165                         }
 166                 }
 167         }
 168 #endif
 169
 170         self.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 171
 172         if (!g_norecoil)
 173                 self.punchangle_x = recoil * -1;
 174
 175         if (snd != "")
 176         {
 177                 sound (self, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 178         }
 179
 180         if (self.items & IT_STRENGTH)
 181         if (!g_minstagib)
 182                 sound (self, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 183 };
 184
 185 void LaserTarget_Think()
 186 {
 187         entity e;
 188         vector offset;
 189         float uselaser;
 190         uselaser = 0;
 191
 192         // list of weapons that will use the laser, and the options that enable it
 193         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 194                 uselaser = 1;
 195         // example
 196         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 197         //      uselaser = 1;
 198
 199
 200
 201         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 202         if(!uselaser)
 203         {
 204                 // rocket launcher isn't selected, so no laser target.
 205                 if(self.lasertarget != world)
 206                 {
 207                         remove(self.lasertarget);
 208                         self.lasertarget = world;
 209                 }
 210                 return;
 211         }
 212
 213         if(!self.lasertarget)
 214         {
 215                 // we don't have a lasertarget entity, so spawn one
 216                 //bprint("create laser target\n");
 217                 e = self.lasertarget = spawn();
 218                 e.owner = self.owner;                   // Its owner is my owner
 219                 e.classname = "laser_target";
 220                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 221                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 222                 e.scale = 1.25;                         // make it larger
 223                 e.alpha = 0.25;                         // transparency
 224                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 225                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 226                 // make it dynamically glow
 227                 // you should avoid over-using this, as it can slow down the player's computer.
 228                 e.glow_color = 251; // red color
 229                 e.glow_size = 12;
 230         }
 231         else
 232                 e = self.lasertarget;
 233
 234         // move the laser dot to where the player is looking
 235
 236         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 237         offset = '0 0 26' + v_right*3;
 238         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 239         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 240         if(trace_plane_normal != '0 0 0')
 241                 e.angles = vectoangles(trace_plane_normal);
 242         else
 243                 e.angles = vectoangles(v_forward);
 244 }
 245
 246 float CL_Weaponentity_CustomizeEntityForClient()
 247 {
 248         self.viewmodelforclient = self.owner;
 249         if(other.classname == "spectator")
 250                 if(other.enemy == self.owner)
 251                         self.viewmodelforclient = other;
 252         return TRUE;
 253 }
 254
 255 float qcweaponanimation;
 256 vector weapon_offset = '0 -10 0';
 257 vector weapon_adjust = '10 0 -15';
 258 .vector weapon_morph0origin;
 259 .vector weapon_morph0angles;
 260 .float  weapon_morph0time;
 261 .vector weapon_morph1origin;
 262 .vector weapon_morph1angles;
 263 .float  weapon_morph1time;
 264 .vector weapon_morph2origin;
 265 .vector weapon_morph2angles;
 266 .float  weapon_morph2time;
 267 .vector weapon_morph3origin;
 268 .vector weapon_morph3angles;
 269 .float  weapon_morph3time;
 270 .vector weapon_morph4origin;
 271 .vector weapon_morph4angles;
 272 .float  weapon_morph4time;
 273 .string weaponname;
 274
 275 void CL_Weaponentity_Think()
 276 {
 277         float tb;
 278         self.nextthink = time;
 279         if (intermission_running)
 280                 self.frame = self.anim_idle_x;
 281         if (self.owner.weaponentity != self)
 282         {
 283                 if (self.weaponentity)
 284                         remove(self.weaponentity);
 285                 remove(self);
 286                 return;
 287         }
 288         if (self.owner.deadflag != DEAD_NO)
 289         {
 290                 self.model = "";
 291                 if (self.weaponentity)
 292                         self.weaponentity.model = "";
 293                 return;
 294         }
 295         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 296         {
 297                 self.cnt = self.owner.weapon;
 298                 self.dmg = self.owner.modelindex;
 299                 self.deadflag = self.owner.deadflag;
 300
 301                 string animfilename;
 302                 float animfile;
 303                 if (self.owner.weaponname != "")
 304                 {
 305                         // if there is a child entity, hide it until we're sure we use it
 306                         if (self.weaponentity)
 307                                 self.weaponentity.model = "";
 308                         if (qcweaponanimation)
 309                                 setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 310                         else
 311                         {
 312                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".dpm.animinfo");
 313                                 animfile = fopen(animfilename, FILE_READ);
 314                                 if (animfile >= 0)
 315                                 {
 316                                         if (!self.weaponentity)
 317                                                 self.weaponentity = spawn();
 318                                         setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".dpm")); // precision set below
 319                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 320                                         setattachment(self.weaponentity, self, "weapon");
 321                                 }
 322                                 else
 323                                 {
 324                                         animfilename = strcat("models/weapons/w_", self.owner.weaponname, ".dpm.animinfo");
 325                                         animfile = fopen(animfilename, FILE_READ);
 326                                         if (animfile >= 0)
 327                                                 setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".dpm")); // precision set below
 328                                 }
 329                                 if (animfile >= 0)
 330                                 {
 331                                         animparseerror = FALSE;
 332                                         self.anim_fire1  = animparseline(animfile);
 333                                         self.anim_fire2  = animparseline(animfile);
 334                                         self.anim_idle   = animparseline(animfile);
 335                                         self.anim_reload = animparseline(animfile);
 336                                         fclose(animfile);
 337                                         if (animparseerror)
 338                                                 print("Parse error in ", animfilename, ", some player animations are broken\n");
 339                                 }
 340                                 else
 341                                 {
 342                                         self.anim_fire1  = '0 1 10';
 343                                         self.anim_fire2  = '1 1 10';
 344                                         self.anim_idle   = '2 1 10';
 345                                         self.anim_reload = '3 1 10';
 346                                         setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".zym")); // precision set below
 347                                 }
 348                         }
 349                 }
 350                 else
 351                         self.model = "";
 352
 353                 // reset animstate now
 354                 self.wframe = WFRAME_IDLE;
 355                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 356
 357                 if(cvar("g_shootfromcenter") || cvar("g_shootfromeye"))
 358                 {
 359                         entity e;
 360                         e = spawn();
 361                         e.modelindex = self.modelindex;
 362                         float idx;
 363                         vector v;
 364                         idx = gettagindex(e, "shot");
 365                         if (!idx)
 366                                 idx = gettagindex(e, "bone02");
 367                         if(idx)
 368                         {
 369                                 v = gettaginfo(e, idx);
 370                                 setorigin(self, '0 -1 0' * v_y);
 371                         }
 372                         else
 373                                 setorigin(self, '0 0 0');
 374                         remove(e);
 375                 }
 376                 else
 377                         setorigin(self, '0 0 0');
 378         }
 379
 380         tb = (self.effects & EF_TELEPORT_BIT);
 381         self.effects = self.owner.effects - (self.owner.effects & EF_LOWPRECISION);// | EF_LOWPRECISION;
 382         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 383         self.effects &~= EF_TELEPORT_BIT;
 384         self.effects |= tb;
 385
 386         if(self.owner.alpha != 0)
 387                 self.alpha = self.owner.alpha;
 388         else
 389                 self.alpha = 1;
 390
 391         self.colormap = self.owner.colormap;
 392         if (self.weaponentity)
 393         {
 394                 self.weaponentity.effects = self.effects & EF_ADDITIVE;
 395                 self.weaponentity.alpha = self.alpha;
 396                 self.weaponentity.colormap = self.colormap;
 397         }
 398
 399         self.angles = '0 0 0';
 400         local float f;
 401         f = 0;
 402         if (self.state == WS_RAISE)
 403         {
 404                 f = (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 405                 self.angles_x = -90 * f * f;
 406                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 407                 setorigin(self, weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust);
 408         }
 409         else if (self.state == WS_DROP)
 410         {
 411                 f = 1 - (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 412                 self.angles_x = -90 * f * f;
 413                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 414                 setorigin(self, weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust);
 415         }
 416         else if (self.state == WS_CLEAR)
 417         {
 418                 f = 1;
 419                 self.angles_x = -90 * f * f;
 420                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 421                 setorigin(self, weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust);
 422         }
 423         else if (time < self.owner.weapon_morph1time)
 424         {
 425                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 426                 f = 1 - pow(1 - f, 3);
 427                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 428                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 429         }
 430         else if (time < self.owner.weapon_morph2time)
 431         {
 432                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 433                 f = 1 - pow(1 - f, 3);
 434                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 435                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 436         }
 437         else if (time < self.owner.weapon_morph3time)
 438         {
 439                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 440                 f = 1 - pow(1 - f, 3);
 441                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 442                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 443         }
 444         else if (time < self.owner.weapon_morph4time)
 445         {
 446                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 447                 f = 1 - pow(1 - f, 3);
 448                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 449                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 450         }
 451         else if (qcweaponanimation)
 452         {
 453                 // begin a new idle morph
 454                 self.owner.weapon_morph0time   = time;
 455                 self.owner.weapon_morph0angles = self.angles;
 456                 self.owner.weapon_morph0origin = self.origin;
 457
 458                 float r;
 459                 float t;
 460
 461                 r = random();
 462                 if (r < 0.1)
 463                 {
 464                         // turn gun to the left to look at it
 465                         t = 2;
 466                         self.owner.weapon_morph1time   = time + t * 0.2;
 467                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 468                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 469                         self.owner.weapon_morph1origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 470
 471                         self.owner.weapon_morph2time   = time + t * 0.6;
 472                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 473                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 474                         self.owner.weapon_morph2origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 475
 476                         self.owner.weapon_morph3time   = time + t;
 477                         self.owner.weapon_morph3angles = '0 0 0';
 478                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 479                         self.owner.weapon_morph3origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 480                 }
 481                 else if (r < 0.2)
 482                 {
 483                         // raise the gun a bit
 484                         t = 2;
 485                         self.owner.weapon_morph1time   = time + t * 0.2;
 486                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 487                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 488                         self.owner.weapon_morph1origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 489
 490                         self.owner.weapon_morph2time   = time + t * 0.5;
 491                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 492                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 493                         self.owner.weapon_morph2origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 494
 495                         self.owner.weapon_morph3time   = time + t;
 496                         self.owner.weapon_morph3angles = '0 0 0';
 497                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 498                         self.owner.weapon_morph3origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 499                 }
 500                 else if (r < 0.3)
 501                 {
 502                         // tweak it a bit
 503                         t = 5;
 504                         self.owner.weapon_morph1time   = time + t * 0.3;
 505                         self.owner.weapon_morph1angles = randomvec() * 6;
 506                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 507                         self.owner.weapon_morph1origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 508
 509                         self.owner.weapon_morph2time   = time + t * 0.7;
 510                         self.owner.weapon_morph2angles = randomvec() * 6;
 511                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 512                         self.owner.weapon_morph2origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 513
 514                         self.owner.weapon_morph3time   = time + t;
 515                         self.owner.weapon_morph3angles = '0 0 0';
 516                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 517                         self.owner.weapon_morph3origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 518                 }
 519                 else
 520                 {
 521                         // hold it mostly steady
 522                         t = random() * 6 + 4;
 523                         self.owner.weapon_morph1time   = time + t * 0.2;
 524                         self.owner.weapon_morph1angles = randomvec() * 1;
 525                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 526                         self.owner.weapon_morph1origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 527
 528                         self.owner.weapon_morph2time   = time + t * 0.5;
 529                         self.owner.weapon_morph2angles = randomvec() * 1;
 530                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 531                         self.owner.weapon_morph2origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 532
 533                         self.owner.weapon_morph3time   = time + t * 0.7;
 534                         self.owner.weapon_morph3angles = randomvec() * 1;
 535                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 536                         self.owner.weapon_morph3origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 537                 }
 538
 539                 self.owner.weapon_morph4time   = time + t;
 540                 self.owner.weapon_morph4angles = '0 0 0';
 541                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 542                 self.owner.weapon_morph4origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 543
 544         }
 545
 546         // create or update the lasertarget entity
 547         LaserTarget_Think();
 548 };
 549
 550 void CL_ExteriorWeaponentity_Think()
 551 {
 552         float tag_found;
 553         self.nextthink = time;
 554         if (self.owner.exteriorweaponentity != self)
 555         {
 556                 remove(self);
 557                 return;
 558         }
 559         if (self.owner.deadflag != DEAD_NO)
 560         {
 561                 self.model = "";
 562                 return;
 563         }
 564         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 565         {
 566                 self.cnt = self.owner.weapon;
 567                 self.dmg = self.owner.modelindex;
 568                 self.deadflag = self.owner.deadflag;
 569                 if (self.owner.weaponname != "")
 570                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 571                 else
 572                         self.model = "";
 573
 574                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 575                 {
 576                         self.tag_index = tag_found;
 577                         self.tag_entity = self.owner;
 578                 }
 579                 else
 580                         setattachment(self, self.owner, "bip01 r hand");
 581
 582                 // if that didn't find a tag, hide the exterior weapon model
 583                 if (!self.tag_index)
 584                         self.model = "";
 585         }
 586         self.effects = self.owner.effects | EF_LOWPRECISION;
 587         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 588         if(self.owner.alpha != 0)
 589                 self.alpha = self.owner.alpha;
 590         else
 591                 self.alpha = 1;
 592
 593         self.colormap = self.owner.colormap;
 594 };
 595
 596 // spawning weaponentity for client
 597 void CL_SpawnWeaponentity()
 598 {
 599         self.weaponentity = spawn();
 600         self.weaponentity.classname = "weaponentity";
 601         self.weaponentity.solid = SOLID_NOT;
 602         self.weaponentity.owner = self;
 603         setmodel(self.weaponentity, ""); // precision set when changed
 604         self.weaponentity.origin = '0 0 0';
 605         self.weaponentity.angles = '0 0 0';
 606         self.weaponentity.viewmodelforclient = self;
 607         self.weaponentity.flags = 0;
 608         self.weaponentity.think = CL_Weaponentity_Think;
 609         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 610         self.weaponentity.nextthink = time;
 611
 612         self.exteriorweaponentity = spawn();
 613         self.exteriorweaponentity.classname = "exteriorweaponentity";
 614         self.exteriorweaponentity.solid = SOLID_NOT;
 615         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 616         self.exteriorweaponentity.owner = self;
 617         self.exteriorweaponentity.origin = '0 0 0';
 618         self.exteriorweaponentity.angles = '0 0 0';
 619         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 620         self.exteriorweaponentity.nextthink = time;
 621 };
 622
 623 .float hasweapon_complain_spam;
 624
 625 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 626 {
 627         local float weaponbit, f;
 628         local entity oldself;
 629
 630         if(time < self.hasweapon_complain_spam)
 631                 complain = 0;
 632         if(complain)
 633                 self.hasweapon_complain_spam = time + 0.2;
 634
 635         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 636         {
 637                 if (complain)
 638                         sprint(self, "Invalid weapon\n");
 639                 return FALSE;
 640         }
 641         weaponbit = W_WeaponBit(wpn);
 642         if (cl.weapons & weaponbit)
 643         {
 644                 if (andammo)
 645                 {
 646                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 647                         {
 648                                 f = 1;
 649                         }
 650                         else
 651                         {
 652                                 oldself = self;
 653                                 self = cl;
 654                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 655                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 656                                 self = oldself;
 657                         }
 658                         if (!f)
 659                         {
 660                                 if (complain)
 661                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 662                                 return FALSE;
 663                         }
 664                 }
 665                 return TRUE;
 666         }
 667         if (complain)
 668         {
 669                 // DRESK - 3/16/07
 670                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 671                 if(weaponsInMap & weaponbit)
 672                 {
 673                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 674
 675                         if(cvar("g_showweaponspawns"))
 676                         {
 677                                 entity e;
 678                                 string s;
 679
 680                                 e = get_weaponinfo(wpn);
 681                                 s = e.model2;
 682
 683                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 684                                 {
 685                                         if(e.classname == "droppedweapon")
 686                                                 continue;
 687                                         if not(e.flags & FL_ITEM)
 688                                                 continue;
 689                                         WaypointSprite_Spawn(
 690                                                 s,
 691                                                 1, 0,
 692                                                 world, e.origin,
 693                                                 self, 0,
 694                                                 world, enemy,
 695                                                 0
 696                                         );
 697                                 }
 698                         }
 699                 }
 700                 else
 701                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 702         }
 703         return FALSE;
 704 };
 705
 706 // Weapon subs
 707 void w_clear()
 708 {
 709         if (self.weapon != -1)
 710                 self.weapon = 0;
 711         if (self.weaponentity)
 712         {
 713                 self.weaponentity.state = WS_CLEAR;
 714                 self.weaponentity.effects = 0;
 715         }
 716 };
 717
 718 void w_ready()
 719 {
 720         if (self.weaponentity)
 721                 self.weaponentity.state = WS_READY;
 722         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 723 };
 724
 725 // Setup weapon for client (after this raise frame will be launched)
 726 void weapon_setup(float windex)
 727 {
 728         entity e;
 729         qcweaponanimation = cvar("sv_qcweaponanimation");
 730         e = get_weaponinfo(windex);
 731         self.items &~= IT_AMMO;
 732         self.items = self.items | e.items;
 733
 734         // the two weapon entities will notice this has changed and update their models
 735         self.weapon = windex;
 736         self.weaponname = e.mdl;
 737         self.bulletcounter = 0;
 738 };
 739
 740 // perform weapon to attack (weaponstate and attack_finished check is here)
 741 .float race_penalty;
 742 float weapon_prepareattack(float secondary, float attacktime)
 743 {
 744         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 745         //if all players readied up and the countdown is running
 746         if (cvar("sv_ready_restart_after_countdown"))
 747                 if(time < game_starttime || time < self.race_penalty) {
 748                         return FALSE;
 749                 }
 750
 751         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 752         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 753         {
 754                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 755                 return FALSE;
 756         }
 757
 758         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 759                 return FALSE;
 760
 761         // do not even think about shooting if switching
 762         if(self.switchweapon != self.weapon)
 763                 return FALSE;
 764
 765         // don't fire if previous attack is not finished
 766         if(attacktime >= 0)
 767                 if (ATTACK_FINISHED(self) > time + frametime * 0.5)
 768                         return FALSE;
 769         // don't fire while changing weapon
 770         if (self.weaponentity.state != WS_READY)
 771                 return FALSE;
 772         self.weaponentity.state = WS_INUSE;
 773
 774         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 775
 776         // if the weapon hasn't been firing continuously, reset the timer
 777         if(attacktime >= 0)
 778         {
 779                 if (ATTACK_FINISHED(self) < time - frametime * 1.5)
 780                 {
 781                         ATTACK_FINISHED(self) = time;
 782                         //dprint("resetting attack finished to ", ftos(time), "\n");
 783                 }
 784                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime;
 785         }
 786         self.bulletcounter += 1;
 787         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 788         return TRUE;
 789 };
 790
 791 void weapon_thinkf(float fr, float t, void() func)
 792 {
 793         vector a;
 794         vector of, or, ou;
 795         float restartanim;
 796
 797         if (fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2)
 798                 restartanim = TRUE;
 799         else
 800                 restartanim = FALSE;
 801
 802         of = v_forward;
 803         or = v_right;
 804         ou = v_up;
 805
 806         if (self.weaponentity)
 807         {
 808                 self.weaponentity.wframe = fr;
 809                 if (qcweaponanimation)
 810                 {
 811                         if (fr != WFRAME_IDLE)
 812                         {
 813                                 self.weapon_morph0time = time;
 814                                 self.weapon_morph0angles = self.weaponentity.angles;
 815                                 self.weapon_morph0origin = self.weaponentity.origin;
 816
 817                                 self.weapon_morph1angles = '0 0 0';
 818                                 self.weapon_morph1time = time + t;
 819                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 820                                 self.weapon_morph1origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 821
 822                                 self.weapon_morph2angles = '0 0 0';
 823                                 self.weapon_morph2time = time + t;
 824                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
 825                                 self.weapon_morph2origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 826
 827                                 self.weapon_morph3angles = '0 0 0';
 828                                 self.weapon_morph3time = time + t;
 829                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
 830                                 self.weapon_morph3origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 831
 832                                 self.weapon_morph4angles = '0 0 0';
 833                                 self.weapon_morph4time = time + t;
 834                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
 835                                 self.weapon_morph4origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 836
 837                                 if (fr == WFRAME_FIRE1)
 838                                 {
 839                                         self.weapon_morph1angles = '5 0 0';
 840                                         self.weapon_morph1time = time + t * 0.1;
 841                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 842                                         self.weapon_morph1origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 843                                         self.weapon_morph4time = time + t + 1; // delay idle effect
 844                                 }
 845                                 else if (fr == WFRAME_FIRE2)
 846                                 {
 847                                         self.weapon_morph1angles = '10 0 0';
 848                                         self.weapon_morph1time = time + t * 0.1;
 849                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 850                                         self.weapon_morph1origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 851                                         self.weapon_morph4time = time + t + 1; // delay idle effect
 852                                 }
 853                                 else if (fr == WFRAME_RELOAD)
 854                                 {
 855                                         self.weapon_morph1time = time + t * 0.05;
 856                                         self.weapon_morph1angles = '-10 40 0';
 857                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 858                                         self.weapon_morph1origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 859
 860                                         self.weapon_morph2time = time + t * 0.15;
 861                                         self.weapon_morph2angles = '-10 40 5';
 862                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
 863                                         self.weapon_morph2origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 864
 865                                         self.weapon_morph3time = time + t * 0.25;
 866                                         self.weapon_morph3angles = '-10 40 0';
 867                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
 868                                         self.weapon_morph3origin = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 869                                 }
 870                         }
 871                 }
 872                 else
 873                 {
 874                         if (fr == WFRAME_IDLE)
 875                                 a = self.weaponentity.anim_idle;
 876                         else if (fr == WFRAME_FIRE1)
 877                                 a = self.weaponentity.anim_fire1;
 878                         else if (fr == WFRAME_FIRE2)
 879                                 a = self.weaponentity.anim_fire2;
 880                         else if (fr == WFRAME_RELOAD)
 881                                 a = self.weaponentity.anim_reload;
 882                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 883                 }
 884
 885                 if(restartanim)
 886                 {
 887                         BITXOR_ASSIGN(self.weaponentity.effects, EF_TELEPORT_BIT);
 888                 }
 889         }
 890
 891         v_forward = of;
 892         v_right = or;
 893         v_up = ou;
 894
 895         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 896         {
 897                 backtrace("Tried to override initial weapon think function - should this really happen?");
 898         }
 899
 900         if(g_runematch)
 901         {
 902                 if(self.runes & RUNE_SPEED)
 903                 {
 904                         if(self.runes & CURSE_SLOW)
 905                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
 906                         else
 907                                 t = t * cvar("g_balance_rune_speed_atkrate");
 908                 }
 909                 else if(self.runes & CURSE_SLOW)
 910                 {
 911                         t = t * cvar("g_balance_curse_slow_atkrate");
 912                 }
 913         }
 914
 915         // VorteX: haste can be added here
 916         if (self.weapon_think == w_ready)
 917         {
 918                 self.weapon_nextthink = time;
 919                 //dprint("started firing at ", ftos(time), "\n");
 920         }
 921         if (self.weapon_nextthink < time - frametime * 1.5 || self.weapon_nextthink > time + frametime * 1.5)
 922         {
 923                 self.weapon_nextthink = time;
 924                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
 925         }
 926         self.weapon_nextthink = self.weapon_nextthink + t;
 927         self.weapon_think = func;
 928         //dprint("next ", ftos(self.weapon_nextthink), "\n");
 929
 930         if (restartanim)
 931         if (t)
 932         if (!self.crouch) // shoot anim stands up, this looks bad
 933         {
 934                 local vector anim;
 935                 anim = self.anim_shoot;
 936                 anim_z = anim_y / t;
 937                 setanim(self, anim, FALSE, TRUE, TRUE);
 938         }
 939 };
 940
 941 void weapon_boblayer1(float spd, vector org)
 942 {
 943         // VorteX: haste can be added here
 944 };
 945
 946 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
 947 {
 948         vector mdirection;
 949         float mspeed;
 950         float outspeed;
 951         float nstyle;
 952         vector outvelocity;
 953
 954         mdirection = normalize(mvelocity);
 955         mspeed = vlen(mvelocity);
 956
 957         nstyle = cvar("g_projectiles_newton_style");
 958         if(nstyle == 0)
 959         {
 960                 // absolute velocity
 961                 outvelocity = mvelocity;
 962         }
 963         else if(nstyle == 1)
 964         {
 965                 // true Newtonian projectiles
 966                 outvelocity = pvelocity + mvelocity;
 967         }
 968         else if(nstyle == 2)
 969         {
 970                 // true Newtonian projectiles with automatic aim adjustment
 971                 //
 972                 // solve: |outspeed * mdirection - pvelocity| = mspeed
 973                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
 974                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
 975                 // PLUS SIGN!
 976                 // not defined?
 977                 // then...
 978                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
 979                 // velocity without mdirection component > mspeed
 980                 // fire at smallest possible mspeed that works?
 981                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
 982
 983                 float D;
 984                 float p;
 985                 float q;
 986                 p = mdirection * pvelocity;
 987                 q = pvelocity * pvelocity - mspeed * mspeed;
 988                 D = p * p - q;
 989                 if(D < 0)
 990                 {
 991                         //dprint("impossible shot, adjusting\n");
 992                         D = 0;
 993                 }
 994                 outspeed = p + sqrt(D);
 995                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
 996                 outvelocity = mdirection * outspeed;
 997         }
 998         else if(nstyle == 3)
 999         {
1000                 // pseudo-Newtonian:
1001                 outspeed = mspeed + mdirection * pvelocity;
1002                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1003                 outvelocity = mdirection * outspeed;
1004         }
1005         else if(nstyle == 4)
1006         {
1007                 // tZorkian:
1008                 outspeed = mspeed + vlen(pvelocity);
1009                 outvelocity = mdirection * outspeed;
1010         }
1011         else
1012                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1013
1014         return outvelocity;
1015 }
1016
1017 void W_SetupProjectileVelocity(entity missile)
1018 {
1019         if(missile.owner == world)
1020                 error("Unowned missile");
1021
1022         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, missile.velocity);
1023 }