data/qcsrc/server/cl_client.qc

   1 float ClientData_Send(entity to, float sf)
   2 {
   3         if(to != self.owner)
   4         {
   5                 error("wtf");
   6                 return FALSE;
   7         }
   8
   9         entity e;
  10
  11         e = to;
  12         if(to.classname == "spectator")
  13                 e = to.enemy;
  14
  15         sf = 0;
  16
  17         if(e.race_completed)
  18                 sf |= 1; // forced scoreboard
  19         if(to.spectatee_status)
  20                 sf |= 2; // spectator ent number follows
  21         if(e.zoomstate)
  22                 sf |= 4; // zoomed
  23         if(e.porto_v_angle_held)
  24                 sf |= 8; // angles held
  25
  26         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  27         WriteByte(MSG_ENTITY, sf);
  28
  29         if(sf & 2)
  30                 WriteByte(MSG_ENTITY, to.spectatee_status);
  31
  32         if(sf & 8)
  33         {
  34                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  35                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  36         }
  37
  38         return TRUE;
  39 }
  40
  41 void ClientData_Attach()
  42 {
  43         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  44         self.clientdata.drawonlytoclient = self;
  45         self.clientdata.owner = self;
  46 }
  47
  48 void ClientData_Detach()
  49 {
  50         remove(self.clientdata);
  51         self.clientdata = world;
  52 }
  53
  54 void ClientData_Touch(entity e)
  55 {
  56         e.clientdata.SendFlags = 1;
  57
  58         // make it spectatable
  59         entity e2;
  60         FOR_EACH_REALCLIENT(e2)
  61         {
  62                 if(e2 != e)
  63                         if(e2.classname == "spectator")
  64                                 if(e2.enemy == e)
  65                                         e2.clientdata.SendFlags = 1;
  66         }
  67 }
  68
  69
  70 #define SPAWNPOINT_SCORE frags
  71
  72 .string netname_previous;
  73
  74 void spawnfunc_info_player_survivor (void)
  75 {
  76         spawnfunc_info_player_deathmatch();
  77 }
  78
  79 void spawnfunc_info_player_start (void)
  80 {
  81         spawnfunc_info_player_deathmatch();
  82 }
  83
  84 void spawnfunc_info_player_deathmatch (void)
  85 {
  86         self.classname = "info_player_deathmatch";
  87         relocate_spawnpoint();
  88 }
  89
  90 void spawnpoint_use()
  91 {
  92         if(teams_matter)
  93         if(have_team_spawns)
  94         {
  95                 self.team = activator.team;
  96                 some_spawn_has_been_used = 1;
  97         }
  98 };
  99
 100 // Returns:
 101 //   -1 if a spawn can't be used
 102 //   otherwise, a weight of the spawnpoint
 103 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 104 {
 105         float shortest, thisdist;
 106         entity player;
 107
 108         // filter out spots for the wrong team
 109         if(teamcheck)
 110         if(spot.team != teamcheck)
 111                 return -1;
 112
 113         if(race_spawns)
 114                 if(spot.target == "")
 115                         return -1;
 116
 117         if(clienttype(self) == CLIENTTYPE_REAL)
 118         {
 119                 if(spot.restriction == 1)
 120                         return -1;
 121         }
 122         else
 123         {
 124                 if(spot.restriction == 2)
 125                         return -1;
 126         }
 127
 128         // filter out spots for assault
 129         if(spot.target != "") {
 130                 local entity ent;
 131                 float good, found;
 132                 ent = find(world, targetname, spot.target);
 133                 while(ent) {
 134                         if(ent.classname == "target_objective")
 135                         {
 136                                 found = 1;
 137                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 138                                         return -1;
 139                                 good = 1;
 140                         }
 141                         else if(ent.classname == "trigger_race_checkpoint")
 142                         {
 143                                 found = 1;
 144                                 if(self.classname == "player") // spectators may spawn everywhere
 145                                 {
 146                                         if(g_race_qualifying)
 147                                         {
 148                                                 // spawn at first
 149                                                 if(ent.race_checkpoint != 0)
 150                                                         return -1;
 151                                                 if(spot.race_place != race_lowest_place_spawn)
 152                                                         return -1;
 153                                         }
 154                                         else
 155                                         {
 156                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 157                                                         return -1;
 158                                                 float pl;
 159                                                 pl = self.race_place;
 160                                                 if(pl > race_highest_place_spawn)
 161                                                         pl = 0;
 162                                                 if(spot.race_place != pl)
 163                                                         return -1;
 164                                         }
 165                                 }
 166                                 good = 1;
 167                         }
 168                         ent = find(ent, targetname, spot.target);
 169                 }
 170
 171                 if(found && !good)
 172                         return -1;
 173         }
 174
 175         player = playerlist;
 176         shortest = vlen(world.maxs - world.mins);
 177         for(player = playerlist; player; player = player.chain)
 178                 if (player != self)
 179                 {
 180                         thisdist = vlen(player.origin - spot.origin);
 181                         if (thisdist < shortest)
 182                                 shortest = thisdist;
 183                 }
 184         return shortest;
 185 }
 186
 187 float spawn_allbad;
 188 float spawn_allgood;
 189 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 190 {
 191         local entity spot, spotlist, spotlistend;
 192         spawn_allgood = TRUE;
 193         spawn_allbad = TRUE;
 194
 195         spotlist = world;
 196         spotlistend = world;
 197
 198         for(spot = firstspot; spot; spot = spot.chain)
 199         {
 200                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 201
 202                 if(cvar("spawn_debugview"))
 203                 {
 204                         setmodel(spot, "models/runematch/rune.mdl");
 205                         if(spot.SPAWNPOINT_SCORE < mindist)
 206                         {
 207                                 spot.colormod = '1 0 0';
 208                                 spot.scale = 1;
 209                         }
 210                         else
 211                         {
 212                                 spot.colormod = '0 1 0';
 213                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 214                         }
 215                 }
 216
 217                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 218                 {
 219                         if(spot.SPAWNPOINT_SCORE < mindist)
 220                         {
 221                                 // too short distance
 222                                 spawn_allgood = FALSE;
 223                         }
 224                         else
 225                         {
 226                                 // perfect
 227                                 spawn_allbad = FALSE;
 228
 229                                 if(spotlistend)
 230                                         spotlistend.chain = spot;
 231                                 spotlistend = spot;
 232                                 if(!spotlist)
 233                                         spotlist = spot;
 234
 235                                 /*
 236                                 if(teamcheck)
 237                                 if(spot.team != teamcheck)
 238                                         error("invalid spawn added");
 239
 240                                 print("added ", etos(spot), "\n");
 241                                 */
 242                         }
 243                 }
 244         }
 245         if(spotlistend)
 246                 spotlistend.chain = world;
 247
 248         /*
 249                 entity e;
 250                 if(teamcheck)
 251                         for(e = spotlist; e; e = e.chain)
 252                         {
 253                                 print("seen ", etos(e), "\n");
 254                                 if(e.team != teamcheck)
 255                                         error("invalid spawn found");
 256                         }
 257         */
 258
 259         return spotlist;
 260 }
 261
 262 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 263 {
 264         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 265         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 266         local entity spot;
 267
 268         RandomSelection_Init();
 269         for(spot = firstspot; spot; spot = spot.chain)
 270                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 271
 272         return RandomSelection_chosen_ent;
 273 }
 274
 275 /*
 276 =============
 277 SelectSpawnPoint
 278
 279 Finds a point to respawn
 280 =============
 281 */
 282 entity SelectSpawnPoint (float anypoint)
 283 {
 284         local float teamcheck;
 285         local entity firstspot_new;
 286         local entity spot, firstspot, playerlist;
 287
 288         spot = find (world, classname, "testplayerstart");
 289         if (spot)
 290                 return spot;
 291
 292         teamcheck = 0;
 293
 294         if(!anypoint && have_team_spawns)
 295                 teamcheck = self.team;
 296
 297         // get the list of players
 298         playerlist = findchain(classname, "player");
 299         // get the entire list of spots
 300         firstspot = findchain(classname, "info_player_deathmatch");
 301         // filter out the bad ones
 302         // (note this returns the original list if none survived)
 303         if(anypoint)
 304         {
 305                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 306         }
 307         else
 308         {
 309                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 310                 if(!firstspot_new)
 311                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 312                 firstspot = firstspot_new;
 313
 314                 // there is 50/50 chance of choosing a random spot or the furthest spot
 315                 // (this means that roughly every other spawn will be furthest, so you
 316                 // usually won't get fragged at spawn twice in a row)
 317                 if (arena_roundbased)
 318                 {
 319                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 320                         if(firstspot_new)
 321                                 firstspot = firstspot_new;
 322                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 323                 }
 324                 else if (random() > cvar("g_spawn_furthest"))
 325                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 326                 else
 327                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 328         }
 329
 330         if(cvar("spawn_debugview"))
 331         {
 332                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 333
 334                 entity e;
 335                 if(teamcheck)
 336                         for(e = firstspot; e; e = e.chain)
 337                                 if(e.team != teamcheck)
 338                                         error("invalid spawn found");
 339         }
 340
 341         if (!spot)
 342         {
 343                 if(cvar("spawn_debug"))
 344                         GotoNextMap();
 345                 else
 346                 {
 347                         if(some_spawn_has_been_used)
 348                                 return world; // team can't spawn any more, because of actions of other team
 349                         else
 350                                 error("Cannot find a spawn point - please fix the map!");
 351                 }
 352         }
 353
 354         return spot;
 355 }
 356
 357 /*
 358 =============
 359 CheckPlayerModel
 360
 361 Checks if the argument string can be a valid playermodel.
 362 Returns a valid one in doubt.
 363 =============
 364 */
 365 string FallbackPlayerModel = "models/player/marine.zym";
 366 string CheckPlayerModel(string plyermodel) {
 367         if(strlen(plyermodel) < 4)
 368                 return FallbackPlayerModel;
 369         if( substring(plyermodel,0,14) != "models/player/")
 370                 return FallbackPlayerModel;
 371         else if(cvar("sv_servermodelsonly"))
 372         {
 373                 if(substring(plyermodel,-4,4) != ".zym")
 374                 if(substring(plyermodel,-4,4) != ".dpm")
 375                 if(substring(plyermodel,-4,4) != ".md3")
 376                 if(substring(plyermodel,-4,4) != ".psk")
 377                         return FallbackPlayerModel;
 378                 // forbid the LOD models
 379                 if(substring(plyermodel, -9,5) == "_lod1")
 380                         return FallbackPlayerModel;
 381                 if(substring(plyermodel, -9,5) == "_lod2")
 382                         return FallbackPlayerModel;
 383                 if(plyermodel != strtolower(plyermodel))
 384                         return FallbackPlayerModel;
 385                 if(!fexists(plyermodel))
 386                         return FallbackPlayerModel;
 387         }
 388         return plyermodel;
 389 }
 390
 391 /*
 392 =============
 393 Client_customizeentityforclient
 394
 395 LOD reduction
 396 =============
 397 */
 398 void Client_uncustomizeentityforclient()
 399 {
 400         if(self.modelindex == 0) // no need to uncustomize then
 401                 return;
 402         self.modelindex = self.modelindex_lod0;
 403         self.skin = self.skinindex;
 404 }
 405
 406 float Client_customizeentityforclient()
 407 {
 408         entity modelsource;
 409
 410         if(self.modelindex == 0)
 411                 return TRUE;
 412
 413         // forcemodel stuff
 414
 415 #ifdef PROFILING
 416         float t0;
 417         t0 = gettime(GETTIME_HIRES); // reference
 418 #endif
 419
 420         modelsource = self;
 421
 422 #ifdef ALLOW_FORCEMODELS
 423         if(other.cvar_cl_forceplayermodelsfromnexuiz)
 424                 if not(self.modelindex_lod0_from_nexuiz)
 425                         modelsource = other;
 426         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 427                 modelsource = other;
 428 #endif
 429
 430         self.skin = modelsource.skinindex;
 431
 432 #if 0
 433         if(modelsource == self)
 434                 self.skin = modelsource.skinindex;
 435         else
 436                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 437 #endif
 438
 439         // self: me
 440         // other: the player viewing me
 441         float distance;
 442         float f;
 443
 444         if(other.cvar_cl_playerdetailreduction <= 0)
 445         {
 446                 if(other.cvar_cl_playerdetailreduction <= -2)
 447                         self.modelindex = modelsource.modelindex_lod2;
 448                 else if(other.cvar_cl_playerdetailreduction <= -1)
 449                         self.modelindex = modelsource.modelindex_lod1;
 450                 else
 451                         self.modelindex = modelsource.modelindex_lod0;
 452         }
 453         else
 454         {
 455                 distance = vlen(self.origin - other.origin);
 456                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 457                 if(f > sv_loddistance2)
 458                         self.modelindex = modelsource.modelindex_lod2;
 459                 else if(f > sv_loddistance1)
 460                         self.modelindex = modelsource.modelindex_lod1;
 461                 else
 462                         self.modelindex = modelsource.modelindex_lod0;
 463         }
 464
 465 #ifdef PROFILING
 466         float t1;
 467         t1 = gettime(GETTIME_HIRES); // reference
 468         client_cefc_accumulator += (t1 - t0);
 469 #endif
 470
 471         return TRUE;
 472 }
 473
 474 void UpdatePlayerSounds();
 475 void setmodel_lod(entity e, string modelname)
 476 {
 477         string s;
 478
 479         if(sv_loddistance1)
 480         {
 481                 // FIXME: this only supports 3-letter extensions
 482                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 483                 if(fexists(s))
 484                 {
 485                         setmodel(e, s); // players have high precision
 486                         self.modelindex_lod1 = self.modelindex;
 487                 }
 488                 else
 489                         self.modelindex_lod1 = -1;
 490
 491                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 492                 if(fexists(s))
 493                 {
 494                         setmodel(e, s); // players have high precision
 495                         self.modelindex_lod2 = self.modelindex;
 496                 }
 497                 else
 498                         self.modelindex_lod2 = -1;
 499
 500                 precache_model(modelname);
 501                 setmodel(e, modelname); // players have high precision
 502                 self.modelindex_lod0 = self.modelindex;
 503
 504                 if(self.modelindex_lod1 < 0)
 505                         self.modelindex_lod1 = self.modelindex;
 506
 507                 if(self.modelindex_lod2 < 0)
 508                         self.modelindex_lod2 = self.modelindex;
 509         }
 510         else
 511         {
 512                 precache_model(modelname);
 513                 setmodel(e, modelname); // players have high precision
 514                 self.modelindex_lod0 = self.modelindex;
 515                         // save it for possible player model forcing
 516         }
 517
 518         s = whichpack(self.model);
 519         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
 520
 521         player_setupanimsformodel();
 522         UpdatePlayerSounds();
 523 }
 524
 525 /*
 526 =============
 527 PutObserverInServer
 528
 529 putting a client as observer in the server
 530 =============
 531 */
 532 void FixPlayermodel();
 533 void PutObserverInServer (void)
 534 {
 535         entity  spot;
 536
 537         race_PreSpawnObserver();
 538
 539         spot = SelectSpawnPoint (TRUE);
 540         if(!spot)
 541                 error("No spawnpoints for observers?!?\n");
 542         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 543
 544         if(clienttype(self) == CLIENTTYPE_REAL)
 545         {
 546                 msg_entity = self;
 547                 WriteByte(MSG_ONE, SVC_SETVIEW);
 548                 WriteEntity(MSG_ONE, self);
 549         }
 550
 551         DropAllRunes(self);
 552         kh_Key_DropAll(self, TRUE);
 553
 554         Portal_ClearAll(self);
 555
 556         if(self.flagcarried)
 557                 DropFlag(self.flagcarried, world, world);
 558         if(self.ballcarried)
 559                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 560
 561         WaypointSprite_PlayerDead();
 562
 563         if(self.killcount != -666)
 564         {
 565                 if(g_lms)
 566                 {
 567                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 568                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 569                         else
 570                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 571                 }
 572                 else
 573                         bprint ("^4", self.netname, "^4 is spectating now\n");
 574         }
 575
 576         PlayerScore_Clear(self); // clear scores when needed
 577
 578         self.spectatortime = time;
 579
 580         self.classname = "observer";
 581         self.iscreature = FALSE;
 582         self.health = -666;
 583         self.takedamage = DAMAGE_NO;
 584         self.solid = SOLID_NOT;
 585         self.movetype = MOVETYPE_NOCLIP;
 586         self.flags = FL_CLIENT | FL_NOTARGET;
 587         self.armorvalue = 666;
 588         self.effects = 0;
 589         self.armorvalue = cvar("g_balance_armor_start");
 590         self.pauserotarmor_finished = 0;
 591         self.pauserothealth_finished = 0;
 592         self.pauseregen_finished = 0;
 593         self.damageforcescale = 0;
 594         self.death_time = 0;
 595         self.dead_frame = 0;
 596         self.alpha = 0;
 597         self.scale = 0;
 598         self.fade_time = 0;
 599         self.pain_frame = 0;
 600         self.pain_finished = 0;
 601         self.strength_finished = 0;
 602         self.invincible_finished = 0;
 603         self.pushltime = 0;
 604         self.think = SUB_Null;
 605         self.nextthink = 0;
 606         self.hook_time = 0;
 607         self.runes = 0;
 608         self.deadflag = DEAD_NO;
 609         self.angles = spot.angles;
 610         self.angles_z = 0;
 611         self.fixangle = TRUE;
 612         self.crouch = FALSE;
 613
 614         self.view_ofs = PL_VIEW_OFS;
 615         setorigin (self, spot.origin);
 616         setsize (self, '0 0 0', '0 0 0');
 617         self.prevorigin = self.origin;
 618         self.items = 0;
 619         self.weapons = 0;
 620         self.model = "";
 621         FixPlayermodel();
 622         self.model = "";
 623         self.modelindex = 0;
 624         self.weapon = 0;
 625         self.weaponmodel = "";
 626         self.weaponentity = world;
 627         self.exteriorweaponentity = world;
 628         self.killcount = -666;
 629         self.velocity = '0 0 0';
 630         self.avelocity = '0 0 0';
 631         self.punchangle = '0 0 0';
 632         self.punchvector = '0 0 0';
 633         self.oldvelocity = self.velocity;
 634
 635         if(sv_loddistance1)
 636                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 637
 638         self.team = -1;
 639
 640         if(g_arena)
 641         {
 642                 if(self.version_mismatch)
 643                 {
 644                         Spawnqueue_Unmark(self);
 645                         Spawnqueue_Remove(self);
 646                 }
 647                 else
 648                 {
 649                         Spawnqueue_Insert(self);
 650                 }
 651         }
 652         else if(g_lms)
 653         {
 654                 // Only if the player cannot play at all
 655                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 656                         self.frags = FRAGS_SPECTATOR;
 657                 else
 658                         self.frags = FRAGS_LMS_LOSER;
 659         }
 660         else
 661                 self.frags = FRAGS_SPECTATOR;
 662 }
 663
 664 float RestrictSkin(float s)
 665 {
 666         if(!teams_matter)
 667                 return s;
 668         if(s == 6)
 669                 return 6;
 670         return mod(s, 3);
 671 }
 672
 673 void FixPlayermodel()
 674 {
 675         local string defaultmodel;
 676         local float defaultskin, chmdl, oldskin;
 677         local vector m1, m2;
 678
 679         defaultmodel = "";
 680
 681         if(cvar("sv_defaultcharacter") == 1) {
 682                 defaultskin = 0;
 683
 684                 if(teams_matter)
 685                 {
 686                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 687                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 688                 }
 689
 690                 if(defaultmodel == "")
 691                 {
 692                         defaultmodel = cvar_string("sv_defaultplayermodel");
 693                         defaultskin = cvar("sv_defaultplayerskin");
 694                 }
 695         }
 696
 697         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 698         {
 699                 if(self.model != "")
 700                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 701                 self.model = ""; // force the != checks to return true
 702         }
 703
 704         if(defaultmodel != "")
 705         {
 706                 if (defaultmodel != self.model)
 707                 {
 708                         m1 = self.mins;
 709                         m2 = self.maxs;
 710                         setmodel_lod (self, defaultmodel);
 711                         setsize (self, m1, m2);
 712                         chmdl = TRUE;
 713                 }
 714
 715                 oldskin = self.skinindex;
 716                 self.skinindex = defaultskin;
 717         } else {
 718                 if (self.playermodel != self.model)
 719                 {
 720                         self.playermodel = CheckPlayerModel(self.playermodel);
 721                         m1 = self.mins;
 722                         m2 = self.maxs;
 723                         setmodel_lod (self, self.playermodel);
 724                         setsize (self, m1, m2);
 725                         chmdl = TRUE;
 726                 }
 727
 728                 oldskin = self.skinindex;
 729                 self.skinindex = RestrictSkin(stof(self.playerskin));
 730         }
 731
 732         if(chmdl || oldskin != self.skinindex)
 733                 self.species = player_getspecies(); // model or skin has changed
 734
 735         if(!teams_matter)
 736                 if(strlen(cvar_string("sv_defaultplayercolors")))
 737                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 738                                 setcolor(self, cvar("sv_defaultplayercolors"));
 739 }
 740
 741 void PlayerTouchExplode(entity p1, entity p2)
 742 {
 743         vector org;
 744         org = (p1.origin + p2.origin) * 0.5;
 745         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 746
 747         te_explosion(org);
 748
 749         entity e;
 750         e = spawn();
 751         setorigin(e, org);
 752         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 753         remove(e);
 754 }
 755
 756 /*
 757 =============
 758 PutClientInServer
 759
 760 Called when a client spawns in the server
 761 =============
 762 */
 763 //void() ctf_playerchanged;
 764 void PutClientInServer (void)
 765 {
 766         if(clienttype(self) == CLIENTTYPE_BOT)
 767         {
 768                 self.classname = "player";
 769         }
 770         else if(clienttype(self) == CLIENTTYPE_REAL)
 771         {
 772                 msg_entity = self;
 773                 WriteByte(MSG_ONE, SVC_SETVIEW);
 774                 WriteEntity(MSG_ONE, self);
 775         }
 776
 777         // player is dead and becomes observer
 778         // FIXME fix LMS scoring for new system
 779         if(g_lms)
 780         {
 781                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 782                         self.classname = "observer";
 783         }
 784
 785         if(g_arena)
 786         if(!self.spawned)
 787                 self.classname = "observer";
 788
 789         if(gameover)
 790                 self.classname = "observer";
 791
 792         if(self.classname == "player") {
 793                 entity spot, oldself;
 794
 795                 if(self.team < 0)
 796                         JoinBestTeam(self, FALSE, TRUE);
 797
 798                 race_PreSpawn();
 799
 800                 spot = SelectSpawnPoint (FALSE);
 801                 if(!spot)
 802                 {
 803                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 804                         return; // spawn failed
 805                 }
 806
 807                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 808                 self.campingrifle_bulletcounter = cvar("g_balance_campingrifle_magazinecapacity");
 809
 810                 self.classname = "player";
 811                 self.wasplayer = TRUE;
 812                 self.iscreature = TRUE;
 813                 self.movetype = MOVETYPE_WALK;
 814                 self.solid = SOLID_SLIDEBOX;
 815                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 816                 self.frags = FRAGS_PLAYER;
 817                 if(independent_players)
 818                         MAKE_INDEPENDENT_PLAYER(self);
 819                 self.flags = FL_CLIENT;
 820                 self.takedamage = DAMAGE_AIM;
 821                 if(g_minstagib)
 822                         self.effects = EF_FULLBRIGHT;
 823                 else
 824                         self.effects = 0;
 825                 self.air_finished = time + 12;
 826                 self.dmg = 2;
 827
 828                 if(inWarmupStage)
 829                 {
 830                         self.ammo_shells = warmup_start_ammo_shells;
 831                         self.ammo_nails = warmup_start_ammo_nails;
 832                         self.ammo_rockets = warmup_start_ammo_rockets;
 833                         self.ammo_cells = warmup_start_ammo_cells;
 834                         self.ammo_fuel = warmup_start_ammo_fuel;
 835                         self.health = warmup_start_health;
 836                         self.armorvalue = warmup_start_armorvalue;
 837                         self.weapons = warmup_start_weapons;
 838                 }
 839                 else
 840                 {
 841                         self.ammo_shells = start_ammo_shells;
 842                         self.ammo_nails = start_ammo_nails;
 843                         self.ammo_rockets = start_ammo_rockets;
 844                         self.ammo_cells = start_ammo_cells;
 845                         self.ammo_fuel = start_ammo_fuel;
 846                         self.health = start_health;
 847                         self.armorvalue = start_armorvalue;
 848                         self.weapons = start_weapons;
 849                 }
 850                 self.items = start_items;
 851                 self.switchweapon = w_getbestweapon(self);
 852                 self.cnt = self.switchweapon;
 853                 self.weapon = 0;
 854                 self.jump_interval = time;
 855
 856                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 857                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 858                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 859                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 860                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 861                 //extend the pause of rotting if client was reset at the beginning of the countdown
 862                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 863                         self.spawnshieldtime += game_starttime - time;
 864                         self.pauserotarmor_finished += game_starttime - time;
 865                         self.pauserothealth_finished += game_starttime - time;
 866                         self.pauseregen_finished += game_starttime - time;
 867                 }
 868                 self.damageforcescale = 2;
 869                 self.death_time = 0;
 870                 self.dead_frame = 0;
 871                 self.alpha = 0;
 872                 self.scale = 0;
 873                 self.fade_time = 0;
 874                 self.pain_frame = 0;
 875                 self.pain_finished = 0;
 876                 self.strength_finished = 0;
 877                 self.invincible_finished = 0;
 878                 self.pushltime = 0;
 879                 //self.speed_finished = 0;
 880                 //self.slowmo_finished = 0;
 881                 // players have no think function
 882                 self.think = SUB_Null;
 883                 self.nextthink = 0;
 884                 self.hook_time = 0;
 885                 self.dmg_team = 0;
 886
 887                 self.metertime = 0;
 888
 889                 self.runes = 0;
 890
 891                 self.deadflag = DEAD_NO;
 892
 893                 self.angles = spot.angles;
 894
 895                 self.angles_z = 0; // never spawn tilted even if the spot says to
 896                 self.fixangle = TRUE; // turn this way immediately
 897                 self.velocity = '0 0 0';
 898                 self.avelocity = '0 0 0';
 899                 self.punchangle = '0 0 0';
 900                 self.punchvector = '0 0 0';
 901                 self.oldvelocity = self.velocity;
 902
 903                 msg_entity = self;
 904                 WRITESPECTATABLE_MSG_ONE({
 905                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 906                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 907                 });
 908
 909                 if(sv_loddistance1)
 910                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 911
 912                 self.model = "";
 913                 FixPlayermodel();
 914
 915                 self.crouch = FALSE;
 916                 self.view_ofs = PL_VIEW_OFS;
 917                 setsize (self, PL_MIN, PL_MAX);
 918                 self.spawnorigin = spot.origin;
 919                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 920                 // don't reset back to last position, even if new position is stuck in solid
 921                 self.oldorigin = self.origin;
 922                 self.prevorigin = self.origin;
 923                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 924
 925                 if(g_arena)
 926                 {
 927                         Spawnqueue_Remove(self);
 928                         Spawnqueue_Mark(self);
 929                 }
 930
 931                 self.event_damage = PlayerDamage;
 932
 933                 self.bot_attack = TRUE;
 934
 935                 self.statdraintime = time + 5;
 936                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 937
 938                 if(self.killcount == -666) {
 939                         PlayerScore_Clear(self);
 940                         self.killcount = 0;
 941                 }
 942
 943                 self.cnt = WEP_LASER;
 944                 self.nixnex_lastchange_id = -1;
 945
 946                 CL_SpawnWeaponentity();
 947                 self.alpha = default_player_alpha;
 948                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 949                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 950
 951                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 952                 self.lms_traveled_distance = 0;
 953                 self.speedrunning = FALSE;
 954
 955                 race_PostSpawn(spot);
 956
 957                 if(cvar("spawn_debug"))
 958                 {
 959                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 960                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 961                 }
 962
 963                 //stuffcmd(self, "chase_active 0");
 964                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 965
 966                 if (cvar("g_spawnsound"))
 967                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 968
 969                 if(g_assault) {
 970                         if(self.team == assault_attacker_team)
 971                                 centerprint(self, "You are attacking!");
 972                         else
 973                                 centerprint(self, "You are defending!");
 974                 }
 975
 976                 target_voicescript_clear(self);
 977
 978                 oldself = self;
 979                 self = spot;
 980                         activator = oldself;
 981                                 SUB_UseTargets();
 982                         activator = world;
 983                 self = oldself;
 984
 985         } else if(self.classname == "observer") {
 986                 PutObserverInServer ();
 987         }
 988
 989         //if(g_ctf)
 990         //      ctf_playerchanged();
 991 }
 992
 993 float ClientInit_SendEntity(entity to, float sf)
 994 {
 995         float i;
 996         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 997         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 998         for(i = 1; i <= 24; ++i)
 999                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
1000         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1001         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1002         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1003
1004         if(sv_foginterval && world.fog != "")
1005                 WriteString(MSG_ENTITY, world.fog);
1006         else
1007                 WriteString(MSG_ENTITY, "");
1008         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1009         return TRUE;
1010 }
1011
1012 void ClientInit_Spawn()
1013 {
1014         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1015 }
1016
1017 /*
1018 =============
1019 SetNewParms
1020 =============
1021 */
1022 void SetNewParms (void)
1023 {
1024         // initialize parms for a new player
1025         parm1 = -(86400 * 366);
1026 }
1027
1028 /*
1029 =============
1030 SetChangeParms
1031 =============
1032 */
1033 void SetChangeParms (void)
1034 {
1035         // save parms for level change
1036         parm1 = self.parm_idlesince - time;
1037 }
1038
1039 /*
1040 =============
1041 DecodeLevelParms
1042 =============
1043 */
1044 void DecodeLevelParms (void)
1045 {
1046         // load parms
1047         self.parm_idlesince = parm1;
1048         if(self.parm_idlesince == -(86400 * 366))
1049                 self.parm_idlesince = time;
1050
1051         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1052         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1053 }
1054
1055 /*
1056 =============
1057 ClientKill
1058
1059 Called when a client types 'kill' in the console
1060 =============
1061 */
1062
1063 void ClientKill_Now_TeamChange()
1064 {
1065         if(self.killindicator_teamchange == -1)
1066         {
1067                 self.team = -1;
1068                 JoinBestTeam( self, FALSE, FALSE );
1069         }
1070         else
1071                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1072 }
1073
1074 void ClientKill_Now()
1075 {
1076         if(self.killindicator_teamchange)
1077                 ClientKill_Now_TeamChange();
1078
1079         // in any case:
1080         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1081
1082         if(self.killindicator)
1083         {
1084                 dprint("Cleaned up after a leaked kill indicator.\n");
1085                 remove(self.killindicator);
1086                 self.killindicator = world;
1087         }
1088 }
1089 void KillIndicator_Think()
1090 {
1091         if (!self.owner.modelindex)
1092         {
1093                 self.owner.killindicator = world;
1094                 remove(self);
1095                 return;
1096         }
1097
1098         if(self.cnt <= 0)
1099         {
1100                 self = self.owner;
1101                 ClientKill_Now(); // no oldself needed
1102                 return;
1103         }
1104         else
1105         {
1106                 if(self.cnt <= 10)
1107                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1108                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1109                 {
1110                         if(self.cnt <= 10)
1111                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1112                         if(self.owner.killindicator_teamchange)
1113                         {
1114                                 if(self.owner.killindicator_teamchange == -1)
1115                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1116                                 else
1117                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1118                         }
1119                         else
1120                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1121                 }
1122                 self.nextthink = time + 1;
1123                 self.cnt -= 1;
1124         }
1125 }
1126
1127 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1128 {
1129         float killtime;
1130         entity e;
1131         killtime = cvar("g_balance_kill_delay");
1132
1133         if(g_race_qualifying)
1134                 killtime = 0;
1135
1136         self.killindicator_teamchange = targetteam;
1137
1138         if(!self.killindicator)
1139         {
1140                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1141                 {
1142                         ClientKill_Now();
1143                 }
1144                 else
1145                 {
1146                         self.killindicator = spawn();
1147                         self.killindicator.owner = self;
1148                         self.killindicator.scale = 0.5;
1149                         setattachment(self.killindicator, self, "");
1150                         setorigin(self.killindicator, '0 0 52');
1151                         self.killindicator.think = KillIndicator_Think;
1152                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1153                         self.killindicator.cnt = ceil(killtime);
1154                         self.killindicator.count = bound(0, ceil(killtime), 10);
1155                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1156
1157                         for(e = world; (e = find(e, classname, "body")) != world; )
1158                         {
1159                                 if(e.enemy != self)
1160                                         continue;
1161                                 e.killindicator = spawn();
1162                                 e.killindicator.owner = e;
1163                                 e.killindicator.scale = 0.5;
1164                                 setattachment(e.killindicator, e, "");
1165                                 setorigin(e.killindicator, '0 0 52');
1166                                 e.killindicator.think = KillIndicator_Think;
1167                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1168                                 e.killindicator.cnt = ceil(killtime);
1169                         }
1170                         self.lip = 0;
1171                 }
1172         }
1173         if(self.killindicator)
1174         {
1175                 if(targetteam)
1176                         self.killindicator.colormod = TeamColor(targetteam);
1177                 else
1178                         self.killindicator.colormod = '0 0 0';
1179         }
1180 }
1181
1182 void ClientKill (void)
1183 {
1184         ClientKill_TeamChange(0);
1185 }
1186
1187 void DoTeamChange(float destteam)
1188 {
1189         float t, c0;
1190         if(!teams_matter)
1191         {
1192                 if(destteam >= 0)
1193                         SetPlayerColors(self, destteam);
1194                 return;
1195         }
1196         if(self.classname == "player")
1197         if(destteam == -1)
1198         {
1199                 CheckAllowedTeams(self);
1200                 t = FindSmallestTeam(self, TRUE);
1201                 switch(self.team)
1202                 {
1203                         case COLOR_TEAM1: c0 = c1; break;
1204                         case COLOR_TEAM2: c0 = c2; break;
1205                         case COLOR_TEAM3: c0 = c3; break;
1206                         case COLOR_TEAM4: c0 = c4; break;
1207                         default:          c0 = 999;
1208                 }
1209                 switch(t)
1210                 {
1211                         case 1:
1212                                 if(c0 > c1)
1213                                         destteam = COLOR_TEAM1;
1214                                 break;
1215                         case 2:
1216                                 if(c0 > c2)
1217                                         destteam = COLOR_TEAM2;
1218                                 break;
1219                         case 3:
1220                                 if(c0 > c3)
1221                                         destteam = COLOR_TEAM3;
1222                                 break;
1223                         case 4:
1224                                 if(c0 > c4)
1225                                         destteam = COLOR_TEAM4;
1226                                 break;
1227                 }
1228                 if(destteam == -1)
1229                         return;
1230         }
1231         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1232                 return;
1233         ClientKill_TeamChange(destteam);
1234 }
1235
1236 void FixClientCvars(entity e)
1237 {
1238         // send prediction settings to the client
1239         stuffcmd(e, "\nin_bindmap 0 0\n");
1240         if(g_race || g_cts)
1241                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1242         /*
1243          * we no longer need to stuff this. Remove this comment block if you feel
1244          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1245         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1246         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1247         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1248         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1249         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1250         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1251         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1252         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1253         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1254         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1255         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1256         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1257         stuffcmd(e, "cl_movement_edgefriction 1\n");
1258          */
1259 }
1260
1261 /*
1262 =============
1263 ClientConnect
1264
1265 Called when a client connects to the server
1266 =============
1267 */
1268 //void ctf_clientconnect();
1269 string ColoredTeamName(float t);
1270 void DecodeLevelParms (void);
1271 //void dom_player_join_team(entity pl);
1272 void ClientConnect (void)
1273 {
1274         local string s;
1275         float t;
1276
1277         if(self.flags & FL_CLIENT)
1278         {
1279                 print("Warning: ClientConnect, but already connected!\n");
1280                 return;
1281         }
1282
1283         if(Ban_MaybeEnforceBan(self))
1284                 return;
1285
1286         DecodeLevelParms();
1287
1288         self.classname = "player_joining";
1289
1290         self.flags = FL_CLIENT;
1291         self.version_nagtime = time + 10 + random() * 10;
1292
1293         if(player_count<0)
1294         {
1295                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1296                 player_count = 0;
1297         }
1298
1299         PlayerScore_Attach(self);
1300         ClientData_Attach();
1301
1302         bot_clientconnect();
1303
1304         race_PreSpawnObserver();
1305
1306         //if(g_domination)
1307         //      dom_player_join_team(self);
1308
1309         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1310
1311         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1312                 self.classname = "observer";
1313         } else {
1314                 if(teams_matter)
1315                 {
1316                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1317                         {
1318                                 self.classname = "player";
1319                                 campaign_bots_may_start = 1;
1320                         }
1321                         else
1322                         {
1323                                 self.classname = "observer"; // do it anyway
1324                         }
1325                 }
1326                 else
1327                 {
1328                         self.classname = "player";
1329                         campaign_bots_may_start = 1;
1330                 }
1331         }
1332
1333         self.playerid = (playerid_last = playerid_last + 1);
1334         if(cvar("sv_eventlog"))
1335         {
1336                 if(clienttype(self) == CLIENTTYPE_REAL)
1337                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1338                 else
1339                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1340                 s = strcat(":team:", ftos(self.playerid), ":");
1341                 s = strcat(s, ftos(self.team));
1342                 GameLogEcho(s);
1343         }
1344         self.netname_previous = strzone(self.netname);
1345
1346         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1347
1348         bprint ("^4",self.netname);
1349         bprint ("^4 connected");
1350
1351         if(g_domination || g_ctf)
1352         {
1353                 bprint(" and joined the ");
1354                 bprint(ColoredTeamName(self.team));
1355         }
1356
1357         bprint("\n");
1358
1359         self.welcomemessage_time = 0;
1360
1361         stuffcmd(self, strcat(clientstuff, "\n"));
1362         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1363         stuffcmd(self, "cl_particles_reloadeffects\n");
1364
1365         FixClientCvars(self);
1366
1367         // spawnfunc_waypoint sprites
1368         WaypointSprite_InitClient(self);
1369
1370         // Wazat's grappling hook
1371         SetGrappleHookBindings();
1372
1373         // get autoswitch state from player when he toggles it
1374         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1375
1376         // get version info from player
1377         stuffcmd(self, "cmd clientversion $gameversion\n");
1378
1379         // get other cvars from player
1380         GetCvars(0);
1381
1382         // set cvar for team scoreboard
1383         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1384
1385         // notify about available teams
1386         if(teams_matter)
1387         {
1388                 CheckAllowedTeams(self);
1389                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1390                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1391         }
1392         else
1393                 stuffcmd(self, "set _teams_available 0\n");
1394
1395         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1396
1397         if(g_arena)
1398         {
1399                 self.classname = "observer";
1400                 Spawnqueue_Insert(self);
1401         }
1402         /*else if(g_ctf)
1403         {
1404                 ctf_clientconnect();
1405         }*/
1406
1407         if(teams_matter || sv_cheats)
1408                 attach_entcs();
1409
1410         bot_relinkplayerlist();
1411
1412         self.spectatortime = time;
1413         if(blockSpectators)
1414         {
1415                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1416         }
1417
1418         self.jointime = time;
1419         self.allowedTimeouts = cvar("sv_timeout_number");
1420
1421         if(clienttype(self) == CLIENTTYPE_REAL)
1422         {
1423                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1424                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1425         }
1426
1427         if(g_lms)
1428         {
1429                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1430                 {
1431                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1432                         self.frags = FRAGS_SPECTATOR;
1433                 }
1434         }
1435
1436         if(!sv_foginterval && world.fog != "")
1437                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1438
1439         SoundEntity_Attach(self);
1440
1441         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1442         {
1443                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1444                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1445         }
1446         else
1447                 self.hitplotfh = -1;
1448 }
1449
1450 /*
1451 =============
1452 ClientDisconnect
1453
1454 Called when a client disconnects from the server
1455 =============
1456 */
1457 .entity chatbubbleentity;
1458 .entity teambubbleentity;
1459 void ReadyCount();
1460 void ClientDisconnect (void)
1461 {
1462         if not(self.flags & FL_CLIENT)
1463         {
1464                 print("Warning: ClientDisconnect without ClientConnect\n");
1465                 return;
1466         }
1467
1468         if(self.hitplotfh >= 0)
1469         {
1470                 fclose(self.hitplotfh);
1471                 self.hitplotfh = -1;
1472         }
1473
1474         bot_clientdisconnect();
1475
1476         if(self.entcs)
1477                 detach_entcs();
1478
1479         if(cvar("sv_eventlog"))
1480                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1481         bprint ("^4",self.netname);
1482         bprint ("^4 disconnected\n");
1483
1484         SoundEntity_Detach(self);
1485
1486         DropAllRunes(self);
1487         kh_Key_DropAll(self, TRUE);
1488
1489         Portal_ClearAll(self);
1490
1491         if(self.flagcarried)
1492                 DropFlag(self.flagcarried, world, world);
1493         if(self.ballcarried)
1494                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1495
1496         // Here, everything has been done that requires this player to be a client.
1497
1498         self.flags &~= FL_CLIENT;
1499
1500         if (self.chatbubbleentity)
1501                 remove (self.chatbubbleentity);
1502
1503         if (self.teambubbleentity)
1504                 remove (self.teambubbleentity);
1505
1506         if (self.killindicator)
1507                 remove (self.killindicator);
1508
1509         WaypointSprite_PlayerGone();
1510
1511         bot_relinkplayerlist();
1512
1513         // remove laserdot
1514         if(self.weaponentity)
1515                 if(self.weaponentity.lasertarget)
1516                         remove(self.weaponentity.lasertarget);
1517
1518         if(g_arena)
1519         {
1520                 Spawnqueue_Unmark(self);
1521                 Spawnqueue_Remove(self);
1522         }
1523
1524         ClientData_Detach();
1525         PlayerScore_Detach(self);
1526
1527         if(self.netname_previous)
1528                 strunzone(self.netname_previous);
1529         if(self.clientstatus)
1530                 strunzone(self.clientstatus);
1531
1532         ClearPlayerSounds();
1533
1534         self.playerid = 0;
1535         ReadyCount();
1536
1537         // free cvars
1538         GetCvars(-1);
1539 }
1540
1541 .float BUTTON_CHAT;
1542 void ChatBubbleThink()
1543 {
1544         self.nextthink = time;
1545         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1546         {
1547                 if(self.owner) // but why can that ever be world?
1548                         self.owner.chatbubbleentity = world;
1549                 remove(self);
1550                 return;
1551         }
1552         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1553 #ifdef TETRIS
1554                 || self.owner.tetris_on
1555 #endif
1556         )
1557                 self.model = self.mdl;
1558         else
1559                 self.model = "";
1560 };
1561
1562 void UpdateChatBubble()
1563 {
1564         if (!self.modelindex)
1565                 return;
1566         // spawn a chatbubble entity if needed
1567         if (!self.chatbubbleentity)
1568         {
1569                 self.chatbubbleentity = spawn();
1570                 self.chatbubbleentity.owner = self;
1571                 self.chatbubbleentity.exteriormodeltoclient = self;
1572                 self.chatbubbleentity.think = ChatBubbleThink;
1573                 self.chatbubbleentity.nextthink = time;
1574                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1575                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1576                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1577                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1578                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1579                 self.chatbubbleentity.model = "";
1580                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1581         }
1582 }
1583
1584
1585 void TeamBubbleThink()
1586 {
1587         self.nextthink = time;
1588         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1589         {
1590                 if(self.owner) // but why can that ever be world?
1591                         self.owner.teambubbleentity = world;
1592                 remove(self);
1593                 return;
1594         }
1595 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1596         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1597                 self.model = "";
1598         else
1599                 self.model = self.mdl;
1600
1601 };
1602
1603 float TeamBubble_customizeentityforclient()
1604 {
1605         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1606 }
1607
1608 void UpdateTeamBubble()
1609 {
1610         if (!self.modelindex || !teams_matter)
1611                 return;
1612         // spawn a teambubble entity if needed
1613         if (!self.teambubbleentity && teams_matter)
1614         {
1615                 self.teambubbleentity = spawn();
1616                 self.teambubbleentity.owner = self;
1617                 self.teambubbleentity.exteriormodeltoclient = self;
1618                 self.teambubbleentity.think = TeamBubbleThink;
1619                 self.teambubbleentity.nextthink = time;
1620                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1621 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1622                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1623                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1624                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1625                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1626                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1627                 self.teambubbleentity.effects = EF_LOWPRECISION;
1628         }
1629 }
1630
1631 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1632 // added to the model skins
1633 /*void UpdateColorModHack()
1634 {
1635         local float c;
1636         c = self.clientcolors & 15;
1637         // LordHavoc: only bothering to support white, green, red, yellow, blue
1638              if (!teams_matter) self.colormod = '0 0 0';
1639         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1640         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1641         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1642         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1643         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1644         else self.colormod = '1 1 1';
1645 };*/
1646
1647 void respawn(void)
1648 {
1649         CopyBody(1);
1650         self.effects |= EF_NODRAW; // prevent another CopyBody
1651         PutClientInServer();
1652 }
1653
1654 void play_countdown(float finished, string samp)
1655 {
1656         if(clienttype(self) == CLIENTTYPE_REAL)
1657                 if(floor(finished - time - frametime) != floor(finished - time))
1658                         if(finished - time < 6)
1659                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1660 }
1661
1662 /**
1663  * When sv_timeout is used this function returs strings like
1664  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1665  * Called by centerprint functions
1666  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1667  */
1668 string getTimeoutText(float addOneSecond) {
1669         if (!cvar("sv_timeout") || !timeoutStatus)
1670                 return "";
1671
1672         local string retStr;
1673         if (timeoutStatus == 1) {
1674                 if (addOneSecond == 1) {
1675                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1676                 }
1677                 else {
1678                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1679                 }
1680                 return retStr;
1681         }
1682         else if (timeoutStatus == 2) {
1683                 if (addOneSecond) {
1684                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1685                         //don't show messages like "Timeout ends in 0 seconds"...
1686                         if ((remainingTimeoutTime + 1) > 0)
1687                                 return retStr;
1688                         else
1689                                 return "";
1690                 }
1691                 else {
1692                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1693                         //don't show messages like "Timeout ends in 0 seconds"...
1694                         if (remainingTimeoutTime > 0)
1695                                 return retStr;
1696                         else
1697                                 return "";
1698                 }
1699         }
1700         else return "";
1701 }
1702
1703 void player_powerups (void)
1704 {
1705         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1706         {
1707                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1708                 self.modelflags |= MF_ROCKET;
1709         }
1710         else
1711         {
1712                 SoundEntity_StopSound(self, CHAN_PLAYER);
1713                 self.modelflags &~= MF_ROCKET;
1714         }
1715
1716         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1717
1718         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1719                 return;
1720
1721         if (g_minstagib)
1722         {
1723                 self.effects |= EF_FULLBRIGHT;
1724
1725                 if (self.items & IT_STRENGTH)
1726                 {
1727                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1728                         if (time > self.strength_finished)
1729                         {
1730                                 self.alpha = default_player_alpha;
1731                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1732                                 self.items &~= IT_STRENGTH;
1733                                 sprint(self, "^3Invisibility has worn off\n");
1734                         }
1735                 }
1736                 else
1737                 {
1738                         if (time < self.strength_finished)
1739                         {
1740                                 self.alpha = g_minstagib_invis_alpha;
1741                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1742                                 self.items |= IT_STRENGTH;
1743                                 sprint(self, "^3You are invisible\n");
1744                         }
1745                 }
1746
1747                 if (self.items & IT_INVINCIBLE)
1748                 {
1749                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1750                         if (time > self.invincible_finished)
1751                         {
1752                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1753                                 sprint(self, "^3Speed has worn off\n");
1754                         }
1755                 }
1756                 else
1757                 {
1758                         if (time < self.invincible_finished)
1759                         {
1760                                 self.items = self.items | IT_INVINCIBLE;
1761                                 sprint(self, "^3You are on speed\n");
1762                         }
1763                 }
1764                 return;
1765         }
1766
1767         if (self.items & IT_STRENGTH)
1768         {
1769                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1770                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1771                 if (time > self.strength_finished)
1772                 {
1773                         self.items = self.items - (self.items & IT_STRENGTH);
1774                         sprint(self, "^3Strength has worn off\n");
1775                 }
1776         }
1777         else
1778         {
1779                 if (time < self.strength_finished)
1780                 {
1781                         self.items = self.items | IT_STRENGTH;
1782                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1783                 }
1784         }
1785         if (self.items & IT_INVINCIBLE)
1786         {
1787                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1788                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1789                 if (time > self.invincible_finished)
1790                 {
1791                         self.items = self.items - (self.items & IT_INVINCIBLE);
1792                         sprint(self, "^3Shield has worn off\n");
1793                 }
1794         }
1795         else
1796         {
1797                 if (time < self.invincible_finished)
1798                 {
1799                         self.items = self.items | IT_INVINCIBLE;
1800                         sprint(self, "^3Shield surrounds you\n");
1801                 }
1802         }
1803
1804         if (cvar("g_fullbrightplayers"))
1805                 self.effects = self.effects | EF_FULLBRIGHT;
1806
1807         // midair gamemode: damage only while in the air
1808         // if in midair mode, being on ground grants temporary invulnerability
1809         // (this is so that multishot weapon don't clear the ground flag on the
1810         // first damage in the frame, leaving the player vulnerable to the
1811         // remaining hits in the same frame)
1812         if (self.flags & FL_ONGROUND)
1813         if (g_midair)
1814                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1815
1816         if (time >= game_starttime)
1817         if (time < self.spawnshieldtime)
1818                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1819 }
1820
1821 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1822 {
1823         if(current > stable)
1824                 return current;
1825         else if(current > stable - 0.25) // when close enough, "snap"
1826                 return stable;
1827         else
1828                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1829 }
1830
1831 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1832 {
1833         if(current < stable)
1834                 return current;
1835         else if(current < stable + 0.25) // when close enough, "snap"
1836                 return stable;
1837         else
1838                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1839 }
1840
1841 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1842 {
1843         if(current > rotstable)
1844         {
1845                 if(rotframetime > 0)
1846                 {
1847                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1848                         current = max(rotstable, current - rotlinear * rotframetime);
1849                 }
1850         }
1851         else if(current < regenstable)
1852         {
1853                 if(regenframetime > 0)
1854                 {
1855                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1856                         current = min(regenstable, current + regenlinear * regenframetime);
1857                 }
1858         }
1859
1860         if(current > limit)
1861                 current = limit;
1862
1863         return current;
1864 }
1865
1866 void player_regen (void)
1867 {
1868         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1869         maxh = cvar("g_balance_health_rotstable");
1870         maxa = cvar("g_balance_armor_rotstable");
1871         maxf = cvar("g_balance_fuel_rotstable");
1872         minh = cvar("g_balance_health_regenstable");
1873         mina = cvar("g_balance_armor_regenstable");
1874         minf = cvar("g_balance_fuel_regenstable");
1875         limith = cvar("g_balance_health_limit");
1876         limita = cvar("g_balance_armor_limit");
1877         limitf = cvar("g_balance_fuel_limit");
1878
1879         max_mod = regen_mod = rot_mod = limit_mod = 1;
1880
1881         if (self.runes & RUNE_REGEN)
1882         {
1883                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1884                 {
1885                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1886                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1887                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1888                 }
1889                 else
1890                 {
1891                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1892                         max_mod = cvar("g_balance_rune_regen_hpmod");
1893                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1894                 }
1895         }
1896         else if (self.runes & CURSE_VENOM)
1897         {
1898                 max_mod = cvar("g_balance_curse_venom_hpmod");
1899                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1900                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1901                 else
1902                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1903                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1904                 //if (!self.runes & RUNE_REGEN)
1905                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1906         }
1907         maxh = maxh * max_mod;
1908         //maxa = maxa * max_mod;
1909         //maxf = maxf * max_mod;
1910         minh = minh * max_mod;
1911         //mina = mina * max_mod;
1912         //minf = minf * max_mod;
1913         limith = limith * limit_mod;
1914         limita = limita * limit_mod;
1915         //limitf = limitf * limit_mod;
1916
1917         if(g_lms)
1918                 rot_mod = 0;
1919
1920         if (!g_minstagib && (!g_lms || cvar("g_lms_regenerate")))
1921         {
1922                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1923                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1924
1925                 // if player rotted to death...  die!
1926                 if(self.health < 1)
1927                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1928         }
1929
1930         self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1931 }
1932
1933 float zoomstate_set;
1934 void SetZoomState(float z)
1935 {
1936         if(z != self.zoomstate)
1937         {
1938                 self.zoomstate = z;
1939                 ClientData_Touch(self);
1940         }
1941         zoomstate_set = 1;
1942 }
1943
1944 void GetPressedKeys(void) {
1945         if (self.movement_x > 0) // get if movement keys are pressed
1946         {       // forward key pressed
1947                 self.pressedkeys |= KEY_FORWARD;
1948                 self.pressedkeys &~= KEY_BACKWARD;
1949         }
1950         else if (self.movement_x < 0)
1951         {       // backward key pressed
1952                 self.pressedkeys |= KEY_BACKWARD;
1953                 self.pressedkeys &~= KEY_FORWARD;
1954         }
1955         else
1956         {       // no x input
1957                 self.pressedkeys &~= KEY_FORWARD;
1958                 self.pressedkeys &~= KEY_BACKWARD;
1959         }
1960
1961         if (self.movement_y > 0)
1962         {       // right key pressed
1963                 self.pressedkeys |= KEY_RIGHT;
1964                 self.pressedkeys &~= KEY_LEFT;
1965         }
1966         else if (self.movement_y < 0)
1967         {       // left key pressed
1968                 self.pressedkeys |= KEY_LEFT;
1969                 self.pressedkeys &~= KEY_RIGHT;
1970         }
1971         else
1972         {       // no y input
1973                 self.pressedkeys &~= KEY_RIGHT;
1974                 self.pressedkeys &~= KEY_LEFT;
1975         }
1976
1977         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1978                 self.pressedkeys |= KEY_JUMP;
1979         else
1980                 self.pressedkeys &~= KEY_JUMP;
1981         if (self.BUTTON_CROUCH)
1982                 self.pressedkeys |= KEY_CROUCH;
1983         else
1984                 self.pressedkeys &~= KEY_CROUCH;
1985 }
1986
1987 /*
1988 ======================
1989 spectate mode routines
1990 ======================
1991 */
1992 void SpectateCopy(entity spectatee) {
1993         self.armortype = spectatee.armortype;
1994         self.armorvalue = spectatee.armorvalue;
1995         self.ammo_cells = spectatee.ammo_cells;
1996         self.ammo_shells = spectatee.ammo_shells;
1997         self.ammo_nails = spectatee.ammo_nails;
1998         self.ammo_rockets = spectatee.ammo_rockets;
1999         self.ammo_fuel = spectatee.ammo_fuel;
2000         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2001         self.health = spectatee.health;
2002         self.impulse = 0;
2003         self.items = spectatee.items;
2004         self.metertime = spectatee.metertime;
2005         self.strength_finished = spectatee.strength_finished;
2006         self.invincible_finished = spectatee.invincible_finished;
2007         self.pressedkeys = spectatee.pressedkeys;
2008         self.weapons = spectatee.weapons;
2009         self.switchweapon = spectatee.switchweapon;
2010         self.weapon = spectatee.weapon;
2011         self.punchangle = spectatee.punchangle;
2012         self.view_ofs = spectatee.view_ofs;
2013         self.v_angle = spectatee.v_angle;
2014         self.velocity = spectatee.velocity;
2015         self.dmg_take = spectatee.dmg_take;
2016         self.dmg_save = spectatee.dmg_save;
2017         self.dmg_inflictor = spectatee.dmg_inflictor;
2018         self.angles = spectatee.v_angle;
2019         self.fixangle = TRUE;
2020         setorigin(self, spectatee.origin);
2021         setsize(self, spectatee.mins, spectatee.maxs);
2022         SetZoomState(spectatee.zoomstate);
2023 }
2024
2025 float SpectateUpdate() {
2026         if(!self.enemy)
2027                 return 0;
2028
2029         if (self == self.enemy)
2030                 return 0;
2031
2032         if(self.enemy.classname != "player")
2033                 return 0;
2034
2035         SpectateCopy(self.enemy);
2036
2037         return 1;
2038 }
2039
2040 float SpectateNext() {
2041         other = find(self.enemy, classname, "player");
2042         if (!other) {
2043                 other = find(other, classname, "player");
2044         }
2045         if (other) {
2046                 self.enemy = other;
2047         }
2048         if(self.enemy.classname == "player") {
2049                 msg_entity = self;
2050                 WriteByte(MSG_ONE, SVC_SETVIEW);
2051                 WriteEntity(MSG_ONE, self.enemy);
2052                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2053                 self.movetype = MOVETYPE_NONE;
2054                 if(!SpectateUpdate())
2055                         PutObserverInServer();
2056                 return 1;
2057         } else {
2058                 return 0;
2059         }
2060 }
2061
2062 /*
2063 =============
2064 ShowRespawnCountdown()
2065
2066 Update a respawn countdown display.
2067 =============
2068 */
2069 void ShowRespawnCountdown()
2070 {
2071         float number;
2072         if(self.deadflag == DEAD_NO) // just respawned?
2073                 return;
2074         else
2075         {
2076                 number = ceil(self.death_time - time);
2077                 if(number <= 0)
2078                         return;
2079                 if(number <= self.respawn_countdown)
2080                 {
2081                         self.respawn_countdown = number - 1;
2082                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2083                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
2084                 }
2085         }
2086 }
2087
2088 void LeaveSpectatorMode()
2089 {
2090         if(isJoinAllowed()) {
2091                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2092                         self.classname = "player";
2093                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2094                                 JoinBestTeam(self, FALSE, TRUE);
2095                         if(cvar("g_campaign"))
2096                                 campaign_bots_may_start = 1;
2097                         PutClientInServer();
2098                         if(self.classname == "player")
2099                                 bprint ("^4", self.netname, "^4 is playing now\n");
2100                         if(!cvar("g_campaign"))
2101                                 centerprint(self,""); // clear MOTD
2102                         return;
2103                 } else {
2104                         stuffcmd(self,"menu_showteamselect\n");
2105                         return;
2106                 }
2107         }
2108         else {
2109                 //player may not join because of g_maxplayers is set
2110                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2111         }
2112 }
2113
2114 /**
2115  * Determines whether the player is allowed to join. This depends on cvar
2116  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2117  * it checks whether the number of currently playing players exceeds g_maxplayers.
2118  * @return bool TRUE if the player is allowed to join, false otherwise
2119  */
2120 float isJoinAllowed() {
2121         if (!cvar("g_maxplayers"))
2122                 return TRUE;
2123
2124         local entity e;
2125         local float currentlyPlaying;
2126         FOR_EACH_REALPLAYER(e) {
2127                 if(e.classname == "player")
2128                         currentlyPlaying += 1;
2129         }
2130         if(currentlyPlaying < cvar("g_maxplayers"))
2131                 return TRUE;
2132
2133         return FALSE;
2134 }
2135
2136 /**
2137  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2138  * g_maxplayers_spectator_blocktime seconds
2139  */
2140 void checkSpectatorBlock() {
2141         if(self.classname == "spectator" || self.classname == "observer") {
2142                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2143                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2144                         dropclient(self);
2145                 }
2146         }
2147 }
2148
2149 float vercmp_recursive(string v1, string v2)
2150 {
2151         float dot1, dot2;
2152         string s1, s2;
2153         float r;
2154
2155         dot1 = strstrofs(v1, ".", 0);
2156         dot2 = strstrofs(v2, ".", 0);
2157         if(dot1 == -1)
2158                 s1 = v1;
2159         else
2160                 s1 = substring(v1, 0, dot1);
2161         if(dot2 == -1)
2162                 s2 = v2;
2163         else
2164                 s2 = substring(v2, 0, dot2);
2165
2166         r = stof(s1) - stof(s2);
2167         if(r != 0)
2168                 return r;
2169
2170         r = strcasecmp(s1, s2);
2171         if(r != 0)
2172                 return r;
2173
2174         if(dot1 == -1)
2175                 if(dot2 == -1)
2176                         return 0;
2177                 else
2178                         return -1;
2179         else
2180                 if(dot2 == -1)
2181                         return 1;
2182                 else
2183                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2184 }
2185
2186 float vercmp(string v1, string v2)
2187 {
2188         if(strcasecmp(v1, v2) == 0) // early out check
2189                 return 0;
2190         return vercmp_recursive(v1, v2);
2191 }
2192
2193 void ObserverThink()
2194 {
2195         if (self.flags & FL_JUMPRELEASED) {
2196                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2197                         self.welcomemessage_time = 0;
2198                         self.flags &~= FL_JUMPRELEASED;
2199                         self.flags |= FL_SPAWNING;
2200                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2201                         self.welcomemessage_time = 0;
2202                         self.flags &~= FL_JUMPRELEASED;
2203                         if(SpectateNext() == 1) {
2204                                 self.classname = "spectator";
2205                         }
2206                 }
2207         } else {
2208                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2209                         self.flags |= FL_JUMPRELEASED;
2210                         if(self.flags & FL_SPAWNING)
2211                         {
2212                                 self.flags &~= FL_SPAWNING;
2213                                 LeaveSpectatorMode();
2214                                 return;
2215                         }
2216                 }
2217         }
2218         PrintWelcomeMessage(self);
2219 }
2220
2221 void SpectatorThink()
2222 {
2223         if (self.flags & FL_JUMPRELEASED) {
2224                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2225                         self.welcomemessage_time = 0;
2226                         self.flags &~= FL_JUMPRELEASED;
2227                         self.flags |= FL_SPAWNING;
2228                 } else if(self.BUTTON_ATCK) {
2229                         self.welcomemessage_time = 0;
2230                         self.flags &~= FL_JUMPRELEASED;
2231                         if(SpectateNext() == 1) {
2232                                 self.classname = "spectator";
2233                         } else {
2234                                 self.classname = "observer";
2235                                 PutClientInServer();
2236                         }
2237                 } else if (self.BUTTON_ATCK2) {
2238                         self.welcomemessage_time = 0;
2239                         self.flags &~= FL_JUMPRELEASED;
2240                         self.classname = "observer";
2241                         PutClientInServer();
2242                 } else {
2243                         if(!SpectateUpdate())
2244                                 PutObserverInServer();
2245                 }
2246         } else {
2247                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2248                         self.flags |= FL_JUMPRELEASED;
2249                         if(self.flags & FL_SPAWNING)
2250                         {
2251                                 self.flags &~= FL_SPAWNING;
2252                                 LeaveSpectatorMode();
2253                                 return;
2254                         }
2255                 }
2256         }
2257         PrintWelcomeMessage(self);
2258         self.flags |= FL_CLIENT | FL_NOTARGET;
2259 }
2260
2261 .float touchexplode_time;
2262
2263 /*
2264 =============
2265 PlayerPreThink
2266
2267 Called every frame for each client before the physics are run
2268 =============
2269 */
2270 void() ctf_setstatus;
2271 void() nexball_setstatus;
2272 .float items_added;
2273 void PlayerPreThink (void)
2274 {
2275         self.stat_game_starttime = game_starttime;
2276         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2277         self.stat_leadlimit = cvar("leadlimit");
2278
2279         if(blockSpectators && frametime)
2280                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2281                 checkSpectatorBlock();
2282
2283         zoomstate_set = 0;
2284
2285         if(self.netname_previous != self.netname)
2286         {
2287                 if(cvar("sv_eventlog"))
2288                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2289                 if(self.netname_previous)
2290                         strunzone(self.netname_previous);
2291                 self.netname_previous = strzone(self.netname);
2292         }
2293
2294         // version nagging
2295         if(self.version_nagtime)
2296                 if(self.cvar_g_nexuizversion)
2297                         if(time > self.version_nagtime)
2298                         {
2299                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2300                                 {
2301                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2302                                         {
2303                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2304                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2305                                         }
2306                                         else
2307                                         {
2308                                                 float r;
2309                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2310                                                 if(r < 0)
2311                                                 {
2312                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2313                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2314                                                 }
2315                                                 else if(r > 0)
2316                                                 {
2317                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2318                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2319                                                 }
2320                                         }
2321                                 }
2322                                 self.version_nagtime = 0;
2323                         }
2324
2325         // GOD MODE info
2326         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2327         {
2328                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2329                 self.max_armorvalue = 0;
2330         }
2331
2332 #ifdef TETRIS
2333         if (TetrisPreFrame())
2334                 return;
2335 #endif
2336
2337         if(frametime)
2338                 antilag_record(self);
2339
2340         if(self.classname == "player") {
2341 //              if(self.netname == "Wazat")
2342 //                      bprint(self.classname, "\n");
2343
2344                 CheckRules_Player();
2345
2346                 PrintWelcomeMessage(self);
2347
2348                 if (intermission_running)
2349                 {
2350                         IntermissionThink ();   // otherwise a button could be missed between
2351                         return;                                 // the think tics
2352                 }
2353
2354                 if(self.teleport_time)
2355                 if(time > self.teleport_time)
2356                 {
2357                         self.teleport_time = 0;
2358                         self.effects = self.effects - (self.effects & EF_NODRAW);
2359                 }
2360
2361                 Nixnex_GiveCurrentWeapon();
2362
2363                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2364                         UpdateSelectedPlayer();
2365
2366                 //don't allow the player to turn around while game is paused!
2367                 if(timeoutStatus == 2) {
2368                         self.v_angle = self.lastV_angle;
2369                         self.angles = self.lastV_angle;
2370                         self.fixangle = TRUE;
2371                 }
2372
2373                 if(frametime)
2374                         player_powerups();
2375
2376                 if (self.deadflag != DEAD_NO)
2377                 {
2378                         float button_pressed, force_respawn;
2379                         if(frametime)
2380                                 player_anim();
2381                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2382                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2383                         if (self.deadflag == DEAD_DYING)
2384                         {
2385                                 if(force_respawn)
2386                                         self.deadflag = DEAD_RESPAWNING;
2387                                 else if(!button_pressed)
2388                                         self.deadflag = DEAD_DEAD;
2389                         }
2390                         else if (self.deadflag == DEAD_DEAD)
2391                         {
2392                                 if(button_pressed)
2393                                         self.deadflag = DEAD_RESPAWNABLE;
2394                         }
2395                         else if (self.deadflag == DEAD_RESPAWNABLE)
2396                         {
2397                                 if(!button_pressed)
2398                                         self.deadflag = DEAD_RESPAWNING;
2399                         }
2400                         else if (self.deadflag == DEAD_RESPAWNING)
2401                         {
2402                                 if(time > self.death_time)
2403                                 {
2404                                         self.death_time = time + 1; // only retry once a second
2405                                         respawn();
2406                                 }
2407                         }
2408                         ShowRespawnCountdown();
2409                         return;
2410                 }
2411
2412                 if(g_touchexplode)
2413                 if(time > self.touchexplode_time)
2414                 if(self.classname == "player")
2415                 if(self.deadflag == DEAD_NO)
2416                 if not(IS_INDEPENDENT_PLAYER(self))
2417                 FOR_EACH_PLAYER(other) if(self != other)
2418                 {
2419                         if(time > other.touchexplode_time)
2420                         if(other.classname == "player")
2421                         if(other.deadflag == DEAD_NO)
2422                         if not(IS_INDEPENDENT_PLAYER(other))
2423                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2424                         {
2425                                 PlayerTouchExplode(self, other);
2426                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2427                         }
2428                 }
2429
2430                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2431                 {
2432                         vector dist;
2433
2434                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2435                         dist = self.prevorigin - self.origin;
2436                         dist_z = 0;
2437                         self.lms_traveled_distance += fabs(vlen(dist));
2438
2439                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2440                         {
2441                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2442                                 self.lms_traveled_distance = 0;
2443                         }
2444
2445                         if(time > self.lms_nextcheck)
2446                         {
2447                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2448                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2449                                 {
2450                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2451                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2452                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2453                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2454                                 }
2455                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2456                                 self.lms_traveled_distance = 0;
2457                         }
2458                 }
2459
2460                 self.prevorigin = self.origin;
2461
2462                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2463                 {
2464                         if (!self.crouch)
2465                         {
2466                                 self.crouch = TRUE;
2467                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2468                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2469                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2470                         }
2471                 }
2472                 else
2473                 {
2474                         if (self.crouch)
2475                         {
2476                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2477                                 if (!trace_startsolid)
2478                                 {
2479                                         self.crouch = FALSE;
2480                                         self.view_ofs = PL_VIEW_OFS;
2481                                         setsize (self, PL_MIN, PL_MAX);
2482                                 }
2483                         }
2484                 }
2485
2486                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2487                 {
2488                         if(self.bloodloss_timer < time)
2489                         {
2490                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2491                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2492                         }
2493                 }
2494
2495                 FixPlayermodel();
2496
2497                 GrapplingHookFrame();
2498
2499                 if(frametime)
2500                 {
2501                         self.items &~= self.items_added;
2502
2503                         W_WeaponFrame();
2504
2505                         self.items_added = 0;
2506                         if(self.items & IT_JETPACK)
2507                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2508                                         self.items_added |= IT_FUEL;
2509
2510                         self.items |= self.items_added;
2511                 }
2512
2513                 player_regen();
2514                 if(frametime)
2515                         player_anim();
2516
2517                 if (g_minstagib)
2518                         minstagib_ammocheck();
2519
2520                 ctf_setstatus();
2521                 kh_setstatus();
2522                 nexball_setstatus();
2523
2524                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2525
2526                 //self.angles_y=self.v_angle_y + 90;   // temp
2527         } else if(gameover) {
2528                 if (intermission_running)
2529                         IntermissionThink ();   // otherwise a button could be missed between
2530                 return;
2531         } else if(self.classname == "observer") {
2532                 ObserverThink();
2533         } else if(self.classname == "spectator") {
2534                 SpectatorThink();
2535         }
2536
2537         if(!zoomstate_set)
2538                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2539
2540         float oldspectatee_status;
2541         oldspectatee_status = self.spectatee_status;
2542         if(self.classname == "spectator")
2543                 self.spectatee_status = num_for_edict(self.enemy);
2544         else if(self.classname == "observer")
2545                 self.spectatee_status = num_for_edict(self);
2546         else
2547                 self.spectatee_status = 0;
2548         if(self.spectatee_status != oldspectatee_status)
2549         {
2550                 ClientData_Touch(self);
2551                 if(g_race || g_cts)
2552                         race_InitSpectator();
2553         }
2554
2555         if(self.teamkill_soundtime)
2556         if(time > self.teamkill_soundtime)
2557         {
2558                 self.teamkill_soundtime = 0;
2559
2560                 entity oldpusher, oldself;
2561
2562                 oldself = self; self = self.teamkill_soundsource;
2563                 oldpusher = self.pusher; self.pusher = oldself;
2564
2565                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2566
2567                 self.pusher = oldpusher;
2568                 self = oldself;
2569         }
2570
2571         if(self.taunt_soundtime)
2572         if(time > self.taunt_soundtime)
2573         {
2574                 self.taunt_soundtime = 0;
2575                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2576         }
2577
2578         target_voicescript_next(self);
2579 }
2580
2581 // on dragger:
2582 .entity dragentity;
2583 .float draggravity;
2584 .float dragspeed; // speed of mouse wheel action
2585 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2586 .vector draglocalvector; // local attachment vector of the dragentity
2587 .float draglocalangle;
2588 // on draggee:
2589 .entity draggedby;
2590 .float dragmovetype;
2591 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2592 {
2593         float tagscale;
2594
2595         draggee.dragmovetype = draggee.movetype;
2596         draggee.draggravity = draggee.gravity;
2597         draggee.movetype = MOVETYPE_WALK;
2598         draggee.gravity = 0.00001;
2599         draggee.flags &~= FL_ONGROUND;
2600         draggee.draggedby = dragger;
2601
2602         dragger.dragentity = draggee;
2603
2604         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2605         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2606         touchpoint = touchpoint - gettaginfo(draggee, 0);
2607         tagscale = pow(vlen(v_forward), -2);
2608         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2609         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2610         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2611
2612         dragger.dragspeed = 64;
2613 }
2614
2615 void Drag_Finish(entity dragger)
2616 {
2617         entity draggee;
2618         draggee = dragger.dragentity;
2619         if(dragger)
2620                 dragger.dragentity = world;
2621         draggee.draggedby = world;
2622         draggee.movetype = draggee.dragmovetype;
2623         draggee.gravity = draggee.draggravity;
2624
2625         switch(draggee.movetype)
2626         {
2627                 case MOVETYPE_TOSS:
2628                 case MOVETYPE_WALK:
2629                 case MOVETYPE_STEP:
2630                 case MOVETYPE_FLYMISSILE:
2631                 case MOVETYPE_BOUNCE:
2632                 case MOVETYPE_BOUNCEMISSILE:
2633                         break;
2634                 default:
2635                         draggee.velocity = '0 0 0';
2636                         break;
2637         }
2638
2639         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2640         {
2641                 draggee.velocity = '0 0 0';
2642                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2643         }
2644 }
2645
2646 float Drag_IsDraggable(entity draggee)
2647 {
2648         // TODO add more checks for bad stuff here
2649         if(draggee.classname == "func_bobbing")
2650                 return FALSE;
2651         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2652                 return FALSE;
2653         if(draggee.classname == "plat")
2654                 return FALSE;
2655         if(draggee.classname == "func_button")
2656                 return FALSE;
2657         if(draggee.model == "")
2658                 return FALSE;
2659         if(draggee.classname == "spectator")
2660                 return FALSE;
2661         if(draggee.classname == "observer")
2662                 return FALSE;
2663         if(draggee.classname == "exteriorweaponentity")
2664                 return FALSE;
2665
2666         return TRUE;
2667 }
2668
2669 float Drag_MayChangeAngles(entity draggee)
2670 {
2671         // TODO add more checks for bad stuff here
2672         if(substring(draggee.model, 0, 1) == "*")
2673                 return FALSE;
2674         return TRUE;
2675 }
2676
2677 void Drag_MoveForward(entity dragger)
2678 {
2679         dragger.dragdistance += dragger.dragspeed;
2680 }
2681
2682 void Drag_SetSpeed(entity dragger, float s)
2683 {
2684         dragger.dragspeed = pow(2, s);
2685 }
2686
2687 void Drag_MoveBackward(entity dragger)
2688 {
2689         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2690 }
2691
2692 void Drag_Update(entity dragger)
2693 {
2694         vector curorigin, neworigin, goodvelocity;
2695         float f;
2696         entity draggee;
2697
2698         draggee = dragger.dragentity;
2699         draggee.flags &~= FL_ONGROUND;
2700
2701         curorigin = gettaginfo(draggee, 0);
2702         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2703         makevectors(dragger.v_angle);
2704         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2705         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2706
2707         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2708                 dragger.draglocalangle += 360;
2709         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2710                 dragger.draglocalangle -= 360;
2711
2712         f = min(frametime * 10, 1);
2713         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2714
2715         if(Drag_MayChangeAngles(draggee))
2716                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2717
2718         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2719
2720         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2721 }
2722
2723 float Drag_CanDrag(entity dragger)
2724 {
2725         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2726 }
2727
2728 float Drag_IsDragging(entity dragger)
2729 {
2730         if(!dragger.dragentity)
2731                 return FALSE;
2732         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2733         {
2734                 dragger.dragentity = world;
2735                 return FALSE;
2736         }
2737         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2738         {
2739                 Drag_Finish(dragger);
2740                 return FALSE;
2741         }
2742         return TRUE;
2743 }
2744
2745 void Drag_MoveDrag(entity from, entity to)
2746 {
2747         if(from.draggedby)
2748         {
2749                 to.draggedby = from.draggedby;
2750                 to.draggedby.dragentity = to;
2751                 from.draggedby = world;
2752         }
2753 }
2754
2755 /*
2756 =============
2757 PlayerPostThink
2758
2759 Called every frame for each client after the physics are run
2760 =============
2761 */
2762 .float idlekick_lasttimeleft;
2763 void PlayerPostThink (void)
2764 {
2765         // Savage: Check for nameless players
2766         if (strlen(self.netname) < 1) {
2767                 self.netname = "Player";
2768                 stuffcmd(self, "seta _cl_name Player\n");
2769         }
2770
2771         if(sv_maxidle && frametime)
2772         {
2773                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2774                 float timeleft;
2775                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2776                 if(timeleft <= 0)
2777                 {
2778                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2779                         announce(self, "announcer/robotic/terminated.wav");
2780                         dropclient(self);
2781                         return;
2782                 }
2783                 else if(timeleft <= 10)
2784                 {
2785                         if(timeleft != self.idlekick_lasttimeleft)
2786                         {
2787                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2788                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2789                         }
2790                 }
2791                 else
2792                 {
2793                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2794                 }
2795                 self.idlekick_lasttimeleft = timeleft;
2796         }
2797
2798 #ifdef TETRIS
2799         if(self.impulse == 100)
2800                 ImpulseCommands();
2801         if (TetrisPostFrame())
2802                 return;
2803 #endif
2804
2805         if(sv_cheats || self.maycheat)
2806                 if(Drag_CanDrag(self))
2807                         if(self.BUTTON_DRAG)
2808                                 if(!self.dragentity)
2809                                         if(self.cursor_trace_ent)
2810                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2811                                                 {
2812                                                         if(self.cursor_trace_ent.draggedby)
2813                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2814                                                         if(self.cursor_trace_ent.tag_entity)
2815                                                                 detach_sameorigin(self.cursor_trace_ent);
2816                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2817                                                 }
2818
2819         if(Drag_IsDragging(self))
2820         {
2821                 if(self.BUTTON_DRAG)
2822                 {
2823                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2824                         {
2825                                 Drag_MoveForward(self);
2826                                 self.impulse = 0;
2827                         }
2828                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2829                         {
2830                                 Drag_MoveBackward(self);
2831                                 self.impulse = 0;
2832                         }
2833                         else if(self.impulse >= 1 && self.impulse <= 9)
2834                         {
2835                                 Drag_SetSpeed(self, self.impulse - 1);
2836                         }
2837                         else if(self.impulse == 14)
2838                         {
2839                                 Drag_SetSpeed(self, 9);
2840                         }
2841
2842                         if(frametime)
2843                                 Drag_Update(self);
2844                 }
2845                 else
2846                 {
2847                         Drag_Finish(self);
2848                 }
2849         }
2850
2851         if(self.classname == "player") {
2852                 CheckRules_Player();
2853                 UpdateChatBubble();
2854                 UpdateTeamBubble();
2855                 if (self.impulse)
2856                         ImpulseCommands();
2857                 if (intermission_running)
2858                         return;         // intermission or finale
2859
2860                 GetPressedKeys();
2861         } else if (self.classname == "observer") {
2862                 //do nothing
2863         } else if (self.classname == "spectator") {
2864                 //do nothing
2865         }
2866
2867         /*
2868         float i;
2869         for(i = 0; i < 1000; ++i)
2870         {
2871                 vector end;
2872                 end = self.origin + '0 0 1024' + 512 * randomvec();
2873                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2874                 if(trace_fraction < 1)
2875                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2876                 {
2877                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2878                         break;
2879                 }
2880         }
2881         */
2882
2883         Arena_Warmup();
2884
2885         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2886
2887         if(self.waypointsprite_attachedforcarrier)
2888                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2889 }