data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 void W_SwitchWeapon_Force(entity e, float w)
  11 {
  12         e.cnt = e.switchweapon;
  13         e.switchweapon = w;
  14 }
  15
  16 .float antilag_debug;
  17
  18 // VorteX: static frame globals
  19 float WFRAME_DONTCHANGE = -1;
  20 float WFRAME_FIRE1 = 0;
  21 float WFRAME_FIRE2 = 1;
  22 float WFRAME_IDLE = 2;
  23 float WFRAME_RELOAD = 3;
  24 .float wframe;
  25
  26 void(float fr, float t, void() func) weapon_thinkf;
  27
  28 vector w_shotorg;
  29 vector w_shotdir;
  30
  31 // this function calculates w_shotorg and w_shotdir based on the weapon model
  32 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  33 // make sure you call makevectors first (FIXME?)
  34 void W_SetupShot(entity ent, vector vecs, float antilag, float recoil, string snd)
  35 {
  36         float nudge = 1; // added to traceline target and subtracted from result
  37         local vector trueaimpoint;
  38         local float oldsolid;
  39         oldsolid = self.dphitcontentsmask;
  40         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  41         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, self);
  42         trueaimpoint = trace_endpos;
  43
  44         if(ent.weaponentity.movedir_x > 0)
  45         {
  46                 vecs = ent.weaponentity.movedir;
  47                 vecs_y = -vecs_y;
  48         }
  49         else if (cvar("g_shootfromeye"))
  50                 vecs_y = vecs_z = 0;
  51         else if (cvar("g_shootfromcenter"))
  52                 vecs_y = 0;
  53
  54         if(debug_shotorg != '0 0 0')
  55                 vecs = debug_shotorg;
  56
  57         w_shotorg = ent.origin + ent.view_ofs + v_right * vecs_y + v_up * vecs_z;
  58
  59         // now move the shotorg forward as much as requested if possible
  60         traceline(w_shotorg, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, self);
  61         w_shotorg = trace_endpos - v_forward * nudge;
  62         // calculate the shotdir from the chosen shotorg
  63         w_shotdir = normalize(trueaimpoint - w_shotorg);
  64
  65 #if 0
  66         // explanation of g_antilag:
  67         // if client reports it was aiming at a player, and the serverside trace
  68         // says it would miss, change the aim point to the player's new origin,
  69         // but only if the shot at the player's new origin would hit of course
  70         //
  71         // FIXME: a much better method for bullet weapons would be to leave a
  72         // trail of lagged 'ghosts' behind players, and see if the bullet hits the
  73         // ghost corresponding to this player's ping time, and if so it would do
  74         // damage to the real player
  75         if (antilag)
  76         if (self.cursor_trace_ent)                 // client was aiming at someone
  77         if (self.cursor_trace_ent != self)         // just to make sure
  78         if (self.cursor_trace_ent.takedamage)      // and that person is killable
  79         if (self.cursor_trace_ent.classname == "player") // and actually a player
  80         if (cvar("g_antilag") == 1)
  81         {
  82                 // verify that the shot would miss without antilag
  83                 // (avoids an issue where guns would always shoot at their origin)
  84                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  85                 if (!trace_ent.takedamage)
  86                 {
  87                         // verify that the shot would hit if altered
  88                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
  89                         if (trace_ent == self.cursor_trace_ent)
  90                         {
  91                                 // verify that the shot would hit in the past
  92                                 if(self.antilag_debug)
  93                                         antilag_takeback(self.cursor_trace_ent, time - self.antilag_debug);
  94                                 else
  95                                         antilag_takeback(self.cursor_trace_ent, time - ANTILAG_LATENCY(self));
  96
  97                                 traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  98                                 antilag_restore(self.cursor_trace_ent);
  99
 100                                 if(trace_ent == self.cursor_trace_ent)
 101                                 {
 102                                         // HIT!
 103                                         w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
 104                                         dprint("ANTILAG HIT for ", self.netname, "\n");
 105                                 }
 106                                 else
 107                                 {
 108                                         // prydon cursor aimbot or odd network conditions
 109                                         dprint("WARNING: antilag ghost trace for ", self.netname, " failed!\n");
 110                                 }
 111
 112                                 if(cvar("developer") >= 2)
 113                                 {
 114                                         vector v, vplus, vel;
 115                                         float X;
 116                                         v     = antilag_takebackorigin(self.cursor_trace_ent, time - (ANTILAG_LATENCY(self)       ));
 117                                         vplus = antilag_takebackorigin(self.cursor_trace_ent, time - (ANTILAG_LATENCY(self) + 0.01));
 118                                         vel = (vplus - v) * (1 / 0.01);
 119                                         // solve: v + X * vel = closest to self.origin + self.view_ofs, v_forward axis
 120                                         v     -= (self.origin + self.view_ofs);
 121                                         // solve: v + X * vel = closest to v_forward axis
 122                                         // project into 2D by subtracting v_forward components:
 123                                         v   -= (v   * v_forward) * v_forward;
 124                                         vel -= (vel * v_forward) * v_forward;
 125                                         // solve: v + X * vel = closest to origin
 126                                         // (v + X * vel)^2 closest to 0
 127                                         // v^2 + 2 * X * (v * vel) + X^2 * vel^2 closest to 0
 128                                         X = -(v * vel) / (vel * vel);
 129                                         dprint("dead center needs adjustment of ", ftos(X), " (that is, ", ftos(ANTILAG_LATENCY(self) + X), " instead of ", ftos(ANTILAG_LATENCY(self)), "\n");
 130                                 }
 131                         }
 132                 }
 133         }
 134 #else
 135         if (antilag)
 136         {
 137                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 138                 {
 139                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 140                         if (!trace_ent.takedamage)
 141                         {
 142                                 traceline_antilag_force (self, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self, ANTILAG_LATENCY(self));
 143                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 144                                 {
 145                                         entity e;
 146                                         e = trace_ent;
 147                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, self);
 148                                         if(trace_ent == e)
 149                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 150                                 }
 151                         }
 152                 }
 153                 else if(cvar("g_antilag") == 3) // client side hitscan
 154                 {
 155                         if (self.cursor_trace_ent)                 // client was aiming at someone
 156                         if (self.cursor_trace_ent != self)         // just to make sure
 157                         if (self.cursor_trace_ent.takedamage)      // and that person is killable
 158                         if (self.cursor_trace_ent.classname == "player") // and actually a player
 159                         {
 160                                 // verify that the shot would miss without antilag
 161                                 // (avoids an issue where guns would always shoot at their origin)
 162                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 163                                 if (!trace_ent.takedamage)
 164                                 {
 165                                         // verify that the shot would hit if altered
 166                                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
 167                                         if (trace_ent == self.cursor_trace_ent)
 168                                                 w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
 169                                         else
 170                                                 print("antilag fail\n");
 171                                 }
 172                         }
 173                 }
 174         }
 175 #endif
 176
 177         self.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 178
 179         if (!g_norecoil)
 180                 self.punchangle_x = recoil * -1;
 181
 182         if (snd != "")
 183         {
 184                 sound (self, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 185         }
 186
 187         if (self.items & IT_STRENGTH)
 188         if (!g_minstagib)
 189                 sound (self, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 190 };
 191
 192 void LaserTarget_Think()
 193 {
 194         entity e;
 195         vector offset;
 196         float uselaser;
 197         uselaser = 0;
 198
 199         // list of weapons that will use the laser, and the options that enable it
 200         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 201                 uselaser = 1;
 202         // example
 203         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 204         //      uselaser = 1;
 205
 206
 207
 208         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 209         if(!uselaser)
 210         {
 211                 // rocket launcher isn't selected, so no laser target.
 212                 if(self.lasertarget != world)
 213                 {
 214                         remove(self.lasertarget);
 215                         self.lasertarget = world;
 216                 }
 217                 return;
 218         }
 219
 220         if(!self.lasertarget)
 221         {
 222                 // we don't have a lasertarget entity, so spawn one
 223                 //bprint("create laser target\n");
 224                 e = self.lasertarget = spawn();
 225                 e.owner = self.owner;                   // Its owner is my owner
 226                 e.classname = "laser_target";
 227                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 228                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 229                 e.scale = 1.25;                         // make it larger
 230                 e.alpha = 0.25;                         // transparency
 231                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 232                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 233                 // make it dynamically glow
 234                 // you should avoid over-using this, as it can slow down the player's computer.
 235                 e.glow_color = 251; // red color
 236                 e.glow_size = 12;
 237         }
 238         else
 239                 e = self.lasertarget;
 240
 241         // move the laser dot to where the player is looking
 242
 243         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 244         offset = '0 0 26' + v_right*3;
 245         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 246         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 247         if(trace_plane_normal != '0 0 0')
 248                 e.angles = vectoangles(trace_plane_normal);
 249         else
 250                 e.angles = vectoangles(v_forward);
 251 }
 252
 253 float CL_Weaponentity_CustomizeEntityForClient()
 254 {
 255         self.viewmodelforclient = self.owner;
 256         if(other.classname == "spectator")
 257                 if(other.enemy == self.owner)
 258                         self.viewmodelforclient = other;
 259         return TRUE;
 260 }
 261
 262 float qcweaponanimation;
 263 vector weapon_offset = '0 -10 0';
 264 vector weapon_adjust = '10 0 -15';
 265 .vector weapon_morph0origin;
 266 .vector weapon_morph0angles;
 267 .float  weapon_morph0time;
 268 .vector weapon_morph1origin;
 269 .vector weapon_morph1angles;
 270 .float  weapon_morph1time;
 271 .vector weapon_morph2origin;
 272 .vector weapon_morph2angles;
 273 .float  weapon_morph2time;
 274 .vector weapon_morph3origin;
 275 .vector weapon_morph3angles;
 276 .float  weapon_morph3time;
 277 .vector weapon_morph4origin;
 278 .vector weapon_morph4angles;
 279 .float  weapon_morph4time;
 280 .string weaponname;
 281 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 282
 283 void CL_Weaponentity_Think()
 284 {
 285         float tb;
 286         self.nextthink = time;
 287         if (intermission_running)
 288                 self.frame = self.anim_idle_x;
 289         if (self.owner.weaponentity != self)
 290         {
 291                 if (self.weaponentity)
 292                         remove(self.weaponentity);
 293                 remove(self);
 294                 return;
 295         }
 296         if (self.owner.deadflag != DEAD_NO)
 297         {
 298                 self.model = "";
 299                 if (self.weaponentity)
 300                         self.weaponentity.model = "";
 301                 return;
 302         }
 303         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 304         {
 305                 self.cnt = self.owner.weapon;
 306                 self.dmg = self.owner.modelindex;
 307                 self.deadflag = self.owner.deadflag;
 308
 309                 string animfilename;
 310                 float animfile;
 311                 float modelfile;
 312                 if (self.owner.weaponname != "")
 313                 {
 314                         // if there is a child entity, hide it until we're sure we use it
 315                         if (self.weaponentity)
 316                                 self.weaponentity.model = "";
 317                         if (qcweaponanimation)
 318                                 setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 319                         else
 320                         {
 321                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".zym");
 322                                 modelfile = fopen(animfilename, FILE_READ);
 323                                 if (modelfile >= 0)
 324                                 {
 325                                         fclose(modelfile);
 326                                         self.anim_fire1  = '0 1 10';
 327                                         self.anim_fire2  = '1 1 10';
 328                                         self.anim_idle   = '2 1 10';
 329                                         self.anim_reload = '3 1 10';
 330                                         setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".zym")); // precision set below
 331                                         if (!self.weaponentity)
 332                                                 self.weaponentity = spawn();
 333                                         setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".dpm")); // precision set below
 334                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 335                                         setattachment(self.weaponentity, self, "weapon");
 336                                 }
 337                                 else
 338                                 {
 339                                         animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".dpm.animinfo");
 340                                         animfile = fopen(animfilename, FILE_READ);
 341                                         if (animfile >= 0)
 342                                         {
 343                                                 if (!self.weaponentity)
 344                                                         self.weaponentity = spawn();
 345                                                 setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".dpm")); // precision set below
 346                                                 setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 347                                                 setattachment(self.weaponentity, self, "weapon");
 348                                         }
 349                                         else
 350                                         {
 351                                                 animfilename = strcat("models/weapons/w_", self.owner.weaponname, ".dpm.animinfo");
 352                                                 animfile = fopen(animfilename, FILE_READ);
 353                                                 if (animfile >= 0)
 354                                                         setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".dpm")); // precision set below
 355                                         }
 356                                         if (animfile >= 0)
 357                                         {
 358                                                 animparseerror = FALSE;
 359                                                 self.anim_fire1  = animparseline(animfile);
 360                                                 self.anim_fire2  = animparseline(animfile);
 361                                                 self.anim_idle   = animparseline(animfile);
 362                                                 self.anim_reload = animparseline(animfile);
 363                                                 fclose(animfile);
 364                                                 if (animparseerror)
 365                                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 366                                         }
 367                                         else
 368                                         {
 369                                                 self.anim_fire1  = '0 1 10';
 370                                                 self.anim_fire2  = '1 1 10';
 371                                                 self.anim_idle   = '2 1 10';
 372                                                 self.anim_reload = '3 1 10';
 373                                                 setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".zym")); // precision set below
 374                                         }
 375                                 }
 376                         }
 377                 }
 378                 else
 379                         self.model = "";
 380
 381                 if(qcweaponanimation)
 382                 {
 383                         self.angles = '0 0 0';
 384                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 385                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 386                         self.movedir_x += 30;
 387                 }
 388                 else
 389                 {
 390                         float idx;
 391                         idx = gettagindex(self, "shot");
 392                         if(!idx)
 393                         {
 394                                 print("WARNING: the weapon ", self.model, " does not support the correct shot origin tag.\n");
 395                                 idx = gettagindex(self, "bone02");
 396                         }
 397                         if(idx)
 398                         {
 399                                 self.origin = '0 0 0';
 400                                 self.angles = '0 0 0';
 401                                 self.frame = 0;
 402                                 self.viewmodelforclient = world;
 403                                 self.movedir = gettaginfo(self, idx);
 404                                 self.viewmodelforclient = self.owner;
 405                         }
 406                         else
 407                                 self.movedir = '0 0 0';
 408                 }
 409
 410                 self.view_ofs = '0 0 0';
 411
 412                 if(cvar("g_shootfromcenter") || cvar("g_shootfromeye"))
 413                 if(self.movedir_x >= 0)
 414                 {
 415                         self.view_ofs_y = -self.movedir_y;
 416                         self.movedir_y = 0;
 417                 }
 418
 419                 if(cvar("g_shootfromeye"))
 420                 {
 421                         self.movedir_z = 0;
 422                 }
 423
 424                 // check if an instant weapon switch occurred
 425                 if (qcweaponanimation)
 426                 {
 427                         if (self.state == WS_READY)
 428                         {
 429                                 self.angles = '0 0 0';
 430                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 431                                 setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 432                         }
 433                 }
 434                 else
 435                         setorigin(self, self.view_ofs);
 436                 // reset animstate now
 437                 self.wframe = WFRAME_IDLE;
 438                 self.weapon_morph0time = 0;
 439                 self.weapon_morph1time = 0;
 440                 self.weapon_morph2time = 0;
 441                 self.weapon_morph3time = 0;
 442                 self.weapon_morph4time = 0;
 443                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 444         }
 445
 446         tb = (self.effects & EF_TELEPORT_BIT);
 447         self.effects = self.owner.effects - (self.owner.effects & EF_LOWPRECISION);// | EF_LOWPRECISION;
 448         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 449         self.effects &~= EF_TELEPORT_BIT;
 450         self.effects |= tb;
 451
 452         if(self.owner.alpha != 0)
 453                 self.alpha = self.owner.alpha;
 454         else
 455                 self.alpha = 1;
 456
 457         self.colormap = self.owner.colormap;
 458         if (self.weaponentity)
 459         {
 460                 self.weaponentity.effects = self.effects & EF_ADDITIVE;
 461                 self.weaponentity.alpha = self.alpha;
 462                 self.weaponentity.colormap = self.colormap;
 463         }
 464
 465         self.angles = '0 0 0';
 466         local float f;
 467         f = 0;
 468         if (self.state == WS_RAISE)
 469         {
 470                 f = (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 471                 self.angles_x = -90 * f * f;
 472                 if (qcweaponanimation)
 473                 {
 474                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 475                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 476                 }
 477         }
 478         else if (self.state == WS_DROP)
 479         {
 480                 f = 1 - (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 481                 self.angles_x = -90 * f * f;
 482                 if (qcweaponanimation)
 483                 {
 484                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 485                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 486                 }
 487         }
 488         else if (self.state == WS_CLEAR)
 489         {
 490                 f = 1;
 491                 self.angles_x = -90 * f * f;
 492                 if (qcweaponanimation)
 493                 {
 494                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 495                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 496                 }
 497         }
 498         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 499         {
 500                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 501                 f = 1 - pow(1 - f, 3);
 502                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 503                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 504         }
 505         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 506         {
 507                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 508                 f = 1 - pow(1 - f, 3);
 509                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 510                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 511         }
 512         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 513         {
 514                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 515                 f = 1 - pow(1 - f, 3);
 516                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 517                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 518         }
 519         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 520         {
 521                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 522                 f = 1 - pow(1 - f, 3);
 523                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 524                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 525         }
 526         else if (qcweaponanimation)
 527         {
 528                 // begin a new idle morph
 529                 self.owner.weapon_morph0time   = time;
 530                 self.owner.weapon_morph0angles = self.angles;
 531                 self.owner.weapon_morph0origin = self.origin;
 532
 533                 float r;
 534                 float t;
 535
 536                 r = random();
 537                 if (r < 0.1)
 538                 {
 539                         // turn gun to the left to look at it
 540                         t = 2;
 541                         self.owner.weapon_morph1time   = time + t * 0.2;
 542                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 543                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 544                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 545
 546                         self.owner.weapon_morph2time   = time + t * 0.6;
 547                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 548                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 549                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 550
 551                         self.owner.weapon_morph3time   = time + t;
 552                         self.owner.weapon_morph3angles = '0 0 0';
 553                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 554                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 555                 }
 556                 else if (r < 0.2)
 557                 {
 558                         // raise the gun a bit
 559                         t = 2;
 560                         self.owner.weapon_morph1time   = time + t * 0.2;
 561                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 562                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 563                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 564
 565                         self.owner.weapon_morph2time   = time + t * 0.5;
 566                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 567                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 568                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 569
 570                         self.owner.weapon_morph3time   = time + t;
 571                         self.owner.weapon_morph3angles = '0 0 0';
 572                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 573                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 574                 }
 575                 else if (r < 0.3)
 576                 {
 577                         // tweak it a bit
 578                         t = 5;
 579                         self.owner.weapon_morph1time   = time + t * 0.3;
 580                         self.owner.weapon_morph1angles = randomvec() * 6;
 581                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 582                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 583
 584                         self.owner.weapon_morph2time   = time + t * 0.7;
 585                         self.owner.weapon_morph2angles = randomvec() * 6;
 586                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 587                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 588
 589                         self.owner.weapon_morph3time   = time + t;
 590                         self.owner.weapon_morph3angles = '0 0 0';
 591                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 592                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 593                 }
 594                 else
 595                 {
 596                         // hold it mostly steady
 597                         t = random() * 6 + 4;
 598                         self.owner.weapon_morph1time   = time + t * 0.2;
 599                         self.owner.weapon_morph1angles = randomvec() * 1;
 600                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 601                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 602
 603                         self.owner.weapon_morph2time   = time + t * 0.5;
 604                         self.owner.weapon_morph2angles = randomvec() * 1;
 605                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 606                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 607
 608                         self.owner.weapon_morph3time   = time + t * 0.7;
 609                         self.owner.weapon_morph3angles = randomvec() * 1;
 610                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 611                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 612                 }
 613
 614                 self.owner.weapon_morph4time   = time + t;
 615                 self.owner.weapon_morph4angles = '0 0 0';
 616                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 617                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 618
 619         }
 620
 621         // create or update the lasertarget entity
 622         LaserTarget_Think();
 623 };
 624
 625 void CL_ExteriorWeaponentity_Think()
 626 {
 627         float tag_found;
 628         self.nextthink = time;
 629         if (self.owner.exteriorweaponentity != self)
 630         {
 631                 remove(self);
 632                 return;
 633         }
 634         if (self.owner.deadflag != DEAD_NO)
 635         {
 636                 self.model = "";
 637                 return;
 638         }
 639         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 640         {
 641                 self.cnt = self.owner.weapon;
 642                 self.dmg = self.owner.modelindex;
 643                 self.deadflag = self.owner.deadflag;
 644                 if (self.owner.weaponname != "")
 645                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 646                 else
 647                         self.model = "";
 648
 649                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 650                 {
 651                         self.tag_index = tag_found;
 652                         self.tag_entity = self.owner;
 653                 }
 654                 else
 655                         setattachment(self, self.owner, "bip01 r hand");
 656
 657                 // if that didn't find a tag, hide the exterior weapon model
 658                 if (!self.tag_index)
 659                         self.model = "";
 660         }
 661         self.effects = self.owner.effects | EF_LOWPRECISION;
 662         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 663         if(self.owner.alpha != 0)
 664                 self.alpha = self.owner.alpha;
 665         else
 666                 self.alpha = 1;
 667
 668         self.colormap = self.owner.colormap;
 669 };
 670
 671 // spawning weaponentity for client
 672 void CL_SpawnWeaponentity()
 673 {
 674         self.weaponentity = spawn();
 675         self.weaponentity.classname = "weaponentity";
 676         self.weaponentity.solid = SOLID_NOT;
 677         self.weaponentity.owner = self;
 678         setmodel(self.weaponentity, ""); // precision set when changed
 679         self.weaponentity.origin = '0 0 0';
 680         self.weaponentity.angles = '0 0 0';
 681         self.weaponentity.viewmodelforclient = self;
 682         self.weaponentity.flags = 0;
 683         self.weaponentity.think = CL_Weaponentity_Think;
 684         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 685         self.weaponentity.nextthink = time;
 686
 687         self.exteriorweaponentity = spawn();
 688         self.exteriorweaponentity.classname = "exteriorweaponentity";
 689         self.exteriorweaponentity.solid = SOLID_NOT;
 690         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 691         self.exteriorweaponentity.owner = self;
 692         self.exteriorweaponentity.origin = '0 0 0';
 693         self.exteriorweaponentity.angles = '0 0 0';
 694         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 695         self.exteriorweaponentity.nextthink = time;
 696 };
 697
 698 .float hasweapon_complain_spam;
 699
 700 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 701 {
 702         local float weaponbit, f;
 703         local entity oldself;
 704
 705         if(time < self.hasweapon_complain_spam)
 706                 complain = 0;
 707         if(complain)
 708                 self.hasweapon_complain_spam = time + 0.2;
 709
 710         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 711         {
 712                 if (complain)
 713                         sprint(self, "Invalid weapon\n");
 714                 return FALSE;
 715         }
 716         weaponbit = W_WeaponBit(wpn);
 717         if (cl.weapons & weaponbit)
 718         {
 719                 if (andammo)
 720                 {
 721                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 722                         {
 723                                 f = 1;
 724                         }
 725                         else
 726                         {
 727                                 oldself = self;
 728                                 self = cl;
 729                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 730                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 731                                 self = oldself;
 732                         }
 733                         if (!f)
 734                         {
 735                                 if (complain)
 736                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 737                                 return FALSE;
 738                         }
 739                 }
 740                 return TRUE;
 741         }
 742         if (complain)
 743         {
 744                 // DRESK - 3/16/07
 745                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 746                 if(weaponsInMap & weaponbit)
 747                 {
 748                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 749
 750                         if(cvar("g_showweaponspawns"))
 751                         {
 752                                 entity e;
 753                                 string s;
 754
 755                                 e = get_weaponinfo(wpn);
 756                                 s = e.model2;
 757
 758                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 759                                 {
 760                                         if(e.classname == "droppedweapon")
 761                                                 continue;
 762                                         if not(e.flags & FL_ITEM)
 763                                                 continue;
 764                                         WaypointSprite_Spawn(
 765                                                 s,
 766                                                 1, 0,
 767                                                 world, e.origin,
 768                                                 self, 0,
 769                                                 world, enemy,
 770                                                 0
 771                                         );
 772                                 }
 773                         }
 774                 }
 775                 else
 776                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 777         }
 778         return FALSE;
 779 };
 780
 781 // Weapon subs
 782 void w_clear()
 783 {
 784         if (self.weapon != -1)
 785                 self.weapon = 0;
 786         if (self.weaponentity)
 787         {
 788                 self.weaponentity.state = WS_CLEAR;
 789                 self.weaponentity.effects = 0;
 790         }
 791 };
 792
 793 void w_ready()
 794 {
 795         if (self.weaponentity)
 796                 self.weaponentity.state = WS_READY;
 797         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 798 };
 799
 800 // Setup weapon for client (after this raise frame will be launched)
 801 void weapon_setup(float windex)
 802 {
 803         entity e;
 804         qcweaponanimation = cvar("sv_qcweaponanimation");
 805         e = get_weaponinfo(windex);
 806         self.items &~= IT_AMMO;
 807         self.items = self.items | e.items;
 808
 809         // the two weapon entities will notice this has changed and update their models
 810         self.weapon = windex;
 811         self.weaponname = e.mdl;
 812         self.bulletcounter = 0;
 813 };
 814
 815 // perform weapon to attack (weaponstate and attack_finished check is here)
 816 .float race_penalty;
 817 float weapon_prepareattack(float secondary, float attacktime)
 818 {
 819         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 820         //if all players readied up and the countdown is running
 821         if (cvar("sv_ready_restart_after_countdown"))
 822                 if(time < game_starttime || time < self.race_penalty) {
 823                         return FALSE;
 824                 }
 825
 826         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 827         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 828         {
 829                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 830                 return FALSE;
 831         }
 832
 833         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 834                 return FALSE;
 835
 836         // do not even think about shooting if switching
 837         if(self.switchweapon != self.weapon)
 838                 return FALSE;
 839
 840         // don't fire if previous attack is not finished
 841         if(attacktime >= 0)
 842                 if (ATTACK_FINISHED(self) > time + frametime * 0.5)
 843                         return FALSE;
 844         // don't fire while changing weapon
 845         if (self.weaponentity.state != WS_READY)
 846                 return FALSE;
 847         self.weaponentity.state = WS_INUSE;
 848
 849         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 850
 851         // if the weapon hasn't been firing continuously, reset the timer
 852         if(attacktime >= 0)
 853         {
 854                 if (ATTACK_FINISHED(self) < time - frametime * 1.5)
 855                 {
 856                         ATTACK_FINISHED(self) = time;
 857                         //dprint("resetting attack finished to ", ftos(time), "\n");
 858                 }
 859                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime;
 860         }
 861         self.bulletcounter += 1;
 862         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 863         return TRUE;
 864 };
 865
 866 void weapon_thinkf(float fr, float t, void() func)
 867 {
 868         vector a;
 869         vector of, or, ou;
 870         float restartanim;
 871
 872         if(fr == WFRAME_DONTCHANGE)
 873         {
 874                 fr = self.weaponentity.wframe;
 875                 restartanim = FALSE;
 876         }
 877         else if (fr == WFRAME_IDLE)
 878                 restartanim = FALSE;
 879         else
 880                 restartanim = TRUE;
 881
 882         of = v_forward;
 883         or = v_right;
 884         ou = v_up;
 885
 886         if (self.weaponentity)
 887         {
 888                 self.weaponentity.wframe = fr;
 889                 if (qcweaponanimation)
 890                 {
 891                         if (fr != WFRAME_IDLE)
 892                         {
 893                                 self.weapon_morph0time = time;
 894                                 self.weapon_morph0angles = self.weaponentity.angles;
 895                                 self.weapon_morph0origin = self.weaponentity.origin;
 896
 897                                 self.weapon_morph1angles = '0 0 0';
 898                                 self.weapon_morph1time = time + t;
 899                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 900                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 901
 902                                 self.weapon_morph2angles = '0 0 0';
 903                                 self.weapon_morph2time = time + t;
 904                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
 905                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 906
 907                                 self.weapon_morph3angles = '0 0 0';
 908                                 self.weapon_morph3time = time + t;
 909                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
 910                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 911
 912                                 self.weapon_morph4angles = '0 0 0';
 913                                 self.weapon_morph4time = time + t;
 914                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
 915                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 916
 917                                 if (fr == WFRAME_FIRE1)
 918                                 {
 919                                         self.weapon_morph1angles = '5 0 0';
 920                                         self.weapon_morph1time = time + t * 0.1;
 921                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 922                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 923                                         self.weapon_morph4time = time + t + 1; // delay idle effect
 924                                 }
 925                                 else if (fr == WFRAME_FIRE2)
 926                                 {
 927                                         self.weapon_morph1angles = '10 0 0';
 928                                         self.weapon_morph1time = time + t * 0.1;
 929                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 930                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 931                                         self.weapon_morph4time = time + t + 1; // delay idle effect
 932                                 }
 933                                 else if (fr == WFRAME_RELOAD)
 934                                 {
 935                                         self.weapon_morph1time = time + t * 0.05;
 936                                         self.weapon_morph1angles = '-10 40 0';
 937                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 938                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 939
 940                                         self.weapon_morph2time = time + t * 0.15;
 941                                         self.weapon_morph2angles = '-10 40 5';
 942                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
 943                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 944
 945                                         self.weapon_morph3time = time + t * 0.25;
 946                                         self.weapon_morph3angles = '-10 40 0';
 947                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
 948                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 949                                 }
 950                         }
 951                 }
 952                 else
 953                 {
 954                         if (fr == WFRAME_IDLE)
 955                                 a = self.weaponentity.anim_idle;
 956                         else if (fr == WFRAME_FIRE1)
 957                                 a = self.weaponentity.anim_fire1;
 958                         else if (fr == WFRAME_FIRE2)
 959                                 a = self.weaponentity.anim_fire2;
 960                         else if (fr == WFRAME_RELOAD)
 961                                 a = self.weaponentity.anim_reload;
 962                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 963                 }
 964
 965                 if(restartanim)
 966                 {
 967                         BITXOR_ASSIGN(self.weaponentity.effects, EF_TELEPORT_BIT);
 968                 }
 969         }
 970
 971         v_forward = of;
 972         v_right = or;
 973         v_up = ou;
 974
 975         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 976         {
 977                 backtrace("Tried to override initial weapon think function - should this really happen?");
 978         }
 979
 980         if(g_runematch)
 981         {
 982                 if(self.runes & RUNE_SPEED)
 983                 {
 984                         if(self.runes & CURSE_SLOW)
 985                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
 986                         else
 987                                 t = t * cvar("g_balance_rune_speed_atkrate");
 988                 }
 989                 else if(self.runes & CURSE_SLOW)
 990                 {
 991                         t = t * cvar("g_balance_curse_slow_atkrate");
 992                 }
 993         }
 994
 995         // VorteX: haste can be added here
 996         if (self.weapon_think == w_ready)
 997         {
 998                 self.weapon_nextthink = time;
 999                 //dprint("started firing at ", ftos(time), "\n");
1000         }
1001         if (self.weapon_nextthink < time - frametime * 1.5 || self.weapon_nextthink > time + frametime * 1.5)
1002         {
1003                 self.weapon_nextthink = time;
1004                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1005         }
1006         self.weapon_nextthink = self.weapon_nextthink + t;
1007         self.weapon_think = func;
1008         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1009
1010         if (restartanim)
1011         if (t)
1012         if (!self.crouch) // shoot anim stands up, this looks bad
1013         {
1014                 local vector anim;
1015                 anim = self.anim_shoot;
1016                 anim_z = anim_y / t;
1017                 setanim(self, anim, FALSE, TRUE, TRUE);
1018         }
1019 };
1020
1021 void weapon_boblayer1(float spd, vector org)
1022 {
1023         // VorteX: haste can be added here
1024 };
1025
1026 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1027 {
1028         vector mdirection;
1029         float mspeed;
1030         float outspeed;
1031         float nstyle;
1032         vector outvelocity;
1033
1034         mdirection = normalize(mvelocity);
1035         mspeed = vlen(mvelocity);
1036
1037         nstyle = cvar("g_projectiles_newton_style");
1038         if(nstyle == 0)
1039         {
1040                 // absolute velocity
1041                 outvelocity = mvelocity;
1042         }
1043         else if(nstyle == 1)
1044         {
1045                 // true Newtonian projectiles
1046                 outvelocity = pvelocity + mvelocity;
1047         }
1048         else if(nstyle == 2)
1049         {
1050                 // true Newtonian projectiles with automatic aim adjustment
1051                 //
1052                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1053                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1054                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1055                 // PLUS SIGN!
1056                 // not defined?
1057                 // then...
1058                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1059                 // velocity without mdirection component > mspeed
1060                 // fire at smallest possible mspeed that works?
1061                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1062
1063                 float D;
1064                 float p;
1065                 float q;
1066                 p = mdirection * pvelocity;
1067                 q = pvelocity * pvelocity - mspeed * mspeed;
1068                 D = p * p - q;
1069                 if(D < 0)
1070                 {
1071                         //dprint("impossible shot, adjusting\n");
1072                         D = 0;
1073                 }
1074                 outspeed = p + sqrt(D);
1075                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1076                 outvelocity = mdirection * outspeed;
1077         }
1078         else if(nstyle == 3)
1079         {
1080                 // pseudo-Newtonian:
1081                 outspeed = mspeed + mdirection * pvelocity;
1082                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1083                 outvelocity = mdirection * outspeed;
1084         }
1085         else if(nstyle == 4)
1086         {
1087                 // tZorkian:
1088                 outspeed = mspeed + vlen(pvelocity);
1089                 outvelocity = mdirection * outspeed;
1090         }
1091         else
1092                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1093
1094         return outvelocity;
1095 }
1096
1097 void W_SetupProjectileVelocity(entity missile)
1098 {
1099         if(missile.owner == world)
1100                 error("Unowned missile");
1101
1102         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, missile.velocity);
1103 }