data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16
  17 #define SHTEST_DELTA 15
  18 .float shtest_next;
  19 .float shtest_accumulator;
  20
  21 /*
  22 =============
  23 PlayerJump
  24
  25 When you press the jump key
  26 =============
  27 */
  28 void PlayerJump (void)
  29 {
  30         float mjumpheight;
  31
  32         mjumpheight = cvar("sv_jumpvelocity");
  33         if (self.waterlevel >= 2)
  34         {
  35                 if (self.watertype == CONTENT_WATER)
  36                         self.velocity_z = 200;
  37                 else if (self.watertype == CONTENT_SLIME)
  38                         self.velocity_z = 80;
  39                 else
  40                         self.velocity_z = 50;
  41
  42                 return;
  43         }
  44
  45
  46         if (!(self.flags & FL_ONGROUND))
  47                 return;
  48
  49         if (!(self.flags & FL_JUMPRELEASED))
  50                 return;
  51
  52         if(g_runematch)
  53         {
  54                 if(self.runes & RUNE_SPEED)
  55                 {
  56                         if(self.runes & CURSE_SLOW)
  57                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  58                         else
  59                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  60                 }
  61                 else if(self.runes & CURSE_SLOW)
  62                 {
  63                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  64                 }
  65         }
  66
  67         if(g_minstagib && (self.items & IT_INVINCIBLE))
  68         {
  69                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  70         }
  71
  72         self.velocity_z = self.velocity_z + mjumpheight;
  73         self.oldvelocity_z = self.velocity_z;
  74
  75         self.flags = self.flags - FL_ONGROUND;
  76         self.flags = self.flags - FL_JUMPRELEASED;
  77
  78         if (self.crouch)
  79                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  80         else
  81                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  82 }
  83
  84 void() CheckWaterJump =
  85 {
  86         local vector start, end;
  87
  88 // check for a jump-out-of-water
  89         makevectors (self.angles);
  90         start = self.origin;
  91         start_z = start_z + 8;
  92         v_forward_z = 0;
  93         normalize(v_forward);
  94         end = start + v_forward*24;
  95         traceline (start, end, TRUE, self);
  96         if (trace_fraction < 1)
  97         {       // solid at waist
  98                 start_z = start_z + self.maxs_z - 8;
  99                 end = start + v_forward*24;
 100                 self.movedir = trace_plane_normal * -50;
 101                 traceline (start, end, TRUE, self);
 102                 if (trace_fraction == 1)
 103                 {       // open at eye level
 104                         self.flags = self.flags | FL_WATERJUMP;
 105                         self.velocity_z = 225;
 106                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 107                         self.teleport_time = time + 2;  // safety net
 108                         return;
 109                 }
 110         }
 111 };
 112
 113 .vector movement_old;
 114 .float buttons_old;
 115 .vector v_angle_old;
 116
 117 void Nixnex_GiveCurrentWeapon();
 118 void SV_PlayerPhysics()
 119 {
 120         local vector wishvel, wishdir, v;
 121         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 122         string temps;
 123
 124         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 125         if(buttons != self.buttons_old)
 126                 self.parm_idlesince = time;
 127         self.buttons_old = buttons;
 128
 129         if(self.movement != self.movement_old)
 130                 self.parm_idlesince = time;
 131         self.movement_old = self.movement;
 132
 133         if(self.v_angle != self.v_angle_old)
 134                 self.parm_idlesince = time;
 135         self.v_angle_old = self.v_angle;
 136
 137         if(time > self.shtest_next)
 138         {
 139                 if(self.shtest_next > 0)
 140                 {
 141                         // self.shtest_accumulator:
 142                         //   started at time - SHTEST_DELTA
 143                         //   should be at SHTEST_DELTA
 144                         shtest_score = self.shtest_accumulator / SHTEST_DELTA;
 145                         if(shtest_score > 1.2)
 146                                 dprint("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 147                         else if(cvar("developer_shtest"))
 148                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 149                 }
 150                 self.shtest_next = time + SHTEST_DELTA;
 151                 self.shtest_accumulator = 0;
 152         }
 153         self.shtest_accumulator += frametime;
 154
 155         if (clienttype(self) == CLIENTTYPE_BOT)
 156                 bot_think();
 157
 158         if (self.movetype == MOVETYPE_NONE)
 159                 return;
 160
 161         if (self.punchangle != '0 0 0')
 162         {
 163                 f = vlen(self.punchangle) - 10 * frametime;
 164                 if (f > 0)
 165                         self.punchangle = normalize(self.punchangle) * f;
 166                 else
 167                         self.punchangle = '0 0 0';
 168         }
 169
 170         if (self.punchvector != '0 0 0')
 171         {
 172                 f = vlen(self.punchvector) - 30 * frametime;
 173                 if (f > 0)
 174                         self.punchvector = normalize(self.punchvector) * f;
 175                 else
 176                         self.punchvector = '0 0 0';
 177         }
 178
 179         maxspd_mod = 1;
 180
 181         if(g_runematch)
 182         {
 183                 if(self.runes & RUNE_SPEED)
 184                 {
 185                         if(self.runes & CURSE_SLOW)
 186                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 187                         else
 188                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 189                 }
 190                 else if(self.runes & CURSE_SLOW)
 191                 {
 192                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 193                 }
 194         }
 195
 196         if(g_minstagib && (self.items & IT_INVINCIBLE))
 197         {
 198                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 199         }
 200
 201         swampspd_mod = 1;
 202         if(self.in_swamp) {
 203                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 204         }
 205
 206         if(self.flags & FL_NOTARGET)
 207                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 208
 209         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 210
 211         if(self.speed != spd)
 212         {
 213                 self.speed = spd;
 214                 temps = ftos(spd);
 215                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 216                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 217                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 218                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 219
 220                 temps = ftos(sv_accelerate * maxspd_mod);
 221                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 222         }
 223
 224         // if dead, behave differently
 225         if (self.deadflag)
 226                 return;
 227
 228         if (!self.fixangle)
 229         {
 230                 self.angles_x = 0;
 231                 self.angles_y = self.v_angle_y;
 232                 self.angles_z = 0;
 233         }
 234
 235         if(self.classname == "player")
 236         {
 237                 if (self.BUTTON_JUMP)
 238                         PlayerJump ();
 239                 else
 240                         self.flags = self.flags | FL_JUMPRELEASED;
 241
 242                 if (self.waterlevel == 2)
 243                         CheckWaterJump ();
 244         }
 245
 246         if (self.flags & FL_WATERJUMP )
 247         {
 248                 self.velocity_x = self.movedir_x;
 249                 self.velocity_y = self.movedir_y;
 250                 if (time > self.teleport_time || self.waterlevel == 0)
 251                 {
 252                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 253                         self.teleport_time = 0;
 254                 }
 255         }
 256         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 257         {
 258                 // noclipping or flying
 259                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 260
 261                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 262                 makevectors(self.v_angle);
 263                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 264                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 265                 // acceleration
 266                 wishdir = normalize(wishvel);
 267                 wishspeed = vlen(wishvel);
 268                 if (wishspeed > sv_maxspeed*maxspd_mod)
 269                         wishspeed = sv_maxspeed*maxspd_mod;
 270                 if (time >= self.teleport_time)
 271                 {
 272                         f = wishspeed - (self.velocity * wishdir);
 273                         if (f > 0)
 274                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 275                 }
 276         }
 277         else if (self.waterlevel >= 2)
 278         {
 279                 // swimming
 280                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 281
 282                 makevectors(self.v_angle);
 283                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 284                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 285                 if (wishvel == '0 0 0')
 286                         wishvel = '0 0 -60'; // drift towards bottom
 287
 288                 wishdir = normalize(wishvel);
 289                 wishspeed = vlen(wishvel);
 290                 if (wishspeed > sv_maxspeed*maxspd_mod)
 291                         wishspeed = sv_maxspeed*maxspd_mod;
 292                 wishspeed = wishspeed * 0.7;
 293
 294                 // water friction
 295                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 296
 297                 // water acceleration
 298                 f = wishspeed - (self.velocity * wishdir);
 299                 if (f > 0)
 300                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 301         }
 302         else if (time < self.ladder_time)
 303         {
 304                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 305                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 306
 307                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 308                 makevectors(self.v_angle);
 309                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 310                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 311                 if (self.gravity)
 312                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 313                 else
 314                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 315                 if (self.ladder_entity.classname == "func_water")
 316                 {
 317                         f = vlen(wishvel);
 318                         if (f > self.ladder_entity.speed)
 319                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 320
 321                         self.watertype = self.ladder_entity.skin;
 322                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 323                         if ((self.origin_z + self.view_ofs_z) < f)
 324                                 self.waterlevel = 3;
 325                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 326                                 self.waterlevel = 2;
 327                         else if ((self.origin_z + self.mins_z + 1) < f)
 328                                 self.waterlevel = 1;
 329                         else
 330                         {
 331                                 self.waterlevel = 0;
 332                                 self.watertype = CONTENT_EMPTY;
 333                         }
 334                 }
 335                 // acceleration
 336                 wishdir = normalize(wishvel);
 337                 wishspeed = vlen(wishvel);
 338                 if (wishspeed > sv_maxspeed)
 339                         wishspeed = sv_maxspeed;
 340                 if (time >= self.teleport_time)
 341                 {
 342                         f = wishspeed - (self.velocity * wishdir);
 343                         if (f > 0)
 344                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 345                 }
 346         }
 347         else if (self.flags & FL_ONGROUND)
 348         {
 349                 // walking
 350                 makevectors(self.v_angle_y * '0 1 0');
 351                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 352
 353                 if(!(self.lastflags & FL_ONGROUND))
 354                 {
 355                         if(cvar("speedmeter"))
 356                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 357                         if(self.lastground < time - 0.3)
 358                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 359                         if(self.jumppadcount > 1)
 360                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 361                         self.jumppadcount = 0;
 362                 }
 363
 364                 if (self.velocity_x || self.velocity_y)
 365                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 366                 {
 367                         v = self.velocity;
 368                         v_z = 0;
 369                         f = vlen(v);
 370                         if (f < sv_stopspeed)
 371                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 372                         else
 373                                 f = 1 - frametime * sv_friction;
 374                         if (f > 0)
 375                                 self.velocity = self.velocity * f;
 376                         else
 377                                 self.velocity = '0 0 0';
 378                 }
 379                 // acceleration
 380                 wishdir = normalize(wishvel);
 381                 wishspeed = vlen(wishvel);
 382                 if (wishspeed > sv_maxspeed*maxspd_mod)
 383                         wishspeed = sv_maxspeed*maxspd_mod;
 384                 if (self.crouch)
 385                         wishspeed = wishspeed * 0.5;
 386                 if (time >= self.teleport_time)
 387                 {
 388                         f = wishspeed - (self.velocity * wishdir);
 389                         if (f > 0)
 390                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 391                 }
 392         }
 393         else
 394         {
 395                 if(maxspd_mod < 1)
 396                 {
 397                         maxairspd = sv_maxairspeed*maxspd_mod;
 398                         airaccel = sv_airaccelerate*maxspd_mod;
 399                 }
 400                 else
 401                 {
 402                         maxairspd = sv_maxairspeed;
 403                         airaccel = sv_airaccelerate;
 404                 }
 405                 // airborn
 406                 makevectors(self.v_angle_y * '0 1 0');
 407                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 408                 // acceleration
 409                 wishdir = normalize(wishvel);
 410                 wishspeed = vlen(wishvel);
 411                 if (wishspeed > maxairspd)
 412                         wishspeed = maxairspd;
 413                 if (self.crouch)
 414                         wishspeed = wishspeed * 0.5;
 415                 if (time >= self.teleport_time)
 416                 {
 417                         // NOTE: this does the same as the commented out old code if:
 418                         //   sv_airaccel_qw 0
 419                         //   sv_airaccel_sideways_friction 0
 420
 421                         float vel_straight;
 422                         float vel_z;
 423                         vector vel_perpend;
 424                         vel_straight = self.velocity * wishdir;
 425                         vel_z = self.velocity_z;
 426                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 427
 428                         f = wishspeed - vel_straight;
 429                         if(f > 0)
 430                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 431                         if(wishspeed > 0)
 432                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 433
 434                         // anti-sideways friction to fix QW-style bunnyhopping
 435                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 436
 437                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 438
 439                         /*
 440                         f = wishspeed;// - (self.velocity * wishdir);
 441                         if (f > 0)
 442                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 443                         */
 444                 }
 445         }
 446
 447         if(self.flags & FL_ONGROUND)
 448                 self.lastground = time;
 449
 450         self.lastflags = self.flags;
 451 };