data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         info_player_deathmatch();
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8         self.classname = "info_player_deathmatch";
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27
  28                 local float spotactive;
  29                 spotactive = 1;
  30
  31                 // filter out spots for assault
  32                 if(spot.target != "") {
  33                         local entity ent;
  34                         ent = find(world, targetname, spot.target);
  35                         while(ent) {
  36                                 if(ent.classname == "target_objective")
  37                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  38                                                 spotactive = 0;
  39                                 ent = find(ent, targetname, spot.target);
  40                         }
  41                 }
  42
  43                 if (spot.team == teamcheck && spotactive > 0)
  44                 {
  45                         pcount = 0;
  46                         player = playerlist;
  47                         while (player)
  48                         {
  49                                 if (player != self)
  50                                 if (vlen(player.origin - spot.origin) < mindist)
  51                                         pcount = pcount + 1;
  52                                 player = player.chain;
  53                         }
  54                         if (!pcount)
  55                         {
  56                                 spawn_allbad = FALSE;
  57                                 if (newfirstspot)
  58                                         previousspot.chain = spot;
  59                                 else
  60                                         newfirstspot = spot;
  61                                 previousspot = spot;
  62                                 spot.chain = world;
  63                         }
  64                         else
  65                                 spawn_allgood = FALSE;
  66                 }
  67                 spot = nextspot;
  68         }
  69         // if we couldn't find ANY good points, return the original list
  70         if (!newfirstspot)
  71                 newfirstspot = firstspot;
  72         return newfirstspot;
  73 }
  74
  75 entity Spawn_RandomPoint(entity firstspot)
  76 {
  77         local entity spot;
  78         local float numspots;
  79         // count number of spots
  80         numspots = 0;
  81         spot = firstspot;
  82         while (spot)
  83         {
  84                 numspots = numspots + 1;
  85                 spot = spot.chain;
  86         }
  87         // pick a random one
  88         numspots = numspots * random();
  89         spot = firstspot;
  90         while (spot.chain && numspots >= 1)
  91         {
  92                 numspots = numspots - 1;
  93                 spot = spot.chain;
  94         }
  95         return spot;
  96 }
  97
  98 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  99 {
 100         local entity best, spot, player;
 101         local float bestrating, rating;
 102         best = world;
 103         bestrating = -1000000;
 104         spot = firstspot;
 105         while (spot)
 106         {
 107                 rating = 1000000000;
 108                 player = playerlist;
 109                 while (player)
 110                 {
 111                         if (player != self)
 112                                 rating = min(rating, vlen(player.origin - spot.origin));
 113                         player = player.chain;
 114                 }
 115                 rating = rating + random() * 16;
 116                 if (bestrating < rating)
 117                 {
 118                         best = spot;
 119                         bestrating = rating;
 120                 }
 121                 spot = spot.chain;
 122         }
 123         return best;
 124 }
 125
 126 /*
 127 =============
 128 SelectSpawnPoint
 129
 130 Finds a point to respawn
 131 =============
 132 */
 133 entity SelectSpawnPoint (float anypoint)
 134 {
 135         local float teamcheck;
 136         local entity spot, firstspot, playerlist;
 137
 138         spot = find (world, classname, "testplayerstart");
 139         if (spot)
 140                 return spot;
 141
 142         teamcheck = 0;
 143
 144         if(!anypoint && (g_ctf || g_assault))
 145                 teamcheck = self.team;
 146
 147         // get the list of players
 148         playerlist = findchain(classname, "player");
 149         // get the entire list of spots
 150         firstspot = findchain(classname, "info_player_deathmatch");
 151         // filter out the bad ones
 152         // (note this returns the original list if none survived)
 153         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 154
 155         // there is 50/50 chance of choosing a random spot or the furthest spot
 156         // (this means that roughly every other spawn will be furthest, so you
 157         // usually won't get fragged at spawn twice in a row)
 158         if (arena_roundbased)
 159         {
 160                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 161                 spot = Spawn_RandomPoint(firstspot);
 162         }
 163         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 164                 spot = Spawn_RandomPoint(firstspot);
 165         else
 166                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 167
 168         if (!spot)
 169         {
 170                 if(cvar("spawn_debug"))
 171                         GotoNextMap();
 172                 else
 173                         error ("PutClientInServer: no start points on level");
 174         }
 175
 176         return spot;
 177 }
 178
 179 /*
 180 =============
 181 CheckPlayerModel
 182
 183 Checks if the argument string can be a valid playermodel.
 184 Returns a valid one in doubt.
 185 =============
 186 */
 187 string FallbackPlayerModel = "models/player/marine.zym";
 188 string CheckPlayerModel(string plyermodel) {
 189         if(strlen(plyermodel) < 4)
 190                 return FallbackPlayerModel;
 191         if( substring(plyermodel,0,14) != "models/player/")
 192                 return FallbackPlayerModel;
 193         else if(cvar("sv_servermodelsonly"))
 194         {
 195                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 196                         return FallbackPlayerModel;
 197                 if(!fexists(plyermodel))
 198                         return FallbackPlayerModel;
 199         }
 200         return plyermodel;
 201 }
 202
 203 /*
 204 =============
 205 Client_customizeentityforclient
 206
 207 LOD reduction
 208 =============
 209 */
 210 float Client_customizeentityforclient()
 211 {
 212 #ifdef ALLOW_VARIABLE_LOD
 213         // self: me
 214         // other: the player viewing me
 215         float distance;
 216         float f;
 217
 218         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 219                 return TRUE;
 220
 221         if(other.cvar_cl_playerdetailreduction <= 0)
 222         {
 223                 if(other.cvar_cl_playerdetailreduction <= -2)
 224                         self.modelindex = self.modelindex_lod2;
 225                 else if(other.cvar_cl_playerdetailreduction <= -1)
 226                         self.modelindex = self.modelindex_lod1;
 227                 else
 228                         self.modelindex = self.modelindex_lod0;
 229         }
 230         else
 231         {
 232                 distance = vlen(self.origin - other.origin);
 233                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 234                 if(f > 10000)
 235                         self.modelindex = self.modelindex_lod2;
 236                 else if(f > 5000)
 237                         self.modelindex = self.modelindex_lod1;
 238                 else
 239                         self.modelindex = self.modelindex_lod0;
 240         }
 241 #endif
 242
 243         return TRUE;
 244 }
 245
 246 void setmodel_lod(entity e, string modelname)
 247 {
 248 #ifdef ALLOW_VARIABLE_LOD
 249         string s;
 250
 251         // FIXME: this only supports 3-letter extensions
 252         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 253         if(fexists(s))
 254         {
 255                 precache_model(s);
 256                 setmodel(e, s); // players have high precision
 257                 self.modelindex_lod1 = self.modelindex;
 258         }
 259         else
 260                 self.modelindex_lod1 = -1;
 261
 262         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 263         if(fexists(s))
 264         {
 265                 precache_model(s);
 266                 setmodel(e, s); // players have high precision
 267                 self.modelindex_lod2 = self.modelindex;
 268         }
 269         else
 270                 self.modelindex_lod2 = -1;
 271
 272         precache_model(modelname);
 273         setmodel(e, modelname); // players have high precision
 274         self.modelindex_lod0 = self.modelindex;
 275
 276         if(self.modelindex_lod1 < 0)
 277                 self.modelindex_lod1 = self.modelindex;
 278
 279         if(self.modelindex_lod2 < 0)
 280                 self.modelindex_lod2 = self.modelindex;
 281 #else
 282         precache_model(modelname);
 283         setmodel(e, modelname); // players have high precision
 284 #endif
 285         player_setupanimsformodel();
 286 }
 287
 288 /*
 289 =============
 290 PutObserverInServer
 291
 292 putting a client as observer in the server
 293 =============
 294 */
 295 void PutObserverInServer (void)
 296 {
 297         entity  spot;
 298         spot = SelectSpawnPoint (TRUE);
 299         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 300
 301         if(clienttype(self) == CLIENTTYPE_REAL)
 302         {
 303                 msg_entity = self;
 304                 WriteByte(MSG_ONE, SVC_SETVIEW);
 305                 WriteEntity(MSG_ONE, self);
 306         }
 307
 308         DropAllRunes(self);
 309         kh_Key_DropAll(self, TRUE);
 310
 311         if(self.flagcarried)
 312                 DropFlag(self.flagcarried);
 313
 314         WaypointSprite_PlayerDead();
 315
 316         DistributeFragsAmongTeam(self, self.team, 1);
 317
 318         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 319                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 320         else if(self.killcount != -666)
 321                 bprint ("^4", self.netname, "^4 is spectating now\n");
 322
 323         self.classname = "observer";
 324         self.health = -666;
 325         self.takedamage = DAMAGE_NO;
 326         self.solid = SOLID_NOT;
 327         self.movetype = MOVETYPE_NOCLIP;
 328         self.flags = FL_CLIENT | FL_NOTARGET;
 329         self.armorvalue = 666;
 330         self.effects = 0;
 331         self.armorvalue = cvar("g_balance_armor_start");
 332         self.pauserotarmor_finished = 0;
 333         self.pauserothealth_finished = 0;
 334         self.pauseregen_finished = 0;
 335         self.damageforcescale = 0;
 336         self.death_time = 0;
 337         self.dead_frame = 0;
 338         self.deaths = 0;
 339         self.alpha = 0;
 340         self.scale = 0;
 341         self.fade_time = 0;
 342         self.pain_frame = 0;
 343         self.pain_finished = 0;
 344         self.strength_finished = 0;
 345         self.invincible_finished = 0;
 346         self.pushltime = 0;
 347         self.think = SUB_Null;
 348         self.nextthink = 0;
 349         self.hook_time = 0;
 350         self.runes = 0;
 351         self.deadflag = DEAD_NO;
 352         self.angles = spot.angles;
 353         self.angles_z = 0;
 354         self.fixangle = TRUE;
 355         self.crouch = FALSE;
 356
 357         self.view_ofs = PL_VIEW_OFS;
 358         setorigin (self, spot.origin);
 359         setsize (self, '0 0 0', '0 0 0');
 360         self.oldorigin = self.origin;
 361         self.items = 0;
 362         self.model = "";
 363         self.modelindex = 0;
 364         self.weapon = 0;
 365         self.weaponmodel = "";
 366         self.weaponentity = world;
 367         self.killcount = -666;
 368         self.velocity = '0 0 0';
 369         self.avelocity = '0 0 0';
 370         self.punchangle = '0 0 0';
 371         self.punchvector = '0 0 0';
 372         self.oldvelocity = self.velocity;
 373         self.customizeentityforclient = Client_customizeentityforclient;
 374
 375         if(g_arena)
 376         {
 377                 if(self.frags != -2)
 378                 {
 379                         Spawnqueue_Insert(self);
 380                 }
 381                 else
 382                 {
 383                         Spawnqueue_Unmark(self);
 384                         Spawnqueue_Remove(self);
 385                 }
 386         }
 387         else if(!g_lms)
 388                 self.frags = -666;
 389 }
 390
 391
 392 /*
 393 =============
 394 PutClientInServer
 395
 396 Called when a client spawns in the server
 397 =============
 398 */
 399 void PutClientInServer (void)
 400 {
 401         if(clienttype(self) == CLIENTTYPE_BOT)
 402         {
 403                 self.classname = "player";
 404         }
 405         else if(clienttype(self) == CLIENTTYPE_REAL)
 406         {
 407                 msg_entity = self;
 408                 WriteByte(MSG_ONE, SVC_SETVIEW);
 409                 WriteEntity(MSG_ONE, self);
 410         }
 411
 412         // player is dead and becomes observer
 413         if(g_lms && self.frags < 1)
 414                 self.classname = "observer";
 415
 416         if(g_arena)
 417         if(!self.spawned)
 418                 self.classname = "observer";
 419
 420         if(self.classname == "player") {
 421                 entity  spot;
 422
 423                 spot = SelectSpawnPoint (FALSE);
 424
 425                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 426
 427                 self.classname = "player";
 428                 self.iscreature = TRUE;
 429                 self.movetype = MOVETYPE_WALK;
 430                 self.solid = SOLID_SLIDEBOX;
 431                 self.flags = FL_CLIENT;
 432                 self.takedamage = DAMAGE_AIM;
 433                 self.effects = 0;
 434                 self.air_finished = time + 12;
 435                 self.dmg = 2;
 436
 437                 self.ammo_shells = start_ammo_shells;
 438                 self.ammo_nails = start_ammo_nails;
 439                 self.ammo_rockets = start_ammo_rockets;
 440                 self.ammo_cells = start_ammo_cells;
 441                 self.health = start_health;
 442                 self.armorvalue = start_armorvalue;
 443                 self.items = start_items;
 444                 self.switchweapon = start_switchweapon;
 445                 self.weapon = 0;
 446                 self.jump_interval = time;
 447
 448                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 449                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 450                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 451                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 452                 self.damageforcescale = 2;
 453                 self.death_time = 0;
 454                 self.dead_frame = 0;
 455                 self.alpha = 0;
 456                 self.scale = 0;
 457                 self.fade_time = 0;
 458                 self.pain_frame = 0;
 459                 self.pain_finished = 0;
 460                 self.strength_finished = 0;
 461                 self.invincible_finished = 0;
 462                 self.pushltime = 0;
 463                 //self.speed_finished = 0;
 464                 //self.slowmo_finished = 0;
 465                 // players have no think function
 466                 self.think = SUB_Null;
 467                 self.nextthink = 0;
 468                 self.hook_time = 0;
 469
 470                 self.runes = 0;
 471
 472                 self.deadflag = DEAD_NO;
 473
 474                 self.angles = spot.angles;
 475
 476                 self.angles_z = 0; // never spawn tilted even if the spot says to
 477                 self.fixangle = TRUE; // turn this way immediately
 478                 self.velocity = '0 0 0';
 479                 self.avelocity = '0 0 0';
 480                 self.punchangle = '0 0 0';
 481                 self.punchvector = '0 0 0';
 482                 self.oldvelocity = self.velocity;
 483
 484                 self.viewzoom = 0.6;
 485                 self.has_zoomed = 0;
 486
 487                 self.customizeentityforclient = Client_customizeentityforclient;
 488
 489                 if(cvar("sv_defaultcharacter") == 1) {
 490                         local string defaultmodel;
 491                         defaultmodel = cvar_string("sv_defaultplayermodel");
 492                         setmodel_lod (self, defaultmodel);
 493                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 494                 } else {
 495                         self.playermodel = CheckPlayerModel(self.playermodel);
 496                         setmodel_lod (self, self.playermodel);
 497                         if(teams_matter)
 498                         {
 499                                 float s;
 500                                 s = stof(self.playerskin);
 501                                 if(s >= 0 && s < 3)
 502                                         self.skin = s;
 503                                 else if(s == 6)
 504                                         self.skin = 6;
 505                                 else
 506                                         self.skin = 0;
 507                         }
 508                         else
 509                                 self.skin = stof(self.playerskin);
 510                 }
 511                 if(!teams_matter)
 512                         if(strlen(cvar_string("sv_defaultplayercolors")))
 513                                 setcolor(self, cvar("sv_defaultplayercolors"));
 514
 515                 self.crouch = FALSE;
 516                 self.view_ofs = PL_VIEW_OFS;
 517                 setsize (self, PL_MIN, PL_MAX);
 518                 self.spawnorigin = spot.origin;
 519                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 520                 // don't reset back to last position, even if new position is stuck in solid
 521                 self.oldorigin = self.origin;
 522
 523                 if(g_arena)
 524                 {
 525                         Spawnqueue_Remove(self);
 526                         Spawnqueue_Mark(self);
 527                 }
 528
 529                 self.event_damage = PlayerDamage;
 530
 531                 self.bot_attack = TRUE;
 532
 533                 self.statdraintime = time + 5;
 534                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 535
 536                 if(self.killcount == -666) {
 537                         self.killcount = 0;
 538                         if(!g_arena)
 539                         if(!g_lms)
 540                                 self.frags = 0;
 541                 }
 542
 543                 self.cnt = WEP_LASER;
 544                 self.nixnex_lastchange_id = -1;
 545
 546                 CL_SpawnWeaponentity();
 547                 self.alpha = default_player_alpha;
 548                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 549
 550                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 551                 self.lms_traveled_distance = 0;
 552
 553                 if(cvar("spawn_debug"))
 554                 {
 555                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 556                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 557                 }
 558
 559                 //stuffcmd(self, "chase_active 0");
 560                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 561
 562                 if (cvar("g_spawnsound"))
 563                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 564
 565                 if(g_assault) {
 566                         if(self.team == assault_attacker_team)
 567                                 centerprint(self, "You are attacking!\n");
 568                         else
 569                                 centerprint(self, "You are defending!\n");
 570                 }
 571
 572         } else if(self.classname == "observer") {
 573                 PutObserverInServer ();
 574         }
 575 }
 576
 577 /*
 578 =============
 579 SetNewParms
 580 =============
 581 */
 582 void SetNewParms (void)
 583 {
 584
 585 }
 586
 587 /*
 588 =============
 589 SetChangeParms
 590 =============
 591 */
 592 void SetChangeParms (void)
 593 {
 594
 595 }
 596
 597 /*
 598 =============
 599 ClientKill
 600
 601 Called when a client types 'kill' in the console
 602 =============
 603 */
 604 void ClientKill (void)
 605 {
 606         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 607 }
 608
 609 void FixClientCvars(entity e)
 610 {
 611         float t;
 612         // send prediction settings to the client
 613         stuffcmd(e, "\nin_bindmap 0 0\n");
 614         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 615         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 616         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 617         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 618         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 619         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 620         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 621         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 622         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 623         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 624         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 625         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 626         stuffcmd(e, "cl_movement_edgefriction 1\n");
 627
 628         // notify about available teams
 629         if(teamplay)
 630         {
 631                 CheckAllowedTeams(e);
 632                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
 633                 stuffcmd(e, strcat("set _teams_available ", ftos(t), "\n"));
 634         }
 635         else
 636                 stuffcmd(e, "set _teams_available 0\n");
 637 }
 638
 639 /*
 640 =============
 641 ClientConnect
 642
 643 Called when a client connects to the server
 644 =============
 645 */
 646 string ColoredTeamName(float t);
 647 //void dom_player_join_team(entity pl);
 648 void ClientConnect (void)
 649 {
 650         local string s;
 651         float wep;
 652
 653         if(Ban_IsClientBanned(self))
 654         {
 655                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 656                 dropclient(self);
 657                 bprint(s);
 658                 return;
 659         }
 660
 661         self.classname = "player_joining";
 662         self.flags = self.flags | FL_CLIENT;
 663         self.version_nagtime = time + 10 + random() * 10;
 664
 665         if(player_count<0)
 666         {
 667                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 668                 player_count = 0;
 669         }
 670
 671         bot_clientconnect();
 672
 673         //if(g_domination)
 674         //      dom_player_join_team(self);
 675
 676         //JoinBestTeam(self, FALSE);
 677
 678         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 679                 self.classname = "observer";
 680         } else {
 681                 self.classname = "player";
 682                 campaign_bots_may_start = 1;
 683         }
 684
 685         self.playerid = (playerid_last = playerid_last + 1);
 686         if(cvar("sv_eventlog"))
 687         {
 688                 if(clienttype(self) == CLIENTTYPE_REAL)
 689                         s = "player";
 690                 else
 691                         s = "bot";
 692                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 693                 s = strcat(":team:", ftos(self.playerid), ":");
 694                 s = strcat(s, ftos(self.team));
 695                 GameLogEcho(s, FALSE);
 696         }
 697
 698         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 699
 700         bprint ("^4",self.netname);
 701         bprint ("^4 connected");
 702
 703         if(g_domination || g_ctf)
 704         {
 705                 bprint(" and joined the ");
 706                 bprint(ColoredTeamName(self.team));
 707         }
 708
 709         bprint("\n");
 710
 711         self.welcomemessage_time = 0;
 712
 713         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 714         // TODO: is this being used for anything else than cd tracks?
 715         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 716
 717         FixClientCvars(self);
 718
 719         // waypoint sprites
 720         WaypointSprite_InitClient(self);
 721
 722         // Wazat's grappling hook
 723         SetGrappleHookBindings();
 724
 725         // get autoswitch state from player when he toggles it
 726         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 727
 728         // get version info from player
 729         stuffcmd(self, "cmd clientversion $gameversion\n");
 730
 731         // send all weapon info strings
 732         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
 733         wep = WEP_FIRST;
 734         while (wep <= WEP_LAST)
 735         {
 736                 weapon_action(wep, WR_REGISTER);
 737                 wep = wep + 1;
 738         }
 739
 740         // get other cvars from player
 741         GetCvars(0);
 742
 743         // set cvar for team scoreboard
 744         if (teams_matter)
 745         {
 746                 local float t;
 747                 t = cvar("teamplay");
 748                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 749                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 750         }
 751         else
 752                 stuffcmd(self, "set teamplay 0\n");
 753
 754         if(g_lms)
 755         {
 756                 self.frags = LMS_NewPlayerLives();
 757                 if(!self.frags)
 758                         self.frags = -666;
 759         }
 760         else if(g_arena)
 761         {
 762                 self.classname = "observer";
 763                 Spawnqueue_Insert(self);
 764         }
 765
 766         bot_relinkplayerlist();
 767
 768         self.jointime = time;
 769 }
 770
 771 /*
 772 =============
 773 ClientDisconnect
 774
 775 Called when a client disconnects from the server
 776 =============
 777 */
 778 void(entity e) DropFlag;
 779 .entity chatbubbleentity;
 780 .entity teambubbleentity;
 781 void ClientDisconnect (void)
 782 {
 783         float save;
 784         if(cvar("sv_eventlog"))
 785                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 786         bprint ("^4",self.netname);
 787         bprint ("^4 disconnected\n");
 788
 789         if (self.chatbubbleentity)
 790         {
 791                 remove (self.chatbubbleentity);
 792                 self.chatbubbleentity = world;
 793         }
 794
 795         if (self.teambubbleentity)
 796         {
 797                 remove (self.teambubbleentity);
 798                 self.teambubbleentity = world;
 799         }
 800
 801         WaypointSprite_PlayerGone();
 802
 803         DropAllRunes(self);
 804         kh_Key_DropAll(self, TRUE);
 805
 806         if(self.flagcarried)
 807                 DropFlag(self.flagcarried);
 808
 809         DistributeFragsAmongTeam(self, self.team, 1);
 810
 811         save = self.flags;
 812         self.flags = self.flags - (self.flags & FL_CLIENT);
 813         bot_relinkplayerlist();
 814         self.flags = save;
 815
 816         // remove laserdot
 817         if(self.weaponentity)
 818                 if(self.weaponentity.lasertarget)
 819                         remove(self.weaponentity.lasertarget);
 820
 821         if(g_arena)
 822         {
 823                 Spawnqueue_Unmark(self);
 824                 Spawnqueue_Remove(self);
 825         }
 826
 827         // free cvars
 828         GetCvars(-1);
 829 }
 830
 831 .float buttonchat;
 832 void() ChatBubbleThink =
 833 {
 834         self.nextthink = time;
 835         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 836         {
 837                 self.owner.chatbubbleentity = world;
 838                 remove(self);
 839                 return;
 840         }
 841         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 842         if (self.owner.buttonchat && !self.owner.deadflag)
 843                 self.model = self.mdl;
 844         else
 845                 self.model = "";
 846 };
 847
 848 void() UpdateChatBubble =
 849 {
 850         if (!self.modelindex)
 851                 return;
 852         // spawn a chatbubble entity if needed
 853         if (!self.chatbubbleentity)
 854         {
 855                 self.chatbubbleentity = spawn();
 856                 self.chatbubbleentity.owner = self;
 857                 self.chatbubbleentity.exteriormodeltoclient = self;
 858                 self.chatbubbleentity.think = ChatBubbleThink;
 859                 self.chatbubbleentity.nextthink = time;
 860                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
 861                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 862                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 863                 self.chatbubbleentity.model = "";
 864                 self.chatbubbleentity.effects = EF_LOWPRECISION;
 865         }
 866 }
 867
 868
 869 void() TeamBubbleThink =
 870 {
 871         self.nextthink = time;
 872         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 873         {
 874                 self.owner.teambubbleentity = world;
 875                 remove(self);
 876                 return;
 877         }
 878 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 879         if (self.owner.buttonchat || self.owner.deadflag)
 880                 self.model = "";
 881         else
 882                 self.model = self.mdl;
 883
 884 };
 885
 886 float() TeamBubble_customizeentityforclient
 887 {
 888         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 889 }
 890
 891 void() UpdateTeamBubble =
 892 {
 893         if (!self.modelindex || !cvar("teamplay"))
 894                 return;
 895         // spawn a teambubble entity if needed
 896         if (!self.teambubbleentity && cvar("teamplay"))
 897         {
 898                 self.teambubbleentity = spawn();
 899                 self.teambubbleentity.owner = self;
 900                 self.teambubbleentity.exteriormodeltoclient = self;
 901                 self.teambubbleentity.think = TeamBubbleThink;
 902                 self.teambubbleentity.nextthink = time;
 903                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
 904 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 905                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 906                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 907                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 908                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 909                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 910                 self.teambubbleentity.effects = EF_LOWPRECISION;
 911         }
 912 }
 913
 914 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 915 // added to the model skins
 916 /*void() UpdateColorModHack =
 917 {
 918         local float c;
 919         c = self.clientcolors & 15;
 920         // LordHavoc: only bothering to support white, green, red, yellow, blue
 921              if (teamplay == 0) self.colormod = '0 0 0';
 922         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 923         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 924         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 925         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 926         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 927         else self.colormod = '1 1 1';
 928 };*/
 929
 930 void respawn(void)
 931 {
 932         CopyBody(1);
 933         PutClientInServer();
 934 }
 935
 936 void player_powerups (void)
 937 {
 938         if (g_minstagib)
 939         {
 940                 self.effects = EF_FULLBRIGHT;
 941                 if (self.items & IT_STRENGTH)
 942                 {
 943                         if (time > self.strength_finished)
 944                         {
 945                                 self.alpha = default_player_alpha;
 946                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 947                                 self.items = self.items - (self.items & IT_STRENGTH);
 948                                 sprint(self, "^3Invisibility has worn off\n");
 949                         }
 950                 }
 951                 else
 952                 {
 953                         if (time < self.strength_finished)
 954                         {
 955                                 self.alpha = cvar("g_minstagib_invis_alpha");
 956                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 957                                 self.items = self.items | IT_STRENGTH;
 958                                 sprint(self, "^3You are invisible\n");
 959                         }
 960                 }
 961
 962                 if (self.items & IT_INVINCIBLE)
 963                 {
 964                         if (time > self.invincible_finished)
 965                         {
 966                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 967                                 sprint(self, "^3Speed has worn off\n");
 968                         }
 969                 }
 970                 else
 971                 {
 972                         if (time < self.invincible_finished)
 973                         {
 974                                 self.items = self.items | IT_INVINCIBLE;
 975                                 sprint(self, "^3You are on speed\n");
 976                         }
 977                 }
 978                 return;
 979         }
 980
 981         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 982         if (self.items & IT_STRENGTH)
 983         {
 984                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 985                 if (time > self.strength_finished)
 986                 {
 987                         self.items = self.items - (self.items & IT_STRENGTH);
 988                         sprint(self, "^3Strength has worn off\n");
 989                 }
 990         }
 991         else
 992         {
 993                 if (time < self.strength_finished)
 994                 {
 995                         self.items = self.items | IT_STRENGTH;
 996                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
 997                 }
 998         }
 999         if (self.items & IT_INVINCIBLE)
1000         {
1001                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1002                 if (time > self.invincible_finished)
1003                 {
1004                         self.items = self.items - (self.items & IT_INVINCIBLE);
1005                         sprint(self, "^3Shield has worn off\n");
1006                 }
1007         }
1008         else
1009         {
1010                 if (time < self.invincible_finished)
1011                 {
1012                         self.items = self.items | IT_INVINCIBLE;
1013                         sprint(self, "^3Shield surrounds you\n");
1014                 }
1015         }
1016
1017         if (cvar("g_fullbrightplayers"))
1018                 self.effects = self.effects | EF_FULLBRIGHT;
1019
1020         // midair gamemode: damage only while in the air
1021         // if in midair mode, being on ground grants temporary invulnerability
1022         // (this is so that multishot weapon don't clear the ground flag on the
1023         // first damage in the frame, leaving the player vulnerable to the
1024         // remaining hits in the same frame)
1025         if (self.flags & FL_ONGROUND)
1026         if (g_midair)
1027                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1028
1029         if (time < self.spawnshieldtime)
1030                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1031 }
1032
1033 float CalcRegen(float current, float stable, float regenfactor)
1034 {
1035         if(current > stable)
1036                 return current;
1037         else if(current > stable - 0.25) // when close enough, "snap"
1038                 return stable;
1039         else
1040                 return min(stable, current + (stable - current) * regenfactor * frametime);
1041 }
1042
1043 void player_regen (void)
1044 {
1045         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1046         maxh = cvar("g_balance_health_stable");
1047         maxa = cvar("g_balance_armor_stable");
1048         limith = cvar("g_balance_health_limit");
1049         limita = cvar("g_balance_armor_limit");
1050
1051         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1052                 return;
1053
1054         max_mod = regen_mod = rot_mod = limit_mod = 1;
1055
1056         if (self.runes & RUNE_REGEN)
1057         {
1058                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1059                 {
1060                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1061                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1062                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1063                 }
1064                 else
1065                 {
1066                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1067                         max_mod = cvar("g_balance_rune_regen_hpmod");
1068                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1069                 }
1070         }
1071         else if (self.runes & CURSE_VENOM)
1072         {
1073                 max_mod = cvar("g_balance_curse_venom_hpmod");
1074                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1075                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1076                 else
1077                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1078                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1079                 //if (!self.runes & RUNE_REGEN)
1080                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1081         }
1082         maxh = maxh * max_mod;
1083         //maxa = maxa * max_mod;
1084         limith = limith * limit_mod;
1085         limita = limita * limit_mod;
1086
1087         if (self.armorvalue > maxa)
1088         {
1089                 if (time > self.pauserotarmor_finished)
1090                 {
1091                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1092                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1093                 }
1094         }
1095         else if (self.armorvalue < maxa)
1096         {
1097                 if (time > self.pauseregen_finished)
1098                 {
1099                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1100                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1101                 }
1102         }
1103         if (self.health > maxh)
1104         {
1105                 if (time > self.pauserothealth_finished)
1106                 {
1107                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1108                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1109                 }
1110         }
1111         else if (self.health < maxh)
1112         {
1113                 if (time > self.pauseregen_finished)
1114                 {
1115                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1116                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1117                 }
1118         }
1119
1120         if (self.health > limith)
1121                 self.health = limith;
1122         if (self.armorvalue > limita)
1123                 self.armorvalue = limita;
1124
1125         // if player rotted to death...  die!
1126         if(self.health < 1)
1127                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1128 }
1129
1130 /*
1131 ======================
1132 spectate mode routines
1133 ======================
1134 */
1135 void SpectateCopy(entity spectatee) {
1136         self.armortype = spectatee.armortype;
1137         self.armorvalue = spectatee.armorvalue;
1138         self.currentammo = spectatee.currentammo;
1139         self.effects = spectatee.effects;
1140         self.health = spectatee.health;
1141         self.impulse = 0;
1142         self.items = spectatee.items;
1143         self.punchangle = spectatee.punchangle;
1144         self.view_ofs = spectatee.view_ofs;
1145         self.v_angle = spectatee.v_angle;
1146         self.viewzoom = spectatee.viewzoom;
1147         setorigin(self, spectatee.origin);
1148         setsize(self, spectatee.mins, spectatee.maxs);
1149 }
1150
1151 void SpectateUpdate() {
1152         if(!self.enemy)
1153                         PutObserverInServer();
1154
1155         if (self != self.enemy) {
1156                 if(self.enemy.flags & FL_NOTARGET)
1157                         PutObserverInServer();
1158                 SpectateCopy(self.enemy);
1159                 self.dmg_take = self.enemy.dmg_take;
1160                 self.dmg_save = self.enemy.dmg_save;
1161                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1162                 self.fixangle = TRUE;
1163                 self.angles = self.enemy.v_angle;
1164                 //msg_entity = self;
1165                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1166                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1167                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1168                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1169         }
1170 }
1171
1172 float SpectateNext() {
1173         other = find(self.enemy, classname, "player");
1174         if (!other) {
1175                 other = find(other, classname, "player");
1176         }
1177         if (other) {
1178                 self.enemy = other;
1179         }
1180         if(self.enemy.classname == "player") {
1181                 msg_entity = self;
1182                 WriteByte(MSG_ONE, SVC_SETVIEW);
1183                 WriteEntity(MSG_ONE, self.enemy);
1184                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1185                 SpectateUpdate();
1186                 return 1;
1187         } else {
1188                 return 0;
1189         }
1190 }
1191
1192 /*
1193 =============
1194 ShowRespawnCountdown()
1195
1196 Update a respawn countdown display.
1197 =============
1198 */
1199 void ShowRespawnCountdown()
1200 {
1201         float number;
1202         if(self.deadflag == DEAD_NO) // just respawned?
1203                 return;
1204         else
1205         {
1206                 number = ceil(self.death_time - time);
1207                 if(number <= 0)
1208                         return;
1209                 if(number <= self.respawn_countdown)
1210                 {
1211                         self.respawn_countdown = number - 1;
1212                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1213                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1214                 }
1215         }
1216 }
1217
1218 void LeaveSpectatorMode()
1219 {
1220         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1221                 self.classname = "player";
1222                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1223                         JoinBestTeam(self, 0);
1224                 if(cvar("g_campaign"))
1225                         campaign_bots_may_start = 1;
1226                 PutClientInServer();
1227                 if(!(self.flags & FL_NOTARGET))
1228                         bprint ("^4", self.netname, "^4 is playing now\n");
1229                 centerprint(self,"");
1230                 return;
1231         } else {
1232                 stuffcmd(self,"menu_showteamselect\n");
1233                 return;
1234         }
1235 }
1236
1237 /*
1238 =============
1239 PlayerPreThink
1240
1241 Called every frame for each client before the physics are run
1242 =============
1243 */
1244 void() ctf_setstatus;
1245 .float vote_nagtime;
1246 void PlayerPreThink (void)
1247 {
1248         // version nagging
1249         if(self.version_nagtime)
1250                 if(self.cvar_g_nexuizversion)
1251                         if(time > self.version_nagtime)
1252                         {
1253                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1254                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1255                                         {
1256                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1257                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1258                                         }
1259                                 self.version_nagtime = 0;
1260                         }
1261
1262         // vote nagging
1263         if(self.cvar_scr_centertime)
1264                 if(time > self.vote_nagtime)
1265                 {
1266                         VoteNag();
1267                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1268                 }
1269
1270         // GOD MODE info
1271         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1272         {
1273                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1274                 self.max_armorvalue = 0;
1275         }
1276
1277         if(self.classname == "player") {
1278                 local vector m1, m2;
1279
1280 //              if(self.netname == "Wazat")
1281 //                      bprint(self.classname, "\n");
1282
1283                 CheckRules_Player();
1284
1285                 if(self.button7)
1286                         PrintWelcomeMessage(self);
1287
1288                 if(g_lms || !cvar("sv_spectate"))
1289                 if((time - self.jointime) <= cvar("welcome_message_time"))
1290                         PrintWelcomeMessage(self);
1291
1292                 if (intermission_running)
1293                 {
1294                         IntermissionThink ();   // otherwise a button could be missed between
1295                         return;                                 // the think tics
1296                 }
1297
1298                 if(time > self.teleport_time)
1299                 {
1300                         self.effects = self.effects - (self.effects & EF_NODRAW);
1301                         if(self.weaponentity)
1302                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1303                 }
1304
1305                 Nixnex_GiveCurrentWeapon();
1306
1307                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1308                         UpdateSelectedPlayer();
1309
1310                 if (self.deadflag != DEAD_NO)
1311                 {
1312                         float button_pressed, force_respawn;
1313                         player_anim();
1314                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1315                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1316                         if (self.deadflag == DEAD_DYING)
1317                         {
1318                                 if(force_respawn)
1319                                         self.deadflag = DEAD_RESPAWNING;
1320                                 else if(!button_pressed)
1321                                         self.deadflag = DEAD_DEAD;
1322                         }
1323                         else if (self.deadflag == DEAD_DEAD)
1324                         {
1325                                 if(button_pressed)
1326                                         self.deadflag = DEAD_RESPAWNABLE;
1327                         }
1328                         else if (self.deadflag == DEAD_RESPAWNABLE)
1329                         {
1330                                 if(!button_pressed)
1331                                         self.deadflag = DEAD_RESPAWNING;
1332                         }
1333                         else if (self.deadflag == DEAD_RESPAWNING)
1334                         {
1335                                 if(time > self.death_time)
1336                                         respawn();
1337                         }
1338                         ShowRespawnCountdown();
1339                         return;
1340                 }
1341
1342                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1343                 {
1344                         vector dist;
1345
1346                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1347                         dist = self.oldorigin - self.origin;
1348                         dist_z = 0;
1349                         self.lms_traveled_distance += fabs(vlen(dist));
1350
1351                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1352                         {
1353                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1354                                 self.lms_traveled_distance = 0;
1355                         }
1356
1357                         if(time > self.lms_nextcheck)
1358                         {
1359                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1360                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1361                                 {
1362                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1363                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1364                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1365                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1366                                 }
1367                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1368                                 self.lms_traveled_distance = 0;
1369                         }
1370                 }
1371
1372                 if (self.button5 && !self.hook.state)
1373                 {
1374                         if (!self.crouch)
1375                         {
1376                                 self.crouch = TRUE;
1377                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1378                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1379                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
1380                         }
1381                 }
1382                 else
1383                 {
1384                         if (self.crouch)
1385                         {
1386                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1387                                 if (!trace_startsolid)
1388                                 {
1389                                         self.crouch = FALSE;
1390                                         self.view_ofs = PL_VIEW_OFS;
1391                                         setsize (self, PL_MIN, PL_MAX);
1392                                 }
1393                         }
1394                 }
1395
1396                 if(cvar("sv_defaultcharacter") == 1) {
1397                         local string defaultmodel;
1398                         defaultmodel = cvar_string("sv_defaultplayermodel");
1399
1400                         if (defaultmodel != self.model)
1401                         {
1402                                 m1 = self.mins;
1403                                 m2 = self.maxs;
1404                                 setmodel_lod (self, defaultmodel);
1405                                 setsize (self, m1, m2);
1406                         }
1407
1408                         if (self.skin != cvar("sv_defaultplayerskin"))
1409                                 self.skin = cvar("sv_defaultplayerskin");
1410                 } else {
1411                         if (self.playermodel != self.model)
1412                         {
1413                                 self.playermodel = CheckPlayerModel(self.playermodel);
1414                                 m1 = self.mins;
1415                                 m2 = self.maxs;
1416                                 setmodel_lod (self, self.playermodel);
1417                                 setsize (self, m1, m2);
1418                         }
1419
1420                         if(teams_matter)
1421                         {
1422                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1423                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1424                         }
1425                         else
1426                         {
1427                                 if (self.skin != stof(self.playerskin))
1428                                         self.skin = stof(self.playerskin);
1429                         }
1430                 }
1431                 if(!teams_matter)
1432                         if(strlen(cvar_string("sv_defaultplayercolors")))
1433                                 if(self.clientcolors != cvar("sv_defaultplayercolors"))
1434                                         setcolor(self, cvar("sv_defaultplayercolors"));
1435
1436                 GrapplingHookFrame();
1437
1438                 W_WeaponFrame();
1439
1440                 {
1441                         float zoomfactor, zoomspeed, zoomdir;
1442                         zoomfactor = self.cvar_cl_zoomfactor;
1443                         if(zoomfactor < 1 || zoomfactor > 16)
1444                                 zoomfactor = 2.5;
1445                         zoomspeed = self.cvar_cl_zoomspeed;
1446                         if(zoomspeed >= 0) // < 0 is instant zoom
1447                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1448                                         zoomspeed = 3.5;
1449
1450                         zoomdir = self.button4;
1451                         if(self.button3)
1452                                 if(self.weapon == WEP_NEX)
1453                                         if(!g_minstagib)
1454                                                 zoomdir = 1;
1455
1456                         if(zoomdir)
1457                                 self.has_zoomed = 1;
1458
1459                         if(self.has_zoomed)
1460                         {
1461                                 if(zoomspeed <= 0) // instant zoom
1462                                 {
1463                                         if(zoomdir)
1464                                                 self.viewzoom = 1 / zoomfactor;
1465                                         else
1466                                                 self.viewzoom = 1;
1467                                 }
1468                                 else
1469                                 {
1470                                         // geometric zoom would be:
1471                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1472                                         // however, testing showed that arithmetic/harmonic zoom works better
1473                                         if(zoomdir)
1474                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1475                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1476                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1477                                         else
1478                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1479                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1480                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1481                                 }
1482                         }
1483                         else
1484                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1485                 }
1486
1487                 player_powerups();
1488                 player_regen();
1489                 player_anim();
1490
1491                 if (g_minstagib)
1492                         minstagib_ammocheck();
1493
1494                 ctf_setstatus();
1495                 kh_setstatus();
1496
1497                 //self.angles_y=self.v_angle_y + 90;   // temp
1498
1499                 //if (TetrisPreFrame()) return;
1500         } else if(gameover) {
1501                 if (intermission_running)
1502                         IntermissionThink ();   // otherwise a button could be missed between
1503                 return;
1504         } else if(self.classname == "observer") {
1505
1506                 if (self.flags & FL_JUMPRELEASED) {
1507                         if (self.button2 && self.version == cvar("gameversion")) {
1508                                 self.welcomemessage_time = 0;
1509                                 self.flags = self.flags - FL_JUMPRELEASED;
1510                                 LeaveSpectatorMode();
1511                                 return;
1512                         } else if(self.button0 && self.version == cvar("gameversion")) {
1513                                 self.welcomemessage_time = 0;
1514                                 self.flags = self.flags - FL_JUMPRELEASED;
1515                                 if(SpectateNext() == 1) {
1516                                         self.classname = "spectator";
1517                                 }
1518                         }
1519                 } else {
1520                         if (!(self.button0 || self.button2)) {
1521                                 self.flags = self.flags | FL_JUMPRELEASED;
1522                         }
1523                 }
1524                 PrintWelcomeMessage(self);
1525         } else if(self.classname == "spectator") {
1526                 if (self.flags & FL_JUMPRELEASED) {
1527                         if (self.button2 && self.version == cvar("gameversion")) {
1528                                 self.welcomemessage_time = 0;
1529                                 self.flags = self.flags - FL_JUMPRELEASED;
1530                                 LeaveSpectatorMode();
1531                                 return;
1532                         } else if(self.button0) {
1533                                 self.welcomemessage_time = 0;
1534                                 self.flags = self.flags - FL_JUMPRELEASED;
1535                                 if(SpectateNext() == 1) {
1536                                         self.classname = "spectator";
1537                                 } else {
1538                                         self.classname = "observer";
1539                                         PutClientInServer();
1540                                 }
1541                         } else if (self.button3) {
1542                                 self.welcomemessage_time = 0;
1543                                 self.flags = self.flags - FL_JUMPRELEASED;
1544                                 self.classname = "observer";
1545                                 PutClientInServer();
1546                         } else {
1547                                 SpectateUpdate();
1548                         }
1549                 } else {
1550                         if (!(self.button0 || self.button3)) {
1551                                 self.flags = self.flags | FL_JUMPRELEASED;
1552                         }
1553                 }
1554                 PrintWelcomeMessage(self);
1555                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1556         }
1557 }
1558
1559
1560 /*
1561 =============
1562 PlayerPostThink
1563
1564 Called every frame for each client after the physics are run
1565 =============
1566 */
1567 void PlayerPostThink (void)
1568 {
1569         // Savage: Check for nameless players
1570         if (strlen(self.netname) < 1) {
1571                 self.netname = "Player";
1572                 stuffcmd(self, "seta _cl_name Player\n");
1573         }
1574
1575         if(self.classname == "player") {
1576                 CheckRules_Player();
1577                 UpdateChatBubble();
1578                 UpdateTeamBubble();
1579                 if (self.impulse)
1580                         ImpulseCommands();
1581                 if (intermission_running)
1582                         return;         // intermission or finale
1583
1584                 //PrintWelcomeMessage(self);
1585                 //if (TetrisPostFrame()) return;
1586
1587                 // restart countdown
1588                 if(time < restart_countdown)
1589                 {
1590                         string s;
1591                         float sec;
1592
1593                         sec = ceil(restart_countdown-time);
1594                         s = strcat(NEWLINES, "^1Game starts in ", ftos(sec), " seconds");
1595                         centerprint(self, s);
1596                         self.movetype = MOVETYPE_NONE;
1597                         self.velocity = '0 0 0';
1598                         self.avelocity = '0 0 0';
1599                         self.movement = '0 0 0';
1600                 }
1601                 else if(self.movetype == MOVETYPE_NONE)
1602                 {
1603                         self.movetype = MOVETYPE_WALK;
1604                         centerprint(self, "\n");
1605                 }
1606         } else if (self.classname == "observer") {
1607                 //do nothing
1608         } else if (self.classname == "spectator") {
1609                 //do nothing
1610         }
1611
1612         Arena_Warmup();
1613 }