data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 144         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 145                 spot = Spawn_RandomPoint(firstspot);
 146         else
 147                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 148
 149         if (!spot)
 150         {
 151                 if(cvar("spawn_debug"))
 152                         GotoNextMap();
 153                 else
 154                         error ("PutClientInServer: no start points on level");
 155         }
 156
 157         return spot;
 158 }
 159
 160 /*
 161 =============
 162 CheckPlayerModel
 163
 164 Checks if the argument string can be a valid playermodel.
 165 Returns a valid one in doubt.
 166 =============
 167 */
 168 string FallbackPlayerModel = "models/player/marine.zym";
 169 string CheckPlayerModel(string plyermodel) {
 170         if(strlen(plyermodel) < 4)
 171                 return FallbackPlayerModel;
 172         if( substring(plyermodel,0,14) != "models/player/")
 173                 return FallbackPlayerModel;
 174         else if(cvar("sv_servermodelsonly"))
 175         {
 176                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 177                         return FallbackPlayerModel;
 178                 if(!fexists(plyermodel))
 179                         return FallbackPlayerModel;
 180         }
 181         return plyermodel;
 182 }
 183
 184 /*
 185 =============
 186 Client_customizeentityforclient
 187
 188 LOD reduction
 189 =============
 190 */
 191 float Client_customizeentityforclient()
 192 {
 193 #ifdef ALLOW_VARIABLE_LOD
 194         // self: me
 195         // other: the player viewing me
 196         float distance;
 197         float f;
 198
 199         if(other.cvar_cl_playerdetailreduction <= 0)
 200         {
 201                 if(other.cvar_cl_playerdetailreduction <= -2)
 202                         self.modelindex = self.modelindex_lod2;
 203                 else if(other.cvar_cl_playerdetailreduction <= -1)
 204                         self.modelindex = self.modelindex_lod1;
 205                 else
 206                         self.modelindex = self.modelindex_lod0;
 207         }
 208         else
 209         {
 210                 distance = vlen(self.origin - other.origin);
 211                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 212                 if(f > 10000)
 213                         self.modelindex = self.modelindex_lod2;
 214                 else if(f > 5000)
 215                         self.modelindex = self.modelindex_lod1;
 216                 else
 217                         self.modelindex = self.modelindex_lod0;
 218         }
 219 #endif
 220
 221         return TRUE;
 222 }
 223
 224 void setmodel_lod(entity e, string modelname)
 225 {
 226 #ifdef ALLOW_VARIABLE_LOD
 227         string s;
 228
 229         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 230         if(fexists(s))
 231         {
 232                 precache_model(s);
 233                 setmodel(e, s);
 234                 self.modelindex_lod1 = self.modelindex;
 235         }
 236         else
 237                 self.modelindex_lod1 = -1;
 238
 239         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 240         if(fexists(s))
 241         {
 242                 precache_model(s);
 243                 setmodel(e, s);
 244                 self.modelindex_lod2 = self.modelindex;
 245         }
 246         else
 247                 self.modelindex_lod2 = -1;
 248
 249         precache_model(modelname);
 250         setmodel(e, modelname);
 251         self.modelindex_lod0 = self.modelindex;
 252
 253         if(self.modelindex_lod1 < 0)
 254                 self.modelindex_lod1 = self.modelindex;
 255
 256         if(self.modelindex_lod2 < 0)
 257                 self.modelindex_lod2 = self.modelindex;
 258 #else
 259         precache_model(modelname);
 260         setmodel(e, modelname);
 261 #endif
 262 }
 263
 264 /*
 265 =============
 266 PutObserverInServer
 267
 268 putting a client as observer in the server
 269 =============
 270 */
 271 void PutObserverInServer (void)
 272 {
 273         entity  spot;
 274         spot = SelectSpawnPoint (FALSE);
 275         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 276
 277         if(clienttype(self) == CLIENTTYPE_REAL)
 278         {
 279                 msg_entity = self;
 280                 WriteByte(MSG_ONE, SVC_SETVIEW);
 281                 WriteEntity(MSG_ONE, self);
 282         }
 283
 284         if (cvar("g_runematch"))
 285                 DropAllRunes(self);
 286
 287         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 288                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 289         else if(self.killcount != -666)
 290                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 291
 292         self.classname = "observer";
 293         self.health = -666;
 294         self.takedamage = DAMAGE_NO;
 295         self.solid = SOLID_NOT;
 296         self.movetype = MOVETYPE_NOCLIP;
 297         self.flags = FL_CLIENT | FL_NOTARGET;
 298         self.armorvalue = 666;
 299         self.effects = 0;
 300         self.armorvalue = cvar("g_balance_armor_start");
 301         self.pauserotarmor_finished = 0;
 302         self.pauserothealth_finished = 0;
 303         self.pauseregen_finished = 0;
 304         self.damageforcescale = 0;
 305         self.death_time = 0;
 306         self.dead_time = 0;
 307         self.dead_frame = 0;
 308         self.die_frame = 0;
 309         self.deaths = 0;
 310         self.alpha = 0;
 311         self.scale = 0;
 312         self.fade_time = 0;
 313         self.pain_frame = 0;
 314         self.pain_finished = 0;
 315         self.strength_finished = 0;
 316         self.invincible_finished = 0;
 317         self.pushltime = 0;
 318         self.think = SUB_Null;
 319         self.nextthink = 0;
 320         self.hook_time = 0;
 321         self.runes = 0;
 322         self.deadflag = DEAD_NO;
 323         self.angles = spot.angles;
 324         self.angles_z = 0;
 325         self.fixangle = TRUE;
 326         self.crouch = FALSE;
 327         self.view_ofs = PL_VIEW_OFS;
 328         setorigin (self, spot.origin);
 329         setsize (self, '0 0 0', '0 0 0');
 330         self.oldorigin = self.origin;
 331         self.items = 0;
 332         self.model = "";
 333         self.modelindex = 0;
 334         self.weapon = 0;
 335         self.weaponmodel = "";
 336         self.weaponentity = world;
 337         self.killcount = -666;
 338         self.velocity = '0 0 0';
 339         self.avelocity = '0 0 0';
 340         self.punchangle = '0 0 0';
 341         self.punchvector = '0 0 0';
 342         self.oldvelocity = self.velocity;
 343
 344         if(cvar("g_arena"))
 345         {
 346                 if(self.frags != -2)
 347                 {
 348                         Spawnqueue_Insert(self);
 349                 }
 350                 else
 351                 {
 352                         Spawnqueue_Unmark(self);
 353                         Spawnqueue_Remove(self);
 354                 }
 355         }
 356         else if(!cvar("g_lms"))
 357                 self.frags = -666;
 358 }
 359
 360
 361 /*
 362 =============
 363 PutClientInServer
 364
 365 Called when a client spawns in the server
 366 =============
 367 */
 368 void PutClientInServer (void)
 369 {
 370         if(clienttype(self) == CLIENTTYPE_BOT)
 371         {
 372                 self.classname = "player";
 373         }
 374         else if(clienttype(self) == CLIENTTYPE_REAL)
 375         {
 376                 msg_entity = self;
 377                 WriteByte(MSG_ONE, SVC_SETVIEW);
 378                 WriteEntity(MSG_ONE, self);
 379         }
 380
 381         // player is dead and becomes observer
 382         if(cvar("g_lms") && self.frags < 1)
 383                 self.classname = "observer";
 384
 385         if(cvar("g_arena"))
 386         if(!self.spawned)
 387                 self.classname = "observer";
 388
 389         if(self.classname == "player") {
 390                 entity  spot;
 391
 392                 spot = SelectSpawnPoint (FALSE);
 393
 394                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 395
 396                 self.classname = "player";
 397                 self.iscreature = TRUE;
 398                 self.movetype = MOVETYPE_WALK;
 399                 self.solid = SOLID_SLIDEBOX;
 400                 self.flags = FL_CLIENT;
 401                 self.takedamage = DAMAGE_AIM;
 402                 self.effects = 0;
 403                 self.health = cvar("g_balance_health_start");
 404                 self.armorvalue = cvar("g_balance_armor_start");
 405                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 406                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 407                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 408                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 409                 self.damageforcescale = 2;
 410                 self.death_time = 0;
 411                 self.dead_time = 0;
 412                 self.dead_frame = 0;
 413                 self.die_frame = 0;
 414                 self.alpha = 0;
 415                 self.scale = 0;
 416                 self.fade_time = 0;
 417                 self.pain_frame = 0;
 418                 self.pain_finished = 0;
 419                 self.strength_finished = 0;
 420                 self.invincible_finished = 0;
 421                 self.pushltime = 0;
 422                 //self.speed_finished = 0;
 423                 //self.slowmo_finished = 0;
 424                 // players have no think function
 425                 self.think = SUB_Null;
 426                 self.nextthink = 0;
 427                 self.weapon = 0;
 428                 self.switchweapon = 0;
 429                 self.hook_time = 0;
 430
 431                 self.runes = 0;
 432
 433                 self.deadflag = DEAD_NO;
 434
 435                 self.angles = spot.angles;
 436
 437                 self.angles_z = 0; // never spawn tilted even if the spot says to
 438                 self.fixangle = TRUE; // turn this way immediately
 439                 self.velocity = '0 0 0';
 440                 self.avelocity = '0 0 0';
 441                 self.punchangle = '0 0 0';
 442                 self.punchvector = '0 0 0';
 443                 self.oldvelocity = self.velocity;
 444
 445                 self.viewzoom = 0.6;
 446
 447                 self.customizeentityforclient = Client_customizeentityforclient;
 448
 449                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 450                         local string defaultmodel;
 451                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 452                         setmodel_lod (self, defaultmodel);
 453                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 454                 } else {
 455                         self.playermodel = CheckPlayerModel(self.playermodel);
 456                         setmodel_lod (self, self.playermodel);
 457                         self.skin = stof(self.playerskin);
 458
 459                 }
 460
 461                 self.crouch = FALSE;
 462                 self.view_ofs = PL_VIEW_OFS;
 463                 setsize (self, PL_MIN, PL_MAX);
 464                 self.spawnorigin = spot.origin;
 465                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 466                 // don't reset back to last position, even if new position is stuck in solid
 467                 self.oldorigin = self.origin;
 468
 469                 if(cvar("g_lms"))
 470                 {
 471                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 472                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 473                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 474                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 475                         self.health = cvar("g_lms_start_health");
 476                         self.armorvalue = cvar("g_lms_start_armor");
 477                 }
 478                 else if (cvar("g_use_ammunition")) {
 479                         self.ammo_shells = cvar("g_start_ammo_shells");
 480                         self.ammo_nails = cvar("g_start_ammo_nails");
 481                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 482                         self.ammo_cells = cvar("g_start_ammo_cells");
 483                 } else {
 484                         self.ammo_shells = 999;
 485                         self.ammo_nails = 999;
 486                         self.ammo_rockets = 999;
 487                         self.ammo_cells = 999;
 488                 }
 489
 490                 self.items = 0;
 491                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 492                 {
 493                         self.items = self.items | IT_LASER;
 494                         self.switchweapon = WEP_LASER;
 495                 }
 496                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 497                 {
 498                         self.items = self.items | IT_SHOTGUN;
 499                         self.switchweapon = WEP_SHOTGUN;
 500                 }
 501                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 502                 {
 503                         self.items = self.items | IT_UZI;
 504                         self.switchweapon = WEP_UZI;
 505                 }
 506                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 507                 {
 508                         self.items = self.items | IT_GRENADE_LAUNCHER;
 509                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 510                 }
 511                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 512                 {
 513                         self.items = self.items | IT_ELECTRO;
 514                         self.switchweapon = WEP_ELECTRO;
 515                 }
 516                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 517                 {
 518                         self.items = self.items | IT_CRYLINK;
 519                         self.switchweapon = WEP_CRYLINK;
 520                 }
 521                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 522                 {
 523                         self.items = self.items | IT_NEX;
 524                         self.switchweapon = WEP_NEX;
 525                 }
 526                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 527                 {
 528                         self.items = self.items | IT_HAGAR;
 529                         self.switchweapon = WEP_HAGAR;
 530                 }
 531                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 532                 {
 533                         self.items = self.items | IT_ROCKET_LAUNCHER;
 534                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 535                 }
 536
 537                 if(cvar("g_instagib"))
 538                 {
 539                         self.items = IT_NEX;
 540                         self.switchweapon = WEP_NEX;
 541                         self.ammo_cells = 999;
 542                 }
 543
 544                 if(cvar("g_rocketarena"))
 545                 {
 546                         self.items = IT_ROCKET_LAUNCHER;
 547                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 548                         self.ammo_rockets = 999;
 549                 }
 550
 551                 if(cvar("g_nixnex"))
 552                 {
 553                         self.items = 0;
 554                         // will be done later
 555                 }
 556
 557                 if(cvar("g_minstagib"))
 558                 {
 559                         self.health = 100;
 560                         self.armorvalue = 0;
 561                         self.items = IT_NEX;
 562                         self.switchweapon = WEP_NEX;
 563                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 564                         self.extralives = 0;
 565                         self.jump_interval = time;
 566                 }
 567
 568                 if(cvar("g_arena"))
 569                         Spawnqueue_Remove(self);
 570
 571                 self.event_damage = PlayerDamage;
 572
 573                 self.bot_attack = TRUE;
 574
 575                 self.statdraintime = time + 5;
 576                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 577
 578                 if(self.killcount == -666) {
 579                         self.killcount = 0;
 580                         if(!cvar("g_arena"))
 581                         if(!cvar("g_lms"))
 582                                 self.frags = 0;
 583                 }
 584
 585                 self.cnt = WEP_LASER;
 586                 self.nixnex_lastchange_id = -1;
 587
 588                 CL_SpawnWeaponentity();
 589                 self.alpha = default_player_alpha;
 590                 self.exteriorweaponentity.alpha = default_player_alpha;
 591
 592                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 593                 self.lms_traveled_distance = 0;
 594
 595                 if(cvar("spawn_debug"))
 596                 {
 597                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 598                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 599                 }
 600
 601                 //stuffcmd(self, "chase_active 0");
 602                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 603         } else if(self.classname == "observer") {
 604                 PutObserverInServer ();
 605         }
 606 }
 607
 608 /*
 609 =============
 610 SetNewParms
 611 =============
 612 */
 613 void SetNewParms (void)
 614 {
 615
 616 }
 617
 618 /*
 619 =============
 620 SetChangeParms
 621 =============
 622 */
 623 void SetChangeParms (void)
 624 {
 625
 626 }
 627
 628 /*
 629 =============
 630 ClientKill
 631
 632 Called when a client types 'kill' in the console
 633 =============
 634 */
 635 void ClientKill (void)
 636 {
 637         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 638 }
 639
 640 /*
 641 =============
 642 ClientConnect
 643
 644 Called when a client connects to the server
 645 =============
 646 */
 647 string ColoredTeamName(float t);
 648 //void dom_player_join_team(entity pl);
 649 void ClientConnect (void)
 650 {
 651         self.classname = "player_joining";
 652         self.flags = self.flags | FL_CLIENT;
 653
 654         if(player_count<0) player_count = 0;
 655
 656         bot_clientconnect();
 657
 658         //if(cvar("g_domination"))
 659         //      dom_player_join_team(self);
 660
 661         //JoinBestTeam(self, FALSE);
 662
 663         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 664                 self.classname = "observer";
 665         } else {
 666                 self.classname = "player";
 667                 campaign_bots_may_start = 1;
 668         }
 669
 670         self.playerid = (playerid_last = playerid_last + 1);
 671         if(cvar("sv_eventlog"))
 672         {
 673                 string s;
 674                 if(clienttype(self) == CLIENTTYPE_REAL)
 675                         s = "player";
 676                 else
 677                         s = "bot";
 678                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 679                 s = strcat(":team:", ftos(self.playerid), ":");
 680                 s = strcat(s, ftos(self.team));
 681                 GameLogEcho(s, FALSE);
 682         }
 683
 684         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 685
 686         bprint ("^4",self.netname);
 687         bprint ("^4 connected");
 688
 689         if(cvar("g_domination") || cvar("g_ctf"))
 690         {
 691                 bprint(" and joined the ");
 692                 bprint(ColoredTeamName(self.team));
 693         }
 694
 695         bprint("\n");
 696
 697         self.welcomemessage_time = time + cvar("welcome_message_time");
 698         self.welcomemessage_time2 = 0;
 699
 700         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 701         // send prediction settings to the client
 702         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 703         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 704         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 705         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 706         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 707         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 708         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 709         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 710         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 711         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 712         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 713         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 714         // Wazat's grappling hook
 715         SetGrappleHookBindings();
 716
 717         // get autoswitch state from player
 718         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 719         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 720
 721         // get version info from player
 722         stuffcmd(self, "cmd clientversion $gameversion\n");
 723
 724         // get other cvars from player
 725         GetCvars(0);
 726
 727         // set cvar for team scoreboard
 728         if (teams_matter)
 729         {
 730                 local float t;
 731                 t = cvar("teamplay");
 732                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 733                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 734         }
 735         else
 736                 stuffcmd(self, strcat("set teamplay 0\n"));
 737
 738         if(cvar("g_lms"))
 739         {
 740                 self.frags = cvar("fraglimit");
 741                 // no fraglimit was set, so player gets 999 lives
 742                 if(self.frags < 1)
 743                         self.frags = 999;
 744
 745                 // disallow player to join after the worst player has lost g_lms_last_join lives
 746                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 747                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 748                 {
 749                         self.frags = -666;
 750                         lms_dead_count += 1;
 751                 }
 752                 else if(cvar("fraglimit") > lms_lowest_lives)
 753                 {
 754                         self.frags = lms_lowest_lives;
 755                 }
 756         }
 757         else if(cvar("g_arena"))
 758         {
 759                 self.classname = "observer";
 760                 Spawnqueue_Insert(self);
 761         }
 762
 763         bot_relinkplayerlist();
 764
 765         self.jointime = time;
 766 }
 767
 768 /*
 769 =============
 770 ClientDisconnect
 771
 772 Called when a client disconnects from the server
 773 =============
 774 */
 775 void(entity e) DropFlag;
 776 .entity chatbubbleentity;
 777 .entity teambubbleentity;
 778 void ClientDisconnect (void)
 779 {
 780         float save;
 781         if(cvar("sv_eventlog"))
 782                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 783         bprint ("^4",self.netname);
 784         bprint ("^4 disconnected\n");
 785
 786         if (self.chatbubbleentity)
 787         {
 788                 remove (self.chatbubbleentity);
 789                 self.chatbubbleentity = world;
 790         }
 791
 792         if (self.teambubbleentity)
 793         {
 794                 remove (self.teambubbleentity);
 795                 self.teambubbleentity = world;
 796         }
 797
 798         DropAllRunes(self);
 799
 800         if(self.flagcarried)
 801                 DropFlag(self.flagcarried);
 802
 803         save = self.flags;
 804         self.flags = self.flags - (self.flags & FL_CLIENT);
 805         bot_relinkplayerlist();
 806         self.flags = save;
 807
 808         // player was dead, decrease dead count
 809         if(cvar("g_lms") && self.frags < 1)
 810                 lms_dead_count -= 1;
 811         else if(cvar("g_arena"))
 812         {
 813                 Spawnqueue_Unmark(self);
 814                 Spawnqueue_Remove(self);
 815         }
 816 }
 817
 818 .float buttonchat;
 819 void() ChatBubbleThink =
 820 {
 821         self.nextthink = time;
 822         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 823         {
 824                 self.owner.chatbubbleentity = world;
 825                 remove(self);
 826                 return;
 827         }
 828         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 829         if (self.owner.buttonchat && !self.owner.deadflag)
 830                 self.model = self.mdl;
 831         else
 832                 self.model = "";
 833 };
 834
 835 void() UpdateChatBubble =
 836 {
 837         if (!self.modelindex)
 838                 return;
 839         // spawn a chatbubble entity if needed
 840         if (!self.chatbubbleentity)
 841         {
 842                 self.chatbubbleentity = spawn();
 843                 self.chatbubbleentity.owner = self;
 844                 self.chatbubbleentity.exteriormodeltoclient = self;
 845                 self.chatbubbleentity.think = ChatBubbleThink;
 846                 self.chatbubbleentity.nextthink = time;
 847                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 848                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 849                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 850                 self.chatbubbleentity.model = "";
 851         }
 852 }
 853
 854
 855 void() TeamBubbleThink =
 856 {
 857         self.nextthink = time;
 858         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 859         {
 860                 self.owner.teambubbleentity = world;
 861                 remove(self);
 862                 return;
 863         }
 864 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 865         if (self.owner.buttonchat || self.owner.deadflag)
 866                 self.model = "";
 867         else
 868                 self.model = self.mdl;
 869
 870 };
 871
 872 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 873
 874 void() UpdateTeamBubble =
 875 {
 876         if (!self.modelindex || !cvar("teamplay"))
 877                 return;
 878         // spawn a teambubble entity if needed
 879         if (!self.teambubbleentity && cvar("teamplay"))
 880         {
 881                 self.teambubbleentity = spawn();
 882                 self.teambubbleentity.owner = self;
 883                 self.teambubbleentity.exteriormodeltoclient = self;
 884                 self.teambubbleentity.think = TeamBubbleThink;
 885                 self.teambubbleentity.nextthink = time;
 886                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 887 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 888                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 889                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 890                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 891                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 892                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 893         }
 894 }
 895
 896 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 897 // added to the model skins
 898 /*void() UpdateColorModHack =
 899 {
 900         local float c;
 901         c = self.clientcolors & 15;
 902         // LordHavoc: only bothering to support white, green, red, yellow, blue
 903              if (teamplay == 0) self.colormod = '0 0 0';
 904         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 905         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 906         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 907         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 908         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 909         else self.colormod = '1 1 1';
 910 };*/
 911
 912 /*
 913 =============
 914 PlayerJump
 915
 916 When you press the jump key
 917 =============
 918 */
 919 void PlayerJump (void)
 920 {
 921         float mjumpheight;
 922
 923         mjumpheight = cvar("g_balance_jumpheight");
 924         if (self.waterlevel >= 2)
 925         {
 926                 if (self.watertype == CONTENT_WATER)
 927                         self.velocity_z = 200;
 928                 else if (self.watertype == CONTENT_SLIME)
 929                         self.velocity_z = 80;
 930                 else
 931                         self.velocity_z = 50;
 932
 933                 return;
 934         }
 935
 936
 937         if (!(self.flags & FL_ONGROUND))
 938                 return;
 939
 940         if (!(self.flags & FL_JUMPRELEASED))
 941                 return;
 942
 943         if(cvar("g_runematch"))
 944         {
 945                 if(self.runes & RUNE_SPEED)
 946                 {
 947                         if(self.runes & CURSE_SLOW)
 948                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 949                         else
 950                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 951                 }
 952                 else if(self.runes & CURSE_SLOW)
 953                 {
 954                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 955                 }
 956         }
 957
 958         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 959         {
 960                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 961         }
 962
 963         self.velocity_z = self.velocity_z + mjumpheight;
 964         self.oldvelocity_z = self.velocity_z;
 965
 966         self.flags = self.flags - FL_ONGROUND;
 967         self.flags = self.flags - FL_JUMPRELEASED;
 968 }
 969
 970 void() CheckWaterJump =
 971 {
 972         local vector start, end;
 973
 974 // check for a jump-out-of-water
 975         makevectors (self.angles);
 976         start = self.origin;
 977         start_z = start_z + 8;
 978         v_forward_z = 0;
 979         normalize(v_forward);
 980         end = start + v_forward*24;
 981         traceline (start, end, TRUE, self);
 982         if (trace_fraction < 1)
 983         {       // solid at waist
 984                 start_z = start_z + self.maxs_z - 8;
 985                 end = start + v_forward*24;
 986                 self.movedir = trace_plane_normal * -50;
 987                 traceline (start, end, TRUE, self);
 988                 if (trace_fraction == 1)
 989                 {       // open at eye level
 990                         self.flags = self.flags | FL_WATERJUMP;
 991                         self.velocity_z = 225;
 992                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 993                         self.teleport_time = time + 2;  // safety net
 994                         return;
 995                 }
 996         }
 997 };
 998
 999
