data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector animparseline(float animfile)
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void player_setupanimsformodel()
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void player_setanim(vector anim, float looping, float override, float restart)
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void player_updateframe()
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         if(sv_gentle < 1)
 262                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 263         // damage resistance (ignore most of the damage from a bullet or similar)
 264         damage = max(damage - 5, 1);
 265
 266         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 267         take = bound(0, damage - save, damage);
 268
 269         if (save > 10)
 270                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 271         else if (take > 30)
 272                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 273         else if (take > 10)
 274                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 275
 276         if(sv_gentle < 1) {
 277                 if (take > 50)
 278                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 279                 if (take > 100)
 280                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 281         }
 282
 283         if (!(self.flags & FL_GODMODE))
 284         {
 285                 self.armorvalue = self.armorvalue - save;
 286                 self.health = self.health - take;
 287                 // pause regeneration for 5 seconds
 288                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 289         }
 290         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 291         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 292         self.dmg_inflictor = inflictor;
 293
 294         if (self.health <= -50)
 295         {
 296                 // don't use any animations as a gib
 297                 self.frame = 0;
 298                 self.dead_frame = 0;
 299                 // view just above the floor
 300                 self.view_ofs = '0 0 4';
 301
 302                 // make a juicy mess
 303                 local float multiplier;
 304                 multiplier = 1;
 305                 if (cvar("ekg"))
 306                         multiplier = 5;
 307
 308
 309                 // make a meaty mess
 310                 TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 311
 312                 if(sv_gentle < 1) {
 313                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 314                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 315
 316                         local float c;
 317                         c = 0;
 318
 319                         while (c < multiplier)
 320                         {
 321                                 c = c + 1;
 322                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 323                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 324                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 325                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 326                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 327                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 328
 329                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 330                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 331                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 332                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 333                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 334                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 335                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 336                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 337                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 338                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 339                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 340
 341                                 // these splat on impact
 342                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 343                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 344                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 345                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 346                         }
 347                         sound (self, CHAN_PLAYER, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 348                 }
 349         }
 350 }
 351
 352 void ClientKill_Now_TeamChange();
 353
 354 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 355 {
 356         local float take, save, waves, sdelay;
 357
 358         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 359         if(sv_gentle > 0) {
 360                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 361         } else {
 362                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 363         }
 364
 365         if(g_arena)
 366         if(numspawned < 2)
 367                 return;
 368
 369         if (!g_minstagib)
 370         {
 371                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 372                 take = bound(0, damage - save, damage);
 373         }
 374         else
 375         {
 376                 save = 0;
 377                 take = damage;
 378         }
 379
 380         if (save > 10)
 381                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 382         else if (take > 30)
 383                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 384         else if (take > 10)
 385                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 386
 387         if (take > 50)
 388                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 389         if (take > 100)
 390                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 391
 392         if (time > self.spawnshieldtime)
 393         {
 394                 if (!(self.flags & FL_GODMODE))
 395                 {
 396                         self.armorvalue = self.armorvalue - save;
 397                         self.health = self.health - take;
 398                         // pause regeneration for 5 seconds
 399                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 400
 401                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 402                         {
 403                                 self.pain_finished = time + 0.5;        //Supajoe
 404
 405                                 if(sv_gentle < 1) {
 406                                         if (random() > 0.5)
 407                                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 408                                         else
 409                                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 410
 411                                         if(deathtype != IT_LASER || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 412                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 413                                         {
 414                                                 if(self.health > 75) // TODO make a "gentle" version?
 415                                                         PlayerSound(playersound_pain100, CHAN_PAIN, 0);
 416                                                 else if(self.health > 50)
 417                                                         PlayerSound(playersound_pain75, CHAN_PAIN, 0);
 418                                                 else if(self.health > 25)
 419                                                         PlayerSound(playersound_pain50, CHAN_PAIN, 0);
 420                                                 else if(self.health > 1)
 421                                                         PlayerSound(playersound_pain25, CHAN_PAIN, 0);
 422                                         }
 423                                 }
 424
 425                                 // throw off bot aim temporarily
 426                                 local float shake;
 427                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 428                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 429                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 430                         }
 431                 }
 432                 else
 433                         self.max_armorvalue += (save + take);
 434         }
 435         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 436         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 437         self.dmg_inflictor = inflictor;
 438
 439         if(attacker == self)
 440         {
 441                 // don't reset pushltime for self damage as it may be an attempt to
 442                 // escape a lava pit or similar
 443                 //self.pushltime = 0;
 444         }
 445         else if(attacker.classname == "player" || attacker.classname == "gib")
 446         {
 447                 self.pusher = attacker;
 448                 self.pushltime = time + cvar("g_maxpushtime");
 449         }
 450         else if(time < self.pushltime)
 451         {
 452                 attacker = self.pusher;
 453                 self.pushltime = max(self.pushltime, time + 0.6);
 454         }
 455         else
 456                 self.pushltime = 0;
 457
 458         if (self.health < 1)
 459         {
 460                 float defer_ClientKill_Now_TeamChange;
 461                 defer_ClientKill_Now_TeamChange = FALSE;
 462
 463                 if(sv_gentle < 1) // TODO make a "gentle" version?
 464                 {
 465                         if(deathtype == DEATH_DROWN)
 466                                 PlayerSound(playersound_drown, CHAN_PAIN, 0);
 467                         else
 468                                 PlayerSound(playersound_death, CHAN_PAIN, 0);
 469                 }
 470
 471                 // get rid of kill indicator
 472                 if(self.killindicator)
 473                 {
 474                         remove(self.killindicator);
 475                         self.killindicator = world;
 476                         if(self.killindicator_teamchange)
 477                                 defer_ClientKill_Now_TeamChange = TRUE;
 478
 479                         if(self.classname == "body")
 480                         if(deathtype == DEATH_KILL)
 481                         {
 482                                 // for the lemmings fans, a small harmless explosion
 483                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 484                         }
 485                 }
 486
 487                 // become fully visible
 488                 self.alpha = 1;
 489                 // clear selected player display
 490                 ClearSelectedPlayer();
 491                 // throw a weapon
 492                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 493                 // print an obituary message
 494                 Obituary (attacker, self, deathtype);
 495                 DropAllRunes(self);
 496                 if(self == attacker)
 497                         kh_Key_DropAll(self, TRUE);
 498                 else if(attacker.classname == "player" || attacker.classname == "gib")
 499                         kh_Key_DropAll(self, FALSE);
 500                 else
 501                         kh_Key_DropAll(self, TRUE);
 502                 if(self.flagcarried)
 503                         DropFlag(self.flagcarried);
 504                 // clear waypoints
 505                 WaypointSprite_PlayerDead();
 506                 // make the corpse upright (not tilted)
 507                 self.angles_x = 0;
 508                 self.angles_z = 0;
 509                 // don't spin
 510                 self.avelocity = '0 0 0';
 511                 // view from the floor
 512                 self.view_ofs = '0 0 -8';
 513                 // toss the corpse
 514                 self.movetype = MOVETYPE_TOSS;
 515                 // shootable corpse
 516                 self.solid = SOLID_CORPSE;
 517                 // don't stick to the floor
 518                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 519                 // dying animation
 520                 self.deadflag = DEAD_DYING;
 521                 // when to allow respawn
 522                 sdelay = 0;
 523                 waves = 0;
 524                 if(cvar("g_respawn_mapsettings"))
 525                 {
 526                         sdelay = cvar("g_respawn_mapsettings_delay");
 527                         waves = cvar("g_respawn_mapsettings_waves");
 528                 }
 529                 if(!sdelay)
 530                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 531                 if(!sdelay)
 532                         sdelay = cvar("g_respawn_delay");
 533                 if(!waves)
 534                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 535                 if(!waves)
 536                         waves = cvar("g_respawn_waves");
 537                 if(waves)
 538                         self.death_time = ceil((time + sdelay) / waves) * waves;
 539                 else
 540                         self.death_time = time + sdelay;
 541                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 542                         self.respawn_countdown = 10; // first number to count down from is 10
 543                 else
 544                         self.respawn_countdown = -1; // do not count down
 545                 if (random() < 0.5)
 546                 {
 547                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 548                         self.dead_frame = self.anim_dead1_x;
 549                 }
 550                 else
 551                 {
 552                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 553                         self.dead_frame = self.anim_dead2_x;
 554                 }
 555                 // set damage function to corpse damage
 556                 self.event_damage = PlayerCorpseDamage;
 557                 // call the corpse damage function just in case it wants to gib
 558                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 559                 // set up to fade out later
 560                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 561
 562                 // remove laserdot
 563                 if(self.weaponentity)
 564                         if(self.weaponentity.lasertarget)
 565                                 remove(self.weaponentity.lasertarget);
 566
 567                 if(clienttype(self) == CLIENTTYPE_REAL)
 568                 {
 569                         self.fixangle = TRUE;
 570                         //msg_entity = self;
 571                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 572                         //WriteAngle (MSG_ONE, self.v_angle_x);
 573                         //WriteAngle (MSG_ONE, self.v_angle_y);
 574                         //WriteAngle (MSG_ONE, 80);
 575                 }
 576
 577                 if(g_arena)
 578                         Spawnqueue_Unmark(self);
 579
 580                 if(defer_ClientKill_Now_TeamChange)
 581                         ClientKill_Now_TeamChange();
 582
 583                 if(sv_gentle > 0) {
 584                         // remove corpse
 585                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 586                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 587                 }
 588         }
 589 }
 590
 591 float UpdateSelectedPlayer_countvalue(float v)
 592 {
 593         return max(0, (v - 1.0) / 0.5);
 594 }
 595
 596 // returns: -2 if no hit, otherwise cos of the angle
 597 // uses the global v_angle
 598 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 599 {
 600         vector so, d;
 601         float c;
 602
 603         if(p == self)
 604                 return -2;
 605
 606         if(p.deadflag)
 607                 return -2;
 608
 609         so = self.origin + self.view_ofs;
 610         d = p.origin - so;
 611
 612         // misaimed?
 613         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 614                 return -2;
 615
 616         // now find the cos of the angle...
 617         c = normalize(d) * v_forward;
 618
 619         if(c <= mincosangle)
 620                 return -2;
 621
 622         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 623         if(trace_fraction < 1)
 624                 return -2;
 625
 626         return c;
 627 }
 628
 629 void ClearSelectedPlayer()
 630 {
 631         if(self.selected_player)
 632         {
 633                 centerprint_expire(self, CENTERPRIO_POINT);
 634                 self.selected_player = world;
 635                 self.selected_player_display_needs_update = FALSE;
 636         }
 637 }
 638
 639 void UpdateSelectedPlayer()
 640 {
 641         entity selected;
 642         float selected_score;
 643         selected = world;
 644         selected_score = 0.95; // 18 degrees
 645
 646         if(!cvar("sv_allow_shownames"))
 647                 return;
 648
 649         if(clienttype(self) != CLIENTTYPE_REAL)
 650                 return;
 651
 652         if(self.cvar_cl_shownames == 0)
 653                 return;
 654
 655         if(self.cvar_cl_shownames == 1 && !teams_matter)
 656                 return;
 657
 658         makevectors(self.v_angle); // sets v_forward
 659
 660         // 1. cursor trace is always right
 661         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 662         {
 663                 selected = self.cursor_trace_ent;
 664         }
 665         else
 666         {
 667                 // 2. if we don't have a cursor trace, find the player which is least
 668                 //    mis-aimed at
 669                 entity p;
 670                 FOR_EACH_PLAYER(p)
 671                 {
 672                         float c;
 673                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 674                         if(c >= -1)
 675                         {
 676                                 selected = p;
 677                                 selected_score = c;
 678                         }
 679                 }
 680         }
 681
 682         if(selected)
 683         {
 684                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 685         }
 686         else
 687         {
 688                 if(time < self.selected_player_display_timeout)
 689                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 690                                 selected = self.selected_player;
 691         }
 692
 693         if(selected)
 694         {
 695                 if(selected == self.selected_player)
 696                 {
 697                         float save;
 698                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 699                         self.selected_player_count = self.selected_player_count + frametime;
 700                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 701                         {
 702                                 string namestr, healthstr;
 703                                 namestr = playername(selected);
 704                                 if(teams_matter)
 705                                 {
 706                                         healthstr = ftos(floor(selected.health));
 707                                         if(self.team == selected.team)
 708                                         {
 709                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 710                                                 self.selected_player_display_needs_update = TRUE;
 711                                         }
 712                                 }
 713                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 714                         }
 715                 }
 716                 else
 717                 {
 718                         ClearSelectedPlayer();
 719                         self.selected_player = selected;
 720                         self.selected_player_time = time;
 721                         self.selected_player_count = 0;
 722                         self.selected_player_display_needs_update = FALSE;
 723                 }
 724         }
 725         else
 726         {
 727                 ClearSelectedPlayer();
 728         }
 729
 730         if(self.selected_player)
 731                 self.last_selected_player = self.selected_player;
 732 }
 733
 734 float GetVoiceMessageTeamsayType(string type)
 735 {
 736         if(type == "taunt")
 737                 return 0;
 738         if(type == "teamshoot")
 739                 return 2;
 740         return 1;
 741 }
 742
 743 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 744 float GetPlayerSoundSampleField_notFound;
 745 float GetPlayerSoundSampleField_fixed;
 746 .string GetVoiceMessageSampleField(string type)
 747 {
 748         GetPlayerSoundSampleField_notFound = 0;
 749         GetPlayerSoundSampleField_fixed = 0;
 750         switch(type)
 751         {
 752                 case "attack":       return playersound_attack;
 753                 case "attackinfive": return playersound_attackinfive;
 754                 case "coverme":      return playersound_coverme;
 755                 case "defend":       return playersound_defend;
 756                 case "freelance":    return playersound_freelance;
 757                 case "incoming":     return playersound_incoming;
 758                 case "meet":         return playersound_meet;
 759                 case "needhelp":     return playersound_needhelp;
 760                 case "seenflag":     return playersound_seenflag;
 761                 case "taunt":        return playersound_taunt;
 762                 case "teamshoot":    return playersound_teamshoot;
 763         }
 764         GetPlayerSoundSampleField_notFound = 1;
 765         return playersound_taunt;
 766 }
 767
 768 .string GetPlayerSoundSampleField(string type)
 769 {
 770         GetPlayerSoundSampleField_notFound = 0;
 771         GetPlayerSoundSampleField_fixed = 0;
 772         switch(type)
 773         {
 774                 case "death":        return playersound_death;
 775                 case "drown":        return playersound_drown;
 776                 case "falling":      return playersound_falling;
 777                 case "gasp":         return playersound_gasp;
 778                 case "jump":         return playersound_jump;
 779                 case "pain25":       return playersound_pain25;
 780                 case "pain50":       return playersound_pain50;
 781                 case "pain75":       return playersound_pain75;
 782                 case "pain100":      return playersound_pain100;
 783         }
 784         GetPlayerSoundSampleField_notFound = 1;
 785         return playersound_taunt;
 786 }
 787
 788 void PrecacheGlobalSound(string samplestring)
 789 {
 790         float n, i;
 791         tokenize(samplestring);
 792         n = stof(argv(1));
 793         if(n > 0)
 794         {
 795                 for(i = 1; i <= n; ++i)
 796                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 797         }
 798         else
 799         {
 800                 precache_sound(strcat(argv(0), ".wav"));
 801         }
 802 }
 803
 804 void PrecachePlayerSounds(string f)
 805 {
 806         float fh;
 807         string s;
 808         fh = fopen(f, FILE_READ);
 809         if(fh < 0)
 810                 return;
 811         while((s = fgets(fh)))
 812         {
 813                 if(tokenize(s) != 3)
 814                 {
 815                         dprint("Invalid sound info line: ", s, "\n");
 816                         continue;
 817                 }
 818                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 819         }
 820         fclose(fh);
 821 }
 822
 823 void ClearPlayerSounds()
 824 {
 825         if(self.playersound_attack      ) { strunzone(self.playersound_attack      ); self.playersound_attack = string_null; }
 826         if(self.playersound_attackinfive) { strunzone(self.playersound_attackinfive); self.playersound_attackinfive = string_null; }
 827         if(self.playersound_coverme     ) { strunzone(self.playersound_coverme     ); self.playersound_coverme = string_null; }
 828         if(self.playersound_defend      ) { strunzone(self.playersound_defend      ); self.playersound_defend = string_null; }
 829         if(self.playersound_freelance   ) { strunzone(self.playersound_freelance   ); self.playersound_freelance = string_null; }
 830         if(self.playersound_incoming    ) { strunzone(self.playersound_incoming    ); self.playersound_incoming = string_null; }
 831         if(self.playersound_meet        ) { strunzone(self.playersound_meet        ); self.playersound_meet = string_null; }
 832         if(self.playersound_needhelp    ) { strunzone(self.playersound_needhelp    ); self.playersound_needhelp = string_null; }
 833         if(self.playersound_seenflag    ) { strunzone(self.playersound_seenflag    ); self.playersound_seenflag = string_null; }
 834         if(self.playersound_taunt       ) { strunzone(self.playersound_taunt       ); self.playersound_taunt = string_null; }
 835         if(self.playersound_teamshoot   ) { strunzone(self.playersound_teamshoot   ); self.playersound_teamshoot = string_null; }
 836         if(self.playersound_death       ) { strunzone(self.playersound_death       ); self.playersound_death = string_null; }
 837         if(self.playersound_drown       ) { strunzone(self.playersound_drown       ); self.playersound_drown = string_null; }
 838         if(self.playersound_falling     ) { strunzone(self.playersound_falling     ); self.playersound_falling = string_null; }
 839         if(self.playersound_gasp        ) { strunzone(self.playersound_gasp        ); self.playersound_gasp = string_null; }
 840         if(self.playersound_jump        ) { strunzone(self.playersound_jump        ); self.playersound_jump = string_null; }
 841         if(self.playersound_pain25      ) { strunzone(self.playersound_pain25      ); self.playersound_pain25 = string_null; }
 842         if(self.playersound_pain50      ) { strunzone(self.playersound_pain50      ); self.playersound_pain50 = string_null; }
 843         if(self.playersound_pain75      ) { strunzone(self.playersound_pain75      ); self.playersound_pain75 = string_null; }
 844         if(self.playersound_pain100     ) { strunzone(self.playersound_pain100     ); self.playersound_pain100 = string_null; }
 845 }
 846
 847 void LoadPlayerSounds(string f, float first)
 848 {
 849         float fh;
 850         string s;
 851         var .string field;
 852         fh = fopen(f, FILE_READ);
 853         if(fh < 0)
 854                 return;
 855         while((s = fgets(fh)))
 856         {
 857                 if(tokenize(s) != 3)
 858                         continue;
 859                 field = GetPlayerSoundSampleField(argv(0));
 860                 if(GetPlayerSoundSampleField_notFound)
 861                         field = GetVoiceMessageSampleField(argv(0));
 862                 if(GetPlayerSoundSampleField_notFound)
 863                         continue;
 864                 if(GetPlayerSoundSampleField_fixed)
 865                         if not(first)
 866                                 continue;
 867                 if(self.field)
 868                         strunzone(self.field);
 869                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 870         }
 871         fclose(fh);
 872 }
 873
 874 .float modelindex_for_playersound;
 875 void UpdatePlayerSounds()
 876 {
 877         if(self.modelindex == self.modelindex_for_playersound)
 878                 return;
 879         self.modelindex_for_playersound = self.modelindex;
 880         ClearPlayerSounds();
 881         LoadPlayerSounds("sound/player/default.sounds", 1);
 882         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
 883 }
 884
 885 void GlobalSound(string sample, float chan, float teamsay)
 886 {
 887         float n;
 888
 889         if(sample == "")
 890                 return;
 891
 892         tokenize(sample);
 893         n = stof(argv(1));
 894         if(n > 0)
 895                 sample = strcat(argv(0), ftos(ceil(random() * n)), ".wav"); // randomization
 896         else
 897                 sample = strcat(argv(0), ".wav"); // randomization
 898
 899         if(teamsay == 2) // only to last attacker
 900         {
 901                 if(teams_matter)
 902                         if(self.pusher)
 903                                 if(self.pusher.team == self.team)
 904                                 {
 905                                         msg_entity = self.pusher;
 906                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 907                                         msg_entity = self;
 908                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 909                                 }
 910         }
 911         else if(teamsay == 0) // to everyone
 912         {
 913                 // broadcast the sound, but it's directional
 914                 sound(self, chan, sample, VOL_BASE, ATTN_NORM);
 915         }
 916         else if(teamsay == 1) // to the same team
 917         {
 918                 if(teams_matter)
 919                 {
 920                         entity e;
 921                         FOR_EACH_REALCLIENT(e)
 922                                 if(!teams_matter || e.team == self.team)
 923                                 {
 924                                         msg_entity = e;
 925                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 926                                 }
 927                 }
 928                 else
 929                 {
 930                         sound(self, chan, sample, VOL_BASE, ATTN_NONE);
 931                 }
 932         }
 933 }
 934
 935 void PlayerSound(.string samplefield, float chan, float teamsay)
 936 {
 937         string sample;
 938         sample = self.samplefield;
 939         GlobalSound(sample, chan, teamsay);
 940 }
 941
 942 void VoiceMessage(string type)
 943 {
 944         var .string sample;
 945         var float teamsay;
 946         sample = GetVoiceMessageSampleField(type);
 947
 948         if(GetPlayerSoundSampleField_notFound)
 949         {
 950                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 951                 return;
 952         }
 953
 954         teamsay = GetVoiceMessageTeamsayType(type);
 955
 956         PlayerSound(sample, CHAN_VOICE, teamsay);
 957 }