data/qcsrc/server/cl_client.qc

   1 .float spectatee_status;
   2 .float zoomstate;
   3 .float bloodloss_timer;
   4
   5 .entity clientdata;
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(to.classname == "spectator")
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(e2.classname == "spectator")
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74
  75 #define SPAWNPOINT_SCORE frags
  76
  77 .string netname_previous;
  78
  79 void spawnfunc_info_player_survivor (void)
  80 {
  81         spawnfunc_info_player_deathmatch();
  82 }
  83
  84 void spawnfunc_info_player_start (void)
  85 {
  86         spawnfunc_info_player_deathmatch();
  87 }
  88
  89 void spawnfunc_info_player_deathmatch (void)
  90 {
  91         self.classname = "info_player_deathmatch";
  92         relocate_spawnpoint();
  93 }
  94
  95 void spawnpoint_use()
  96 {
  97         if(teams_matter)
  98         if(have_team_spawns)
  99         {
 100                 self.team = activator.team;
 101                 some_spawn_has_been_used = 1;
 102         }
 103 };
 104
 105 // Returns:
 106 //   -1 if a spawn can't be used
 107 //   otherwise, a weight of the spawnpoint
 108 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 109 {
 110         float shortest, thisdist;
 111         entity player;
 112
 113         // filter out spots for the wrong team
 114         if(teamcheck)
 115         if(spot.team != teamcheck)
 116                 return -1;
 117
 118         if(race_spawns)
 119                 if(spot.target == "")
 120                         return -1;
 121
 122         // filter out spots for assault
 123         if(spot.target != "") {
 124                 local entity ent;
 125                 float good, found;
 126                 ent = find(world, targetname, spot.target);
 127                 while(ent) {
 128                         found = 1;
 129                         if(ent.classname == "target_objective")
 130                         {
 131                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 132                                         return -1;
 133                                 good = 1;
 134                         }
 135                         else if(ent.classname == "trigger_race_checkpoint")
 136                         {
 137                                 if(self.classname == "player") // spectators may spawn everywhere
 138                                 {
 139                                         if(g_race_qualifying)
 140                                         {
 141                                                 // spawn at first
 142                                                 if(ent.race_checkpoint != 0)
 143                                                         return -1;
 144                                                 if(spot.race_place != race_lowest_place_spawn)
 145                                                         return -1;
 146                                         }
 147                                         else
 148                                         {
 149                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 150                                                         return -1;
 151                                                 float pl;
 152                                                 pl = self.race_place;
 153                                                 if(pl > race_highest_place_spawn)
 154                                                         pl = 0;
 155                                                 if(spot.race_place != pl)
 156                                                         return -1;
 157                                         }
 158                                 }
 159                                 good = 1;
 160                         }
 161                         else
 162                         {
 163                         }
 164                         ent = find(ent, targetname, spot.target);
 165                 }
 166
 167                 if(found && !good)
 168                         return -1;
 169         }
 170
 171         player = playerlist;
 172         shortest = vlen(world.maxs - world.mins);
 173         for(player = playerlist; player; player = player.chain)
 174                 if (player != self)
 175                 {
 176                         thisdist = vlen(player.origin - spot.origin);
 177                         if (thisdist < shortest)
 178                                 shortest = thisdist;
 179                 }
 180         return shortest;
 181 }
 182
 183 float spawn_allbad;
 184 float spawn_allgood;
 185 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 186 {
 187         local entity spot, spotlist, spotlistend;
 188         spawn_allgood = TRUE;
 189         spawn_allbad = TRUE;
 190
 191         spotlist = world;
 192         spotlistend = world;
 193
 194         for(spot = firstspot; spot; spot = spot.chain)
 195         {
 196                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 197
 198                 if(cvar("spawn_debugview"))
 199                 {
 200                         setmodel(spot, "models/runematch/rune.mdl");
 201                         if(spot.SPAWNPOINT_SCORE < mindist)
 202                         {
 203                                 spot.colormod = '1 0 0';
 204                                 spot.scale = 1;
 205                         }
 206                         else
 207                         {
 208                                 spot.colormod = '0 1 0';
 209                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 210                         }
 211                 }
 212
 213                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 214                 {
 215                         if(spot.SPAWNPOINT_SCORE < mindist)
 216                         {
 217                                 // too short distance
 218                                 spawn_allgood = FALSE;
 219                         }
 220                         else
 221                         {
 222                                 // perfect
 223                                 spawn_allbad = FALSE;
 224
 225                                 if(spotlistend)
 226                                         spotlistend.chain = spot;
 227                                 spotlistend = spot;
 228                                 if(!spotlist)
 229                                         spotlist = spot;
 230
 231                                 /*
 232                                 if(teamcheck)
 233                                 if(spot.team != teamcheck)
 234                                         error("invalid spawn added");
 235
 236                                 print("added ", etos(spot), "\n");
 237                                 */
 238                         }
 239                 }
 240         }
 241         if(spotlistend)
 242                 spotlistend.chain = world;
 243
 244         /*
 245                 entity e;
 246                 if(teamcheck)
 247                         for(e = spotlist; e; e = e.chain)
 248                         {
 249                                 print("seen ", etos(e), "\n");
 250                                 if(e.team != teamcheck)
 251                                         error("invalid spawn found");
 252                         }
 253         */
 254
 255         return spotlist;
 256 }
 257
 258 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 259 {
 260         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 261         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 262         local entity spot;
 263
 264         RandomSelection_Init();
 265         for(spot = firstspot; spot; spot = spot.chain)
 266                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 267
 268         return RandomSelection_chosen_ent;
 269 }
 270
 271 /*
 272 =============
 273 SelectSpawnPoint
 274
 275 Finds a point to respawn
 276 =============
 277 */
 278 entity SelectSpawnPoint (float anypoint)
 279 {
 280         local float teamcheck;
 281         local entity firstspot_new;
 282         local entity spot, firstspot, playerlist;
 283
 284         spot = find (world, classname, "testplayerstart");
 285         if (spot)
 286                 return spot;
 287
 288         teamcheck = 0;
 289
 290         if(!anypoint && have_team_spawns)
 291                 teamcheck = self.team;
 292
 293         // get the list of players
 294         playerlist = findchain(classname, "player");
 295         // get the entire list of spots
 296         firstspot = findchain(classname, "info_player_deathmatch");
 297         // filter out the bad ones
 298         // (note this returns the original list if none survived)
 299         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 300         if(!firstspot_new)
 301                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 302         firstspot = firstspot_new;
 303
 304         // there is 50/50 chance of choosing a random spot or the furthest spot
 305         // (this means that roughly every other spawn will be furthest, so you
 306         // usually won't get fragged at spawn twice in a row)
 307         if (arena_roundbased)
 308         {
 309                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 310                 if(firstspot_new)
 311                         firstspot = firstspot_new;
 312                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 313         }
 314         else if (random() > cvar("g_spawn_furthest"))
 315                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 316         else
 317                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 318
 319         if(cvar("spawn_debugview"))
 320         {
 321                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 322
 323                 entity e;
 324                 if(teamcheck)
 325                         for(e = firstspot; e; e = e.chain)
 326                                 if(e.team != teamcheck)
 327                                         error("invalid spawn found");
 328         }
 329
 330         if (!spot)
 331         {
 332                 if(cvar("spawn_debug"))
 333                         GotoNextMap();
 334                 else
 335                 {
 336                         if(some_spawn_has_been_used)
 337                                 return world; // team can't spawn any more, because of actions of other team
 338                         else
 339                                 error("Cannot find a spawn point - please fix the map!");
 340                 }
 341         }
 342
 343         return spot;
 344 }
 345
 346 /*
 347 =============
 348 CheckPlayerModel
 349
 350 Checks if the argument string can be a valid playermodel.
 351 Returns a valid one in doubt.
 352 =============
 353 */
 354 string FallbackPlayerModel = "models/player/marine.zym";
 355 string CheckPlayerModel(string plyermodel) {
 356         if(strlen(plyermodel) < 4)
 357                 return FallbackPlayerModel;
 358         if( substring(plyermodel,0,14) != "models/player/")
 359                 return FallbackPlayerModel;
 360         else if(cvar("sv_servermodelsonly"))
 361         {
 362                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 363                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 364                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 365                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 366                         return FallbackPlayerModel;
 367                 if(plyermodel != strtolower(plyermodel))
 368                         return FallbackPlayerModel;
 369                 if(!fexists(plyermodel))
 370                         return FallbackPlayerModel;
 371         }
 372         return plyermodel;
 373 }
 374
 375 /*
 376 =============
 377 Client_customizeentityforclient
 378
 379 LOD reduction
 380 =============
 381 */
 382 float Client_customizeentityforclient()
 383 {
 384 #ifdef ALLOW_VARIABLE_LOD
 385         // self: me
 386         // other: the player viewing me
 387         float distance;
 388         float f;
 389
 390         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 391                 return TRUE;
 392
 393         if(other.cvar_cl_playerdetailreduction <= 0)
 394         {
 395                 if(other.cvar_cl_playerdetailreduction <= -2)
 396                         self.modelindex = self.modelindex_lod2;
 397                 else if(other.cvar_cl_playerdetailreduction <= -1)
 398                         self.modelindex = self.modelindex_lod1;
 399                 else
 400                         self.modelindex = self.modelindex_lod0;
 401         }
 402         else
 403         {
 404                 distance = vlen(self.origin - other.origin);
 405                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 406                 if(f > 10000)
 407                         self.modelindex = self.modelindex_lod2;
 408                 else if(f > 5000)
 409                         self.modelindex = self.modelindex_lod1;
 410                 else
 411                         self.modelindex = self.modelindex_lod0;
 412         }
 413 #endif
 414
 415         return TRUE;
 416 }
 417
 418 void UpdatePlayerSounds();
 419 void setmodel_lod(entity e, string modelname)
 420 {
 421 #ifdef ALLOW_VARIABLE_LOD
 422         string s;
 423
 424         // FIXME: this only supports 3-letter extensions
 425         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 426         if(fexists(s))
 427         {
 428                 precache_model(s);
 429                 setmodel(e, s); // players have high precision
 430                 self.modelindex_lod1 = self.modelindex;
 431         }
 432         else
 433                 self.modelindex_lod1 = -1;
 434
 435         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 436         if(fexists(s))
 437         {
 438                 precache_model(s);
 439                 setmodel(e, s); // players have high precision
 440                 self.modelindex_lod2 = self.modelindex;
 441         }
 442         else
 443                 self.modelindex_lod2 = -1;
 444
 445         precache_model(modelname);
 446         setmodel(e, modelname); // players have high precision
 447         self.modelindex_lod0 = self.modelindex;
 448
 449         if(self.modelindex_lod1 < 0)
 450                 self.modelindex_lod1 = self.modelindex;
 451
 452         if(self.modelindex_lod2 < 0)
 453                 self.modelindex_lod2 = self.modelindex;
 454 #else
 455         precache_model(modelname);
 456         setmodel(e, modelname); // players have high precision
 457 #endif
 458         player_setupanimsformodel();
 459         UpdatePlayerSounds();
 460 }
 461
 462 /*
 463 =============
 464 PutObserverInServer
 465
 466 putting a client as observer in the server
 467 =============
 468 */
 469 void PutObserverInServer (void)
 470 {
 471         entity  spot;
 472
 473         race_PreSpawnObserver();
 474
 475         spot = SelectSpawnPoint (TRUE);
 476         if(!spot)
 477                 error("No spawnpoints for observers?!?\n");
 478         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 479
 480         if(clienttype(self) == CLIENTTYPE_REAL)
 481         {
 482                 msg_entity = self;
 483                 WriteByte(MSG_ONE, SVC_SETVIEW);
 484                 WriteEntity(MSG_ONE, self);
 485         }
 486
 487         DropAllRunes(self);
 488         kh_Key_DropAll(self, TRUE);
 489
 490         Portal_ClearAll(self);
 491
 492         if(self.flagcarried)
 493                 DropFlag(self.flagcarried, world, world);
 494
 495         WaypointSprite_PlayerDead();
 496
 497         if(self.killcount != -666)
 498         {
 499                 if(g_lms)
 500                 {
 501                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 502                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 503                         else
 504                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 505                 }
 506                 else
 507                         bprint ("^4", self.netname, "^4 is spectating now\n");
 508         }
 509
 510         PlayerScore_Clear(self); // clear scores when needed
 511
 512         self.spectatortime = time;
 513
 514         self.classname = "observer";
 515         self.iscreature = FALSE;
 516         self.health = -666;
 517         self.takedamage = DAMAGE_NO;
 518         self.solid = SOLID_NOT;
 519         self.movetype = MOVETYPE_NOCLIP;
 520         self.flags = FL_CLIENT | FL_NOTARGET;
 521         self.armorvalue = 666;
 522         self.effects = 0;
 523         self.armorvalue = cvar("g_balance_armor_start");
 524         self.pauserotarmor_finished = 0;
 525         self.pauserothealth_finished = 0;
 526         self.pauseregen_finished = 0;
 527         self.damageforcescale = 0;
 528         self.death_time = 0;
 529         self.dead_frame = 0;
 530         self.alpha = 0;
 531         self.scale = 0;
 532         self.fade_time = 0;
 533         self.pain_frame = 0;
 534         self.pain_finished = 0;
 535         self.strength_finished = 0;
 536         self.invincible_finished = 0;
 537         self.pushltime = 0;
 538         self.think = SUB_Null;
 539         self.nextthink = 0;
 540         self.hook_time = 0;
 541         self.runes = 0;
 542         self.deadflag = DEAD_NO;
 543         self.angles = spot.angles;
 544         self.angles_z = 0;
 545         self.fixangle = TRUE;
 546         self.crouch = FALSE;
 547
 548         self.view_ofs = PL_VIEW_OFS;
 549         setorigin (self, spot.origin);
 550         setsize (self, '0 0 0', '0 0 0');
 551         self.oldorigin = self.origin;
 552         self.items = 0;
 553         self.weapons = 0;
 554         self.model = "";
 555         self.modelindex = 0;
 556         self.weapon = 0;
 557         self.weaponmodel = "";
 558         self.weaponentity = world;
 559         self.killcount = -666;
 560         self.velocity = '0 0 0';
 561         self.avelocity = '0 0 0';
 562         self.punchangle = '0 0 0';
 563         self.punchvector = '0 0 0';
 564         self.oldvelocity = self.velocity;
 565         self.customizeentityforclient = Client_customizeentityforclient;
 566
 567         if(g_arena)
 568         {
 569                 if(self.version_mismatch)
 570                 {
 571                         Spawnqueue_Unmark(self);
 572                         Spawnqueue_Remove(self);
 573                 }
 574                 else
 575                 {
 576                         Spawnqueue_Insert(self);
 577                 }
 578         }
 579         else if(g_lms)
 580         {
 581                 // Only if the player cannot play at all
 582                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 583                         self.frags = FRAGS_SPECTATOR;
 584                 else
 585                         self.frags = FRAGS_LMS_LOSER;
 586         }
 587         else
 588                 self.frags = FRAGS_SPECTATOR;
 589 }
 590
 591 float RestrictSkin(float s)
 592 {
 593         if(!teams_matter)
 594                 return s;
 595         if(s == 6)
 596                 return 6;
 597         return mod(s, 3);
 598 }
 599
 600 void FixPlayermodel()
 601 {
 602         local string defaultmodel;
 603         local float defaultskin;
 604         local vector m1, m2;
 605
 606         defaultmodel = "";
 607
 608         if(cvar("sv_defaultcharacter") == 1) {
 609                 defaultskin = 0;
 610
 611                 if(teams_matter)
 612                 {
 613                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 614                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 615                 }
 616
 617                 if(defaultmodel == "")
 618                 {
 619                         defaultmodel = cvar_string("sv_defaultplayermodel");
 620                         defaultskin = cvar("sv_defaultplayerskin");
 621                 }
 622         }
 623
 624         if(self.modelindex == 0)
 625         {
 626                 if(self.model != "")
 627                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 628                 self.model = ""; // force the != checks to return true
 629         }
 630
 631         if(defaultmodel != "")
 632         {
 633                 if (defaultmodel != self.model)
 634                 {
 635                         m1 = self.mins;
 636                         m2 = self.maxs;
 637                         setmodel_lod (self, defaultmodel);
 638                         setsize (self, m1, m2);
 639                 }
 640
 641                 self.skin = defaultskin;
 642         } else {
 643                 if (self.playermodel != self.model)
 644                 {
 645                         self.playermodel = CheckPlayerModel(self.playermodel);
 646                         m1 = self.mins;
 647                         m2 = self.maxs;
 648                         setmodel_lod (self, self.playermodel);
 649                         setsize (self, m1, m2);
 650                 }
 651
 652                 self.skin = RestrictSkin(stof(self.playerskin));
 653         }
 654
 655         if(!teams_matter)
 656                 if(strlen(cvar_string("sv_defaultplayercolors")))
 657                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 658                                 setcolor(self, cvar("sv_defaultplayercolors"));
 659 }
 660
 661 void PlayerTouchExplode(entity p1, entity p2)
 662 {
 663         vector org;
 664         org = (p1.origin + p2.origin) * 0.5;
 665         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 666
 667         te_explosion(org);
 668
 669         entity e;
 670         e = spawn();
 671         setorigin(e, org);
 672         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 673         remove(e);
 674 }
 675
 676 /*
 677 =============
 678 PutClientInServer
 679
 680 Called when a client spawns in the server
 681 =============
 682 */
 683 //void() ctf_playerchanged;
 684 void PutClientInServer (void)
 685 {
 686         if(clienttype(self) == CLIENTTYPE_BOT)
 687         {
 688                 self.classname = "player";
 689         }
 690         else if(clienttype(self) == CLIENTTYPE_REAL)
 691         {
 692                 msg_entity = self;
 693                 WriteByte(MSG_ONE, SVC_SETVIEW);
 694                 WriteEntity(MSG_ONE, self);
 695         }
 696
 697         // player is dead and becomes observer
 698         // FIXME fix LMS scoring for new system
 699         if(g_lms)
 700         {
 701                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 702                         self.classname = "observer";
 703         }
 704
 705         if(g_arena)
 706         if(!self.spawned)
 707                 self.classname = "observer";
 708
 709         if(self.classname == "player") {
 710                 entity spot, oldself;
 711
 712                 race_PreSpawn();
 713
 714                 spot = SelectSpawnPoint (FALSE);
 715                 if(!spot)
 716                 {
 717                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 718                         return; // spawn failed
 719                 }
 720
 721                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 722                 self.campingrifle_bulletcounter = 0;
 723
 724                 self.classname = "player";
 725                 self.iscreature = TRUE;
 726                 self.movetype = MOVETYPE_WALK;
 727                 self.solid = SOLID_SLIDEBOX;
 728                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 729                 self.frags = FRAGS_PLAYER;
 730                 if(independent_players)
 731                         MAKE_INDEPENDENT_PLAYER(self);
 732                 self.flags = FL_CLIENT;
 733                 self.takedamage = DAMAGE_AIM;
 734                 if(g_minstagib)
 735                         self.effects = EF_FULLBRIGHT;
 736                 else
 737                         self.effects = 0;
 738                 self.air_finished = time + 12;
 739                 self.dmg = 2;
 740
 741                 if(inWarmupStage)
 742                 {
 743                         self.ammo_shells = warmup_start_ammo_shells;
 744                         self.ammo_nails = warmup_start_ammo_nails;
 745                         self.ammo_rockets = warmup_start_ammo_rockets;
 746                         self.ammo_cells = warmup_start_ammo_cells;
 747                         self.health = warmup_start_health;
 748                         self.armorvalue = warmup_start_armorvalue;
 749                         self.weapons = warmup_start_weapons;
 750                 }
 751                 else
 752                 {
 753                         self.ammo_shells = start_ammo_shells;
 754                         self.ammo_nails = start_ammo_nails;
 755                         self.ammo_rockets = start_ammo_rockets;
 756                         self.ammo_cells = start_ammo_cells;
 757                         self.health = start_health;
 758                         self.armorvalue = start_armorvalue;
 759                         self.weapons = start_weapons;
 760                 }
 761                 self.items = start_items;
 762                 self.switchweapon = w_getbestweapon(self);
 763                 self.cnt = self.switchweapon;
 764                 self.weapon = 0;
 765                 self.jump_interval = time;
 766
 767                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 768                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 769                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 770                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 771                 //extend the pause of rotting if client was reset at the beginning of the countdown
 772                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 773                         self.spawnshieldtime += game_starttime - time;
 774                         self.pauserotarmor_finished += game_starttime - time;
 775                         self.pauserothealth_finished += game_starttime - time;
 776                         self.pauseregen_finished += game_starttime - time;
 777                 }
 778                 self.damageforcescale = 2;
 779                 self.death_time = 0;
 780                 self.dead_frame = 0;
 781                 self.alpha = 0;
 782                 self.scale = 0;
 783                 self.fade_time = 0;
 784                 self.pain_frame = 0;
 785                 self.pain_finished = 0;
 786                 self.strength_finished = 0;
 787                 self.invincible_finished = 0;
 788                 self.pushltime = 0;
 789                 //self.speed_finished = 0;
 790                 //self.slowmo_finished = 0;
 791                 // players have no think function
 792                 self.think = SUB_Null;
 793                 self.nextthink = 0;
 794                 self.hook_time = 0;
 795                 self.dmg_team = 0;
 796
 797                 self.runes = 0;
 798
 799                 self.deadflag = DEAD_NO;
 800
 801                 self.angles = spot.angles;
 802
 803                 self.angles_z = 0; // never spawn tilted even if the spot says to
 804                 self.fixangle = TRUE; // turn this way immediately
 805                 self.velocity = '0 0 0';
 806                 self.avelocity = '0 0 0';
 807                 self.punchangle = '0 0 0';
 808                 self.punchvector = '0 0 0';
 809                 self.oldvelocity = self.velocity;
 810
 811                 msg_entity = self;
 812                 WRITESPECTATABLE_MSG_ONE({
 813                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 814                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 815                 });
 816
 817                 self.customizeentityforclient = Client_customizeentityforclient;
 818
 819                 self.model = "";
 820                 FixPlayermodel();
 821
 822                 self.crouch = FALSE;
 823                 self.view_ofs = PL_VIEW_OFS;
 824                 setsize (self, PL_MIN, PL_MAX);
 825                 self.spawnorigin = spot.origin;
 826                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 827                 // don't reset back to last position, even if new position is stuck in solid
 828                 self.oldorigin = self.origin;
 829
 830                 if(g_arena)
 831                 {
 832                         Spawnqueue_Remove(self);
 833                         Spawnqueue_Mark(self);
 834                 }
 835
 836                 self.event_damage = PlayerDamage;
 837
 838                 self.bot_attack = TRUE;
 839
 840                 self.statdraintime = time + 5;
 841                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 842
 843                 if(self.killcount == -666) {
 844                         PlayerScore_Clear(self);
 845                         self.killcount = 0;
 846                 }
 847
 848                 self.cnt = WEP_LASER;
 849                 self.nixnex_lastchange_id = -1;
 850
 851                 CL_SpawnWeaponentity();
 852                 self.alpha = default_player_alpha;
 853                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 854                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 855
 856                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 857                 self.lms_traveled_distance = 0;
 858                 self.speedrunning = FALSE;
 859
 860                 race_PostSpawn(spot);
 861
 862                 if(cvar("spawn_debug"))
 863                 {
 864                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 865                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 866                 }
 867
 868                 //stuffcmd(self, "chase_active 0");
 869                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 870
 871                 if (cvar("g_spawnsound"))
 872                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 873
 874                 if(g_assault) {
 875                         if(self.team == assault_attacker_team)
 876                                 centerprint(self, "You are attacking!");
 877                         else
 878                                 centerprint(self, "You are defending!");
 879                 }
 880
 881                 target_voicescript_clear(self);
 882
 883                 oldself = self;
 884                 self = spot;
 885                         activator = oldself;
 886                                 SUB_UseTargets();
 887                         activator = world;
 888                 self = oldself;
 889
 890         } else if(self.classname == "observer") {
 891                 PutObserverInServer ();
 892         }
 893
 894         //if(g_ctf)
 895         //      ctf_playerchanged();
 896 }
 897
 898 float ClientInit_SendEntity(entity to, float sf)
 899 {
 900         float i;
 901         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 902         WriteShort(MSG_ENTITY, CSQC_REVISION);
 903         for(i = 1; i <= 24; ++i)
 904                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
 905         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
 906         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
 907         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
 908
 909         if(sv_foginterval && world.fog != "")
 910                 WriteString(MSG_ENTITY, world.fog);
 911         else
 912                 WriteString(MSG_ENTITY, "");
 913
 914         return TRUE;
 915 }
 916
 917 void ClientInit_Spawn()
 918 {
 919         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
 920 }
 921
 922 /*
 923 =============
 924 SetNewParms
 925 =============
 926 */
 927 void SetNewParms (void)
 928 {
 929         // initialize parms for a new player
 930         parm1 = -(86400 * 366);
 931 }
 932
 933 /*
 934 =============
 935 SetChangeParms
 936 =============
 937 */
 938 void SetChangeParms (void)
 939 {
 940         // save parms for level change
 941         parm1 = self.parm_idlesince - time;
 942 }
 943
 944 /*
 945 =============
 946 DecodeLevelParms
 947 =============
 948 */
 949 void DecodeLevelParms (void)
 950 {
 951         // load parms
 952         self.parm_idlesince = parm1;
 953         if(self.parm_idlesince == -(86400 * 366))
 954                 self.parm_idlesince = time;
 955
 956         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 957         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 958 }
 959
 960 /*
 961 =============
 962 ClientKill
 963
 964 Called when a client types 'kill' in the console
 965 =============
 966 */
 967
 968 void ClientKill_Now_TeamChange()
 969 {
 970         if(self.killindicator_teamchange == -1)
 971         {
 972                 self.team = -1;
 973                 JoinBestTeam( self, FALSE, FALSE );
 974         }
 975         else
 976         {
 977                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 978         }
 979 }
 980
 981 void ClientKill_Now()
 982 {
 983         if(self.killindicator_teamchange)
 984                 ClientKill_Now_TeamChange();
 985
 986         // in any case:
 987         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 988
 989         if(self.killindicator)
 990         {
 991                 dprint("Cleaned up after a leaked kill indicator.\n");
 992                 remove(self.killindicator);
 993                 self.killindicator = world;
 994         }
 995 }
 996 void KillIndicator_Think()
 997 {
 998         if (!self.owner.modelindex)
 999         {
1000                 self.owner.killindicator = world;
1001                 remove(self);
1002                 return;
1003         }
1004
1005         if(self.cnt <= 0)
1006         {
1007                 self = self.owner;
1008                 ClientKill_Now(); // no oldself needed
1009                 return;
1010         }
1011         else
1012         {
1013                 if(self.cnt <= 10)
1014                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1015                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1016                 {
1017                         if(self.cnt <= 10)
1018                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1019                         if(self.owner.killindicator_teamchange)
1020                         {
1021                                 if(self.owner.killindicator_teamchange == -1)
1022                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1023                                 else
1024                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1025                         }
1026                         else
1027                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1028                 }
1029                 self.nextthink = time + 1;
1030                 self.cnt -= 1;
1031         }
1032 }
1033
1034 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1035 {
1036         float killtime;
1037         entity e;
1038         killtime = cvar("g_balance_kill_delay");
1039
1040         self.killindicator_teamchange = targetteam;
1041
1042         if(!self.killindicator)
1043         {
1044                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1045                 {
1046                         ClientKill_Now();
1047                 }
1048                 else
1049                 {
1050                         self.killindicator = spawn();
1051                         self.killindicator.owner = self;
1052                         self.killindicator.scale = 0.5;
1053                         setattachment(self.killindicator, self, "");
1054                         setorigin(self.killindicator, '0 0 52');
1055                         self.killindicator.think = KillIndicator_Think;
1056                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1057                         self.killindicator.cnt = ceil(killtime);
1058                         self.killindicator.count = bound(0, ceil(killtime), 10);
1059                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1060
1061                         for(e = world; (e = find(e, classname, "body")) != world; )
1062                         {
1063                                 if(e.enemy != self)
1064                                         continue;
1065                                 e.killindicator = spawn();
1066                                 e.killindicator.owner = e;
1067                                 e.killindicator.scale = 0.5;
1068                                 setattachment(e.killindicator, e, "");
1069                                 setorigin(e.killindicator, '0 0 52');
1070                                 e.killindicator.think = KillIndicator_Think;
1071                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1072                                 e.killindicator.cnt = ceil(killtime);
1073                         }
1074                         self.lip = 0;
1075                 }
1076         }
1077         if(self.killindicator)
1078         {
1079                 if(targetteam)
1080                         self.killindicator.colormod = TeamColor(targetteam);
1081                 else
1082                         self.killindicator.colormod = '0 0 0';
1083         }
1084 }
1085
1086 void ClientKill (void)
1087 {
1088         ClientKill_TeamChange(0);
1089 }
1090
1091 void DoTeamChange(float destteam)
1092 {
1093         float t, c0;
1094         if(!cvar("teamplay"))
1095         {
1096                 if(destteam >= 0)
1097                         SetPlayerColors(self, destteam);
1098                 return;
1099         }
1100         if(self.classname == "player")
1101         if(destteam == -1)
1102         {
1103                 CheckAllowedTeams(self);
1104                 t = FindSmallestTeam(self, TRUE);
1105                 switch(self.team)
1106                 {
1107                         case COLOR_TEAM1: c0 = c1; break;
1108                         case COLOR_TEAM2: c0 = c2; break;
1109                         case COLOR_TEAM3: c0 = c3; break;
1110                         case COLOR_TEAM4: c0 = c4; break;
1111                         default:          c0 = 999;
1112                 }
1113                 switch(t)
1114                 {
1115                         case 1:
1116                                 if(c0 > c1)
1117                                         destteam = COLOR_TEAM1;
1118                                 break;
1119                         case 2:
1120                                 if(c0 > c2)
1121                                         destteam = COLOR_TEAM2;
1122                                 break;
1123                         case 3:
1124                                 if(c0 > c3)
1125                                         destteam = COLOR_TEAM3;
1126                                 break;
1127                         case 4:
1128                                 if(c0 > c4)
1129                                         destteam = COLOR_TEAM4;
1130                                 break;
1131                 }
1132                 if(destteam == -1)
1133                         return;
1134         }
1135         if(destteam == self.team && !self.killindicator)
1136                 return;
1137         ClientKill_TeamChange(destteam);
1138 }
1139
1140 void FixClientCvars(entity e)
1141 {
1142         // send prediction settings to the client
1143         stuffcmd(e, "\nin_bindmap 0 0\n");
1144         /*
1145          * we no longer need to stuff this. Remove this comment block if you feel
1146          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1147         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1148         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1149         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1150         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1151         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1152         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1153         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1154         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1155         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1156         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1157         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1158         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1159         stuffcmd(e, "cl_movement_edgefriction 1\n");
1160          */
1161 }
1162
1163 /*
1164 =============
1165 ClientConnect
1166
1167 Called when a client connects to the server
1168 =============
1169 */
1170 //void ctf_clientconnect();
1171 string ColoredTeamName(float t);
1172 void DecodeLevelParms (void);
1173 //void dom_player_join_team(entity pl);
1174 void ClientConnect (void)
1175 {
1176         local string s;
1177
1178         if(self.flags & FL_CLIENT)
1179         {
1180                 print("Warning: ClientConnect, but already connected!\n");
1181                 return;
1182         }
1183
1184         if(Ban_MaybeEnforceBan(self))
1185                 return;
1186
1187         DecodeLevelParms();
1188
1189         self.classname = "player_joining";
1190
1191         self.flags = FL_CLIENT;
1192         self.version_nagtime = time + 10 + random() * 10;
1193
1194         if(player_count<0)
1195         {
1196                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1197                 player_count = 0;
1198         }
1199
1200         PlayerScore_Attach(self);
1201         ClientData_Attach();
1202
1203         bot_clientconnect();
1204
1205         race_PreSpawnObserver();
1206
1207         //if(g_domination)
1208         //      dom_player_join_team(self);
1209
1210         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1211                 self.classname = "observer";
1212         } else {
1213                 if(cvar("teamplay"))
1214                 {
1215                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1216                         {
1217                                 self.classname = "player";
1218                                 campaign_bots_may_start = 1;
1219                                 JoinBestTeam(self, FALSE, TRUE);
1220                         }
1221                         else
1222                         {
1223                                 self.classname = "observer"; // do it anyway
1224                         }
1225                 }
1226                 else
1227                 {
1228                         self.classname = "player";
1229                         campaign_bots_may_start = 1;
1230                 }
1231         }
1232
1233         self.playerid = (playerid_last = playerid_last + 1);
1234         if(cvar("sv_eventlog"))
1235         {
1236                 if(clienttype(self) == CLIENTTYPE_REAL)
1237                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1238                 else
1239                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1240                 s = strcat(":team:", ftos(self.playerid), ":");
1241                 s = strcat(s, ftos(self.team));
1242                 GameLogEcho(s);
1243         }
1244         self.netname_previous = strzone(self.netname);
1245
1246         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1247
1248         bprint ("^4",self.netname);
1249         bprint ("^4 connected");
1250
1251         if(g_domination || g_ctf)
1252         {
1253                 bprint(" and joined the ");
1254                 bprint(ColoredTeamName(self.team));
1255         }
1256
1257         bprint("\n");
1258
1259         self.welcomemessage_time = 0;
1260
1261         stuffcmd(self, strcat(clientstuff, "\n"));
1262         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1263         stuffcmd(self, "cl_particles_reloadeffects\n");
1264
1265         FixClientCvars(self);
1266
1267         // spawnfunc_waypoint sprites
1268         WaypointSprite_InitClient(self);
1269
1270         // Wazat's grappling hook
1271         SetGrappleHookBindings();
1272
1273         // get autoswitch state from player when he toggles it
1274         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1275
1276         // get version info from player
1277         stuffcmd(self, "cmd clientversion $gameversion\n");
1278
1279         // get other cvars from player
1280         GetCvars(0);
1281
1282         // set cvar for team scoreboard
1283         if (teams_matter)
1284         {
1285                 local float t;
1286                 t = cvar("teamplay");
1287                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1288                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1289         }
1290         else
1291                 stuffcmd(self, "set teamplay 0\n");
1292
1293         // notify about available teams
1294         if(teamplay)
1295         {
1296                 CheckAllowedTeams(self);
1297                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1298                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1299         }
1300         else
1301                 stuffcmd(self, "set _teams_available 0\n");
1302
1303         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1304
1305         if(g_arena)
1306         {
1307                 self.classname = "observer";
1308                 Spawnqueue_Insert(self);
1309         }
1310         /*else if(g_ctf)
1311         {
1312                 ctf_clientconnect();
1313         }*/
1314
1315         if(teams_matter)
1316                 attach_entcs();
1317
1318         bot_relinkplayerlist();
1319
1320         self.spectatortime = time;
1321         if(blockSpectators)
1322         {
1323                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1324         }
1325
1326         self.jointime = time;
1327         self.allowedTimeouts = cvar("sv_timeout_number");
1328
1329         if(clienttype(self) == CLIENTTYPE_REAL)
1330         {
1331                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1332
1333                 if(cvar("g_bugrigs"))
1334                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1335         }
1336
1337         if(g_lms)
1338         {
1339                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1340                 {
1341                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1342                         self.frags = FRAGS_SPECTATOR;
1343                 }
1344         }
1345
1346         if(!sv_foginterval && world.fog != "")
1347                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1348 }
1349
1350 /*
1351 =============
1352 ClientDisconnect
1353
1354 Called when a client disconnects from the server
1355 =============
1356 */
1357 .entity chatbubbleentity;
1358 .entity teambubbleentity;
1359 void ReadyCount();
1360 void ClientDisconnect (void)
1361 {
1362         if not(self.flags & FL_CLIENT)
1363         {
1364                 print("Warning: ClientDisconnect without ClientConnect\n");
1365                 return;
1366         }
1367
1368         bot_clientdisconnect();
1369
1370         if(teams_matter)
1371                 detach_entcs();
1372
1373         if(cvar("sv_eventlog"))
1374                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1375         bprint ("^4",self.netname);
1376         bprint ("^4 disconnected\n");
1377
1378         DropAllRunes(self);
1379         kh_Key_DropAll(self, TRUE);
1380
1381         Portal_ClearAll(self);
1382
1383         if(self.flagcarried)
1384                 DropFlag(self.flagcarried, world, world);
1385
1386         // Here, everything has been done that requires this player to be a client.
1387
1388         self.flags &~= FL_CLIENT;
1389
1390         if (self.chatbubbleentity)
1391                 remove (self.chatbubbleentity);
1392
1393         if (self.teambubbleentity)
1394                 remove (self.teambubbleentity);
1395
1396         if (self.killindicator)
1397                 remove (self.killindicator);
1398
1399         WaypointSprite_PlayerGone();
1400
1401         bot_relinkplayerlist();
1402
1403         // remove laserdot
1404         if(self.weaponentity)
1405                 if(self.weaponentity.lasertarget)
1406                         remove(self.weaponentity.lasertarget);
1407
1408         if(g_arena)
1409         {
1410                 Spawnqueue_Unmark(self);
1411                 Spawnqueue_Remove(self);
1412         }
1413
1414         ClientData_Detach();
1415         PlayerScore_Detach(self);
1416
1417         if(self.netname_previous)
1418                 strunzone(self.netname_previous);
1419
1420         ClearPlayerSounds();
1421
1422         self.playerid = 0;
1423         ReadyCount();
1424
1425         // free cvars
1426         GetCvars(-1);
1427 }
1428
1429 .float BUTTON_CHAT;
1430 void ChatBubbleThink()
1431 {
1432         self.nextthink = time;
1433         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1434         {
1435                 if(self.owner) // but why can that ever be world?
1436                         self.owner.chatbubbleentity = world;
1437                 remove(self);
1438                 return;
1439         }
1440         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1441                 self.model = self.mdl;
1442         else
1443                 self.model = "";
1444 };
1445
1446 void UpdateChatBubble()
1447 {
1448         if (!self.modelindex)
1449                 return;
1450         // spawn a chatbubble entity if needed
1451         if (!self.chatbubbleentity)
1452         {
1453                 self.chatbubbleentity = spawn();
1454                 self.chatbubbleentity.owner = self;
1455                 self.chatbubbleentity.exteriormodeltoclient = self;
1456                 self.chatbubbleentity.think = ChatBubbleThink;
1457                 self.chatbubbleentity.nextthink = time;
1458                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1459                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1460                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1461                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1462                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1463                 self.chatbubbleentity.model = "";
1464                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1465         }
1466 }
1467
1468
1469 void TeamBubbleThink()
1470 {
1471         self.nextthink = time;
1472         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1473         {
1474                 if(self.owner) // but why can that ever be world?
1475                         self.owner.teambubbleentity = world;
1476                 remove(self);
1477                 return;
1478         }
1479 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1480         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1481                 self.model = "";
1482         else
1483                 self.model = self.mdl;
1484
1485 };
1486
1487 float TeamBubble_customizeentityforclient()
1488 {
1489         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1490 }
1491
1492 void UpdateTeamBubble()
1493 {
1494         if (!self.modelindex || !cvar("teamplay"))
1495                 return;
1496         // spawn a teambubble entity if needed
1497         if (!self.teambubbleentity && cvar("teamplay"))
1498         {
1499                 self.teambubbleentity = spawn();
1500                 self.teambubbleentity.owner = self;
1501                 self.teambubbleentity.exteriormodeltoclient = self;
1502                 self.teambubbleentity.think = TeamBubbleThink;
1503                 self.teambubbleentity.nextthink = time;
1504                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1505 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1506                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1507                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1508                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1509                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1510                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1511                 self.teambubbleentity.effects = EF_LOWPRECISION;
1512         }
1513 }
1514
1515 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1516 // added to the model skins
1517 /*void UpdateColorModHack()
1518 {
1519         local float c;
1520         c = self.clientcolors & 15;
1521         // LordHavoc: only bothering to support white, green, red, yellow, blue
1522              if (teamplay == 0) self.colormod = '0 0 0';
1523         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1524         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1525         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1526         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1527         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1528         else self.colormod = '1 1 1';
1529 };*/
1530
1531 void respawn(void)
1532 {
1533         CopyBody(1);
1534         self.effects |= EF_NODRAW; // prevent another CopyBody
1535         PutClientInServer();
1536 }
1537
1538 /**
1539  * When sv_timeout is used this function returs strings like
1540  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1541  * Called by centerprint functions
1542  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1543  */
1544 string getTimeoutText(float addOneSecond) {
1545         if (!cvar("sv_timeout") || !timeoutStatus)
1546                 return "";
1547
1548         local string retStr;
1549         if (timeoutStatus == 1) {
1550                 if (addOneSecond == 1) {
1551                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1552                 }
1553                 else {
1554                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1555                 }
1556                 return retStr;
1557         }
1558         else if (timeoutStatus == 2) {
1559                 if (addOneSecond) {
1560                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1561                         //don't show messages like "Timeout ends in 0 seconds"...
1562                         if ((remainingTimeoutTime + 1) > 0)
1563                                 return retStr;
1564                         else
1565                                 return "";
1566                 }
1567                 else {
1568                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1569                         //don't show messages like "Timeout ends in 0 seconds"...
1570                         if (remainingTimeoutTime > 0)
1571                                 return retStr;
1572                         else
1573                                 return "";
1574                 }
1575         }
1576         else return "";
1577 }
1578
1579 void player_powerups (void)
1580 {
1581         if (g_minstagib)
1582         {
1583                 if (self.items & IT_STRENGTH)
1584                 {
1585                         if (time > self.strength_finished)
1586                         {
1587                                 self.alpha = default_player_alpha;
1588                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1589                                 self.items &~= IT_STRENGTH;
1590                                 sprint(self, "^3Invisibility has worn off\n");
1591                         }
1592                 }
1593                 else
1594                 {
1595                         if (time < self.strength_finished)
1596                         {
1597                                 self.alpha = g_minstagib_invis_alpha;
1598                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1599                                 self.items |= IT_STRENGTH;
1600                                 sprint(self, "^3You are invisible\n");
1601                         }
1602                 }
1603
1604                 if (self.items & IT_INVINCIBLE)
1605                 {
1606                         if (time > self.invincible_finished)
1607                         {
1608                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1609                                 sprint(self, "^3Speed has worn off\n");
1610                         }
1611                 }
1612                 else
1613                 {
1614                         if (time < self.invincible_finished)
1615                         {
1616                                 self.items = self.items | IT_INVINCIBLE;
1617                                 sprint(self, "^3You are on speed\n");
1618                         }
1619                 }
1620                 return;
1621         }
1622
1623         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1624         if (self.items & IT_STRENGTH)
1625         {
1626                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1627                 if (time > self.strength_finished)
1628                 {
1629                         self.items = self.items - (self.items & IT_STRENGTH);
1630                         sprint(self, "^3Strength has worn off\n");
1631                 }
1632         }
1633         else
1634         {
1635                 if (time < self.strength_finished)
1636                 {
1637                         self.items = self.items | IT_STRENGTH;
1638                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1639                 }
1640         }
1641         if (self.items & IT_INVINCIBLE)
1642         {
1643                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1644                 if (time > self.invincible_finished)
1645                 {
1646                         self.items = self.items - (self.items & IT_INVINCIBLE);
1647                         sprint(self, "^3Shield has worn off\n");
1648                 }
1649         }
1650         else
1651         {
1652                 if (time < self.invincible_finished)
1653                 {
1654                         self.items = self.items | IT_INVINCIBLE;
1655                         sprint(self, "^3Shield surrounds you\n");
1656                 }
1657         }
1658
1659         if (cvar("g_fullbrightplayers"))
1660                 self.effects = self.effects | EF_FULLBRIGHT;
1661
1662         // midair gamemode: damage only while in the air
1663         // if in midair mode, being on ground grants temporary invulnerability
1664         // (this is so that multishot weapon don't clear the ground flag on the
1665         // first damage in the frame, leaving the player vulnerable to the
1666         // remaining hits in the same frame)
1667         if (self.flags & FL_ONGROUND)
1668         if (g_midair)
1669                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1670
1671         if (time >= game_starttime)
1672         if (time < self.spawnshieldtime)
1673                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1674 }
1675
1676 float CalcRegen(float current, float stable, float regenfactor)
1677 {
1678         if(current > stable)
1679                 return current;
1680         else if(current > stable - 0.25) // when close enough, "snap"
1681                 return stable;
1682         else
1683                 return min(stable, current + (stable - current) * regenfactor * frametime);
1684 }
1685
1686 void player_regen (void)
1687 {
1688         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1689         maxh = cvar("g_balance_health_stable");
1690         maxa = cvar("g_balance_armor_stable");
1691         limith = cvar("g_balance_health_limit");
1692         limita = cvar("g_balance_armor_limit");
1693
1694         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1695                 return;
1696
1697         max_mod = regen_mod = rot_mod = limit_mod = 1;
1698
1699         if (self.runes & RUNE_REGEN)
1700         {
1701                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1702                 {
1703                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1704                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1705                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1706                 }
1707                 else
1708                 {
1709                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1710                         max_mod = cvar("g_balance_rune_regen_hpmod");
1711                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1712                 }
1713         }
1714         else if (self.runes & CURSE_VENOM)
1715         {
1716                 max_mod = cvar("g_balance_curse_venom_hpmod");
1717                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1718                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1719                 else
1720                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1721                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1722                 //if (!self.runes & RUNE_REGEN)
1723                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1724         }
1725         maxh = maxh * max_mod;
1726         //maxa = maxa * max_mod;
1727         limith = limith * limit_mod;
1728         limita = limita * limit_mod;
1729
1730         if (self.armorvalue > maxa)
1731         {
1732                 if (time > self.pauserotarmor_finished)
1733                 {
1734                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1735                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1736                 }
1737         }
1738         else if (self.armorvalue < maxa)
1739         {
1740                 if (time > self.pauseregen_finished)
1741                 {
1742                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1743                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1744                 }
1745         }
1746         if (self.health > maxh)
1747         {
1748                 if (time > self.pauserothealth_finished)
1749                 {
1750                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1751                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1752                 }
1753         }
1754         else if (self.health < maxh)
1755         {
1756                 if (time > self.pauseregen_finished)
1757                 {
1758                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1759                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1760                 }
1761         }
1762
1763         if (self.health > limith)
1764                 self.health = limith;
1765         if (self.armorvalue > limita)
1766                 self.armorvalue = limita;
1767
1768         // if player rotted to death...  die!
1769         if(self.health < 1)
1770                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1771 }
1772
1773 float zoomstate_set;
1774 void SetZoomState(float z)
1775 {
1776         if(z != self.zoomstate)
1777                 ClientData_Touch(self);
1778         zoomstate_set = 1;
1779 }
1780
1781 void GetPressedKeys(void) {
1782         if (self.movement_x > 0) // get if movement keys are pressed
1783         {       // forward key pressed
1784                 self.pressedkeys |= KEY_FORWARD;
1785                 self.pressedkeys &~= KEY_BACKWARD;
1786         }
1787         else if (self.movement_x < 0)
1788         {       // backward key pressed
1789                 self.pressedkeys |= KEY_BACKWARD;
1790                 self.pressedkeys &~= KEY_FORWARD;
1791         }
1792         else
1793         {       // no x input
1794                 self.pressedkeys &~= KEY_FORWARD;
1795                 self.pressedkeys &~= KEY_BACKWARD;
1796         }
1797
1798         if (self.movement_y > 0)
1799         {       // right key pressed
1800                 self.pressedkeys |= KEY_RIGHT;
1801                 self.pressedkeys &~= KEY_LEFT;
1802         }
1803         else if (self.movement_y < 0)
1804         {       // left key pressed
1805                 self.pressedkeys |= KEY_LEFT;
1806                 self.pressedkeys &~= KEY_RIGHT;
1807         }
1808         else
1809         {       // no y input
1810                 self.pressedkeys &~= KEY_RIGHT;
1811                 self.pressedkeys &~= KEY_LEFT;
1812         }
1813
1814         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1815                 self.pressedkeys |= KEY_JUMP;
1816         else
1817                 self.pressedkeys &~= KEY_JUMP;
1818         if (self.BUTTON_CROUCH)
1819                 self.pressedkeys |= KEY_CROUCH;
1820         else
1821                 self.pressedkeys &~= KEY_CROUCH;
1822 }
1823
1824 /*
1825 ======================
1826 spectate mode routines
1827 ======================
1828 */
1829 void SpectateCopy(entity spectatee) {
1830         self.armortype = spectatee.armortype;
1831         self.armorvalue = spectatee.armorvalue;
1832         self.currentammo = spectatee.currentammo;
1833         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1834         self.health = spectatee.health;
1835         self.impulse = 0;
1836         self.items = spectatee.items;
1837         self.strength_finished = spectatee.strength_finished;
1838         self.invincible_finished = spectatee.invincible_finished;
1839         self.pressedkeys = spectatee.pressedkeys;
1840         self.weapons = spectatee.weapons;
1841         self.switchweapon = spectatee.switchweapon;
1842         self.weapon = spectatee.weapon;
1843         self.punchangle = spectatee.punchangle;
1844         self.view_ofs = spectatee.view_ofs;
1845         self.v_angle = spectatee.v_angle;
1846         self.velocity = spectatee.velocity;
1847         self.dmg_take = spectatee.dmg_take;
1848         self.dmg_save = spectatee.dmg_save;
1849         self.dmg_inflictor = spectatee.dmg_inflictor;
1850         self.angles = spectatee.v_angle;
1851         self.fixangle = TRUE;
1852         setorigin(self, spectatee.origin);
1853         setsize(self, spectatee.mins, spectatee.maxs);
1854         SetZoomState(spectatee.zoomstate);
1855 }
1856
1857 float SpectateUpdate() {
1858         if(!self.enemy)
1859                 return 0;
1860
1861         if (self == self.enemy)
1862                 return 0;
1863
1864         if(self.enemy.flags & FL_NOTARGET)
1865                 return 0;
1866
1867         SpectateCopy(self.enemy);
1868
1869         return 1;
1870 }
1871
1872 float SpectateNext() {
1873         other = find(self.enemy, classname, "player");
1874         if (!other) {
1875                 other = find(other, classname, "player");
1876         }
1877         if (other) {
1878                 self.enemy = other;
1879         }
1880         if(self.enemy.classname == "player") {
1881                 msg_entity = self;
1882                 WriteByte(MSG_ONE, SVC_SETVIEW);
1883                 WriteEntity(MSG_ONE, self.enemy);
1884                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1885                 if(!SpectateUpdate())
1886                         PutObserverInServer();
1887                 return 1;
1888         } else {
1889                 return 0;
1890         }
1891 }
1892
1893 /*
1894 =============
1895 ShowRespawnCountdown()
1896
1897 Update a respawn countdown display.
1898 =============
1899 */
1900 void ShowRespawnCountdown()
1901 {
1902         float number;
1903         if(self.deadflag == DEAD_NO) // just respawned?
1904                 return;
1905         else
1906         {
1907                 number = ceil(self.death_time - time);
1908                 if(number <= 0)
1909                         return;
1910                 if(number <= self.respawn_countdown)
1911                 {
1912                         self.respawn_countdown = number - 1;
1913                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1914                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
1915                 }
1916         }
1917 }
1918
1919 void LeaveSpectatorMode()
1920 {
1921         if(isJoinAllowed()) {
1922                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1923                         self.classname = "player";
1924                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1925                                 JoinBestTeam(self, FALSE, TRUE);
1926                         if(cvar("g_campaign"))
1927                                 campaign_bots_may_start = 1;
1928                         PutClientInServer();
1929                         if(!(self.flags & FL_NOTARGET))
1930                                 bprint ("^4", self.netname, "^4 is playing now\n");
1931                         centerprint(self,"");
1932                         return;
1933                 } else {
1934                         stuffcmd(self,"menu_showteamselect\n");
1935                         return;
1936                 }
1937         }
1938         else {
1939                 //player may not join because of g_maxplayers is set
1940                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1941         }
1942 }
1943
1944 /**
1945  * Determines whether the player is allowed to join. This depends on cvar
1946  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1947  * it checks whether the number of currently playing players exceeds g_maxplayers.
1948  * @return bool TRUE if the player is allowed to join, false otherwise
1949  */
1950 float isJoinAllowed() {
1951         if (!cvar("g_maxplayers"))
1952                 return TRUE;
1953
1954         local entity e;
1955         local float currentlyPlaying;
1956         FOR_EACH_REALPLAYER(e) {
1957                 if(e.classname == "player")
1958                         currentlyPlaying += 1;
1959         }
1960         if(currentlyPlaying < cvar("g_maxplayers"))
1961                 return TRUE;
1962
1963         return FALSE;
1964 }
1965
1966 /**
1967  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1968  * g_maxplayers_spectator_blocktime seconds
1969  */
1970 void checkSpectatorBlock() {
1971         if(self.classname == "spectator" || self.classname == "observer") {
1972                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1973                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1974                         dropclient(self);
1975                 }
1976         }
1977 }
1978
1979 float vercmp_recursive(string v1, string v2)
1980 {
1981         float dot1, dot2;
1982         string s1, s2;
1983         float r;
1984
1985         dot1 = strstrofs(v1, ".", 0);
1986         dot2 = strstrofs(v2, ".", 0);
1987         if(dot1 == -1)
1988                 s1 = v1;
1989         else
1990                 s1 = substring(v1, 0, dot1);
1991         if(dot2 == -1)
1992                 s2 = v2;
1993         else
1994                 s2 = substring(v2, 0, dot2);
1995
1996         r = stof(s1) - stof(s2);
1997         if(r != 0)
1998                 return r;
1999
2000         r = strcasecmp(s1, s2);
2001         if(r != 0)
2002                 return r;
2003
2004         if(dot1 == -1)
2005                 if(dot2 == -1)
2006                         return 0;
2007                 else
2008                         return -1;
2009         else
2010                 if(dot2 == -1)
2011                         return 1;
2012                 else
2013                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2014 }
2015
2016 float vercmp(string v1, string v2)
2017 {
2018         if(strcasecmp(v1, v2) == 0) // early out check
2019                 return 0;
2020         return vercmp_recursive(v1, v2);
2021 }
2022
2023 void ObserverThink()
2024 {
2025         if (self.flags & FL_JUMPRELEASED) {
2026                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2027                         self.welcomemessage_time = 0;
2028                         self.flags &~= FL_JUMPRELEASED;
2029                         LeaveSpectatorMode();
2030                         return;
2031                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2032                         self.welcomemessage_time = 0;
2033                         self.flags &~= FL_JUMPRELEASED;
2034                         if(SpectateNext() == 1) {
2035                                 self.classname = "spectator";
2036                         }
2037                 }
2038         } else {
2039                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2040                         self.flags |= FL_JUMPRELEASED;
2041                 }
2042         }
2043         PrintWelcomeMessage(self);
2044 }
2045
2046 void SpectatorThink()
2047 {
2048         if (self.flags & FL_JUMPRELEASED) {
2049                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2050                         self.welcomemessage_time = 0;
2051                         self.flags &~= FL_JUMPRELEASED;
2052                         LeaveSpectatorMode();
2053                         return;
2054                 } else if(self.BUTTON_ATCK) {
2055                         self.welcomemessage_time = 0;
2056                         self.flags &~= FL_JUMPRELEASED;
2057                         if(SpectateNext() == 1) {
2058                                 self.classname = "spectator";
2059                         } else {
2060                                 self.classname = "observer";
2061                                 PutClientInServer();
2062                         }
2063                 } else if (self.BUTTON_ATCK2) {
2064                         self.welcomemessage_time = 0;
2065                         self.flags &~= FL_JUMPRELEASED;
2066                         self.classname = "observer";
2067                         PutClientInServer();
2068                 } else {
2069                         if(!SpectateUpdate())
2070                                 PutObserverInServer();
2071                 }
2072         } else {
2073                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2074                         self.flags |= FL_JUMPRELEASED;
2075                 }
2076         }
2077         PrintWelcomeMessage(self);
2078         self.flags |= FL_CLIENT | FL_NOTARGET;
2079 }
2080
2081 .float touchexplode_time;
2082
2083 /*
2084 =============
2085 PlayerPreThink
2086
2087 Called every frame for each client before the physics are run
2088 =============
2089 */
2090 void() ctf_setstatus;
2091 void PlayerPreThink (void)
2092 {
2093         self.stat_sys_ticrate = cvar("sys_ticrate");
2094         self.stat_game_starttime = game_starttime;
2095         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2096
2097         if(blockSpectators && frametime)
2098                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2099                 checkSpectatorBlock();
2100
2101         zoomstate_set = 0;
2102
2103         if(self.netname_previous != self.netname)
2104         {
2105                 if(cvar("sv_eventlog"))
2106                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2107                 if(self.netname_previous)
2108                         strunzone(self.netname_previous);
2109                 self.netname_previous = strzone(self.netname);
2110         }
2111
2112         // version nagging
2113         if(self.version_nagtime)
2114                 if(self.cvar_g_nexuizversion)
2115                         if(time > self.version_nagtime)
2116                         {
2117                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2118                                 {
2119                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2120                                         {
2121                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2122                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2123                                         }
2124                                         else
2125                                         {
2126                                                 float r;
2127                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2128                                                 if(r < 0)
2129                                                 {
2130                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2131                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2132                                                 }
2133                                                 else if(r > 0)
2134                                                 {
2135                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2136                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2137                                                 }
2138                                         }
2139                                 }
2140                                 self.version_nagtime = 0;
2141                         }
2142
2143         // GOD MODE info
2144         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2145         {
2146                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2147                 self.max_armorvalue = 0;
2148         }
2149
2150         if(frametime)
2151                 antilag_record(self);
2152
2153         if(self.classname == "player") {
2154 //              if(self.netname == "Wazat")
2155 //                      bprint(self.classname, "\n");
2156
2157                 CheckRules_Player();
2158
2159                 PrintWelcomeMessage(self);
2160
2161                 if (intermission_running)
2162                 {
2163                         IntermissionThink ();   // otherwise a button could be missed between
2164                         return;                                 // the think tics
2165                 }
2166
2167                 if(self.teleport_time)
2168                 if(time > self.teleport_time)
2169                 {
2170                         self.teleport_time = 0;
2171                         self.effects = self.effects - (self.effects & EF_NODRAW);
2172                 }
2173
2174                 Nixnex_GiveCurrentWeapon();
2175
2176                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2177                         UpdateSelectedPlayer();
2178
2179                 //don't allow the player to turn around while game is paused!
2180                 if(timeoutStatus == 2) {
2181                         self.v_angle = self.lastV_angle;
2182                         self.angles = self.lastV_angle;
2183                         self.fixangle = TRUE;
2184                 }
2185
2186                 if (self.deadflag != DEAD_NO)
2187                 {
2188                         float button_pressed, force_respawn;
2189                         player_anim();
2190                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2191                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2192                         if (self.deadflag == DEAD_DYING)
2193                         {
2194                                 if(force_respawn)
2195                                         self.deadflag = DEAD_RESPAWNING;
2196                                 else if(!button_pressed)
2197                                         self.deadflag = DEAD_DEAD;
2198                         }
2199                         else if (self.deadflag == DEAD_DEAD)
2200                         {
2201                                 if(button_pressed)
2202                                         self.deadflag = DEAD_RESPAWNABLE;
2203                         }
2204                         else if (self.deadflag == DEAD_RESPAWNABLE)
2205                         {
2206                                 if(!button_pressed)
2207                                         self.deadflag = DEAD_RESPAWNING;
2208                         }
2209                         else if (self.deadflag == DEAD_RESPAWNING)
2210                         {
2211                                 if(time > self.death_time)
2212                                 {
2213                                         self.death_time = time + 1; // only retry once a second
2214                                         respawn();
2215                                 }
2216                         }
2217                         ShowRespawnCountdown();
2218                         return;
2219                 }
2220
2221                 if(g_touchexplode)
2222                 if(time > self.touchexplode_time)
2223                 if(self.classname == "player")
2224                 if(self.deadflag == DEAD_NO)
2225                 if not(IS_INDEPENDENT_PLAYER(self))
2226                 FOR_EACH_PLAYER(other) if(self != other)
2227                 {
2228                         if(time > other.touchexplode_time)
2229                         if(other.classname == "player")
2230                         if(other.deadflag == DEAD_NO)
2231                         if not(IS_INDEPENDENT_PLAYER(other))
2232                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2233                         {
2234                                 PlayerTouchExplode(self, other);
2235                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2236                         }
2237                 }
2238
2239                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2240                 {
2241                         vector dist;
2242
2243                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2244                         dist = self.oldorigin - self.origin;
2245                         dist_z = 0;
2246                         self.lms_traveled_distance += fabs(vlen(dist));
2247
2248                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2249                         {
2250                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2251                                 self.lms_traveled_distance = 0;
2252                         }
2253
2254                         if(time > self.lms_nextcheck)
2255                         {
2256                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2257                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2258                                 {
2259                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2260                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2261                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2262                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2263                                 }
2264                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2265                                 self.lms_traveled_distance = 0;
2266                         }
2267                 }
2268
2269                 self.oldorigin = self.origin;
2270
2271                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2272                 {
2273                         if (!self.crouch)
2274                         {
2275                                 self.crouch = TRUE;
2276                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2277                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2278                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2279                         }
2280                 }
2281                 else
2282                 {
2283                         if (self.crouch)
2284                         {
2285                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2286                                 if (!trace_startsolid)
2287                                 {
2288                                         self.crouch = FALSE;
2289                                         self.view_ofs = PL_VIEW_OFS;
2290                                         setsize (self, PL_MIN, PL_MAX);
2291                                 }
2292                         }
2293                 }
2294
2295                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2296                 {
2297                         if(self.bloodloss_timer < time)
2298                         {
2299                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2300                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2301                         }
2302                 }
2303
2304                 FixPlayermodel();
2305
2306                 GrapplingHookFrame();
2307
2308                 W_WeaponFrame();
2309
2310                 player_powerups();
2311                 player_regen();
2312                 player_anim();
2313
2314                 if (g_minstagib)
2315                         minstagib_ammocheck();
2316
2317                 ctf_setstatus();
2318                 kh_setstatus();
2319
2320                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2321
2322                 //self.angles_y=self.v_angle_y + 90;   // temp
2323
2324                 //if (TetrisPreFrame()) return;
2325         } else if(gameover) {
2326                 if (intermission_running)
2327                         IntermissionThink ();   // otherwise a button could be missed between
2328                 return;
2329         } else if(self.classname == "observer") {
2330                 ObserverThink();
2331         } else if(self.classname == "spectator") {
2332                 SpectatorThink();
2333         }
2334
2335         if(!zoomstate_set)
2336                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2337
2338         float oldspectatee_status;
2339         oldspectatee_status = self.spectatee_status;
2340         if(self.classname == "spectator")
2341                 self.spectatee_status = num_for_edict(self.enemy);
2342         else if(self.classname == "observer")
2343                 self.spectatee_status = num_for_edict(self);
2344         else
2345                 self.spectatee_status = 0;
2346         if(self.spectatee_status != oldspectatee_status)
2347         {
2348                 ClientData_Touch(self);
2349                 if(g_race)
2350                         race_InitSpectator();
2351         }
2352
2353         if(self.teamkill_soundtime)
2354         if(time > self.teamkill_soundtime)
2355         {
2356                 self.teamkill_soundtime = 0;
2357
2358                 entity oldpusher, oldself;
2359
2360                 oldself = self; self = self.teamkill_soundsource;
2361                 oldpusher = self.pusher; self.pusher = oldself;
2362
2363                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2364
2365                 self.pusher = oldpusher;
2366                 self = oldself;
2367         }
2368
2369         if(self.taunt_soundtime)
2370         if(time > self.taunt_soundtime)
2371         {
2372                 self.taunt_soundtime = 0;
2373                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2374         }
2375
2376         target_voicescript_next(self);
2377 }
2378
2379
2380 /*
2381 =============
2382 PlayerPostThink
2383
2384 Called every frame for each client after the physics are run
2385 =============
2386 */
2387 .float idlekick_lasttimeleft;
2388 .float race_penalty;
2389 .float race_penalty_nagged;
2390 .float race_penalty_nagtime;
2391 void PlayerPostThink (void)
2392 {
2393         // Savage: Check for nameless players
2394         if (strlen(self.netname) < 1) {
2395                 self.netname = "Player";
2396                 stuffcmd(self, "seta _cl_name Player\n");
2397         }
2398
2399         if(sv_maxidle && frametime)
2400         {
2401                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2402                 float timeleft;
2403                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2404                 if(timeleft <= 0)
2405                 {
2406                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2407                         announce(self, "announcer/robotic/terminated.wav");
2408                         dropclient(self);
2409                         return;
2410                 }
2411                 else if(timeleft <= 10)
2412                 {
2413                         if(timeleft != self.idlekick_lasttimeleft)
2414                         {
2415                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2416                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2417                         }
2418                 }
2419                 else
2420                 {
2421                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2422                 }
2423                 self.idlekick_lasttimeleft = timeleft;
2424         }
2425
2426         if(self.classname == "player") {
2427                 CheckRules_Player();
2428                 UpdateChatBubble();
2429                 UpdateTeamBubble();
2430                 if (self.impulse)
2431                         ImpulseCommands();
2432                 if (intermission_running)
2433                         return;         // intermission or finale
2434
2435                 //if (TetrisPostFrame()) return;
2436
2437                 // restart countdown
2438                         if(time < game_starttime) {
2439                                 if (!cvar("sv_ready_restart_after_countdown"))
2440                                 {
2441                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2442                                         {
2443                                                 if(time < game_starttime - 2)
2444                                                 {
2445                                                         if(!self.race_penalty_nagged)
2446                                                         {
2447                                                                 // TODO better notification for this!
2448                                                                 self.race_penalty_nagtime = 0;
2449                                                                 self.race_penalty_nagged = 1;
2450                                                         }
2451                                                 }
2452                                                 else if(!self.race_penalty)
2453                                                 {
2454                                                         self.race_penalty_nagtime = 0;
2455                                                         self.race_penalty = time + 5;
2456                                                 }
2457                                         }
2458                                         if(time > self.race_penalty_nagtime)
2459                                         {
2460                                                 if(self.race_penalty > time)
2461                                                 {
2462                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2463                                                 }
2464                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2465                                                 {
2466                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2467                                                 }
2468                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2469                                         }
2470                                         self.movetype = MOVETYPE_NONE;
2471                                         self.velocity = '0 0 0';
2472                                         self.avelocity = '0 0 0';
2473                                         self.movement = '0 0 0';
2474                                 }
2475                         }
2476                         else if (time < self.race_penalty)
2477                         {
2478                                 self.movetype = MOVETYPE_NONE;
2479                                 self.velocity = '0 0 0';
2480                                 self.avelocity = '0 0 0';
2481                                 self.movement = '0 0 0';
2482                         }
2483                         else
2484                         {
2485                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2486                                 if (!cvar("sv_ready_restart_after_countdown"))
2487                                 {
2488                                         if(self.movetype == MOVETYPE_NONE)
2489                                         {
2490                                                 self.movetype = MOVETYPE_WALK;
2491                                         }
2492                                         self.race_penalty = 0;
2493                                         self.race_penalty_nagged = 0;
2494                                 }
2495                         }
2496                 GetPressedKeys();
2497         } else if (self.classname == "observer") {
2498                 //do nothing
2499         } else if (self.classname == "spectator") {
2500                 //do nothing
2501         }
2502
2503         /*
2504         float i;
2505         for(i = 0; i < 1000; ++i)
2506         {
2507                 vector end;
2508                 end = self.origin + '0 0 1024' + 512 * randomvec();
2509                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2510                 if(trace_fraction < 1)
2511                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2512                 {
2513                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2514                         break;
2515                 }
2516         }
2517         */
2518
2519         Arena_Warmup();
2520
2521         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2522 }