data/qcsrc/server/cl_weapons.qc

   1
   2 // generic weapons table
   3 // add new weapons here
   4 float weapon_action(float wpn, float wrequest)
   5 {
   6         if (wpn == WEP_LASER)
   7                 return w_laser(wrequest);
   8         else if (wpn == WEP_SHOTGUN)
   9                 return w_shotgun(wrequest);
  10         else if (wpn == WEP_UZI)
  11                 return w_uzi(wrequest);
  12         else if (wpn == WEP_GRENADE_LAUNCHER)
  13                 return w_glauncher(wrequest);
  14         else if (wpn == WEP_ELECTRO)
  15                 return w_electro(wrequest);
  16         else if (wpn == WEP_CRYLINK)
  17                 return w_crylink(wrequest);
  18         else if (wpn == WEP_NEX)
  19                 return w_nex(wrequest);
  20         else if (wpn == WEP_HAGAR)
  21                 return w_hagar(wrequest);
  22         else if (wpn == WEP_ROCKET_LAUNCHER)
  23                 return w_rlauncher(wrequest);
  24         return FALSE;
  25 };
  26
  27 string W_Name(float weaponid)
  28 {
  29         if(weaponid == WEP_LASER)             return "Laser";
  30         if(weaponid == WEP_UZI)               return "Machine Gun";
  31         if(weaponid == WEP_SHOTGUN)           return "Shotgun";
  32         if(weaponid == WEP_GRENADE_LAUNCHER)  return "Mortar";
  33         if(weaponid == WEP_ELECTRO)           return "Electro";
  34         if(weaponid == WEP_NEX)               return "Nex";
  35         if(weaponid == WEP_HAGAR)             return "Hagar";
  36         if(weaponid == WEP_ROCKET_LAUNCHER)   return "Rocket Launcher";
  37         if(weaponid == WEP_CRYLINK)           return "Crylink";
  38         return "@!#%'n Tuba";
  39 }
  40
  41 float W_ItemCode(float wpn)
  42 {
  43         switch(wpn)
  44         {
  45                 case WEP_LASER:            return IT_LASER;
  46                 case WEP_SHOTGUN:          return IT_SHOTGUN;
  47                 case WEP_UZI:              return IT_UZI;
  48                 case WEP_GRENADE_LAUNCHER: return IT_GRENADE_LAUNCHER;
  49                 case WEP_ELECTRO:          return IT_ELECTRO;
  50                 case WEP_CRYLINK:          return IT_CRYLINK;
  51                 case WEP_NEX:              return IT_NEX;
  52                 case WEP_HAGAR:            return IT_HAGAR;
  53                 case WEP_ROCKET_LAUNCHER:  return IT_ROCKET_LAUNCHER;
  54                 default:                   return 0;
  55         }
  56 }
  57
  58 float W_AmmoItemCode(float wpn)
  59 {
  60         switch(wpn)
  61         {
  62                 case WEP_SHOTGUN:          return IT_SHELLS;
  63                 case WEP_UZI:              return IT_NAILS;
  64                 case WEP_GRENADE_LAUNCHER: return IT_ROCKETS;
  65                 case WEP_ELECTRO:          return IT_CELLS;
  66                 case WEP_CRYLINK:          return IT_CELLS;
  67                 case WEP_NEX:              return IT_CELLS;
  68                 case WEP_HAGAR:            return IT_ROCKETS;
  69                 case WEP_ROCKET_LAUNCHER:  return IT_ROCKETS;
  70                 default:                   return 0;
  71         }
  72 }
  73
  74 // think function for tossed weapons
  75 void thrown_wep_think()
  76 {
  77         self.solid = SOLID_TRIGGER;
  78         self.owner = world;
  79         SUB_SetFade(self, time + 20, 1);
  80         setorigin(self, self.origin);
  81 };
  82
  83 // toss current weapon
  84 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
  85 {
  86         local float w, ammo;
  87         local entity wep, e;
  88         local .float ammofield;
  89
  90         w = self.weapon;
  91         if (w == 0)
  92                 return; // just in case
  93         if (w == WEP_LASER)
  94                 return;
  95         if (g_instagib)
  96                 return;
  97         if (g_rocketarena)
  98                 return;
  99         if (g_lms)
 100                 return;
 101         if (g_nixnex)
 102                 return;
 103         if (!cvar("g_pickup_items"))
 104                 return;
 105
 106         e = self;
 107         wep = spawn();
 108         self = wep;
 109
 110         setorigin(wep, e.origin + delta);
 111         makevectors(e.angles);
 112         wep.classname = "droppedweapon";
 113         wep.velocity = velo; // e.velocity * 0.5 + v_forward * 750;
 114         SUB_SetFade(wep, time + 20, 1);
 115
 116         ammofield = Item_CounterField(W_AmmoItemCode(w));
 117         w = W_ItemCode(w);
 118         if(!(e.items & w))
 119         {
 120                 remove(wep);
 121                 goto leave;
 122         }
 123         Item_SpawnByItemCode(w);
 124         if(startitem_failed)
 125                 goto leave;
 126         if(doreduce)
 127         {
 128                 ammo = min(e.ammofield, wep.ammofield);
 129                 wep.ammofield = ammo;
 130                 e.ammofield -= ammo;
 131         }
 132
 133         if(e.items & w)
 134                 if(e.health >= 1)
 135                         sprint(e, strcat("You dropped the ^2", wep.netname, " with ", ftos(wep.ammofield), " ammo", "\n"));
 136
 137         wep.owner = e;
 138         setorigin(wep, wep.origin);
 139         wep.nextthink = time + 0.5;
 140         wep.think = thrown_wep_think;
 141         wep.classname = "droppedweapon";
 142         wep.flags = wep.flags | FL_TOSSED;
 143         e.items = e.items - (e.items & w);
 144         e.switchweapon = w_getbestweapon(e);
 145         wep.colormap = e.colormap;
 146         if (e.switchweapon != e.weapon)
 147                 e.cnt = e.weapon;
 148
 149 :leave
 150         self = e;
 151 };
 152
 153 // switch between weapons
 154 void W_SwitchWeapon(float imp)
 155 {
 156         if (self.weapon != imp)
 157         if (client_hasweapon(self, imp, TRUE, TRUE))
 158         {
 159                 self.cnt = self.weapon ? self.weapon : self.switchweapon;
 160                 self.switchweapon = imp;
 161         }
 162 };
 163
 164 // next weapon
 165 void W_NextWeapon()
 166 {
 167         local float weaponwant, maxtries;
 168
 169         maxtries = WEP_LAST;
 170
 171         weaponwant = self.switchweapon + 1;
 172         if (weaponwant < WEP_FIRST)
 173                 weaponwant = WEP_LAST;
 174         if (weaponwant > WEP_LAST)
 175                 weaponwant = WEP_FIRST;
 176         while(!client_hasweapon(self, weaponwant, TRUE, FALSE))
 177         {
 178                 if(!maxtries)
 179                         return;
 180
 181                 maxtries -= 1;
 182                 weaponwant = weaponwant + 1;
 183                 if (weaponwant < WEP_FIRST)
 184                         weaponwant = WEP_LAST;
 185                 if (weaponwant > WEP_LAST)
 186                         weaponwant = WEP_FIRST;
 187         }
 188         self.cnt = self.weapon ? self.weapon : self.switchweapon;
 189         self.switchweapon = weaponwant;
 190 };
 191
 192 // prev weapon
 193 void W_PreviousWeapon()
 194 {
 195         local float weaponwant, maxtries;
 196
 197         maxtries = WEP_LAST;
 198
 199         weaponwant = self.switchweapon - 1;
 200         if (weaponwant < WEP_FIRST)
 201                 weaponwant = WEP_LAST;
 202         if (weaponwant > WEP_LAST)
 203                 weaponwant = WEP_FIRST;
 204         while(!client_hasweapon(self, weaponwant, TRUE, FALSE))
 205         {
 206                 if(!maxtries)
 207                         return;
 208
 209                 maxtries -= 1;
 210                 weaponwant = weaponwant - 1;
 211                 if (weaponwant < WEP_FIRST)
 212                         weaponwant = WEP_LAST;
 213                 if (weaponwant > WEP_LAST)
 214                         weaponwant = WEP_FIRST;
 215         }
 216         self.cnt = self.weapon ? self.weapon : self.switchweapon;
 217         self.switchweapon = weaponwant;
 218 };
 219
 220 float W_GetCycleWeapon(string weaponorder, float dir)
 221 {
 222         float n, i, weaponwant, first_valid, prev_valid, switchtonext, switchtolast;
 223         n = tokenize(weaponorder);
 224         switchtonext = switchtolast = 0;
 225         first_valid = prev_valid = -1;
 226
 227         if(dir == 0)
 228                 switchtonext = 1;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 weaponwant = stof(argv(i));
 233                 if(client_hasweapon(self, weaponwant, TRUE, FALSE))
 234                 {
 235                         if(switchtonext)
 236                                 return weaponwant;
 237                         if(first_valid < 0)
 238                                 first_valid = weaponwant;
 239                         prev_valid = weaponwant;
 240                         if(weaponwant == self.weapon)
 241                         {
 242                                 if(dir >= 0)
 243                                         switchtonext = 1;
 244                                 else if(prev_valid >= 0)
 245                                         return prev_valid;
 246                                 else
 247                                 {
 248                                         switchtolast = 1;
 249                                         break;
 250                                 }
 251                         }
 252                 }
 253         }
 254         if(first_valid >= 0)
 255         {
 256                 if(switchtolast)
 257                         return prev_valid;
 258                 else
 259                         return first_valid;
 260         }
 261         return -1;
 262 }
 263
 264 void W_CycleWeapon(string weaponorder, float dir)
 265 {
 266         float w;
 267         w = W_GetCycleWeapon(weaponorder, dir);
 268         if(w >= 0)
 269                 W_SwitchWeapon(w);
 270         else
 271                 // none available
 272                 sprint(self, "You do not have any of the specified weapons.\n");
 273 }
 274
 275 // Bringed back weapon frame
 276 void W_WeaponFrame()
 277 {
 278         if((arena_roundbased && time < warmup) || ((time < restart_countdown) && !cvar("sv_ready_restart_after_countdown")))
 279                 return;
 280
 281         if (!self.weaponentity || self.health < 1)
 282                 return; // Dead player can't use weapons and injure impulse commands
 283
 284         if(!self.switchweapon)
 285         {
 286                 self.weapon = 0;
 287                 self.weaponentity.state = WS_CLEAR;
 288                 return;
 289         }
 290
 291         makevectors(self.v_angle);
 292
 293         // Change weapon
 294         if (self.weapon != self.switchweapon)
 295         {
 296                 if (self.weaponentity.state == WS_CLEAR)
 297                 {
 298                         player_setanim(self.anim_draw, FALSE, TRUE, TRUE);
 299                         self.weaponentity.state = WS_RAISE;
 300                         weapon_action(self.switchweapon, WR_SETUP);
 301                         // VorteX: add player model weapon select frame here
 302                         // setcustomframe(PlayerWeaponRaise);
 303                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_ready);
 304                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 305                 }
 306                 else if (self.weaponentity.state == WS_READY)
 307                 {
 308 #ifndef INDEPENDENT_ATTACK_FINISHED
 309                         if(ATTACK_FINISHED(self) <= time + frametime * 0.5)
 310                         {
 311 #endif
 312                         sound (self, CHAN_WEAPON, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 313                         self.weaponentity.state = WS_DROP;
 314                         // set up weapon switch think in the future, and start drop anim
 315                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_clear);
 316                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 317 #ifndef INDEPENDENT_ATTACK_FINISHED
 318                         }
 319 #endif
 320                 }
 321         }
 322
 323         // call the think code which may fire the weapon
 324         // and do so multiple times to resolve framerate dependency issues if the
 325         // server framerate is very low and the weapon fire rate very high
 326         local float c;
 327         c = 0;
 328         while (c < 5)
 329         {
 330                 c = c + 1;
 331                 weapon_action(self.weapon, WR_THINK);
 332                 if (time + frametime * 0.5 >= self.weapon_nextthink)
 333                         self.weapon_think();
 334         }
 335
 336         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 337         //if (ATTACK_FINISHED(self) < time)
 338         //      ATTACK_FINISHED(self) = time;
 339
 340         //if (self.weapon_nextthink < time)
 341         //      self.weapon_nextthink = time;
 342
 343         // update currentammo incase it has changed
 344         if (self.items & IT_CELLS)
 345                 self.currentammo = self.ammo_cells;
 346         else if (self.items & IT_ROCKETS)
 347                 self.currentammo = self.ammo_rockets;
 348         else if (self.items & IT_NAILS)
 349                 self.currentammo = self.ammo_nails;
 350         else if (self.items & IT_SHELLS)
 351                 self.currentammo = self.ammo_shells;
 352         else
 353                 self.currentammo = 1;
 354
 355 };
 356
 357 float nixnex_weapon;
 358 float nixnex_nextchange;
 359 float nixnex_nextweapon;
 360 .float nixnex_lastchange_id;
 361 .float nixnex_lastinfotime;
 362 .float nixnex_nextincr;
 363
 364 void Nixnex_ChooseNextWeapon()
 365 {
 366         float numberof, id;
 367         numberof = WEP_LAST - WEP_FIRST; // all but the current one
 368         if(g_nixnex_with_laser)
 369                 numberof = numberof - 1;
 370         id = WEP_FIRST + ceil(random() * numberof) - 1;
 371
 372         if(g_nixnex_with_laser) // skip the laser if needed
 373                 id = id + 1;
 374
 375         if(id >= nixnex_weapon) // skip the current weapon
 376                 id = id + 1;
 377
 378         if(id < WEP_FIRST) // can't happen, but to be sure...
 379         {
 380                 dprint("Won't happen (id < WEP_FIRST)\n");
 381                 id = WEP_FIRST;
 382         }
 383         if(id > WEP_LAST) // either
 384         {
 385                 dprint("Won't happen (id > WEP_LAST)\n");
 386                 id = WEP_LAST;
 387         }
 388
 389         nixnex_nextweapon = id;
 390 }
 391
 392 void Nixnex_GiveCurrentWeapon()
 393 {
 394         float dt;
 395         if(g_nixnex)
 396         {
 397                 if(!nixnex_nextweapon)
 398                         Nixnex_ChooseNextWeapon();
 399
 400                 dt = ceil(nixnex_nextchange - time);
 401
 402                 if(dt <= 0)
 403                 {
 404                         nixnex_weapon = nixnex_nextweapon;
 405                         nixnex_nextweapon = 0;
 406                         nixnex_nextchange = time + cvar("g_balance_nixnex_roundtime");
 407                         //weapon_action(nixnex_weapon, WR_PRECACHE); // forget it, too slow
 408                 }
 409
 410                 if(nixnex_nextchange != self.nixnex_lastchange_id) // this shall only be called once per round!
 411                 {
 412                         self.nixnex_lastchange_id = nixnex_nextchange;
 413                         if (cvar("g_use_ammunition"))
 414                         {
 415                                 self.ammo_shells = cvar("g_balance_nixnex_ammo_shells");
 416                                 self.ammo_nails = cvar("g_balance_nixnex_ammo_nails");
 417                                 self.ammo_rockets = cvar("g_balance_nixnex_ammo_rockets");
 418                                 self.ammo_cells = cvar("g_balance_nixnex_ammo_cells");
 419                         }
 420                         else
 421                         {
 422                                 self.ammo_shells = cvar("g_pickup_shells_max");
 423                                 self.ammo_nails = cvar("g_pickup_nails_max");
 424                                 self.ammo_rockets = cvar("g_pickup_rockets_max");
 425                                 self.ammo_cells = cvar("g_pickup_cells_max");
 426                         }
 427                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 428                         if(dt >= 1 && dt <= 5)
 429                                 self.nixnex_lastinfotime = -42;
 430                         else
 431                                 centerprint(self, strcat("\n\n^2Active weapon: ^3", W_Name(nixnex_weapon), "\n"));
 432                 }
 433                 if(self.nixnex_lastinfotime != dt)
 434                 {
 435                         self.nixnex_lastinfotime = dt; // initial value 0 should count as "not seen"
 436                         if(dt >= 1 && dt <= 5)
 437                                 centerprint(self, strcat("^3", ftos(dt), "^2 seconds until weapon change...\n\nNext weapon: ^3", W_Name(nixnex_nextweapon), "\n"));
 438                 }
 439
 440                 if(cvar("g_use_ammunition") && time > self.nixnex_nextincr)
 441                 {
 442                         self.ammo_shells = self.ammo_shells + cvar("g_balance_nixnex_ammoincr_shells");
 443                         self.ammo_nails = self.ammo_nails + cvar("g_balance_nixnex_ammoincr_nails");
 444                         self.ammo_rockets = self.ammo_rockets + cvar("g_balance_nixnex_ammoincr_rockets");
 445                         self.ammo_cells = self.ammo_cells + cvar("g_balance_nixnex_ammoincr_cells");
 446                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 447                 }
 448
 449                 self.items = self.items - (self.items & (IT_LASER | IT_SHOTGUN | IT_UZI | IT_GRENADE_LAUNCHER | IT_ELECTRO | IT_CRYLINK | IT_NEX | IT_HAGAR | IT_ROCKET_LAUNCHER));
 450                 if(g_nixnex_with_laser)
 451                         self.items = self.items | IT_LASER;
 452                 self.items = self.items | W_ItemCode(nixnex_weapon);
 453
 454                 if(self.switchweapon != nixnex_weapon)
 455                         if(!client_hasweapon(self, self.switchweapon, TRUE, FALSE))
 456                                 if(client_hasweapon(self, nixnex_weapon, TRUE, FALSE))
 457                                         W_SwitchWeapon(nixnex_weapon);
 458         }
 459 }
 460