data/qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2
   3 float sv_accelerate;
   4 float sv_friction;
   5 float sv_maxspeed;
   6 float sv_airaccelerate;
   7 float sv_maxairspeed;
   8 float sv_stopspeed;
   9 float sv_gravity;
  10 float sv_airaccel_sideways_friction;
  11 float sv_airaccel_qw;
  12 float sv_airstopaccelerate;
  13 float sv_airstrafeaccelerate;
  14 float sv_maxairstrafespeed;
  15 float sv_aircontrol;
  16 float sv_warsowbunny_airforwardaccel;
  17 float sv_warsowbunny_accel;
  18 float sv_warsowbunny_topspeed;
  19 float sv_warsowbunny_turnaccel;
  20 float sv_warsowbunny_backtosideratio;
  21
  22 .float ladder_time;
  23 .entity ladder_entity;
  24 .float gravity;
  25 .float swamp_slowdown;
  26 .float lastflags;
  27 .float lastground;
  28 .float wasFlying;
  29 .float spectatorspeed;
  30
  31 #define SHTEST_DELTA 10
  32 #define SHTEST_THRESHOLD 1.1
  33 .float shtest_next;
  34 .float shtest_accumulator;
  35 .float doublejump_nextjumptime;
  36
  37 /*
  38 =============
  39 PlayerJump
  40
  41 When you press the jump key
  42 =============
  43 */
  44 void PlayerJump (void)
  45 {
  46         float mjumpheight;
  47
  48         mjumpheight = cvar("sv_jumpvelocity");
  49         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  50         {
  51                 if (self.watertype == CONTENT_WATER)
  52                         self.velocity_z = 200;
  53                 else if (self.watertype == CONTENT_SLIME)
  54                         self.velocity_z = 80;
  55                 else
  56                         self.velocity_z = 50;
  57
  58                 return;
  59         }
  60
  61         if (!(self.flags & FL_ONGROUND))
  62                 return;
  63
  64         if(!sv_pogostick)
  65                 if (!(self.flags & FL_JUMPRELEASED))
  66                         return;
  67
  68         if(self.health <= g_bloodloss)
  69                 return;
  70
  71         if(sv_doublejump)
  72                 if(time < self.doublejump_nextjumptime)
  73                         return;
  74
  75         if(g_runematch)
  76         {
  77                 if(self.runes & RUNE_SPEED)
  78                 {
  79                         if(self.runes & CURSE_SLOW)
  80                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  81                         else
  82                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  83                 }
  84                 else if(self.runes & CURSE_SLOW)
  85                 {
  86                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  87                 }
  88         }
  89
  90         if(g_minstagib && (self.items & IT_INVINCIBLE))
  91         {
  92                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  93         }
  94
  95         if(!(self.lastflags & FL_ONGROUND))
  96         {
  97                 if(cvar("speedmeter"))
  98                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
  99                 if(self.lastground < time - 0.3)
 100                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 101                 if(self.jumppadcount > 1)
 102                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 103                 self.jumppadcount = 0;
 104         }
 105
 106         self.velocity_z = self.velocity_z + mjumpheight;
 107         self.oldvelocity_z = self.velocity_z;
 108
 109         self.flags &~= FL_ONGROUND;
 110         self.flags &~= FL_JUMPRELEASED;
 111
 112         if (self.crouch)
 113                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 114         else
 115                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 116
 117         if(g_jump_grunt)
 118                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 119
 120         if(sv_doublejump)
 121         {
 122                 // we're moving upwards at self.velocity_z
 123                 // only allow jumping after we got 3 units upwards
 124                 // so we for sure leave the FL_ONGROUND check
 125                 //
 126                 // but as this sucks because of factoring in gravity, we'll just do it
 127                 // for 4 units, and constant velocity
 128                 self.doublejump_nextjumptime = time + 4 / max(40, self.velocity_z); // max 0.1s blocking of jumps
 129         }
 130 }
 131
 132 void CheckWaterJump()
 133 {
 134         local vector start, end;
 135
 136 // check for a jump-out-of-water
 137         makevectors (self.angles);
 138         start = self.origin;
 139         start_z = start_z + 8;
 140         v_forward_z = 0;
 141         normalize(v_forward);
 142         end = start + v_forward*24;
 143         traceline (start, end, TRUE, self);
 144         if (trace_fraction < 1)
 145         {       // solid at waist
 146                 start_z = start_z + self.maxs_z - 8;
 147                 end = start + v_forward*24;
 148                 self.movedir = trace_plane_normal * -50;
 149                 traceline (start, end, TRUE, self);
 150                 if (trace_fraction == 1)
 151                 {       // open at eye level
 152                         self.flags |= FL_WATERJUMP;
 153                         self.velocity_z = 225;
 154                         self.flags &~= FL_JUMPRELEASED;
 155                         self.teleport_time = time + 2;  // safety net
 156                         return;
 157                 }
 158         }
 159 };
 160
 161 float racecar_angle(float forward, float down)
 162 {
 163         float ret, angle_mult;
 164
 165         if(forward < 0)
 166         {
 167                 forward = -forward;
 168                 down = -down;
 169         }
 170
 171         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 172
 173         angle_mult = forward / (800 + forward);
 174
 175         if(ret > 180)
 176                 return ret * angle_mult + 360 * (1 - angle_mult);
 177         else
 178                 return ret * angle_mult;
 179 }
 180
 181 void RaceCarPhysics()
 182 {
 183         // using this move type for "big rigs"
 184         // the engine does not push the entity!
 185
 186         float accel, steer, f;
 187         vector angles_save, rigvel;
 188
 189         angles_save = self.angles;
 190         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 191         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 192
 193         if(g_bugrigs_reverse_speeding)
 194         {
 195                 if(accel < 0)
 196                 {
 197                         // back accel is DIGITAL
 198                         // to prevent speedhack
 199                         if(accel < -0.5)
 200                                 accel = -1;
 201                         else
 202                                 accel = 0;
 203                 }
 204         }
 205
 206         self.angles_x = 0;
 207         self.angles_z = 0;
 208         makevectors(self.angles); // new forward direction!
 209
 210         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 211         {
 212                 float myspeed, upspeed, steerfactor, accelfactor;
 213
 214                 myspeed = self.velocity * v_forward;
 215                 upspeed = self.velocity * v_up;
 216
 217                 // responsiveness factor for steering and acceleration
 218                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 219                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 220
 221                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 222                         steerfactor = -myspeed * g_bugrigs_steer;
 223                 else
 224                         steerfactor = -myspeed * f * g_bugrigs_steer;
 225
 226                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 227                         accelfactor = g_bugrigs_accel;
 228                 else
 229                         accelfactor = f * g_bugrigs_accel;
 230                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 231
 232                 if(accel < 0)
 233                 {
 234                         if(myspeed > 0)
 235                         {
 236                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 237                         }
 238                         else
 239                         {
 240                                 if(!g_bugrigs_reverse_speeding)
 241                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 242                         }
 243                 }
 244                 else
 245                 {
 246                         if(myspeed >= 0)
 247                         {
 248                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 249                         }
 250                         else
 251                         {
 252                                 if(g_bugrigs_reverse_stopping)
 253                                         myspeed = 0;
 254                                 else
 255                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 256                         }
 257                 }
 258                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 259                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 260
 261                 self.angles_y += steer * frametime * steerfactor; // apply steering
 262                 makevectors(self.angles); // new forward direction!
 263
 264                 myspeed += accel * accelfactor * frametime;
 265
 266                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 267         }
 268         else
 269         {
 270                 myspeed = vlen(self.velocity);
 271
 272                 // responsiveness factor for steering and acceleration
 273                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 274                 steerfactor = -myspeed * f;
 275                 self.angles_y += steer * frametime * steerfactor; // apply steering
 276
 277                 rigvel = self.velocity;
 278                 makevectors(self.angles); // new forward direction!
 279         }
 280
 281         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 282         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 283         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 284         //MAXIMA: solve(total_acceleration(v) = 0, v);
 285
 286         if(g_bugrigs_planar_movement)
 287         {
 288                 vector rigvel_xy, neworigin, up;
 289                 float mt;
 290
 291                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 292                 rigvel_xy = rigvel;
 293                 rigvel_xy_z = 0;
 294
 295                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 296                         mt = MOVE_NORMAL;
 297                 else
 298                         mt = MOVE_NOMONSTERS;
 299
 300                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 301                 up = trace_endpos - self.origin;
 302
 303                 // BUG RIGS: align the move to the surface instead of doing collision testing
 304                 // can we move?
 305                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 306
 307                 // align to surface
 308                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 309
 310                 if(trace_fraction < 0.5)
 311                 {
 312                         trace_fraction = 1;
 313                         neworigin = self.origin;
 314                 }
 315                 else
 316                         neworigin = trace_endpos;
 317
 318                 if(trace_fraction < 1)
 319                 {
 320                         // now set angles_x so that the car points parallel to the surface
 321                         self.angles = vectoangles(
 322                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 323                                         +
 324                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 325                                         +
 326                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 327                                         );
 328                         self.flags |= FL_ONGROUND;
 329                 }
 330                 else
 331                 {
 332                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 333                         self.flags &~= FL_ONGROUND;
 334                 }
 335
 336                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 337                 self.movetype = MOVETYPE_NOCLIP;
 338         }
 339         else
 340         {
 341                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 342                 self.velocity = rigvel;
 343                 self.movetype = MOVETYPE_FLY;
 344         }
 345
 346         trace_fraction = 1;
 347         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 348         if(trace_fraction != 1)
 349         {
 350                 self.angles = vectoangles2(
 351                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 352                                 +
 353                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 354                                 +
 355                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 356                                 trace_plane_normal
 357                                 );
 358         }
 359         else
 360         {
 361                 vector vel_local;
 362
 363                 vel_local_x = v_forward * self.velocity;
 364                 vel_local_y = v_right * self.velocity;
 365                 vel_local_z = v_up * self.velocity;
 366
 367                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 368                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 369         }
 370
 371         // smooth the angles
 372         vector vf1, vu1, smoothangles;
 373         makevectors(self.angles);
 374         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 375         if(f == 0)
 376                 f = 1;
 377         vf1 = v_forward * f;
 378         vu1 = v_up * f;
 379         makevectors(angles_save);
 380         vf1 = vf1 + v_forward * (1 - f);
 381         vu1 = vu1 + v_up * (1 - f);
 382         smoothangles = vectoangles2(vf1, vu1);
 383         self.angles_x = -smoothangles_x;
 384         self.angles_z =  smoothangles_z;
 385 }
 386
 387 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 388 {
 389         float zspeed, xyspeed, dot, k;
 390
 391         if(self.movement_x == 0 || self.movement_y != 0)
 392                 return; // can't control movement if not moving forward or backward
 393
 394         zspeed = self.velocity_z;
 395         self.velocity_z = 0;
 396         xyspeed = vlen(self.velocity);
 397         self.velocity = normalize(self.velocity);
 398
 399         dot = self.velocity * wishdir;
 400         k = 32;
 401         k *= sv_aircontrol*dot*dot*frametime;
 402
 403         if(dot > 0) // we can't change direction while slowing down
 404                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 405
 406         self.velocity = self.velocity * xyspeed;
 407         self.velocity_z = zspeed;
 408 }
 409
 410 void PM_Accelerate(vector wishdir, float wishspeed, float accel, float accelqw, float sidefric)
 411 {
 412         float vel_straight;
 413         float vel_z;
 414         vector vel_perpend;
 415         float addspeed;
 416
 417         vel_straight = self.velocity * wishdir;
 418         vel_z = self.velocity_z;
 419         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 420
 421         addspeed = wishspeed - vel_straight;
 422         if(addspeed > 0)
 423                 vel_straight = vel_straight + min(addspeed, accel * frametime * wishspeed) * accelqw;
 424         if(wishspeed > 0)
 425                 vel_straight = vel_straight + min(wishspeed, accel * frametime * wishspeed) * (1 - accelqw);
 426
 427         vel_perpend = vel_perpend * (1 - frametime * wishspeed * sidefric);
 428
 429         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 430 }
 431
 432 void PM_AirAccelerate(vector wishdir, float wishspeed)
 433 {
 434         vector curvel, wishvel, acceldir, curdir;
 435         float addspeed, accelspeed, curspeed, f;
 436         float dot;
 437
 438         if(wishspeed == 0)
 439                 return;
 440
 441         curvel = self.velocity;
 442         curvel_z = 0;
 443         curspeed = vlen(curvel);
 444
 445         if(wishspeed > curspeed * 1.01)
 446         {
 447                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * sv_maxspeed * frametime);
 448         }
 449         else
 450         {
 451                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - sv_maxspeed));
 452                 wishspeed = max(curspeed, sv_maxspeed) + sv_warsowbunny_accel * f * sv_maxspeed * frametime;
 453         }
 454         wishvel = wishdir * wishspeed;
 455         acceldir = wishvel - curvel;
 456         addspeed = vlen(acceldir);
 457         acceldir = normalize(acceldir);
 458
 459         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * sv_maxspeed * frametime);
 460
 461         if(sv_warsowbunny_backtosideratio < 1)
 462         {
 463                 curdir = normalize(curvel);
 464                 dot = acceldir * curdir;
 465                 if(dot < 0)
 466                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 467         }
 468
 469         self.velocity += accelspeed * acceldir;
 470 }
 471
 472 .vector movement_old;
 473 .float buttons_old;
 474 .vector v_angle_old;
 475 .string lastclassname;
 476
 477 void Nixnex_GiveCurrentWeapon();
 478 .float() PlayerPhysplug;
 479
 480 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 481 .float specialcommand_pos;
 482 void SpecialCommand()
 483 {
 484 #ifdef TETRIS
 485         TetrisImpulse();
 486 #else
 487         if(sv_cheats || self.maycheat)
 488                 self.impulse = 99;
 489         else
 490                 print("A hollow voice says \"Plugh\".\n");
 491 #endif
 492 }
 493
 494 void SV_PlayerPhysics()
 495 {
 496         local vector wishvel, wishdir, v;
 497         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 498         string temps;
 499         float buttons_prev;
 500         float not_allowed_to_move;
 501         string c;
 502
 503         if(g_race || g_cts)
 504         {
 505                 // if record times matter
 506                 // ensure nothing EVIL is being done (i.e. strafebot)
 507                 // this hinders joystick users though
 508                 // but it still gives SOME analog control
 509                 // TODO implement this for engine cl_movement code too (basically, clipping to the four axes)
 510                 wishvel_x = fabs(self.movement_x);
 511                 wishvel_y = fabs(self.movement_y);
 512                 if(wishvel_x != 0 && wishvel_y != 0 && wishvel_x != wishvel_y)
 513                 {
 514                         wishvel_z = 0;
 515                         wishspeed = vlen(wishvel);
 516                         if(wishvel_x >= 2 * wishvel_y)
 517                         {
 518                                 // pure X motion
 519                                 if(self.movement_x > 0)
 520                                         self.movement_x = wishspeed;
 521                                 else
 522                                         self.movement_x = -wishspeed;
 523                                 self.movement_y = 0;
 524                         }
 525                         else if(wishvel_y >= 2 * wishvel_x)
 526                         {
 527                                 // pure Y motion
 528                                 self.movement_x = 0;
 529                                 if(self.movement_y > 0)
 530                                         self.movement_y = wishspeed;
 531                                 else
 532                                         self.movement_y = -wishspeed;
 533                         }
 534                         else
 535                         {
 536                                 // diagonal
 537                                 if(self.movement_x > 0)
 538                                         self.movement_x = 0.70710678118654752440 * wishspeed;
 539                                 else
 540                                         self.movement_x = -0.70710678118654752440 * wishspeed;
 541                                 if(self.movement_y > 0)
 542                                         self.movement_y = 0.70710678118654752440 * wishspeed;
 543                                 else
 544                                         self.movement_y = -0.70710678118654752440 * wishspeed;
 545                         }
 546                 }
 547         }
 548
 549         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 550
 551         if(!buttons)
 552                 c = "x";
 553         else if(buttons == 1)
 554                 c = "1";
 555         else if(buttons == 2)
 556                 c = " ";
 557         else if(buttons == 128)
 558                 c = "s";
 559         else if(buttons == 256)
 560                 c = "w";
 561         else if(buttons == 512)
 562                 c = "a";
 563         else if(buttons == 1024)
 564                 c = "d";
 565         else
 566                 c = "?";
 567
 568         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 569         {
 570                 self.specialcommand_pos += 1;
 571                 if(self.specialcommand_pos >= strlen(specialcommand))
 572                 {
 573                         self.specialcommand_pos = 0;
 574                         SpecialCommand();
 575                         return;
 576                 }
 577         }
 578         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 579                 self.specialcommand_pos = 0;
 580
 581     if(self.PlayerPhysplug)
 582         if(self.PlayerPhysplug())
 583             return;
 584
 585         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 586         {
 587                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 588                         self.parm_idlesince = time;
 589         }
 590         buttons_prev = self.buttons_old;
 591         self.buttons_old = buttons;
 592         self.movement_old = self.movement;
 593         self.v_angle_old = self.v_angle;
 594
 595         if(time < self.nickspamtime)
 596         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 597         {
 598                 // slight annoyance for nick change scripts
 599                 self.movement = -1 * self.movement;
 600                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 601
 602                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 603                 {
 604                         self.angles_x = random() * 360;
 605                         self.angles_y = random() * 360;
 606                         // at least I'm not forcing retardedview by also assigning to angles_z
 607                         self.fixangle = 1;
 608                 }
 609         }
 610
 611         if(time > self.shtest_next)
 612         {
 613                 if(self.shtest_next > 0)
 614                 {
 615                         // self.shtest_accumulator:
 616                         //   started at time - SHTEST_DELTA
 617                         //   should be at SHTEST_DELTA
 618                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 619                         if(shtest_score > SHTEST_THRESHOLD)
 620                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 621                         else if(cvar("developer_shtest"))
 622                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 623                 }
 624                 self.shtest_next = time + SHTEST_DELTA;
 625                 self.shtest_accumulator = 0;
 626         }
 627         self.shtest_accumulator += frametime;
 628
 629         if (clienttype(self) == CLIENTTYPE_BOT)
 630                 bot_think();
 631
 632         self.items &~= IT_USING_JETPACK;
 633
 634         if(self.classname == "player")
 635         {
 636                 if(self.race_penalty)
 637                         if(time > self.race_penalty)
 638                                 self.race_penalty = 0;
 639
 640                 not_allowed_to_move = 0;
 641                 if(self.race_penalty)
 642                         not_allowed_to_move = 1;
 643                 if(!cvar("sv_ready_restart_after_countdown"))
 644                 if(time < game_starttime)
 645                         not_allowed_to_move = 1;
 646
 647                 if(not_allowed_to_move)
 648                 {
 649                         self.velocity = '0 0 0';
 650                         self.movetype = MOVETYPE_NONE;
 651                         self.disableclientprediction = 2;
 652                 }
 653                 else if(self.disableclientprediction == 2)
 654                 {
 655                         if(self.movetype == MOVETYPE_NONE)
 656                                 self.movetype = MOVETYPE_WALK;
 657                         self.disableclientprediction = 0;
 658                 }
 659         }
 660
 661         if (self.movetype == MOVETYPE_NONE)
 662                 return;
 663
 664         if (self.punchangle != '0 0 0')
 665         {
 666                 f = vlen(self.punchangle) - 10 * frametime;
 667                 if (f > 0)
 668                         self.punchangle = normalize(self.punchangle) * f;
 669                 else
 670                         self.punchangle = '0 0 0';
 671         }
 672
 673         if (self.punchvector != '0 0 0')
 674         {
 675                 f = vlen(self.punchvector) - 30 * frametime;
 676                 if (f > 0)
 677                         self.punchvector = normalize(self.punchvector) * f;
 678                 else
 679                         self.punchvector = '0 0 0';
 680         }
 681
 682         maxspd_mod = 1;
 683
 684         if(g_runematch)
 685         {
 686                 if(self.runes & RUNE_SPEED)
 687                 {
 688                         if(self.runes & CURSE_SLOW)
 689                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 690                         else
 691                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 692                 }
 693                 else if(self.runes & CURSE_SLOW)
 694                 {
 695                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 696                 }
 697         }
 698
 699         if(g_minstagib && (self.items & IT_INVINCIBLE))
 700         {
 701                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 702         }
 703
 704         if(g_nexball && self.ballcarried)
 705         {
 706                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 707         }
 708
 709         swampspd_mod = 1;
 710         if(self.in_swamp) {
 711                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 712         }
 713
 714         if(self.classname != "player")
 715         {
 716                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 717                 if(!self.spectatorspeed)
 718                         self.spectatorspeed = maxspd_mod;
 719                 if(self.impulse && self.impulse <= 19)
 720                 {
 721                         if(self.lastclassname != "player")
 722                         {
 723                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 724                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 725                                 else if(self.impulse == 11)
 726                                         self.spectatorspeed = maxspd_mod;
 727                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 728                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 729                                 else if(self.impulse >= 1 && self.impulse <= 9)
 730                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 731                         } // otherwise just clear
 732                         self.impulse = 0;
 733                 }
 734                 maxspd_mod = self.spectatorspeed;
 735         }
 736
 737         spd = max(sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 738         if(self.speed != spd)
 739         {
 740                 self.speed = spd;
 741                 temps = ftos(spd);
 742                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 743                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 744                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 745                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 746         }
 747
 748         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 749         swampspd_mod = 1;
 750
 751         // if dead, behave differently
 752         if (self.deadflag)
 753                 goto end;
 754
 755         if (!self.fixangle && !g_bugrigs)
 756         {
 757                 self.angles_x = 0;
 758                 self.angles_y = self.v_angle_y;
 759                 self.angles_z = 0;
 760         }
 761
 762         if(self.flags & FL_ONGROUND)
 763         if(self.wasFlying)
 764         {
 765                 self.wasFlying = 0;
 766
 767                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 768                 if(time >= self.ladder_time)
 769                 if not(self.hook)
 770                 {
 771                         self.nextstep = time + 0.3 + random() * 0.1;
 772                         trace_dphitq3surfaceflags = 0;
 773                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 774                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 775                         {
 776                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 777                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 778                                 else
 779                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 780                         }
 781                 }
 782         }
 783
 784         if(IsFlying(self))
 785                 self.wasFlying = 1;
 786
 787         if(self.classname == "player")
 788         {
 789                 if(sv_doublejump)
 790                 {
 791                         self.flags &~= FL_ONGROUND;
 792                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 1', MOVE_NORMAL, self);
 793                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 794                                 self.flags |= FL_ONGROUND;
 795                 }
 796
 797                 if (self.BUTTON_JUMP)
 798                         PlayerJump ();
 799                 else
 800                         self.flags |= FL_JUMPRELEASED;
 801
 802                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 803                         CheckWaterJump ();
 804         }
 805
 806         if (self.flags & FL_WATERJUMP )
 807         {
 808                 self.velocity_x = self.movedir_x;
 809                 self.velocity_y = self.movedir_y;
 810                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 811                 {
 812                         self.flags &~= FL_WATERJUMP;
 813                         self.teleport_time = 0;
 814                 }
 815         }
 816         else if (g_bugrigs && self.classname == "player")
 817         {
 818                 RaceCarPhysics();
 819         }
 820         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 821         {
 822                 // noclipping or flying
 823                 self.flags &~= FL_ONGROUND;
 824
 825                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 826                 makevectors(self.v_angle);
 827                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 828                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 829                 // acceleration
 830                 wishdir = normalize(wishvel);
 831                 wishspeed = vlen(wishvel);
 832                 if (wishspeed > sv_maxspeed*maxspd_mod)
 833                         wishspeed = sv_maxspeed*maxspd_mod;
 834                 if (time >= self.teleport_time)
 835                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 836         }
 837         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 838         {
 839                 // swimming
 840                 self.flags &~= FL_ONGROUND;
 841
 842                 makevectors(self.v_angle);
 843                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 844                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 845                 if (wishvel == '0 0 0')
 846                         wishvel = '0 0 -60'; // drift towards bottom
 847
 848                 wishdir = normalize(wishvel);
 849                 wishspeed = vlen(wishvel);
 850                 if (wishspeed > sv_maxspeed*maxspd_mod)
 851                         wishspeed = sv_maxspeed*maxspd_mod;
 852                 wishspeed = wishspeed * 0.7;
 853
 854                 // water friction
 855                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 856
 857                 // water acceleration
 858                 PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 859         }
 860         else if (time < self.ladder_time)
 861         {
 862                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 863                 self.flags &~= FL_ONGROUND;
 864
 865                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 866                 makevectors(self.v_angle);
 867                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 868                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 869                 if (self.gravity)
 870                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 871                 else
 872                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 873                 if (self.ladder_entity.classname == "func_water")
 874                 {
 875                         f = vlen(wishvel);
 876                         if (f > self.ladder_entity.speed)
 877                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 878
 879                         self.watertype = self.ladder_entity.skin;
 880                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 881                         if ((self.origin_z + self.view_ofs_z) < f)
 882                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 883                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 884                                 self.waterlevel = WATERLEVEL_SWIMMING;
 885                         else if ((self.origin_z + self.mins_z + 1) < f)
 886                                 self.waterlevel = WATERLEVEL_WETFEET;
 887                         else
 888                         {
 889                                 self.waterlevel = WATERLEVEL_NONE;
 890                                 self.watertype = CONTENT_EMPTY;
 891                         }
 892                 }
 893                 // acceleration
 894                 wishdir = normalize(wishvel);
 895                 wishspeed = vlen(wishvel);
 896                 if (wishspeed > sv_maxspeed*maxspd_mod)
 897                         wishspeed = sv_maxspeed*maxspd_mod;
 898                 if (time >= self.teleport_time)
 899                 {
 900                         // water acceleration
 901                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 902                 }
 903         }
 904         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 905         {
 906                 //makevectors(self.v_angle_y * '0 1 0');
 907                 makevectors(self.v_angle);
 908                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 909                 // add remaining speed as Z component
 910                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 911                 // fix speedhacks :P
 912                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 913                 // add the unused velocity as up component
 914                 wishvel_z = 0;
 915
 916                 // if(self.BUTTON_JUMP)
 917                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 918
 919                 // it is now normalized, so...
 920                 float a_side, a_up, a_add, a_diff;
 921                 a_side = cvar("g_jetpack_acceleration_side");
 922                 a_up = cvar("g_jetpack_acceleration_up");
 923                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 924
 925                 wishvel_x *= a_side;
 926                 wishvel_y *= a_side;
 927                 wishvel_z *= a_up;
 928                 wishvel_z += a_add;
 929
 930                 float best;
 931                 best = 0;
 932                 //////////////////////////////////////////////////////////////////////////////////////
 933                 // finding the maximum over all vectors of above form
 934                 // with wishvel having an absolute value of 1
 935                 //////////////////////////////////////////////////////////////////////////////////////
 936                 // we're finding the maximum over
 937                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 938                 // for z in the range from -1 to 1
 939                 //////////////////////////////////////////////////////////////////////////////////////
 940                 // maximum is EITHER attained at the single extreme point:
 941                 a_diff = a_side * a_side - a_up * a_up;
 942                 if(a_diff != 0)
 943                 {
 944                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 945                         if(f > -1 && f < 1) // can it be attained?
 946                         {
 947                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 948                                 //print("middle\n");
 949                         }
 950                 }
 951                 // OR attained at z = 1:
 952                 f = (a_up + a_add) * (a_up + a_add);
 953                 if(f > best)
 954                 {
 955                         best = f;
 956                         //print("top\n");
 957                 }
 958                 // OR attained at z = -1:
 959                 f = (a_up - a_add) * (a_up - a_add);
 960                 if(f > best)
 961                 {
 962                         best = f;
 963                         //print("bottom\n");
 964                 }
 965                 best = sqrt(best);
 966                 //////////////////////////////////////////////////////////////////////////////////////
 967
 968                 //print("best possible acceleration: ", ftos(best), "\n");
 969
 970                 float fxy, fz;
 971                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 972                 if(wishvel_z - sv_gravity > 0)
 973                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 974                 else
 975                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 976
 977                 float fvel;
 978                 fvel = vlen(wishvel);
 979                 wishvel_x *= fxy;
 980                 wishvel_y *= fxy;
 981                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 982
 983                 fvel = min(1, vlen(wishvel) / best);
 984                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
 985                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
 986                 else
 987                         f = 1;
 988
 989                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 990
 991                 if (f > 0 && wishvel != '0 0 0')
 992                 {
 993                         self.velocity = self.velocity + wishvel * f * frametime;
 994                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 995                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
 996                         self.flags &~= FL_ONGROUND;
 997                         self.items |= IT_USING_JETPACK;
 998
 999                         // jetpack also inhibits health regeneration, but only for 1 second
1000                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1001                 }
1002         }
1003         else if (self.flags & FL_ONGROUND)
1004         {
1005                 // we get here if we ran out of ammo
1006                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1007                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1008
1009                 // walking
1010                 makevectors(self.v_angle_y * '0 1 0');
1011                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1012
1013                 if(!(self.lastflags & FL_ONGROUND))
1014                 {
1015                         if(cvar("speedmeter"))
1016                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1017                         if(self.lastground < time - 0.3)
1018                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1019                         if(self.jumppadcount > 1)
1020                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1021                         self.jumppadcount = 0;
1022                 }
1023
1024 #ifdef LETS_TEST_FTEQCC
1025                 if(self.velocity_x || self.velocity_y)
1026                 {
1027                         // good
1028                 }
1029                 else
1030                 {
1031                         if(self.velocity_x)
1032                                 checkclient();
1033                         if(self.velocity_y)
1034                                 checkclient();
1035                 }
1036 #endif
1037
1038                 v = self.velocity;
1039                 v_z = 0;
1040                 f = vlen(v);
1041                 if(f > 0)
1042                 {
1043                         if (f < sv_stopspeed)
1044                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1045                         else
1046                                 f = 1 - frametime * sv_friction;
1047                         if (f > 0)
1048                                 self.velocity = self.velocity * f;
1049                         else
1050                                 self.velocity = '0 0 0';
1051                 }
1052
1053                 // acceleration
1054                 wishdir = normalize(wishvel);
1055                 wishspeed = vlen(wishvel);
1056                 if (wishspeed > sv_maxspeed*maxspd_mod)
1057                         wishspeed = sv_maxspeed*maxspd_mod;
1058                 if (self.crouch)
1059                         wishspeed = wishspeed * 0.5;
1060                 if (time >= self.teleport_time)
1061                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
1062         }
1063         else
1064         {
1065                 // we get here if we ran out of ammo
1066                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1067                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1068
1069                 if(maxspd_mod < 1)
1070                 {
1071                         maxairspd = sv_maxairspeed*maxspd_mod;
1072                         airaccel = sv_airaccelerate*maxspd_mod;
1073                 }
1074                 else
1075                 {
1076                         maxairspd = sv_maxairspeed;
1077                         airaccel = sv_airaccelerate;
1078                 }
1079                 // airborn
1080                 makevectors(self.v_angle_y * '0 1 0');
1081                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1082                 // acceleration
1083                 wishdir = normalize(wishvel);
1084                 wishspeed = vlen(wishvel);
1085                 if (wishspeed > maxairspd)
1086                         wishspeed = maxairspd;
1087                 if (self.crouch)
1088                         wishspeed = wishspeed * 0.5;
1089                 if (time >= self.teleport_time)
1090                 {
1091                         float accelerating;
1092                         float wishspeed2;
1093                         float airaccelqw;
1094
1095                         airaccelqw = sv_airaccel_qw;
1096                         accelerating = (self.velocity * wishdir > 0);
1097                         wishspeed2 = wishspeed;
1098
1099                         // CPM
1100                         if(sv_airstopaccelerate)
1101                                 if(self.velocity * wishdir < 0)
1102                                         airaccel = sv_airstopaccelerate*maxspd_mod;
1103                         if(self.movement_x == 0 && self.movement_y != 0)
1104                         {
1105                                 if(sv_maxairstrafespeed)
1106                                 {
1107                                         wishspeed = min(wishspeed, sv_maxairstrafespeed*maxspd_mod);
1108                                         if(sv_maxairstrafespeed < sv_maxairspeed)
1109                                                 airaccelqw = 1;
1110                                 }
1111                                 if(sv_airstrafeaccelerate)
1112                                 {
1113                                         airaccel = sv_airstrafeaccelerate*maxspd_mod;
1114                                         if(sv_airstrafeaccelerate > sv_airaccelerate)
1115                                                 airaccelqw = 1;
1116                                 }
1117                         }
1118                         // !CPM
1119
1120                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1121                                 PM_AirAccelerate(wishdir, wishspeed);
1122                         else
1123                                 PM_Accelerate(wishdir, wishspeed, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd);
1124
1125                         if(sv_aircontrol)
1126                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1127                 }
1128         }
1129
1130 :end
1131         if(self.flags & FL_ONGROUND)
1132                 self.lastground = time;
1133
1134         self.lastflags = self.flags;
1135         self.lastclassname = self.classname;
1136 };