data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
  23                         else
  24                                 t = t * cvar("g_balance_rune_speed_atkrate");
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * cvar("g_balance_curse_slow_atkrate");
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39 }
  40
  41 .float antilag_debug;
  42
  43 // VorteX: static frame globals
  44 float WFRAME_DONTCHANGE = -1;
  45 float WFRAME_FIRE1 = 0;
  46 float WFRAME_FIRE2 = 1;
  47 float WFRAME_IDLE = 2;
  48 float WFRAME_RELOAD = 3;
  49 .float wframe;
  50
  51 void(float fr, float t, void() func) weapon_thinkf;
  52
  53 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  54 {
  55         vector ret;
  56         ret_x = screenright * v;
  57         ret_y = screenup * v;
  58         ret_z = screenforward * v;
  59         return ret;
  60 }
  61
  62 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  63 {
  64         float i, j, k;
  65         vector mi, ma, thisv, myv, ret;
  66
  67         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  68
  69         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  70
  71         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  72         {
  73                 thisv = targ.origin;
  74                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  75                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  76                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  77                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  78                 if(i || j || k)
  79                 {
  80                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  81                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  82                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  83                 }
  84                 else
  85                 {
  86                         // first run
  87                         mi = ma = thisv;
  88                 }
  89         }
  90
  91         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  92         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  93         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  94         ret_z = thisv_z - myv_z;
  95         return ret;
  96 }
  97
  98 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
  99 {
 100         vector hitplot;
 101         vector org;
 102         float lag;
 103
 104         if(player.hitplotfh >= 0)
 105         {
 106                 lag = ANTILAG_LATENCY(player);
 107                 if(lag < 0.001)
 108                         lag = 0;
 109                 if(clienttype(player) != CLIENTTYPE_REAL)
 110                         lag = 0; // only antilag for clients
 111
 112                 org = player.origin + player.view_ofs;
 113                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 114                 if(trace_ent.flags & FL_CLIENT)
 115                 {
 116                         antilag_takeback(trace_ent, time - lag);
 117                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 118                         antilag_restore(trace_ent);
 119                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 120                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 121                 }
 122         }
 123 }
 124
 125 vector w_shotorg;
 126 vector w_shotdir;
 127
 128 // this function calculates w_shotorg and w_shotdir based on the weapon model
 129 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 130 // make sure you call makevectors first (FIXME?)
 131 void W_SetupShot_Dir_ProjectileSize(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage)
 132 {
 133         float nudge = 1; // added to traceline target and subtracted from result
 134         local vector trueaimpoint;
 135         local float oldsolid;
 136         vector vecs, dv;
 137         oldsolid = ent.dphitcontentsmask;
 138         if(ent.weapon == WEP_CAMPINGRIFLE)
 139                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 140         else
 141                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 142         if(antilag)
 143                 traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 144                 // passing world, because we do NOT want it to touch dphitcontentsmask
 145         else
 146                 traceline(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, ent);
 147         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 148         trueaimpoint = trace_endpos;
 149
 150         // track max damage
 151         if not(inWarmupStage) {
 152                 entity w;
 153                 w = get_weaponinfo(ent.weapon);
 154                 if(w.weapon_type == WEP_TYPE_SPLASH) {  // splash damage
 155                         ent.stats_fired[ent.weapon - 1] += maxdamage;
 156                         ent.stat_fired = ent.weapon + 64 * floor(ent.stats_fired[ent.weapon - 1]);
 157                 }
 158         }
 159
 160         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 161
 162         if(ent.weaponentity.movedir_x > 0)
 163         {
 164                 vecs = ent.weaponentity.movedir;
 165                 vecs_y = -vecs_y;
 166         }
 167         else
 168                 vecs = '0 0 0';
 169
 170         if(debug_shotorg != '0 0 0')
 171                 vecs = debug_shotorg;
 172
 173         dv = v_right * vecs_y + v_up * vecs_z;
 174         w_shotorg = ent.origin + ent.view_ofs + dv;
 175
 176         // now move the shotorg forward as much as requested if possible
 177         if(antilag)
 178         {
 179                 if(ent.antilag_debug)
 180                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 181                 else
 182                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 183         }
 184         else
 185                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 186         w_shotorg = trace_endpos - v_forward * nudge;
 187         // calculate the shotdir from the chosen shotorg
 188         w_shotdir = normalize(trueaimpoint - w_shotorg);
 189
 190         if (antilag)
 191         if (!ent.cvar_cl_noantilag)
 192         {
 193                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 194                 {
 195                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
 196                         if (!trace_ent.takedamage)
 197                         {
 198                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 199                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 200                                 {
 201                                         entity e;
 202                                         e = trace_ent;
 203                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 204                                         if(trace_ent == e)
 205                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 206                                 }
 207                         }
 208                 }
 209                 else if(cvar("g_antilag") == 3) // client side hitscan
 210                 {
 211                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 212                         if (ent.cursor_trace_ent != ent)         // just to make sure
 213                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 214                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 215                         {
 216                                 // verify that the shot would miss without antilag
 217                                 // (avoids an issue where guns would always shoot at their origin)
 218                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
 219                                 if (!trace_ent.takedamage)
 220                                 {
 221                                         // verify that the shot would hit if altered
 222                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 223                                         if (trace_ent == ent.cursor_trace_ent)
 224                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 225                                         else
 226                                                 print("antilag fail\n");
 227                                 }
 228                         }
 229                 }
 230         }
 231
 232         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 233
 234         if (!g_norecoil)
 235                 ent.punchangle_x = recoil * -1;
 236
 237         if (snd != "")
 238         {
 239                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 240         }
 241
 242         if (ent.items & IT_STRENGTH)
 243         if (!g_minstagib)
 244                 sound (ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 245 };
 246
 247 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
 248 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 249 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 250
 251 void LaserTarget_Think()
 252 {
 253         entity e;
 254         vector offset;
 255         float uselaser;
 256         uselaser = 0;
 257
 258         // list of weapons that will use the laser, and the options that enable it
 259         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 260                 uselaser = 1;
 261         // example
 262         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 263         //      uselaser = 1;
 264
 265
 266
 267         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 268         if(!uselaser)
 269         {
 270                 // rocket launcher isn't selected, so no laser target.
 271                 if(self.lasertarget != world)
 272                 {
 273                         remove(self.lasertarget);
 274                         self.lasertarget = world;
 275                 }
 276                 return;
 277         }
 278
 279         if(!self.lasertarget)
 280         {
 281                 // we don't have a lasertarget entity, so spawn one
 282                 //bprint("create laser target\n");
 283                 e = self.lasertarget = spawn();
 284                 e.owner = self.owner;                   // Its owner is my owner
 285                 e.classname = "laser_target";
 286                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 287                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 288                 e.scale = 1.25;                         // make it larger
 289                 e.alpha = 0.25;                         // transparency
 290                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 291                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 292                 // make it dynamically glow
 293                 // you should avoid over-using this, as it can slow down the player's computer.
 294                 e.glow_color = 251; // red color
 295                 e.glow_size = 12;
 296         }
 297         else
 298                 e = self.lasertarget;
 299
 300         // move the laser dot to where the player is looking
 301
 302         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 303         offset = '0 0 26' + v_right*3;
 304         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 305         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 306         if(trace_plane_normal != '0 0 0')
 307                 e.angles = vectoangles(trace_plane_normal);
 308         else
 309                 e.angles = vectoangles(v_forward);
 310 }
 311
 312 float CL_Weaponentity_CustomizeEntityForClient()
 313 {
 314         self.viewmodelforclient = self.owner;
 315         if(other.classname == "spectator")
 316                 if(other.enemy == self.owner)
 317                         self.viewmodelforclient = other;
 318         return TRUE;
 319 }
 320
 321 float qcweaponanimation;
 322 vector weapon_offset = '0 -10 0';
 323 vector weapon_adjust = '10 0 -15';
 324 .vector weapon_morph0origin;
 325 .vector weapon_morph0angles;
 326 .float  weapon_morph0time;
 327 .vector weapon_morph1origin;
 328 .vector weapon_morph1angles;
 329 .float  weapon_morph1time;
 330 .vector weapon_morph2origin;
 331 .vector weapon_morph2angles;
 332 .float  weapon_morph2time;
 333 .vector weapon_morph3origin;
 334 .vector weapon_morph3angles;
 335 .float  weapon_morph3time;
 336 .vector weapon_morph4origin;
 337 .vector weapon_morph4angles;
 338 .float  weapon_morph4time;
 339 .string weaponname;
 340 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 341
 342 /*
 343  * supported formats:
 344  *
 345  * 1. simple animated model, muzzlr flash handling on h_ model:
 346  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 347  *      tags:
 348  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 349  *        shell = casings ejection point (must be on the right hand side of the gun)
 350  *        weapon = attachment for v_tuba.md3
 351  *    v_tuba.md3 - first and third person model
 352  *    g_tuba.md3 - pickup model
 353  *
 354  * 2. fully animated model, muzzle flash handling on h_ model:
 355  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 356  *      tags:
 357  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 358  *        shell = casings ejection point (must be on the right hand side of the gun)
 359  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 360  *    v_tuba.md3 - third person model
 361  *    g_tuba.md3 - pickup model
 362  *
 363  * 3. fully animated model, muzzle flash handling on v_ model:
 364  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 365  *      tags:
 366  *        shot = muzzle end (shot origin)
 367  *        shell = casings ejection point (must be on the right hand side of the gun)
 368  *    v_tuba.md3 - third person model
 369  *      tags:
 370  *        shot = muzzle end (for muzzle flashes)
 371  *    g_tuba.md3 - pickup model
 372  */
 373
 374 void CL_Weaponentity_Think()
 375 {
 376         float tb, v_shot_idx;
 377         self.nextthink = time;
 378         if (intermission_running)
 379                 self.frame = self.anim_idle_x;
 380         if (self.owner.weaponentity != self)
 381         {
 382                 if (self.weaponentity)
 383                         remove(self.weaponentity);
 384                 remove(self);
 385                 return;
 386         }
 387         if (self.owner.deadflag != DEAD_NO)
 388         {
 389                 self.model = "";
 390                 if (self.weaponentity)
 391                         self.weaponentity.model = "";
 392                 return;
 393         }
 394         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 395         {
 396                 self.cnt = self.owner.weapon;
 397                 self.dmg = self.owner.modelindex;
 398                 self.deadflag = self.owner.deadflag;
 399
 400                 string animfilename;
 401                 float animfile;
 402                 if (self.owner.weaponname != "")
 403                 {
 404                         // if there is a child entity, hide it until we're sure we use it
 405                         if (self.weaponentity)
 406                                 self.weaponentity.model = "";
 407                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 408                         v_shot_idx = gettagindex(self, "shot"); // used later
 409                         if(!v_shot_idx)
 410                                 v_shot_idx = gettagindex(self, "tag_shot");
 411
 412                         if(qcweaponanimation)
 413                         {
 414                                 self.angles = '0 0 0';
 415                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 416                                 self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 417                                 self.movedir_x += 32;
 418                                 self.spawnorigin = self.movedir;
 419                                 // oldorigin - not calculated here
 420                         }
 421                         else
 422                         {
 423                                 setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".dpm")); // precision set below
 424                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".dpm.animinfo");
 425                                 animfile = fopen(animfilename, FILE_READ);
 426                                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 427                                 self.anim_fire1  = '0 1 0.01';
 428                                 self.anim_fire2  = '1 1 0.01';
 429                                 self.anim_idle   = '2 1 0.01';
 430                                 self.anim_reload = '3 1 0.01';
 431                                 if (animfile >= 0)
 432                                 {
 433                                         animparseerror = FALSE;
 434                                         self.anim_fire1  = animparseline(animfile);
 435                                         self.anim_fire2  = animparseline(animfile);
 436                                         self.anim_idle   = animparseline(animfile);
 437                                         self.anim_reload = animparseline(animfile);
 438                                         fclose(animfile);
 439                                         if (animparseerror)
 440                                                 print("Parse error in ", animfilename, ", some player animations are broken\n");
 441                                 }
 442
 443                                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 444                                 // if we don't, this is a "real" animated model
 445                                 if(gettagindex(self, "weapon"))
 446                                 {
 447                                         if (!self.weaponentity)
 448                                                 self.weaponentity = spawn();
 449                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 450                                         setattachment(self.weaponentity, self, "weapon");
 451                                 }
 452                                 else if(gettagindex(self, "tag_weapon"))
 453                                 {
 454                                         if (!self.weaponentity)
 455                                                 self.weaponentity = spawn();
 456                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 457                                         setattachment(self.weaponentity, self, "tag_weapon");
 458                                 }
 459                                 else
 460                                 {
 461                                         if(self.weaponentity)
 462                                                 remove(self.weaponentity);
 463                                         self.weaponentity = world;
 464                                 }
 465
 466                                 setorigin(self,'0 0 0');
 467                                 self.angles = '0 0 0';
 468                                 self.frame = 0;
 469                                 self.viewmodelforclient = world;
 470
 471                                 float idx;
 472                                 idx = gettagindex(self, "shot");
 473                                 if(!idx)
 474                                         idx = gettagindex(self, "tag_shot");
 475                                 if(idx)
 476                                 {
 477                                         self.movedir = gettaginfo(self, idx);
 478                                 }
 479                                 else
 480                                 {
 481                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 482                                         self.movedir = '0 0 0';
 483                                 }
 484
 485                                 idx = gettagindex(self, "shell");
 486                                 if(!idx)
 487                                         idx = gettagindex(self, "tag_shell");
 488                                 if(idx)
 489                                 {
 490                                         self.spawnorigin = gettaginfo(self, idx);
 491                                 }
 492                                 else
 493                                 {
 494                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 495                                         self.spawnorigin = self.movedir;
 496                                 }
 497
 498                                 if(v_shot_idx)
 499                                 {
 500                                         self.oldorigin = '0 0 0';
 501                                 }
 502                                 else
 503                                 {
 504                                         if(self.weaponentity)
 505                                         {
 506                                                 idx = gettagindex(self, "weapon");
 507                                                 if(!idx)
 508                                                         idx = gettagindex(self, "tag_weapon");
 509                                         }
 510                                         else
 511                                         {
 512                                                 idx = gettagindex(self, "handle");
 513                                                 if(!idx)
 514                                                         idx = gettagindex(self, "tag_handle");
 515                                         }
 516                                         if(idx)
 517                                         {
 518                                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 519                                         }
 520                                         else
 521                                         {
 522                                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 523                                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 524                                         }
 525                                 }
 526
 527                                 self.viewmodelforclient = self.owner;
 528                         }
 529                 }
 530                 else
 531                 {
 532                         self.model = "";
 533                         if(self.weaponentity)
 534                                 remove(self.weaponentity);
 535                         self.weaponentity = world;
 536                         self.movedir = '0 0 0';
 537                         self.spawnorigin = '0 0 0';
 538                         self.oldorigin = '0 0 0';
 539                         self.anim_fire1  = '0 1 0.01';
 540                         self.anim_fire2  = '0 1 0.01';
 541                         self.anim_idle   = '0 1 0.01';
 542                         self.anim_reload = '0 1 0.01';
 543                 }
 544
 545                 self.view_ofs = '0 0 0';
 546
 547                 if(self.movedir_x >= 0)
 548                 {
 549                         vector v0;
 550                         v0 = self.movedir;
 551                         self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 552                         self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 553                 }
 554                 self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 555                 self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 556
 557                 self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 558
 559                 // check if an instant weapon switch occurred
 560                 if (qcweaponanimation)
 561                 {
 562                         if (self.state == WS_READY)
 563                         {
 564                                 self.angles = '0 0 0';
 565                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 566                                 setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 567                         }
 568                 }
 569                 else
 570                         setorigin(self, self.view_ofs);
 571                 // reset animstate now
 572                 self.wframe = WFRAME_IDLE;
 573                 self.weapon_morph0time = 0;
 574                 self.weapon_morph1time = 0;
 575                 self.weapon_morph2time = 0;
 576                 self.weapon_morph3time = 0;
 577                 self.weapon_morph4time = 0;
 578                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 579         }
 580
 581         tb = (self.effects & EF_TELEPORT_BIT);
 582         self.effects = self.owner.effects & EFMASK_CHEAP;
 583         self.effects &~= EF_LOWPRECISION;
 584         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 585         self.effects &~= EF_TELEPORT_BIT;
 586         self.effects |= tb;
 587
 588         if(self.owner.alpha == default_player_alpha)
 589                 self.alpha = default_weapon_alpha;
 590         else if(self.owner.alpha != 0)
 591                 self.alpha = self.owner.alpha;
 592         else
 593                 self.alpha = 1;
 594
 595         self.colormap = self.owner.colormap;
 596         if (self.weaponentity)
 597         {
 598                 self.weaponentity.effects = self.effects;
 599                 self.weaponentity.alpha = self.alpha;
 600                 self.weaponentity.colormap = self.colormap;
 601         }
 602
 603         self.angles = '0 0 0';
 604         local float f;
 605         f = 0;
 606         if (self.state == WS_RAISE && !intermission_running)
 607         {
 608                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 609                 self.angles_x = -90 * f * f;
 610                 if (qcweaponanimation)
 611                 {
 612                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 613                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 614                 }
 615         }
 616         else if (self.state == WS_DROP && !intermission_running)
 617         {
 618                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 619                 self.angles_x = -90 * f * f;
 620                 if (qcweaponanimation)
 621                 {
 622                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 623                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 624                 }
 625         }
 626         else if (self.state == WS_CLEAR)
 627         {
 628                 f = 1;
 629                 self.angles_x = -90 * f * f;
 630                 if (qcweaponanimation)
 631                 {
 632                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 633                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 634                 }
 635         }
 636         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 637         {
 638                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 639                 f = 1 - pow(1 - f, 3);
 640                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 641                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 642         }
 643         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 644         {
 645                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 646                 f = 1 - pow(1 - f, 3);
 647                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 648                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 649         }
 650         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 651         {
 652                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 653                 f = 1 - pow(1 - f, 3);
 654                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 655                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 656         }
 657         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 658         {
 659                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 660                 f = 1 - pow(1 - f, 3);
 661                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 662                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 663         }
 664         else if (qcweaponanimation)
 665         {
 666                 // begin a new idle morph
 667                 self.owner.weapon_morph0time   = time;
 668                 self.owner.weapon_morph0angles = self.angles;
 669                 self.owner.weapon_morph0origin = self.origin;
 670
 671                 float r;
 672                 float t;
 673
 674                 r = random();
 675                 if (r < 0.1)
 676                 {
 677                         // turn gun to the left to look at it
 678                         t = 2;
 679                         self.owner.weapon_morph1time   = time + t * 0.2;
 680                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 681                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 682                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 683
 684                         self.owner.weapon_morph2time   = time + t * 0.6;
 685                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 686                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 687                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 688
 689                         self.owner.weapon_morph3time   = time + t;
 690                         self.owner.weapon_morph3angles = '0 0 0';
 691                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 692                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 693                 }
 694                 else if (r < 0.2)
 695                 {
 696                         // raise the gun a bit
 697                         t = 2;
 698                         self.owner.weapon_morph1time   = time + t * 0.2;
 699                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 700                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 701                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 702
 703                         self.owner.weapon_morph2time   = time + t * 0.5;
 704                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 705                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 706                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 707
 708                         self.owner.weapon_morph3time   = time + t;
 709                         self.owner.weapon_morph3angles = '0 0 0';
 710                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 711                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 712                 }
 713                 else if (r < 0.3)
 714                 {
 715                         // tweak it a bit
 716                         t = 5;
 717                         self.owner.weapon_morph1time   = time + t * 0.3;
 718                         self.owner.weapon_morph1angles = randomvec() * 6;
 719                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 720                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 721
 722                         self.owner.weapon_morph2time   = time + t * 0.7;
 723                         self.owner.weapon_morph2angles = randomvec() * 6;
 724                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 725                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 726
 727                         self.owner.weapon_morph3time   = time + t;
 728                         self.owner.weapon_morph3angles = '0 0 0';
 729                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 730                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 731                 }
 732                 else
 733                 {
 734                         // hold it mostly steady
 735                         t = random() * 6 + 4;
 736                         self.owner.weapon_morph1time   = time + t * 0.2;
 737                         self.owner.weapon_morph1angles = randomvec() * 1;
 738                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 739                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 740
 741                         self.owner.weapon_morph2time   = time + t * 0.5;
 742                         self.owner.weapon_morph2angles = randomvec() * 1;
 743                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 744                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 745
 746                         self.owner.weapon_morph3time   = time + t * 0.7;
 747                         self.owner.weapon_morph3angles = randomvec() * 1;
 748                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 749                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 750                 }
 751
 752                 self.owner.weapon_morph4time   = time + t;
 753                 self.owner.weapon_morph4angles = '0 0 0';
 754                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 755                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 756
 757         }
 758
 759         // create or update the lasertarget entity
 760         LaserTarget_Think();
 761 };
 762
 763 void CL_ExteriorWeaponentity_Think()
 764 {
 765         float tag_found;
 766         vector ang;
 767         self.nextthink = time;
 768         if (self.owner.exteriorweaponentity != self)
 769         {
 770                 remove(self);
 771                 return;
 772         }
 773         if (self.owner.deadflag != DEAD_NO)
 774         {
 775                 self.model = "";
 776                 return;
 777         }
 778         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 779         {
 780                 self.cnt = self.owner.weapon;
 781                 self.dmg = self.owner.modelindex;
 782                 self.deadflag = self.owner.deadflag;
 783                 if (self.owner.weaponname != "")
 784                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 785                 else
 786                         self.model = "";
 787
 788                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 789                 {
 790                         self.tag_index = tag_found;
 791                         self.tag_entity = self.owner;
 792                 }
 793                 else
 794                         setattachment(self, self.owner, "bip01 r hand");
 795
 796                 // if that didn't find a tag, hide the exterior weapon model
 797                 if (!self.tag_index)
 798                         self.model = "";
 799         }
 800         self.effects = self.owner.effects | EF_LOWPRECISION;
 801         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 802         if(self.owner.alpha == default_player_alpha)
 803                 self.alpha = default_weapon_alpha;
 804         else if(self.owner.alpha != 0)
 805                 self.alpha = self.owner.alpha;
 806         else
 807                 self.alpha = 1;
 808
 809         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 810         ang_y = 0;
 811         ang_z = 0;
 812
 813         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 814         {
 815                 ang_y = self.owner.v_angle_y;
 816                 makevectors(ang);
 817                 var vector v = v_forward;
 818                 var float t = self.frame1time;
 819                 self.frame1time = time;
 820                 gettaginfo(self.tag_entity, self.tag_index);
 821                 self.frame1time = t;
 822                 // untransform v according to this coordinate space
 823                 vector w;
 824                 w_x = v_forward * v;
 825                 w_y = -v_right * v;
 826                 w_z = v_up * v;
 827                 self.angles = vectoangles(w);
 828         }
 829         else
 830         {
 831                 ang_x = -/* don't ask */ang_x;
 832                 self.angles = ang;
 833         }
 834
 835         self.colormap = self.owner.colormap;
 836 };
 837
 838 // spawning weaponentity for client
 839 void CL_SpawnWeaponentity()
 840 {
 841         self.weaponentity = spawn();
 842         self.weaponentity.classname = "weaponentity";
 843         self.weaponentity.solid = SOLID_NOT;
 844         self.weaponentity.owner = self;
 845         setmodel(self.weaponentity, ""); // precision set when changed
 846         setorigin(self.weaponentity, '0 0 0');
 847         self.weaponentity.angles = '0 0 0';
 848         self.weaponentity.viewmodelforclient = self;
 849         self.weaponentity.flags = 0;
 850         self.weaponentity.think = CL_Weaponentity_Think;
 851         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 852         self.weaponentity.nextthink = time;
 853
 854         self.exteriorweaponentity = spawn();
 855         self.exteriorweaponentity.classname = "exteriorweaponentity";
 856         self.exteriorweaponentity.solid = SOLID_NOT;
 857         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 858         self.exteriorweaponentity.owner = self;
 859         setorigin(self.exteriorweaponentity, '0 0 0');
 860         self.exteriorweaponentity.angles = '0 0 0';
 861         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 862         self.exteriorweaponentity.nextthink = time;
 863 };
 864
 865 .float hasweapon_complain_spam;
 866
 867 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 868 {
 869         local float weaponbit, f;
 870         local entity oldself;
 871
 872         if(time < self.hasweapon_complain_spam)
 873                 complain = 0;
 874         if(complain)
 875                 self.hasweapon_complain_spam = time + 0.2;
 876
 877         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 878         {
 879                 if (complain)
 880                         sprint(self, "Invalid weapon\n");
 881                 return FALSE;
 882         }
 883         weaponbit = W_WeaponBit(wpn);
 884         if (cl.weapons & weaponbit)
 885         {
 886                 if (andammo)
 887                 {
 888                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 889                         {
 890                                 f = 1;
 891                         }
 892                         else
 893                         {
 894                                 oldself = self;
 895                                 self = cl;
 896                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 897                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 898                                 self = oldself;
 899                         }
 900                         if (!f)
 901                         {
 902                                 if (complain)
 903                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 904                                 {
 905                                         play2(cl, "weapons/unavailable.wav");
 906                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 907                                 }
 908                                 return FALSE;
 909                         }
 910                 }
 911                 return TRUE;
 912         }
 913         if (complain)
 914         {
 915                 // DRESK - 3/16/07
 916                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 917                 if(weaponsInMap & weaponbit)
 918                 {
 919                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 920
 921                         if(cvar("g_showweaponspawns"))
 922                         {
 923                                 entity e;
 924                                 string s;
 925
 926                                 e = get_weaponinfo(wpn);
 927                                 s = e.model2;
 928
 929                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 930                                 {
 931                                         if(e.classname == "droppedweapon")
 932                                                 continue;
 933                                         if not(e.flags & FL_ITEM)
 934                                                 continue;
 935                                         WaypointSprite_Spawn(
 936                                                 s,
 937                                                 1, 0,
 938                                                 world, e.origin,
 939                                                 self, 0,
 940                                                 world, enemy,
 941                                                 0
 942                                         );
 943                                 }
 944                         }
 945                 }
 946                 else
 947                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 948
 949                 play2(cl, "weapons/unavailable.wav");
 950         }
 951         return FALSE;
 952 };
 953
 954 // Weapon subs
 955 void w_clear()
 956 {
 957         if (self.weapon != -1)
 958                 self.weapon = 0;
 959         if (self.weaponentity)
 960         {
 961                 self.weaponentity.state = WS_CLEAR;
 962                 self.weaponentity.effects = 0;
 963         }
 964 };
 965
 966 void w_ready()
 967 {
 968         if (self.weaponentity)
 969                 self.weaponentity.state = WS_READY;
 970         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 971 };
 972
 973 // Setup weapon for client (after this raise frame will be launched)
 974 void weapon_setup(float windex)
 975 {
 976         entity e;
 977         qcweaponanimation = cvar("sv_qcweaponanimation");
 978         e = get_weaponinfo(windex);
 979         self.items &~= IT_AMMO;
 980         self.items = self.items | e.items;
 981
 982         // the two weapon entities will notice this has changed and update their models
 983         self.weapon = windex;
 984         self.weaponname = e.mdl;
 985         self.bulletcounter = 0;
 986 };
 987
 988 // perform weapon to attack (weaponstate and attack_finished check is here)
 989 .float race_penalty;
 990 float weapon_prepareattack(float secondary, float attacktime)
 991 {
 992         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 993         //if all players readied up and the countdown is running
 994         if(time < game_starttime || time < self.race_penalty) {
 995                 return FALSE;
 996         }
 997
 998         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 999         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1000         {
1001                 // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1002                 float w, ww;
1003                 w = W_WeaponBit(self.weapon);
1004                 self.weapons &~= w;
1005                 ww = w_getbestweapon(self);
1006                 self.weapons |= w;
1007                 if(ww)
1008                         W_SwitchWeapon_Force(self, ww);
1009                 return FALSE;
1010         }
1011
1012         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1013                 return FALSE;
1014
1015         // do not even think about shooting if switching
1016         if(self.switchweapon != self.weapon)
1017                 return FALSE;
1018
1019         if(attacktime >= 0)
1020         {
1021                 // don't fire if previous attack is not finished
1022                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1023                         return FALSE;
1024                 // don't fire while changing weapon
1025                 if (self.weaponentity.state != WS_READY)
1026                         return FALSE;
1027         }
1028         self.weaponentity.state = WS_INUSE;
1029
1030         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1031
1032         // if the weapon hasn't been firing continuously, reset the timer
1033         if(attacktime >= 0)
1034         {
1035                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1036                 {
1037                         ATTACK_FINISHED(self) = time;
1038                         //dprint("resetting attack finished to ", ftos(time), "\n");
1039                 }
1040                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1041         }
1042         self.bulletcounter += 1;
1043         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1044         return TRUE;
1045 };
1046
1047 void weapon_thinkf(float fr, float t, void() func)
1048 {
1049         vector a;
1050         vector of, or, ou;
1051         float restartanim;
1052
1053         if(fr == WFRAME_DONTCHANGE)
1054         {
1055                 fr = self.weaponentity.wframe;
1056                 restartanim = FALSE;
1057         }
1058         else if (fr == WFRAME_IDLE)
1059                 restartanim = FALSE;
1060         else
1061                 restartanim = TRUE;
1062
1063         of = v_forward;
1064         or = v_right;
1065         ou = v_up;
1066
1067         if (self.weaponentity)
1068         {
1069                 self.weaponentity.wframe = fr;
1070                 if (qcweaponanimation)
1071                 {
1072                         if (fr != WFRAME_IDLE)
1073                         {
1074                                 self.weapon_morph0time = time;
1075                                 self.weapon_morph0angles = self.weaponentity.angles;
1076                                 self.weapon_morph0origin = self.weaponentity.origin;
1077
1078                                 self.weapon_morph1angles = '0 0 0';
1079                                 self.weapon_morph1time = time + t;
1080                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1081                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1082
1083                                 self.weapon_morph2angles = '0 0 0';
1084                                 self.weapon_morph2time = time + t;
1085                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1086                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1087
1088                                 self.weapon_morph3angles = '0 0 0';
1089                                 self.weapon_morph3time = time + t;
1090                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1091                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1092
1093                                 self.weapon_morph4angles = '0 0 0';
1094                                 self.weapon_morph4time = time + t;
1095                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1096                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1097
1098                                 if (fr == WFRAME_FIRE1)
1099                                 {
1100                                         self.weapon_morph1angles = '5 0 0';
1101                                         self.weapon_morph1time = time + t * 0.1;
1102                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1103                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1104                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1105                                 }
1106                                 else if (fr == WFRAME_FIRE2)
1107                                 {
1108                                         self.weapon_morph1angles = '10 0 0';
1109                                         self.weapon_morph1time = time + t * 0.1;
1110                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1111                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1112                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1113                                 }
1114                                 else if (fr == WFRAME_RELOAD)
1115                                 {
1116                                         self.weapon_morph1time = time + t * 0.05;
1117                                         self.weapon_morph1angles = '-10 40 0';
1118                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1119                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1120
1121                                         self.weapon_morph2time = time + t * 0.15;
1122                                         self.weapon_morph2angles = '-10 40 5';
1123                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1124                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1125
1126                                         self.weapon_morph3time = time + t * 0.25;
1127                                         self.weapon_morph3angles = '-10 40 0';
1128                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1129                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1130                                 }
1131                         }
1132                 }
1133                 else
1134                 {
1135                         if (fr == WFRAME_IDLE)
1136                                 a = self.weaponentity.anim_idle;
1137                         else if (fr == WFRAME_FIRE1)
1138                                 a = self.weaponentity.anim_fire1;
1139                         else if (fr == WFRAME_FIRE2)
1140                                 a = self.weaponentity.anim_fire2;
1141                         else if (fr == WFRAME_RELOAD)
1142                                 a = self.weaponentity.anim_reload;
1143                         a_z *= g_weaponratefactor;
1144                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1145                 }
1146         }
1147
1148         v_forward = of;
1149         v_right = or;
1150         v_up = ou;
1151
1152         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1153         {
1154                 backtrace("Tried to override initial weapon think function - should this really happen?");
1155         }
1156
1157         t *= W_WeaponRateFactor();
1158
1159         // VorteX: haste can be added here
1160         if (self.weapon_think == w_ready)
1161         {
1162                 self.weapon_nextthink = time;
1163                 //dprint("started firing at ", ftos(time), "\n");
1164         }
1165         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1166         {
1167                 self.weapon_nextthink = time;
1168                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1169         }
1170         self.weapon_nextthink = self.weapon_nextthink + t;
1171         self.weapon_think = func;
1172         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1173
1174         if (restartanim)
1175         if (t)
1176         if (!self.crouch) // shoot anim stands up, this looks bad
1177         {
1178                 local vector anim;
1179                 anim = self.anim_shoot;
1180                 anim_z = anim_y / t;
1181                 setanim(self, anim, FALSE, TRUE, TRUE);
1182         }
1183 };
1184
1185 void weapon_boblayer1(float spd, vector org)
1186 {
1187         // VorteX: haste can be added here
1188 };
1189
1190 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1191 {
1192         vector mdirection;
1193         float mspeed;
1194         float outspeed;
1195         float nstyle;
1196         vector outvelocity;
1197
1198         mvelocity = mvelocity * g_weaponspeedfactor;
1199
1200         mdirection = normalize(mvelocity);
1201         mspeed = vlen(mvelocity);
1202
1203         nstyle = cvar("g_projectiles_newton_style");
1204         if(nstyle == 0)
1205         {
1206                 // absolute velocity
1207                 outvelocity = mvelocity;
1208         }
1209         else if(nstyle == 1)
1210         {
1211                 // true Newtonian projectiles
1212                 outvelocity = pvelocity + mvelocity;
1213         }
1214         else if(nstyle == 2)
1215         {
1216                 // true Newtonian projectiles with automatic aim adjustment
1217                 //
1218                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1219                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1220                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1221                 // PLUS SIGN!
1222                 // not defined?
1223                 // then...
1224                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1225                 // velocity without mdirection component > mspeed
1226                 // fire at smallest possible mspeed that works?
1227                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1228
1229                 vector solution;
1230                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1231                 if(solution_z)
1232                         outspeed = solution_y; // the larger one
1233                 else
1234                 {
1235                         //outspeed = 0; // slowest possible shot
1236                         outspeed = solution_x; // the real part (that is, the average!)
1237                         //dprint("impossible shot, adjusting\n");
1238                 }
1239
1240                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1241                 outvelocity = mdirection * outspeed;
1242         }
1243         else if(nstyle == 3)
1244         {
1245                 // pseudo-Newtonian:
1246                 outspeed = mspeed + mdirection * pvelocity;
1247                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1248                 outvelocity = mdirection * outspeed;
1249         }
1250         else if(nstyle == 4)
1251         {
1252                 // tZorkian:
1253                 outspeed = mspeed + vlen(pvelocity);
1254                 outvelocity = mdirection * outspeed;
1255         }
1256         else
1257                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1258
1259         return outvelocity;
1260 }
1261
1262 void W_AttachToShotorg(entity flash, vector offset)
1263 {
1264         entity xflash;
1265         flash.owner = self;
1266         flash.angles_z = random() * 360;
1267         if(qcweaponanimation)
1268         {
1269                 setorigin(flash, w_shotorg + w_shotdir * 50);
1270                 flash.angles = vectoangles(w_shotdir);
1271                 flash.angles_z = random() * 360;
1272         }
1273         else
1274         {
1275                 setattachment(flash, self.weaponentity, "shot");
1276                 setorigin(flash, offset);
1277
1278                 xflash = spawn();
1279                 copyentity(flash, xflash);
1280
1281                 flash.viewmodelforclient = self;
1282
1283                 if(self.weaponentity.oldorigin_x > 0)
1284                 {
1285                         setattachment(xflash, self.exteriorweaponentity, "");
1286                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1287                 }
1288                 else
1289                 {
1290                         setattachment(xflash, self.exteriorweaponentity, "shot");
1291                 }
1292         }
1293 }
1294
1295 vector cliptoplane(vector v, vector p)
1296 {
1297         return v - (v * p) * p;
1298 }
1299
1300 vector solve_cubic_pq(float p, float q)
1301 {
1302         float D, u, v, a;
1303         D = q*q/4.0 + p*p*p/27.0;
1304         if(D < 0)
1305         {
1306                 // irreducibilis
1307                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1308                 u = sqrt(-4.0/3.0 * p);
1309                 // a in range 0..pi/3
1310                 // cos(a)
1311                 // cos(a + 2pi/3)
1312                 // cos(a + 4pi/3)
1313                 return
1314                         u *
1315                         (
1316                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1317                                 +
1318                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1319                                 +
1320                                 '0 0 1' * cos(a)
1321                         );
1322         }
1323         else if(D == 0)
1324         {
1325                 // simple
1326                 if(p == 0)
1327                         return '0 0 0';
1328                 u = 3*q/p;
1329                 v = -u/2;
1330                 if(u >= v)
1331                         return '1 1 0' * v + '0 0 1' * u;
1332                 else
1333                         return '0 1 1' * v + '1 0 0' * u;
1334         }
1335         else
1336         {
1337                 // cardano
1338                 u = cbrt(-q/2.0 + sqrt(D));
1339                 v = cbrt(-q/2.0 - sqrt(D));
1340                 return '1 1 1' * (u + v);
1341         }
1342 }
1343 vector solve_cubic_abcd(float a, float b, float c, float d)
1344 {
1345         // y = 3*a*x + b
1346         // x = (y - b) / 3a
1347         float p, q;
1348         vector v;
1349         p = (9*a*c - 3*b*b);
1350         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1351         v = solve_cubic_pq(p, q);
1352         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1353         if(a < 0)
1354                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1355         return v;
1356 }
1357
1358 vector findperpendicular(vector v)
1359 {
1360         vector p;
1361         p_x = v_z;
1362         p_y = -v_x;
1363         p_z = v_y;
1364         return normalize(cliptoplane(p, v));
1365 }
1366
1367 vector W_CalculateProjectileSpread(vector forward, float spread)
1368 {
1369         float sigma;
1370         vector v1, v2;
1371         float dx, dy, r;
1372         float sstyle;
1373         if(spread <= 0)
1374                 return forward;
1375         sstyle = cvar("g_projectiles_spread_style");
1376
1377         if(sstyle == 0)
1378         {
1379                 // this is the baseline for the spread value!
1380                 // standard deviation: sqrt(2/5)
1381                 // density function: sqrt(1-r^2)
1382                 return forward + randomvec() * spread;
1383         }
1384         else if(sstyle == 1)
1385         {
1386                 // same thing, basically
1387                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1388         }
1389         else if(sstyle == 2)
1390         {
1391                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1392                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1393                 v1 = findperpendicular(forward);
1394                 v2 = cross(forward, v1);
1395                 // random point on unit circle
1396                 dx = random() * 2 * M_PI;
1397                 dy = sin(dx);
1398                 dx = cos(dx);
1399                 // radius in our dist function
1400                 r = random();
1401                 r = sqrt(r);
1402                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1403         }
1404         else if(sstyle == 3) // gauss 3d
1405         {
1406                 sigma = spread * 0.44721359549996; // match baseline stddev
1407                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1408                 v1 = forward;
1409                 v1_x += gsl_ran_gaussian(sigma);
1410                 v1_y += gsl_ran_gaussian(sigma);
1411                 v1_z += gsl_ran_gaussian(sigma);
1412                 return v1;
1413         }
1414         else if(sstyle == 4) // gauss 2d
1415         {
1416                 sigma = spread * 0.44721359549996; // match baseline stddev
1417                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1418                 v1_x = gsl_ran_gaussian(sigma);
1419                 v1_y = gsl_ran_gaussian(sigma);
1420                 v1_z = gsl_ran_gaussian(sigma);
1421                 return normalize(forward + cliptoplane(v1, forward));
1422         }
1423         else if(sstyle == 5) // 1-r
1424         {
1425                 sigma = spread * 1.154700538379252; // match baseline stddev
1426                 v1 = findperpendicular(forward);
1427                 v2 = cross(forward, v1);
1428                 // random point on unit circle
1429                 dx = random() * 2 * M_PI;
1430                 dy = sin(dx);
1431                 dx = cos(dx);
1432                 // radius in our dist function
1433                 r = random();
1434                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1435                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1436         }
1437         else if(sstyle == 6) // 1-r^2
1438         {
1439                 sigma = spread * 1.095445115010332; // match baseline stddev
1440                 v1 = findperpendicular(forward);
1441                 v2 = cross(forward, v1);
1442                 // random point on unit circle
1443                 dx = random() * 2 * M_PI;
1444                 dy = sin(dx);
1445                 dx = cos(dx);
1446                 // radius in our dist function
1447                 r = random();
1448                 r = sqrt(1 - r);
1449                 r = sqrt(1 - r);
1450                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1451         }
1452         else if(sstyle == 7) // (1-r) (2-r)
1453         {
1454                 sigma = spread * 1.224744871391589; // match baseline stddev
1455                 v1 = findperpendicular(forward);
1456                 v2 = cross(forward, v1);
1457                 // random point on unit circle
1458                 dx = random() * 2 * M_PI;
1459                 dy = sin(dx);
1460                 dx = cos(dx);
1461                 // radius in our dist function
1462                 r = random();
1463                 r = 1 - sqrt(r);
1464                 r = 1 - sqrt(r);
1465                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1466         }
1467         else
1468                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1469         return '0 0 0';
1470         /*
1471          * how to derive falloff functions:
1472          * rho(r) := (2-r) * (1-r);
1473          * a : 0;
1474          * b : 1;
1475          * rhor(r) := r * rho(r);
1476          * cr(t) := integrate(rhor(r), r, a, t);
1477          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1478          * variance : scr(b) / cr(b);
1479          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1480          * sqrt(0.4 / variance), numer;
1481          */
1482 }
1483
1484 #if 0
1485 float mspercallsum;
1486 float mspercallsstyle;
1487 float mspercallcount;
1488 #endif
1489 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float spread)
1490 {
1491         if(missile.owner == world)
1492                 error("Unowned missile");
1493
1494         dir = dir + upDir * (pUpSpeed / pSpeed);
1495         pSpeed *= vlen(dir);
1496         dir = normalize(dir);
1497
1498 #if 0
1499         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1500         {
1501                 mspercallsum = mspercallcount = 0;
1502                 mspercallsstyle = cvar("g_projectiles_spread_style");
1503         }
1504         mspercallsum -= gettime(GETTIME_HIRES);
1505 #endif
1506         dir = W_CalculateProjectileSpread(dir, spread);
1507 #if 0
1508         mspercallsum += gettime(GETTIME_HIRES);
1509         mspercallcount += 1;
1510         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1511 #endif
1512
1513         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);
1514 }
1515
1516 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1517 {
1518         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, spread);
1519 }
1520
1521 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_spread"))
1522 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, cvar(#s "_spread"))