data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 144         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 145                 spot = Spawn_RandomPoint(firstspot);
 146         else
 147                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 148
 149         if (!spot)
 150         {
 151                 if(cvar("spawn_debug"))
 152                         GotoNextMap();
 153                 else
 154                         error ("PutClientInServer: no start points on level");
 155         }
 156
 157         return spot;
 158 }
 159
 160 /*
 161 =============
 162 CheckPlayerModel
 163
 164 Checks if the argument string can be a valid playermodel.
 165 Returns a valid one in doubt.
 166 =============
 167 */
 168 string FallbackPlayerModel = "models/player/marine.zym";
 169 string CheckPlayerModel(string plyermodel) {
 170         if(strlen(plyermodel) < 4)
 171                 return FallbackPlayerModel;
 172         if( substring(plyermodel,0,14) != "models/player/")
 173                 return FallbackPlayerModel;
 174         else if(cvar("sv_servermodelsonly"))
 175         {
 176                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 177                         return FallbackPlayerModel;
 178                 if(!fexists(plyermodel))
 179                         return FallbackPlayerModel;
 180         }
 181         return plyermodel;
 182 }
 183
 184 /*
 185 =============
 186 Client_customizeentityforclient
 187
 188 LOD reduction
 189 =============
 190 */
 191 float Client_customizeentityforclient()
 192 {
 193 #ifdef ALLOW_VARIABLE_LOD
 194         // self: me
 195         // other: the player viewing me
 196         float distance;
 197         float f;
 198
 199         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 200                 return TRUE;
 201
 202         if(other.cvar_cl_playerdetailreduction <= 0)
 203         {
 204                 if(other.cvar_cl_playerdetailreduction <= -2)
 205                         self.modelindex = self.modelindex_lod2;
 206                 else if(other.cvar_cl_playerdetailreduction <= -1)
 207                         self.modelindex = self.modelindex_lod1;
 208                 else
 209                         self.modelindex = self.modelindex_lod0;
 210         }
 211         else
 212         {
 213                 distance = vlen(self.origin - other.origin);
 214                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 215                 if(f > 10000)
 216                         self.modelindex = self.modelindex_lod2;
 217                 else if(f > 5000)
 218                         self.modelindex = self.modelindex_lod1;
 219                 else
 220                         self.modelindex = self.modelindex_lod0;
 221         }
 222 #endif
 223
 224         return TRUE;
 225 }
 226
 227 void setmodel_lod(entity e, string modelname)
 228 {
 229 #ifdef ALLOW_VARIABLE_LOD
 230         string s;
 231
 232         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 233         if(fexists(s))
 234         {
 235                 precache_model(s);
 236                 setmodel(e, s);
 237                 self.modelindex_lod1 = self.modelindex;
 238         }
 239         else
 240                 self.modelindex_lod1 = -1;
 241
 242         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 243         if(fexists(s))
 244         {
 245                 precache_model(s);
 246                 setmodel(e, s);
 247                 self.modelindex_lod2 = self.modelindex;
 248         }
 249         else
 250                 self.modelindex_lod2 = -1;
 251
 252         precache_model(modelname);
 253         setmodel(e, modelname);
 254         self.modelindex_lod0 = self.modelindex;
 255
 256         if(self.modelindex_lod1 < 0)
 257                 self.modelindex_lod1 = self.modelindex;
 258
 259         if(self.modelindex_lod2 < 0)
 260                 self.modelindex_lod2 = self.modelindex;
 261 #else
 262         precache_model(modelname);
 263         setmodel(e, modelname);
 264 #endif
 265 }
 266
 267 /*
 268 =============
 269 PutObserverInServer
 270
 271 putting a client as observer in the server
 272 =============
 273 */
 274 void PutObserverInServer (void)
 275 {
 276         entity  spot;
 277         spot = SelectSpawnPoint (FALSE);
 278         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 279
 280         if(clienttype(self) == CLIENTTYPE_REAL)
 281         {
 282                 msg_entity = self;
 283                 WriteByte(MSG_ONE, SVC_SETVIEW);
 284                 WriteEntity(MSG_ONE, self);
 285         }
 286
 287         if (cvar("g_runematch"))
 288                 DropAllRunes(self);
 289
 290         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 291                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 292         else if(self.killcount != -666)
 293                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 294
 295         self.classname = "observer";
 296         self.health = -666;
 297         self.takedamage = DAMAGE_NO;
 298         self.solid = SOLID_NOT;
 299         self.movetype = MOVETYPE_NOCLIP;
 300         self.flags = FL_CLIENT | FL_NOTARGET;
 301         self.armorvalue = 666;
 302         self.effects = 0;
 303         self.armorvalue = cvar("g_balance_armor_start");
 304         self.pauserotarmor_finished = 0;
 305         self.pauserothealth_finished = 0;
 306         self.pauseregen_finished = 0;
 307         self.damageforcescale = 0;
 308         self.death_time = 0;
 309         self.dead_time = 0;
 310         self.dead_frame = 0;
 311         self.die_frame = 0;
 312         self.deaths = 0;
 313         self.alpha = 0;
 314         self.scale = 0;
 315         self.fade_time = 0;
 316         self.pain_frame = 0;
 317         self.pain_finished = 0;
 318         self.strength_finished = 0;
 319         self.invincible_finished = 0;
 320         self.pushltime = 0;
 321         self.think = SUB_Null;
 322         self.nextthink = 0;
 323         self.hook_time = 0;
 324         self.runes = 0;
 325         self.deadflag = DEAD_NO;
 326         self.angles = spot.angles;
 327         self.angles_z = 0;
 328         self.fixangle = TRUE;
 329         self.crouch = FALSE;:q
 330
 331         self.view_ofs = PL_VIEW_OFS;
 332         setorigin (self, spot.origin);
 333         setsize (self, '0 0 0', '0 0 0');
 334         self.oldorigin = self.origin;
 335         self.items = 0;
 336         self.model = "";
 337         self.modelindex = 0;
 338         self.weapon = 0;
 339         self.weaponmodel = "";
 340         self.weaponentity = world;
 341         self.killcount = -666;
 342         self.velocity = '0 0 0';
 343         self.avelocity = '0 0 0';
 344         self.punchangle = '0 0 0';
 345         self.punchvector = '0 0 0';
 346         self.oldvelocity = self.velocity;
 347         self.customizeentityforclient = Client_customizeentityforclient;
 348
 349         if(cvar("g_arena"))
 350         {
 351                 if(self.frags != -2)
 352                 {
 353                         Spawnqueue_Insert(self);
 354                 }
 355                 else
 356                 {
 357                         Spawnqueue_Unmark(self);
 358                         Spawnqueue_Remove(self);
 359                 }
 360         }
 361         else if(!cvar("g_lms"))
 362                 self.frags = -666;
 363 }
 364
 365
 366 /*
 367 =============
 368 PutClientInServer
 369
 370 Called when a client spawns in the server
 371 =============
 372 */
 373 void PutClientInServer (void)
 374 {
 375         if(clienttype(self) == CLIENTTYPE_BOT)
 376         {
 377                 self.classname = "player";
 378         }
 379         else if(clienttype(self) == CLIENTTYPE_REAL)
 380         {
 381                 msg_entity = self;
 382                 WriteByte(MSG_ONE, SVC_SETVIEW);
 383                 WriteEntity(MSG_ONE, self);
 384         }
 385
 386         // player is dead and becomes observer
 387         if(cvar("g_lms") && self.frags < 1)
 388                 self.classname = "observer";
 389
 390         if(cvar("g_arena"))
 391         if(!self.spawned)
 392                 self.classname = "observer";
 393
 394         if(self.classname == "player") {
 395                 entity  spot;
 396
 397                 spot = SelectSpawnPoint (FALSE);
 398
 399                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 400
 401                 self.classname = "player";
 402                 self.iscreature = TRUE;
 403                 self.movetype = MOVETYPE_WALK;
 404                 self.solid = SOLID_SLIDEBOX;
 405                 self.flags = FL_CLIENT;
 406                 self.takedamage = DAMAGE_AIM;
 407                 self.effects = 0;
 408                 self.health = cvar("g_balance_health_start");
 409                 self.armorvalue = cvar("g_balance_armor_start");
 410                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 411                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 412                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 413                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 414                 self.damageforcescale = 2;
 415                 self.death_time = 0;
 416                 self.dead_time = 0;
 417                 self.dead_frame = 0;
 418                 self.die_frame = 0;
 419                 self.alpha = 0;
 420                 self.scale = 0;
 421                 self.fade_time = 0;
 422                 self.pain_frame = 0;
 423                 self.pain_finished = 0;
 424                 self.strength_finished = 0;
 425                 self.invincible_finished = 0;
 426                 self.pushltime = 0;
 427                 //self.speed_finished = 0;
 428                 //self.slowmo_finished = 0;
 429                 // players have no think function
 430                 self.think = SUB_Null;
 431                 self.nextthink = 0;
 432                 self.weapon = 0;
 433                 self.switchweapon = 0;
 434                 self.hook_time = 0;
 435
 436                 self.runes = 0;
 437
 438                 self.deadflag = DEAD_NO;
 439
 440                 self.angles = spot.angles;
 441
 442                 self.angles_z = 0; // never spawn tilted even if the spot says to
 443                 self.fixangle = TRUE; // turn this way immediately
 444                 self.velocity = '0 0 0';
 445                 self.avelocity = '0 0 0';
 446                 self.punchangle = '0 0 0';
 447                 self.punchvector = '0 0 0';
 448                 self.oldvelocity = self.velocity;
 449
 450                 self.viewzoom = 0.6;
 451
 452                 self.customizeentityforclient = Client_customizeentityforclient;
 453
 454                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 455                         local string defaultmodel;
 456                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 457                         setmodel_lod (self, defaultmodel);
 458                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 459                 } else {
 460                         self.playermodel = CheckPlayerModel(self.playermodel);
 461                         setmodel_lod (self, self.playermodel);
 462                         self.skin = stof(self.playerskin);
 463
 464                 }
 465
 466                 self.crouch = FALSE;
 467                 self.view_ofs = PL_VIEW_OFS;
 468                 setsize (self, PL_MIN, PL_MAX);
 469                 self.spawnorigin = spot.origin;
 470                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 471                 // don't reset back to last position, even if new position is stuck in solid
 472                 self.oldorigin = self.origin;
 473
 474                 if(cvar("g_lms"))
 475                 {
 476                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 477                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 478                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 479                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 480                         self.health = cvar("g_lms_start_health");
 481                         self.armorvalue = cvar("g_lms_start_armor");
 482                 }
 483                 else if (cvar("g_use_ammunition")) {
 484                         self.ammo_shells = cvar("g_start_ammo_shells");
 485                         self.ammo_nails = cvar("g_start_ammo_nails");
 486                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 487                         self.ammo_cells = cvar("g_start_ammo_cells");
 488                 } else {
 489                         self.ammo_shells = 999;
 490                         self.ammo_nails = 999;
 491                         self.ammo_rockets = 999;
 492                         self.ammo_cells = 999;
 493                 }
 494
 495                 self.items = 0;
 496                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 497                 {
 498                         self.items = self.items | IT_LASER;
 499                         self.switchweapon = WEP_LASER;
 500                 }
 501                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 502                 {
 503                         self.items = self.items | IT_SHOTGUN;
 504                         self.switchweapon = WEP_SHOTGUN;
 505                 }
 506                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 507                 {
 508                         self.items = self.items | IT_UZI;
 509                         self.switchweapon = WEP_UZI;
 510                 }
 511                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 512                 {
 513                         self.items = self.items | IT_GRENADE_LAUNCHER;
 514                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 515                 }
 516                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 517                 {
 518                         self.items = self.items | IT_ELECTRO;
 519                         self.switchweapon = WEP_ELECTRO;
 520                 }
 521                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 522                 {
 523                         self.items = self.items | IT_CRYLINK;
 524                         self.switchweapon = WEP_CRYLINK;
 525                 }
 526                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 527                 {
 528                         self.items = self.items | IT_NEX;
 529                         self.switchweapon = WEP_NEX;
 530                 }
 531                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 532                 {
 533                         self.items = self.items | IT_HAGAR;
 534                         self.switchweapon = WEP_HAGAR;
 535                 }
 536                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 537                 {
 538                         self.items = self.items | IT_ROCKET_LAUNCHER;
 539                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 540                 }
 541
 542                 if(cvar("g_instagib"))
 543                 {
 544                         self.items = IT_NEX;
 545                         self.switchweapon = WEP_NEX;
 546                         self.ammo_cells = 999;
 547                 }
 548
 549                 if(cvar("g_rocketarena"))
 550                 {
 551                         self.items = IT_ROCKET_LAUNCHER;
 552                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 553                         self.ammo_rockets = 999;
 554                 }
 555
 556                 if(cvar("g_nixnex"))
 557                 {
 558                         self.items = 0;
 559                         // will be done later
 560                 }
 561
 562                 if(cvar("g_minstagib"))
 563                 {
 564                         self.health = 100;
 565                         self.armorvalue = 0;
 566                         self.items = IT_NEX;
 567                         self.switchweapon = WEP_NEX;
 568                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 569                         self.extralives = 0;
 570                         self.jump_interval = time;
 571                 }
 572
 573                 if(cvar("g_arena"))
 574                 {
 575                         Spawnqueue_Remove(self);
 576                         Spawnqueue_Mark(self);
 577                 }
 578
 579                 self.event_damage = PlayerDamage;
 580
 581                 self.bot_attack = TRUE;
 582
 583                 self.statdraintime = time + 5;
 584                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 585
 586                 if(self.killcount == -666) {
 587                         self.killcount = 0;
 588                         if(!cvar("g_arena"))
 589                         if(!cvar("g_lms"))
 590                                 self.frags = 0;
 591                 }
 592
 593                 self.cnt = WEP_LASER;
 594                 self.nixnex_lastchange_id = -1;
 595
 596                 CL_SpawnWeaponentity();
 597                 self.alpha = default_player_alpha;
 598                 self.exteriorweaponentity.alpha = default_player_alpha;
 599
 600                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 601                 self.lms_traveled_distance = 0;
 602
 603                 if(cvar("spawn_debug"))
 604                 {
 605                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 606                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 607                 }
 608
 609                 //stuffcmd(self, "chase_active 0");
 610                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 611         } else if(self.classname == "observer") {
 612                 PutObserverInServer ();
 613         }
 614 }
 615
 616 /*
 617 =============
 618 SetNewParms
 619 =============
 620 */
 621 void SetNewParms (void)
 622 {
 623
 624 }
 625
 626 /*
 627 =============
 628 SetChangeParms
 629 =============
 630 */
 631 void SetChangeParms (void)
 632 {
 633
 634 }
 635
 636 /*
 637 =============
 638 ClientKill
 639
 640 Called when a client types 'kill' in the console
 641 =============
 642 */
 643 void ClientKill (void)
 644 {
 645         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 646 }
 647
 648 /*
 649 =============
 650 ClientConnect
 651
 652 Called when a client connects to the server
 653 =============
 654 */
 655 string ColoredTeamName(float t);
 656 //void dom_player_join_team(entity pl);
 657 void ClientConnect (void)
 658 {
 659         self.classname = "player_joining";
 660         self.flags = self.flags | FL_CLIENT;
 661
 662         if(player_count<0) player_count = 0;
 663
 664         bot_clientconnect();
 665
 666         //if(cvar("g_domination"))
 667         //      dom_player_join_team(self);
 668
 669         //JoinBestTeam(self, FALSE);
 670
 671         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 672                 self.classname = "observer";
 673         } else {
 674                 self.classname = "player";
 675                 campaign_bots_may_start = 1;
 676         }
 677
 678         self.playerid = (playerid_last = playerid_last + 1);
 679         if(cvar("sv_eventlog"))
 680         {
 681                 string s;
 682                 if(clienttype(self) == CLIENTTYPE_REAL)
 683                         s = "player";
 684                 else
 685                         s = "bot";
 686                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 687                 s = strcat(":team:", ftos(self.playerid), ":");
 688                 s = strcat(s, ftos(self.team));
 689                 GameLogEcho(s, FALSE);
 690         }
 691
 692         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 693
 694         bprint ("^4",self.netname);
 695         bprint ("^4 connected");
 696
 697         if(cvar("g_domination") || cvar("g_ctf"))
 698         {
 699                 bprint(" and joined the ");
 700                 bprint(ColoredTeamName(self.team));
 701         }
 702
 703         bprint("\n");
 704
 705         self.welcomemessage_time = time + cvar("welcome_message_time");
 706         self.welcomemessage_time2 = 0;
 707
 708         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 709         // send prediction settings to the client
 710         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 711         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 712         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 713         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 714         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 715         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 716         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 717         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 718         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 719         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 720         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 721         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 722         // Wazat's grappling hook
 723         SetGrappleHookBindings();
 724
 725         // get autoswitch state from player
 726         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 727         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 728
 729         // get version info from player
 730         stuffcmd(self, "cmd clientversion $gameversion\n");
 731
 732         // get other cvars from player
 733         GetCvars(0);
 734
 735         // set cvar for team scoreboard
 736         if (teams_matter)
 737         {
 738                 local float t;
 739                 t = cvar("teamplay");
 740                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 741                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 742         }
 743         else
 744                 stuffcmd(self, strcat("set teamplay 0\n"));
 745
 746         if(cvar("g_lms"))
 747         {
 748                 self.frags = cvar("fraglimit");
 749                 // no fraglimit was set, so player gets 999 lives
 750                 if(self.frags < 1)
 751                         self.frags = 999;
 752
 753                 // disallow player to join after the worst player has lost g_lms_last_join lives
 754                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 755                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 756                 {
 757                         self.frags = -666;
 758                         lms_dead_count += 1;
 759                 }
 760                 else if(cvar("fraglimit") > lms_lowest_lives)
 761                 {
 762                         self.frags = lms_lowest_lives;
 763                 }
 764         }
 765         else if(cvar("g_arena"))
 766         {
 767                 self.classname = "observer";
 768                 Spawnqueue_Insert(self);
 769         }
 770
 771         bot_relinkplayerlist();
 772
 773         self.jointime = time;
 774 }
 775
 776 /*
 777 =============
 778 ClientDisconnect
 779
 780 Called when a client disconnects from the server
 781 =============
 782 */
 783 void(entity e) DropFlag;
 784 .entity chatbubbleentity;
 785 .entity teambubbleentity;
 786 void ClientDisconnect (void)
 787 {
 788         float save;
 789         if(cvar("sv_eventlog"))
 790                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 791         bprint ("^4",self.netname);
 792         bprint ("^4 disconnected\n");
 793
 794         if (self.chatbubbleentity)
 795         {
 796                 remove (self.chatbubbleentity);
 797                 self.chatbubbleentity = world;
 798         }
 799
 800         if (self.teambubbleentity)
 801         {
 802                 remove (self.teambubbleentity);
 803                 self.teambubbleentity = world;
 804         }
 805
 806         DropAllRunes(self);
 807
 808         if(self.flagcarried)
 809                 DropFlag(self.flagcarried);
 810
 811         save = self.flags;
 812         self.flags = self.flags - (self.flags & FL_CLIENT);
 813         bot_relinkplayerlist();
 814         self.flags = save;
 815
 816         // player was dead, decrease dead count
 817         if(cvar("g_lms") && self.frags < 1)
 818                 lms_dead_count -= 1;
 819         else if(cvar("g_arena"))
 820         {
 821                 Spawnqueue_Unmark(self);
 822                 Spawnqueue_Remove(self);
 823         }
 824 }
 825
 826 .float buttonchat;
 827 void() ChatBubbleThink =
 828 {
 829         self.nextthink = time;
 830         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 831         {
 832                 self.owner.chatbubbleentity = world;
 833                 remove(self);
 834                 return;
 835         }
 836         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 837         if (self.owner.buttonchat && !self.owner.deadflag)
 838                 self.model = self.mdl;
 839         else
 840                 self.model = "";
 841 };
 842
 843 void() UpdateChatBubble =
 844 {
 845         if (!self.modelindex)
 846                 return;
 847         // spawn a chatbubble entity if needed
 848         if (!self.chatbubbleentity)
 849         {
 850                 self.chatbubbleentity = spawn();
 851                 self.chatbubbleentity.owner = self;
 852                 self.chatbubbleentity.exteriormodeltoclient = self;
 853                 self.chatbubbleentity.think = ChatBubbleThink;
 854                 self.chatbubbleentity.nextthink = time;
 855                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 856                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 857                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 858                 self.chatbubbleentity.model = "";
 859         }
 860 }
 861
 862
 863 void() TeamBubbleThink =
 864 {
 865         self.nextthink = time;
 866         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 867         {
 868                 self.owner.teambubbleentity = world;
 869                 remove(self);
 870                 return;
 871         }
 872 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 873         if (self.owner.buttonchat || self.owner.deadflag)
 874                 self.model = "";
 875         else
 876                 self.model = self.mdl;
 877
 878 };
 879
 880 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 881
 882 void() UpdateTeamBubble =
 883 {
 884         if (!self.modelindex || !cvar("teamplay"))
 885                 return;
 886         // spawn a teambubble entity if needed
 887         if (!self.teambubbleentity && cvar("teamplay"))
 888         {
 889                 self.teambubbleentity = spawn();
 890                 self.teambubbleentity.owner = self;
 891                 self.teambubbleentity.exteriormodeltoclient = self;
 892                 self.teambubbleentity.think = TeamBubbleThink;
 893                 self.teambubbleentity.nextthink = time;
 894                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 895 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 896                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 897                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 898                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 899                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 900                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 901         }
 902 }
 903
 904 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 905 // added to the model skins
 906 /*void() UpdateColorModHack =
 907 {
 908         local float c;
 909         c = self.clientcolors & 15;
 910         // LordHavoc: only bothering to support white, green, red, yellow, blue
 911              if (teamplay == 0) self.colormod = '0 0 0';
 912         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 913         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 914         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 915         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 916         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 917         else self.colormod = '1 1 1';
 918 };*/
 919
 920 /*
 921 =============
 922 PlayerJump
 923
 924 When you press the jump key
 925 =============
 926 */
 927 void PlayerJump (void)
 928 {
 929         float mjumpheight;
 930
 931         mjumpheight = cvar("g_balance_jumpheight");
 932         if (self.waterlevel >= 2)
 933         {
 934                 if (self.watertype == CONTENT_WATER)
 935                         self.velocity_z = 200;
 936                 else if (self.watertype == CONTENT_SLIME)
 937                         self.velocity_z = 80;
 938                 else
 939                         self.velocity_z = 50;
 940
 941                 return;
 942         }
 943
 944
 945         if (!(self.flags & FL_ONGROUND))
 946                 return;
 947
 948         if (!(self.flags & FL_JUMPRELEASED))
 949                 return;
 950
 951         if(cvar("g_runematch"))
 952         {
 953                 if(self.runes & RUNE_SPEED)
 954                 {
 955                         if(self.runes & CURSE_SLOW)
 956                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 957                         else
 958                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 959                 }
 960                 else if(self.runes & CURSE_SLOW)
 961                 {
 962                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 963                 }
 964         }
 965
 966         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 967         {
 968                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 969         }
 970
 971         self.velocity_z = self.velocity_z + mjumpheight;
 972         self.oldvelocity_z = self.velocity_z;
 973
 974         self.flags = self.flags - FL_ONGROUND;
 975         self.flags = self.flags - FL_JUMPRELEASED;
 976 }
 977
 978 void() CheckWaterJump =
 979 {
 980         local vector start, end;
 981
 982 // check for a jump-out-of-water
 983         makevectors (self.angles);
 984         start = self.origin;
 985         start_z = start_z + 8;
 986         v_forward_z = 0;
 987         normalize(v_forward);
 988         end = start + v_forward*24;
 989         traceline (start, end, TRUE, self);
 990         if (trace_fraction < 1)
 991         {       // solid at waist
 992                 start_z = start_z + self.maxs_z - 8;
 993                 end = start + v_forward*24;
 994                 self.movedir = trace_plane_normal * -50;
 995                 traceline (start, end, TRUE, self);
 996                 if (trace_fraction == 1)
 997                 {       // open at eye level
 998                         self.flags = self.flags | FL_WATERJUMP;
 999                         self.velocity_z = 225;
1000                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1001                         self.teleport_time = time + 2;  // safety net
1002                         return;
1003                 }
1004         }
1005 };
1006
1007
1008 void respawn(void)
1009 {
1010         CopyBody(1);
1011         PutClientInServer();
1012 }
1013
1014 void player_powerups (void)
1015 {
1016         if (cvar("g_minstagib"))
1017         {
1018                 self.effects = EF_FULLBRIGHT;
1019                 if (self.items & IT_STRENGTH)
1020                 {
1021                         if (time > self.strength_finished)
1022                         {
1023                                 self.alpha = default_player_alpha;
1024                                 self.exteriorweaponentity.alpha = default_player_alpha;
1025                                 self.items = self.items - (self.items & IT_STRENGTH);
1026                                 sprint(self, "^3Invisibility has worn off\n");
1027                         }
1028                 }
1029                 else
1030                 {
1031                         if (time < self.strength_finished)
1032                         {
1033                                 self.alpha = cvar("g_minstagib_invis_alpha");
1034                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1035                                 self.items = self.items | IT_STRENGTH;
1036                                 sprint(self, "^3You are invisible\n");
1037                         }
1038                 }
1039
1040                 if (self.items & IT_INVINCIBLE)
1041                 {
1042                         if (time > self.invincible_finished)
1043                         {
1044                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1045                                 sprint(self, "^3Speed has worn off\n");
1046                         }
1047                 }
1048                 else
1049                 {
1050                         if (time < self.invincible_finished)
1051                         {
1052                                 self.items = self.items | IT_INVINCIBLE;
1053                                 sprint(self, "^3You are on speed\n");
1054                         }
1055                 }
1056                 return;
1057         }
1058
1059         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1060         if (self.items & IT_STRENGTH)
1061         {
1062                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1063                 if (time > self.strength_finished)
1064                 {
1065                         self.items = self.items - (self.items & IT_STRENGTH);
1066                         sprint(self, "^3Strength has worn off\n");
1067                 }
1068         }
1069         else
1070         {
1071                 if (time < self.strength_finished)
1072                 {
1073                         self.items = self.items | IT_STRENGTH;
1074                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1075                 }
1076         }
1077         if (self.items & IT_INVINCIBLE)
1078         {
1079                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1080                 if (time > self.invincible_finished)
1081                 {
1082                         self.items = self.items - (self.items & IT_INVINCIBLE);
1083                         sprint(self, "^3Shield has worn off\n");
1084                 }
1085         }
1086         else
1087         {
1088                 if (time < self.invincible_finished)
1089                 {
1090                         self.items = self.items | IT_INVINCIBLE;
1091                         sprint(self, "^3Shield surrounds you\n");
1092                 }
1093         }
1094
1095         if (cvar("g_fullbrightplayers"))
1096                 self.effects = self.effects | EF_FULLBRIGHT;
1097
1098         // midair gamemode: damage only while in the air
1099         // if in midair mode, being on ground grants temporary invulnerability
1100         // (this is so that multishot weapon don't clear the ground flag on the
1101         // first damage in the frame, leaving the player vulnerable to the
1102         // remaining hits in the same frame)
1103         if (self.flags & FL_ONGROUND)
1104         if (cvar("g_midair"))
1105                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1106
1107         if (time < self.spawnshieldtime)
1108                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1109 }
1110
1111 void player_regen (void)
1112 {
1113         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1114         maxh = cvar("g_balance_health_stable");
1115         maxa = cvar("g_balance_armor_stable");
1116         limith = cvar("g_balance_health_limit");
1117         limita = cvar("g_balance_armor_limit");
1118
1119         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1120                 return;
1121
1122         if(cvar("g_runematch"))
1123         {
1124                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1125                 if (self.runes & RUNE_REGEN)
1126                 {
1127                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1128                         {
1129                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1130                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1131                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1132                         }
1133                         else
1134                         {
1135                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1136                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1137                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1138                         }
1139                 }
1140                 else if (self.runes & CURSE_VENOM)
1141                 {
1142                         max_mod = cvar("g_balance_curse_venom_hpmod");
1143                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1144                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1145                         else
1146                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1147                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1148                         //if (!self.runes & RUNE_REGEN)
1149                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1150                 }
1151                 maxh = maxh * max_mod;
1152                 //maxa = maxa * max_mod;
1153
1154                 if (time > self.pauserotarmor_finished)
1155                 {
1156                         if (self.armorvalue > maxa)
1157                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1158                 }
1159                 if (time > self.pauserothealth_finished)
1160                 {
1161                         if (self.health > maxh)
1162                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1163                 }
1164                 if (time > self.pauseregen_finished)
1165                 {
1166                         if (self.health < maxh)
1167                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1168                         if (self.armorvalue < maxa)
1169                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1170                 }
1171         }
1172         else
1173         {
1174                 if (time > self.pauserothealth_finished)
1175                 if (self.health > maxh)
1176                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1177                 if (time > self.pauserotarmor_finished)
1178                 if (self.armorvalue > maxa)
1179                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1180                 if (time > self.pauseregen_finished)
1181                 {
1182                         if (self.health < maxh)
1183                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1184                         if (self.armorvalue < maxa)
1185                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1186                 }
1187         }
1188
1189         if (self.health > limith)
1190                 self.health = limith;
1191         if(self.health < 1)
1192                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1193         if (self.armorvalue > limita)
1194                 self.armorvalue = limita;
1195 }
1196
1197 /*
1198 ======================
1199 spectate mode routines
1200 ======================
1201 */
1202 void SpectateCopy(entity spectatee) {
1203         self.armortype = spectatee.armortype;
1204         self.armorvalue = spectatee.armorvalue;
1205         self.currentammo = spectatee.currentammo;
1206         self.effects = spectatee.effects;
1207         self.health = spectatee.health;
1208         self.impulse = 0;
1209         self.items = spectatee.items;
1210         self.punchangle = spectatee.punchangle;
1211         self.view_ofs = spectatee.view_ofs;
1212         self.v_angle = spectatee.v_angle;
1213         self.viewzoom = spectatee.viewzoom;
1214         setorigin(self, spectatee.origin);
1215         setsize(self, spectatee.mins, spectatee.maxs);
1216 }
1217
1218 void SpectateUpdate() {
1219         if (self != self.enemy) {
1220                 if(self.enemy.flags & FL_NOTARGET)
1221                         PutObserverInServer();
1222                 SpectateCopy(self.enemy);
1223                 self.dmg_take = self.enemy.dmg_take;
1224                 self.dmg_save = self.enemy.dmg_save;
1225                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1226                 self.fixangle = TRUE;
1227                 self.angles = self.enemy.v_angle;
1228                 //msg_entity = self;
1229                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1230                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1231                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1232                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1233         }
1234 }
1235
1236 float SpectateNext() {
1237         other = find(self.enemy, classname, "player");
1238         if (!other) {
1239                 other = find(other, classname, "player");
1240         }
1241         if (other) {
1242                 self.enemy = other;
1243         }
1244         if(self.enemy.classname == "player") {
1245                 msg_entity = self;
1246                 WriteByte(MSG_ONE, SVC_SETVIEW);
1247                 WriteEntity(MSG_ONE, self.enemy);
1248                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1249                 SpectateUpdate();
1250                 return 1;
1251         } else {
1252                 return 0;
1253         }
1254 }
1255
1256 /*
1257 =============
1258 PlayerPreThink
1259
1260 Called every frame for each client before the physics are run
1261 =============
1262 */
1263 void PlayerPreThink (void)
1264 {
1265         if(self.classname == "player") {
1266                 local vector m1, m2;
1267
1268 //              if(self.netname == "Wazat")
1269 //                      bprint(strcat(self.classname, "\n"));
1270
1271                 CheckRules_Player();
1272
1273                 Nixnex_GiveCurrentWeapon();
1274
1275                 if(self.button7)
1276                         PrintWelcomeMessage(self);
1277
1278                 if(cvar("g_lms") || !cvar("sv_spectate"))
1279                 if((time - self.jointime) <= cvar("welcome_message_time"))
1280                         PrintWelcomeMessage(self);
1281
1282                 if (intermission_running)
1283                 {
1284                         IntermissionThink ();   // otherwise a button could be missed between
1285                         return;                                 // the think tics
1286                 }
1287
1288                 if (self.deadflag != DEAD_NO)
1289                 {
1290                         player_anim();
1291                         if (self.deadflag == DEAD_DYING)
1292                         {
1293                                 if (time > self.dead_time)
1294                                         self.deadflag = DEAD_DEAD;
1295                         }
1296                         else if (self.deadflag == DEAD_DEAD)
1297                         {
1298                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1299                                         self.deadflag = DEAD_RESPAWNABLE;
1300                                 else if (!self.button0 && !self.button2 && !self.button3)
1301                                         self.deadflag = DEAD_RESPAWNABLE;
1302                         }
1303                         else if (self.deadflag == DEAD_RESPAWNABLE)
1304                         {
1305                                 if (self.button0  ||
1306                                     self.button2  ||
1307                                     self.button3  ||
1308                                     self.button4  ||
1309                                     self.button5  ||
1310                                     self.button6  ||
1311                                     self.button7  ||
1312                                     self.button8  ||
1313                                     self.buttonuse ||
1314                                     cvar("g_lms") ||
1315                                     cvar("g_forced_respawn"))
1316                                         respawn();
1317                         }
1318                         return;
1319                 }
1320
1321                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1322                 {
1323                         vector dist;
1324
1325                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1326                         dist = self.oldorigin - self.origin;
1327                         dist_z = 0;
1328                         self.lms_traveled_distance += fabs(vlen(dist));
1329
1330                         if(time > self.lms_nextcheck)
1331                         {
1332                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1333                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1334                                 {
1335                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1336                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1337                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1338                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1339                                 }
1340                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1341                                 self.lms_traveled_distance = 0;
1342                         }
1343                 }
1344
1345                 if (self.button5 && !self.hook.state)
1346                 {
1347                         if (!self.crouch)
1348                         {
1349                                 self.crouch = TRUE;
1350                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1351                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1352                         }
1353                 }
1354                 else
1355                 {
1356                         if (self.crouch)
1357                         {
1358                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1359                                 if (!trace_startsolid)
1360                                 {
1361                                         self.crouch = FALSE;
1362                                         self.view_ofs = PL_VIEW_OFS;
1363                                         setsize (self, PL_MIN, PL_MAX);
1364                                 }
1365                         }
1366                 }
1367
1368                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1369                         local string defaultmodel;
1370                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1371
1372                         if (defaultmodel != self.model)
1373                         {
1374                                 m1 = self.mins;
1375                                 m2 = self.maxs;
1376                                 setmodel_lod (self, defaultmodel);
1377                                 setsize (self, m1, m2);
1378                         }
1379
1380                         if (self.skin != cvar("sv_defaultplayerskin"))
1381                                 self.skin = cvar("sv_defaultplayerskin");
1382                 } else {
1383                         if (self.playermodel != self.model)
1384                         {
1385                                 self.playermodel = CheckPlayerModel(self.playermodel);
1386                                 m1 = self.mins;
1387                                 m2 = self.maxs;
1388                                 setmodel_lod (self, self.playermodel);
1389                                 setsize (self, m1, m2);
1390                         }
1391
1392                         if (self.skin != stof(self.playerskin))
1393                                 self.skin = stof(self.playerskin);
1394                 }
1395                 // Savage: Check for nameless players
1396                 if (strlen(self.netname) < 1) {
1397                         self.netname = "Player";
1398                         stuffcmd(self, "name Player\n");
1399                 }
1400
1401                 GrapplingHookFrame();
1402
1403                 W_WeaponFrame();
1404
1405                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1406                 {
1407                         if (cvar("g_minstagib") && self.button3)
1408                         {
1409                                 if (self.jump_interval <= (time + 0.1))
1410                                 {
1411                                         self.jump_interval = time + 1;
1412                                         W_Laser_Attack();
1413                                 }
1414                         }
1415                         else if (self.viewzoom > 0.4)
1416                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1417                 }
1418                 else if (self.viewzoom < 1.0)
1419                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1420
1421
1422                 if (self.button2)
1423                         PlayerJump ();
1424                 else
1425                         self.flags = self.flags | FL_JUMPRELEASED;
1426
1427                 player_powerups();
1428                 player_regen();
1429                 player_anim();
1430
1431                 if (cvar("g_minstagib"))
1432                         minstagib_ammocheck();
1433
1434                 //self.angles_y=self.v_angle_y + 90;   // temp
1435
1436                 if (self.waterlevel == 2)
1437                         CheckWaterJump ();
1438
1439                 //if (TetrisPreFrame()) return;
1440         } else if(gameover) {
1441                 if (intermission_running)
1442                         IntermissionThink ();   // otherwise a button could be missed between
1443                 return;
1444         } else if(self.classname == "observer") {
1445
1446                 if (self.flags & FL_JUMPRELEASED) {
1447                         if (self.button2 && self.version == cvar("gameversion")) {
1448                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1449                                         self.flags = self.flags & !FL_JUMPRELEASED;
1450                                         self.classname = "player";
1451                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1452                                                 JoinBestTeam(self, 0);
1453                                         if(cvar("g_campaign"))
1454                                                 campaign_bots_may_start = 1;
1455                                         PutClientInServer();
1456                                         if(self.flags & !FL_NOTARGET)
1457                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1458                                         centerprint(self,"");
1459                                         return;
1460                                 } else {
1461                                         self.flags = self.flags & !FL_JUMPRELEASED;
1462                                         stuffcmd(self,"menu_showteamselect\n");
1463                                         return;
1464                                 }
1465                         } else if(self.button0 && self.version == cvar("gameversion")) {
1466                                 self.flags = self.flags & !FL_JUMPRELEASED;
1467                                 if(SpectateNext() == 1) {
1468                                         self.classname = "spectator";
1469                                 }
1470                         }
1471                 } else {
1472                         if (!(self.button0 || self.button2)) {
1473                                 self.flags = self.flags | FL_JUMPRELEASED;
1474                         }
1475                 }
1476                 PrintWelcomeMessage(self);
1477         } else if(self.classname == "spectator") {
1478
1479                 if (self.flags & FL_JUMPRELEASED) {
1480                         if (self.button2 && self.version == cvar("gameversion")) {
1481                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1482                                         self.flags = self.flags & !FL_JUMPRELEASED;
1483                                         self.classname = "player";
1484                                         if(!cvar("g_lms"))
1485                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1486
1487                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1488                                                 JoinBestTeam(self, 0);
1489                                         if(cvar("g_campaign"))
1490                                                 campaign_bots_may_start = 1;
1491                                         PutClientInServer();
1492                                         centerprint(self,"");
1493                                         return;
1494                                 } else {
1495                                         self.flags = self.flags & !FL_JUMPRELEASED;
1496                                         stuffcmd(self,"menu_showteamselect\n");
1497                                         return;
1498                                 }
1499                         } else if(self.button0) {
1500                                 self.flags = self.flags & !FL_JUMPRELEASED;
1501                                 if(SpectateNext() == 1) {
1502                                         self.classname = "spectator";
1503                                 } else {
1504                                         self.classname = "observer";
1505                                         PutClientInServer();
1506                                 }
1507                         } else if (self.button3) {
1508                                 self.flags = self.flags & !FL_JUMPRELEASED;
1509                                 self.classname = "observer";
1510                                 PutClientInServer();
1511                         } else {
1512                                 SpectateUpdate();
1513                         }
1514         } else {
1515                 if (!(self.button0 || self.button3)) {
1516                         self.flags = self.flags | FL_JUMPRELEASED;
1517                 }
1518                 }
1519                 PrintWelcomeMessage(self);
1520         }
1521 }
1522
1523
1524 /*
1525 =============
1526 PlayerPostThink
1527
1528 Called every frame for each client after the physics are run
1529 =============
1530 */
1531 void PlayerPostThink (void)
1532 {
1533         if(self.classname == "player") {
1534                 CheckRules_Player();
1535                 UpdateChatBubble();
1536                 UpdateTeamBubble();
1537                 if (self.deadflag == DEAD_NO)
1538                 if (self.impulse)
1539                         ImpulseCommands ();
1540                 if (intermission_running)
1541                         return;         // intermission or finale
1542
1543                 //PrintWelcomeMessage(self);
1544                 //if (TetrisPostFrame()) return;
1545         } else if (self.classname == "observer") {
1546                 //do nothing
1547         } else if (self.classname == "spectator") {
1548                 //do nothing
1549         }
1550         Arena_Warmup();
1551 }