data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= 2)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(g_runematch)
  57         {
  58                 if(self.runes & RUNE_SPEED)
  59                 {
  60                         if(self.runes & CURSE_SLOW)
  61                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  62                         else
  63                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  64                 }
  65                 else if(self.runes & CURSE_SLOW)
  66                 {
  67                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  68                 }
  69         }
  70
  71         if(g_minstagib && (self.items & IT_INVINCIBLE))
  72         {
  73                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  74         }
  75
  76         self.velocity_z = self.velocity_z + mjumpheight;
  77         self.oldvelocity_z = self.velocity_z;
  78
  79         self.flags = self.flags - FL_ONGROUND;
  80         self.flags = self.flags - FL_JUMPRELEASED;
  81
  82         if (self.crouch)
  83                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  84         else
  85                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  86
  87         if(g_jump_grunt)
  88                 PlayerSound(playersound_jump, CHAN_PLAYER, 0);
  89 }
  90
  91 void CheckWaterJump()
  92 {
  93         local vector start, end;
  94
  95 // check for a jump-out-of-water
  96         makevectors (self.angles);
  97         start = self.origin;
  98         start_z = start_z + 8;
  99         v_forward_z = 0;
 100         normalize(v_forward);
 101         end = start + v_forward*24;
 102         traceline (start, end, TRUE, self);
 103         if (trace_fraction < 1)
 104         {       // solid at waist
 105                 start_z = start_z + self.maxs_z - 8;
 106                 end = start + v_forward*24;
 107                 self.movedir = trace_plane_normal * -50;
 108                 traceline (start, end, TRUE, self);
 109                 if (trace_fraction == 1)
 110                 {       // open at eye level
 111                         self.flags = self.flags | FL_WATERJUMP;
 112                         self.velocity_z = 225;
 113                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 114                         self.teleport_time = time + 2;  // safety net
 115                         return;
 116                 }
 117         }
 118 };
 119
 120 .vector movement_old;
 121 .float buttons_old;
 122 .vector v_angle_old;
 123
 124 void Nixnex_GiveCurrentWeapon();
 125 void SV_PlayerPhysics()
 126 {
 127         local vector wishvel, wishdir, v;
 128         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 129         string temps;
 130
 131         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 132         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 133         {
 134                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 135                         self.parm_idlesince = time;
 136         }
 137         self.buttons_old = buttons;
 138         self.movement_old = self.movement;
 139         self.v_angle_old = self.v_angle;
 140
 141         if(time > self.shtest_next)
 142         {
 143                 if(self.shtest_next > 0)
 144                 {
 145                         // self.shtest_accumulator:
 146                         //   started at time - SHTEST_DELTA
 147                         //   should be at SHTEST_DELTA
 148                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 149                         if(shtest_score > SHTEST_THRESHOLD)
 150                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 151                         else if(cvar("developer_shtest"))
 152                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 153                 }
 154                 self.shtest_next = time + SHTEST_DELTA;
 155                 self.shtest_accumulator = 0;
 156         }
 157         self.shtest_accumulator += frametime;
 158
 159         if (clienttype(self) == CLIENTTYPE_BOT)
 160                 bot_think();
 161
 162         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 163                 return;
 164
 165         if(g_bigrigs && self.movetype == MOVETYPE_WALK)
 166         {
 167                 self.disableclientprediction = 1;
 168                 self.movetype = MOVETYPE_NONE;
 169         }
 170
 171         if (self.punchangle != '0 0 0')
 172         {
 173                 f = vlen(self.punchangle) - 10 * frametime;
 174                 if (f > 0)
 175                         self.punchangle = normalize(self.punchangle) * f;
 176                 else
 177                         self.punchangle = '0 0 0';
 178         }
 179
 180         if (self.punchvector != '0 0 0')
 181         {
 182                 f = vlen(self.punchvector) - 30 * frametime;
 183                 if (f > 0)
 184                         self.punchvector = normalize(self.punchvector) * f;
 185                 else
 186                         self.punchvector = '0 0 0';
 187         }
 188
 189         maxspd_mod = 1;
 190
 191         if(g_runematch)
 192         {
 193                 if(self.runes & RUNE_SPEED)
 194                 {
 195                         if(self.runes & CURSE_SLOW)
 196                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 197                         else
 198                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 199                 }
 200                 else if(self.runes & CURSE_SLOW)
 201                 {
 202                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 203                 }
 204         }
 205
 206         if(g_minstagib && (self.items & IT_INVINCIBLE))
 207         {
 208                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 209         }
 210
 211         swampspd_mod = 1;
 212         if(self.in_swamp) {
 213                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 214         }
 215
 216         if(self.flags & FL_NOTARGET)
 217         {
 218                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 219                 if(!self.spectatorspeed)
 220                         self.spectatorspeed = maxspd_mod;
 221                 if(self.impulse && self.impulse <= 19)
 222                 {
 223                         if(self.lastflags & FL_NOTARGET)
 224                         {
 225                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 226                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 227                                 else if(self.impulse == 11)
 228                                         self.spectatorspeed = maxspd_mod;
 229                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 230                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 231                                 else if(self.impulse >= 1 && self.impulse <= 9)
 232                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 233                         } // otherwise just clear
 234                         self.impulse = 0;
 235                 }
 236                 maxspd_mod = self.spectatorspeed;
 237         }
 238
 239         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 240
 241         if(self.speed != spd)
 242         {
 243                 self.speed = spd;
 244                 temps = ftos(spd);
 245                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 246                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 247                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 248                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 249
 250                 temps = ftos(sv_accelerate * maxspd_mod);
 251                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 252         }
 253
 254         // if dead, behave differently
 255         if (self.deadflag)
 256                 return;
 257
 258         if (!self.fixangle && !g_bigrigs)
 259         {
 260                 self.angles_x = 0;
 261                 self.angles_y = self.v_angle_y;
 262                 self.angles_z = 0;
 263         }
 264
 265         if(self.flags & FL_ONGROUND)
 266         if(self.wasFlying)
 267         {
 268                 self.wasFlying = 0;
 269
 270                 if(self.waterlevel < 2)
 271                 if(time >= self.ladder_time)
 272                 if not(self.hook)
 273                 {
 274                         self.nextstep = time + 0.3 + random() * 0.1;
 275                         trace_dphitq3surfaceflags = 0;
 276                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 277                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 278                         {
 279                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 280                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, 0);
 281                                 else
 282                                         GlobalSound(globalsound_fall, CHAN_PLAYER, 0);
 283                         }
 284                 }
 285         }
 286
 287         if(IsFlying(self))
 288                 self.wasFlying = 1;
 289
 290         if(self.classname == "player")
 291         {
 292                 if(sv_doublejump)
 293                 {
 294                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 295                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 296                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 297                                 self.flags = self.flags | FL_ONGROUND;
 298                 }
 299
 300                 if (self.BUTTON_JUMP)
 301                         PlayerJump ();
 302                 else
 303                         self.flags = self.flags | FL_JUMPRELEASED;
 304
 305                 if (self.waterlevel == 2)
 306                         CheckWaterJump ();
 307         }
 308
 309         if (self.flags & FL_WATERJUMP )
 310         {
 311                 self.velocity_x = self.movedir_x;
 312                 self.velocity_y = self.movedir_y;
 313                 if (time > self.teleport_time || self.waterlevel == 0)
 314                 {
 315                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 316                         self.teleport_time = 0;
 317                 }
 318         }
 319         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 320         {
 321                 // noclipping or flying
 322                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 323
 324                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 325                 makevectors(self.v_angle);
 326                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 327                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 328                 // acceleration
 329                 wishdir = normalize(wishvel);
 330                 wishspeed = vlen(wishvel);
 331                 if (wishspeed > sv_maxspeed*maxspd_mod)
 332                         wishspeed = sv_maxspeed*maxspd_mod;
 333                 if (time >= self.teleport_time)
 334                 {
 335                         f = wishspeed - (self.velocity * wishdir);
 336                         if (f > 0)
 337                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 338                 }
 339         }
 340         else if (g_bigrigs)
 341         {
 342                 // using this move type for "big rigs"
 343                 // the engine does not push the entity!
 344
 345                 float accel, steer, myspeed, steerfactor, accelfactor, upspeed, friction;
 346                 vector neworigin, up, angles_save;
 347
 348                 accel = self.movement_x / sv_maxspeed;
 349                 steer = self.movement_y / sv_maxspeed;
 350
 351                 angles_save = self.angles;
 352                 self.angles_x = 0;
 353                 self.angles_z = 0;
 354                 makevectors(self.angles); // new forward direction!
 355                 myspeed = self.velocity * v_forward;
 356                 upspeed = self.velocity * v_up;
 357
 358                 // responsiveness factor for steering and acceleration
 359                 f = 1 / (1 + pow(max(0, myspeed / 400), 2));
 360
 361                 steerfactor = -myspeed * f;
 362                 accelfactor = f * 800;
 363
 364                 // BUG RIGS: make friction FAIL if reversing
 365                 if(accel < 0)
 366                 {
 367                         if(myspeed <= 0)
 368                                 friction = 0;
 369                         else
 370                                 myspeed = max(0, myspeed - frametime * 1000);
 371                 }
 372                 else
 373                         myspeed = max(0, myspeed - frametime * 50);
 374                         // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 375
 376                 // BUG RIGS: stop when reversing and releasing the button
 377                 if(myspeed < 0 && accel == 0)
 378                         myspeed = 0;
 379
 380                 self.angles_y += steer * frametime * steerfactor; // apply steering
 381                 makevectors(self.angles); // new forward direction!
 382
 383                 myspeed += accel * accelfactor * frametime;
 384
 385                 self.velocity = v_forward * myspeed;
 386                 upspeed -= frametime * sv_gravity;
 387
 388                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', MOVE_NORMAL, self);
 389                 up = trace_endpos - self.origin;
 390
 391                 // BUG RIGS: align the move to the surface instead of doing collision testing
 392                 // can we move?
 393                 neworigin = trace_endpos + self.velocity * frametime;
 394                 tracebox(trace_endpos, self.mins, self.maxs, neworigin, MOVE_NORMAL, self);
 395
 396                 // align to surface
 397                 tracebox(trace_endpos, self.mins, self.maxs, neworigin - up + '0 0 1' * upspeed * frametime, MOVE_NORMAL, self);
 398
 399                 if(trace_fraction >= 0.5)
 400                         self.origin = trace_endpos;
 401                 else
 402                         trace_fraction = 1;
 403
 404                 // now set angles_x so that the car points parallel to the surface
 405                 if(trace_fraction < 1)
 406                 {
 407                         self.angles = vectoangles(normalize(
 408                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 409                                 +
 410                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 411                                 +
 412                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 413                         ));
 414                         self.flags |= FL_ONGROUND;
 415                 }
 416                 else
 417                 {
 418                         self.angles_x = angles_save_x;
 419                         self.angles_z = angles_save_z;
 420                         self.velocity += '0 0 1' * upspeed;
 421                         self.flags (-) FL_ONGROUND;
 422                 }
 423
 424                 // relink
 425                 setorigin(self, self.origin);
 426         }
 427         else if (self.waterlevel >= 2)
 428         {
 429                 // swimming
 430                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 431
 432                 makevectors(self.v_angle);
 433                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 434                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 435                 if (wishvel == '0 0 0')
 436                         wishvel = '0 0 -60'; // drift towards bottom
 437
 438                 wishdir = normalize(wishvel);
 439                 wishspeed = vlen(wishvel);
 440                 if (wishspeed > sv_maxspeed*maxspd_mod)
 441                         wishspeed = sv_maxspeed*maxspd_mod;
 442                 wishspeed = wishspeed * 0.7;
 443
 444                 // water friction
 445                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 446
 447                 // water acceleration
 448                 f = wishspeed - (self.velocity * wishdir);
 449                 if (f > 0)
 450                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 451         }
 452         else if (time < self.ladder_time)
 453         {
 454                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 455                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 456
 457                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 458                 makevectors(self.v_angle);
 459                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 460                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 461                 if (self.gravity)
 462                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 463                 else
 464                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 465                 if (self.ladder_entity.classname == "func_water")
 466                 {
 467                         f = vlen(wishvel);
 468                         if (f > self.ladder_entity.speed)
 469                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 470
 471                         self.watertype = self.ladder_entity.skin;
 472                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 473                         if ((self.origin_z + self.view_ofs_z) < f)
 474                                 self.waterlevel = 3;
 475                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 476                                 self.waterlevel = 2;
 477                         else if ((self.origin_z + self.mins_z + 1) < f)
 478                                 self.waterlevel = 1;
 479                         else
 480                         {
 481                                 self.waterlevel = 0;
 482                                 self.watertype = CONTENT_EMPTY;
 483                         }
 484                 }
 485                 // acceleration
 486                 wishdir = normalize(wishvel);
 487                 wishspeed = vlen(wishvel);
 488                 if (wishspeed > sv_maxspeed)
 489                         wishspeed = sv_maxspeed;
 490                 if (time >= self.teleport_time)
 491                 {
 492                         f = wishspeed - (self.velocity * wishdir);
 493                         if (f > 0)
 494                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 495                 }
 496         }
 497         else if (self.flags & FL_ONGROUND)
 498         {
 499                 // walking
 500                 makevectors(self.v_angle_y * '0 1 0');
 501                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 502
 503                 if(!(self.lastflags & FL_ONGROUND))
 504                 {
 505                         if(cvar("speedmeter"))
 506                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 507                         if(self.lastground < time - 0.3)
 508                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 509                         if(self.jumppadcount > 1)
 510                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 511                         self.jumppadcount = 0;
 512                 }
 513
 514                 if (self.velocity_x || self.velocity_y)
 515                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 516                 {
 517                         v = self.velocity;
 518                         v_z = 0;
 519                         f = vlen(v);
 520                         if (f < sv_stopspeed)
 521                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 522                         else
 523                                 f = 1 - frametime * sv_friction;
 524                         if (f > 0)
 525                                 self.velocity = self.velocity * f;
 526                         else
 527                                 self.velocity = '0 0 0';
 528                 }
 529                 // acceleration
 530                 wishdir = normalize(wishvel);
 531                 wishspeed = vlen(wishvel);
 532                 if (wishspeed > sv_maxspeed*maxspd_mod)
 533                         wishspeed = sv_maxspeed*maxspd_mod;
 534                 if (self.crouch)
 535                         wishspeed = wishspeed * 0.5;
 536                 if (time >= self.teleport_time)
 537                 {
 538                         f = wishspeed - (self.velocity * wishdir);
 539                         if (f > 0)
 540                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 541                 }
 542         }
 543         else
 544         {
 545                 if(maxspd_mod < 1)
 546                 {
 547                         maxairspd = sv_maxairspeed*maxspd_mod;
 548                         airaccel = sv_airaccelerate*maxspd_mod;
 549                 }
 550                 else
 551                 {
 552                         maxairspd = sv_maxairspeed;
 553                         airaccel = sv_airaccelerate;
 554                 }
 555                 // airborn
 556                 makevectors(self.v_angle_y * '0 1 0');
 557                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 558                 // acceleration
 559                 wishdir = normalize(wishvel);
 560                 wishspeed = vlen(wishvel);
 561                 if (wishspeed > maxairspd)
 562                         wishspeed = maxairspd;
 563                 if (self.crouch)
 564                         wishspeed = wishspeed * 0.5;
 565                 if (time >= self.teleport_time)
 566                 {
 567                         // NOTE: this does the same as the commented out old code if:
 568                         //   sv_airaccel_qw 0
 569                         //   sv_airaccel_sideways_friction 0
 570
 571                         float vel_straight;
 572                         float vel_z;
 573                         vector vel_perpend;
 574                         vel_straight = self.velocity * wishdir;
 575                         vel_z = self.velocity_z;
 576                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 577
 578                         f = wishspeed - vel_straight;
 579                         if(f > 0)
 580                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 581                         if(wishspeed > 0)
 582                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 583
 584                         // anti-sideways friction to fix QW-style bunnyhopping
 585                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 586
 587                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 588
 589                         /*
 590                         f = wishspeed;// - (self.velocity * wishdir);
 591                         if (f > 0)
 592                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 593                         */
 594                 }
 595         }
 596
 597         if(self.flags & FL_ONGROUND)
 598                 self.lastground = time;
 599
 600         self.lastflags = self.flags;
 601 };