data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= 2)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(g_runematch)
  57         {
  58                 if(self.runes & RUNE_SPEED)
  59                 {
  60                         if(self.runes & CURSE_SLOW)
  61                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  62                         else
  63                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  64                 }
  65                 else if(self.runes & CURSE_SLOW)
  66                 {
  67                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  68                 }
  69         }
  70
  71         if(g_minstagib && (self.items & IT_INVINCIBLE))
  72         {
  73                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  74         }
  75
  76         self.velocity_z = self.velocity_z + mjumpheight;
  77         self.oldvelocity_z = self.velocity_z;
  78
  79         self.flags = self.flags - FL_ONGROUND;
  80         self.flags = self.flags - FL_JUMPRELEASED;
  81
  82         if (self.crouch)
  83                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  84         else
  85                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  86
  87         if(g_jump_grunt)
  88                 PlayerSound(playersound_jump, CHAN_PLAYER, 0);
  89 }
  90
  91 void CheckWaterJump()
  92 {
  93         local vector start, end;
  94
  95 // check for a jump-out-of-water
  96         makevectors (self.angles);
  97         start = self.origin;
  98         start_z = start_z + 8;
  99         v_forward_z = 0;
 100         normalize(v_forward);
 101         end = start + v_forward*24;
 102         traceline (start, end, TRUE, self);
 103         if (trace_fraction < 1)
 104         {       // solid at waist
 105                 start_z = start_z + self.maxs_z - 8;
 106                 end = start + v_forward*24;
 107                 self.movedir = trace_plane_normal * -50;
 108                 traceline (start, end, TRUE, self);
 109                 if (trace_fraction == 1)
 110                 {       // open at eye level
 111                         self.flags = self.flags | FL_WATERJUMP;
 112                         self.velocity_z = 225;
 113                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 114                         self.teleport_time = time + 2;  // safety net
 115                         return;
 116                 }
 117         }
 118 };
 119
 120 .vector movement_old;
 121 .float buttons_old;
 122 .vector v_angle_old;
 123
 124 void Nixnex_GiveCurrentWeapon();
 125 void SV_PlayerPhysics()
 126 {
 127         local vector wishvel, wishdir, v;
 128         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 129         string temps;
 130
 131         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 132         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 133         {
 134                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 135                         self.parm_idlesince = time;
 136         }
 137         self.buttons_old = buttons;
 138         self.movement_old = self.movement;
 139         self.v_angle_old = self.v_angle;
 140
 141         if(time > self.shtest_next)
 142         {
 143                 if(self.shtest_next > 0)
 144                 {
 145                         // self.shtest_accumulator:
 146                         //   started at time - SHTEST_DELTA
 147                         //   should be at SHTEST_DELTA
 148                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 149                         if(shtest_score > SHTEST_THRESHOLD)
 150                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 151                         else if(cvar("developer_shtest"))
 152                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 153                 }
 154                 self.shtest_next = time + SHTEST_DELTA;
 155                 self.shtest_accumulator = 0;
 156         }
 157         self.shtest_accumulator += frametime;
 158
 159         if (clienttype(self) == CLIENTTYPE_BOT)
 160                 bot_think();
 161
 162         if (self.movetype == MOVETYPE_NONE)
 163                 return;
 164
 165         if (self.punchangle != '0 0 0')
 166         {
 167                 f = vlen(self.punchangle) - 10 * frametime;
 168                 if (f > 0)
 169                         self.punchangle = normalize(self.punchangle) * f;
 170                 else
 171                         self.punchangle = '0 0 0';
 172         }
 173
 174         if (self.punchvector != '0 0 0')
 175         {
 176                 f = vlen(self.punchvector) - 30 * frametime;
 177                 if (f > 0)
 178                         self.punchvector = normalize(self.punchvector) * f;
 179                 else
 180                         self.punchvector = '0 0 0';
 181         }
 182
 183         maxspd_mod = 1;
 184
 185         if(g_runematch)
 186         {
 187                 if(self.runes & RUNE_SPEED)
 188                 {
 189                         if(self.runes & CURSE_SLOW)
 190                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 191                         else
 192                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 193                 }
 194                 else if(self.runes & CURSE_SLOW)
 195                 {
 196                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 197                 }
 198         }
 199
 200         if(g_minstagib && (self.items & IT_INVINCIBLE))
 201         {
 202                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 203         }
 204
 205         swampspd_mod = 1;
 206         if(self.in_swamp) {
 207                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 208         }
 209
 210         if(self.flags & FL_NOTARGET)
 211         {
 212                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 213                 if(!self.spectatorspeed)
 214                         self.spectatorspeed = maxspd_mod;
 215                 if(self.impulse && self.impulse <= 19)
 216                 {
 217                         if(self.lastflags & FL_NOTARGET)
 218                         {
 219                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 220                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 221                                 else if(self.impulse == 11)
 222                                         self.spectatorspeed = maxspd_mod;
 223                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 224                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 225                                 else if(self.impulse >= 1 && self.impulse <= 9)
 226                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 227                         } // otherwise just clear
 228                         self.impulse = 0;
 229                 }
 230                 maxspd_mod = self.spectatorspeed;
 231         }
 232
 233         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 234
 235         if(self.speed != spd)
 236         {
 237                 self.speed = spd;
 238                 temps = ftos(spd);
 239                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 240                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 241                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 242                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 243
 244                 temps = ftos(sv_accelerate * maxspd_mod);
 245                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 246         }
 247
 248         // if dead, behave differently
 249         if (self.deadflag)
 250                 return;
 251
 252         if (!self.fixangle && self.movetype != MOVETYPE_PUSH)
 253         {
 254                 self.angles_x = 0;
 255                 self.angles_y = self.v_angle_y;
 256                 self.angles_z = 0;
 257         }
 258
 259         if(self.flags & FL_ONGROUND)
 260         if(self.wasFlying)
 261         {
 262                 self.wasFlying = 0;
 263
 264                 if(self.waterlevel < 2)
 265                 if(time >= self.ladder_time)
 266                 if not(self.hook)
 267                 {
 268                         self.nextstep = time + 0.3 + random() * 0.1;
 269                         trace_dphitq3surfaceflags = 0;
 270                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 271                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 272                         {
 273                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 274                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, 0);
 275                                 else
 276                                         GlobalSound(globalsound_fall, CHAN_PLAYER, 0);
 277                         }
 278                 }
 279         }
 280
 281         if(IsFlying(self))
 282                 self.wasFlying = 1;
 283
 284         if(self.classname == "player")
 285         {
 286                 if(sv_doublejump)
 287                 {
 288                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 289                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 290                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 291                                 self.flags = self.flags | FL_ONGROUND;
 292                 }
 293
 294                 if (self.BUTTON_JUMP)
 295                         PlayerJump ();
 296                 else
 297                         self.flags = self.flags | FL_JUMPRELEASED;
 298
 299                 if (self.waterlevel == 2)
 300                         CheckWaterJump ();
 301         }
 302
 303         if (self.flags & FL_WATERJUMP )
 304         {
 305                 self.velocity_x = self.movedir_x;
 306                 self.velocity_y = self.movedir_y;
 307                 if (time > self.teleport_time || self.waterlevel == 0)
 308                 {
 309                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 310                         self.teleport_time = 0;
 311                 }
 312         }
 313         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 314         {
 315                 // noclipping or flying
 316                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 317
 318                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 319                 makevectors(self.v_angle);
 320                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 321                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 322                 // acceleration
 323                 wishdir = normalize(wishvel);
 324                 wishspeed = vlen(wishvel);
 325                 if (wishspeed > sv_maxspeed*maxspd_mod)
 326                         wishspeed = sv_maxspeed*maxspd_mod;
 327                 if (time >= self.teleport_time)
 328                 {
 329                         f = wishspeed - (self.velocity * wishdir);
 330                         if (f > 0)
 331                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 332                 }
 333         }
 334         else if (self.movetype == MOVETYPE_PUSH)
 335         {
 336                 // using this move type for "big rigs"
 337                 // the engine does not push the entity!
 338
 339                 float accel, steer, myspeed, steerfactor, accelfactor, upspeed, friction;
 340                 vector neworigin, up, angles_save;
 341
 342                 accel = self.movement_x / sv_maxspeed;
 343                 steer = self.movement_y / sv_maxspeed;
 344
 345                 angles_save = self.angles;
 346                 self.angles_x = 0;
 347                 self.angles_z = 0;
 348                 makevectors(self.angles); // new forward direction!
 349                 myspeed = self.velocity * v_forward;
 350                 upspeed = self.velocity * v_up;
 351                 if(myspeed <= 0 && accel < 0)
 352                         steerfactor = -5000; // LOL
 353                 else
 354                         steerfactor = -400 * 400 / (400 + myspeed);
 355                 accelfactor = 2000 * 400 / (400 + max(myspeed, -myspeed));
 356                 friction = 5 * 100 / (100 + max(myspeed, -myspeed));
 357
 358                 self.angles_y += steer * frametime * steerfactor; // apply steering
 359                 makevectors(self.angles); // new forward direction!
 360
 361                 myspeed = myspeed * (1 - frametime * friction);
 362                 myspeed += accel * accelfactor * frametime;
 363                 if(myspeed < 0)
 364                         myspeed = 0;
 365
 366                 self.velocity = v_forward * myspeed;
 367                 upspeed -= frametime * sv_gravity;
 368
 369                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', MOVE_NORMAL, self);
 370                 up = trace_endpos - self.origin;
 371
 372                 // can we move?
 373                 neworigin = trace_endpos + self.velocity * frametime;
 374                 tracebox(trace_endpos, self.mins, self.maxs, neworigin, MOVE_NORMAL, self);
 375
 376                 // align to surface
 377                 tracebox(trace_endpos, self.mins, self.maxs, neworigin - up + '0 0 1' * upspeed * frametime, MOVE_NORMAL, self);
 378
 379                 if(trace_fraction >= 0.5)
 380                         self.origin = trace_endpos;
 381                 else
 382                         trace_fraction = 1;
 383
 384                 // now set angles_x so that the car points parallel to the surface
 385                 if(trace_fraction < 1)
 386                 {
 387                         self.angles = vectoangles(normalize(
 388                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 389                                 +
 390                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 391                                 +
 392                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 393                         ));
 394                         self.flags |= FL_ONGROUND;
 395                 }
 396                 else
 397                 {
 398                         self.angles_x = angles_save_x;
 399                         self.angles_z = angles_save_z;
 400                         self.velocity += '0 0 1' * upspeed;
 401                         self.flags (-) FL_ONGROUND;
 402                 }
 403
 404                 // relink
 405                 setorigin(self, self.origin);
 406         }
 407         else if (self.waterlevel >= 2)
 408         {
 409                 // swimming
 410                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 411
 412                 makevectors(self.v_angle);
 413                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 414                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 415                 if (wishvel == '0 0 0')
 416                         wishvel = '0 0 -60'; // drift towards bottom
 417
 418                 wishdir = normalize(wishvel);
 419                 wishspeed = vlen(wishvel);
 420                 if (wishspeed > sv_maxspeed*maxspd_mod)
 421                         wishspeed = sv_maxspeed*maxspd_mod;
 422                 wishspeed = wishspeed * 0.7;
 423
 424                 // water friction
 425                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 426
 427                 // water acceleration
 428                 f = wishspeed - (self.velocity * wishdir);
 429                 if (f > 0)
 430                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 431         }
 432         else if (time < self.ladder_time)
 433         {
 434                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 435                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 436
 437                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 438                 makevectors(self.v_angle);
 439                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 440                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 441                 if (self.gravity)
 442                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 443                 else
 444                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 445                 if (self.ladder_entity.classname == "func_water")
 446                 {
 447                         f = vlen(wishvel);
 448                         if (f > self.ladder_entity.speed)
 449                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 450
 451                         self.watertype = self.ladder_entity.skin;
 452                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 453                         if ((self.origin_z + self.view_ofs_z) < f)
 454                                 self.waterlevel = 3;
 455                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 456                                 self.waterlevel = 2;
 457                         else if ((self.origin_z + self.mins_z + 1) < f)
 458                                 self.waterlevel = 1;
 459                         else
 460                         {
 461                                 self.waterlevel = 0;
 462                                 self.watertype = CONTENT_EMPTY;
 463                         }
 464                 }
 465                 // acceleration
 466                 wishdir = normalize(wishvel);
 467                 wishspeed = vlen(wishvel);
 468                 if (wishspeed > sv_maxspeed)
 469                         wishspeed = sv_maxspeed;
 470                 if (time >= self.teleport_time)
 471                 {
 472                         f = wishspeed - (self.velocity * wishdir);
 473                         if (f > 0)
 474                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 475                 }
 476         }
 477         else if (self.flags & FL_ONGROUND)
 478         {
 479                 // walking
 480                 makevectors(self.v_angle_y * '0 1 0');
 481                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 482
 483                 if(!(self.lastflags & FL_ONGROUND))
 484                 {
 485                         if(cvar("speedmeter"))
 486                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 487                         if(self.lastground < time - 0.3)
 488                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 489                         if(self.jumppadcount > 1)
 490                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 491                         self.jumppadcount = 0;
 492                 }
 493
 494                 if (self.velocity_x || self.velocity_y)
 495                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 496                 {
 497                         v = self.velocity;
 498                         v_z = 0;
 499                         f = vlen(v);
 500                         if (f < sv_stopspeed)
 501                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 502                         else
 503                                 f = 1 - frametime * sv_friction;
 504                         if (f > 0)
 505                                 self.velocity = self.velocity * f;
 506                         else
 507                                 self.velocity = '0 0 0';
 508                 }
 509                 // acceleration
 510                 wishdir = normalize(wishvel);
 511                 wishspeed = vlen(wishvel);
 512                 if (wishspeed > sv_maxspeed*maxspd_mod)
 513                         wishspeed = sv_maxspeed*maxspd_mod;
 514                 if (self.crouch)
 515                         wishspeed = wishspeed * 0.5;
 516                 if (time >= self.teleport_time)
 517                 {
 518                         f = wishspeed - (self.velocity * wishdir);
 519                         if (f > 0)
 520                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 521                 }
 522         }
 523         else
 524         {
 525                 if(maxspd_mod < 1)
 526                 {
 527                         maxairspd = sv_maxairspeed*maxspd_mod;
 528                         airaccel = sv_airaccelerate*maxspd_mod;
 529                 }
 530                 else
 531                 {
 532                         maxairspd = sv_maxairspeed;
 533                         airaccel = sv_airaccelerate;
 534                 }
 535                 // airborn
 536                 makevectors(self.v_angle_y * '0 1 0');
 537                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 538                 // acceleration
 539                 wishdir = normalize(wishvel);
 540                 wishspeed = vlen(wishvel);
 541                 if (wishspeed > maxairspd)
 542                         wishspeed = maxairspd;
 543                 if (self.crouch)
 544                         wishspeed = wishspeed * 0.5;
 545                 if (time >= self.teleport_time)
 546                 {
 547                         // NOTE: this does the same as the commented out old code if:
 548                         //   sv_airaccel_qw 0
 549                         //   sv_airaccel_sideways_friction 0
 550
 551                         float vel_straight;
 552                         float vel_z;
 553                         vector vel_perpend;
 554                         vel_straight = self.velocity * wishdir;
 555                         vel_z = self.velocity_z;
 556                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 557
 558                         f = wishspeed - vel_straight;
 559                         if(f > 0)
 560                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 561                         if(wishspeed > 0)
 562                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 563
 564                         // anti-sideways friction to fix QW-style bunnyhopping
 565                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 566
 567                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 568
 569                         /*
 570                         f = wishspeed;// - (self.velocity * wishdir);
 571                         if (f > 0)
 572                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 573                         */
 574                 }
 575         }
 576
 577         if(self.flags & FL_ONGROUND)
 578                 self.lastground = time;
 579
 580         self.lastflags = self.flags;
 581 };