data/qcsrc/server/cl_client.qc

   1 void info_player_survivor (void)
   2 {
   3         info_player_deathmatch();
   4 }
   5
   6 void info_player_start (void)
   7 {
   8         info_player_deathmatch();
   9 }
  10
  11 void info_player_deathmatch (void)
  12 {
  13         self.classname = "info_player_deathmatch";
  14         relocate_spawnpoint();
  15 }
  16
  17 void() spawnpoint_use =
  18 {
  19         if(teams_matter)
  20         if(have_team_spawns)
  21         {
  22                 self.team = activator.team;
  23                 some_spawn_has_been_used = 1;
  24         }
  25 };
  26
  27 float spawn_allbad;
  28 float spawn_allgood;
  29 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  30 {
  31         local entity spot, player, nextspot, previousspot, newfirstspot;
  32         local float pcount;
  33         spot = firstspot;
  34         newfirstspot = world;
  35         previousspot = world;
  36         spawn_allgood = TRUE;
  37         spawn_allbad = TRUE;
  38         while (spot)
  39         {
  40                 nextspot = spot.chain;
  41                 // count team mismatches as bad spots
  42
  43                 local float spotactive;
  44                 spotactive = 1;
  45
  46                 // filter out spots for assault
  47                 if(spot.target != "") {
  48                         local entity ent;
  49                         ent = find(world, targetname, spot.target);
  50                         while(ent) {
  51                                 if(ent.classname == "target_objective")
  52                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  53                                                 spotactive = 0;
  54                                 ent = find(ent, targetname, spot.target);
  55                         }
  56                 }
  57
  58                 if ((!teamcheck || spot.team == teamcheck) && spotactive > 0)
  59                 {
  60                         pcount = 0;
  61                         player = playerlist;
  62                         while (player)
  63                         {
  64                                 if (player != self)
  65                                 if (vlen(player.origin - spot.origin) < mindist)
  66                                         pcount = pcount + 1;
  67                                 player = player.chain;
  68                         }
  69                         if (!pcount)
  70                         {
  71                                 spawn_allbad = FALSE;
  72                                 if (newfirstspot)
  73                                         previousspot.chain = spot;
  74                                 else
  75                                         newfirstspot = spot;
  76                                 previousspot = spot;
  77                                 spot.chain = world;
  78                         }
  79                         else
  80                                 spawn_allgood = FALSE;
  81                 }
  82                 spot = nextspot;
  83         }
  84         // if we couldn't find ANY good points, return world
  85         return newfirstspot;
  86 }
  87
  88 entity Spawn_RandomPoint(entity firstspot)
  89 {
  90         local entity spot;
  91         local float numspots;
  92         // count number of spots
  93         numspots = 0;
  94         spot = firstspot;
  95         while (spot)
  96         {
  97                 numspots = numspots + 1;
  98                 spot = spot.chain;
  99         }
 100         // pick a random one
 101         numspots = numspots * random();
 102         spot = firstspot;
 103         while (spot.chain && numspots >= 1)
 104         {
 105                 numspots = numspots - 1;
 106                 spot = spot.chain;
 107         }
 108         return spot;
 109 }
 110
 111 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
 112 {
 113         local entity best, spot, player;
 114         local float bestrating, rating;
 115         best = world;
 116         bestrating = -1000000;
 117         spot = firstspot;
 118         while (spot)
 119         {
 120                 rating = 1000000000;
 121                 player = playerlist;
 122                 while (player)
 123                 {
 124                         if (player != self)
 125                                 rating = min(rating, vlen(player.origin - spot.origin));
 126                         player = player.chain;
 127                 }
 128                 rating = rating + random() * 16;
 129                 if (bestrating < rating)
 130                 {
 131                         best = spot;
 132                         bestrating = rating;
 133                 }
 134                 spot = spot.chain;
 135         }
 136         return best;
 137 }
 138
 139 /*
 140 =============
 141 SelectSpawnPoint
 142
 143 Finds a point to respawn
 144 =============
 145 */
 146 entity SelectSpawnPoint (float anypoint)
 147 {
 148         local float teamcheck;
 149         local entity firstspot_new;
 150         local entity spot, firstspot, playerlist;
 151
 152         spot = find (world, classname, "testplayerstart");
 153         if (spot)
 154                 return spot;
 155
 156         teamcheck = 0;
 157
 158         if(!anypoint && have_team_spawns)
 159                 teamcheck = self.team;
 160
 161         // get the list of players
 162         playerlist = findchain(classname, "player");
 163         // get the entire list of spots
 164         firstspot = findchain(classname, "info_player_deathmatch");
 165         // filter out the bad ones
 166         // (note this returns the original list if none survived)
 167         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 168         if(!firstspot_new)
 169                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 170         firstspot = firstspot_new;
 171
 172         // there is 50/50 chance of choosing a random spot or the furthest spot
 173         // (this means that roughly every other spawn will be furthest, so you
 174         // usually won't get fragged at spawn twice in a row)
 175         if (arena_roundbased)
 176         {
 177                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 178                 if(firstspot_new)
 179                         firstspot = firstspot_new;
 180                 spot = Spawn_RandomPoint(firstspot);
 181         }
 182         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 183                 spot = Spawn_RandomPoint(firstspot);
 184         else
 185                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 186
 187         if (!spot)
 188         {
 189                 if(cvar("spawn_debug"))
 190                         GotoNextMap();
 191                 else
 192                 {
 193                         if(some_spawn_has_been_used)
 194                                 return world; // team can't spawn any more, because of actions of other team
 195                         else
 196                                 error("Cannot find a spawn point - please fix the map!");
 197                 }
 198         }
 199
 200         return spot;
 201 }
 202
 203 /*
 204 =============
 205 CheckPlayerModel
 206
 207 Checks if the argument string can be a valid playermodel.
 208 Returns a valid one in doubt.
 209 =============
 210 */
 211 string FallbackPlayerModel = "models/player/marine.zym";
 212 string CheckPlayerModel(string plyermodel) {
 213         if(strlen(plyermodel) < 4)
 214                 return FallbackPlayerModel;
 215         if( substring(plyermodel,0,14) != "models/player/")
 216                 return FallbackPlayerModel;
 217         else if(cvar("sv_servermodelsonly"))
 218         {
 219                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 220                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 221                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 222                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 223                         return FallbackPlayerModel;
 224                 if(!fexists(plyermodel))
 225                         return FallbackPlayerModel;
 226         }
 227         return plyermodel;
 228 }
 229
 230 /*
 231 =============
 232 Client_customizeentityforclient
 233
 234 LOD reduction
 235 =============
 236 */
 237 float Client_customizeentityforclient()
 238 {
 239 #ifdef ALLOW_VARIABLE_LOD
 240         // self: me
 241         // other: the player viewing me
 242         float distance;
 243         float f;
 244
 245         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 246                 return TRUE;
 247
 248         if(other.cvar_cl_playerdetailreduction <= 0)
 249         {
 250                 if(other.cvar_cl_playerdetailreduction <= -2)
 251                         self.modelindex = self.modelindex_lod2;
 252                 else if(other.cvar_cl_playerdetailreduction <= -1)
 253                         self.modelindex = self.modelindex_lod1;
 254                 else
 255                         self.modelindex = self.modelindex_lod0;
 256         }
 257         else
 258         {
 259                 distance = vlen(self.origin - other.origin);
 260                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 261                 if(f > 10000)
 262                         self.modelindex = self.modelindex_lod2;
 263                 else if(f > 5000)
 264                         self.modelindex = self.modelindex_lod1;
 265                 else
 266                         self.modelindex = self.modelindex_lod0;
 267         }
 268 #endif
 269
 270         return TRUE;
 271 }
 272
 273 void UpdatePlayerSounds();
 274 void setmodel_lod(entity e, string modelname)
 275 {
 276 #ifdef ALLOW_VARIABLE_LOD
 277         string s;
 278
 279         // FIXME: this only supports 3-letter extensions
 280         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 281         if(fexists(s))
 282         {
 283                 precache_model(s);
 284                 setmodel(e, s); // players have high precision
 285                 self.modelindex_lod1 = self.modelindex;
 286         }
 287         else
 288                 self.modelindex_lod1 = -1;
 289
 290         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 291         if(fexists(s))
 292         {
 293                 precache_model(s);
 294                 setmodel(e, s); // players have high precision
 295                 self.modelindex_lod2 = self.modelindex;
 296         }
 297         else
 298                 self.modelindex_lod2 = -1;
 299
 300         precache_model(modelname);
 301         setmodel(e, modelname); // players have high precision
 302         self.modelindex_lod0 = self.modelindex;
 303
 304         if(self.modelindex_lod1 < 0)
 305                 self.modelindex_lod1 = self.modelindex;
 306
 307         if(self.modelindex_lod2 < 0)
 308                 self.modelindex_lod2 = self.modelindex;
 309 #else
 310         precache_model(modelname);
 311         setmodel(e, modelname); // players have high precision
 312 #endif
 313         player_setupanimsformodel();
 314         UpdatePlayerSounds();
 315 }
 316
 317 /*
 318 =============
 319 PutObserverInServer
 320
 321 putting a client as observer in the server
 322 =============
 323 */
 324 void PutObserverInServer (void)
 325 {
 326         entity  spot;
 327         spot = SelectSpawnPoint (TRUE);
 328         if(!spot)
 329                 error("No spawnpoints for observers?!?\n");
 330         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 331
 332         if(clienttype(self) == CLIENTTYPE_REAL)
 333         {
 334                 msg_entity = self;
 335                 WriteByte(MSG_ONE, SVC_SETVIEW);
 336                 WriteEntity(MSG_ONE, self);
 337         }
 338
 339         DropAllRunes(self);
 340         kh_Key_DropAll(self, TRUE);
 341
 342         if(self.flagcarried)
 343                 DropFlag(self.flagcarried);
 344
 345         WaypointSprite_PlayerDead();
 346
 347         DistributeFragsAmongTeam(self, self.team, 1);
 348
 349         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 350                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 351         else if(self.killcount != -666)
 352                 bprint ("^4", self.netname, "^4 is spectating now\n");
 353
 354         self.classname = "observer";
 355         self.health = -666;
 356         self.takedamage = DAMAGE_NO;
 357         self.solid = SOLID_NOT;
 358         self.movetype = MOVETYPE_NOCLIP;
 359         self.flags = FL_CLIENT | FL_NOTARGET;
 360         self.armorvalue = 666;
 361         self.effects = 0;
 362         self.armorvalue = cvar("g_balance_armor_start");
 363         self.pauserotarmor_finished = 0;
 364         self.pauserothealth_finished = 0;
 365         self.pauseregen_finished = 0;
 366         self.damageforcescale = 0;
 367         self.death_time = 0;
 368         self.dead_frame = 0;
 369         self.deaths = 0;
 370         self.alpha = 0;
 371         self.scale = 0;
 372         self.fade_time = 0;
 373         self.pain_frame = 0;
 374         self.pain_finished = 0;
 375         self.strength_finished = 0;
 376         self.invincible_finished = 0;
 377         self.pushltime = 0;
 378         self.think = SUB_Null;
 379         self.nextthink = 0;
 380         self.hook_time = 0;
 381         self.runes = 0;
 382         self.deadflag = DEAD_NO;
 383         self.angles = spot.angles;
 384         self.angles_z = 0;
 385         self.fixangle = TRUE;
 386         self.crouch = FALSE;
 387
 388         self.view_ofs = PL_VIEW_OFS;
 389         setorigin (self, spot.origin);
 390         setsize (self, '0 0 0', '0 0 0');
 391         self.oldorigin = self.origin;
 392         self.items = 0;
 393         self.model = "";
 394         self.modelindex = 0;
 395         self.weapon = 0;
 396         self.weaponmodel = "";
 397         self.weaponentity = world;
 398         self.killcount = -666;
 399         self.velocity = '0 0 0';
 400         self.avelocity = '0 0 0';
 401         self.punchangle = '0 0 0';
 402         self.punchvector = '0 0 0';
 403         self.oldvelocity = self.velocity;
 404         self.customizeentityforclient = Client_customizeentityforclient;
 405         self.viewzoom = 1;
 406
 407         if(g_arena)
 408         {
 409                 if(self.frags != -2)
 410                 {
 411                         Spawnqueue_Insert(self);
 412                 }
 413                 else
 414                 {
 415                         Spawnqueue_Unmark(self);
 416                         Spawnqueue_Remove(self);
 417                 }
 418         }
 419         else if(!g_lms)
 420                 self.frags = -666;
 421 }
 422
 423 float RestrictSkin(float s)
 424 {
 425         if(!teams_matter)
 426                 return s;
 427         if(s == 6)
 428                 return 6;
 429         return mod(s, 3);
 430 }
 431
 432 void FixPlayermodel()
 433 {
 434         local string defaultmodel;
 435         local float defaultskin;
 436         local vector m1, m2;
 437
 438         if(cvar("sv_defaultcharacter") == 1) {
 439                 defaultmodel = "";
 440                 defaultskin = 0;
 441
 442                 if(teams_matter)
 443                 {
 444                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 445                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 446                 }
 447
 448                 if(defaultmodel == "")
 449                 {
 450                         defaultmodel = cvar_string("sv_defaultplayermodel");
 451                         defaultskin = cvar("sv_defaultplayerskin");
 452                 }
 453
 454                 if (defaultmodel != self.model)
 455                 {
 456                         m1 = self.mins;
 457                         m2 = self.maxs;
 458                         setmodel_lod (self, defaultmodel);
 459                         setsize (self, m1, m2);
 460                 }
 461
 462                 self.skin = defaultskin;
 463         } else {
 464                 if (self.playermodel != self.model)
 465                 {
 466                         self.playermodel = CheckPlayerModel(self.playermodel);
 467                         m1 = self.mins;
 468                         m2 = self.maxs;
 469                         setmodel_lod (self, self.playermodel);
 470                         setsize (self, m1, m2);
 471                 }
 472
 473                 self.skin = RestrictSkin(stof(self.playerskin));
 474         }
 475
 476         if(!teams_matter)
 477                 if(strlen(cvar_string("sv_defaultplayercolors")))
 478                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 479                                 setcolor(self, cvar("sv_defaultplayercolors"));
 480 }
 481
 482 /*
 483 =============
 484 PutClientInServer
 485
 486 Called when a client spawns in the server
 487 =============
 488 */
 489 void PutClientInServer (void)
 490 {
 491         if(clienttype(self) == CLIENTTYPE_BOT)
 492         {
 493                 self.classname = "player";
 494         }
 495         else if(clienttype(self) == CLIENTTYPE_REAL)
 496         {
 497                 msg_entity = self;
 498                 WriteByte(MSG_ONE, SVC_SETVIEW);
 499                 WriteEntity(MSG_ONE, self);
 500         }
 501
 502         // player is dead and becomes observer
 503         if(g_lms && self.frags < 1)
 504                 self.classname = "observer";
 505
 506         if(g_arena)
 507         if(!self.spawned)
 508                 self.classname = "observer";
 509
 510         if(self.classname == "player") {
 511                 entity  spot;
 512
 513                 spot = SelectSpawnPoint (FALSE);
 514                 if(!spot)
 515                 {
 516                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 517                         return; // spawn failed
 518                 }
 519
 520                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 521
 522                 self.classname = "player";
 523                 self.iscreature = TRUE;
 524                 self.movetype = MOVETYPE_WALK;
 525                 self.solid = SOLID_SLIDEBOX;
 526                 self.flags = FL_CLIENT;
 527                 self.takedamage = DAMAGE_AIM;
 528                 if(g_minstagib)
 529                         self.effects = EF_FULLBRIGHT;
 530                 else
 531                         self.effects = 0;
 532                 self.air_finished = time + 12;
 533                 self.dmg = 2;
 534
 535                 self.ammo_shells = start_ammo_shells;
 536                 self.ammo_nails = start_ammo_nails;
 537                 self.ammo_rockets = start_ammo_rockets;
 538                 self.ammo_cells = start_ammo_cells;
 539                 self.health = start_health;
 540                 self.armorvalue = start_armorvalue;
 541                 self.items = start_items;
 542                 self.switchweapon = start_switchweapon;
 543                 self.weapon = 0;
 544                 self.jump_interval = time;
 545
 546                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 547                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 548                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 549                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 550                 self.damageforcescale = 2;
 551                 self.death_time = 0;
 552                 self.dead_frame = 0;
 553                 self.alpha = 0;
 554                 self.scale = 0;
 555                 self.fade_time = 0;
 556                 self.pain_frame = 0;
 557                 self.pain_finished = 0;
 558                 self.strength_finished = 0;
 559                 self.invincible_finished = 0;
 560                 self.pushltime = 0;
 561                 //self.speed_finished = 0;
 562                 //self.slowmo_finished = 0;
 563                 // players have no think function
 564                 self.think = SUB_Null;
 565                 self.nextthink = 0;
 566                 self.hook_time = 0;
 567
 568                 self.runes = 0;
 569
 570                 self.deadflag = DEAD_NO;
 571
 572                 self.angles = spot.angles;
 573
 574                 self.angles_z = 0; // never spawn tilted even if the spot says to
 575                 self.fixangle = TRUE; // turn this way immediately
 576                 self.velocity = '0 0 0';
 577                 self.avelocity = '0 0 0';
 578                 self.punchangle = '0 0 0';
 579                 self.punchvector = '0 0 0';
 580                 self.oldvelocity = self.velocity;
 581
 582                 self.viewzoom = 0.6;
 583                 self.has_zoomed = 0;
 584
 585                 self.customizeentityforclient = Client_customizeentityforclient;
 586
 587                 self.model = "";
 588                 FixPlayermodel();
 589
 590                 self.crouch = FALSE;
 591                 self.view_ofs = PL_VIEW_OFS;
 592                 setsize (self, PL_MIN, PL_MAX);
 593                 self.spawnorigin = spot.origin;
 594                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 595                 // don't reset back to last position, even if new position is stuck in solid
 596                 self.oldorigin = self.origin;
 597
 598                 if(g_arena)
 599                 {
 600                         Spawnqueue_Remove(self);
 601                         Spawnqueue_Mark(self);
 602                 }
 603
 604                 self.event_damage = PlayerDamage;
 605
 606                 self.bot_attack = TRUE;
 607
 608                 self.statdraintime = time + 5;
 609                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 610
 611                 if(self.killcount == -666) {
 612                         self.killcount = 0;
 613                         if(!g_arena)
 614                         if(!g_lms)
 615                                 self.frags = 0;
 616                 }
 617
 618                 self.cnt = WEP_LASER;
 619                 self.nixnex_lastchange_id = -1;
 620
 621                 CL_SpawnWeaponentity();
 622                 self.alpha = default_player_alpha;
 623                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 624                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 625
 626                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 627                 self.lms_traveled_distance = 0;
 628                 self.speedrunning = FALSE;
 629
 630                 if(cvar("spawn_debug"))
 631                 {
 632                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 633                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 634                 }
 635
 636                 //stuffcmd(self, "chase_active 0");
 637                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 638
 639                 if (cvar("g_spawnsound"))
 640                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 641
 642                 if(g_assault) {
 643                         if(self.team == assault_attacker_team)
 644                                 centerprint(self, "You are attacking!\n");
 645                         else
 646                                 centerprint(self, "You are defending!\n");
 647                 }
 648
 649         } else if(self.classname == "observer") {
 650                 PutObserverInServer ();
 651         }
 652 }
 653
 654 /*
 655 =============
 656 SetNewParms
 657 =============
 658 */
 659 void SetNewParms (void)
 660 {
 661
 662 }
 663
 664 /*
 665 =============
 666 SetChangeParms
 667 =============
 668 */
 669 void SetChangeParms (void)
 670 {
 671
 672 }
 673
 674 /*
 675 =============
 676 ClientKill
 677
 678 Called when a client types 'kill' in the console
 679 =============
 680 */
 681 void ClientKill (void)
 682 {
 683         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 684 }
 685
 686 void FixClientCvars(entity e)
 687 {
 688         float t;
 689         // send prediction settings to the client
 690         stuffcmd(e, "\nin_bindmap 0 0\n");
 691         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 692         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 693         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 694         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 695         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 696         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 697         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 698         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 699         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 700         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 701         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 702         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 703         stuffcmd(e, "cl_movement_edgefriction 1\n");
 704
 705         // notify about available teams
 706         if(teamplay)
 707         {
 708                 CheckAllowedTeams(e);
 709                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
 710                 stuffcmd(e, strcat("set _teams_available ", ftos(t), "\n"));
 711         }
 712         else
 713                 stuffcmd(e, "set _teams_available 0\n");
 714 }
 715
 716 /*
 717 =============
 718 ClientConnect
 719
 720 Called when a client connects to the server
 721 =============
 722 */
 723 string ColoredTeamName(float t);
 724 //void dom_player_join_team(entity pl);
 725 void ClientConnect (void)
 726 {
 727         local string s;
 728         float wep;
 729
 730         if(Ban_IsClientBanned(self))
 731         {
 732                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 733                 dropclient(self);
 734                 bprint(s);
 735                 return;
 736         }
 737
 738         self.classname = "player_joining";
 739         self.flags = self.flags | FL_CLIENT;
 740         self.version_nagtime = time + 10 + random() * 10;
 741
 742         if(player_count<0)
 743         {
 744                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 745                 player_count = 0;
 746         }
 747
 748         bot_clientconnect();
 749
 750         //if(g_domination)
 751         //      dom_player_join_team(self);
 752
 753         //JoinBestTeam(self, FALSE);
 754
 755         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 756                 self.classname = "observer";
 757         } else {
 758                 self.classname = "player";
 759                 campaign_bots_may_start = 1;
 760         }
 761
 762         self.playerid = (playerid_last = playerid_last + 1);
 763         if(cvar("sv_eventlog"))
 764         {
 765                 if(clienttype(self) == CLIENTTYPE_REAL)
 766                         s = "player";
 767                 else
 768                         s = "bot";
 769                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 770                 s = strcat(":team:", ftos(self.playerid), ":");
 771                 s = strcat(s, ftos(self.team));
 772                 GameLogEcho(s, FALSE);
 773         }
 774
 775         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 776
 777         bprint ("^4",self.netname);
 778         bprint ("^4 connected");
 779
 780         if(g_domination || g_ctf)
 781         {
 782                 bprint(" and joined the ");
 783                 bprint(ColoredTeamName(self.team));
 784         }
 785
 786         bprint("\n");
 787
 788         self.welcomemessage_time = 0;
 789
 790         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 791         // TODO: is this being used for anything else than cd tracks?
 792         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 793
 794         FixClientCvars(self);
 795
 796         // waypoint sprites
 797         WaypointSprite_InitClient(self);
 798
 799         // Wazat's grappling hook
 800         SetGrappleHookBindings();
 801
 802         // get autoswitch state from player when he toggles it
 803         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 804
 805         // get version info from player
 806         stuffcmd(self, "cmd clientversion $gameversion\n");
 807
 808         // send all weapon info strings
 809         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
 810         wep = WEP_FIRST;
 811         while (wep <= WEP_LAST)
 812         {
 813                 weapon_action(wep, WR_REGISTER);
 814                 wep = wep + 1;
 815         }
 816
 817         // get other cvars from player
 818         GetCvars(0);
 819
 820         // set cvar for team scoreboard
 821         if (teams_matter)
 822         {
 823                 local float t;
 824                 t = cvar("teamplay");
 825                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 826                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 827         }
 828         else
 829                 stuffcmd(self, "set teamplay 0\n");
 830
 831         if(g_lms)
 832         {
 833                 self.frags = LMS_NewPlayerLives();
 834                 if(!self.frags)
 835                         self.frags = -666;
 836         }
 837         else if(g_arena)
 838         {
 839                 self.classname = "observer";
 840                 Spawnqueue_Insert(self);
 841         }
 842
 843         bot_relinkplayerlist();
 844
 845         self.jointime = time;
 846 }
 847
 848 /*
 849 =============
 850 ClientDisconnect
 851
 852 Called when a client disconnects from the server
 853 =============
 854 */
 855 void(entity e) DropFlag;
 856 .entity chatbubbleentity;
 857 .entity teambubbleentity;
 858 void ClientDisconnect (void)
 859 {
 860         float save;
 861         if(cvar("sv_eventlog"))
 862                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 863         bprint ("^4",self.netname);
 864         bprint ("^4 disconnected\n");
 865
 866         if (self.chatbubbleentity)
 867         {
 868                 remove (self.chatbubbleentity);
 869                 self.chatbubbleentity = world;
 870         }
 871
 872         if (self.teambubbleentity)
 873         {
 874                 remove (self.teambubbleentity);
 875                 self.teambubbleentity = world;
 876         }
 877
 878         WaypointSprite_PlayerGone();
 879
 880         DropAllRunes(self);
 881         kh_Key_DropAll(self, TRUE);
 882
 883         if(self.flagcarried)
 884                 DropFlag(self.flagcarried);
 885
 886         DistributeFragsAmongTeam(self, self.team, 1);
 887
 888         save = self.flags;
 889         self.flags = self.flags - (self.flags & FL_CLIENT);
 890         bot_relinkplayerlist();
 891         self.flags = save;
 892
 893         // remove laserdot
 894         if(self.weaponentity)
 895                 if(self.weaponentity.lasertarget)
 896                         remove(self.weaponentity.lasertarget);
 897
 898         if(g_arena)
 899         {
 900                 Spawnqueue_Unmark(self);
 901                 Spawnqueue_Remove(self);
 902         }
 903
 904         // free cvars
 905         GetCvars(-1);
 906 }
 907
 908 .float buttonchat;
 909 void() ChatBubbleThink =
 910 {
 911         self.nextthink = time;
 912         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 913         {
 914                 self.owner.chatbubbleentity = world;
 915                 remove(self);
 916                 return;
 917         }
 918         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 919         if (self.owner.buttonchat && !self.owner.deadflag)
 920                 self.model = self.mdl;
 921         else
 922                 self.model = "";
 923 };
 924
 925 void() UpdateChatBubble =
 926 {
 927         if (!self.modelindex)
 928                 return;
 929         // spawn a chatbubble entity if needed
 930         if (!self.chatbubbleentity)
 931         {
 932                 self.chatbubbleentity = spawn();
 933                 self.chatbubbleentity.owner = self;
 934                 self.chatbubbleentity.exteriormodeltoclient = self;
 935                 self.chatbubbleentity.think = ChatBubbleThink;
 936                 self.chatbubbleentity.nextthink = time;
 937                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
 938                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 939                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 940                 self.chatbubbleentity.model = "";
 941                 self.chatbubbleentity.effects = EF_LOWPRECISION;
 942         }
 943 }
 944
 945
 946 void() TeamBubbleThink =
 947 {
 948         self.nextthink = time;
 949         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 950         {
 951                 self.owner.teambubbleentity = world;
 952                 remove(self);
 953                 return;
 954         }
 955 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 956         if (self.owner.buttonchat || self.owner.deadflag)
 957                 self.model = "";
 958         else
 959                 self.model = self.mdl;
 960
 961 };
 962
 963 float() TeamBubble_customizeentityforclient
 964 {
 965         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 966 }
 967
 968 void() UpdateTeamBubble =
 969 {
 970         if (!self.modelindex || !cvar("teamplay"))
 971                 return;
 972         // spawn a teambubble entity if needed
 973         if (!self.teambubbleentity && cvar("teamplay"))
 974         {
 975                 self.teambubbleentity = spawn();
 976                 self.teambubbleentity.owner = self;
 977                 self.teambubbleentity.exteriormodeltoclient = self;
 978                 self.teambubbleentity.think = TeamBubbleThink;
 979                 self.teambubbleentity.nextthink = time;
 980                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
 981 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 982                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 983                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 984                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 985                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 986                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 987                 self.teambubbleentity.effects = EF_LOWPRECISION;
 988         }
 989 }
 990
 991 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 992 // added to the model skins
 993 /*void() UpdateColorModHack =
 994 {
 995         local float c;
 996         c = self.clientcolors & 15;
 997         // LordHavoc: only bothering to support white, green, red, yellow, blue
 998              if (teamplay == 0) self.colormod = '0 0 0';
 999         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1000         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1001         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1002         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1003         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1004         else self.colormod = '1 1 1';
1005 };*/
1006
1007 void respawn(void)
1008 {
1009         CopyBody(1);
1010         self.effects |= EF_NODRAW; // prevent another CopyBody
1011         PutClientInServer();
1012 }
1013
1014 void player_powerups (void)
1015 {
1016         if (g_minstagib)
1017         {
1018                 if (self.items & IT_STRENGTH)
1019                 {
1020                         if (time > self.strength_finished)
1021                         {
1022                                 if (g_minstagib_invis_alpha > 0)
1023                                 {
1024                                         self.alpha = default_player_alpha;
1025                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1026                                         self.effects = self.effects | EF_FULLBRIGHT;
1027                                 }
1028                                 else
1029                                 {
1030                                         self.effects -= self.effects & EF_NODRAW;
1031                                 }
1032                                 self.items = self.items - (self.items & IT_STRENGTH);
1033                                 sprint(self, "^3Invisibility has worn off\n");
1034                         }
1035                 }
1036                 else
1037                 {
1038                         if (time < self.strength_finished)
1039                         {
1040                                 if (g_minstagib_invis_alpha > 0)
1041                                 {
1042                                         self.alpha = g_minstagib_invis_alpha;
1043                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1044                                         self.effects -= self.effects & EF_FULLBRIGHT;
1045                                 }
1046                                 else
1047                                 {
1048                                         self.effects = self.effects | EF_NODRAW;
1049                                 }
1050                                 self.items = self.items | IT_STRENGTH;
1051                                 sprint(self, "^3You are invisible\n");
1052                         }
1053                 }
1054
1055                 if (self.items & IT_INVINCIBLE)
1056                 {
1057                         if (time > self.invincible_finished)
1058                         {
1059                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1060                                 sprint(self, "^3Speed has worn off\n");
1061                         }
1062                 }
1063                 else
1064                 {
1065                         if (time < self.invincible_finished)
1066                         {
1067                                 self.items = self.items | IT_INVINCIBLE;
1068                                 sprint(self, "^3You are on speed\n");
1069                         }
1070                 }
1071                 return;
1072         }
1073
1074         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1075         if (self.items & IT_STRENGTH)
1076         {
1077                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1078                 if (time > self.strength_finished)
1079                 {
1080                         self.items = self.items - (self.items & IT_STRENGTH);
1081                         sprint(self, "^3Strength has worn off\n");
1082                 }
1083         }
1084         else
1085         {
1086                 if (time < self.strength_finished)
1087                 {
1088                         self.items = self.items | IT_STRENGTH;
1089                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1090                 }
1091         }
1092         if (self.items & IT_INVINCIBLE)
1093         {
1094                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1095                 if (time > self.invincible_finished)
1096                 {
1097                         self.items = self.items - (self.items & IT_INVINCIBLE);
1098                         sprint(self, "^3Shield has worn off\n");
1099                 }
1100         }
1101         else
1102         {
1103                 if (time < self.invincible_finished)
1104                 {
1105                         self.items = self.items | IT_INVINCIBLE;
1106                         sprint(self, "^3Shield surrounds you\n");
1107                 }
1108         }
1109
1110         if (cvar("g_fullbrightplayers"))
1111                 self.effects = self.effects | EF_FULLBRIGHT;
1112
1113         // midair gamemode: damage only while in the air
1114         // if in midair mode, being on ground grants temporary invulnerability
1115         // (this is so that multishot weapon don't clear the ground flag on the
1116         // first damage in the frame, leaving the player vulnerable to the
1117         // remaining hits in the same frame)
1118         if (self.flags & FL_ONGROUND)
1119         if (g_midair)
1120                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1121
1122         if (time < self.spawnshieldtime)
1123                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1124 }
1125
1126 float CalcRegen(float current, float stable, float regenfactor)
1127 {
1128         if(current > stable)
1129                 return current;
1130         else if(current > stable - 0.25) // when close enough, "snap"
1131                 return stable;
1132         else
1133                 return min(stable, current + (stable - current) * regenfactor * frametime);
1134 }
1135
1136 void player_regen (void)
1137 {
1138         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1139         maxh = cvar("g_balance_health_stable");
1140         maxa = cvar("g_balance_armor_stable");
1141         limith = cvar("g_balance_health_limit");
1142         limita = cvar("g_balance_armor_limit");
1143
1144         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1145                 return;
1146
1147         max_mod = regen_mod = rot_mod = limit_mod = 1;
1148
1149         if (self.runes & RUNE_REGEN)
1150         {
1151                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1152                 {
1153                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1154                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1155                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1156                 }
1157                 else
1158                 {
1159                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1160                         max_mod = cvar("g_balance_rune_regen_hpmod");
1161                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1162                 }
1163         }
1164         else if (self.runes & CURSE_VENOM)
1165         {
1166                 max_mod = cvar("g_balance_curse_venom_hpmod");
1167                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1168                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1169                 else
1170                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1171                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1172                 //if (!self.runes & RUNE_REGEN)
1173                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1174         }
1175         maxh = maxh * max_mod;
1176         //maxa = maxa * max_mod;
1177         limith = limith * limit_mod;
1178         limita = limita * limit_mod;
1179
1180         if (self.armorvalue > maxa)
1181         {
1182                 if (time > self.pauserotarmor_finished)
1183                 {
1184                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1185                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1186                 }
1187         }
1188         else if (self.armorvalue < maxa)
1189         {
1190                 if (time > self.pauseregen_finished)
1191                 {
1192                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1193                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1194                 }
1195         }
1196         if (self.health > maxh)
1197         {
1198                 if (time > self.pauserothealth_finished)
1199                 {
1200                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1201                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1202                 }
1203         }
1204         else if (self.health < maxh)
1205         {
1206                 if (time > self.pauseregen_finished)
1207                 {
1208                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1209                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1210                 }
1211         }
1212
1213         if (self.health > limith)
1214                 self.health = limith;
1215         if (self.armorvalue > limita)
1216                 self.armorvalue = limita;
1217
1218         // if player rotted to death...  die!
1219         if(self.health < 1)
1220                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1221 }
1222
1223 /*
1224 ======================
1225 spectate mode routines
1226 ======================
1227 */
1228 void SpectateCopy(entity spectatee) {
1229         self.armortype = spectatee.armortype;
1230         self.armorvalue = spectatee.armorvalue;
1231         self.currentammo = spectatee.currentammo;
1232         self.effects = spectatee.effects;
1233         self.health = spectatee.health;
1234         self.impulse = 0;
1235         self.items = spectatee.items;
1236         self.punchangle = spectatee.punchangle;
1237         self.view_ofs = spectatee.view_ofs;
1238         self.v_angle = spectatee.v_angle;
1239         self.viewzoom = spectatee.viewzoom;
1240         self.velocity = spectatee.velocity;
1241         self.dmg_take = spectatee.dmg_take;
1242         self.dmg_save = spectatee.dmg_save;
1243         self.dmg_inflictor = spectatee.dmg_inflictor;
1244         self.angles = spectatee.v_angle;
1245         self.fixangle = TRUE;
1246         setorigin(self, spectatee.origin);
1247         setsize(self, spectatee.mins, spectatee.maxs);
1248 }
1249
1250 void SpectateUpdate() {
1251         if(!self.enemy)
1252                         PutObserverInServer();
1253
1254         if (self != self.enemy) {
1255                 if(self.enemy.flags & FL_NOTARGET)
1256                         PutObserverInServer();
1257                 SpectateCopy(self.enemy);
1258                 //msg_entity = self;
1259                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1260                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1261                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1262                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1263         }
1264 }
1265
1266 float SpectateNext() {
1267         other = find(self.enemy, classname, "player");
1268         if (!other) {
1269                 other = find(other, classname, "player");
1270         }
1271         if (other) {
1272                 self.enemy = other;
1273         }
1274         if(self.enemy.classname == "player") {
1275                 msg_entity = self;
1276                 WriteByte(MSG_ONE, SVC_SETVIEW);
1277                 WriteEntity(MSG_ONE, self.enemy);
1278                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1279                 SpectateUpdate();
1280                 return 1;
1281         } else {
1282                 return 0;
1283         }
1284 }
1285
1286 /*
1287 =============
1288 ShowRespawnCountdown()
1289
1290 Update a respawn countdown display.
1291 =============
1292 */
1293 void ShowRespawnCountdown()
1294 {
1295         float number;
1296         if(self.deadflag == DEAD_NO) // just respawned?
1297                 return;
1298         else
1299         {
1300                 number = ceil(self.death_time - time);
1301                 if(number <= 0)
1302                         return;
1303                 if(number <= self.respawn_countdown)
1304                 {
1305                         self.respawn_countdown = number - 1;
1306                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1307                                 play2(self, strcat("announcer/robotic/", ftos(number), "announcer/.ogg"));
1308                 }
1309         }
1310 }
1311
1312 void LeaveSpectatorMode()
1313 {
1314         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1315                 self.classname = "player";
1316                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1317                         JoinBestTeam(self, 0);
1318                 if(cvar("g_campaign"))
1319                         campaign_bots_may_start = 1;
1320                 PutClientInServer();
1321                 if(!(self.flags & FL_NOTARGET))
1322                         bprint ("^4", self.netname, "^4 is playing now\n");
1323                 centerprint(self,"");
1324                 return;
1325         } else {
1326                 stuffcmd(self,"menu_showteamselect\n");
1327                 return;
1328         }
1329 }
1330
1331 /*
1332 =============
1333 PlayerPreThink
1334
1335 Called every frame for each client before the physics are run
1336 =============
1337 */
1338 void() ctf_setstatus;
1339 .float vote_nagtime;
1340 void PlayerPreThink (void)
1341 {
1342         // version nagging
1343         if(self.version_nagtime)
1344                 if(self.cvar_g_nexuizversion)
1345                         if(time > self.version_nagtime)
1346                         {
1347                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1348                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1349                                         {
1350                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1351                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1352                                         }
1353                                 self.version_nagtime = 0;
1354                         }
1355
1356         // vote nagging
1357         if(self.cvar_scr_centertime)
1358                 if(time > self.vote_nagtime)
1359                 {
1360                         VoteNag();
1361                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1362                 }
1363
1364         // GOD MODE info
1365         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1366         {
1367                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1368                 self.max_armorvalue = 0;
1369         }
1370
1371         if(frametime)
1372                 antilag_record(self);
1373
1374         if(self.classname == "player") {
1375 //              if(self.netname == "Wazat")
1376 //                      bprint(self.classname, "\n");
1377
1378                 CheckRules_Player();
1379
1380                 if(self.button7)
1381                         PrintWelcomeMessage(self);
1382
1383                 if(g_lms || !cvar("sv_spectate"))
1384                 if((time - self.jointime) <= cvar("welcome_message_time"))
1385                         PrintWelcomeMessage(self);
1386
1387                 if (intermission_running)
1388                 {
1389                         IntermissionThink ();   // otherwise a button could be missed between
1390                         return;                                 // the think tics
1391                 }
1392
1393                 if(self.teleport_time)
1394                 if(time > self.teleport_time)
1395                 {
1396                         self.teleport_time = 0;
1397                         self.effects = self.effects - (self.effects & EF_NODRAW);
1398                         if(self.weaponentity)
1399                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1400                 }
1401
1402                 Nixnex_GiveCurrentWeapon();
1403
1404                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1405                         UpdateSelectedPlayer();
1406
1407                 if (self.deadflag != DEAD_NO)
1408                 {
1409                         float button_pressed, force_respawn;
1410                         player_anim();
1411                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1412                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1413                         if (self.deadflag == DEAD_DYING)
1414                         {
1415                                 if(force_respawn)
1416                                         self.deadflag = DEAD_RESPAWNING;
1417                                 else if(!button_pressed)
1418                                         self.deadflag = DEAD_DEAD;
1419                         }
1420                         else if (self.deadflag == DEAD_DEAD)
1421                         {
1422                                 if(button_pressed)
1423                                         self.deadflag = DEAD_RESPAWNABLE;
1424                         }
1425                         else if (self.deadflag == DEAD_RESPAWNABLE)
1426                         {
1427                                 if(!button_pressed)
1428                                         self.deadflag = DEAD_RESPAWNING;
1429                         }
1430                         else if (self.deadflag == DEAD_RESPAWNING)
1431                         {
1432                                 if(time > self.death_time)
1433                                 {
1434                                         self.death_time = time + 1; // only retry once a second
1435                                         respawn();
1436                                 }
1437                         }
1438                         ShowRespawnCountdown();
1439                         return;
1440                 }
1441
1442                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1443                 {
1444                         vector dist;
1445
1446                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1447                         dist = self.oldorigin - self.origin;
1448                         dist_z = 0;
1449                         self.lms_traveled_distance += fabs(vlen(dist));
1450
1451                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1452                         {
1453                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1454                                 self.lms_traveled_distance = 0;
1455                         }
1456
1457                         if(time > self.lms_nextcheck)
1458                         {
1459                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1460                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1461                                 {
1462                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1463                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1464                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1465                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1466                                 }
1467                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1468                                 self.lms_traveled_distance = 0;
1469                         }
1470                 }
1471
1472                 if (self.button5 && !self.hook.state)
1473                 {
1474                         if (!self.crouch)
1475                         {
1476                                 self.crouch = TRUE;
1477                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1478                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1479                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
1480                         }
1481                 }
1482                 else
1483                 {
1484                         if (self.crouch)
1485                         {
1486                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1487                                 if (!trace_startsolid)
1488                                 {
1489                                         self.crouch = FALSE;
1490                                         self.view_ofs = PL_VIEW_OFS;
1491                                         setsize (self, PL_MIN, PL_MAX);
1492                                 }
1493                         }
1494                 }
1495
1496                 FixPlayermodel();
1497
1498                 GrapplingHookFrame();
1499
1500                 W_WeaponFrame();
1501
1502                 {
1503                         float zoomfactor, zoomspeed, zoomdir;
1504                         zoomfactor = self.cvar_cl_zoomfactor;
1505                         if(zoomfactor < 1 || zoomfactor > 16)
1506                                 zoomfactor = 2.5;
1507                         zoomspeed = self.cvar_cl_zoomspeed;
1508                         if(zoomspeed >= 0) // < 0 is instant zoom
1509                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1510                                         zoomspeed = 3.5;
1511
1512                         zoomdir = self.button4;
1513                         if(self.button3)
1514                                 if(self.weapon == WEP_NEX)
1515                                         if(!g_minstagib)
1516                                                 zoomdir = 1;
1517
1518                         if(zoomdir)
1519                                 self.has_zoomed = 1;
1520
1521                         if(self.has_zoomed)
1522                         {
1523                                 if(zoomspeed <= 0) // instant zoom
1524                                 {
1525                                         if(zoomdir)
1526                                                 self.viewzoom = 1 / zoomfactor;
1527                                         else
1528                                                 self.viewzoom = 1;
1529                                 }
1530                                 else
1531                                 {
1532                                         // geometric zoom would be:
1533                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1534                                         // however, testing showed that arithmetic/harmonic zoom works better
1535                                         if(zoomdir)
1536                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1537                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1538                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1539                                         else
1540                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1541                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1542                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1543                                 }
1544                         }
1545                         else
1546                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1547                 }
1548
1549                 player_powerups();
1550                 player_regen();
1551                 player_anim();
1552
1553                 if (g_minstagib)
1554                         minstagib_ammocheck();
1555
1556                 ctf_setstatus();
1557                 kh_setstatus();
1558
1559                 //self.angles_y=self.v_angle_y + 90;   // temp
1560
1561                 //if (TetrisPreFrame()) return;
1562         } else if(gameover) {
1563                 if (intermission_running)
1564                         IntermissionThink ();   // otherwise a button could be missed between
1565                 return;
1566         } else if(self.classname == "observer") {
1567
1568                 if (self.flags & FL_JUMPRELEASED) {
1569                         if (self.button2 && self.version == cvar("gameversion")) {
1570                                 self.welcomemessage_time = 0;
1571                                 self.flags = self.flags - FL_JUMPRELEASED;
1572                                 LeaveSpectatorMode();
1573                                 return;
1574                         } else if(self.button0 && self.version == cvar("gameversion")) {
1575                                 self.welcomemessage_time = 0;
1576                                 self.flags = self.flags - FL_JUMPRELEASED;
1577                                 if(SpectateNext() == 1) {
1578                                         self.classname = "spectator";
1579                                 }
1580                         }
1581                 } else {
1582                         if (!(self.button0 || self.button2)) {
1583                                 self.flags = self.flags | FL_JUMPRELEASED;
1584                         }
1585                 }
1586                 PrintWelcomeMessage(self);
1587         } else if(self.classname == "spectator") {
1588                 if (self.flags & FL_JUMPRELEASED) {
1589                         if (self.button2 && self.version == cvar("gameversion")) {
1590                                 self.welcomemessage_time = 0;
1591                                 self.flags = self.flags - FL_JUMPRELEASED;
1592                                 LeaveSpectatorMode();
1593                                 return;
1594                         } else if(self.button0) {
1595                                 self.welcomemessage_time = 0;
1596                                 self.flags = self.flags - FL_JUMPRELEASED;
1597                                 if(SpectateNext() == 1) {
1598                                         self.classname = "spectator";
1599                                 } else {
1600                                         self.classname = "observer";
1601                                         PutClientInServer();
1602                                 }
1603                         } else if (self.button3) {
1604                                 self.welcomemessage_time = 0;
1605                                 self.flags = self.flags - FL_JUMPRELEASED;
1606                                 self.classname = "observer";
1607                                 PutClientInServer();
1608                         } else {
1609                                 SpectateUpdate();
1610                         }
1611                 } else {
1612                         if (!(self.button0 || self.button3)) {
1613                                 self.flags = self.flags | FL_JUMPRELEASED;
1614                         }
1615                 }
1616                 PrintWelcomeMessage(self);
1617                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1618         }
1619 }
1620
1621
1622 /*
1623 =============
1624 PlayerPostThink
1625
1626 Called every frame for each client after the physics are run
1627 =============
1628 */
1629 void PlayerPostThink (void)
1630 {
1631         // Savage: Check for nameless players
1632         if (strlen(self.netname) < 1) {
1633                 self.netname = "Player";
1634                 stuffcmd(self, "seta _cl_name Player\n");
1635         }
1636
1637         if(self.classname == "player") {
1638                 CheckRules_Player();
1639                 UpdateChatBubble();
1640                 UpdateTeamBubble();
1641                 if (self.impulse)
1642                         ImpulseCommands();
1643                 if (intermission_running)
1644                         return;         // intermission or finale
1645
1646                 //PrintWelcomeMessage(self);
1647                 //if (TetrisPostFrame()) return;
1648
1649                 // restart countdown
1650                 if(time < restart_countdown)
1651                 {
1652                         string s;
1653                         float sec;
1654
1655                         sec = ceil(restart_countdown-time);
1656                         s = strcat(NEWLINES, "^1Game starts in ", ftos(sec), " seconds");
1657                         centerprint(self, s);
1658                         self.movetype = MOVETYPE_NONE;
1659                         self.velocity = '0 0 0';
1660                         self.avelocity = '0 0 0';
1661                         self.movement = '0 0 0';
1662                 }
1663                 else if(self.movetype == MOVETYPE_NONE)
1664                 {
1665                         self.movetype = MOVETYPE_WALK;
1666                         centerprint(self, "\n");
1667                 }
1668         } else if (self.classname == "observer") {
1669                 //do nothing
1670         } else if (self.classname == "spectator") {
1671                 //do nothing
1672         }
1673
1674         Arena_Warmup();
1675 }