1000 void respawn(void)
1001 {
1002         CopyBody(1);
1003         PutClientInServer();
1004 }
1005
1006 void player_powerups (void)
1007 {
1008         if (cvar("g_minstagib"))
1009         {
1010                 self.effects = EF_FULLBRIGHT;
1011                 if (self.items & IT_STRENGTH)
1012                 {
1013                         if (time > self.strength_finished)
1014                         {
1015                                 self.alpha = default_player_alpha;
1016                                 self.exteriorweaponentity.alpha = default_player_alpha;
1017                                 self.items = self.items - (self.items & IT_STRENGTH);
1018                                 sprint(self, "^3Invisibility has worn off\n");
1019                         }
1020                 }
1021                 else
1022                 {
1023                         if (time < self.strength_finished)
1024                         {
1025                                 self.alpha = cvar("g_minstagib_invis_alpha");
1026                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1027                                 self.items = self.items | IT_STRENGTH;
1028                                 sprint(self, "^3You are invisible\n");
1029                         }
1030                 }
1031
1032                 if (self.items & IT_INVINCIBLE)
1033                 {
1034                         if (time > self.invincible_finished)
1035                         {
1036                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1037                                 sprint(self, "^3Speed has worn off\n");
1038                         }
1039                 }
1040                 else
1041                 {
1042                         if (time < self.invincible_finished)
1043                         {
1044                                 self.items = self.items | IT_INVINCIBLE;
1045                                 sprint(self, "^3You are on speed\n");
1046                         }
1047                 }
1048                 return;
1049         }
1050
1051         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1052         if (self.items & IT_STRENGTH)
1053         {
1054                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1055                 if (time > self.strength_finished)
1056                 {
1057                         self.items = self.items - (self.items & IT_STRENGTH);
1058                         sprint(self, "^3Strength has worn off\n");
1059                 }
1060         }
1061         else
1062         {
1063                 if (time < self.strength_finished)
1064                 {
1065                         self.items = self.items | IT_STRENGTH;
1066                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1067                 }
1068         }
1069         if (self.items & IT_INVINCIBLE)
1070         {
1071                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1072                 if (time > self.invincible_finished)
1073                 {
1074                         self.items = self.items - (self.items & IT_INVINCIBLE);
1075                         sprint(self, "^3Shield has worn off\n");
1076                 }
1077         }
1078         else
1079         {
1080                 if (time < self.invincible_finished)
1081                 {
1082                         self.items = self.items | IT_INVINCIBLE;
1083                         sprint(self, "^3Shield surrounds you\n");
1084                 }
1085         }
1086
1087         if (cvar("g_fullbrightplayers"))
1088                 self.effects = self.effects | EF_FULLBRIGHT;
1089
1090         // midair gamemode: damage only while in the air
1091         // if in midair mode, being on ground grants temporary invulnerability
1092         // (this is so that multishot weapon don't clear the ground flag on the
1093         // first damage in the frame, leaving the player vulnerable to the
1094         // remaining hits in the same frame)
1095         if (self.flags & FL_ONGROUND)
1096         if (cvar("g_midair"))
1097                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1098
1099         if (time < self.spawnshieldtime)
1100                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1101 }
1102
1103 void player_regen (void)
1104 {
1105         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1106         maxh = cvar("g_balance_health_stable");
1107         maxa = cvar("g_balance_armor_stable");
1108         limith = cvar("g_balance_health_limit");
1109         limita = cvar("g_balance_armor_limit");
1110
1111         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1112                 return;
1113
1114         if(cvar("g_runematch"))
1115         {
1116                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1117                 if (self.runes & RUNE_REGEN)
1118                 {
1119                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1120                         {
1121                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1122                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1123                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1124                         }
1125                         else
1126                         {
1127                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1128                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1129                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1130                         }
1131                 }
1132                 else if (self.runes & CURSE_VENOM)
1133                 {
1134                         max_mod = cvar("g_balance_curse_venom_hpmod");
1135                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1136                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1137                         else
1138                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1139                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1140                         //if (!self.runes & RUNE_REGEN)
1141                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1142                 }
1143                 maxh = maxh * max_mod;
1144                 //maxa = maxa * max_mod;
1145
1146                 if (time > self.pauserotarmor_finished)
1147                 {
1148                         if (self.armorvalue > maxa)
1149                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1150                 }
1151                 if (time > self.pauserothealth_finished)
1152                 {
1153                         if (self.health > maxh)
1154                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1155                 }
1156                 if (time > self.pauseregen_finished)
1157                 {
1158                         if (self.health < maxh)
1159                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1160                         if (self.armorvalue < maxa)
1161                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1162                 }
1163         }
1164         else
1165         {
1166                 if (time > self.pauserothealth_finished)
1167                 if (self.health > maxh)
1168                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1169                 if (time > self.pauserotarmor_finished)
1170                 if (self.armorvalue > maxa)
1171                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1172                 if (time > self.pauseregen_finished)
1173                 {
1174                         if (self.health < maxh)
1175                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1176                         if (self.armorvalue < maxa)
1177                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1178                 }
1179         }
1180
1181         if (self.health > limith)
1182                 self.health = limith;
1183         if(self.health < 1)
1184                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1185         if (self.armorvalue > limita)
1186                 self.armorvalue = limita;
1187 }
1188
1189 /*
1190 ======================
1191 spectate mode routines
1192 ======================
1193 */
1194 void SpectateCopy(entity spectatee) {
1195         self.armortype = spectatee.armortype;
1196         self.armorvalue = spectatee.armorvalue;
1197         self.currentammo = spectatee.currentammo;
1198         self.effects = spectatee.effects;
1199         self.health = spectatee.health;
1200         self.impulse = 0;
1201         self.items = spectatee.items;
1202         self.punchangle = spectatee.punchangle;
1203         self.view_ofs = spectatee.view_ofs;
1204         self.v_angle = spectatee.v_angle;
1205         self.viewzoom = spectatee.viewzoom;
1206         setorigin(self, spectatee.origin);
1207         setsize(self, spectatee.mins, spectatee.maxs);
1208 }
1209
1210 void SpectateUpdate() {
1211         if (self != self.enemy) {
1212                 if(self.enemy.flags & FL_NOTARGET)
1213                         PutObserverInServer();
1214                 SpectateCopy(self.enemy);
1215                 self.dmg_take = self.enemy.dmg_take;
1216                 self.dmg_save = self.enemy.dmg_save;
1217                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1218                 self.fixangle = TRUE;
1219                 self.angles = self.enemy.v_angle;
1220                 //msg_entity = self;
1221                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1222                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1223                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1224                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1225         }
1226 }
1227
1228 float SpectateNext() {
1229         other = find(self.enemy, classname, "player");
1230         if (!other) {
1231                 other = find(other, classname, "player");
1232         }
1233         if (other) {
1234                 self.enemy = other;
1235         }
1236         if(self.enemy.classname == "player") {
1237                 msg_entity = self;
1238                 WriteByte(MSG_ONE, SVC_SETVIEW);
1239                 WriteEntity(MSG_ONE, self.enemy);
1240                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1241                 SpectateUpdate();
1242                 return 1;
1243         } else {
1244                 return 0;
1245         }
1246 }
1247
1248 /*
1249 =============
1250 PlayerPreThink
1251
1252 Called every frame for each client before the physics are run
1253 =============
1254 */
1255 void PlayerPreThink (void)
1256 {
1257         if(self.classname == "player") {
1258                 local vector m1, m2;
1259
1260 //              if(self.netname == "Wazat")
1261 //                      bprint(strcat(self.classname, "\n"));
1262
1263                 CheckRules_Player();
1264
1265                 Nixnex_GiveCurrentWeapon();
1266
1267                 if(self.button7)
1268                         PrintWelcomeMessage(self);
1269
1270                 if(cvar("g_lms") || !cvar("sv_spectate"))
1271                 if((time - self.jointime) <= cvar("welcome_message_time"))
1272                         PrintWelcomeMessage(self);
1273
1274                 if (intermission_running)
1275                 {
1276                         IntermissionThink ();   // otherwise a button could be missed between
1277                         return;                                 // the think tics
1278                 }
1279
1280                 if (self.deadflag != DEAD_NO)
1281                 {
1282                         player_anim();
1283                         if (self.deadflag == DEAD_DYING)
1284                         {
1285                                 if (time > self.dead_time)
1286                                         self.deadflag = DEAD_DEAD;
1287                         }
1288                         else if (self.deadflag == DEAD_DEAD)
1289                         {
1290                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1291                                         self.deadflag = DEAD_RESPAWNABLE;
1292                                 else if (!self.button0 && !self.button2 && !self.button3)
1293                                         self.deadflag = DEAD_RESPAWNABLE;
1294                         }
1295                         else if (self.deadflag == DEAD_RESPAWNABLE)
1296                         {
1297                                 if (self.button0  ||
1298                                     self.button2  ||
1299                                     self.button3  ||
1300                                     self.button4  ||
1301                                     self.button5  ||
1302                                     self.button6  ||
1303                                     self.button7  ||
1304                                     self.button8  ||
1305                                     self.buttonuse ||
1306                                     cvar("g_lms") ||
1307                                     cvar("g_forced_respawn"))
1308                                         respawn();
1309                         }
1310                         return;
1311                 }
1312
1313                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1314                 {
1315                         vector dist;
1316
1317                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1318                         dist = self.oldorigin - self.origin;
1319                         dist_z = 0;
1320                         self.lms_traveled_distance += fabs(vlen(dist));
1321
1322                         if(time > self.lms_nextcheck)
1323                         {
1324                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1325                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1326                                 {
1327                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1328                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1329                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1330                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1331                                 }
1332                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1333                                 self.lms_traveled_distance = 0;
1334                         }
1335                 }
1336
1337                 if (self.button5 && !self.hook.state)
1338                 {
1339                         if (!self.crouch)
1340                         {
1341                                 self.crouch = TRUE;
1342                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1343                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1344                         }
1345                 }
1346                 else
1347                 {
1348                         if (self.crouch)
1349                         {
1350                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1351                                 if (!trace_startsolid)
1352                                 {
1353                                         self.crouch = FALSE;
1354                                         self.view_ofs = PL_VIEW_OFS;
1355                                         setsize (self, PL_MIN, PL_MAX);
1356                                 }
1357                         }
1358                 }
1359
1360                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1361                         local string defaultmodel;
1362                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1363
1364                         if (defaultmodel != self.model)
1365                         {
1366                                 m1 = self.mins;
1367                                 m2 = self.maxs;
1368                                 setmodel_lod (self, defaultmodel);
1369                                 setsize (self, m1, m2);
1370                         }
1371
1372                         if (self.skin != cvar("sv_defaultplayerskin"))
1373                                 self.skin = cvar("sv_defaultplayerskin");
1374                 } else {
1375                         if (self.playermodel != self.model)
1376                         {
1377                                 self.playermodel = CheckPlayerModel(self.playermodel);
1378                                 m1 = self.mins;
1379                                 m2 = self.maxs;
1380                                 setmodel_lod (self, self.playermodel);
1381                                 setsize (self, m1, m2);
1382                         }
1383
1384                         if (self.skin != stof(self.playerskin))
1385                                 self.skin = stof(self.playerskin);
1386                 }
1387                 // Savage: Check for nameless players
1388                 if (strlen(self.netname) < 1) {
1389                         self.netname = "Player";
1390                         stuffcmd(self, "name Player\n");
1391                 }
1392
1393                 GrapplingHookFrame();
1394
1395                 W_WeaponFrame();
1396
1397                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1398                 {
1399                         if (cvar("g_minstagib") && self.button3)
1400                         {
1401                                 if (self.jump_interval <= (time + 0.1))
1402                                 {
1403                                         self.jump_interval = time + 1;
1404                                         W_Laser_Attack();
1405                                 }
1406                         }
1407                         else if (self.viewzoom > 0.4)
1408                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1409                 }
1410                 else if (self.viewzoom < 1.0)
1411                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1412
1413
1414                 if (self.button2)
1415                         PlayerJump ();
1416                 else
1417                         self.flags = self.flags | FL_JUMPRELEASED;
1418
1419                 player_powerups();
1420                 player_regen();
1421                 player_anim();
1422
1423                 if (cvar("g_minstagib"))
1424                         minstagib_ammocheck();
1425
1426                 //self.angles_y=self.v_angle_y + 90;   // temp
1427
1428                 if (self.waterlevel == 2)
1429                         CheckWaterJump ();
1430
1431                 //if (TetrisPreFrame()) return;
1432         } else if(gameover) {
1433                 if (intermission_running)
1434                         IntermissionThink ();   // otherwise a button could be missed between
1435                 return;
1436         } else if(self.classname == "observer") {
1437
1438                 if (self.flags & FL_JUMPRELEASED) {
1439                         if (self.button2 && self.version == cvar("gameversion")) {
1440                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1441                                         self.flags = self.flags & !FL_JUMPRELEASED;
1442                                         self.classname = "player";
1443                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1444                                                 JoinBestTeam(self, 0);
1445                                         if(cvar("g_campaign"))
1446                                                 campaign_bots_may_start = 1;
1447                                         PutClientInServer();
1448                                         if(self.flags & !FL_NOTARGET)
1449                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1450                                         centerprint(self,"");
1451                                         return;
1452                                 } else {
1453                                         self.flags = self.flags & !FL_JUMPRELEASED;
1454                                         stuffcmd(self,"menu_showteamselect\n");
1455                                         return;
1456                                 }
1457                         } else if(self.button0 && self.version == cvar("gameversion")) {
1458                                 self.flags = self.flags & !FL_JUMPRELEASED;
1459                                 if(SpectateNext() == 1) {
1460                                         self.classname = "spectator";
1461                                 }
1462                         }
1463                 } else {
1464                         if (!(self.button0 || self.button2)) {
1465                                 self.flags = self.flags | FL_JUMPRELEASED;
1466                         }
1467                 }
1468                 PrintWelcomeMessage(self);
1469         } else if(self.classname == "spectator") {
1470
1471                 if (self.flags & FL_JUMPRELEASED) {
1472                         if (self.button2 && self.version == cvar("gameversion")) {
1473                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1474                                         self.flags = self.flags & !FL_JUMPRELEASED;
1475                                         self.classname = "player";
1476                                         if(!cvar("g_lms"))
1477                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1478
1479                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1480                                                 JoinBestTeam(self, 0);
1481                                         if(cvar("g_campaign"))
1482                                                 campaign_bots_may_start = 1;
1483                                         PutClientInServer();
1484                                         centerprint(self,"");
1485                                         return;
1486                                 } else {
1487                                         self.flags = self.flags & !FL_JUMPRELEASED;
1488                                         stuffcmd(self,"menu_showteamselect\n");
1489                                         return;
1490                                 }
1491                         } else if(self.button0) {
1492                                 self.flags = self.flags & !FL_JUMPRELEASED;
1493                                 if(SpectateNext() == 1) {
1494                                         self.classname = "spectator";
1495                                 } else {
1496                                         self.classname = "observer";
1497                                         PutClientInServer();
1498                                 }
1499                         } else if (self.button3) {
1500                                 self.flags = self.flags & !FL_JUMPRELEASED;
1501                                 self.classname = "observer";
1502                                 PutClientInServer();
1503                         } else {
1504                                 SpectateUpdate();
1505                         }
1506         } else {
1507                 if (!(self.button0 || self.button3)) {
1508                         self.flags = self.flags | FL_JUMPRELEASED;
1509                 }
1510                 }
1511                 PrintWelcomeMessage(self);
1512         }
1513 }
1514
1515
1516 /*
1517 =============
1518 PlayerPostThink
1519
1520 Called every frame for each client after the physics are run
1521 =============
1522 */
1523 void PlayerPostThink (void)
1524 {
1525         if(self.classname == "player") {
1526                 CheckRules_Player();
1527                 UpdateChatBubble();
1528                 UpdateTeamBubble();
1529                 if (self.deadflag == DEAD_NO)
1530                 if (self.impulse)
1531                         ImpulseCommands ();
1532                 if (intermission_running)
1533                         return;         // intermission or finale
1534
1535                 //PrintWelcomeMessage(self);
1536                 //if (TetrisPostFrame()) return;
1537         } else if (self.classname == "observer") {
1538                 //do nothing
1539         } else if (self.classname == "spectator") {
1540                 //do nothing
1541         }
1542         Arena_Warmup();
1543 }