data/qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 float sv_accelerate;
   5 float sv_friction;
   6 float sv_maxspeed;
   7 float sv_airaccelerate;
   8 float sv_maxairspeed;
   9 float sv_stopspeed;
  10 float sv_gravity;
  11 float sv_airaccel_sideways_friction;
  12 float sv_airaccel_qw;
  13 float sv_airstopaccelerate;
  14 float sv_airstrafeaccelerate;
  15 float sv_maxairstrafespeed;
  16 float sv_aircontrol;
  17 float sv_warsowbunny_airforwardaccel;
  18 float sv_warsowbunny_accel;
  19 float sv_warsowbunny_topspeed;
  20 float sv_warsowbunny_turnaccel;
  21 float sv_warsowbunny_backtosideratio;
  22
  23 .float ladder_time;
  24 .entity ladder_entity;
  25 .float gravity;
  26 .float swamp_slowdown;
  27 .float lastflags;
  28 .float lastground;
  29 .float wasFlying;
  30 .float spectatorspeed;
  31
  32 .float doublejump_nextjumptime;
  33
  34 /*
  35 =============
  36 PlayerJump
  37
  38 When you press the jump key
  39 =============
  40 */
  41 void PlayerJump (void)
  42 {
  43         float mjumpheight;
  44
  45         mjumpheight = cvar("sv_jumpvelocity");
  46         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  47         {
  48                 if (self.watertype == CONTENT_WATER)
  49                         self.velocity_z = 200;
  50                 else if (self.watertype == CONTENT_SLIME)
  51                         self.velocity_z = 80;
  52                 else
  53                         self.velocity_z = 50;
  54
  55                 return;
  56         }
  57
  58         if (!(self.flags & FL_ONGROUND))
  59                 return;
  60
  61         if(!sv_pogostick)
  62                 if (!(self.flags & FL_JUMPRELEASED))
  63                         return;
  64
  65         if(self.health <= g_bloodloss)
  66                 return;
  67
  68         if(sv_doublejump)
  69                 if(time < self.doublejump_nextjumptime)
  70                         return;
  71
  72         if(g_runematch)
  73         {
  74                 if(self.runes & RUNE_SPEED)
  75                 {
  76                         if(self.runes & CURSE_SLOW)
  77                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  78                         else
  79                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  80                 }
  81                 else if(self.runes & CURSE_SLOW)
  82                 {
  83                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  84                 }
  85         }
  86
  87         if(g_minstagib && (self.items & IT_INVINCIBLE))
  88         {
  89                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  90         }
  91
  92         if(!(self.lastflags & FL_ONGROUND))
  93         {
  94                 if(cvar("speedmeter"))
  95                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
  96                 if(self.lastground < time - 0.3)
  97                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
  98                 if(self.jumppadcount > 1)
  99                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 100                 self.jumppadcount = 0;
 101         }
 102
 103         self.velocity_z = self.velocity_z + mjumpheight;
 104         self.oldvelocity_z = self.velocity_z;
 105
 106         self.flags &~= FL_ONGROUND;
 107         self.flags &~= FL_JUMPRELEASED;
 108
 109         if (self.crouch)
 110                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 111         else
 112                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 113
 114         if(g_jump_grunt)
 115                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 116
 117         if(sv_doublejump)
 118         {
 119                 // we're moving upwards at self.velocity_z
 120                 // only allow jumping after we got 3 units upwards
 121                 // so we for sure leave the FL_ONGROUND check
 122                 //
 123                 // but as this sucks because of factoring in gravity, we'll just do it
 124                 // for 4 units, and constant velocity
 125                 self.doublejump_nextjumptime = time + 4 / max(40, self.velocity_z); // max 0.1s blocking of jumps
 126         }
 127
 128         self.restart_jump = -1; // restart jump anim next time
 129         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 130 }
 131
 132 void CheckWaterJump()
 133 {
 134         local vector start, end;
 135
 136 // check for a jump-out-of-water
 137         makevectors (self.angles);
 138         start = self.origin;
 139         start_z = start_z + 8;
 140         v_forward_z = 0;
 141         normalize(v_forward);
 142         end = start + v_forward*24;
 143         traceline (start, end, TRUE, self);
 144         if (trace_fraction < 1)
 145         {       // solid at waist
 146                 start_z = start_z + self.maxs_z - 8;
 147                 end = start + v_forward*24;
 148                 self.movedir = trace_plane_normal * -50;
 149                 traceline (start, end, TRUE, self);
 150                 if (trace_fraction == 1)
 151                 {       // open at eye level
 152                         self.flags |= FL_WATERJUMP;
 153                         self.velocity_z = 225;
 154                         self.flags &~= FL_JUMPRELEASED;
 155                         self.teleport_time = time + 2;  // safety net
 156                         return;
 157                 }
 158         }
 159 };
 160
 161 float racecar_angle(float forward, float down)
 162 {
 163         float ret, angle_mult;
 164
 165         if(forward < 0)
 166         {
 167                 forward = -forward;
 168                 down = -down;
 169         }
 170
 171         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 172
 173         angle_mult = forward / (800 + forward);
 174
 175         if(ret > 180)
 176                 return ret * angle_mult + 360 * (1 - angle_mult);
 177         else
 178                 return ret * angle_mult;
 179 }
 180
 181 void RaceCarPhysics()
 182 {
 183         // using this move type for "big rigs"
 184         // the engine does not push the entity!
 185
 186         float accel, steer, f;
 187         vector angles_save, rigvel;
 188
 189         angles_save = self.angles;
 190         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 191         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 192
 193         if(g_bugrigs_reverse_speeding)
 194         {
 195                 if(accel < 0)
 196                 {
 197                         // back accel is DIGITAL
 198                         // to prevent speedhack
 199                         if(accel < -0.5)
 200                                 accel = -1;
 201                         else
 202                                 accel = 0;
 203                 }
 204         }
 205
 206         self.angles_x = 0;
 207         self.angles_z = 0;
 208         makevectors(self.angles); // new forward direction!
 209
 210         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 211         {
 212                 float myspeed, upspeed, steerfactor, accelfactor;
 213
 214                 myspeed = self.velocity * v_forward;
 215                 upspeed = self.velocity * v_up;
 216
 217                 // responsiveness factor for steering and acceleration
 218                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 219                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 220
 221                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 222                         steerfactor = -myspeed * g_bugrigs_steer;
 223                 else
 224                         steerfactor = -myspeed * f * g_bugrigs_steer;
 225
 226                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 227                         accelfactor = g_bugrigs_accel;
 228                 else
 229                         accelfactor = f * g_bugrigs_accel;
 230                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 231
 232                 if(accel < 0)
 233                 {
 234                         if(myspeed > 0)
 235                         {
 236                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 237                         }
 238                         else
 239                         {
 240                                 if(!g_bugrigs_reverse_speeding)
 241                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 242                         }
 243                 }
 244                 else
 245                 {
 246                         if(myspeed >= 0)
 247                         {
 248                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 249                         }
 250                         else
 251                         {
 252                                 if(g_bugrigs_reverse_stopping)
 253                                         myspeed = 0;
 254                                 else
 255                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 256                         }
 257                 }
 258                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 259                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 260
 261                 self.angles_y += steer * frametime * steerfactor; // apply steering
 262                 makevectors(self.angles); // new forward direction!
 263
 264                 myspeed += accel * accelfactor * frametime;
 265
 266                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 267         }
 268         else
 269         {
 270                 myspeed = vlen(self.velocity);
 271
 272                 // responsiveness factor for steering and acceleration
 273                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 274                 steerfactor = -myspeed * f;
 275                 self.angles_y += steer * frametime * steerfactor; // apply steering
 276
 277                 rigvel = self.velocity;
 278                 makevectors(self.angles); // new forward direction!
 279         }
 280
 281         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 282         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 283         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 284         //MAXIMA: solve(total_acceleration(v) = 0, v);
 285
 286         if(g_bugrigs_planar_movement)
 287         {
 288                 vector rigvel_xy, neworigin, up;
 289                 float mt;
 290
 291                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 292                 rigvel_xy = rigvel;
 293                 rigvel_xy_z = 0;
 294
 295                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 296                         mt = MOVE_NORMAL;
 297                 else
 298                         mt = MOVE_NOMONSTERS;
 299
 300                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 301                 up = trace_endpos - self.origin;
 302
 303                 // BUG RIGS: align the move to the surface instead of doing collision testing
 304                 // can we move?
 305                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 306
 307                 // align to surface
 308                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 309
 310                 if(trace_fraction < 0.5)
 311                 {
 312                         trace_fraction = 1;
 313                         neworigin = self.origin;
 314                 }
 315                 else
 316                         neworigin = trace_endpos;
 317
 318                 if(trace_fraction < 1)
 319                 {
 320                         // now set angles_x so that the car points parallel to the surface
 321                         self.angles = vectoangles(
 322                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 323                                         +
 324                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 325                                         +
 326                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 327                                         );
 328                         self.flags |= FL_ONGROUND;
 329                 }
 330                 else
 331                 {
 332                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 333                         self.flags &~= FL_ONGROUND;
 334                 }
 335
 336                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 337                 self.movetype = MOVETYPE_NOCLIP;
 338         }
 339         else
 340         {
 341                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 342                 self.velocity = rigvel;
 343                 self.movetype = MOVETYPE_FLY;
 344         }
 345
 346         trace_fraction = 1;
 347         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 348         if(trace_fraction != 1)
 349         {
 350                 self.angles = vectoangles2(
 351                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 352                                 +
 353                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 354                                 +
 355                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 356                                 trace_plane_normal
 357                                 );
 358         }
 359         else
 360         {
 361                 vector vel_local;
 362
 363                 vel_local_x = v_forward * self.velocity;
 364                 vel_local_y = v_right * self.velocity;
 365                 vel_local_z = v_up * self.velocity;
 366
 367                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 368                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 369         }
 370
 371         // smooth the angles
 372         vector vf1, vu1, smoothangles;
 373         makevectors(self.angles);
 374         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 375         if(f == 0)
 376                 f = 1;
 377         vf1 = v_forward * f;
 378         vu1 = v_up * f;
 379         makevectors(angles_save);
 380         vf1 = vf1 + v_forward * (1 - f);
 381         vu1 = vu1 + v_up * (1 - f);
 382         smoothangles = vectoangles2(vf1, vu1);
 383         self.angles_x = -smoothangles_x;
 384         self.angles_z =  smoothangles_z;
 385 }
 386
 387 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 388 {
 389         float zspeed, xyspeed, dot, k;
 390
 391         if(self.movement_x == 0 || self.movement_y != 0)
 392                 return; // can't control movement if not moving forward or backward
 393
 394         zspeed = self.velocity_z;
 395         self.velocity_z = 0;
 396         xyspeed = vlen(self.velocity);
 397         self.velocity = normalize(self.velocity);
 398
 399         dot = self.velocity * wishdir;
 400         k = 32;
 401         k *= sv_aircontrol*dot*dot*frametime;
 402
 403         if(dot > 0) // we can't change direction while slowing down
 404                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 405
 406         self.velocity = self.velocity * xyspeed;
 407         self.velocity_z = zspeed;
 408 }
 409
 410 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float sidefric)
 411 {
 412         float vel_straight;
 413         float vel_z;
 414         vector vel_perpend;
 415         float addspeed;
 416         float savespeed;
 417
 418         if(cvar("sv_gameplayfix_q2airaccelerate"))
 419                 wishspeed0 = wishspeed;
 420
 421         savespeed = self.velocity * self.velocity;
 422
 423         vel_straight = self.velocity * wishdir;
 424         vel_z = self.velocity_z;
 425         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 426
 427 #if 0
 428         if(cvar("sv_gameplayfix_alternatespeedclamp"))
 429         {
 430                 // 1. move as normal, but fake a forward move to get the maximum ALLOWED speed
 431                 float vel_xy;
 432                 vel_xy = sqrt(vel_straight * vel_straight + vel_perpend * vel_perpend);
 433                 addspeed = wishspeed - vel_xy;
 434                 if(addspeed > 0)
 435                         vel_xy = vel_xy + min(addspeed, accel * frametime * wishspeed0) * accelqw;
 436                 if(wishspeed > 0)
 437                         vel_xy = vel_xy +               accel * frametime * wishspeed0  * (1 - accelqw);
 438                 // 2. accelerate actually, using our acceleration factor and the max allowed forward speed we derived
 439                 //    we may add at most a vector length of        min(wishspeed, accel * frametime * wishspeed0)
 440                 //    however, the absolute value must not exceed  vel_xy
 441                 addspeed = accel * frametime * wishspeed0;
 442                 addspeed = bound(0, sqrt(vel_xy * vel_xy - vel_perpend * vel_perpend) - vel_straight, addspeed);
 443                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
 444                 // this is how much we can add without exceeding vel_xy
 445                 vel_straight += addspeed;
 446         }
 447         else
 448 #endif
 449         {
 450                 addspeed = wishspeed - vel_straight;
 451                 if(addspeed > 0)
 452                         vel_straight = vel_straight + min(addspeed, accel * frametime * wishspeed0) * accelqw;
 453                 if(wishspeed > 0)
 454                         vel_straight = vel_straight +               accel * frametime * wishspeed0  * (1 - accelqw);
 455         }
 456
 457         if(sidefric < 0 && (vel_perpend*vel_perpend))
 458         {
 459                 float f, fminimum;
 460                 f = (1 - frametime * wishspeed * sidefric);
 461                 fminimum = (savespeed - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 462                 if(fminimum <= 0)
 463                         vel_perpend = vel_perpend * f;
 464                 else
 465                         vel_perpend = vel_perpend * min(1, max(fminimum, f));
 466         }
 467         else
 468                 vel_perpend = vel_perpend * (1 - frametime * wishspeed * sidefric);
 469
 470         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 471 }
 472
 473 void PM_AirAccelerate(vector wishdir, float wishspeed)
 474 {
 475         vector curvel, wishvel, acceldir, curdir;
 476         float addspeed, accelspeed, curspeed, f;
 477         float dot;
 478
 479         if(wishspeed == 0)
 480                 return;
 481
 482         curvel = self.velocity;
 483         curvel_z = 0;
 484         curspeed = vlen(curvel);
 485
 486         if(wishspeed > curspeed * 1.01)
 487         {
 488                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * sv_maxspeed * frametime);
 489         }
 490         else
 491         {
 492                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - sv_maxspeed));
 493                 wishspeed = max(curspeed, sv_maxspeed) + sv_warsowbunny_accel * f * sv_maxspeed * frametime;
 494         }
 495         wishvel = wishdir * wishspeed;
 496         acceldir = wishvel - curvel;
 497         addspeed = vlen(acceldir);
 498         acceldir = normalize(acceldir);
 499
 500         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * sv_maxspeed * frametime);
 501
 502         if(sv_warsowbunny_backtosideratio < 1)
 503         {
 504                 curdir = normalize(curvel);
 505                 dot = acceldir * curdir;
 506                 if(dot < 0)
 507                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 508         }
 509
 510         self.velocity += accelspeed * acceldir;
 511 }
 512
 513 .vector movement_old;
 514 .float buttons_old;
 515 .vector v_angle_old;
 516 .string lastclassname;
 517
 518 void Nixnex_GiveCurrentWeapon();
 519 .float() PlayerPhysplug;
 520
 521 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 522 .float specialcommand_pos;
 523 void SpecialCommand()
 524 {
 525 #ifdef TETRIS
 526         TetrisImpulse();
 527 #else
 528         if(!CheatImpulse(99))
 529                 print("A hollow voice says \"Plugh\".\n");
 530 #endif
 531 }
 532
 533 float speedaward_speed;
 534 string speedaward_holder;
 535 void race_send_speedaward(float msg)
 536 {
 537         // send the best speed of the round
 538         WriteByte(msg, SVC_TEMPENTITY);
 539         WriteByte(msg, TE_CSQC_RACE);
 540         WriteByte(msg, RACE_NET_SPEED_AWARD);
 541         WriteShort(msg, floor(speedaward_speed+0.5));
 542         WriteString(msg, speedaward_holder);
 543 }
 544
 545 float speedaward_alltimebest;
 546 string speedaward_alltimebest_holder;
 547 void race_send_speedaward_alltimebest(float msg)
 548 {
 549         // send the best speed
 550         WriteByte(msg, SVC_TEMPENTITY);
 551         WriteByte(msg, TE_CSQC_RACE);
 552         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 553         WriteShort(msg, floor(speedaward_alltimebest+0.5));
 554         WriteString(msg, speedaward_alltimebest_holder);
 555 }
 556
 557 string GetMapname(void);
 558 float speedaward_lastupdate;
 559 float speedaward_lastsent;
 560 void SV_PlayerPhysics()
 561 {
 562         local vector wishvel, wishdir, v;
 563         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 564         string temps;
 565         float buttons_prev;
 566         float not_allowed_to_move;
 567         string c;
 568
 569     if(self.PlayerPhysplug)
 570         if(self.PlayerPhysplug())
 571             return;
 572
 573         self.race_movetime_frac += frametime;
 574         f = floor(self.race_movetime_frac);
 575         self.race_movetime_frac -= f;
 576         self.race_movetime_count += f;
 577         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 578
 579         anticheat_physics();
 580
 581         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 582
 583         if(!buttons)
 584                 c = "x";
 585         else if(buttons == 1)
 586                 c = "1";
 587         else if(buttons == 2)
 588                 c = " ";
 589         else if(buttons == 128)
 590                 c = "s";
 591         else if(buttons == 256)
 592                 c = "w";
 593         else if(buttons == 512)
 594                 c = "a";
 595         else if(buttons == 1024)
 596                 c = "d";
 597         else
 598                 c = "?";
 599
 600         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 601         {
 602                 self.specialcommand_pos += 1;
 603                 if(self.specialcommand_pos >= strlen(specialcommand))
 604                 {
 605                         self.specialcommand_pos = 0;
 606                         SpecialCommand();
 607                         return;
 608                 }
 609         }
 610         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 611                 self.specialcommand_pos = 0;
 612
 613         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 614         {
 615                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 616                         self.parm_idlesince = time;
 617         }
 618         buttons_prev = self.buttons_old;
 619         self.buttons_old = buttons;
 620         self.movement_old = self.movement;
 621         self.v_angle_old = self.v_angle;
 622
 623         if(time < self.nickspamtime)
 624         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 625         {
 626                 // slight annoyance for nick change scripts
 627                 self.movement = -1 * self.movement;
 628                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 629
 630                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 631                 {
 632                         self.angles_x = random() * 360;
 633                         self.angles_y = random() * 360;
 634                         // at least I'm not forcing retardedview by also assigning to angles_z
 635                         self.fixangle = 1;
 636                 }
 637         }
 638
 639         if (self.punchangle != '0 0 0')
 640         {
 641                 f = vlen(self.punchangle) - 10 * frametime;
 642                 if (f > 0)
 643                         self.punchangle = normalize(self.punchangle) * f;
 644                 else
 645                         self.punchangle = '0 0 0';
 646         }
 647
 648         if (self.punchvector != '0 0 0')
 649         {
 650                 f = vlen(self.punchvector) - 30 * frametime;
 651                 if (f > 0)
 652                         self.punchvector = normalize(self.punchvector) * f;
 653                 else
 654                         self.punchvector = '0 0 0';
 655         }
 656
 657         if (clienttype(self) == CLIENTTYPE_BOT)
 658         {
 659                 if(playerdemo_read())
 660                         return;
 661                 bot_think();
 662         }
 663
 664         self.items &~= IT_USING_JETPACK;
 665
 666         if(self.classname == "player")
 667         {
 668                 if(self.race_penalty)
 669                         if(time > self.race_penalty)
 670                                 self.race_penalty = 0;
 671
 672                 not_allowed_to_move = 0;
 673                 if(self.race_penalty)
 674                         not_allowed_to_move = 1;
 675                 if(!cvar("sv_ready_restart_after_countdown"))
 676                 if(time < game_starttime)
 677                         not_allowed_to_move = 1;
 678
 679                 if(not_allowed_to_move)
 680                 {
 681                         self.velocity = '0 0 0';
 682                         self.movetype = MOVETYPE_NONE;
 683                         self.disableclientprediction = 2;
 684                 }
 685                 else if(self.disableclientprediction == 2)
 686                 {
 687                         if(self.movetype == MOVETYPE_NONE)
 688                                 self.movetype = MOVETYPE_WALK;
 689                         self.disableclientprediction = 0;
 690                 }
 691         }
 692
 693         if (self.movetype == MOVETYPE_NONE)
 694                 return;
 695
 696         maxspd_mod = 1;
 697
 698         if(g_runematch)
 699         {
 700                 if(self.runes & RUNE_SPEED)
 701                 {
 702                         if(self.runes & CURSE_SLOW)
 703                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 704                         else
 705                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 706                 }
 707                 else if(self.runes & CURSE_SLOW)
 708                 {
 709                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 710                 }
 711         }
 712
 713         if(g_minstagib && (self.items & IT_INVINCIBLE))
 714         {
 715                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 716         }
 717
 718         if(g_nexball && self.ballcarried)
 719         {
 720                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 721         }
 722
 723         swampspd_mod = 1;
 724         if(self.in_swamp) {
 725                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 726         }
 727
 728         if(self.classname != "player")
 729         {
 730                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 731                 if(!self.spectatorspeed)
 732                         self.spectatorspeed = maxspd_mod;
 733                 if(self.impulse && self.impulse <= 19)
 734                 {
 735                         if(self.lastclassname != "player")
 736                         {
 737                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 738                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 739                                 else if(self.impulse == 11)
 740                                         self.spectatorspeed = maxspd_mod;
 741                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 742                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 743                                 else if(self.impulse >= 1 && self.impulse <= 9)
 744                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 745                         } // otherwise just clear
 746                         self.impulse = 0;
 747                 }
 748                 maxspd_mod = self.spectatorspeed;
 749         }
 750
 751         spd = max(sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 752         if(self.speed != spd)
 753         {
 754                 self.speed = spd;
 755                 temps = ftos(spd);
 756                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 757                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 758                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 759                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 760         }
 761
 762         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 763         swampspd_mod = 1;
 764
 765         // if dead, behave differently
 766         if (self.deadflag)
 767                 goto end;
 768
 769         if (!self.fixangle && !g_bugrigs)
 770         {
 771                 self.angles_x = 0;
 772                 self.angles_y = self.v_angle_y;
 773                 self.angles_z = 0;
 774         }
 775
 776         if(self.flags & FL_ONGROUND)
 777         if(self.wasFlying)
 778         {
 779                 self.wasFlying = 0;
 780
 781                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 782                 if(time >= self.ladder_time)
 783                 if not(self.hook)
 784                 {
 785                         self.nextstep = time + 0.3 + random() * 0.1;
 786                         trace_dphitq3surfaceflags = 0;
 787                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 788                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 789                         {
 790                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 791                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 792                                 else
 793                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 794                         }
 795                 }
 796         }
 797
 798         if(IsFlying(self))
 799                 self.wasFlying = 1;
 800
 801         if(self.classname == "player")
 802         {
 803                 if(sv_doublejump)
 804                 {
 805                         self.flags &~= FL_ONGROUND;
 806                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 1', MOVE_NORMAL, self);
 807                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 808                                 self.flags |= FL_ONGROUND;
 809                 }
 810
 811                 if (self.BUTTON_JUMP)
 812                         PlayerJump ();
 813                 else
 814                         self.flags |= FL_JUMPRELEASED;
 815
 816                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 817                         CheckWaterJump ();
 818         }
 819
 820         if (self.flags & FL_WATERJUMP )
 821         {
 822                 self.velocity_x = self.movedir_x;
 823                 self.velocity_y = self.movedir_y;
 824                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 825                 {
 826                         self.flags &~= FL_WATERJUMP;
 827                         self.teleport_time = 0;
 828                 }
 829         }
 830         else if (g_bugrigs && self.classname == "player")
 831         {
 832                 RaceCarPhysics();
 833         }
 834         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 835         {
 836                 // noclipping or flying
 837                 self.flags &~= FL_ONGROUND;
 838
 839                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 840                 makevectors(self.v_angle);
 841                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 842                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 843                 // acceleration
 844                 wishdir = normalize(wishvel);
 845                 wishspeed = vlen(wishvel);
 846                 if (wishspeed > sv_maxspeed*maxspd_mod)
 847                         wishspeed = sv_maxspeed*maxspd_mod;
 848                 if (time >= self.teleport_time)
 849                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 850         }
 851         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 852         {
 853                 // swimming
 854                 self.flags &~= FL_ONGROUND;
 855
 856                 makevectors(self.v_angle);
 857                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 858                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 859                 if (wishvel == '0 0 0')
 860                         wishvel = '0 0 -60'; // drift towards bottom
 861
 862                 wishdir = normalize(wishvel);
 863                 wishspeed = vlen(wishvel);
 864                 if (wishspeed > sv_maxspeed*maxspd_mod)
 865                         wishspeed = sv_maxspeed*maxspd_mod;
 866                 wishspeed = wishspeed * 0.7;
 867
 868                 // water friction
 869                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 870
 871                 // water acceleration
 872                 PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 873         }
 874         else if (time < self.ladder_time)
 875         {
 876                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 877                 self.flags &~= FL_ONGROUND;
 878
 879                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 880                 makevectors(self.v_angle);
 881                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 882                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 883                 if (self.gravity)
 884                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 885                 else
 886                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 887                 if (self.ladder_entity.classname == "func_water")
 888                 {
 889                         f = vlen(wishvel);
 890                         if (f > self.ladder_entity.speed)
 891                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 892
 893                         self.watertype = self.ladder_entity.skin;
 894                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 895                         if ((self.origin_z + self.view_ofs_z) < f)
 896                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 897                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 898                                 self.waterlevel = WATERLEVEL_SWIMMING;
 899                         else if ((self.origin_z + self.mins_z + 1) < f)
 900                                 self.waterlevel = WATERLEVEL_WETFEET;
 901                         else
 902                         {
 903                                 self.waterlevel = WATERLEVEL_NONE;
 904                                 self.watertype = CONTENT_EMPTY;
 905                         }
 906                 }
 907                 // acceleration
 908                 wishdir = normalize(wishvel);
 909                 wishspeed = vlen(wishvel);
 910                 if (wishspeed > sv_maxspeed*maxspd_mod)
 911                         wishspeed = sv_maxspeed*maxspd_mod;
 912                 if (time >= self.teleport_time)
 913                 {
 914                         // water acceleration
 915                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 916                 }
 917         }
 918         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 919         {
 920                 //makevectors(self.v_angle_y * '0 1 0');
 921                 makevectors(self.v_angle);
 922                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 923                 // add remaining speed as Z component
 924                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 925                 // fix speedhacks :P
 926                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 927                 // add the unused velocity as up component
 928                 wishvel_z = 0;
 929
 930                 // if(self.BUTTON_JUMP)
 931                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 932
 933                 // it is now normalized, so...
 934                 float a_side, a_up, a_add, a_diff;
 935                 a_side = cvar("g_jetpack_acceleration_side");
 936                 a_up = cvar("g_jetpack_acceleration_up");
 937                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 938
 939                 wishvel_x *= a_side;
 940                 wishvel_y *= a_side;
 941                 wishvel_z *= a_up;
 942                 wishvel_z += a_add;
 943
 944                 float best;
 945                 best = 0;
 946                 //////////////////////////////////////////////////////////////////////////////////////
 947                 // finding the maximum over all vectors of above form
 948                 // with wishvel having an absolute value of 1
 949                 //////////////////////////////////////////////////////////////////////////////////////
 950                 // we're finding the maximum over
 951                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 952                 // for z in the range from -1 to 1
 953                 //////////////////////////////////////////////////////////////////////////////////////
 954                 // maximum is EITHER attained at the single extreme point:
 955                 a_diff = a_side * a_side - a_up * a_up;
 956                 if(a_diff != 0)
 957                 {
 958                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 959                         if(f > -1 && f < 1) // can it be attained?
 960                         {
 961                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 962                                 //print("middle\n");
 963                         }
 964                 }
 965                 // OR attained at z = 1:
 966                 f = (a_up + a_add) * (a_up + a_add);
 967                 if(f > best)
 968                 {
 969                         best = f;
 970                         //print("top\n");
 971                 }
 972                 // OR attained at z = -1:
 973                 f = (a_up - a_add) * (a_up - a_add);
 974                 if(f > best)
 975                 {
 976                         best = f;
 977                         //print("bottom\n");
 978                 }
 979                 best = sqrt(best);
 980                 //////////////////////////////////////////////////////////////////////////////////////
 981
 982                 //print("best possible acceleration: ", ftos(best), "\n");
 983
 984                 float fxy, fz;
 985                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 986                 if(wishvel_z - sv_gravity > 0)
 987                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 988                 else
 989                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 990
 991                 float fvel;
 992                 fvel = vlen(wishvel);
 993                 wishvel_x *= fxy;
 994                 wishvel_y *= fxy;
 995                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 996
 997                 fvel = min(1, vlen(wishvel) / best);
 998                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
 999                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
1000                 else
1001                         f = 1;
1002
1003                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1004
1005                 if (f > 0 && wishvel != '0 0 0')
1006                 {
1007                         self.velocity = self.velocity + wishvel * f * frametime;
1008                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1009                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
1010                         self.flags &~= FL_ONGROUND;
1011                         self.items |= IT_USING_JETPACK;
1012
1013                         // jetpack also inhibits health regeneration, but only for 1 second
1014                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1015                 }
1016         }
1017         else if (self.flags & FL_ONGROUND)
1018         {
1019                 // we get here if we ran out of ammo
1020                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1021                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1022
1023                 // walking
1024                 makevectors(self.v_angle_y * '0 1 0');
1025                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1026
1027                 if(!(self.lastflags & FL_ONGROUND))
1028                 {
1029                         if(cvar("speedmeter"))
1030                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1031                         if(self.lastground < time - 0.3)
1032                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1033                         if(self.jumppadcount > 1)
1034                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1035                         self.jumppadcount = 0;
1036                 }
1037
1038 #ifdef LETS_TEST_FTEQCC
1039                 if(self.velocity_x || self.velocity_y)
1040                 {
1041                         // good
1042                 }
1043                 else
1044                 {
1045                         if(self.velocity_x)
1046                                 checkclient();
1047                         if(self.velocity_y)
1048                                 checkclient();
1049                 }
1050 #endif
1051
1052                 v = self.velocity;
1053                 v_z = 0;
1054                 f = vlen(v);
1055                 if(f > 0)
1056                 {
1057                         if (f < sv_stopspeed)
1058                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1059                         else
1060                                 f = 1 - frametime * sv_friction;
1061                         if (f > 0)
1062                                 self.velocity = self.velocity * f;
1063                         else
1064                                 self.velocity = '0 0 0';
1065                 }
1066
1067                 // acceleration
1068                 wishdir = normalize(wishvel);
1069                 wishspeed = vlen(wishvel);
1070                 if (wishspeed > sv_maxspeed*maxspd_mod)
1071                         wishspeed = sv_maxspeed*maxspd_mod;
1072                 if (self.crouch)
1073                         wishspeed = wishspeed * 0.5;
1074                 if (time >= self.teleport_time)
1075                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
1076         }
1077         else
1078         {
1079                 float wishspeed0;
1080                 // we get here if we ran out of ammo
1081                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1082                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1083
1084                 if(maxspd_mod < 1)
1085                 {
1086                         maxairspd = sv_maxairspeed*maxspd_mod;
1087                         airaccel = sv_airaccelerate*maxspd_mod;
1088                 }
1089                 else
1090                 {
1091                         maxairspd = sv_maxairspeed;
1092                         airaccel = sv_airaccelerate;
1093                 }
1094                 // airborn
1095                 makevectors(self.v_angle_y * '0 1 0');
1096                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1097                 // acceleration
1098                 wishdir = normalize(wishvel);
1099                 wishspeed = wishspeed0 = vlen(wishvel);
1100                 if (wishspeed0 > sv_maxspeed*maxspd_mod)
1101                         wishspeed0 = sv_maxspeed*maxspd_mod;
1102                 if (wishspeed > maxairspd)
1103                         wishspeed = maxairspd;
1104                 if (self.crouch)
1105                         wishspeed = wishspeed * 0.5;
1106                 if (time >= self.teleport_time)
1107                 {
1108                         float accelerating;
1109                         float wishspeed2;
1110                         float airaccelqw;
1111
1112                         airaccelqw = sv_airaccel_qw;
1113                         accelerating = (self.velocity * wishdir > 0);
1114                         wishspeed2 = wishspeed;
1115
1116                         // CPM
1117                         if(sv_airstopaccelerate)
1118                                 if(self.velocity * wishdir < 0)
1119                                         airaccel = sv_airstopaccelerate*maxspd_mod;
1120                         if(self.movement_x == 0 && self.movement_y != 0)
1121                         {
1122                                 if(sv_maxairstrafespeed)
1123                                 {
1124                                         wishspeed = min(wishspeed, sv_maxairstrafespeed*maxspd_mod);
1125                                         if(sv_maxairstrafespeed < sv_maxairspeed)
1126                                                 airaccelqw = 1;
1127                                 }
1128                                 if(sv_airstrafeaccelerate)
1129                                 {
1130                                         airaccel = sv_airstrafeaccelerate*maxspd_mod;
1131                                         if(sv_airstrafeaccelerate > sv_airaccelerate)
1132                                                 airaccelqw = 1;
1133                                 }
1134                         }
1135                         // !CPM
1136
1137                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1138                                 PM_AirAccelerate(wishdir, wishspeed);
1139                         else
1140                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd);
1141
1142                         if(sv_aircontrol)
1143                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1144                 }
1145         }
1146
1147         if((g_cts || g_race) && self.classname != "observer") {
1148                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1149                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1150                         speedaward_holder = self.netname;
1151                         speedaward_lastupdate = time;
1152                 }
1153                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1154                         string rr;
1155                         if(g_cts)
1156                                 rr = CTS_RECORD;
1157                         else
1158                                 rr = RACE_RECORD;
1159                         race_send_speedaward(MSG_ALL);
1160                         speedaward_lastsent = speedaward_speed;
1161                         if (speedaward_speed > speedaward_alltimebest) {
1162                                 speedaward_alltimebest = speedaward_speed;
1163                                 speedaward_alltimebest_holder = speedaward_holder;
1164                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1165                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"), speedaward_alltimebest_holder);
1166                                 race_send_speedaward_alltimebest(MSG_ALL);
1167                         }
1168                 }
1169         }
1170 :end
1171         if(self.flags & FL_ONGROUND)
1172                 self.lastground = time;
1173
1174         self.lastflags = self.flags;
1175         self.lastclassname = self.classname;
1176 };