data/qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2
   3 float sv_accelerate;
   4 float sv_friction;
   5 float sv_maxspeed;
   6 float sv_airaccelerate;
   7 float sv_maxairspeed;
   8 float sv_stopspeed;
   9 float sv_gravity;
  10 float sv_airaccel_sideways_friction;
  11 float sv_airaccel_qw;
  12 float sv_airstopaccelerate;
  13 float sv_airstrafeaccelerate;
  14 float sv_maxairstrafespeed;
  15 float sv_aircontrol;
  16 float sv_warsowbunny_airforwardaccel;
  17 float sv_warsowbunny_accel;
  18 float sv_warsowbunny_topspeed;
  19 float sv_warsowbunny_turnaccel;
  20 float sv_warsowbunny_backtosideratio;
  21
  22 .float ladder_time;
  23 .entity ladder_entity;
  24 .float gravity;
  25 .float swamp_slowdown;
  26 .float lastflags;
  27 .float lastground;
  28 .float wasFlying;
  29 .float spectatorspeed;
  30
  31 #define SHTEST_DELTA 10
  32 #define SHTEST_THRESHOLD 1.1
  33 .float shtest_next;
  34 .float shtest_accumulator;
  35 .float doublejump_nextjumptime;
  36
  37 /*
  38 =============
  39 PlayerJump
  40
  41 When you press the jump key
  42 =============
  43 */
  44 void PlayerJump (void)
  45 {
  46         float mjumpheight;
  47
  48         mjumpheight = cvar("sv_jumpvelocity");
  49         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  50         {
  51                 if (self.watertype == CONTENT_WATER)
  52                         self.velocity_z = 200;
  53                 else if (self.watertype == CONTENT_SLIME)
  54                         self.velocity_z = 80;
  55                 else
  56                         self.velocity_z = 50;
  57
  58                 return;
  59         }
  60
  61         if (!(self.flags & FL_ONGROUND))
  62                 return;
  63
  64         if(!sv_pogostick)
  65                 if (!(self.flags & FL_JUMPRELEASED))
  66                         return;
  67
  68         if(self.health <= g_bloodloss)
  69                 return;
  70
  71         if(sv_doublejump)
  72                 if(time < self.doublejump_nextjumptime)
  73                         return;
  74
  75         if(g_runematch)
  76         {
  77                 if(self.runes & RUNE_SPEED)
  78                 {
  79                         if(self.runes & CURSE_SLOW)
  80                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  81                         else
  82                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  83                 }
  84                 else if(self.runes & CURSE_SLOW)
  85                 {
  86                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  87                 }
  88         }
  89
  90         if(g_minstagib && (self.items & IT_INVINCIBLE))
  91         {
  92                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  93         }
  94
  95         if(!(self.lastflags & FL_ONGROUND))
  96         {
  97                 if(cvar("speedmeter"))
  98                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
  99                 if(self.lastground < time - 0.3)
 100                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 101                 if(self.jumppadcount > 1)
 102                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 103                 self.jumppadcount = 0;
 104         }
 105
 106         self.velocity_z = self.velocity_z + mjumpheight;
 107         self.oldvelocity_z = self.velocity_z;
 108
 109         self.flags &~= FL_ONGROUND;
 110         self.flags &~= FL_JUMPRELEASED;
 111
 112         if (self.crouch)
 113                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 114         else
 115                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 116
 117         if(g_jump_grunt)
 118                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 119
 120         if(sv_doublejump)
 121         {
 122                 // we're moving upwards at self.velocity_z
 123                 // only allow jumping after we got 3 units upwards
 124                 // so we for sure leave the FL_ONGROUND check
 125                 //
 126                 // but as this sucks because of factoring in gravity, we'll just do it
 127                 // for 4 units, and constant velocity
 128                 self.doublejump_nextjumptime = time + 4 / max(40, self.velocity_z); // max 0.1s blocking of jumps
 129         }
 130 }
 131
 132 void CheckWaterJump()
 133 {
 134         local vector start, end;
 135
 136 // check for a jump-out-of-water
 137         makevectors (self.angles);
 138         start = self.origin;
 139         start_z = start_z + 8;
 140         v_forward_z = 0;
 141         normalize(v_forward);
 142         end = start + v_forward*24;
 143         traceline (start, end, TRUE, self);
 144         if (trace_fraction < 1)
 145         {       // solid at waist
 146                 start_z = start_z + self.maxs_z - 8;
 147                 end = start + v_forward*24;
 148                 self.movedir = trace_plane_normal * -50;
 149                 traceline (start, end, TRUE, self);
 150                 if (trace_fraction == 1)
 151                 {       // open at eye level
 152                         self.flags |= FL_WATERJUMP;
 153                         self.velocity_z = 225;
 154                         self.flags &~= FL_JUMPRELEASED;
 155                         self.teleport_time = time + 2;  // safety net
 156                         return;
 157                 }
 158         }
 159 };
 160
 161 float racecar_angle(float forward, float down)
 162 {
 163         float ret, angle_mult;
 164
 165         if(forward < 0)
 166         {
 167                 forward = -forward;
 168                 down = -down;
 169         }
 170
 171         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 172
 173         angle_mult = forward / (800 + forward);
 174
 175         if(ret > 180)
 176                 return ret * angle_mult + 360 * (1 - angle_mult);
 177         else
 178                 return ret * angle_mult;
 179 }
 180
 181 void RaceCarPhysics()
 182 {
 183         // using this move type for "big rigs"
 184         // the engine does not push the entity!
 185
 186         float accel, steer, f;
 187         vector angles_save, rigvel;
 188
 189         angles_save = self.angles;
 190         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 191         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 192
 193         if(g_bugrigs_reverse_speeding)
 194         {
 195                 if(accel < 0)
 196                 {
 197                         // back accel is DIGITAL
 198                         // to prevent speedhack
 199                         if(accel < -0.5)
 200                                 accel = -1;
 201                         else
 202                                 accel = 0;
 203                 }
 204         }
 205
 206         self.angles_x = 0;
 207         self.angles_z = 0;
 208         makevectors(self.angles); // new forward direction!
 209
 210         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 211         {
 212                 float myspeed, upspeed, steerfactor, accelfactor;
 213
 214                 myspeed = self.velocity * v_forward;
 215                 upspeed = self.velocity * v_up;
 216
 217                 // responsiveness factor for steering and acceleration
 218                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 219                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 220
 221                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 222                         steerfactor = -myspeed * g_bugrigs_steer;
 223                 else
 224                         steerfactor = -myspeed * f * g_bugrigs_steer;
 225
 226                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 227                         accelfactor = g_bugrigs_accel;
 228                 else
 229                         accelfactor = f * g_bugrigs_accel;
 230                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 231
 232                 if(accel < 0)
 233                 {
 234                         if(myspeed > 0)
 235                         {
 236                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 237                         }
 238                         else
 239                         {
 240                                 if(!g_bugrigs_reverse_speeding)
 241                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 242                         }
 243                 }
 244                 else
 245                 {
 246                         if(myspeed >= 0)
 247                         {
 248                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 249                         }
 250                         else
 251                         {
 252                                 if(g_bugrigs_reverse_stopping)
 253                                         myspeed = 0;
 254                                 else
 255                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 256                         }
 257                 }
 258                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 259                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 260
 261                 self.angles_y += steer * frametime * steerfactor; // apply steering
 262                 makevectors(self.angles); // new forward direction!
 263
 264                 myspeed += accel * accelfactor * frametime;
 265
 266                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 267         }
 268         else
 269         {
 270                 myspeed = vlen(self.velocity);
 271
 272                 // responsiveness factor for steering and acceleration
 273                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 274                 steerfactor = -myspeed * f;
 275                 self.angles_y += steer * frametime * steerfactor; // apply steering
 276
 277                 rigvel = self.velocity;
 278                 makevectors(self.angles); // new forward direction!
 279         }
 280
 281         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 282         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 283         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 284         //MAXIMA: solve(total_acceleration(v) = 0, v);
 285
 286         if(g_bugrigs_planar_movement)
 287         {
 288                 vector rigvel_xy, neworigin, up;
 289                 float mt;
 290
 291                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 292                 rigvel_xy = rigvel;
 293                 rigvel_xy_z = 0;
 294
 295                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 296                         mt = MOVE_NORMAL;
 297                 else
 298                         mt = MOVE_NOMONSTERS;
 299
 300                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 301                 up = trace_endpos - self.origin;
 302
 303                 // BUG RIGS: align the move to the surface instead of doing collision testing
 304                 // can we move?
 305                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 306
 307                 // align to surface
 308                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 309
 310                 if(trace_fraction < 0.5)
 311                 {
 312                         trace_fraction = 1;
 313                         neworigin = self.origin;
 314                 }
 315                 else
 316                         neworigin = trace_endpos;
 317
 318                 if(trace_fraction < 1)
 319                 {
 320                         // now set angles_x so that the car points parallel to the surface
 321                         self.angles = vectoangles(
 322                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 323                                         +
 324                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 325                                         +
 326                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 327                                         );
 328                         self.flags |= FL_ONGROUND;
 329                 }
 330                 else
 331                 {
 332                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 333                         self.flags &~= FL_ONGROUND;
 334                 }
 335
 336                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 337                 self.movetype = MOVETYPE_NOCLIP;
 338         }
 339         else
 340         {
 341                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 342                 self.velocity = rigvel;
 343                 self.movetype = MOVETYPE_FLY;
 344         }
 345
 346         trace_fraction = 1;
 347         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 348         if(trace_fraction != 1)
 349         {
 350                 self.angles = vectoangles2(
 351                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 352                                 +
 353                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 354                                 +
 355                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 356                                 trace_plane_normal
 357                                 );
 358         }
 359         else
 360         {
 361                 vector vel_local;
 362
 363                 vel_local_x = v_forward * self.velocity;
 364                 vel_local_y = v_right * self.velocity;
 365                 vel_local_z = v_up * self.velocity;
 366
 367                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 368                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 369         }
 370
 371         // smooth the angles
 372         vector vf1, vu1, smoothangles;
 373         makevectors(self.angles);
 374         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 375         if(f == 0)
 376                 f = 1;
 377         vf1 = v_forward * f;
 378         vu1 = v_up * f;
 379         makevectors(angles_save);
 380         vf1 = vf1 + v_forward * (1 - f);
 381         vu1 = vu1 + v_up * (1 - f);
 382         smoothangles = vectoangles2(vf1, vu1);
 383         self.angles_x = -smoothangles_x;
 384         self.angles_z =  smoothangles_z;
 385 }
 386
 387 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 388 {
 389         float zspeed, xyspeed, dot, k;
 390
 391         if(self.movement_x == 0 || self.movement_y != 0)
 392                 return; // can't control movement if not moving forward or backward
 393
 394         zspeed = self.velocity_z;
 395         self.velocity_z = 0;
 396         xyspeed = vlen(self.velocity);
 397         self.velocity = normalize(self.velocity);
 398
 399         dot = self.velocity * wishdir;
 400         k = 32;
 401         k *= sv_aircontrol*dot*dot*frametime;
 402
 403         if(dot > 0) // we can't change direction while slowing down
 404                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 405
 406         self.velocity = self.velocity * xyspeed;
 407         self.velocity_z = zspeed;
 408 }
 409
 410 void PM_Accelerate(vector wishdir, float wishspeed, float accel, float accelqw, float sidefric)
 411 {
 412         float vel_straight;
 413         float vel_z;
 414         vector vel_perpend;
 415         float addspeed;
 416
 417         vel_straight = self.velocity * wishdir;
 418         vel_z = self.velocity_z;
 419         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 420
 421         addspeed = wishspeed - vel_straight;
 422         if(addspeed > 0)
 423                 vel_straight = vel_straight + min(addspeed, accel * frametime * wishspeed) * accelqw;
 424         if(wishspeed > 0)
 425                 vel_straight = vel_straight + min(wishspeed, accel * frametime * wishspeed) * (1 - accelqw);
 426
 427         vel_perpend = vel_perpend * (1 - frametime * wishspeed * sidefric);
 428
 429         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 430 }
 431
 432 void PM_AirAccelerate(vector wishdir, float wishspeed)
 433 {
 434         vector curvel, wishvel, acceldir, curdir;
 435         float addspeed, accelspeed, curspeed, f;
 436         float dot;
 437
 438         if(wishspeed == 0)
 439                 return;
 440
 441         curvel = self.velocity;
 442         curvel_z = 0;
 443         curspeed = vlen(curvel);
 444
 445         if(wishspeed > curspeed * 1.01)
 446         {
 447                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * sv_maxspeed * frametime);
 448         }
 449         else
 450         {
 451                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - sv_maxspeed));
 452                 wishspeed = max(curspeed, sv_maxspeed) + sv_warsowbunny_accel * f * sv_maxspeed * frametime;
 453         }
 454         wishvel = wishdir * wishspeed;
 455         acceldir = wishvel - curvel;
 456         addspeed = vlen(acceldir);
 457         acceldir = normalize(acceldir);
 458
 459         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * sv_maxspeed * frametime);
 460
 461         if(sv_warsowbunny_backtosideratio < 1)
 462         {
 463                 curdir = normalize(curvel);
 464                 dot = acceldir * curdir;
 465                 if(dot < 0)
 466                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 467         }
 468
 469         self.velocity += accelspeed * acceldir;
 470 }
 471
 472 .vector movement_old;
 473 .float buttons_old;
 474 .vector v_angle_old;
 475 .string lastclassname;
 476
 477 void Nixnex_GiveCurrentWeapon();
 478 .float() PlayerPhysplug;
 479
 480 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 481 .float specialcommand_pos;
 482 void SpecialCommand()
 483 {
 484 #ifdef TETRIS
 485         TetrisImpulse();
 486 #else
 487         if(sv_cheats || self.maycheat)
 488                 self.impulse = 99;
 489         else
 490                 print("A hollow voice says \"Plugh\".\n");
 491 #endif
 492 }
 493
 494 void SV_PlayerPhysics()
 495 {
 496         local vector wishvel, wishdir, v;
 497         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 498         string temps;
 499         float buttons_prev;
 500         float not_allowed_to_move;
 501         string c;
 502
 503         if(g_race || g_cts)
 504         {
 505                 // if record times matter
 506                 // ensure nothing EVIL is being done (i.e. strafebot)
 507                 // this hinders joystick users though
 508                 // but it still gives SOME analog control
 509                 // TODO implement this for engine cl_movement code too (basically, clipping to the four axes)
 510                 wishvel_x = fabs(self.movement_x);
 511                 wishvel_y = fabs(self.movement_y);
 512                 wishvel_z = 0;
 513                 wishspeed = vlen(wishvel);
 514                 if(wishvel_x >= 2 * wishvel_y)
 515                 {
 516                         // pure X motion
 517                         if(self.movement_x > 0)
 518                                 self.movement_x = wishspeed;
 519                         else
 520                                 self.movement_x = -wishspeed;
 521                         self.movement_y = 0;
 522                 }
 523                 else if(wishvel_y >= 2 * wishvel_x)
 524                 {
 525                         // pure Y motion
 526                         self.movement_x = 0;
 527                         if(self.movement_y > 0)
 528                                 self.movement_y = wishspeed;
 529                         else
 530                                 self.movement_y = -wishspeed;
 531                 }
 532                 else
 533                 {
 534                         // diagonal
 535                         if(self.movement_x > 0)
 536                                 self.movement_x = 0.70710678118654752440 * wishspeed;
 537                         else
 538                                 self.movement_x = -0.70710678118654752440 * wishspeed;
 539                         if(self.movement_y > 0)
 540                                 self.movement_y = 0.70710678118654752440 * wishspeed;
 541                         else
 542                                 self.movement_y = -0.70710678118654752440 * wishspeed;
 543                 }
 544         }
 545
 546         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 547
 548         if(!buttons)
 549                 c = "x";
 550         else if(buttons == 1)
 551                 c = "1";
 552         else if(buttons == 2)
 553                 c = " ";
 554         else if(buttons == 128)
 555                 c = "s";
 556         else if(buttons == 256)
 557                 c = "w";
 558         else if(buttons == 512)
 559                 c = "a";
 560         else if(buttons == 1024)
 561                 c = "d";
 562         else
 563                 c = "?";
 564
 565         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 566         {
 567                 self.specialcommand_pos += 1;
 568                 if(self.specialcommand_pos >= strlen(specialcommand))
 569                 {
 570                         self.specialcommand_pos = 0;
 571                         SpecialCommand();
 572                         return;
 573                 }
 574         }
 575         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 576                 self.specialcommand_pos = 0;
 577
 578     if(self.PlayerPhysplug)
 579         if(self.PlayerPhysplug())
 580             return;
 581
 582         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 583         {
 584                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 585                         self.parm_idlesince = time;
 586         }
 587         buttons_prev = self.buttons_old;
 588         self.buttons_old = buttons;
 589         self.movement_old = self.movement;
 590         self.v_angle_old = self.v_angle;
 591
 592         if(time < self.nickspamtime)
 593         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 594         {
 595                 // slight annoyance for nick change scripts
 596                 self.movement = -1 * self.movement;
 597                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 598
 599                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 600                 {
 601                         self.angles_x = random() * 360;
 602                         self.angles_y = random() * 360;
 603                         // at least I'm not forcing retardedview by also assigning to angles_z
 604                         self.fixangle = 1;
 605                 }
 606         }
 607
 608         if(time > self.shtest_next)
 609         {
 610                 if(self.shtest_next > 0)
 611                 {
 612                         // self.shtest_accumulator:
 613                         //   started at time - SHTEST_DELTA
 614                         //   should be at SHTEST_DELTA
 615                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 616                         if(shtest_score > SHTEST_THRESHOLD)
 617                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 618                         else if(cvar("developer_shtest"))
 619                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 620                 }
 621                 self.shtest_next = time + SHTEST_DELTA;
 622                 self.shtest_accumulator = 0;
 623         }
 624         self.shtest_accumulator += frametime;
 625
 626         if (clienttype(self) == CLIENTTYPE_BOT)
 627                 bot_think();
 628
 629         self.items &~= IT_USING_JETPACK;
 630
 631         if(self.classname == "player")
 632         {
 633                 if(self.race_penalty)
 634                         if(time > self.race_penalty)
 635                                 self.race_penalty = 0;
 636
 637                 not_allowed_to_move = 0;
 638                 if(self.race_penalty)
 639                         not_allowed_to_move = 1;
 640                 if(!cvar("sv_ready_restart_after_countdown"))
 641                 if(time < game_starttime)
 642                         not_allowed_to_move = 1;
 643
 644                 if(not_allowed_to_move)
 645                 {
 646                         self.velocity = '0 0 0';
 647                         self.movetype = MOVETYPE_NONE;
 648                         self.disableclientprediction = 2;
 649                 }
 650                 else if(self.disableclientprediction == 2)
 651                 {
 652                         if(self.movetype == MOVETYPE_NONE)
 653                                 self.movetype = MOVETYPE_WALK;
 654                         self.disableclientprediction = 0;
 655                 }
 656         }
 657
 658         if (self.movetype == MOVETYPE_NONE)
 659                 return;
 660
 661         if (self.punchangle != '0 0 0')
 662         {
 663                 f = vlen(self.punchangle) - 10 * frametime;
 664                 if (f > 0)
 665                         self.punchangle = normalize(self.punchangle) * f;
 666                 else
 667                         self.punchangle = '0 0 0';
 668         }
 669
 670         if (self.punchvector != '0 0 0')
 671         {
 672                 f = vlen(self.punchvector) - 30 * frametime;
 673                 if (f > 0)
 674                         self.punchvector = normalize(self.punchvector) * f;
 675                 else
 676                         self.punchvector = '0 0 0';
 677         }
 678
 679         maxspd_mod = 1;
 680
 681         if(g_runematch)
 682         {
 683                 if(self.runes & RUNE_SPEED)
 684                 {
 685                         if(self.runes & CURSE_SLOW)
 686                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 687                         else
 688                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 689                 }
 690                 else if(self.runes & CURSE_SLOW)
 691                 {
 692                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 693                 }
 694         }
 695
 696         if(g_minstagib && (self.items & IT_INVINCIBLE))
 697         {
 698                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 699         }
 700
 701         if(g_nexball && self.ballcarried)
 702         {
 703                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 704         }
 705
 706         swampspd_mod = 1;
 707         if(self.in_swamp) {
 708                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 709         }
 710
 711         if(self.classname != "player")
 712         {
 713                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 714                 if(!self.spectatorspeed)
 715                         self.spectatorspeed = maxspd_mod;
 716                 if(self.impulse && self.impulse <= 19)
 717                 {
 718                         if(self.lastclassname != "player")
 719                         {
 720                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 721                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 722                                 else if(self.impulse == 11)
 723                                         self.spectatorspeed = maxspd_mod;
 724                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 725                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 726                                 else if(self.impulse >= 1 && self.impulse <= 9)
 727                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 728                         } // otherwise just clear
 729                         self.impulse = 0;
 730                 }
 731                 maxspd_mod = self.spectatorspeed;
 732         }
 733
 734         spd = max(sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 735         if(self.speed != spd)
 736         {
 737                 self.speed = spd;
 738                 temps = ftos(spd);
 739                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 740                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 741                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 742                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 743         }
 744
 745         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 746         swampspd_mod = 1;
 747
 748         // if dead, behave differently
 749         if (self.deadflag)
 750                 goto end;
 751
 752         if (!self.fixangle && !g_bugrigs)
 753         {
 754                 self.angles_x = 0;
 755                 self.angles_y = self.v_angle_y;
 756                 self.angles_z = 0;
 757         }
 758
 759         if(self.flags & FL_ONGROUND)
 760         if(self.wasFlying)
 761         {
 762                 self.wasFlying = 0;
 763
 764                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 765                 if(time >= self.ladder_time)
 766                 if not(self.hook)
 767                 {
 768                         self.nextstep = time + 0.3 + random() * 0.1;
 769                         trace_dphitq3surfaceflags = 0;
 770                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 771                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 772                         {
 773                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 774                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 775                                 else
 776                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 777                         }
 778                 }
 779         }
 780
 781         if(IsFlying(self))
 782                 self.wasFlying = 1;
 783
 784         if(self.classname == "player")
 785         {
 786                 if(sv_doublejump)
 787                 {
 788                         self.flags &~= FL_ONGROUND;
 789                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 1', MOVE_NORMAL, self);
 790                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 791                                 self.flags |= FL_ONGROUND;
 792                 }
 793
 794                 if (self.BUTTON_JUMP)
 795                         PlayerJump ();
 796                 else
 797                         self.flags |= FL_JUMPRELEASED;
 798
 799                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 800                         CheckWaterJump ();
 801         }
 802
 803         if (self.flags & FL_WATERJUMP )
 804         {
 805                 self.velocity_x = self.movedir_x;
 806                 self.velocity_y = self.movedir_y;
 807                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 808                 {
 809                         self.flags &~= FL_WATERJUMP;
 810                         self.teleport_time = 0;
 811                 }
 812         }
 813         else if (g_bugrigs && self.classname == "player")
 814         {
 815                 RaceCarPhysics();
 816         }
 817         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 818         {
 819                 // noclipping or flying
 820                 self.flags &~= FL_ONGROUND;
 821
 822                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 823                 makevectors(self.v_angle);
 824                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 825                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 826                 // acceleration
 827                 wishdir = normalize(wishvel);
 828                 wishspeed = vlen(wishvel);
 829                 if (wishspeed > sv_maxspeed*maxspd_mod)
 830                         wishspeed = sv_maxspeed*maxspd_mod;
 831                 if (time >= self.teleport_time)
 832                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 833         }
 834         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 835         {
 836                 // swimming
 837                 self.flags &~= FL_ONGROUND;
 838
 839                 makevectors(self.v_angle);
 840                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 841                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 842                 if (wishvel == '0 0 0')
 843                         wishvel = '0 0 -60'; // drift towards bottom
 844
 845                 wishdir = normalize(wishvel);
 846                 wishspeed = vlen(wishvel);
 847                 if (wishspeed > sv_maxspeed*maxspd_mod)
 848                         wishspeed = sv_maxspeed*maxspd_mod;
 849                 wishspeed = wishspeed * 0.7;
 850
 851                 // water friction
 852                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 853
 854                 // water acceleration
 855                 PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 856         }
 857         else if (time < self.ladder_time)
 858         {
 859                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 860                 self.flags &~= FL_ONGROUND;
 861
 862                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 863                 makevectors(self.v_angle);
 864                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 865                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 866                 if (self.gravity)
 867                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 868                 else
 869                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 870                 if (self.ladder_entity.classname == "func_water")
 871                 {
 872                         f = vlen(wishvel);
 873                         if (f > self.ladder_entity.speed)
 874                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 875
 876                         self.watertype = self.ladder_entity.skin;
 877                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 878                         if ((self.origin_z + self.view_ofs_z) < f)
 879                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 880                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 881                                 self.waterlevel = WATERLEVEL_SWIMMING;
 882                         else if ((self.origin_z + self.mins_z + 1) < f)
 883                                 self.waterlevel = WATERLEVEL_WETFEET;
 884                         else
 885                         {
 886                                 self.waterlevel = WATERLEVEL_NONE;
 887                                 self.watertype = CONTENT_EMPTY;
 888                         }
 889                 }
 890                 // acceleration
 891                 wishdir = normalize(wishvel);
 892                 wishspeed = vlen(wishvel);
 893                 if (wishspeed > sv_maxspeed*maxspd_mod)
 894                         wishspeed = sv_maxspeed*maxspd_mod;
 895                 if (time >= self.teleport_time)
 896                 {
 897                         // water acceleration
 898                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 899                 }
 900         }
 901         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 902         {
 903                 //makevectors(self.v_angle_y * '0 1 0');
 904                 makevectors(self.v_angle);
 905                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 906                 // add remaining speed as Z component
 907                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 908                 // fix speedhacks :P
 909                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 910                 // add the unused velocity as up component
 911                 wishvel_z = 0;
 912
 913                 // if(self.BUTTON_JUMP)
 914                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 915
 916                 // it is now normalized, so...
 917                 float a_side, a_up, a_add, a_diff;
 918                 a_side = cvar("g_jetpack_acceleration_side");
 919                 a_up = cvar("g_jetpack_acceleration_up");
 920                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 921
 922                 wishvel_x *= a_side;
 923                 wishvel_y *= a_side;
 924                 wishvel_z *= a_up;
 925                 wishvel_z += a_add;
 926
 927                 float best;
 928                 best = 0;
 929                 //////////////////////////////////////////////////////////////////////////////////////
 930                 // finding the maximum over all vectors of above form
 931                 // with wishvel having an absolute value of 1
 932                 //////////////////////////////////////////////////////////////////////////////////////
 933                 // we're finding the maximum over
 934                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 935                 // for z in the range from -1 to 1
 936                 //////////////////////////////////////////////////////////////////////////////////////
 937                 // maximum is EITHER attained at the single extreme point:
 938                 a_diff = a_side * a_side - a_up * a_up;
 939                 if(a_diff != 0)
 940                 {
 941                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 942                         if(f > -1 && f < 1) // can it be attained?
 943                         {
 944                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 945                                 //print("middle\n");
 946                         }
 947                 }
 948                 // OR attained at z = 1:
 949                 f = (a_up + a_add) * (a_up + a_add);
 950                 if(f > best)
 951                 {
 952                         best = f;
 953                         //print("top\n");
 954                 }
 955                 // OR attained at z = -1:
 956                 f = (a_up - a_add) * (a_up - a_add);
 957                 if(f > best)
 958                 {
 959                         best = f;
 960                         //print("bottom\n");
 961                 }
 962                 best = sqrt(best);
 963                 //////////////////////////////////////////////////////////////////////////////////////
 964
 965                 //print("best possible acceleration: ", ftos(best), "\n");
 966
 967                 float fxy, fz;
 968                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 969                 if(wishvel_z - sv_gravity > 0)
 970                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 971                 else
 972                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 973
 974                 float fvel;
 975                 fvel = vlen(wishvel);
 976                 wishvel_x *= fxy;
 977                 wishvel_y *= fxy;
 978                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 979
 980                 fvel = min(1, vlen(wishvel) / best);
 981                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
 982                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
 983                 else
 984                         f = 1;
 985
 986                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 987
 988                 if (f > 0 && wishvel != '0 0 0')
 989                 {
 990                         self.velocity = self.velocity + wishvel * f * frametime;
 991                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 992                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
 993                         self.flags &~= FL_ONGROUND;
 994                         self.items |= IT_USING_JETPACK;
 995
 996                         // jetpack also inhibits health regeneration, but only for 1 second
 997                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
 998                 }
 999         }
1000         else if (self.flags & FL_ONGROUND)
1001         {
1002                 // we get here if we ran out of ammo
1003                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1004                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1005
1006                 // walking
1007                 makevectors(self.v_angle_y * '0 1 0');
1008                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1009
1010                 if(!(self.lastflags & FL_ONGROUND))
1011                 {
1012                         if(cvar("speedmeter"))
1013                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1014                         if(self.lastground < time - 0.3)
1015                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1016                         if(self.jumppadcount > 1)
1017                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1018                         self.jumppadcount = 0;
1019                 }
1020
1021 #ifdef LETS_TEST_FTEQCC
1022                 if(self.velocity_x || self.velocity_y)
1023                 {
1024                         // good
1025                 }
1026                 else
1027                 {
1028                         if(self.velocity_x)
1029                                 checkclient();
1030                         if(self.velocity_y)
1031                                 checkclient();
1032                 }
1033 #endif
1034
1035                 v = self.velocity;
1036                 v_z = 0;
1037                 f = vlen(v);
1038                 if(f > 0)
1039                 {
1040                         if (f < sv_stopspeed)
1041                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1042                         else
1043                                 f = 1 - frametime * sv_friction;
1044                         if (f > 0)
1045                                 self.velocity = self.velocity * f;
1046                         else
1047                                 self.velocity = '0 0 0';
1048                 }
1049
1050                 // acceleration
1051                 wishdir = normalize(wishvel);
1052                 wishspeed = vlen(wishvel);
1053                 if (wishspeed > sv_maxspeed*maxspd_mod)
1054                         wishspeed = sv_maxspeed*maxspd_mod;
1055                 if (self.crouch)
1056                         wishspeed = wishspeed * 0.5;
1057                 if (time >= self.teleport_time)
1058                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
1059         }
1060         else
1061         {
1062                 // we get here if we ran out of ammo
1063                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1064                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1065
1066                 if(maxspd_mod < 1)
1067                 {
1068                         maxairspd = sv_maxairspeed*maxspd_mod;
1069                         airaccel = sv_airaccelerate*maxspd_mod;
1070                 }
1071                 else
1072                 {
1073                         maxairspd = sv_maxairspeed;
1074                         airaccel = sv_airaccelerate;
1075                 }
1076                 // airborn
1077                 makevectors(self.v_angle_y * '0 1 0');
1078                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1079                 // acceleration
1080                 wishdir = normalize(wishvel);
1081                 wishspeed = vlen(wishvel);
1082                 if (wishspeed > maxairspd)
1083                         wishspeed = maxairspd;
1084                 if (self.crouch)
1085                         wishspeed = wishspeed * 0.5;
1086                 if (time >= self.teleport_time)
1087                 {
1088                         float accelerating;
1089                         float wishspeed2;
1090                         float airaccelqw;
1091
1092                         airaccelqw = sv_airaccel_qw;
1093                         accelerating = (self.velocity * wishdir > 0);
1094                         wishspeed2 = wishspeed;
1095
1096                         // CPM
1097                         if(sv_airstopaccelerate)
1098                                 if(self.velocity * wishdir < 0)
1099                                         airaccel = sv_airstopaccelerate*maxspd_mod;
1100                         if(self.movement_x == 0 && self.movement_y != 0)
1101                         {
1102                                 if(sv_maxairstrafespeed)
1103                                 {
1104                                         wishspeed = min(wishspeed, sv_maxairstrafespeed*maxspd_mod);
1105                                         if(sv_maxairstrafespeed < sv_maxairspeed)
1106                                                 airaccelqw = 1;
1107                                 }
1108                                 if(sv_airstrafeaccelerate)
1109                                 {
1110                                         airaccel = sv_airstrafeaccelerate*maxspd_mod;
1111                                         if(sv_airstrafeaccelerate > sv_airaccelerate)
1112                                                 airaccelqw = 1;
1113                                 }
1114                         }
1115                         // !CPM
1116
1117                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1118                                 PM_AirAccelerate(wishdir, wishspeed);
1119                         else
1120                                 PM_Accelerate(wishdir, wishspeed, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd);
1121
1122                         if(sv_aircontrol)
1123                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1124                 }
1125         }
1126
1127 :end
1128         if(self.flags & FL_ONGROUND)
1129                 self.lastground = time;
1130
1131         self.lastflags = self.flags;
1132         self.lastclassname = self.classname;
1133 };