data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         DistributeFragsAmongTeam(self, self.team, 1);
 294
 295         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 297         else if(self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 299
 300         self.classname = "observer";
 301         self.health = -666;
 302         self.takedamage = DAMAGE_NO;
 303         self.solid = SOLID_NOT;
 304         self.movetype = MOVETYPE_NOCLIP;
 305         self.flags = FL_CLIENT | FL_NOTARGET;
 306         self.armorvalue = 666;
 307         self.effects = 0;
 308         self.armorvalue = cvar("g_balance_armor_start");
 309         self.pauserotarmor_finished = 0;
 310         self.pauserothealth_finished = 0;
 311         self.pauseregen_finished = 0;
 312         self.damageforcescale = 0;
 313         self.death_time = 0;
 314         self.dead_time = 0;
 315         self.dead_frame = 0;
 316         self.die_frame = 0;
 317         self.deaths = 0;
 318         self.alpha = 0;
 319         self.scale = 0;
 320         self.fade_time = 0;
 321         self.pain_frame = 0;
 322         self.pain_finished = 0;
 323         self.strength_finished = 0;
 324         self.invincible_finished = 0;
 325         self.pushltime = 0;
 326         self.think = SUB_Null;
 327         self.nextthink = 0;
 328         self.hook_time = 0;
 329         self.runes = 0;
 330         self.deadflag = DEAD_NO;
 331         self.angles = spot.angles;
 332         self.angles_z = 0;
 333         self.fixangle = TRUE;
 334         self.crouch = FALSE;
 335
 336         self.view_ofs = PL_VIEW_OFS;
 337         setorigin (self, spot.origin);
 338         setsize (self, '0 0 0', '0 0 0');
 339         self.oldorigin = self.origin;
 340         self.items = 0;
 341         self.model = "";
 342         self.modelindex = 0;
 343         self.weapon = 0;
 344         self.weaponmodel = "";
 345         self.weaponentity = world;
 346         self.killcount = -666;
 347         self.velocity = '0 0 0';
 348         self.avelocity = '0 0 0';
 349         self.punchangle = '0 0 0';
 350         self.punchvector = '0 0 0';
 351         self.oldvelocity = self.velocity;
 352         self.customizeentityforclient = Client_customizeentityforclient;
 353
 354         if(cvar("g_arena"))
 355         {
 356                 if(self.frags != -2)
 357                 {
 358                         Spawnqueue_Insert(self);
 359                 }
 360                 else
 361                 {
 362                         Spawnqueue_Unmark(self);
 363                         Spawnqueue_Remove(self);
 364                 }
 365         }
 366         else if(!cvar("g_lms"))
 367                 self.frags = -666;
 368 }
 369
 370
 371 /*
 372 =============
 373 PutClientInServer
 374
 375 Called when a client spawns in the server
 376 =============
 377 */
 378 void PutClientInServer (void)
 379 {
 380         if(clienttype(self) == CLIENTTYPE_BOT)
 381         {
 382                 self.classname = "player";
 383         }
 384         else if(clienttype(self) == CLIENTTYPE_REAL)
 385         {
 386                 msg_entity = self;
 387                 WriteByte(MSG_ONE, SVC_SETVIEW);
 388                 WriteEntity(MSG_ONE, self);
 389         }
 390
 391         // player is dead and becomes observer
 392         if(cvar("g_lms") && self.frags < 1)
 393                 self.classname = "observer";
 394
 395         if(cvar("g_arena"))
 396         if(!self.spawned)
 397                 self.classname = "observer";
 398
 399         if(self.classname == "player") {
 400                 entity  spot;
 401
 402                 spot = SelectSpawnPoint (FALSE);
 403
 404                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 405
 406                 self.classname = "player";
 407                 self.iscreature = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.flags = FL_CLIENT;
 411                 self.takedamage = DAMAGE_AIM;
 412                 self.effects = 0;
 413                 self.health = cvar("g_balance_health_start");
 414                 self.armorvalue = cvar("g_balance_armor_start");
 415                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 416                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 417                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 418                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 419                 self.damageforcescale = 2;
 420                 self.death_time = 0;
 421                 self.dead_time = 0;
 422                 self.dead_frame = 0;
 423                 self.die_frame = 0;
 424                 self.alpha = 0;
 425                 self.scale = 0;
 426                 self.fade_time = 0;
 427                 self.pain_frame = 0;
 428                 self.pain_finished = 0;
 429                 self.strength_finished = 0;
 430                 self.invincible_finished = 0;
 431                 self.pushltime = 0;
 432                 //self.speed_finished = 0;
 433                 //self.slowmo_finished = 0;
 434                 // players have no think function
 435                 self.think = SUB_Null;
 436                 self.nextthink = 0;
 437                 self.weapon = 0;
 438                 self.switchweapon = 0;
 439                 self.hook_time = 0;
 440
 441                 self.runes = 0;
 442
 443                 self.deadflag = DEAD_NO;
 444
 445                 self.angles = spot.angles;
 446
 447                 self.angles_z = 0; // never spawn tilted even if the spot says to
 448                 self.fixangle = TRUE; // turn this way immediately
 449                 self.velocity = '0 0 0';
 450                 self.avelocity = '0 0 0';
 451                 self.punchangle = '0 0 0';
 452                 self.punchvector = '0 0 0';
 453                 self.oldvelocity = self.velocity;
 454
 455                 self.viewzoom = 0.6;
 456
 457                 self.customizeentityforclient = Client_customizeentityforclient;
 458
 459                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 460                         local string defaultmodel;
 461                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 462                         setmodel_lod (self, defaultmodel);
 463                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 464                 } else {
 465                         self.playermodel = CheckPlayerModel(self.playermodel);
 466                         setmodel_lod (self, self.playermodel);
 467                         if(teams_matter)
 468                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 469                         else
 470                                 self.skin = stof(self.playerskin);
 471                 }
 472
 473                 self.crouch = FALSE;
 474                 self.view_ofs = PL_VIEW_OFS;
 475                 setsize (self, PL_MIN, PL_MAX);
 476                 self.spawnorigin = spot.origin;
 477                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 478                 // don't reset back to last position, even if new position is stuck in solid
 479                 self.oldorigin = self.origin;
 480
 481                 if(cvar("g_lms"))
 482                 {
 483                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 484                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 485                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 486                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 487                         self.health = cvar("g_lms_start_health");
 488                         self.armorvalue = cvar("g_lms_start_armor");
 489                 }
 490                 else if (cvar("g_use_ammunition")) {
 491                         self.ammo_shells = cvar("g_start_ammo_shells");
 492                         self.ammo_nails = cvar("g_start_ammo_nails");
 493                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 494                         self.ammo_cells = cvar("g_start_ammo_cells");
 495                 } else {
 496                         self.ammo_shells = 999;
 497                         self.ammo_nails = 999;
 498                         self.ammo_rockets = 999;
 499                         self.ammo_cells = 999;
 500                 }
 501
 502                 self.items = 0;
 503                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 504                 {
 505                         self.items = self.items | IT_LASER;
 506                         self.switchweapon = WEP_LASER;
 507                 }
 508                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 509                 {
 510                         self.items = self.items | IT_SHOTGUN;
 511                         self.switchweapon = WEP_SHOTGUN;
 512                 }
 513                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 514                 {
 515                         self.items = self.items | IT_UZI;
 516                         self.switchweapon = WEP_UZI;
 517                 }
 518                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 519                 {
 520                         self.items = self.items | IT_GRENADE_LAUNCHER;
 521                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 522                 }
 523                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 524                 {
 525                         self.items = self.items | IT_ELECTRO;
 526                         self.switchweapon = WEP_ELECTRO;
 527                 }
 528                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 529                 {
 530                         self.items = self.items | IT_CRYLINK;
 531                         self.switchweapon = WEP_CRYLINK;
 532                 }
 533                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 534                 {
 535                         self.items = self.items | IT_NEX;
 536                         self.switchweapon = WEP_NEX;
 537                 }
 538                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 539                 {
 540                         self.items = self.items | IT_HAGAR;
 541                         self.switchweapon = WEP_HAGAR;
 542                 }
 543                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 544                 {
 545                         self.items = self.items | IT_ROCKET_LAUNCHER;
 546                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 547                 }
 548
 549                 if(cvar("g_instagib"))
 550                 {
 551                         self.items = IT_NEX;
 552                         self.switchweapon = WEP_NEX;
 553                         self.ammo_cells = 999;
 554                 }
 555
 556                 if(cvar("g_rocketarena"))
 557                 {
 558                         self.items = IT_ROCKET_LAUNCHER;
 559                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 560                         self.ammo_rockets = 999;
 561                 }
 562
 563                 if(cvar("g_nixnex"))
 564                 {
 565                         self.items = 0;
 566                         // will be done later
 567                 }
 568
 569                 if(cvar("g_minstagib"))
 570                 {
 571                         self.health = 100;
 572                         self.armorvalue = 0;
 573                         self.items = IT_NEX;
 574                         self.switchweapon = WEP_NEX;
 575                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 576                         self.jump_interval = time;
 577                 }
 578
 579                 if(cvar("g_arena"))
 580                 {
 581                         Spawnqueue_Remove(self);
 582                         Spawnqueue_Mark(self);
 583                 }
 584
 585                 self.event_damage = PlayerDamage;
 586
 587                 self.bot_attack = TRUE;
 588
 589                 self.statdraintime = time + 5;
 590                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 591
 592                 if(self.killcount == -666) {
 593                         self.killcount = 0;
 594                         if(!cvar("g_arena"))
 595                         if(!cvar("g_lms"))
 596                                 self.frags = 0;
 597                 }
 598
 599                 self.cnt = WEP_LASER;
 600                 self.nixnex_lastchange_id = -1;
 601
 602                 CL_SpawnWeaponentity();
 603                 self.alpha = default_player_alpha;
 604                 self.exteriorweaponentity.alpha = default_player_alpha;
 605
 606                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 607                 self.lms_traveled_distance = 0;
 608
 609                 if(cvar("spawn_debug"))
 610                 {
 611                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 612                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 613                 }
 614
 615                 //stuffcmd(self, "chase_active 0");
 616                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 617         } else if(self.classname == "observer") {
 618                 PutObserverInServer ();
 619         }
 620 }
 621
 622 /*
 623 =============
 624 SetNewParms
 625 =============
 626 */
 627 void SetNewParms (void)
 628 {
 629
 630 }
 631
 632 /*
 633 =============
 634 SetChangeParms
 635 =============
 636 */
 637 void SetChangeParms (void)
 638 {
 639
 640 }
 641
 642 /*
 643 =============
 644 ClientKill
 645
 646 Called when a client types 'kill' in the console
 647 =============
 648 */
 649 void ClientKill (void)
 650 {
 651         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 652 }
 653
 654 /*
 655 =============
 656 ClientConnect
 657
 658 Called when a client connects to the server
 659 =============
 660 */
 661 string ColoredTeamName(float t);
 662 //void dom_player_join_team(entity pl);
 663 void ClientConnect (void)
 664 {
 665         local string s;
 666
 667         self.classname = "player_joining";
 668         self.flags = self.flags | FL_CLIENT;
 669         self.version_nagtime = time + 10 + random() * 10;
 670
 671         if(player_count<0)
 672         {
 673                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 674                 player_count = 0;
 675         }
 676
 677         bot_clientconnect();
 678
 679         //if(cvar("g_domination"))
 680         //      dom_player_join_team(self);
 681
 682         //JoinBestTeam(self, FALSE);
 683
 684         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 685                 self.classname = "observer";
 686         } else {
 687                 self.classname = "player";
 688                 campaign_bots_may_start = 1;
 689         }
 690
 691         self.playerid = (playerid_last = playerid_last + 1);
 692         if(cvar("sv_eventlog"))
 693         {
 694                 if(clienttype(self) == CLIENTTYPE_REAL)
 695                         s = "player";
 696                 else
 697                         s = "bot";
 698                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 699                 s = strcat(":team:", ftos(self.playerid), ":");
 700                 s = strcat(s, ftos(self.team));
 701                 GameLogEcho(s, FALSE);
 702         }
 703
 704         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 705
 706         bprint ("^4",self.netname);
 707         bprint ("^4 connected");
 708
 709         if(cvar("g_domination") || cvar("g_ctf"))
 710         {
 711                 bprint(" and joined the ");
 712                 bprint(ColoredTeamName(self.team));
 713         }
 714
 715         bprint("\n");
 716
 717         self.welcomemessage_time = time + cvar("welcome_message_time");
 718         self.welcomemessage_time2 = 0;
 719
 720         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 721         // TODO: is this being used for anything else than cd tracks?
 722         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 723
 724         // send prediction settings to the client
 725         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 726         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 727         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 728         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 729         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 730         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 731         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 732         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 733         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 734         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 735         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 736         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 737         // Wazat's grappling hook
 738         SetGrappleHookBindings();
 739
 740         // get autoswitch state from player
 741         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 742         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 743
 744         // get version info from player
 745         stuffcmd(self, "cmd clientversion $gameversion\n");
 746
 747         // get other cvars from player
 748         GetCvars(0);
 749
 750         // set cvar for team scoreboard
 751         if (teams_matter)
 752         {
 753                 local float t;
 754                 t = cvar("teamplay");
 755                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 756                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 757         }
 758         else
 759                 stuffcmd(self, strcat("set teamplay 0\n"));
 760
 761         if(cvar("g_lms"))
 762         {
 763                 self.frags = cvar("fraglimit");
 764                 // no fraglimit was set, so player gets 999 lives
 765                 if(self.frags < 1)
 766                         self.frags = 999;
 767
 768                 self.frags = LMS_NewPlayerLives();
 769                 if(!self.frags)
 770                 {
 771                         self.frags = -666;
 772                 }
 773         }
 774         else if(cvar("g_arena"))
 775         {
 776                 self.classname = "observer";
 777                 Spawnqueue_Insert(self);
 778         }
 779
 780         bot_relinkplayerlist();
 781
 782         self.jointime = time;
 783 }
 784
 785 /*
 786 =============
 787 ClientDisconnect
 788
 789 Called when a client disconnects from the server
 790 =============
 791 */
 792 void(entity e) DropFlag;
 793 .entity chatbubbleentity;
 794 .entity teambubbleentity;
 795 void ClientDisconnect (void)
 796 {
 797         float save;
 798         if(cvar("sv_eventlog"))
 799                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 800         bprint ("^4",self.netname);
 801         bprint ("^4 disconnected\n");
 802
 803         if (self.chatbubbleentity)
 804         {
 805                 remove (self.chatbubbleentity);
 806                 self.chatbubbleentity = world;
 807         }
 808
 809         if (self.teambubbleentity)
 810         {
 811                 remove (self.teambubbleentity);
 812                 self.teambubbleentity = world;
 813         }
 814
 815         DropAllRunes(self);
 816
 817         if(self.flagcarried)
 818                 DropFlag(self.flagcarried);
 819
 820         DistributeFragsAmongTeam(self, self.team, 1);
 821
 822         save = self.flags;
 823         self.flags = self.flags - (self.flags & FL_CLIENT);
 824         bot_relinkplayerlist();
 825         self.flags = save;
 826
 827         // remove laserdot
 828         if(self.weaponentity)
 829                 if(self.weaponentity.lasertarget)
 830                         remove(self.weaponentity.lasertarget);
 831
 832         if(cvar("g_arena"))
 833         {
 834                 Spawnqueue_Unmark(self);
 835                 Spawnqueue_Remove(self);
 836         }
 837
 838         // free cvars
 839         GetCvars(-1);
 840 }
 841
 842 .float buttonchat;
 843 void() ChatBubbleThink =
 844 {
 845         self.nextthink = time;
 846         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 847         {
 848                 self.owner.chatbubbleentity = world;
 849                 remove(self);
 850                 return;
 851         }
 852         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 853         if (self.owner.buttonchat && !self.owner.deadflag)
 854                 self.model = self.mdl;
 855         else
 856                 self.model = "";
 857 };
 858
 859 void() UpdateChatBubble =
 860 {
 861         if (!self.modelindex)
 862                 return;
 863         // spawn a chatbubble entity if needed
 864         if (!self.chatbubbleentity)
 865         {
 866                 self.chatbubbleentity = spawn();
 867                 self.chatbubbleentity.owner = self;
 868                 self.chatbubbleentity.exteriormodeltoclient = self;
 869                 self.chatbubbleentity.think = ChatBubbleThink;
 870                 self.chatbubbleentity.nextthink = time;
 871                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 872                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 873                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 874                 self.chatbubbleentity.model = "";
 875         }
 876 }
 877
 878
 879 void() TeamBubbleThink =
 880 {
 881         self.nextthink = time;
 882         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 883         {
 884                 self.owner.teambubbleentity = world;
 885                 remove(self);
 886                 return;
 887         }
 888 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 889         if (self.owner.buttonchat || self.owner.deadflag)
 890                 self.model = "";
 891         else
 892                 self.model = self.mdl;
 893
 894 };
 895
 896 float() TeamBubble_customizeentityforclient
 897 {
 898         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 899 }
 900
 901 void() UpdateTeamBubble =
 902 {
 903         if (!self.modelindex || !cvar("teamplay"))
 904                 return;
 905         // spawn a teambubble entity if needed
 906         if (!self.teambubbleentity && cvar("teamplay"))
 907         {
 908                 self.teambubbleentity = spawn();
 909                 self.teambubbleentity.owner = self;
 910                 self.teambubbleentity.exteriormodeltoclient = self;
 911                 self.teambubbleentity.think = TeamBubbleThink;
 912                 self.teambubbleentity.nextthink = time;
 913                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 914 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 915                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 916                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 917                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 918                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 919                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 920         }
 921 }
 922
 923 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 924 // added to the model skins
 925 /*void() UpdateColorModHack =
 926 {
 927         local float c;
 928         c = self.clientcolors & 15;
 929         // LordHavoc: only bothering to support white, green, red, yellow, blue
 930              if (teamplay == 0) self.colormod = '0 0 0';
 931         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 932         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 933         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 934         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 935         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 936         else self.colormod = '1 1 1';
 937 };*/
 938
 939 /*
 940 =============
 941 PlayerJump
 942
 943 When you press the jump key
 944 =============
 945 */
 946 void PlayerJump (void)
 947 {
 948         float mjumpheight;
 949
 950         mjumpheight = cvar("g_balance_jumpheight");
 951         if (self.waterlevel >= 2)
 952         {
 953                 if (self.watertype == CONTENT_WATER)
 954                         self.velocity_z = 200;
 955                 else if (self.watertype == CONTENT_SLIME)
 956                         self.velocity_z = 80;
 957                 else
 958                         self.velocity_z = 50;
 959
 960                 return;
 961         }
 962
 963
 964         if (!(self.flags & FL_ONGROUND))
 965                 return;
 966
 967         if (!(self.flags & FL_JUMPRELEASED))
 968                 return;
 969
 970         if(cvar("g_runematch"))
 971         {
 972                 if(self.runes & RUNE_SPEED)
 973                 {
 974                         if(self.runes & CURSE_SLOW)
 975                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 976                         else
 977                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 978                 }
 979                 else if(self.runes & CURSE_SLOW)
 980                 {
 981                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 982                 }
 983         }
 984
 985         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 986         {
 987                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 988         }
 989
 990         self.velocity_z = self.velocity_z + mjumpheight;
 991         self.oldvelocity_z = self.velocity_z;
 992
 993         self.flags = self.flags - FL_ONGROUND;
 994         self.flags = self.flags - FL_JUMPRELEASED;
 995 }
 996
 997 void() CheckWaterJump =
 998 {
 999         local vector start, end;
1000
1001 // check for a jump-out-of-water
1002         makevectors (self.angles);
1003         start = self.origin;
1004         start_z = start_z + 8;
1005         v_forward_z = 0;
1006         normalize(v_forward);
1007         end = start + v_forward*24;
1008         traceline (start, end, TRUE, self);
1009         if (trace_fraction < 1)
1010         {       // solid at waist
1011                 start_z = start_z + self.maxs_z - 8;
1012                 end = start + v_forward*24;
1013                 self.movedir = trace_plane_normal * -50;
1014                 traceline (start, end, TRUE, self);
1015                 if (trace_fraction == 1)
1016                 {       // open at eye level
1017                         self.flags = self.flags | FL_WATERJUMP;
1018                         self.velocity_z = 225;
1019                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1020                         self.teleport_time = time + 2;  // safety net
1021                         return;
1022                 }
1023         }
1024 };
1025
1026
1027 void respawn(void)
1028 {
1029         CopyBody(1);
1030         PutClientInServer();
1031 }
1032
1033 void player_powerups (void)
1034 {
1035         if (cvar("g_minstagib"))
1036         {
1037                 self.effects = EF_FULLBRIGHT;
1038                 if (self.items & IT_STRENGTH)
1039                 {
1040                         if (time > self.strength_finished)
1041                         {
1042                                 self.alpha = default_player_alpha;
1043                                 self.exteriorweaponentity.alpha = default_player_alpha;
1044                                 self.items = self.items - (self.items & IT_STRENGTH);
1045                                 sprint(self, "^3Invisibility has worn off\n");
1046                         }
1047                 }
1048                 else
1049                 {
1050                         if (time < self.strength_finished)
1051                         {
1052                                 self.alpha = cvar("g_minstagib_invis_alpha");
1053                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1054                                 self.items = self.items | IT_STRENGTH;
1055                                 sprint(self, "^3You are invisible\n");
1056                         }
1057                 }
1058
1059                 if (self.items & IT_INVINCIBLE)
1060                 {
1061                         if (time > self.invincible_finished)
1062                         {
1063                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1064                                 sprint(self, "^3Speed has worn off\n");
1065                         }
1066                 }
1067                 else
1068                 {
1069                         if (time < self.invincible_finished)
1070                         {
1071                                 self.items = self.items | IT_INVINCIBLE;
1072                                 sprint(self, "^3You are on speed\n");
1073                         }
1074                 }
1075                 return;
1076         }
1077
1078         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1079         if (self.items & IT_STRENGTH)
1080         {
1081                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1082                 if (time > self.strength_finished)
1083                 {
1084                         self.items = self.items - (self.items & IT_STRENGTH);
1085                         sprint(self, "^3Strength has worn off\n");
1086                 }
1087         }
1088         else
1089         {
1090                 if (time < self.strength_finished)
1091                 {
1092                         self.items = self.items | IT_STRENGTH;
1093                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1094                 }
1095         }
1096         if (self.items & IT_INVINCIBLE)
1097         {
1098                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1099                 if (time > self.invincible_finished)
1100                 {
1101                         self.items = self.items - (self.items & IT_INVINCIBLE);
1102                         sprint(self, "^3Shield has worn off\n");
1103                 }
1104         }
1105         else
1106         {
1107                 if (time < self.invincible_finished)
1108                 {
1109                         self.items = self.items | IT_INVINCIBLE;
1110                         sprint(self, "^3Shield surrounds you\n");
1111                 }
1112         }
1113
1114         if (cvar("g_fullbrightplayers"))
1115                 self.effects = self.effects | EF_FULLBRIGHT;
1116
1117         // midair gamemode: damage only while in the air
1118         // if in midair mode, being on ground grants temporary invulnerability
1119         // (this is so that multishot weapon don't clear the ground flag on the
1120         // first damage in the frame, leaving the player vulnerable to the
1121         // remaining hits in the same frame)
1122         if (self.flags & FL_ONGROUND)
1123         if (cvar("g_midair"))
1124                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1125
1126         if (time < self.spawnshieldtime)
1127                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1128 }
1129
1130 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1131 {
1132         if(current > stable)
1133                 return current;
1134         else if(current > stable - 0.25) // when close enough, "snap"
1135                 return stable;
1136         else
1137                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1138 }
1139
1140 void player_regen (void)
1141 {
1142         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1143         maxh = cvar("g_balance_health_stable");
1144         maxa = cvar("g_balance_armor_stable");
1145         limith = cvar("g_balance_health_limit");
1146         limita = cvar("g_balance_armor_limit");
1147
1148         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1149                 return;
1150
1151         if(cvar("g_runematch"))
1152         {
1153                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1154                 if (self.runes & RUNE_REGEN)
1155                 {
1156                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1157                         {
1158                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1159                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1160                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1161                         }
1162                         else
1163                         {
1164                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1165                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1166                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1167                         }
1168                 }
1169                 else if (self.runes & CURSE_VENOM)
1170                 {
1171                         max_mod = cvar("g_balance_curse_venom_hpmod");
1172                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1173                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1174                         else
1175                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1176                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1177                         //if (!self.runes & RUNE_REGEN)
1178                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1179                 }
1180                 maxh = maxh * max_mod;
1181                 //maxa = maxa * max_mod;
1182
1183                 if (time > self.pauserotarmor_finished)
1184                 {
1185                         if (self.armorvalue > maxa)
1186                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1187                 }
1188                 if (time > self.pauserothealth_finished)
1189                 {
1190                         if (self.health > maxh)
1191                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1192                 }
1193                 if (time > self.pauseregen_finished)
1194                 {
1195                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1196                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1197                 }
1198         }
1199         else
1200         {
1201                 if (time > self.pauserothealth_finished)
1202                 if (self.health > maxh)
1203                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1204                 if (time > self.pauserotarmor_finished)
1205                 if (self.armorvalue > maxa)
1206                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1207                 if (time > self.pauseregen_finished)
1208                 {
1209                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1210                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1211                 }
1212         }
1213
1214         if (self.health > limith)
1215                 self.health = limith;
1216         if(self.health < 1)
1217                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1218         if (self.armorvalue > limita)
1219                 self.armorvalue = limita;
1220 }
1221
1222 /*
1223 ======================
1224 spectate mode routines
1225 ======================
1226 */
1227 void SpectateCopy(entity spectatee) {
1228         self.armortype = spectatee.armortype;
1229         self.armorvalue = spectatee.armorvalue;
1230         self.currentammo = spectatee.currentammo;
1231         self.effects = spectatee.effects;
1232         self.health = spectatee.health;
1233         self.impulse = 0;
1234         self.items = spectatee.items;
1235         self.punchangle = spectatee.punchangle;
1236         self.view_ofs = spectatee.view_ofs;
1237         self.v_angle = spectatee.v_angle;
1238         self.viewzoom = spectatee.viewzoom;
1239         setorigin(self, spectatee.origin);
1240         setsize(self, spectatee.mins, spectatee.maxs);
1241 }
1242
1243 void SpectateUpdate() {
1244         if(!self.enemy)
1245                         PutObserverInServer();
1246
1247         if (self != self.enemy) {
1248                 if(self.enemy.flags & FL_NOTARGET)
1249                         PutObserverInServer();
1250                 SpectateCopy(self.enemy);
1251                 self.dmg_take = self.enemy.dmg_take;
1252                 self.dmg_save = self.enemy.dmg_save;
1253                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1254                 self.fixangle = TRUE;
1255                 self.angles = self.enemy.v_angle;
1256                 //msg_entity = self;
1257                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1258                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1259                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1260                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1261         }
1262 }
1263
1264 float SpectateNext() {
1265         other = find(self.enemy, classname, "player");
1266         if (!other) {
1267                 other = find(other, classname, "player");
1268         }
1269         if (other) {
1270                 self.enemy = other;
1271         }
1272         if(self.enemy.classname == "player") {
1273                 msg_entity = self;
1274                 WriteByte(MSG_ONE, SVC_SETVIEW);
1275                 WriteEntity(MSG_ONE, self.enemy);
1276                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1277                 SpectateUpdate();
1278                 return 1;
1279         } else {
1280                 return 0;
1281         }
1282 }
1283
1284 /*
1285 =============
1286 PlayerPreThink
1287
1288 Called every frame for each client before the physics are run
1289 =============
1290 */
1291 void() ctf_setstatus;
1292 void PlayerPreThink (void)
1293 {
1294         // version nagging
1295         if(self.version_nagtime)
1296                 if(self.cvar_g_nexuizversion)
1297                         if(time > self.version_nagtime)
1298                         {
1299                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1300                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1301                                         {
1302                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1303                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1304                                         }
1305                                 self.version_nagtime = 0;
1306                         }
1307
1308         if(self.classname == "player") {
1309                 local vector m1, m2;
1310
1311 //              if(self.netname == "Wazat")
1312 //                      bprint(strcat(self.classname, "\n"));
1313
1314                 CheckRules_Player();
1315
1316                 Nixnex_GiveCurrentWeapon();
1317
1318                 if(self.button7)
1319                         PrintWelcomeMessage(self);
1320
1321                 if(cvar("g_lms") || !cvar("sv_spectate"))
1322                 if((time - self.jointime) <= cvar("welcome_message_time"))
1323                         PrintWelcomeMessage(self);
1324
1325                 if (intermission_running)
1326                 {
1327                         IntermissionThink ();   // otherwise a button could be missed between
1328                         return;                                 // the think tics
1329                 }
1330
1331                 if (self.deadflag != DEAD_NO)
1332                 {
1333                         player_anim();
1334                         if (self.deadflag == DEAD_DYING)
1335                         {
1336                                 if (time > self.dead_time)
1337                                         self.deadflag = DEAD_DEAD;
1338                         }
1339                         else if (self.deadflag == DEAD_DEAD)
1340                         {
1341                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1342                                         self.deadflag = DEAD_RESPAWNABLE;
1343                                 else if (!self.button0 && !self.button2 && !self.button3)
1344                                         self.deadflag = DEAD_RESPAWNABLE;
1345                         }
1346                         else if (self.deadflag == DEAD_RESPAWNABLE)
1347                         {
1348                                 if (self.button0  ||
1349                                     self.button2  ||
1350                                     self.button3  ||
1351                                     self.button4  ||
1352                                     self.button5  ||
1353                                     self.button6  ||
1354                                     self.button7  ||
1355                                     self.button8  ||
1356                                     self.buttonuse ||
1357                                     cvar("g_lms") ||
1358                                     cvar("g_forced_respawn"))
1359                                         respawn();
1360                         }
1361                         return;
1362                 }
1363
1364                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1365                 {
1366                         vector dist;
1367
1368                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1369                         dist = self.oldorigin - self.origin;
1370                         dist_z = 0;
1371                         self.lms_traveled_distance += fabs(vlen(dist));
1372
1373                         if(cvar("g_campaign"))
1374                         if(!campaign_bots_may_start)
1375                         {
1376                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1377                                 self.lms_traveled_distance = 0;
1378                         }
1379
1380                         if(time > self.lms_nextcheck)
1381                         {
1382                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1383                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1384                                 {
1385                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1386                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1387                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1388                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1389                                 }
1390                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1391                                 self.lms_traveled_distance = 0;
1392                         }
1393                 }
1394
1395                 if (self.button5 && !self.hook.state)
1396                 {
1397                         if (!self.crouch)
1398                         {
1399                                 self.crouch = TRUE;
1400                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1401                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1402                         }
1403                 }
1404                 else
1405                 {
1406                         if (self.crouch)
1407                         {
1408                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1409                                 if (!trace_startsolid)
1410                                 {
1411                                         self.crouch = FALSE;
1412                                         self.view_ofs = PL_VIEW_OFS;
1413                                         setsize (self, PL_MIN, PL_MAX);
1414                                 }
1415                         }
1416                 }
1417
1418                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1419                         local string defaultmodel;
1420                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1421
1422                         if (defaultmodel != self.model)
1423                         {
1424                                 m1 = self.mins;
1425                                 m2 = self.maxs;
1426                                 setmodel_lod (self, defaultmodel);
1427                                 setsize (self, m1, m2);
1428                         }
1429
1430                         if (self.skin != cvar("sv_defaultplayerskin"))
1431                                 self.skin = cvar("sv_defaultplayerskin");
1432                 } else {
1433                         if (self.playermodel != self.model)
1434                         {
1435                                 self.playermodel = CheckPlayerModel(self.playermodel);
1436                                 m1 = self.mins;
1437                                 m2 = self.maxs;
1438                                 setmodel_lod (self, self.playermodel);
1439                                 setsize (self, m1, m2);
1440                         }
1441
1442                         if(teams_matter)
1443                         {
1444                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1445                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1446                         }
1447                         else
1448                         {
1449                                 if (self.skin != stof(self.playerskin))
1450                                         self.skin = stof(self.playerskin);
1451                         }
1452                 }
1453                 // Savage: Check for nameless players
1454                 if (strlen(self.netname) < 1) {
1455                         self.netname = "Player";
1456                         stuffcmd(self, "name Player\n");
1457                 }
1458
1459                 GrapplingHookFrame();
1460
1461                 W_WeaponFrame();
1462
1463                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1464                 {
1465                         if (cvar("g_minstagib") && self.button3)
1466                         {
1467                                 if (self.jump_interval <= (time + 0.1))
1468                                 {
1469                                         self.jump_interval = time + 1;
1470                                         W_Laser_Attack();
1471                                 }
1472                         }
1473                         else if (self.viewzoom > 0.4)
1474                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1475                 }
1476                 else if (self.viewzoom < 1.0)
1477                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1478
1479
1480                 if (self.button2)
1481                         PlayerJump ();
1482                 else
1483                         self.flags = self.flags | FL_JUMPRELEASED;
1484
1485                 player_powerups();
1486                 player_regen();
1487                 player_anim();
1488
1489                 if (cvar("g_minstagib"))
1490                         minstagib_ammocheck();
1491
1492                 ctf_setstatus();
1493
1494                 //self.angles_y=self.v_angle_y + 90;   // temp
1495
1496                 if (self.waterlevel == 2)
1497                         CheckWaterJump ();
1498
1499                 //if (TetrisPreFrame()) return;
1500         } else if(gameover) {
1501                 if (intermission_running)
1502                         IntermissionThink ();   // otherwise a button could be missed between
1503                 return;
1504         } else if(self.classname == "observer") {
1505
1506                 if (self.flags & FL_JUMPRELEASED) {
1507                         if (self.button2 && self.version == cvar("gameversion")) {
1508                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1509                                         self.flags = self.flags & !FL_JUMPRELEASED;
1510                                         self.classname = "player";
1511                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1512                                                 JoinBestTeam(self, 0);
1513                                         if(cvar("g_campaign"))
1514                                                 campaign_bots_may_start = 1;
1515                                         PutClientInServer();
1516                                         if(self.flags & !FL_NOTARGET)
1517                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1518                                         centerprint(self,"");
1519                                         return;
1520                                 } else {
1521                                         self.flags = self.flags & !FL_JUMPRELEASED;
1522                                         stuffcmd(self,"menu_showteamselect\n");
1523                                         return;
1524                                 }
1525                         } else if(self.button0 && self.version == cvar("gameversion")) {
1526                                 self.flags = self.flags & !FL_JUMPRELEASED;
1527                                 if(SpectateNext() == 1) {
1528                                         self.classname = "spectator";
1529                                 }
1530                         }
1531                 } else {
1532                         if (!(self.button0 || self.button2)) {
1533                                 self.flags = self.flags | FL_JUMPRELEASED;
1534                         }
1535                 }
1536                 PrintWelcomeMessage(self);
1537         } else if(self.classname == "spectator") {
1538                 if (self.flags & FL_JUMPRELEASED) {
1539                         if (self.button2 && self.version == cvar("gameversion")) {
1540                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1541                                         self.flags = self.flags & !FL_JUMPRELEASED;
1542                                         self.classname = "player";
1543                                         if(!cvar("g_lms"))
1544                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1545
1546                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1547                                                 JoinBestTeam(self, 0);
1548                                         if(cvar("g_campaign"))
1549                                                 campaign_bots_may_start = 1;
1550                                         PutClientInServer();
1551                                         centerprint(self,"");
1552                                         return;
1553                                 } else {
1554                                         self.flags = self.flags & !FL_JUMPRELEASED;
1555                                         stuffcmd(self,"menu_showteamselect\n");
1556                                         return;
1557                                 }
1558                         } else if(self.button0) {
1559                                 self.flags = self.flags & !FL_JUMPRELEASED;
1560                                 if(SpectateNext() == 1) {
1561                                         self.classname = "spectator";
1562                                 } else {
1563                                         self.classname = "observer";
1564                                         PutClientInServer();
1565                                 }
1566                         } else if (self.button3) {
1567                                 self.flags = self.flags & !FL_JUMPRELEASED;
1568                                 self.classname = "observer";
1569                                 PutClientInServer();
1570                         } else {
1571                                 SpectateUpdate();
1572                         }
1573                 } else {
1574                         if (!(self.button0 || self.button3)) {
1575                                 self.flags = self.flags | FL_JUMPRELEASED;
1576                         }
1577                 }
1578                 PrintWelcomeMessage(self);
1579                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1580         }
1581 }
1582
1583
1584 /*
1585 =============
1586 PlayerPostThink
1587
1588 Called every frame for each client after the physics are run
1589 =============
1590 */
1591 void PlayerPostThink (void)
1592 {
1593         if(self.classname == "player") {
1594                 CheckRules_Player();
1595                 UpdateChatBubble();
1596                 UpdateTeamBubble();
1597                 if (self.deadflag == DEAD_NO)
1598                 if (self.impulse)
1599                         ImpulseCommands ();
1600                 if (intermission_running)
1601                         return;         // intermission or finale
1602
1603                 //PrintWelcomeMessage(self);
1604                 //if (TetrisPostFrame()) return;
1605         } else if (self.classname == "observer") {
1606                 //do nothing
1607         } else if (self.classname == "spectator") {
1608                 //do nothing
1609         }
1610         Arena_Warmup();
1611 }