data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector animparseline(float animfile)
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize_sane(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void player_setupanimsformodel()
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void player_setanim(vector anim, float looping, float override, float restart)
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void player_updateframe()
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         if(sv_gentle < 1)
 262                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 263         // damage resistance (ignore most of the damage from a bullet or similar)
 264         damage = max(damage - 5, 1);
 265
 266         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 267         take = bound(0, damage - save, damage);
 268
 269         if (save > 10)
 270                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 271         else if (take > 30)
 272                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 273         else if (take > 10)
 274                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 275
 276         if not(IS_INDEPENDENT_PLAYER(self))
 277         if(sv_gentle < 1) {
 278                 if (take > 50)
 279                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 280                 if (take > 100)
 281                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 282         }
 283
 284         if (!(self.flags & FL_GODMODE))
 285         {
 286                 self.armorvalue = self.armorvalue - save;
 287                 self.health = self.health - take;
 288                 // pause regeneration for 5 seconds
 289                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 290         }
 291         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 292         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 293         self.dmg_inflictor = inflictor;
 294
 295         if (self.health <= -50)
 296         {
 297                 // don't use any animations as a gib
 298                 self.frame = 0;
 299                 self.dead_frame = 0;
 300                 // view just above the floor
 301                 self.view_ofs = '0 0 4';
 302
 303                 // make a juicy mess
 304                 local float multiplier;
 305                 multiplier = 1;
 306                 if (cvar("ekg"))
 307                         multiplier = 5;
 308
 309
 310                 // make a meaty mess
 311                 if(IS_INDEPENDENT_PLAYER(self))
 312                 {
 313                         TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 314                         MAKE_INDEPENDENT_PLAYER(self); // undo SOLID_CORPSE
 315                         self.takedamage = DAMAGE_NO; // can't damage this gib, to prevent better jumps from it
 316                 }
 317                 else
 318                         TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 319
 320                 if not(IS_INDEPENDENT_PLAYER(self))
 321                 if(sv_gentle < 1) {
 322                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 323                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 324
 325                         local float c;
 326                         c = 0;
 327
 328                         while (c < multiplier)
 329                         {
 330                                 c = c + 1;
 331                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 332                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 333                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 334                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 335                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 336                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 337
 338                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 339                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 340                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 341                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 342                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 343                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 344                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 345                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 346                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 347                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 348                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 349
 350                                 // these splat on impact
 351                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 352                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 353                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 354                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 355                         }
 356                         sound (self, CHAN_PLAYER, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 357                 }
 358         }
 359 }
 360
 361 void ClientKill_Now_TeamChange();
 362
 363 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 364 {
 365         local float take, save, waves, sdelay;
 366
 367         if(self.hook)
 368                 if(self.hook.aiment)
 369                         if(self.hook.aiment == attacker)
 370                                 RemoveGrapplingHook(self); // STOP THAT, you parasite!
 371
 372         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 373         if(sv_gentle > 0) {
 374                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 375         } else {
 376                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 377         }
 378
 379         if(g_arena)
 380         if(numspawned < 2)
 381                 return;
 382
 383         if (!g_minstagib)
 384         {
 385                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 386                 take = bound(0, damage - save, damage);
 387         }
 388         else
 389         {
 390                 save = 0;
 391                 take = damage;
 392         }
 393
 394         if (save > 10)
 395                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 396         else if (take > 30)
 397                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 398         else if (take > 10)
 399                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 400
 401         if (take > 50)
 402                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 403         if (take > 100)
 404                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 405
 406         if (time > self.spawnshieldtime)
 407         {
 408                 if (!(self.flags & FL_GODMODE))
 409                 {
 410                         self.armorvalue = self.armorvalue - save;
 411                         self.health = self.health - take;
 412                         // pause regeneration for 5 seconds
 413                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 414
 415                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 416                         {
 417                                 self.pain_finished = time + 0.5;        //Supajoe
 418
 419                                 if(sv_gentle < 1) {
 420                                         if (random() > 0.5)
 421                                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 422                                         else
 423                                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 424
 425                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 426                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 427                                         {
 428                                                 if(self.health > 75) // TODO make a "gentle" version?
 429                                                         PlayerSound(playersound_pain100, CHAN_PAIN, 0);
 430                                                 else if(self.health > 50)
 431                                                         PlayerSound(playersound_pain75, CHAN_PAIN, 0);
 432                                                 else if(self.health > 25)
 433                                                         PlayerSound(playersound_pain50, CHAN_PAIN, 0);
 434                                                 else if(self.health > 1)
 435                                                         PlayerSound(playersound_pain25, CHAN_PAIN, 0);
 436                                         }
 437                                 }
 438
 439                                 // throw off bot aim temporarily
 440                                 local float shake;
 441                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 442                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 443                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 444                         }
 445                 }
 446                 else
 447                         self.max_armorvalue += (save + take);
 448         }
 449         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 450         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 451         self.dmg_inflictor = inflictor;
 452
 453         if(attacker == self)
 454         {
 455                 // don't reset pushltime for self damage as it may be an attempt to
 456                 // escape a lava pit or similar
 457                 //self.pushltime = 0;
 458         }
 459         else if(attacker.classname == "player" || attacker.classname == "gib")
 460         {
 461                 self.pusher = attacker;
 462                 self.pushltime = time + cvar("g_maxpushtime");
 463         }
 464         else if(time < self.pushltime)
 465         {
 466                 attacker = self.pusher;
 467                 self.pushltime = max(self.pushltime, time + 0.6);
 468         }
 469         else
 470                 self.pushltime = 0;
 471
 472         if (self.health < 1)
 473         {
 474                 float defer_ClientKill_Now_TeamChange;
 475                 defer_ClientKill_Now_TeamChange = FALSE;
 476
 477                 if(sv_gentle < 1) // TODO make a "gentle" version?
 478                 {
 479                         if(deathtype == DEATH_DROWN)
 480                                 PlayerSound(playersound_drown, CHAN_PAIN, 0);
 481                         else
 482                                 PlayerSound(playersound_death, CHAN_PAIN, 0);
 483                 }
 484
 485                 // get rid of kill indicator
 486                 if(self.killindicator)
 487                 {
 488                         remove(self.killindicator);
 489                         self.killindicator = world;
 490                         if(self.killindicator_teamchange)
 491                                 defer_ClientKill_Now_TeamChange = TRUE;
 492
 493                         if(self.classname == "body")
 494                         if(deathtype == DEATH_KILL)
 495                         {
 496                                 // for the lemmings fans, a small harmless explosion
 497                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 498                         }
 499                 }
 500
 501                 // become fully visible
 502                 self.alpha = 1;
 503                 // clear selected player display
 504                 ClearSelectedPlayer();
 505                 // throw a weapon
 506                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 507                 // print an obituary message
 508                 Obituary (attacker, inflictor, self, deathtype);
 509                 race_PreDie();
 510                 DropAllRunes(self);
 511                 if(self == attacker)
 512                         kh_Key_DropAll(self, TRUE);
 513                 else if(attacker.classname == "player" || attacker.classname == "gib")
 514                         kh_Key_DropAll(self, FALSE);
 515                 else
 516                         kh_Key_DropAll(self, TRUE);
 517                 if(self.flagcarried)
 518                 {
 519                         if(attacker.classname != "player" && attacker.classname != "gib")
 520                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 521                         else if(attacker.team == self.team)
 522                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 523                         else
 524                                 DropFlag(self.flagcarried, world, attacker);
 525                 }
 526                 Portal_ClearAllLater(self);
 527                 // clear waypoints
 528                 WaypointSprite_PlayerDead();
 529                 // make the corpse upright (not tilted)
 530                 self.angles_x = 0;
 531                 self.angles_z = 0;
 532                 // don't spin
 533                 self.avelocity = '0 0 0';
 534                 // view from the floor
 535                 self.view_ofs = '0 0 -8';
 536                 // toss the corpse
 537                 self.movetype = MOVETYPE_TOSS;
 538                 // shootable corpse
 539                 self.solid = SOLID_CORPSE;
 540                 // don't stick to the floor
 541                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 542                 // dying animation
 543                 self.deadflag = DEAD_DYING;
 544                 // when to allow respawn
 545                 sdelay = 0;
 546                 waves = 0;
 547                 if(cvar("g_respawn_mapsettings"))
 548                 {
 549                         sdelay = cvar("g_respawn_mapsettings_delay");
 550                         waves = cvar("g_respawn_mapsettings_waves");
 551                 }
 552                 if(!sdelay)
 553                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 554                 if(!sdelay)
 555                         sdelay = cvar("g_respawn_delay");
 556                 if(!waves)
 557                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 558                 if(!waves)
 559                         waves = cvar("g_respawn_waves");
 560                 if(waves)
 561                         self.death_time = ceil((time + sdelay) / waves) * waves;
 562                 else
 563                         self.death_time = time + sdelay;
 564                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 565                         self.respawn_countdown = 10; // first number to count down from is 10
 566                 else
 567                         self.respawn_countdown = -1; // do not count down
 568                 if (random() < 0.5)
 569                 {
 570                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 571                         self.dead_frame = self.anim_dead1_x;
 572                 }
 573                 else
 574                 {
 575                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 576                         self.dead_frame = self.anim_dead2_x;
 577                 }
 578                 // set damage function to corpse damage
 579                 self.event_damage = PlayerCorpseDamage;
 580                 // call the corpse damage function just in case it wants to gib
 581                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 582                 // set up to fade out later
 583                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 584
 585                 // remove laserdot
 586                 if(self.weaponentity)
 587                         if(self.weaponentity.lasertarget)
 588                                 remove(self.weaponentity.lasertarget);
 589
 590                 if(clienttype(self) == CLIENTTYPE_REAL)
 591                 {
 592                         self.fixangle = TRUE;
 593                         //msg_entity = self;
 594                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 595                         //WriteAngle (MSG_ONE, self.v_angle_x);
 596                         //WriteAngle (MSG_ONE, self.v_angle_y);
 597                         //WriteAngle (MSG_ONE, 80);
 598                 }
 599
 600                 if(g_arena)
 601                         Spawnqueue_Unmark(self);
 602
 603                 if(defer_ClientKill_Now_TeamChange)
 604                         ClientKill_Now_TeamChange();
 605
 606                 if(sv_gentle > 0) {
 607                         // remove corpse
 608                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 609                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 610                 }
 611         }
 612 }
 613
 614 float UpdateSelectedPlayer_countvalue(float v)
 615 {
 616         return max(0, (v - 1.0) / 0.5);
 617 }
 618
 619 // returns: -2 if no hit, otherwise cos of the angle
 620 // uses the global v_angle
 621 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 622 {
 623         vector so, d;
 624         float c;
 625
 626         if(p == self)
 627                 return -2;
 628
 629         if(p.deadflag)
 630                 return -2;
 631
 632         so = self.origin + self.view_ofs;
 633         d = p.origin - so;
 634
 635         // misaimed?
 636         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 637                 return -2;
 638
 639         // now find the cos of the angle...
 640         c = normalize(d) * v_forward;
 641
 642         if(c <= mincosangle)
 643                 return -2;
 644
 645         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 646         if(trace_fraction < 1)
 647                 return -2;
 648
 649         return c;
 650 }
 651
 652 void ClearSelectedPlayer()
 653 {
 654         if(self.selected_player)
 655         {
 656                 centerprint_expire(self, CENTERPRIO_POINT);
 657                 self.selected_player = world;
 658                 self.selected_player_display_needs_update = FALSE;
 659         }
 660 }
 661
 662 void UpdateSelectedPlayer()
 663 {
 664         entity selected;
 665         float selected_score;
 666         selected = world;
 667         selected_score = 0.95; // 18 degrees
 668
 669         if(!cvar("sv_allow_shownames"))
 670                 return;
 671
 672         if(clienttype(self) != CLIENTTYPE_REAL)
 673                 return;
 674
 675         if(self.cvar_cl_shownames == 0)
 676                 return;
 677
 678         if(self.cvar_cl_shownames == 1 && !teams_matter)
 679                 return;
 680
 681         makevectors(self.v_angle); // sets v_forward
 682
 683         // 1. cursor trace is always right
 684         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 685         {
 686                 selected = self.cursor_trace_ent;
 687         }
 688         else
 689         {
 690                 // 2. if we don't have a cursor trace, find the player which is least
 691                 //    mis-aimed at
 692                 entity p;
 693                 FOR_EACH_PLAYER(p)
 694                 {
 695                         float c;
 696                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 697                         if(c >= -1)
 698                         {
 699                                 selected = p;
 700                                 selected_score = c;
 701                         }
 702                 }
 703         }
 704
 705         if(selected)
 706         {
 707                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 708         }
 709         else
 710         {
 711                 if(time < self.selected_player_display_timeout)
 712                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 713                                 selected = self.selected_player;
 714         }
 715
 716         if(selected)
 717         {
 718                 if(selected == self.selected_player)
 719                 {
 720                         float save;
 721                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 722                         self.selected_player_count = self.selected_player_count + frametime;
 723                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 724                         {
 725                                 string namestr, healthstr;
 726                                 namestr = playername(selected);
 727                                 if(teams_matter)
 728                                 {
 729                                         healthstr = ftos(floor(selected.health));
 730                                         if(self.team == selected.team)
 731                                         {
 732                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 733                                                 self.selected_player_display_needs_update = TRUE;
 734                                         }
 735                                 }
 736                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 737                         }
 738                 }
 739                 else
 740                 {
 741                         ClearSelectedPlayer();
 742                         self.selected_player = selected;
 743                         self.selected_player_time = time;
 744                         self.selected_player_count = 0;
 745                         self.selected_player_display_needs_update = FALSE;
 746                 }
 747         }
 748         else
 749         {
 750                 ClearSelectedPlayer();
 751         }
 752
 753         if(self.selected_player)
 754                 self.last_selected_player = self.selected_player;
 755 }
 756
 757 float GetVoiceMessageTeamsayType(string type)
 758 {
 759         if(type == "taunt")
 760                 return 0;
 761         if(type == "teamshoot")
 762                 return 2;
 763         if(type == "teamshoot_auto")
 764                 return 3;
 765         return 1;
 766 }
 767
 768 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 769 float GetPlayerSoundSampleField_notFound;
 770 float GetPlayerSoundSampleField_fixed;
 771 .string GetVoiceMessageSampleField(string type)
 772 {
 773         GetPlayerSoundSampleField_notFound = 0;
 774         GetPlayerSoundSampleField_fixed = 0;
 775         switch(type)
 776         {
 777                 case "attack":            return playersound_attack;
 778                 case "attackinfive":      return playersound_attackinfive;
 779                 case "coverme":           return playersound_coverme;
 780                 case "defend":            return playersound_defend;
 781                 case "freelance":         return playersound_freelance;
 782                 case "incoming":          return playersound_incoming;
 783                 case "meet":              return playersound_meet;
 784                 case "needhelp":          return playersound_needhelp;
 785                 case "seenflag":          return playersound_seenflag;
 786                 case "taunt":             return playersound_taunt;
 787                 case "teamshoot":         return playersound_teamshoot;
 788                 case "teamshoot_auto":    return playersound_teamshoot;
 789         }
 790         GetPlayerSoundSampleField_notFound = 1;
 791         return playersound_taunt;
 792 }
 793
 794 .string GetPlayerSoundSampleField(string type)
 795 {
 796         GetPlayerSoundSampleField_notFound = 0;
 797         GetPlayerSoundSampleField_fixed = 0;
 798         switch(type)
 799         {
 800                 case "death":        return playersound_death;
 801                 case "drown":        return playersound_drown;
 802                 case "falling":      return playersound_falling;
 803                 case "gasp":         return playersound_gasp;
 804                 case "jump":         return playersound_jump;
 805                 case "pain25":       return playersound_pain25;
 806                 case "pain50":       return playersound_pain50;
 807                 case "pain75":       return playersound_pain75;
 808                 case "pain100":      return playersound_pain100;
 809         }
 810         GetPlayerSoundSampleField_notFound = 1;
 811         return playersound_taunt;
 812 }
 813
 814 void PrecacheGlobalSound(string samplestring)
 815 {
 816         float n, i;
 817         tokenize_sane(samplestring);
 818         n = stof(argv(1));
 819         if(n > 0)
 820         {
 821                 for(i = 1; i <= n; ++i)
 822                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 823         }
 824         else
 825         {
 826                 precache_sound(strcat(argv(0), ".wav"));
 827         }
 828 }
 829
 830 void PrecachePlayerSounds(string f)
 831 {
 832         float fh;
 833         string s;
 834         fh = fopen(f, FILE_READ);
 835         if(fh < 0)
 836                 return;
 837         while((s = fgets(fh)))
 838         {
 839                 if(tokenize_sane(s) != 3)
 840                 {
 841                         dprint("Invalid sound info line: ", s, "\n");
 842                         continue;
 843                 }
 844                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 845         }
 846         fclose(fh);
 847 }
 848
 849 void ClearPlayerSounds()
 850 {
 851         if(self.playersound_attack      ) { strunzone(self.playersound_attack      ); self.playersound_attack = string_null; }
 852         if(self.playersound_attackinfive) { strunzone(self.playersound_attackinfive); self.playersound_attackinfive = string_null; }
 853         if(self.playersound_coverme     ) { strunzone(self.playersound_coverme     ); self.playersound_coverme = string_null; }
 854         if(self.playersound_defend      ) { strunzone(self.playersound_defend      ); self.playersound_defend = string_null; }
 855         if(self.playersound_freelance   ) { strunzone(self.playersound_freelance   ); self.playersound_freelance = string_null; }
 856         if(self.playersound_incoming    ) { strunzone(self.playersound_incoming    ); self.playersound_incoming = string_null; }
 857         if(self.playersound_meet        ) { strunzone(self.playersound_meet        ); self.playersound_meet = string_null; }
 858         if(self.playersound_needhelp    ) { strunzone(self.playersound_needhelp    ); self.playersound_needhelp = string_null; }
 859         if(self.playersound_seenflag    ) { strunzone(self.playersound_seenflag    ); self.playersound_seenflag = string_null; }
 860         if(self.playersound_taunt       ) { strunzone(self.playersound_taunt       ); self.playersound_taunt = string_null; }
 861         if(self.playersound_teamshoot   ) { strunzone(self.playersound_teamshoot   ); self.playersound_teamshoot = string_null; }
 862         if(self.playersound_death       ) { strunzone(self.playersound_death       ); self.playersound_death = string_null; }
 863         if(self.playersound_drown       ) { strunzone(self.playersound_drown       ); self.playersound_drown = string_null; }
 864         if(self.playersound_falling     ) { strunzone(self.playersound_falling     ); self.playersound_falling = string_null; }
 865         if(self.playersound_gasp        ) { strunzone(self.playersound_gasp        ); self.playersound_gasp = string_null; }
 866         if(self.playersound_jump        ) { strunzone(self.playersound_jump        ); self.playersound_jump = string_null; }
 867         if(self.playersound_pain25      ) { strunzone(self.playersound_pain25      ); self.playersound_pain25 = string_null; }
 868         if(self.playersound_pain50      ) { strunzone(self.playersound_pain50      ); self.playersound_pain50 = string_null; }
 869         if(self.playersound_pain75      ) { strunzone(self.playersound_pain75      ); self.playersound_pain75 = string_null; }
 870         if(self.playersound_pain100     ) { strunzone(self.playersound_pain100     ); self.playersound_pain100 = string_null; }
 871 }
 872
 873 void LoadPlayerSounds(string f, float first)
 874 {
 875         float fh;
 876         string s;
 877         var .string field;
 878         fh = fopen(f, FILE_READ);
 879         if(fh < 0)
 880                 return;
 881         while((s = fgets(fh)))
 882         {
 883                 if(tokenize_sane(s) != 3)
 884                         continue;
 885                 field = GetPlayerSoundSampleField(argv(0));
 886                 if(GetPlayerSoundSampleField_notFound)
 887                         field = GetVoiceMessageSampleField(argv(0));
 888                 if(GetPlayerSoundSampleField_notFound)
 889                         continue;
 890                 if(GetPlayerSoundSampleField_fixed)
 891                         if not(first)
 892                                 continue;
 893                 if(self.field)
 894                         strunzone(self.field);
 895                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 896         }
 897         fclose(fh);
 898 }
 899
 900 .float modelindex_for_playersound;
 901 void UpdatePlayerSounds()
 902 {
 903         if(self.modelindex == self.modelindex_for_playersound)
 904                 return;
 905         self.modelindex_for_playersound = self.modelindex;
 906         ClearPlayerSounds();
 907         LoadPlayerSounds("sound/player/default.sounds", 1);
 908         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
 909 }
 910
 911 void GlobalSound(string sample, float chan, float teamsay)
 912 {
 913         float n;
 914
 915         if(sample == "")
 916                 return;
 917
 918         tokenize_sane(sample);
 919         n = stof(argv(1));
 920         if(n > 0)
 921                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
 922         else
 923                 sample = strcat(argv(0), ".wav"); // randomization
 924
 925         if(teamsay == 3) // only to last attacker
 926         {
 927                 if(self.pusher)
 928                         if(self.pusher.team == self.team)
 929                         {
 930                                 msg_entity = self.pusher;
 931                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 932                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 933                         }
 934         }
 935         else if(teamsay == 2) // only to last attacker and self
 936         {
 937                 if(self.pusher)
 938                         if(self.pusher.team == self.team)
 939                         {
 940                                 msg_entity = self.pusher;
 941                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 942                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 943                                 msg_entity = self;
 944                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 945                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 946                         }
 947         }
 948         else if(teamsay == 0) // to everyone
 949         {
 950                 // broadcast the sound, but it's directional
 951                 sound(self, chan, sample, VOL_BASE, ATTN_NORM);
 952         }
 953         else if(teamsay == 1) // to the same team
 954         {
 955                 if(teams_matter)
 956                 {
 957                         entity e;
 958                         FOR_EACH_REALCLIENT(e)
 959                                 if(!teams_matter || e.team == self.team)
 960                                 {
 961                                         msg_entity = e;
 962                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 963                                 }
 964                 }
 965                 else
 966                 {
 967                         sound(self, chan, sample, VOL_BASE, ATTN_NONE);
 968                 }
 969         }
 970 }
 971
 972 void PlayerSound(.string samplefield, float chan, float teamsay)
 973 {
 974         string sample;
 975         sample = self.samplefield;
 976         GlobalSound(sample, chan, teamsay);
 977 }
 978
 979 void VoiceMessage(string type)
 980 {
 981         var .string sample;
 982         var float teamsay;
 983         sample = GetVoiceMessageSampleField(type);
 984
 985         if(GetPlayerSoundSampleField_notFound)
 986         {
 987                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 988                 return;
 989         }
 990
 991         teamsay = GetVoiceMessageTeamsayType(type);
 992
 993         PlayerSound(sample, CHAN_VOICE, teamsay);
 994 }