data/qcsrc/server/cl_client.qc

   1 .float wantswelcomemessage;
   2 .string netname_previous;
   3
   4 void spawnfunc_info_player_survivor (void)
   5 {
   6         spawnfunc_info_player_deathmatch();
   7 }
   8
   9 void spawnfunc_info_player_start (void)
  10 {
  11         spawnfunc_info_player_deathmatch();
  12 }
  13
  14 void spawnfunc_info_player_deathmatch (void)
  15 {
  16         self.classname = "spawnfunc_info_player_deathmatch";
  17         relocate_spawnpoint();
  18 }
  19
  20 void() spawnpoint_use =
  21 {
  22         if(teams_matter)
  23         if(have_team_spawns)
  24         {
  25                 self.team = activator.team;
  26                 some_spawn_has_been_used = 1;
  27         }
  28 };
  29
  30 float spawn_allbad;
  31 float spawn_allgood;
  32 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  33 {
  34         local entity spot, player, nextspot, previousspot, newfirstspot;
  35         local float pcount;
  36         spot = firstspot;
  37         newfirstspot = world;
  38         previousspot = world;
  39         spawn_allgood = TRUE;
  40         spawn_allbad = TRUE;
  41         while (spot)
  42         {
  43                 nextspot = spot.chain;
  44                 // count team mismatches as bad spots
  45
  46                 local float spotactive;
  47                 spotactive = 1;
  48
  49                 // filter out spots for assault
  50                 if(spot.target != "") {
  51                         local entity ent;
  52                         ent = find(world, targetname, spot.target);
  53                         while(ent) {
  54                                 if(ent.classname == "spawnfunc_target_objective")
  55                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  56                                                 spotactive = 0;
  57                                 ent = find(ent, targetname, spot.target);
  58                         }
  59                 }
  60
  61                 if ((!teamcheck || spot.team == teamcheck) && spotactive > 0)
  62                 {
  63                         pcount = 0;
  64                         player = playerlist;
  65                         while (player)
  66                         {
  67                                 if (player != self)
  68                                 if (vlen(player.origin - spot.origin) < mindist)
  69                                         pcount = pcount + 1;
  70                                 player = player.chain;
  71                         }
  72                         if (!pcount)
  73                         {
  74                                 spawn_allbad = FALSE;
  75                                 if (newfirstspot)
  76                                         previousspot.chain = spot;
  77                                 else
  78                                         newfirstspot = spot;
  79                                 previousspot = spot;
  80                                 spot.chain = world;
  81                         }
  82                         else
  83                                 spawn_allgood = FALSE;
  84                 }
  85                 spot = nextspot;
  86         }
  87         // if we couldn't find ANY good points, return world
  88         return newfirstspot;
  89 }
  90
  91 entity Spawn_RandomPoint(entity firstspot)
  92 {
  93         local entity spot;
  94         local float numspots;
  95         // count number of spots
  96         numspots = 0;
  97         spot = firstspot;
  98         while (spot)
  99         {
 100                 numspots = numspots + 1;
 101                 spot = spot.chain;
 102         }
 103         // pick a random one
 104         numspots = numspots * random();
 105         spot = firstspot;
 106         while (spot.chain && numspots >= 1)
 107         {
 108                 numspots = numspots - 1;
 109                 spot = spot.chain;
 110         }
 111         return spot;
 112 }
 113
 114 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
 115 {
 116         local entity best, spot, player;
 117         local float bestrating, rating;
 118         best = world;
 119         bestrating = -1000000;
 120         spot = firstspot;
 121         while (spot)
 122         {
 123                 rating = 1000000000;
 124                 player = playerlist;
 125                 while (player)
 126                 {
 127                         if (player != self)
 128                                 rating = min(rating, vlen(player.origin - spot.origin));
 129                         player = player.chain;
 130                 }
 131                 rating = rating + random() * 16;
 132                 if (bestrating < rating)
 133                 {
 134                         best = spot;
 135                         bestrating = rating;
 136                 }
 137                 spot = spot.chain;
 138         }
 139         return best;
 140 }
 141
 142 /*
 143 =============
 144 SelectSpawnPoint
 145
 146 Finds a point to respawn
 147 =============
 148 */
 149 entity SelectSpawnPoint (float anypoint)
 150 {
 151         local float teamcheck;
 152         local entity firstspot_new;
 153         local entity spot, firstspot, playerlist;
 154
 155         spot = find (world, classname, "testplayerstart");
 156         if (spot)
 157                 return spot;
 158
 159         teamcheck = 0;
 160
 161         if(!anypoint && have_team_spawns)
 162                 teamcheck = self.team;
 163
 164         // get the list of players
 165         playerlist = findchain(classname, "player");
 166         // get the entire list of spots
 167         firstspot = findchain(classname, "spawnfunc_info_player_deathmatch");
 168         // filter out the bad ones
 169         // (note this returns the original list if none survived)
 170         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 171         if(!firstspot_new)
 172                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 173         firstspot = firstspot_new;
 174
 175         // there is 50/50 chance of choosing a random spot or the furthest spot
 176         // (this means that roughly every other spawn will be furthest, so you
 177         // usually won't get fragged at spawn twice in a row)
 178         if (arena_roundbased)
 179         {
 180                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 181                 if(firstspot_new)
 182                         firstspot = firstspot_new;
 183                 spot = Spawn_RandomPoint(firstspot);
 184         }
 185         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 186                 spot = Spawn_RandomPoint(firstspot);
 187         else
 188                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 189
 190         if (!spot)
 191         {
 192                 if(cvar("spawn_debug"))
 193                         GotoNextMap();
 194                 else
 195                 {
 196                         if(some_spawn_has_been_used)
 197                                 return world; // team can't spawn any more, because of actions of other team
 198                         else
 199                                 error("Cannot find a spawn point - please fix the map!");
 200                 }
 201         }
 202
 203         return spot;
 204 }
 205
 206 /*
 207 =============
 208 CheckPlayerModel
 209
 210 Checks if the argument string can be a valid playermodel.
 211 Returns a valid one in doubt.
 212 =============
 213 */
 214 string FallbackPlayerModel = "models/player/marine.zym";
 215 string CheckPlayerModel(string plyermodel) {
 216         if(strlen(plyermodel) < 4)
 217                 return FallbackPlayerModel;
 218         if( substring(plyermodel,0,14) != "models/player/")
 219                 return FallbackPlayerModel;
 220         else if(cvar("sv_servermodelsonly"))
 221         {
 222                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 223                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 224                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 225                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 226                         return FallbackPlayerModel;
 227                 if(!fexists(plyermodel))
 228                         return FallbackPlayerModel;
 229         }
 230         return plyermodel;
 231 }
 232
 233 /*
 234 =============
 235 Client_customizeentityforclient
 236
 237 LOD reduction
 238 =============
 239 */
 240 float Client_customizeentityforclient()
 241 {
 242 #ifdef ALLOW_VARIABLE_LOD
 243         // self: me
 244         // other: the player viewing me
 245         float distance;
 246         float f;
 247
 248         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 249                 return TRUE;
 250
 251         if(other.cvar_cl_playerdetailreduction <= 0)
 252         {
 253                 if(other.cvar_cl_playerdetailreduction <= -2)
 254                         self.modelindex = self.modelindex_lod2;
 255                 else if(other.cvar_cl_playerdetailreduction <= -1)
 256                         self.modelindex = self.modelindex_lod1;
 257                 else
 258                         self.modelindex = self.modelindex_lod0;
 259         }
 260         else
 261         {
 262                 distance = vlen(self.origin - other.origin);
 263                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 264                 if(f > 10000)
 265                         self.modelindex = self.modelindex_lod2;
 266                 else if(f > 5000)
 267                         self.modelindex = self.modelindex_lod1;
 268                 else
 269                         self.modelindex = self.modelindex_lod0;
 270         }
 271 #endif
 272
 273         return TRUE;
 274 }
 275
 276 void UpdatePlayerSounds();
 277 void setmodel_lod(entity e, string modelname)
 278 {
 279 #ifdef ALLOW_VARIABLE_LOD
 280         string s;
 281
 282         // FIXME: this only supports 3-letter extensions
 283         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 284         if(fexists(s))
 285         {
 286                 precache_model(s);
 287                 setmodel(e, s); // players have high precision
 288                 self.modelindex_lod1 = self.modelindex;
 289         }
 290         else
 291                 self.modelindex_lod1 = -1;
 292
 293         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 294         if(fexists(s))
 295         {
 296                 precache_model(s);
 297                 setmodel(e, s); // players have high precision
 298                 self.modelindex_lod2 = self.modelindex;
 299         }
 300         else
 301                 self.modelindex_lod2 = -1;
 302
 303         precache_model(modelname);
 304         setmodel(e, modelname); // players have high precision
 305         self.modelindex_lod0 = self.modelindex;
 306
 307         if(self.modelindex_lod1 < 0)
 308                 self.modelindex_lod1 = self.modelindex;
 309
 310         if(self.modelindex_lod2 < 0)
 311                 self.modelindex_lod2 = self.modelindex;
 312 #else
 313         precache_model(modelname);
 314         setmodel(e, modelname); // players have high precision
 315 #endif
 316         player_setupanimsformodel();
 317         UpdatePlayerSounds();
 318 }
 319
 320 /*
 321 =============
 322 PutObserverInServer
 323
 324 putting a client as observer in the server
 325 =============
 326 */
 327 void PutObserverInServer (void)
 328 {
 329         entity  spot;
 330         spot = SelectSpawnPoint (TRUE);
 331         if(!spot)
 332                 error("No spawnpoints for observers?!?\n");
 333         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 334
 335         if(clienttype(self) == CLIENTTYPE_REAL)
 336         {
 337                 msg_entity = self;
 338                 WriteByte(MSG_ONE, SVC_SETVIEW);
 339                 WriteEntity(MSG_ONE, self);
 340         }
 341
 342         DropAllRunes(self);
 343         kh_Key_DropAll(self, TRUE);
 344
 345         if(self.flagcarried)
 346                 DropFlag(self.flagcarried);
 347
 348         WaypointSprite_PlayerDead();
 349
 350         DistributeFragsAmongTeam(self, self.team, 1);
 351
 352         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 353                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 354         else if(self.killcount != -666)
 355                 bprint ("^4", self.netname, "^4 is spectating now\n");
 356
 357         self.spectatortime = time;
 358
 359         self.classname = "observer";
 360         self.health = -666;
 361         self.takedamage = DAMAGE_NO;
 362         self.solid = SOLID_NOT;
 363         self.movetype = MOVETYPE_NOCLIP;
 364         self.flags = FL_CLIENT | FL_NOTARGET;
 365         self.armorvalue = 666;
 366         self.effects = 0;
 367         self.armorvalue = cvar("g_balance_armor_start");
 368         self.pauserotarmor_finished = 0;
 369         self.pauserothealth_finished = 0;
 370         self.pauseregen_finished = 0;
 371         self.damageforcescale = 0;
 372         self.death_time = 0;
 373         self.dead_frame = 0;
 374         self.deaths = 0;
 375         self.alpha = 0;
 376         self.scale = 0;
 377         self.fade_time = 0;
 378         self.pain_frame = 0;
 379         self.pain_finished = 0;
 380         self.strength_finished = 0;
 381         self.invincible_finished = 0;
 382         self.pushltime = 0;
 383         self.think = SUB_Null;
 384         self.nextthink = 0;
 385         self.hook_time = 0;
 386         self.runes = 0;
 387         self.deadflag = DEAD_NO;
 388         self.angles = spot.angles;
 389         self.angles_z = 0;
 390         self.fixangle = TRUE;
 391         self.crouch = FALSE;
 392
 393         self.view_ofs = PL_VIEW_OFS;
 394         setorigin (self, spot.origin);
 395         setsize (self, '0 0 0', '0 0 0');
 396         self.oldorigin = self.origin;
 397         self.items = 0;
 398         self.model = "";
 399         self.modelindex = 0;
 400         self.weapon = 0;
 401         self.weaponmodel = "";
 402         self.weaponentity = world;
 403         self.killcount = -666;
 404         self.velocity = '0 0 0';
 405         self.avelocity = '0 0 0';
 406         self.punchangle = '0 0 0';
 407         self.punchvector = '0 0 0';
 408         self.oldvelocity = self.velocity;
 409         self.customizeentityforclient = Client_customizeentityforclient;
 410         self.viewzoom = 1;
 411         self.wantswelcomemessage = 1;
 412
 413         if(g_arena)
 414         {
 415                 if(self.frags != -2)
 416                 {
 417                         Spawnqueue_Insert(self);
 418                 }
 419                 else
 420                 {
 421                         Spawnqueue_Unmark(self);
 422                         Spawnqueue_Remove(self);
 423                 }
 424         }
 425         else if(!g_lms)
 426                 self.frags = -666;
 427 }
 428
 429 float RestrictSkin(float s)
 430 {
 431         if(!teams_matter)
 432                 return s;
 433         if(s == 6)
 434                 return 6;
 435         return mod(s, 3);
 436 }
 437
 438 void FixPlayermodel()
 439 {
 440         local string defaultmodel;
 441         local float defaultskin;
 442         local vector m1, m2;
 443
 444         defaultmodel = "";
 445
 446         if(cvar("sv_defaultcharacter") == 1) {
 447                 defaultskin = 0;
 448
 449                 if(teams_matter)
 450                 {
 451                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 452                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 453                 }
 454
 455                 if(defaultmodel == "")
 456                 {
 457                         defaultmodel = cvar_string("sv_defaultplayermodel");
 458                         defaultskin = cvar("sv_defaultplayerskin");
 459                 }
 460         }
 461
 462         if(defaultmodel != "")
 463         {
 464                 if (defaultmodel != self.model)
 465                 {
 466                         m1 = self.mins;
 467                         m2 = self.maxs;
 468                         setmodel_lod (self, defaultmodel);
 469                         setsize (self, m1, m2);
 470                 }
 471
 472                 self.skin = defaultskin;
 473         } else {
 474                 if (self.playermodel != self.model)
 475                 {
 476                         self.playermodel = CheckPlayerModel(self.playermodel);
 477                         m1 = self.mins;
 478                         m2 = self.maxs;
 479                         setmodel_lod (self, self.playermodel);
 480                         setsize (self, m1, m2);
 481                 }
 482
 483                 self.skin = RestrictSkin(stof(self.playerskin));
 484         }
 485
 486         if(!teams_matter)
 487                 if(strlen(cvar_string("sv_defaultplayercolors")))
 488                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 489                                 setcolor(self, cvar("sv_defaultplayercolors"));
 490 }
 491
 492 /*
 493 =============
 494 PutClientInServer
 495
 496 Called when a client spawns in the server
 497 =============
 498 */
 499 void PutClientInServer (void)
 500 {
 501         if(clienttype(self) == CLIENTTYPE_BOT)
 502         {
 503                 self.classname = "player";
 504         }
 505         else if(clienttype(self) == CLIENTTYPE_REAL)
 506         {
 507                 msg_entity = self;
 508                 WriteByte(MSG_ONE, SVC_SETVIEW);
 509                 WriteEntity(MSG_ONE, self);
 510         }
 511
 512         // player is dead and becomes observer
 513         if(g_lms && self.frags < 1)
 514                 self.classname = "observer";
 515
 516         if(g_arena)
 517         if(!self.spawned)
 518                 self.classname = "observer";
 519
 520         if(self.classname == "player") {
 521                 entity  spot;
 522
 523                 spot = SelectSpawnPoint (FALSE);
 524                 if(!spot)
 525                 {
 526                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 527                         return; // spawn failed
 528                 }
 529
 530                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 531
 532                 self.classname = "player";
 533                 self.iscreature = TRUE;
 534                 self.movetype = MOVETYPE_WALK;
 535                 self.solid = SOLID_SLIDEBOX;
 536                 self.flags = FL_CLIENT;
 537                 self.takedamage = DAMAGE_AIM;
 538                 if(g_minstagib)
 539                         self.effects = EF_FULLBRIGHT;
 540                 else
 541                         self.effects = 0;
 542                 self.air_finished = time + 12;
 543                 self.dmg = 2;
 544
 545                 self.ammo_shells = start_ammo_shells;
 546                 self.ammo_nails = start_ammo_nails;
 547                 self.ammo_rockets = start_ammo_rockets;
 548                 self.ammo_cells = start_ammo_cells;
 549                 self.health = start_health;
 550                 self.armorvalue = start_armorvalue;
 551                 self.items = start_items;
 552                 self.switchweapon = start_switchweapon;
 553                 self.cnt = start_switchweapon;
 554                 self.weapon = 0;
 555                 self.jump_interval = time;
 556
 557                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 558                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 559                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 560                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 561                 //extend the pause of rotting if client was reset at the beginning of the countdown
 562                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 563                         self.spawnshieldtime += RESTART_COUNTDOWN;
 564                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 565                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 566                         self.pauseregen_finished += RESTART_COUNTDOWN;
 567                 }
 568                 self.damageforcescale = 2;
 569                 self.death_time = 0;
 570                 self.dead_frame = 0;
 571                 self.alpha = 0;
 572                 self.scale = 0;
 573                 self.fade_time = 0;
 574                 self.pain_frame = 0;
 575                 self.pain_finished = 0;
 576                 self.strength_finished = 0;
 577                 self.invincible_finished = 0;
 578                 self.pushltime = 0;
 579                 //self.speed_finished = 0;
 580                 //self.slowmo_finished = 0;
 581                 // players have no think function
 582                 self.think = SUB_Null;
 583                 self.nextthink = 0;
 584                 self.hook_time = 0;
 585
 586                 self.runes = 0;
 587
 588                 self.deadflag = DEAD_NO;
 589
 590                 self.angles = spot.angles;
 591
 592                 self.angles_z = 0; // never spawn tilted even if the spot says to
 593                 self.fixangle = TRUE; // turn this way immediately
 594                 self.velocity = '0 0 0';
 595                 self.avelocity = '0 0 0';
 596                 self.punchangle = '0 0 0';
 597                 self.punchvector = '0 0 0';
 598                 self.oldvelocity = self.velocity;
 599
 600                 self.viewzoom = 0.6;
 601                 self.has_zoomed = 0;
 602
 603                 self.customizeentityforclient = Client_customizeentityforclient;
 604
 605                 self.model = "";
 606                 FixPlayermodel();
 607
 608                 self.crouch = FALSE;
 609                 self.view_ofs = PL_VIEW_OFS;
 610                 setsize (self, PL_MIN, PL_MAX);
 611                 self.spawnorigin = spot.origin;
 612                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 613                 // don't reset back to last position, even if new position is stuck in solid
 614                 self.oldorigin = self.origin;
 615
 616                 if(g_arena)
 617                 {
 618                         Spawnqueue_Remove(self);
 619                         Spawnqueue_Mark(self);
 620                 }
 621
 622                 self.event_damage = PlayerDamage;
 623
 624                 self.bot_attack = TRUE;
 625
 626                 self.statdraintime = time + 5;
 627                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 628
 629                 if(self.killcount == -666) {
 630                         self.killcount = 0;
 631                         if(!g_arena)
 632                         if(!g_lms)
 633                                 self.frags = 0;
 634                 }
 635
 636                 self.cnt = WEP_LASER;
 637                 self.nixnex_lastchange_id = -1;
 638
 639                 CL_SpawnWeaponentity();
 640                 self.alpha = default_player_alpha;
 641                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 642                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 643
 644                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 645                 self.lms_traveled_distance = 0;
 646                 self.speedrunning = FALSE;
 647
 648                 if(cvar("spawn_debug"))
 649                 {
 650                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 651                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 652                 }
 653
 654                 //stuffcmd(self, "chase_active 0");
 655                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 656
 657                 if (cvar("g_spawnsound"))
 658                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 659
 660                 if(g_assault) {
 661                         if(self.team == assault_attacker_team)
 662                                 centerprint(self, "You are attacking!\n");
 663                         else
 664                                 centerprint(self, "You are defending!\n");
 665                 }
 666
 667         } else if(self.classname == "observer") {
 668                 PutObserverInServer ();
 669         }
 670 }
 671
 672 /*
 673 =============
 674 SetNewParms
 675 =============
 676 */
 677 void SetNewParms (void)
 678 {
 679
 680 }
 681
 682 /*
 683 =============
 684 SetChangeParms
 685 =============
 686 */
 687 void SetChangeParms (void)
 688 {
 689
 690 }
 691
 692 /*
 693 =============
 694 ClientKill
 695
 696 Called when a client types 'kill' in the console
 697 =============
 698 */
 699
 700 void ClientKill_Now_TeamChange()
 701 {
 702         if(self.killindicator_teamchange == -1)
 703         {
 704                 self.team = -1;
 705                 JoinBestTeam( self, FALSE, FALSE );
 706         }
 707         else
 708         {
 709                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 710         }
 711 }
 712
 713 void ClientKill_Now()
 714 {
 715         if(self.killindicator_teamchange)
 716                 ClientKill_Now_TeamChange();
 717
 718         // in any case:
 719         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 720 }
 721 void KillIndicator_Think()
 722 {
 723         if (!self.owner.modelindex)
 724         {
 725                 self.owner.killindicator = world;
 726                 remove(self);
 727                 return;
 728         }
 729
 730         if(self.cnt <= 0)
 731         {
 732                 self = self.owner;
 733                 ClientKill_Now(); // no oldself needed
 734                 return;
 735         }
 736         else
 737         {
 738                 if(self.cnt <= 10)
 739                 {
 740                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 741                         play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 742                 }
 743                 if(self.owner.killindicator_teamchange)
 744                 {
 745                         if(self.owner.killindicator_teamchange == -1)
 746                                 centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 747                         else
 748                                 centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 749                 }
 750                 else
 751                         centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 752                 self.nextthink = time + 1;
 753                 self.cnt -= 1;
 754         }
 755 }
 756
 757 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 758 {
 759         float killtime;
 760         killtime = cvar("g_balance_kill_delay");
 761
 762         self.killindicator_teamchange = targetteam;
 763
 764         if(!self.killindicator)
 765         {
 766                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 767                 {
 768                         ClientKill_Now();
 769                 }
 770                 else
 771                 {
 772                         self.killindicator = spawn();
 773                         self.killindicator.owner = self;
 774                         self.killindicator.scale = 0.5;
 775                         setattachment(self.killindicator, self, "");
 776                         setorigin(self.killindicator, '0 0 52');
 777                         self.killindicator.think = KillIndicator_Think;
 778                         self.killindicator.nextthink = time;
 779                         self.killindicator.cnt = ceil(killtime);
 780                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 781                 }
 782         }
 783         if(self.killindicator)
 784         {
 785                 if(targetteam)
 786                         self.killindicator.colormod = TeamColor(targetteam);
 787                 else
 788                         self.killindicator.colormod = '0 0 0';
 789         }
 790 }
 791
 792 void ClientKill (void)
 793 {
 794         ClientKill_TeamChange(0);
 795 }
 796
 797 void DoTeamChange(float destteam)
 798 {
 799         if(!cvar("teamplay"))
 800         {
 801                 if(destteam >= 0)
 802                         SetPlayerColors(self, destteam);
 803                 return;
 804         }
 805         if(destteam == self.team && !self.killindicator)
 806                 return;
 807         ClientKill_TeamChange(destteam);
 808 }
 809
 810 void FixClientCvars(entity e)
 811 {
 812         // send prediction settings to the client
 813         stuffcmd(e, "\nin_bindmap 0 0\n");
 814         /*
 815          * we no longer need to stuff this. Remove this comment block if you feel
 816          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 817         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 818         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 819         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 820         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 821         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 822         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 823         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 824         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 825         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 826         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 827         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 828         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 829         stuffcmd(e, "cl_movement_edgefriction 1\n");
 830          */
 831 }
 832
 833 /*
 834 =============
 835 ClientConnect
 836
 837 Called when a client connects to the server
 838 =============
 839 */
 840 string ColoredTeamName(float t);
 841 //void dom_player_join_team(entity pl);
 842 void ClientConnect (void)
 843 {
 844         local string s;
 845         float wep;
 846
 847         if(Ban_IsClientBanned(self))
 848         {
 849                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 850                 dropclient(self);
 851                 bprint(s);
 852                 return;
 853         }
 854
 855         self.classname = "player_joining";
 856         self.flags = self.flags | FL_CLIENT;
 857         self.version_nagtime = time + 10 + random() * 10;
 858
 859         if(player_count<0)
 860         {
 861                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 862                 player_count = 0;
 863         }
 864
 865         bot_clientconnect();
 866
 867         //if(g_domination)
 868         //      dom_player_join_team(self);
 869
 870         //JoinBestTeam(self, FALSE, FALSE);
 871
 872         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 873                 self.classname = "observer";
 874         } else {
 875                 self.classname = "player";
 876                 campaign_bots_may_start = 1;
 877         }
 878
 879         self.playerid = (playerid_last = playerid_last + 1);
 880         if(cvar("sv_eventlog"))
 881         {
 882                 if(clienttype(self) == CLIENTTYPE_REAL)
 883                         s = "player";
 884                 else
 885                         s = "bot";
 886                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 887                 s = strcat(":team:", ftos(self.playerid), ":");
 888                 s = strcat(s, ftos(self.team));
 889                 GameLogEcho(s, FALSE);
 890         }
 891         self.netname_previous = strzone(self.netname);
 892
 893         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 894
 895         bprint ("^4",self.netname);
 896         bprint ("^4 connected");
 897
 898         if(g_domination || g_ctf)
 899         {
 900                 bprint(" and joined the ");
 901                 bprint(ColoredTeamName(self.team));
 902         }
 903
 904         bprint("\n");
 905
 906         self.welcomemessage_time = 0;
 907
 908         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 909         // TODO: is this being used for anything else than cd tracks?
 910         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 911         //
 912         stuffcmd(self, "cl_particles_reloadeffects\n");
 913
 914         FixClientCvars(self);
 915
 916         // spawnfunc_waypoint sprites
 917         WaypointSprite_InitClient(self);
 918
 919         // Wazat's grappling hook
 920         SetGrappleHookBindings();
 921
 922         // get autoswitch state from player when he toggles it
 923         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
 924
 925         // get version info from player
 926         stuffcmd(self, "cmd clientversion $gameversion\n");
 927
 928         // send all weapon info strings
 929         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
 930         wep = WEP_FIRST;
 931         while (wep <= WEP_LAST)
 932         {
 933                 weapon_action(wep, WR_REGISTER);
 934                 wep = wep + 1;
 935         }
 936
 937         // get other cvars from player
 938         GetCvars(0);
 939
 940         // set cvar for team scoreboard
 941         if (teams_matter)
 942         {
 943                 local float t;
 944                 t = cvar("teamplay");
 945                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 946                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 947         }
 948         else
 949                 stuffcmd(self, "set teamplay 0\n");
 950
 951         // notify about available teams
 952         if(teamplay)
 953         {
 954                 CheckAllowedTeams(self);
 955                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
 956                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
 957         }
 958         else
 959                 stuffcmd(self, "set _teams_available 0\n");
 960
 961         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
 962
 963         if(g_lms)
 964         {
 965                 self.frags = LMS_NewPlayerLives();
 966                 if(!self.frags)
 967                         self.frags = -666;
 968         }
 969         else if(g_arena)
 970         {
 971                 self.classname = "observer";
 972                 Spawnqueue_Insert(self);
 973         }
 974
 975         bot_relinkplayerlist();
 976
 977         self.spectatortime = time;
 978         if(blockSpectators)
 979         {
 980                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 981         }
 982
 983         self.jointime = time;
 984         self.allowedTimeouts = cvar("sv_timeout_number");
 985 }
 986
 987 /*
 988 =============
 989 ClientDisconnect
 990
 991 Called when a client disconnects from the server
 992 =============
 993 */
 994 void(entity e) DropFlag;
 995 .entity chatbubbleentity;
 996 .entity teambubbleentity;
 997 void ClientDisconnect (void)
 998 {
 999         float save;
1000         if(cvar("sv_eventlog"))
1001                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1002         bprint ("^4",self.netname);
1003         bprint ("^4 disconnected\n");
1004
1005         if (self.chatbubbleentity)
1006         {
1007                 remove (self.chatbubbleentity);
1008                 self.chatbubbleentity = world;
1009         }
1010
1011         if (self.teambubbleentity)
1012         {
1013                 remove (self.teambubbleentity);
1014                 self.teambubbleentity = world;
1015         }
1016
1017         if (self.killindicator)
1018         {
1019                 remove (self.killindicator);
1020                 self.killindicator = world;
1021         }
1022
1023         WaypointSprite_PlayerGone();
1024
1025         DropAllRunes(self);
1026         kh_Key_DropAll(self, TRUE);
1027
1028         if(self.flagcarried)
1029                 DropFlag(self.flagcarried);
1030
1031         DistributeFragsAmongTeam(self, self.team, 1);
1032
1033         save = self.flags;
1034         self.flags = self.flags - (self.flags & FL_CLIENT);
1035         bot_relinkplayerlist();
1036         self.flags = save;
1037
1038         // remove laserdot
1039         if(self.weaponentity)
1040                 if(self.weaponentity.lasertarget)
1041                         remove(self.weaponentity.lasertarget);
1042
1043         if(g_arena)
1044         {
1045                 Spawnqueue_Unmark(self);
1046                 Spawnqueue_Remove(self);
1047         }
1048
1049         if(self.netname_previous)
1050                 strunzone(self.netname_previous);
1051
1052         // free cvars
1053         GetCvars(-1);
1054 }
1055
1056 .float buttonchat;
1057 void() ChatBubbleThink =
1058 {
1059         self.nextthink = time;
1060         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1061         {
1062                 self.owner.chatbubbleentity = world;
1063                 remove(self);
1064                 return;
1065         }
1066         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1067         if (self.owner.buttonchat && !self.owner.deadflag)
1068                 self.model = self.mdl;
1069         else
1070                 self.model = "";
1071 };
1072
1073 void() UpdateChatBubble =
1074 {
1075         if (!self.modelindex)
1076                 return;
1077         // spawn a chatbubble entity if needed
1078         if (!self.chatbubbleentity)
1079         {
1080                 self.chatbubbleentity = spawn();
1081                 self.chatbubbleentity.owner = self;
1082                 self.chatbubbleentity.exteriormodeltoclient = self;
1083                 self.chatbubbleentity.think = ChatBubbleThink;
1084                 self.chatbubbleentity.nextthink = time;
1085                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1086                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1087                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1088                 self.chatbubbleentity.model = "";
1089                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1090         }
1091 }
1092
1093
1094 void() TeamBubbleThink =
1095 {
1096         self.nextthink = time;
1097         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1098         {
1099                 self.owner.teambubbleentity = world;
1100                 remove(self);
1101                 return;
1102         }
1103 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1104         if (self.owner.buttonchat || self.owner.deadflag || self.owner.killindicator)
1105                 self.model = "";
1106         else
1107                 self.model = self.mdl;
1108
1109 };
1110
1111 float() TeamBubble_customizeentityforclient
1112 {
1113         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1114 }
1115
1116 void() UpdateTeamBubble =
1117 {
1118         if (!self.modelindex || !cvar("teamplay"))
1119                 return;
1120         // spawn a teambubble entity if needed
1121         if (!self.teambubbleentity && cvar("teamplay"))
1122         {
1123                 self.teambubbleentity = spawn();
1124                 self.teambubbleentity.owner = self;
1125                 self.teambubbleentity.exteriormodeltoclient = self;
1126                 self.teambubbleentity.think = TeamBubbleThink;
1127                 self.teambubbleentity.nextthink = time;
1128                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1129 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1130                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1131                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1132                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1133                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1134                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1135                 self.teambubbleentity.effects = EF_LOWPRECISION;
1136         }
1137 }
1138
1139 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1140 // added to the model skins
1141 /*void() UpdateColorModHack =
1142 {
1143         local float c;
1144         c = self.clientcolors & 15;
1145         // LordHavoc: only bothering to support white, green, red, yellow, blue
1146              if (teamplay == 0) self.colormod = '0 0 0';
1147         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1148         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1149         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1150         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1151         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1152         else self.colormod = '1 1 1';
1153 };*/
1154
1155 void respawn(void)
1156 {
1157         CopyBody(1);
1158         self.effects |= EF_NODRAW; // prevent another CopyBody
1159         PutClientInServer();
1160 }
1161
1162 /**
1163  * When sv_timeout is used this function returs strings like
1164  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1165  * Called by centerprint functions
1166  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1167  */
1168 string getTimeoutText(float addOneSecond) {
1169         if (!cvar("sv_timeout") || !timeoutStatus)
1170                 return "";
1171
1172         local string retStr;
1173         if (timeoutStatus == 1) {
1174                 if (addOneSecond == 1) {
1175                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1176                 }
1177                 else {
1178                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1179                 }
1180                 return retStr;
1181         }
1182         else if (timeoutStatus == 2) {
1183                 if (addOneSecond) {
1184                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1185                         //don't show messages like "Timeout ends in 0 seconds"...
1186                         if ((remainingTimeoutTime + 1) > 0)
1187                                 return retStr;
1188                         else
1189                                 return "";
1190                 }
1191                 else {
1192                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1193                         //don't show messages like "Timeout ends in 0 seconds"...
1194                         if (remainingTimeoutTime > 0)
1195                                 return retStr;
1196                         else
1197                                 return "";
1198                 }
1199         }
1200         else return "";
1201 }
1202
1203 void player_powerups (void)
1204 {
1205         if (g_minstagib)
1206         {
1207                 if (self.items & IT_STRENGTH)
1208                 {
1209                         if (time > self.strength_finished)
1210                         {
1211                                 if (g_minstagib_invis_alpha > 0)
1212                                 {
1213                                         self.alpha = default_player_alpha;
1214                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1215                                         self.effects = self.effects | EF_FULLBRIGHT;
1216                                 }
1217                                 else
1218                                 {
1219                                         self.effects -= self.effects & EF_NODRAW;
1220                                 }
1221                                 self.items = self.items - (self.items & IT_STRENGTH);
1222                                 sprint(self, "^3Invisibility has worn off\n");
1223                         }
1224                 }
1225                 else
1226                 {
1227                         if (time < self.strength_finished)
1228                         {
1229                                 if (g_minstagib_invis_alpha > 0)
1230                                 {
1231                                         self.alpha = g_minstagib_invis_alpha;
1232                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1233                                         self.effects -= self.effects & EF_FULLBRIGHT;
1234                                 }
1235                                 else
1236                                 {
1237                                         self.effects = self.effects | EF_NODRAW;
1238                                 }
1239                                 self.items = self.items | IT_STRENGTH;
1240                                 sprint(self, "^3You are invisible\n");
1241                         }
1242                 }
1243
1244                 if (self.items & IT_INVINCIBLE)
1245                 {
1246                         if (time > self.invincible_finished)
1247                         {
1248                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1249                                 sprint(self, "^3Speed has worn off\n");
1250                         }
1251                 }
1252                 else
1253                 {
1254                         if (time < self.invincible_finished)
1255                         {
1256                                 self.items = self.items | IT_INVINCIBLE;
1257                                 sprint(self, "^3You are on speed\n");
1258                         }
1259                 }
1260                 return;
1261         }
1262
1263         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1264         if (self.items & IT_STRENGTH)
1265         {
1266                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1267                 if (time > self.strength_finished)
1268                 {
1269                         self.items = self.items - (self.items & IT_STRENGTH);
1270                         sprint(self, "^3Strength has worn off\n");
1271                 }
1272         }
1273         else
1274         {
1275                 if (time < self.strength_finished)
1276                 {
1277                         self.items = self.items | IT_STRENGTH;
1278                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1279                 }
1280         }
1281         if (self.items & IT_INVINCIBLE)
1282         {
1283                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1284                 if (time > self.invincible_finished)
1285                 {
1286                         self.items = self.items - (self.items & IT_INVINCIBLE);
1287                         sprint(self, "^3Shield has worn off\n");
1288                 }
1289         }
1290         else
1291         {
1292                 if (time < self.invincible_finished)
1293                 {
1294                         self.items = self.items | IT_INVINCIBLE;
1295                         sprint(self, "^3Shield surrounds you\n");
1296                 }
1297         }
1298
1299         if (cvar("g_fullbrightplayers"))
1300                 self.effects = self.effects | EF_FULLBRIGHT;
1301
1302         // midair gamemode: damage only while in the air
1303         // if in midair mode, being on ground grants temporary invulnerability
1304         // (this is so that multishot weapon don't clear the ground flag on the
1305         // first damage in the frame, leaving the player vulnerable to the
1306         // remaining hits in the same frame)
1307         if (self.flags & FL_ONGROUND)
1308         if (g_midair)
1309                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1310
1311         if (time < self.spawnshieldtime)
1312                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1313 }
1314
1315 float CalcRegen(float current, float stable, float regenfactor)
1316 {
1317         if(current > stable)
1318                 return current;
1319         else if(current > stable - 0.25) // when close enough, "snap"
1320                 return stable;
1321         else
1322                 return min(stable, current + (stable - current) * regenfactor * frametime);
1323 }
1324
1325 void player_regen (void)
1326 {
1327         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1328         maxh = cvar("g_balance_health_stable");
1329         maxa = cvar("g_balance_armor_stable");
1330         limith = cvar("g_balance_health_limit");
1331         limita = cvar("g_balance_armor_limit");
1332
1333         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1334                 return;
1335
1336         max_mod = regen_mod = rot_mod = limit_mod = 1;
1337
1338         if (self.runes & RUNE_REGEN)
1339         {
1340                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1341                 {
1342                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1343                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1344                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1345                 }
1346                 else
1347                 {
1348                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1349                         max_mod = cvar("g_balance_rune_regen_hpmod");
1350                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1351                 }
1352         }
1353         else if (self.runes & CURSE_VENOM)
1354         {
1355                 max_mod = cvar("g_balance_curse_venom_hpmod");
1356                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1357                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1358                 else
1359                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1360                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1361                 //if (!self.runes & RUNE_REGEN)
1362                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1363         }
1364         maxh = maxh * max_mod;
1365         //maxa = maxa * max_mod;
1366         limith = limith * limit_mod;
1367         limita = limita * limit_mod;
1368
1369         if (self.armorvalue > maxa)
1370         {
1371                 if (time > self.pauserotarmor_finished)
1372                 {
1373                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1374                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1375                 }
1376         }
1377         else if (self.armorvalue < maxa)
1378         {
1379                 if (time > self.pauseregen_finished)
1380                 {
1381                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1382                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1383                 }
1384         }
1385         if (self.health > maxh)
1386         {
1387                 if (time > self.pauserothealth_finished)
1388                 {
1389                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1390                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1391                 }
1392         }
1393         else if (self.health < maxh)
1394         {
1395                 if (time > self.pauseregen_finished)
1396                 {
1397                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1398                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1399                 }
1400         }
1401
1402         if (self.health > limith)
1403                 self.health = limith;
1404         if (self.armorvalue > limita)
1405                 self.armorvalue = limita;
1406
1407         // if player rotted to death...  die!
1408         if(self.health < 1)
1409                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1410 }
1411
1412 /*
1413 ======================
1414 spectate mode routines
1415 ======================
1416 */
1417 void SpectateCopy(entity spectatee) {
1418         self.armortype = spectatee.armortype;
1419         self.armorvalue = spectatee.armorvalue;
1420         self.currentammo = spectatee.currentammo;
1421         self.effects = spectatee.effects;
1422         self.health = spectatee.health;
1423         self.impulse = 0;
1424         self.items = spectatee.items;
1425         self.punchangle = spectatee.punchangle;
1426         self.view_ofs = spectatee.view_ofs;
1427         self.v_angle = spectatee.v_angle;
1428         self.viewzoom = spectatee.viewzoom;
1429         self.velocity = spectatee.velocity;
1430         self.dmg_take = spectatee.dmg_take;
1431         self.dmg_save = spectatee.dmg_save;
1432         self.dmg_inflictor = spectatee.dmg_inflictor;
1433         self.angles = spectatee.v_angle;
1434         self.fixangle = TRUE;
1435         setorigin(self, spectatee.origin);
1436         setsize(self, spectatee.mins, spectatee.maxs);
1437 }
1438
1439 void SpectateUpdate() {
1440         if(!self.enemy)
1441                         PutObserverInServer();
1442
1443         if (self != self.enemy) {
1444                 if(self.enemy.flags & FL_NOTARGET)
1445                         PutObserverInServer();
1446                 SpectateCopy(self.enemy);
1447                 //msg_entity = self;
1448                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1449                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1450                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1451                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1452         }
1453 }
1454
1455 float SpectateNext() {
1456         other = find(self.enemy, classname, "player");
1457         if (!other) {
1458                 other = find(other, classname, "player");
1459         }
1460         if (other) {
1461                 self.enemy = other;
1462         }
1463         if(self.enemy.classname == "player") {
1464                 msg_entity = self;
1465                 WriteByte(MSG_ONE, SVC_SETVIEW);
1466                 WriteEntity(MSG_ONE, self.enemy);
1467                 self.wantswelcomemessage = 1;
1468                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1469                 SpectateUpdate();
1470                 return 1;
1471         } else {
1472                 return 0;
1473         }
1474 }
1475
1476 /*
1477 =============
1478 ShowRespawnCountdown()
1479
1480 Update a respawn countdown display.
1481 =============
1482 */
1483 void ShowRespawnCountdown()
1484 {
1485         float number;
1486         if(self.deadflag == DEAD_NO) // just respawned?
1487                 return;
1488         else
1489         {
1490                 number = ceil(self.death_time - time);
1491                 if(number <= 0)
1492                         return;
1493                 if(number <= self.respawn_countdown)
1494                 {
1495                         self.respawn_countdown = number - 1;
1496                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1497                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1498                 }
1499         }
1500 }
1501
1502 void LeaveSpectatorMode()
1503 {
1504         if(isJoinAllowed()) {
1505                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1506                         self.classname = "player";
1507                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1508                                 JoinBestTeam(self, FALSE, TRUE);
1509                         if(cvar("g_campaign"))
1510                                 campaign_bots_may_start = 1;
1511                         PutClientInServer();
1512                         if(!(self.flags & FL_NOTARGET))
1513                                 bprint ("^4", self.netname, "^4 is playing now\n");
1514                         centerprint(self,"");
1515                         return;
1516                 } else {
1517                         stuffcmd(self,"menu_showteamselect\n");
1518                         return;
1519                 }
1520         }
1521         else {
1522                 //player may not join because of g_maxplayers is set
1523                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1524         }
1525 }
1526
1527 /**
1528  * Determines whether the player is allowed to join. This depends on cvar
1529  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1530  * it checks whether the number of currently playing players exceeds g_maxplayers.
1531  * @return bool TRUE if the player is allowed to join, false otherwise
1532  */
1533 float isJoinAllowed() {
1534         if (!cvar("g_maxplayers"))
1535                 return TRUE;
1536
1537         local entity e;
1538         local float currentlyPlaying;
1539         FOR_EACH_REALPLAYER(e) {
1540                 if(e.classname == "player")
1541                         currentlyPlaying += 1;
1542         }
1543         if(currentlyPlaying < cvar("g_maxplayers"))
1544                 return TRUE;
1545
1546         return FALSE;
1547 }
1548
1549 /**
1550  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1551  * g_maxplayers_spectator_blocktime seconds
1552  */
1553 void checkSpectatorBlock() {
1554         if(self.classname == "spectator" || self.classname == "observer") {
1555                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1556                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1557                         dropclient(self);
1558                 }
1559         }
1560 }
1561
1562 float vercmp_recursive(string v1, string v2)
1563 {
1564         float dot1, dot2;
1565         string s1, s2;
1566         float r;
1567
1568         dot1 = strstrofs(v1, ".", 0);
1569         dot2 = strstrofs(v2, ".", 0);
1570         if(dot1 == -1)
1571                 s1 = v1;
1572         else
1573                 s1 = substring(v1, 0, dot1);
1574         if(dot2 == -1)
1575                 s2 = v2;
1576         else
1577                 s2 = substring(v2, 0, dot2);
1578
1579         r = stof(s1) - stof(s2);
1580         if(r != 0)
1581                 return r;
1582
1583         r = strcasecmp(s1, s2);
1584         if(r != 0)
1585                 return r;
1586
1587         if(dot1 == -1)
1588                 if(dot2 == -1)
1589                         return 0;
1590                 else
1591                         return -1;
1592         else
1593                 if(dot2 == -1)
1594                         return 1;
1595                 else
1596                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1597 }
1598
1599 float vercmp(string v1, string v2)
1600 {
1601         if(strcasecmp(v1, v2) == 0) // early out check
1602                 return 0;
1603         return vercmp_recursive(v1, v2);
1604 }
1605
1606 /*
1607 =============
1608 PlayerPreThink
1609
1610 Called every frame for each client before the physics are run
1611 =============
1612 */
1613 void() ctf_setstatus;
1614 .float vote_nagtime;
1615 void PlayerPreThink (void)
1616 {
1617         if(blockSpectators)
1618                 checkSpectatorBlock();
1619
1620         if(self.netname_previous != self.netname)
1621         {
1622                 if(cvar("sv_eventlog"))
1623                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1624                 if(self.netname_previous)
1625                         strunzone(self.netname_previous);
1626                 self.netname_previous = strzone(self.netname);
1627         }
1628
1629         // version nagging
1630         if(self.version_nagtime)
1631                 if(self.cvar_g_nexuizversion)
1632                         if(time > self.version_nagtime)
1633                         {
1634                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1635                                 {
1636                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1637                                         {
1638                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1639                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1640                                         }
1641                                         else
1642                                         {
1643                                                 float r;
1644                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1645                                                 if(r < 0)
1646                                                 {
1647                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1648                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1649                                                 }
1650                                                 else if(r > 0)
1651                                                 {
1652                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1653                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1654                                                 }
1655                                         }
1656                                 }
1657                                 self.version_nagtime = 0;
1658                         }
1659
1660         // vote nagging
1661         if(self.cvar_scr_centertime)
1662                 if(time > self.vote_nagtime)
1663                 {
1664                         VoteNag();
1665                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1666                 }
1667
1668         // GOD MODE info
1669         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1670         {
1671                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1672                 self.max_armorvalue = 0;
1673         }
1674
1675         if(frametime)
1676                 antilag_record(self);
1677
1678         if(self.classname == "player") {
1679 //              if(self.netname == "Wazat")
1680 //                      bprint(self.classname, "\n");
1681
1682                 CheckRules_Player();
1683
1684                 if(self.button7)
1685                         PrintWelcomeMessage(self);
1686
1687                 if(g_lms || !cvar("sv_spectate"))
1688                 if((time - self.jointime) <= cvar("welcome_message_time"))
1689                         PrintWelcomeMessage(self);
1690
1691                 if (intermission_running)
1692                 {
1693                         IntermissionThink ();   // otherwise a button could be missed between
1694                         return;                                 // the think tics
1695                 }
1696
1697                 if(self.teleport_time)
1698                 if(time > self.teleport_time)
1699                 {
1700                         self.teleport_time = 0;
1701                         self.effects = self.effects - (self.effects & EF_NODRAW);
1702                         if(self.weaponentity)
1703                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1704                 }
1705
1706                 Nixnex_GiveCurrentWeapon();
1707
1708                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1709                         UpdateSelectedPlayer();
1710
1711                 //don't allow the player to turn around while game is paused!
1712                 if(timeoutStatus == 2) {
1713                         self.v_angle = self.lastV_angle;
1714                         self.angles = self.lastV_angle;
1715                         self.fixangle = TRUE;
1716                 }
1717
1718                 if (self.deadflag != DEAD_NO)
1719                 {
1720                         float button_pressed, force_respawn;
1721                         player_anim();
1722                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1723                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1724                         if (self.deadflag == DEAD_DYING)
1725                         {
1726                                 if(force_respawn)
1727                                         self.deadflag = DEAD_RESPAWNING;
1728                                 else if(!button_pressed)
1729                                         self.deadflag = DEAD_DEAD;
1730                         }
1731                         else if (self.deadflag == DEAD_DEAD)
1732                         {
1733                                 if(button_pressed)
1734                                         self.deadflag = DEAD_RESPAWNABLE;
1735                         }
1736                         else if (self.deadflag == DEAD_RESPAWNABLE)
1737                         {
1738                                 if(!button_pressed)
1739                                         self.deadflag = DEAD_RESPAWNING;
1740                         }
1741                         else if (self.deadflag == DEAD_RESPAWNING)
1742                         {
1743                                 if(time > self.death_time)
1744                                 {
1745                                         self.death_time = time + 1; // only retry once a second
1746                                         respawn();
1747                                 }
1748                         }
1749                         ShowRespawnCountdown();
1750                         return;
1751                 }
1752
1753                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1754                 {
1755                         vector dist;
1756
1757                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1758                         dist = self.oldorigin - self.origin;
1759                         dist_z = 0;
1760                         self.lms_traveled_distance += fabs(vlen(dist));
1761
1762                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1763                         {
1764                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1765                                 self.lms_traveled_distance = 0;
1766                         }
1767
1768                         if(time > self.lms_nextcheck)
1769                         {
1770                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1771                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1772                                 {
1773                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1774                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1775                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1776                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1777                                 }
1778                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1779                                 self.lms_traveled_distance = 0;
1780                         }
1781                 }
1782
1783                 if (self.button5 && !self.hook.state)
1784                 {
1785                         if (!self.crouch)
1786                         {
1787                                 self.crouch = TRUE;
1788                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1789                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1790                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
1791                         }
1792                 }
1793                 else
1794                 {
1795                         if (self.crouch)
1796                         {
1797                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1798                                 if (!trace_startsolid)
1799                                 {
1800                                         self.crouch = FALSE;
1801                                         self.view_ofs = PL_VIEW_OFS;
1802                                         setsize (self, PL_MIN, PL_MAX);
1803                                 }
1804                         }
1805                 }
1806
1807                 FixPlayermodel();
1808
1809                 GrapplingHookFrame();
1810
1811                 W_WeaponFrame();
1812
1813                 {
1814                         float zoomfactor, zoomspeed, zoomdir;
1815                         zoomfactor = self.cvar_cl_zoomfactor;
1816                         if(zoomfactor < 1 || zoomfactor > 16)
1817                                 zoomfactor = 2.5;
1818                         zoomspeed = self.cvar_cl_zoomspeed;
1819                         if(zoomspeed >= 0) // < 0 is instant zoom
1820                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1821                                         zoomspeed = 3.5;
1822
1823                         zoomdir = self.button4;
1824                         if(self.button3)
1825                                 if(self.weapon == WEP_NEX)
1826                                         if(!g_minstagib)
1827                                                 zoomdir = 1;
1828
1829                         if(zoomdir)
1830                                 self.has_zoomed = 1;
1831
1832                         if(self.has_zoomed)
1833                         {
1834                                 if(zoomspeed <= 0) // instant zoom
1835                                 {
1836                                         if(zoomdir)
1837                                                 self.viewzoom = 1 / zoomfactor;
1838                                         else
1839                                                 self.viewzoom = 1;
1840                                 }
1841                                 else
1842                                 {
1843                                         // geometric zoom would be:
1844                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1845                                         // however, testing showed that arithmetic/harmonic zoom works better
1846                                         if(zoomdir)
1847                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1848                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1849                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1850                                         else
1851                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1852                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1853                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1854                                 }
1855                         }
1856                         else
1857                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1858                 }
1859
1860                 player_powerups();
1861                 player_regen();
1862                 player_anim();
1863
1864                 if (g_minstagib)
1865                         minstagib_ammocheck();
1866
1867                 ctf_setstatus();
1868                 kh_setstatus();
1869
1870                 //self.angles_y=self.v_angle_y + 90;   // temp
1871
1872                 //if (TetrisPreFrame()) return;
1873         } else if(gameover) {
1874                 if (intermission_running)
1875                         IntermissionThink ();   // otherwise a button could be missed between
1876                 return;
1877         } else if(self.classname == "observer") {
1878                 if (self.flags & FL_JUMPRELEASED) {
1879                         if (self.button2 && self.version == cvar("gameversion")) {
1880                                 self.welcomemessage_time = 0;
1881                                 self.flags = self.flags - FL_JUMPRELEASED;
1882                                 LeaveSpectatorMode();
1883                                 return;
1884                         } else if(self.button0 && self.version == cvar("gameversion")) {
1885                                 self.welcomemessage_time = 0;
1886                                 self.flags = self.flags - FL_JUMPRELEASED;
1887                                 if(SpectateNext() == 1) {
1888                                         self.classname = "spectator";
1889                                 }
1890                         }
1891                 } else {
1892                         if (!(self.button0 || self.button2)) {
1893                                 self.flags = self.flags | FL_JUMPRELEASED;
1894                         }
1895                 }
1896                 if(self.button4)
1897                         self.wantswelcomemessage = 0;
1898                 if(self.wantswelcomemessage)
1899                         PrintWelcomeMessage(self);
1900         } else if(self.classname == "spectator") {
1901                 if (self.flags & FL_JUMPRELEASED) {
1902                         if (self.button2 && self.version == cvar("gameversion")) {
1903                                 self.welcomemessage_time = 0;
1904                                 self.flags = self.flags - FL_JUMPRELEASED;
1905                                 LeaveSpectatorMode();
1906                                 return;
1907                         } else if(self.button0) {
1908                                 self.welcomemessage_time = 0;
1909                                 self.flags = self.flags - FL_JUMPRELEASED;
1910                                 if(SpectateNext() == 1) {
1911                                         self.classname = "spectator";
1912                                 } else {
1913                                         self.classname = "observer";
1914                                         PutClientInServer();
1915                                 }
1916                         } else if (self.button3) {
1917                                 self.welcomemessage_time = 0;
1918                                 self.flags = self.flags - FL_JUMPRELEASED;
1919                                 self.classname = "observer";
1920                                 PutClientInServer();
1921                         } else {
1922                                 SpectateUpdate();
1923                         }
1924                 } else {
1925                         if (!(self.button0 || self.button3)) {
1926                                 self.flags = self.flags | FL_JUMPRELEASED;
1927                         }
1928                 }
1929                 if(self.button4)
1930                         self.wantswelcomemessage = 0;
1931                 if(self.wantswelcomemessage)
1932                         PrintWelcomeMessage(self);
1933                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1934         }
1935 }
1936
1937
1938 /*
1939 =============
1940 PlayerPostThink
1941
1942 Called every frame for each client after the physics are run
1943 =============
1944 */
1945 void PlayerPostThink (void)
1946 {
1947         // Savage: Check for nameless players
1948         if (strlen(self.netname) < 1) {
1949                 self.netname = "Player";
1950                 stuffcmd(self, "seta _cl_name Player\n");
1951         }
1952
1953         if(self.classname == "player") {
1954                 CheckRules_Player();
1955                 UpdateChatBubble();
1956                 UpdateTeamBubble();
1957                 if (self.impulse)
1958                         ImpulseCommands();
1959                 if (intermission_running)
1960                         return;         // intermission or finale
1961
1962                 //PrintWelcomeMessage(self);
1963                 //if (TetrisPostFrame()) return;
1964
1965                 // restart countdown
1966                 if (restart_countdown) {
1967                         if(time < restart_countdown) {
1968                                 if (!cvar("sv_ready_restart_after_countdown"))
1969                                 {
1970                                         self.movetype = MOVETYPE_NONE;
1971                                         self.velocity = '0 0 0';
1972                                         self.avelocity = '0 0 0';
1973                                         self.movement = '0 0 0';
1974                                 }
1975                         }
1976                         else
1977                         {
1978                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
1979                                 if (!cvar("sv_ready_restart_after_countdown"))
1980                                 {
1981                                         if(self.movetype == MOVETYPE_NONE)
1982                                         {
1983                                                 self.movetype = MOVETYPE_WALK;
1984                                         }
1985                                 }
1986                         }
1987                 }
1988
1989         } else if (self.classname == "observer") {
1990                 //do nothing
1991         } else if (self.classname == "spectator") {
1992                 //do nothing
1993         }
1994
1995         Arena_Warmup();
1996 }