data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         info_player_deathmatch();
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8         self.classname = "info_player_deathmatch";
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27
  28                 local float spotactive;
  29                 spotactive = 1;
  30
  31                 // filter out spots for assault
  32                 if(spot.target != "") {
  33                         local entity ent;
  34                         ent = find(world, targetname, spot.target);
  35                         while(ent) {
  36                                 if(ent.classname == "target_objective")
  37                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  38                                                 spotactive = 0;
  39                                 ent = find(ent, targetname, spot.target);
  40                         }
  41                 }
  42
  43                 if (spot.team == teamcheck && spotactive > 0)
  44                 {
  45                         pcount = 0;
  46                         player = playerlist;
  47                         while (player)
  48                         {
  49                                 if (player != self)
  50                                 if (vlen(player.origin - spot.origin) < mindist)
  51                                         pcount = pcount + 1;
  52                                 player = player.chain;
  53                         }
  54                         if (!pcount)
  55                         {
  56                                 spawn_allbad = FALSE;
  57                                 if (newfirstspot)
  58                                         previousspot.chain = spot;
  59                                 else
  60                                         newfirstspot = spot;
  61                                 previousspot = spot;
  62                                 spot.chain = world;
  63                         }
  64                         else
  65                                 spawn_allgood = FALSE;
  66                 }
  67                 spot = nextspot;
  68         }
  69         // if we couldn't find ANY good points, return the original list
  70         if (!newfirstspot)
  71                 newfirstspot = firstspot;
  72         return newfirstspot;
  73 }
  74
  75 entity Spawn_RandomPoint(entity firstspot)
  76 {
  77         local entity spot;
  78         local float numspots;
  79         // count number of spots
  80         numspots = 0;
  81         spot = firstspot;
  82         while (spot)
  83         {
  84                 numspots = numspots + 1;
  85                 spot = spot.chain;
  86         }
  87         // pick a random one
  88         numspots = numspots * random();
  89         spot = firstspot;
  90         while (spot.chain && numspots >= 1)
  91         {
  92                 numspots = numspots - 1;
  93                 spot = spot.chain;
  94         }
  95         return spot;
  96 }
  97
  98 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  99 {
 100         local entity best, spot, player;
 101         local float bestrating, rating;
 102         best = world;
 103         bestrating = -1000000;
 104         spot = firstspot;
 105         while (spot)
 106         {
 107                 rating = 1000000000;
 108                 player = playerlist;
 109                 while (player)
 110                 {
 111                         if (player != self)
 112                                 rating = min(rating, vlen(player.origin - spot.origin));
 113                         player = player.chain;
 114                 }
 115                 rating = rating + random() * 16;
 116                 if (bestrating < rating)
 117                 {
 118                         best = spot;
 119                         bestrating = rating;
 120                 }
 121                 spot = spot.chain;
 122         }
 123         return best;
 124 }
 125
 126 /*
 127 =============
 128 SelectSpawnPoint
 129
 130 Finds a point to respawn
 131 =============
 132 */
 133 entity SelectSpawnPoint (float anypoint)
 134 {
 135         local float teamcheck;
 136         local entity spot, firstspot, playerlist;
 137
 138         spot = find (world, classname, "testplayerstart");
 139         if (spot)
 140                 return spot;
 141
 142         teamcheck = 0;
 143
 144         if((!anypoint && cvar("g_ctf")) || cvar("g_assault") )
 145                 teamcheck = self.team;
 146
 147         // get the list of players
 148         playerlist = findchain(classname, "player");
 149         // get the entire list of spots
 150         firstspot = findchain(classname, "info_player_deathmatch");
 151         // filter out the bad ones
 152         // (note this returns the original list if none survived)
 153         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 154
 155         // there is 50/50 chance of choosing a random spot or the furthest spot
 156         // (this means that roughly every other spawn will be furthest, so you
 157         // usually won't get fragged at spawn twice in a row)
 158         if (arena_roundbased)
 159         {
 160                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 161                 spot = Spawn_RandomPoint(firstspot);
 162         }
 163         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 164                 spot = Spawn_RandomPoint(firstspot);
 165         else
 166                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 167
 168         if (!spot)
 169         {
 170                 if(cvar("spawn_debug"))
 171                         GotoNextMap();
 172                 else
 173                         error ("PutClientInServer: no start points on level");
 174         }
 175
 176         return spot;
 177 }
 178
 179 /*
 180 =============
 181 CheckPlayerModel
 182
 183 Checks if the argument string can be a valid playermodel.
 184 Returns a valid one in doubt.
 185 =============
 186 */
 187 string FallbackPlayerModel = "models/player/marine.zym";
 188 string CheckPlayerModel(string plyermodel) {
 189         if(strlen(plyermodel) < 4)
 190                 return FallbackPlayerModel;
 191         if( substring(plyermodel,0,14) != "models/player/")
 192                 return FallbackPlayerModel;
 193         else if(cvar("sv_servermodelsonly"))
 194         {
 195                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 196                         return FallbackPlayerModel;
 197                 if(!fexists(plyermodel))
 198                         return FallbackPlayerModel;
 199         }
 200         return plyermodel;
 201 }
 202
 203 /*
 204 =============
 205 Client_customizeentityforclient
 206
 207 LOD reduction
 208 =============
 209 */
 210 float Client_customizeentityforclient()
 211 {
 212 #ifdef ALLOW_VARIABLE_LOD
 213         // self: me
 214         // other: the player viewing me
 215         float distance;
 216         float f;
 217
 218         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 219                 return TRUE;
 220
 221         if(other.cvar_cl_playerdetailreduction <= 0)
 222         {
 223                 if(other.cvar_cl_playerdetailreduction <= -2)
 224                         self.modelindex = self.modelindex_lod2;
 225                 else if(other.cvar_cl_playerdetailreduction <= -1)
 226                         self.modelindex = self.modelindex_lod1;
 227                 else
 228                         self.modelindex = self.modelindex_lod0;
 229         }
 230         else
 231         {
 232                 distance = vlen(self.origin - other.origin);
 233                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 234                 if(f > 10000)
 235                         self.modelindex = self.modelindex_lod2;
 236                 else if(f > 5000)
 237                         self.modelindex = self.modelindex_lod1;
 238                 else
 239                         self.modelindex = self.modelindex_lod0;
 240         }
 241 #endif
 242
 243         return TRUE;
 244 }
 245
 246 void setmodel_lod(entity e, string modelname)
 247 {
 248 #ifdef ALLOW_VARIABLE_LOD
 249         string s;
 250
 251         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 252         if(fexists(s))
 253         {
 254                 precache_model(s);
 255                 setmodel(e, s); // players have high precision
 256                 self.modelindex_lod1 = self.modelindex;
 257         }
 258         else
 259                 self.modelindex_lod1 = -1;
 260
 261         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 262         if(fexists(s))
 263         {
 264                 precache_model(s);
 265                 setmodel(e, s); // players have high precision
 266                 self.modelindex_lod2 = self.modelindex;
 267         }
 268         else
 269                 self.modelindex_lod2 = -1;
 270
 271         precache_model(modelname);
 272         setmodel(e, modelname); // players have high precision
 273         self.modelindex_lod0 = self.modelindex;
 274
 275         if(self.modelindex_lod1 < 0)
 276                 self.modelindex_lod1 = self.modelindex;
 277
 278         if(self.modelindex_lod2 < 0)
 279                 self.modelindex_lod2 = self.modelindex;
 280 #else
 281         precache_model(modelname);
 282         setmodel(e, modelname); // players have high precision
 283 #endif
 284 }
 285
 286 /*
 287 =============
 288 PutObserverInServer
 289
 290 putting a client as observer in the server
 291 =============
 292 */
 293 void PutObserverInServer (void)
 294 {
 295         entity  spot;
 296         spot = SelectSpawnPoint (FALSE);
 297         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 298
 299         if(clienttype(self) == CLIENTTYPE_REAL)
 300         {
 301                 msg_entity = self;
 302                 WriteByte(MSG_ONE, SVC_SETVIEW);
 303                 WriteEntity(MSG_ONE, self);
 304         }
 305
 306         DropAllRunes(self);
 307         kh_Key_DropAll(self, TRUE);
 308
 309         if(self.flagcarried)
 310                 DropFlag(self.flagcarried);
 311
 312         WaypointSprite_PlayerDead();
 313
 314         DistributeFragsAmongTeam(self, self.team, 1);
 315
 316         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 317                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 318         else if(self.killcount != -666)
 319                 bprint ("^4", self.netname, "^4 is spectating now\n");
 320
 321         self.classname = "observer";
 322         self.health = -666;
 323         self.takedamage = DAMAGE_NO;
 324         self.solid = SOLID_NOT;
 325         self.movetype = MOVETYPE_NOCLIP;
 326         self.flags = FL_CLIENT | FL_NOTARGET;
 327         self.armorvalue = 666;
 328         self.effects = 0;
 329         self.armorvalue = cvar("g_balance_armor_start");
 330         self.pauserotarmor_finished = 0;
 331         self.pauserothealth_finished = 0;
 332         self.pauseregen_finished = 0;
 333         self.damageforcescale = 0;
 334         self.death_time = 0;
 335         self.dead_time = 0;
 336         self.dead_frame = 0;
 337         self.die_frame = 0;
 338         self.deaths = 0;
 339         self.alpha = 0;
 340         self.scale = 0;
 341         self.fade_time = 0;
 342         self.pain_frame = 0;
 343         self.pain_finished = 0;
 344         self.strength_finished = 0;
 345         self.invincible_finished = 0;
 346         self.pushltime = 0;
 347         self.think = SUB_Null;
 348         self.nextthink = 0;
 349         self.hook_time = 0;
 350         self.runes = 0;
 351         self.deadflag = DEAD_NO;
 352         self.angles = spot.angles;
 353         self.angles_z = 0;
 354         self.fixangle = TRUE;
 355         self.crouch = FALSE;
 356
 357         self.view_ofs = PL_VIEW_OFS;
 358         setorigin (self, spot.origin);
 359         setsize (self, '0 0 0', '0 0 0');
 360         self.oldorigin = self.origin;
 361         self.items = 0;
 362         self.model = "";
 363         self.modelindex = 0;
 364         self.weapon = 0;
 365         self.weaponmodel = "";
 366         self.weaponentity = world;
 367         self.killcount = -666;
 368         self.velocity = '0 0 0';
 369         self.avelocity = '0 0 0';
 370         self.punchangle = '0 0 0';
 371         self.punchvector = '0 0 0';
 372         self.oldvelocity = self.velocity;
 373         self.customizeentityforclient = Client_customizeentityforclient;
 374
 375         if(cvar("g_arena"))
 376         {
 377                 if(self.frags != -2)
 378                 {
 379                         Spawnqueue_Insert(self);
 380                 }
 381                 else
 382                 {
 383                         Spawnqueue_Unmark(self);
 384                         Spawnqueue_Remove(self);
 385                 }
 386         }
 387         else if(!cvar("g_lms"))
 388                 self.frags = -666;
 389 }
 390
 391
 392 /*
 393 =============
 394 PutClientInServer
 395
 396 Called when a client spawns in the server
 397 =============
 398 */
 399 void PutClientInServer (void)
 400 {
 401         if(clienttype(self) == CLIENTTYPE_BOT)
 402         {
 403                 self.classname = "player";
 404         }
 405         else if(clienttype(self) == CLIENTTYPE_REAL)
 406         {
 407                 msg_entity = self;
 408                 WriteByte(MSG_ONE, SVC_SETVIEW);
 409                 WriteEntity(MSG_ONE, self);
 410         }
 411
 412         // player is dead and becomes observer
 413         if(cvar("g_lms") && self.frags < 1)
 414                 self.classname = "observer";
 415
 416         if(cvar("g_arena"))
 417         if(!self.spawned)
 418                 self.classname = "observer";
 419
 420         if(self.classname == "player") {
 421                 entity  spot;
 422
 423                 spot = SelectSpawnPoint (FALSE);
 424
 425                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 426
 427                 self.classname = "player";
 428                 self.iscreature = TRUE;
 429                 self.movetype = MOVETYPE_WALK;
 430                 self.solid = SOLID_SLIDEBOX;
 431                 self.flags = FL_CLIENT;
 432                 self.takedamage = DAMAGE_AIM;
 433                 self.effects = 0;
 434                 self.air_finished = time + 12;
 435                 self.dmg = 2;
 436
 437                 self.ammo_shells = start_ammo_shells;
 438                 self.ammo_nails = start_ammo_nails;
 439                 self.ammo_rockets = start_ammo_rockets;
 440                 self.ammo_cells = start_ammo_cells;
 441                 self.health = start_health;
 442                 self.armorvalue = start_armorvalue;
 443                 self.items = start_items;
 444                 self.switchweapon = start_switchweapon;
 445                 self.weapon = 0;
 446                 self.jump_interval = time;
 447
 448                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 449                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 450                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 451                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 452                 self.damageforcescale = 2;
 453                 self.death_time = 0;
 454                 self.dead_time = 0;
 455                 self.dead_frame = 0;
 456                 self.die_frame = 0;
 457                 self.alpha = 0;
 458                 self.scale = 0;
 459                 self.fade_time = 0;
 460                 self.pain_frame = 0;
 461                 self.pain_finished = 0;
 462                 self.strength_finished = 0;
 463                 self.invincible_finished = 0;
 464                 self.pushltime = 0;
 465                 //self.speed_finished = 0;
 466                 //self.slowmo_finished = 0;
 467                 // players have no think function
 468                 self.think = SUB_Null;
 469                 self.nextthink = 0;
 470                 self.hook_time = 0;
 471
 472                 self.runes = 0;
 473
 474                 self.deadflag = DEAD_NO;
 475
 476                 self.angles = spot.angles;
 477
 478                 self.angles_z = 0; // never spawn tilted even if the spot says to
 479                 self.fixangle = TRUE; // turn this way immediately
 480                 self.velocity = '0 0 0';
 481                 self.avelocity = '0 0 0';
 482                 self.punchangle = '0 0 0';
 483                 self.punchvector = '0 0 0';
 484                 self.oldvelocity = self.velocity;
 485
 486                 self.viewzoom = 0.6;
 487                 self.has_zoomed = 0;
 488
 489                 self.customizeentityforclient = Client_customizeentityforclient;
 490
 491                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 492                         local string defaultmodel;
 493                         defaultmodel = cvar_string("sv_defaultplayermodel");
 494                         setmodel_lod (self, defaultmodel);
 495                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 496                 } else {
 497                         self.playermodel = CheckPlayerModel(self.playermodel);
 498                         setmodel_lod (self, self.playermodel);
 499                         if(teams_matter)
 500                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 501                         else
 502                                 self.skin = stof(self.playerskin);
 503                 }
 504
 505                 self.crouch = FALSE;
 506                 self.view_ofs = PL_VIEW_OFS;
 507                 setsize (self, PL_MIN, PL_MAX);
 508                 self.spawnorigin = spot.origin;
 509                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 510                 // don't reset back to last position, even if new position is stuck in solid
 511                 self.oldorigin = self.origin;
 512
 513                 if(cvar("g_arena"))
 514                 {
 515                         Spawnqueue_Remove(self);
 516                         Spawnqueue_Mark(self);
 517                 }
 518
 519                 self.event_damage = PlayerDamage;
 520
 521                 self.bot_attack = TRUE;
 522
 523                 self.statdraintime = time + 5;
 524                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 525
 526                 if(self.killcount == -666) {
 527                         self.killcount = 0;
 528                         if(!cvar("g_arena"))
 529                         if(!cvar("g_lms"))
 530                                 self.frags = 0;
 531                 }
 532
 533                 self.cnt = WEP_LASER;
 534                 self.nixnex_lastchange_id = -1;
 535
 536                 CL_SpawnWeaponentity();
 537                 self.alpha = default_player_alpha;
 538                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 539
 540                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 541                 self.lms_traveled_distance = 0;
 542
 543                 if(cvar("spawn_debug"))
 544                 {
 545                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 546                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 547                 }
 548
 549                 //stuffcmd(self, "chase_active 0");
 550                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 551
 552                 if (cvar("g_spawnsound"))
 553                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 554
 555                 if(cvar("g_assault")) {
 556                         if(self.team == assault_attacker_team)
 557                                 centerprint(self, "You are attacking!\n");
 558                         else
 559                                 centerprint(self, "You are defending!\n");
 560                 }
 561
 562         } else if(self.classname == "observer") {
 563                 PutObserverInServer ();
 564         }
 565 }
 566
 567 /*
 568 =============
 569 SetNewParms
 570 =============
 571 */
 572 void SetNewParms (void)
 573 {
 574
 575 }
 576
 577 /*
 578 =============
 579 SetChangeParms
 580 =============
 581 */
 582 void SetChangeParms (void)
 583 {
 584
 585 }
 586
 587 /*
 588 =============
 589 ClientKill
 590
 591 Called when a client types 'kill' in the console
 592 =============
 593 */
 594 void ClientKill (void)
 595 {
 596         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 597 }
 598
 599 void FixClientCvars(entity e)
 600 {
 601         // send prediction settings to the client
 602         stuffcmd(e, "\nin_bindmap 0 0\n");
 603         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 604         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 605         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 606         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 607         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 608         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 609         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 610         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 611         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 612         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 613         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 614         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 615         stuffcmd(e, "cl_movement_edgefriction 1\n");
 616 }
 617
 618 /*
 619 =============
 620 ClientConnect
 621
 622 Called when a client connects to the server
 623 =============
 624 */
 625 string ColoredTeamName(float t);
 626 //void dom_player_join_team(entity pl);
 627 void ClientConnect (void)
 628 {
 629         if(Ban_IsClientBanned(self))
 630         {
 631                 dropclient(self);
 632                 bprint("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 633                 return;
 634         }
 635
 636         local string s;
 637
 638         self.classname = "player_joining";
 639         self.flags = self.flags | FL_CLIENT;
 640         self.version_nagtime = time + 10 + random() * 10;
 641
 642         if(player_count<0)
 643         {
 644                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 645                 player_count = 0;
 646         }
 647
 648         bot_clientconnect();
 649
 650         //if(cvar("g_domination"))
 651         //      dom_player_join_team(self);
 652
 653         //JoinBestTeam(self, FALSE);
 654
 655         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 656                 self.classname = "observer";
 657         } else {
 658                 self.classname = "player";
 659                 campaign_bots_may_start = 1;
 660         }
 661
 662         self.playerid = (playerid_last = playerid_last + 1);
 663         if(cvar("sv_eventlog"))
 664         {
 665                 if(clienttype(self) == CLIENTTYPE_REAL)
 666                         s = "player";
 667                 else
 668                         s = "bot";
 669                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 670                 s = strcat(":team:", ftos(self.playerid), ":");
 671                 s = strcat(s, ftos(self.team));
 672                 GameLogEcho(s, FALSE);
 673         }
 674
 675         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 676
 677         bprint ("^4",self.netname);
 678         bprint ("^4 connected");
 679
 680         if(cvar("g_domination") || cvar("g_ctf"))
 681         {
 682                 bprint(" and joined the ");
 683                 bprint(ColoredTeamName(self.team));
 684         }
 685
 686         bprint("\n");
 687
 688         self.welcomemessage_time = 0;
 689
 690         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 691         // TODO: is this being used for anything else than cd tracks?
 692         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 693
 694         FixClientCvars(self);
 695
 696         // waypoint sprites
 697         WaypointSprite_InitClient(self);
 698
 699         // Wazat's grappling hook
 700         SetGrappleHookBindings();
 701
 702         // get autoswitch state from player when he toggles it
 703         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 704
 705         // get version info from player
 706         stuffcmd(self, "cmd clientversion $gameversion\n");
 707
 708         // get other cvars from player
 709         GetCvars(0);
 710
 711         // set cvar for team scoreboard
 712         if (teams_matter)
 713         {
 714                 local float t;
 715                 t = cvar("teamplay");
 716                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 717                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 718         }
 719         else
 720                 stuffcmd(self, "set teamplay 0\n");
 721
 722         if(cvar("g_lms"))
 723         {
 724                 self.frags = cvar("fraglimit");
 725                 // no fraglimit was set, so player gets 999 lives
 726                 if(self.frags < 1)
 727                         self.frags = 999;
 728
 729                 self.frags = LMS_NewPlayerLives();
 730                 if(!self.frags)
 731                 {
 732                         self.frags = -666;
 733                 }
 734         }
 735         else if(cvar("g_arena"))
 736         {
 737                 self.classname = "observer";
 738                 Spawnqueue_Insert(self);
 739         }
 740
 741         bot_relinkplayerlist();
 742
 743         self.jointime = time;
 744 }
 745
 746 /*
 747 =============
 748 ClientDisconnect
 749
 750 Called when a client disconnects from the server
 751 =============
 752 */
 753 void(entity e) DropFlag;
 754 .entity chatbubbleentity;
 755 .entity teambubbleentity;
 756 void ClientDisconnect (void)
 757 {
 758         float save;
 759         if(cvar("sv_eventlog"))
 760                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 761         bprint ("^4",self.netname);
 762         bprint ("^4 disconnected\n");
 763
 764         if (self.chatbubbleentity)
 765         {
 766                 remove (self.chatbubbleentity);
 767                 self.chatbubbleentity = world;
 768         }
 769
 770         if (self.teambubbleentity)
 771         {
 772                 remove (self.teambubbleentity);
 773                 self.teambubbleentity = world;
 774         }
 775
 776         WaypointSprite_PlayerGone();
 777
 778         DropAllRunes(self);
 779         kh_Key_DropAll(self, TRUE);
 780
 781         if(self.flagcarried)
 782                 DropFlag(self.flagcarried);
 783
 784         DistributeFragsAmongTeam(self, self.team, 1);
 785
 786         save = self.flags;
 787         self.flags = self.flags - (self.flags & FL_CLIENT);
 788         bot_relinkplayerlist();
 789         self.flags = save;
 790
 791         // remove laserdot
 792         if(self.weaponentity)
 793                 if(self.weaponentity.lasertarget)
 794                         remove(self.weaponentity.lasertarget);
 795
 796         if(cvar("g_arena"))
 797         {
 798                 Spawnqueue_Unmark(self);
 799                 Spawnqueue_Remove(self);
 800         }
 801
 802         // free cvars
 803         GetCvars(-1);
 804 }
 805
 806 .float buttonchat;
 807 void() ChatBubbleThink =
 808 {
 809         self.nextthink = time;
 810         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 811         {
 812                 self.owner.chatbubbleentity = world;
 813                 remove(self);
 814                 return;
 815         }
 816         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 817         if (self.owner.buttonchat && !self.owner.deadflag)
 818                 self.model = self.mdl;
 819         else
 820                 self.model = "";
 821 };
 822
 823 void() UpdateChatBubble =
 824 {
 825         if (!self.modelindex)
 826                 return;
 827         // spawn a chatbubble entity if needed
 828         if (!self.chatbubbleentity)
 829         {
 830                 self.chatbubbleentity = spawn();
 831                 self.chatbubbleentity.owner = self;
 832                 self.chatbubbleentity.exteriormodeltoclient = self;
 833                 self.chatbubbleentity.think = ChatBubbleThink;
 834                 self.chatbubbleentity.nextthink = time;
 835                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
 836                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 837                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 838                 self.chatbubbleentity.model = "";
 839                 self.chatbubbleentity.effects = EF_LOWPRECISION;
 840         }
 841 }
 842
 843
 844 void() TeamBubbleThink =
 845 {
 846         self.nextthink = time;
 847         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 848         {
 849                 self.owner.teambubbleentity = world;
 850                 remove(self);
 851                 return;
 852         }
 853 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 854         if (self.owner.buttonchat || self.owner.deadflag)
 855                 self.model = "";
 856         else
 857                 self.model = self.mdl;
 858
 859 };
 860
 861 float() TeamBubble_customizeentityforclient
 862 {
 863         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 864 }
 865
 866 void() UpdateTeamBubble =
 867 {
 868         if (!self.modelindex || !cvar("teamplay"))
 869                 return;
 870         // spawn a teambubble entity if needed
 871         if (!self.teambubbleentity && cvar("teamplay"))
 872         {
 873                 self.teambubbleentity = spawn();
 874                 self.teambubbleentity.owner = self;
 875                 self.teambubbleentity.exteriormodeltoclient = self;
 876                 self.teambubbleentity.think = TeamBubbleThink;
 877                 self.teambubbleentity.nextthink = time;
 878                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
 879 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 880                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 881                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 882                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 883                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 884                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 885                 self.teambubbleentity.effects = EF_LOWPRECISION;
 886         }
 887 }
 888
 889 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 890 // added to the model skins
 891 /*void() UpdateColorModHack =
 892 {
 893         local float c;
 894         c = self.clientcolors & 15;
 895         // LordHavoc: only bothering to support white, green, red, yellow, blue
 896              if (teamplay == 0) self.colormod = '0 0 0';
 897         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 898         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 899         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 900         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 901         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 902         else self.colormod = '1 1 1';
 903 };*/
 904
 905 void respawn(void)
 906 {
 907         CopyBody(1);
 908         PutClientInServer();
 909 }
 910
 911 void player_powerups (void)
 912 {
 913         if (cvar("g_minstagib"))
 914         {
 915                 self.effects = EF_FULLBRIGHT;
 916                 if (self.items & IT_STRENGTH)
 917                 {
 918                         if (time > self.strength_finished)
 919                         {
 920                                 self.alpha = default_player_alpha;
 921                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 922                                 self.items = self.items - (self.items & IT_STRENGTH);
 923                                 sprint(self, "^3Invisibility has worn off\n");
 924                         }
 925                 }
 926                 else
 927                 {
 928                         if (time < self.strength_finished)
 929                         {
 930                                 self.alpha = cvar("g_minstagib_invis_alpha");
 931                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 932                                 self.items = self.items | IT_STRENGTH;
 933                                 sprint(self, "^3You are invisible\n");
 934                         }
 935                 }
 936
 937                 if (self.items & IT_INVINCIBLE)
 938                 {
 939                         if (time > self.invincible_finished)
 940                         {
 941                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 942                                 sprint(self, "^3Speed has worn off\n");
 943                         }
 944                 }
 945                 else
 946                 {
 947                         if (time < self.invincible_finished)
 948                         {
 949                                 self.items = self.items | IT_INVINCIBLE;
 950                                 sprint(self, "^3You are on speed\n");
 951                         }
 952                 }
 953                 return;
 954         }
 955
 956         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 957         if (self.items & IT_STRENGTH)
 958         {
 959                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 960                 if (time > self.strength_finished)
 961                 {
 962                         self.items = self.items - (self.items & IT_STRENGTH);
 963                         sprint(self, "^3Strength has worn off\n");
 964                 }
 965         }
 966         else
 967         {
 968                 if (time < self.strength_finished)
 969                 {
 970                         self.items = self.items | IT_STRENGTH;
 971                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
 972                 }
 973         }
 974         if (self.items & IT_INVINCIBLE)
 975         {
 976                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 977                 if (time > self.invincible_finished)
 978                 {
 979                         self.items = self.items - (self.items & IT_INVINCIBLE);
 980                         sprint(self, "^3Shield has worn off\n");
 981                 }
 982         }
 983         else
 984         {
 985                 if (time < self.invincible_finished)
 986                 {
 987                         self.items = self.items | IT_INVINCIBLE;
 988                         sprint(self, "^3Shield surrounds you\n");
 989                 }
 990         }
 991
 992         if (cvar("g_fullbrightplayers"))
 993                 self.effects = self.effects | EF_FULLBRIGHT;
 994
 995         // midair gamemode: damage only while in the air
 996         // if in midair mode, being on ground grants temporary invulnerability
 997         // (this is so that multishot weapon don't clear the ground flag on the
 998         // first damage in the frame, leaving the player vulnerable to the
 999         // remaining hits in the same frame)
1000         if (self.flags & FL_ONGROUND)
1001         if (cvar("g_midair"))
1002                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1003
1004         if (time < self.spawnshieldtime)
1005                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1006 }
1007
1008 float CalcRegen(float current, float stable, float regenfactor)
1009 {
1010         if(current > stable)
1011                 return current;
1012         else if(current > stable - 0.25) // when close enough, "snap"
1013                 return stable;
1014         else
1015                 return min(stable, current + (stable - current) * regenfactor * frametime);
1016 }
1017
1018 void player_regen (void)
1019 {
1020         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1021         maxh = cvar("g_balance_health_stable");
1022         maxa = cvar("g_balance_armor_stable");
1023         limith = cvar("g_balance_health_limit");
1024         limita = cvar("g_balance_armor_limit");
1025
1026         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1027                 return;
1028
1029         max_mod = regen_mod = rot_mod = limit_mod = 1;
1030
1031         if (self.runes & RUNE_REGEN)
1032         {
1033                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1034                 {
1035                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1036                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1037                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1038                 }
1039                 else
1040                 {
1041                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1042                         max_mod = cvar("g_balance_rune_regen_hpmod");
1043                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1044                 }
1045         }
1046         else if (self.runes & CURSE_VENOM)
1047         {
1048                 max_mod = cvar("g_balance_curse_venom_hpmod");
1049                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1050                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1051                 else
1052                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1053                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1054                 //if (!self.runes & RUNE_REGEN)
1055                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1056         }
1057         maxh = maxh * max_mod;
1058         //maxa = maxa * max_mod;
1059         limith = limith * limit_mod;
1060         limita = limita * limit_mod;
1061
1062         if (self.armorvalue > maxa)
1063         {
1064                 if (time > self.pauserotarmor_finished)
1065                 {
1066                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1067                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1068                 }
1069         }
1070         else if (self.armorvalue < maxa)
1071         {
1072                 if (time > self.pauseregen_finished)
1073                 {
1074                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1075                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1076                 }
1077         }
1078         if (self.health > maxh)
1079         {
1080                 if (time > self.pauserothealth_finished)
1081                 {
1082                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1083                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1084                 }
1085         }
1086         else if (self.health < maxh)
1087         {
1088                 if (time > self.pauseregen_finished)
1089                 {
1090                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1091                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1092                 }
1093         }
1094
1095         if (self.health > limith)
1096                 self.health = limith;
1097         if (self.armorvalue > limita)
1098                 self.armorvalue = limita;
1099
1100         // if player rotted to death...  die!
1101         if(self.health < 1)
1102                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1103 }
1104
1105 /*
1106 ======================
1107 spectate mode routines
1108 ======================
1109 */
1110 void SpectateCopy(entity spectatee) {
1111         self.armortype = spectatee.armortype;
1112         self.armorvalue = spectatee.armorvalue;
1113         self.currentammo = spectatee.currentammo;
1114         self.effects = spectatee.effects;
1115         self.health = spectatee.health;
1116         self.impulse = 0;
1117         self.items = spectatee.items;
1118         self.punchangle = spectatee.punchangle;
1119         self.view_ofs = spectatee.view_ofs;
1120         self.v_angle = spectatee.v_angle;
1121         self.viewzoom = spectatee.viewzoom;
1122         setorigin(self, spectatee.origin);
1123         setsize(self, spectatee.mins, spectatee.maxs);
1124 }
1125
1126 void SpectateUpdate() {
1127         if(!self.enemy)
1128                         PutObserverInServer();
1129
1130         if (self != self.enemy) {
1131                 if(self.enemy.flags & FL_NOTARGET)
1132                         PutObserverInServer();
1133                 SpectateCopy(self.enemy);
1134                 self.dmg_take = self.enemy.dmg_take;
1135                 self.dmg_save = self.enemy.dmg_save;
1136                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1137                 self.fixangle = TRUE;
1138                 self.angles = self.enemy.v_angle;
1139                 //msg_entity = self;
1140                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1141                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1142                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1143                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1144         }
1145 }
1146
1147 float SpectateNext() {
1148         other = find(self.enemy, classname, "player");
1149         if (!other) {
1150                 other = find(other, classname, "player");
1151         }
1152         if (other) {
1153                 self.enemy = other;
1154         }
1155         if(self.enemy.classname == "player") {
1156                 msg_entity = self;
1157                 WriteByte(MSG_ONE, SVC_SETVIEW);
1158                 WriteEntity(MSG_ONE, self.enemy);
1159                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1160                 SpectateUpdate();
1161                 return 1;
1162         } else {
1163                 return 0;
1164         }
1165 }
1166
1167 /*
1168 =============
1169 ShowRespawnCountdown()
1170
1171 Update a respawn countdown display.
1172 =============
1173 */
1174 void ShowRespawnCountdown()
1175 {
1176         float number;
1177         if(self.deadflag == DEAD_NO) // just respawned?
1178                 return;
1179         else
1180         {
1181                 number = ceil(self.death_time - time);
1182                 if(number <= 0)
1183                         return;
1184                 if(number <= self.respawn_countdown)
1185                 {
1186                         self.respawn_countdown = number - 1;
1187                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1188                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1189                 }
1190         }
1191 }
1192
1193 void LeaveSpectatorMode()
1194 {
1195         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1196                 self.classname = "player";
1197                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1198                         JoinBestTeam(self, 0);
1199                 if(cvar("g_campaign"))
1200                         campaign_bots_may_start = 1;
1201                 PutClientInServer();
1202                 if(!(self.flags & FL_NOTARGET))
1203                         bprint ("^4", self.netname, "^4 is playing now\n");
1204                 centerprint(self,"");
1205                 return;
1206         } else {
1207                 stuffcmd(self,"menu_showteamselect\n");
1208                 return;
1209         }
1210 }
1211
1212 /*
1213 =============
1214 PlayerPreThink
1215
1216 Called every frame for each client before the physics are run
1217 =============
1218 */
1219 void() ctf_setstatus;
1220 .float vote_nagtime;
1221 void PlayerPreThink (void)
1222 {
1223         // version nagging
1224         if(self.version_nagtime)
1225                 if(self.cvar_g_nexuizversion)
1226                         if(time > self.version_nagtime)
1227                         {
1228                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1229                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1230                                         {
1231                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1232                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1233                                         }
1234                                 self.version_nagtime = 0;
1235                         }
1236
1237         // vote nagging
1238         if(self.cvar_scr_centertime)
1239                 if(time > self.vote_nagtime)
1240                 {
1241                         VoteNag();
1242                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1243                 }
1244
1245         // GOD MODE info
1246         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1247         {
1248                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1249                 self.max_armorvalue = 0;
1250         }
1251
1252         if(self.classname == "player") {
1253                 local vector m1, m2;
1254
1255 //              if(self.netname == "Wazat")
1256 //                      bprint(self.classname, "\n");
1257
1258                 CheckRules_Player();
1259
1260                 if(self.button7)
1261                         PrintWelcomeMessage(self);
1262
1263                 if(cvar("g_lms") || !cvar("sv_spectate"))
1264                 if((time - self.jointime) <= cvar("welcome_message_time"))
1265                         PrintWelcomeMessage(self);
1266
1267                 if (intermission_running)
1268                 {
1269                         IntermissionThink ();   // otherwise a button could be missed between
1270                         return;                                 // the think tics
1271                 }
1272
1273                 if(time > self.teleport_time)
1274                 {
1275                         self.effects = self.effects - (self.effects & EF_NODRAW);
1276                         if(self.weaponentity)
1277                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1278                 }
1279
1280                 Nixnex_GiveCurrentWeapon();
1281                 UpdateSelectedPlayer();
1282
1283                 if (self.deadflag != DEAD_NO)
1284                 {
1285                         float button_pressed, force_respawn;
1286                         player_anim();
1287                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1288                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1289                         if (self.deadflag == DEAD_DYING)
1290                         {
1291                                 if(force_respawn)
1292                                         self.deadflag = DEAD_RESPAWNING;
1293                                 else if(!button_pressed)
1294                                         self.deadflag = DEAD_DEAD;
1295                         }
1296                         else if (self.deadflag == DEAD_DEAD)
1297                         {
1298                                 if(button_pressed)
1299                                         self.deadflag = DEAD_RESPAWNABLE;
1300                         }
1301                         else if (self.deadflag == DEAD_RESPAWNABLE)
1302                         {
1303                                 if(!button_pressed)
1304                                         self.deadflag = DEAD_RESPAWNING;
1305                         }
1306                         else if (self.deadflag == DEAD_RESPAWNING)
1307                         {
1308                                 if(time > self.death_time)
1309                                         respawn();
1310                         }
1311                         ShowRespawnCountdown();
1312                         return;
1313                 }
1314
1315                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1316                 {
1317                         vector dist;
1318
1319                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1320                         dist = self.oldorigin - self.origin;
1321                         dist_z = 0;
1322                         self.lms_traveled_distance += fabs(vlen(dist));
1323
1324                         if(cvar("g_campaign"))
1325                         if(!campaign_bots_may_start)
1326                         {
1327                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1328                                 self.lms_traveled_distance = 0;
1329                         }
1330
1331                         if(time > self.lms_nextcheck)
1332                         {
1333                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1334                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1335                                 {
1336                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1337                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1338                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1339                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1340                                 }
1341                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1342                                 self.lms_traveled_distance = 0;
1343                         }
1344                 }
1345
1346                 if (self.button5 && !self.hook.state)
1347                 {
1348                         if (!self.crouch)
1349                         {
1350                                 self.crouch = TRUE;
1351                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1352                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1353                         }
1354                 }
1355                 else
1356                 {
1357                         if (self.crouch)
1358                         {
1359                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1360                                 if (!trace_startsolid)
1361                                 {
1362                                         self.crouch = FALSE;
1363                                         self.view_ofs = PL_VIEW_OFS;
1364                                         setsize (self, PL_MIN, PL_MAX);
1365                                 }
1366                         }
1367                 }
1368
1369                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1370                         local string defaultmodel;
1371                         defaultmodel = cvar_string("sv_defaultplayermodel");
1372
1373                         if (defaultmodel != self.model)
1374                         {
1375                                 m1 = self.mins;
1376                                 m2 = self.maxs;
1377                                 setmodel_lod (self, defaultmodel);
1378                                 setsize (self, m1, m2);
1379                         }
1380
1381                         if (self.skin != cvar("sv_defaultplayerskin"))
1382                                 self.skin = cvar("sv_defaultplayerskin");
1383                 } else {
1384                         if (self.playermodel != self.model)
1385                         {
1386                                 self.playermodel = CheckPlayerModel(self.playermodel);
1387                                 m1 = self.mins;
1388                                 m2 = self.maxs;
1389                                 setmodel_lod (self, self.playermodel);
1390                                 setsize (self, m1, m2);
1391                         }
1392
1393                         if(teams_matter)
1394                         {
1395                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1396                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1397                         }
1398                         else
1399                         {
1400                                 if (self.skin != stof(self.playerskin))
1401                                         self.skin = stof(self.playerskin);
1402                         }
1403                 }
1404
1405                 GrapplingHookFrame();
1406
1407                 W_WeaponFrame();
1408
1409                 {
1410                         float zoomfactor, zoomspeed, zoomdir;
1411                         zoomfactor = self.cvar_cl_zoomfactor;
1412                         if(zoomfactor < 1 || zoomfactor > 16)
1413                                 zoomfactor = 2.5;
1414                         zoomspeed = self.cvar_cl_zoomspeed;
1415                         if(zoomspeed >= 0) // < 0 is instant zoom
1416                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1417                                         zoomspeed = 3.5;
1418
1419                         zoomdir = self.button4;
1420                         if(self.button3)
1421                                 if(self.weapon == WEP_NEX)
1422                                         if(!cvar("g_minstagib"))
1423                                                 zoomdir = 1;
1424
1425                         if(zoomdir)
1426                                 self.has_zoomed = 1;
1427
1428                         if(self.has_zoomed)
1429                         {
1430                                 if(zoomspeed <= 0) // instant zoom
1431                                 {
1432                                         if(zoomdir)
1433                                                 self.viewzoom = 1 / zoomfactor;
1434                                         else
1435                                                 self.viewzoom = 1;
1436                                 }
1437                                 else
1438                                 {
1439                                         // geometric zoom would be:
1440                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1441                                         // however, testing showed that arithmetic/harmonic zoom works better
1442                                         if(zoomdir)
1443                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1444                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1445                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1446                                         else
1447                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1448                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1449                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1450                                 }
1451                         }
1452                         else
1453                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1454                 }
1455
1456                 player_powerups();
1457                 player_regen();
1458                 player_anim();
1459
1460                 if (cvar("g_minstagib"))
1461                         minstagib_ammocheck();
1462
1463                 ctf_setstatus();
1464                 kh_setstatus();
1465
1466                 //self.angles_y=self.v_angle_y + 90;   // temp
1467
1468                 //if (TetrisPreFrame()) return;
1469         } else if(gameover) {
1470                 if (intermission_running)
1471                         IntermissionThink ();   // otherwise a button could be missed between
1472                 return;
1473         } else if(self.classname == "observer") {
1474
1475                 if (self.flags & FL_JUMPRELEASED) {
1476                         if (self.button2 && self.version == cvar("gameversion")) {
1477                                 self.welcomemessage_time = 0;
1478                                 self.flags = self.flags - FL_JUMPRELEASED;
1479                                 LeaveSpectatorMode();
1480                                 return;
1481                         } else if(self.button0 && self.version == cvar("gameversion")) {
1482                                 self.welcomemessage_time = 0;
1483                                 self.flags = self.flags - FL_JUMPRELEASED;
1484                                 if(SpectateNext() == 1) {
1485                                         self.classname = "spectator";
1486                                 }
1487                         }
1488                 } else {
1489                         if (!(self.button0 || self.button2)) {
1490                                 self.flags = self.flags | FL_JUMPRELEASED;
1491                         }
1492                 }
1493                 PrintWelcomeMessage(self);
1494         } else if(self.classname == "spectator") {
1495                 if (self.flags & FL_JUMPRELEASED) {
1496                         if (self.button2 && self.version == cvar("gameversion")) {
1497                                 self.welcomemessage_time = 0;
1498                                 self.flags = self.flags - FL_JUMPRELEASED;
1499                                 LeaveSpectatorMode();
1500                                 return;
1501                         } else if(self.button0) {
1502                                 self.welcomemessage_time = 0;
1503                                 self.flags = self.flags - FL_JUMPRELEASED;
1504                                 if(SpectateNext() == 1) {
1505                                         self.classname = "spectator";
1506                                 } else {
1507                                         self.classname = "observer";
1508                                         PutClientInServer();
1509                                 }
1510                         } else if (self.button3) {
1511                                 self.welcomemessage_time = 0;
1512                                 self.flags = self.flags - FL_JUMPRELEASED;
1513                                 self.classname = "observer";
1514                                 PutClientInServer();
1515                         } else {
1516                                 SpectateUpdate();
1517                         }
1518                 } else {
1519                         if (!(self.button0 || self.button3)) {
1520                                 self.flags = self.flags | FL_JUMPRELEASED;
1521                         }
1522                 }
1523                 PrintWelcomeMessage(self);
1524                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1525         }
1526 }
1527
1528
1529 /*
1530 =============
1531 PlayerPostThink
1532
1533 Called every frame for each client after the physics are run
1534 =============
1535 */
1536 void PlayerPostThink (void)
1537 {
1538         // Savage: Check for nameless players
1539         if (strlen(self.netname) < 1) {
1540                 self.netname = "Player";
1541                 stuffcmd(self, "seta _cl_name Player\n");
1542         }
1543
1544         if(self.classname == "player") {
1545                 CheckRules_Player();
1546                 UpdateChatBubble();
1547                 UpdateTeamBubble();
1548                 if (self.impulse)
1549                         ImpulseCommands ();
1550                 if (intermission_running)
1551                         return;         // intermission or finale
1552
1553                 //PrintWelcomeMessage(self);
1554                 //if (TetrisPostFrame()) return;
1555         } else if (self.classname == "observer") {
1556                 //do nothing
1557         } else if (self.classname == "spectator") {
1558                 //do nothing
1559         }
1560         Arena_Warmup();
1561 }