data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         DropAllRunes(self);
 291
 292         if(self.flagcarried)
 293                 DropFlag(self.flagcarried);
 294
 295         DistributeFragsAmongTeam(self, self.team, 1);
 296
 297         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 299         else if(self.killcount != -666)
 300                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 301
 302         self.classname = "observer";
 303         self.health = -666;
 304         self.takedamage = DAMAGE_NO;
 305         self.solid = SOLID_NOT;
 306         self.movetype = MOVETYPE_NOCLIP;
 307         self.flags = FL_CLIENT | FL_NOTARGET;
 308         self.armorvalue = 666;
 309         self.effects = 0;
 310         self.armorvalue = cvar("g_balance_armor_start");
 311         self.pauserotarmor_finished = 0;
 312         self.pauserothealth_finished = 0;
 313         self.pauseregen_finished = 0;
 314         self.damageforcescale = 0;
 315         self.death_time = 0;
 316         self.dead_time = 0;
 317         self.dead_frame = 0;
 318         self.die_frame = 0;
 319         self.deaths = 0;
 320         self.alpha = 0;
 321         self.scale = 0;
 322         self.fade_time = 0;
 323         self.pain_frame = 0;
 324         self.pain_finished = 0;
 325         self.strength_finished = 0;
 326         self.invincible_finished = 0;
 327         self.pushltime = 0;
 328         self.think = SUB_Null;
 329         self.nextthink = 0;
 330         self.hook_time = 0;
 331         self.runes = 0;
 332         self.deadflag = DEAD_NO;
 333         self.angles = spot.angles;
 334         self.angles_z = 0;
 335         self.fixangle = TRUE;
 336         self.crouch = FALSE;
 337
 338         self.view_ofs = PL_VIEW_OFS;
 339         setorigin (self, spot.origin);
 340         setsize (self, '0 0 0', '0 0 0');
 341         self.oldorigin = self.origin;
 342         self.items = 0;
 343         self.model = "";
 344         self.modelindex = 0;
 345         self.weapon = 0;
 346         self.weaponmodel = "";
 347         self.weaponentity = world;
 348         self.killcount = -666;
 349         self.velocity = '0 0 0';
 350         self.avelocity = '0 0 0';
 351         self.punchangle = '0 0 0';
 352         self.punchvector = '0 0 0';
 353         self.oldvelocity = self.velocity;
 354         self.customizeentityforclient = Client_customizeentityforclient;
 355
 356         if(cvar("g_arena"))
 357         {
 358                 if(self.frags != -2)
 359                 {
 360                         Spawnqueue_Insert(self);
 361                 }
 362                 else
 363                 {
 364                         Spawnqueue_Unmark(self);
 365                         Spawnqueue_Remove(self);
 366                 }
 367         }
 368         else if(!cvar("g_lms"))
 369                 self.frags = -666;
 370 }
 371
 372
 373 /*
 374 =============
 375 PutClientInServer
 376
 377 Called when a client spawns in the server
 378 =============
 379 */
 380 void PutClientInServer (void)
 381 {
 382         if(clienttype(self) == CLIENTTYPE_BOT)
 383         {
 384                 self.classname = "player";
 385         }
 386         else if(clienttype(self) == CLIENTTYPE_REAL)
 387         {
 388                 msg_entity = self;
 389                 WriteByte(MSG_ONE, SVC_SETVIEW);
 390                 WriteEntity(MSG_ONE, self);
 391         }
 392
 393         // player is dead and becomes observer
 394         if(cvar("g_lms") && self.frags < 1)
 395                 self.classname = "observer";
 396
 397         if(cvar("g_arena"))
 398         if(!self.spawned)
 399                 self.classname = "observer";
 400
 401         if(self.classname == "player") {
 402                 entity  spot;
 403
 404                 spot = SelectSpawnPoint (FALSE);
 405
 406                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 407
 408                 self.classname = "player";
 409                 self.iscreature = TRUE;
 410                 self.movetype = MOVETYPE_WALK;
 411                 self.solid = SOLID_SLIDEBOX;
 412                 self.flags = FL_CLIENT;
 413                 self.takedamage = DAMAGE_AIM;
 414                 self.effects = 0;
 415                 self.health = cvar("g_balance_health_start");
 416                 self.armorvalue = cvar("g_balance_armor_start");
 417                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 418                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 419                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 420                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 421                 self.damageforcescale = 2;
 422                 self.death_time = 0;
 423                 self.dead_time = 0;
 424                 self.dead_frame = 0;
 425                 self.die_frame = 0;
 426                 self.alpha = 0;
 427                 self.scale = 0;
 428                 self.fade_time = 0;
 429                 self.pain_frame = 0;
 430                 self.pain_finished = 0;
 431                 self.strength_finished = 0;
 432                 self.invincible_finished = 0;
 433                 self.pushltime = 0;
 434                 //self.speed_finished = 0;
 435                 //self.slowmo_finished = 0;
 436                 // players have no think function
 437                 self.think = SUB_Null;
 438                 self.nextthink = 0;
 439                 self.weapon = 0;
 440                 self.switchweapon = 0;
 441                 self.hook_time = 0;
 442
 443                 self.runes = 0;
 444
 445                 self.deadflag = DEAD_NO;
 446
 447                 self.angles = spot.angles;
 448
 449                 self.angles_z = 0; // never spawn tilted even if the spot says to
 450                 self.fixangle = TRUE; // turn this way immediately
 451                 self.velocity = '0 0 0';
 452                 self.avelocity = '0 0 0';
 453                 self.punchangle = '0 0 0';
 454                 self.punchvector = '0 0 0';
 455                 self.oldvelocity = self.velocity;
 456
 457                 self.viewzoom = 0.6;
 458
 459                 self.customizeentityforclient = Client_customizeentityforclient;
 460
 461                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 462                         local string defaultmodel;
 463                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 464                         setmodel_lod (self, defaultmodel);
 465                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 466                 } else {
 467                         self.playermodel = CheckPlayerModel(self.playermodel);
 468                         setmodel_lod (self, self.playermodel);
 469                         if(teams_matter)
 470                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 471                         else
 472                                 self.skin = stof(self.playerskin);
 473                 }
 474
 475                 self.crouch = FALSE;
 476                 self.view_ofs = PL_VIEW_OFS;
 477                 setsize (self, PL_MIN, PL_MAX);
 478                 self.spawnorigin = spot.origin;
 479                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 480                 // don't reset back to last position, even if new position is stuck in solid
 481                 self.oldorigin = self.origin;
 482
 483                 if(cvar("g_lms"))
 484                 {
 485                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 486                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 487                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 488                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 489                         self.health = cvar("g_lms_start_health");
 490                         self.armorvalue = cvar("g_lms_start_armor");
 491                 }
 492                 else if (cvar("g_use_ammunition")) {
 493                         self.ammo_shells = cvar("g_start_ammo_shells");
 494                         self.ammo_nails = cvar("g_start_ammo_nails");
 495                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 496                         self.ammo_cells = cvar("g_start_ammo_cells");
 497                 } else {
 498                         self.ammo_shells = 999;
 499                         self.ammo_nails = 999;
 500                         self.ammo_rockets = 999;
 501                         self.ammo_cells = 999;
 502                 }
 503
 504                 self.items = 0;
 505                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 506                 {
 507                         self.items = self.items | IT_LASER;
 508                         self.switchweapon = WEP_LASER;
 509                 }
 510                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 511                 {
 512                         self.items = self.items | IT_SHOTGUN;
 513                         self.switchweapon = WEP_SHOTGUN;
 514                 }
 515                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 516                 {
 517                         self.items = self.items | IT_UZI;
 518                         self.switchweapon = WEP_UZI;
 519                 }
 520                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 521                 {
 522                         self.items = self.items | IT_GRENADE_LAUNCHER;
 523                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 524                 }
 525                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 526                 {
 527                         self.items = self.items | IT_ELECTRO;
 528                         self.switchweapon = WEP_ELECTRO;
 529                 }
 530                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 531                 {
 532                         self.items = self.items | IT_CRYLINK;
 533                         self.switchweapon = WEP_CRYLINK;
 534                 }
 535                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 536                 {
 537                         self.items = self.items | IT_NEX;
 538                         self.switchweapon = WEP_NEX;
 539                 }
 540                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 541                 {
 542                         self.items = self.items | IT_HAGAR;
 543                         self.switchweapon = WEP_HAGAR;
 544                 }
 545                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 546                 {
 547                         self.items = self.items | IT_ROCKET_LAUNCHER;
 548                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 549                 }
 550
 551                 if(cvar("g_instagib"))
 552                 {
 553                         self.items = IT_NEX;
 554                         self.switchweapon = WEP_NEX;
 555                         self.ammo_cells = 999;
 556                 }
 557
 558                 if(cvar("g_rocketarena"))
 559                 {
 560                         self.items = IT_ROCKET_LAUNCHER;
 561                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 562                         self.ammo_rockets = 999;
 563                 }
 564
 565                 if(cvar("g_nixnex"))
 566                 {
 567                         self.items = 0;
 568                         // will be done later
 569                 }
 570
 571                 if(cvar("g_minstagib"))
 572                 {
 573                         self.health = 100;
 574                         self.armorvalue = 0;
 575                         self.items = IT_NEX;
 576                         self.switchweapon = WEP_NEX;
 577                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 578                         self.jump_interval = time;
 579                 }
 580
 581                 if(cvar("g_arena"))
 582                 {
 583                         Spawnqueue_Remove(self);
 584                         Spawnqueue_Mark(self);
 585                 }
 586
 587                 self.event_damage = PlayerDamage;
 588
 589                 self.bot_attack = TRUE;
 590
 591                 self.statdraintime = time + 5;
 592                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 593
 594                 if(self.killcount == -666) {
 595                         self.killcount = 0;
 596                         if(!cvar("g_arena"))
 597                         if(!cvar("g_lms"))
 598                                 self.frags = 0;
 599                 }
 600
 601                 self.cnt = WEP_LASER;
 602                 self.nixnex_lastchange_id = -1;
 603
 604                 CL_SpawnWeaponentity();
 605                 self.alpha = default_player_alpha;
 606                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 607
 608                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 609                 self.lms_traveled_distance = 0;
 610
 611                 if(cvar("spawn_debug"))
 612                 {
 613                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 614                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 615                 }
 616
 617                 //stuffcmd(self, "chase_active 0");
 618                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 619         } else if(self.classname == "observer") {
 620                 PutObserverInServer ();
 621         }
 622 }
 623
 624 /*
 625 =============
 626 SetNewParms
 627 =============
 628 */
 629 void SetNewParms (void)
 630 {
 631
 632 }
 633
 634 /*
 635 =============
 636 SetChangeParms
 637 =============
 638 */
 639 void SetChangeParms (void)
 640 {
 641
 642 }
 643
 644 /*
 645 =============
 646 ClientKill
 647
 648 Called when a client types 'kill' in the console
 649 =============
 650 */
 651 void ClientKill (void)
 652 {
 653         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 654 }
 655
 656 /*
 657 =============
 658 ClientConnect
 659
 660 Called when a client connects to the server
 661 =============
 662 */
 663 string ColoredTeamName(float t);
 664 //void dom_player_join_team(entity pl);
 665 void ClientConnect (void)
 666 {
 667         local string s;
 668
 669         self.classname = "player_joining";
 670         self.flags = self.flags | FL_CLIENT;
 671         self.version_nagtime = time + 10 + random() * 10;
 672
 673         if(player_count<0)
 674         {
 675                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 676                 player_count = 0;
 677         }
 678
 679         bot_clientconnect();
 680
 681         //if(cvar("g_domination"))
 682         //      dom_player_join_team(self);
 683
 684         //JoinBestTeam(self, FALSE);
 685
 686         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 687                 self.classname = "observer";
 688         } else {
 689                 self.classname = "player";
 690                 campaign_bots_may_start = 1;
 691         }
 692
 693         self.playerid = (playerid_last = playerid_last + 1);
 694         if(cvar("sv_eventlog"))
 695         {
 696                 if(clienttype(self) == CLIENTTYPE_REAL)
 697                         s = "player";
 698                 else
 699                         s = "bot";
 700                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 701                 s = strcat(":team:", ftos(self.playerid), ":");
 702                 s = strcat(s, ftos(self.team));
 703                 GameLogEcho(s, FALSE);
 704         }
 705
 706         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 707
 708         bprint ("^4",self.netname);
 709         bprint ("^4 connected");
 710
 711         if(cvar("g_domination") || cvar("g_ctf"))
 712         {
 713                 bprint(" and joined the ");
 714                 bprint(ColoredTeamName(self.team));
 715         }
 716
 717         bprint("\n");
 718
 719         self.welcomemessage_time = 0;
 720
 721         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 722         // TODO: is this being used for anything else than cd tracks?
 723         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 724
 725         // send prediction settings to the client
 726         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 727         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 728         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 729         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 730         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 731         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 732         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 733         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 734         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 735         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 736         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 737         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 738         // Wazat's grappling hook
 739         SetGrappleHookBindings();
 740
 741         // get autoswitch state from player
 742         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 743         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 744
 745         // get version info from player
 746         stuffcmd(self, "cmd clientversion $gameversion\n");
 747
 748         // get other cvars from player
 749         GetCvars(0);
 750
 751         // set cvar for team scoreboard
 752         if (teams_matter)
 753         {
 754                 local float t;
 755                 t = cvar("teamplay");
 756                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 757                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 758         }
 759         else
 760                 stuffcmd(self, strcat("set teamplay 0\n"));
 761
 762         if(cvar("g_lms"))
 763         {
 764                 self.frags = cvar("fraglimit");
 765                 // no fraglimit was set, so player gets 999 lives
 766                 if(self.frags < 1)
 767                         self.frags = 999;
 768
 769                 self.frags = LMS_NewPlayerLives();
 770                 if(!self.frags)
 771                 {
 772                         self.frags = -666;
 773                 }
 774         }
 775         else if(cvar("g_arena"))
 776         {
 777                 self.classname = "observer";
 778                 Spawnqueue_Insert(self);
 779         }
 780
 781         bot_relinkplayerlist();
 782
 783         self.jointime = time;
 784 }
 785
 786 /*
 787 =============
 788 ClientDisconnect
 789
 790 Called when a client disconnects from the server
 791 =============
 792 */
 793 void(entity e) DropFlag;
 794 .entity chatbubbleentity;
 795 .entity teambubbleentity;
 796 void ClientDisconnect (void)
 797 {
 798         float save;
 799         if(cvar("sv_eventlog"))
 800                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 801         bprint ("^4",self.netname);
 802         bprint ("^4 disconnected\n");
 803
 804         if (self.chatbubbleentity)
 805         {
 806                 remove (self.chatbubbleentity);
 807                 self.chatbubbleentity = world;
 808         }
 809
 810         if (self.teambubbleentity)
 811         {
 812                 remove (self.teambubbleentity);
 813                 self.teambubbleentity = world;
 814         }
 815
 816         DropAllRunes(self);
 817
 818         if(self.flagcarried)
 819                 DropFlag(self.flagcarried);
 820
 821         DistributeFragsAmongTeam(self, self.team, 1);
 822
 823         save = self.flags;
 824         self.flags = self.flags - (self.flags & FL_CLIENT);
 825         bot_relinkplayerlist();
 826         self.flags = save;
 827
 828         // remove laserdot
 829         if(self.weaponentity)
 830                 if(self.weaponentity.lasertarget)
 831                         remove(self.weaponentity.lasertarget);
 832
 833         if(cvar("g_arena"))
 834         {
 835                 Spawnqueue_Unmark(self);
 836                 Spawnqueue_Remove(self);
 837         }
 838
 839         // free cvars
 840         GetCvars(-1);
 841 }
 842
 843 .float buttonchat;
 844 void() ChatBubbleThink =
 845 {
 846         self.nextthink = time;
 847         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 848         {
 849                 self.owner.chatbubbleentity = world;
 850                 remove(self);
 851                 return;
 852         }
 853         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 854         if (self.owner.buttonchat && !self.owner.deadflag)
 855                 self.model = self.mdl;
 856         else
 857                 self.model = "";
 858 };
 859
 860 void() UpdateChatBubble =
 861 {
 862         if (!self.modelindex)
 863                 return;
 864         // spawn a chatbubble entity if needed
 865         if (!self.chatbubbleentity)
 866         {
 867                 self.chatbubbleentity = spawn();
 868                 self.chatbubbleentity.owner = self;
 869                 self.chatbubbleentity.exteriormodeltoclient = self;
 870                 self.chatbubbleentity.think = ChatBubbleThink;
 871                 self.chatbubbleentity.nextthink = time;
 872                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 873                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 874                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 875                 self.chatbubbleentity.model = "";
 876         }
 877 }
 878
 879
 880 void() TeamBubbleThink =
 881 {
 882         self.nextthink = time;
 883         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 884         {
 885                 self.owner.teambubbleentity = world;
 886                 remove(self);
 887                 return;
 888         }
 889 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 890         if (self.owner.buttonchat || self.owner.deadflag)
 891                 self.model = "";
 892         else
 893                 self.model = self.mdl;
 894
 895 };
 896
 897 float() TeamBubble_customizeentityforclient
 898 {
 899         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 900 }
 901
 902 void() UpdateTeamBubble =
 903 {
 904         if (!self.modelindex || !cvar("teamplay"))
 905                 return;
 906         // spawn a teambubble entity if needed
 907         if (!self.teambubbleentity && cvar("teamplay"))
 908         {
 909                 self.teambubbleentity = spawn();
 910                 self.teambubbleentity.owner = self;
 911                 self.teambubbleentity.exteriormodeltoclient = self;
 912                 self.teambubbleentity.think = TeamBubbleThink;
 913                 self.teambubbleentity.nextthink = time;
 914                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 915 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 916                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 917                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 918                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 919                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 920                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 921         }
 922 }
 923
 924 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 925 // added to the model skins
 926 /*void() UpdateColorModHack =
 927 {
 928         local float c;
 929         c = self.clientcolors & 15;
 930         // LordHavoc: only bothering to support white, green, red, yellow, blue
 931              if (teamplay == 0) self.colormod = '0 0 0';
 932         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 933         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 934         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 935         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 936         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 937         else self.colormod = '1 1 1';
 938 };*/
 939
 940 /*
 941 =============
 942 PlayerJump
 943
 944 When you press the jump key
 945 =============
 946 */
 947 void PlayerJump (void)
 948 {
 949         float mjumpheight;
 950
 951         mjumpheight = cvar("g_balance_jumpheight");
 952         if (self.waterlevel >= 2)
 953         {
 954                 if (self.watertype == CONTENT_WATER)
 955                         self.velocity_z = 200;
 956                 else if (self.watertype == CONTENT_SLIME)
 957                         self.velocity_z = 80;
 958                 else
 959                         self.velocity_z = 50;
 960
 961                 return;
 962         }
 963
 964
 965         if (!(self.flags & FL_ONGROUND))
 966                 return;
 967
 968         if (!(self.flags & FL_JUMPRELEASED))
 969                 return;
 970
 971         if(cvar("g_runematch"))
 972         {
 973                 if(self.runes & RUNE_SPEED)
 974                 {
 975                         if(self.runes & CURSE_SLOW)
 976                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 977                         else
 978                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 979                 }
 980                 else if(self.runes & CURSE_SLOW)
 981                 {
 982                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 983                 }
 984         }
 985
 986         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 987         {
 988                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 989         }
 990
 991         self.velocity_z = self.velocity_z + mjumpheight;
 992         self.oldvelocity_z = self.velocity_z;
 993
 994         self.flags = self.flags - FL_ONGROUND;
 995         self.flags = self.flags - FL_JUMPRELEASED;
 996 }
 997
 998 void() CheckWaterJump =
 999 {
1000         local vector start, end;
1001
1002 // check for a jump-out-of-water
1003         makevectors (self.angles);
1004         start = self.origin;
1005         start_z = start_z + 8;
1006         v_forward_z = 0;
1007         normalize(v_forward);
1008         end = start + v_forward*24;
1009         traceline (start, end, TRUE, self);
1010         if (trace_fraction < 1)
1011         {       // solid at waist
1012                 start_z = start_z + self.maxs_z - 8;
1013                 end = start + v_forward*24;
1014                 self.movedir = trace_plane_normal * -50;
1015                 traceline (start, end, TRUE, self);
1016                 if (trace_fraction == 1)
1017                 {       // open at eye level
1018                         self.flags = self.flags | FL_WATERJUMP;
1019                         self.velocity_z = 225;
1020                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1021                         self.teleport_time = time + 2;  // safety net
1022                         return;
1023                 }
1024         }
1025 };
1026
1027
1028 void respawn(void)
1029 {
1030         CopyBody(1);
1031         PutClientInServer();
1032 }
1033
1034 void player_powerups (void)
1035 {
1036         if (cvar("g_minstagib"))
1037         {
1038                 self.effects = EF_FULLBRIGHT;
1039                 if (self.items & IT_STRENGTH)
1040                 {
1041                         if (time > self.strength_finished)
1042                         {
1043                                 self.alpha = default_player_alpha;
1044                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1045                                 self.items = self.items - (self.items & IT_STRENGTH);
1046                                 sprint(self, "^3Invisibility has worn off\n");
1047                         }
1048                 }
1049                 else
1050                 {
1051                         if (time < self.strength_finished)
1052                         {
1053                                 self.alpha = cvar("g_minstagib_invis_alpha");
1054                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1055                                 self.items = self.items | IT_STRENGTH;
1056                                 sprint(self, "^3You are invisible\n");
1057                         }
1058                 }
1059
1060                 if (self.items & IT_INVINCIBLE)
1061                 {
1062                         if (time > self.invincible_finished)
1063                         {
1064                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1065                                 sprint(self, "^3Speed has worn off\n");
1066                         }
1067                 }
1068                 else
1069                 {
1070                         if (time < self.invincible_finished)
1071                         {
1072                                 self.items = self.items | IT_INVINCIBLE;
1073                                 sprint(self, "^3You are on speed\n");
1074                         }
1075                 }
1076                 return;
1077         }
1078
1079         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1080         if (self.items & IT_STRENGTH)
1081         {
1082                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1083                 if (time > self.strength_finished)
1084                 {
1085                         self.items = self.items - (self.items & IT_STRENGTH);
1086                         sprint(self, "^3Strength has worn off\n");
1087                 }
1088         }
1089         else
1090         {
1091                 if (time < self.strength_finished)
1092                 {
1093                         self.items = self.items | IT_STRENGTH;
1094                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1095                 }
1096         }
1097         if (self.items & IT_INVINCIBLE)
1098         {
1099                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1100                 if (time > self.invincible_finished)
1101                 {
1102                         self.items = self.items - (self.items & IT_INVINCIBLE);
1103                         sprint(self, "^3Shield has worn off\n");
1104                 }
1105         }
1106         else
1107         {
1108                 if (time < self.invincible_finished)
1109                 {
1110                         self.items = self.items | IT_INVINCIBLE;
1111                         sprint(self, "^3Shield surrounds you\n");
1112                 }
1113         }
1114
1115         if (cvar("g_fullbrightplayers"))
1116                 self.effects = self.effects | EF_FULLBRIGHT;
1117
1118         // midair gamemode: damage only while in the air
1119         // if in midair mode, being on ground grants temporary invulnerability
1120         // (this is so that multishot weapon don't clear the ground flag on the
1121         // first damage in the frame, leaving the player vulnerable to the
1122         // remaining hits in the same frame)
1123         if (self.flags & FL_ONGROUND)
1124         if (cvar("g_midair"))
1125                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1126
1127         if (time < self.spawnshieldtime)
1128                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1129 }
1130
1131 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1132 {
1133         if(current > stable)
1134                 return current;
1135         else if(current > stable - 0.25) // when close enough, "snap"
1136                 return stable;
1137         else
1138                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1139 }
1140
1141 void player_regen (void)
1142 {
1143         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1144         maxh = cvar("g_balance_health_stable");
1145         maxa = cvar("g_balance_armor_stable");
1146         limith = cvar("g_balance_health_limit");
1147         limita = cvar("g_balance_armor_limit");
1148
1149         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1150                 return;
1151
1152         if(cvar("g_runematch"))
1153         {
1154                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1155                 if (self.runes & RUNE_REGEN)
1156                 {
1157                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1158                         {
1159                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1160                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1161                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1162                         }
1163                         else
1164                         {
1165                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1166                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1167                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1168                         }
1169                 }
1170                 else if (self.runes & CURSE_VENOM)
1171                 {
1172                         max_mod = cvar("g_balance_curse_venom_hpmod");
1173                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1174                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1175                         else
1176                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1177                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1178                         //if (!self.runes & RUNE_REGEN)
1179                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1180                 }
1181                 maxh = maxh * max_mod;
1182                 //maxa = maxa * max_mod;
1183
1184                 if (time > self.pauserotarmor_finished)
1185                 {
1186                         if (self.armorvalue > maxa)
1187                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1188                 }
1189                 if (time > self.pauserothealth_finished)
1190                 {
1191                         if (self.health > maxh)
1192                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1193                 }
1194                 if (time > self.pauseregen_finished)
1195                 {
1196                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1197                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1198                 }
1199         }
1200         else
1201         {
1202                 if (time > self.pauserothealth_finished)
1203                 if (self.health > maxh)
1204                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1205                 if (time > self.pauserotarmor_finished)
1206                 if (self.armorvalue > maxa)
1207                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1208                 if (time > self.pauseregen_finished)
1209                 {
1210                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1211                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1212                 }
1213         }
1214
1215         if (self.health > limith)
1216                 self.health = limith;
1217         if(self.health < 1)
1218                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1219         if (self.armorvalue > limita)
1220                 self.armorvalue = limita;
1221 }
1222
1223 /*
1224 ======================
1225 spectate mode routines
1226 ======================
1227 */
1228 void SpectateCopy(entity spectatee) {
1229         self.armortype = spectatee.armortype;
1230         self.armorvalue = spectatee.armorvalue;
1231         self.currentammo = spectatee.currentammo;
1232         self.effects = spectatee.effects;
1233         self.health = spectatee.health;
1234         self.impulse = 0;
1235         self.items = spectatee.items;
1236         self.punchangle = spectatee.punchangle;
1237         self.view_ofs = spectatee.view_ofs;
1238         self.v_angle = spectatee.v_angle;
1239         self.viewzoom = spectatee.viewzoom;
1240         setorigin(self, spectatee.origin);
1241         setsize(self, spectatee.mins, spectatee.maxs);
1242 }
1243
1244 void SpectateUpdate() {
1245         if(!self.enemy)
1246                         PutObserverInServer();
1247
1248         if (self != self.enemy) {
1249                 if(self.enemy.flags & FL_NOTARGET)
1250                         PutObserverInServer();
1251                 SpectateCopy(self.enemy);
1252                 self.dmg_take = self.enemy.dmg_take;
1253                 self.dmg_save = self.enemy.dmg_save;
1254                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1255                 self.fixangle = TRUE;
1256                 self.angles = self.enemy.v_angle;
1257                 //msg_entity = self;
1258                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1259                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1260                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1261                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1262         }
1263 }
1264
1265 float SpectateNext() {
1266         other = find(self.enemy, classname, "player");
1267         if (!other) {
1268                 other = find(other, classname, "player");
1269         }
1270         if (other) {
1271                 self.enemy = other;
1272         }
1273         if(self.enemy.classname == "player") {
1274                 msg_entity = self;
1275                 WriteByte(MSG_ONE, SVC_SETVIEW);
1276                 WriteEntity(MSG_ONE, self.enemy);
1277                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1278                 SpectateUpdate();
1279                 return 1;
1280         } else {
1281                 return 0;
1282         }
1283 }
1284
1285 /*
1286 =============
1287 ShowRespawnCountdown()
1288
1289 Update a respawn countdown display.
1290 =============
1291 */
1292 void ShowRespawnCountdown()
1293 {
1294         float number;
1295         if(self.deadflag == DEAD_NO) // just respawned?
1296                 return;
1297         else
1298         {
1299                 number = ceil(self.death_time - time);
1300                 if(number <= 0)
1301                         return;
1302                 if(number <= self.respawn_countdown)
1303                 {
1304                         self.respawn_countdown = number - 1;
1305                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1306                                 stuffcmd(self, strcat("play2 announcer/robotic/", ftos(number), ".ogg\n"));
1307                 }
1308         }
1309 }
1310
1311 void LeaveSpectatorMode()
1312 {
1313         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1314                 self.classname = "player";
1315                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1316                         JoinBestTeam(self, 0);
1317                 if(cvar("g_campaign"))
1318                         campaign_bots_may_start = 1;
1319                 PutClientInServer();
1320                 if(!(self.flags & FL_NOTARGET))
1321                         bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1322                 centerprint(self,"");
1323                 return;
1324         } else {
1325                 stuffcmd(self,"menu_showteamselect\n");
1326                 return;
1327         }
1328 }
1329
1330 /*
1331 =============
1332 PlayerPreThink
1333
1334 Called every frame for each client before the physics are run
1335 =============
1336 */
1337 void() ctf_setstatus;
1338 void PlayerPreThink (void)
1339 {
1340         // version nagging
1341         if(self.version_nagtime)
1342                 if(self.cvar_g_nexuizversion)
1343                         if(time > self.version_nagtime)
1344                         {
1345                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1346                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1347                                         {
1348                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1349                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1350                                         }
1351                                 self.version_nagtime = 0;
1352                         }
1353
1354         if(self.classname == "player") {
1355                 local vector m1, m2;
1356
1357 //              if(self.netname == "Wazat")
1358 //                      bprint(strcat(self.classname, "\n"));
1359
1360                 CheckRules_Player();
1361
1362                 Nixnex_GiveCurrentWeapon();
1363
1364                 if(self.button7)
1365                         PrintWelcomeMessage(self);
1366
1367                 if(cvar("g_lms") || !cvar("sv_spectate"))
1368                 if((time - self.jointime) <= cvar("welcome_message_time"))
1369                         PrintWelcomeMessage(self);
1370
1371                 if (intermission_running)
1372                 {
1373                         IntermissionThink ();   // otherwise a button could be missed between
1374                         return;                                 // the think tics
1375                 }
1376
1377                 if (self.deadflag != DEAD_NO)
1378                 {
1379                         float button_pressed, force_respawn;
1380                         player_anim();
1381                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1382                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1383                         if (self.deadflag == DEAD_DYING)
1384                         {
1385                                 if(force_respawn)
1386                                         self.deadflag = DEAD_RESPAWNING;
1387                                 else if(!button_pressed)
1388                                         self.deadflag = DEAD_DEAD;
1389                         }
1390                         else if (self.deadflag == DEAD_DEAD)
1391                         {
1392                                 if(button_pressed)
1393                                         self.deadflag = DEAD_RESPAWNABLE;
1394                         }
1395                         else if (self.deadflag == DEAD_RESPAWNABLE)
1396                         {
1397                                 if(!button_pressed)
1398                                         self.deadflag = DEAD_RESPAWNING;
1399                         }
1400                         else if (self.deadflag == DEAD_RESPAWNING)
1401                         {
1402                                 if(time > self.death_time)
1403                                         respawn();
1404                         }
1405                         ShowRespawnCountdown();
1406                         return;
1407                 }
1408
1409                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1410                 {
1411                         vector dist;
1412
1413                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1414                         dist = self.oldorigin - self.origin;
1415                         dist_z = 0;
1416                         self.lms_traveled_distance += fabs(vlen(dist));
1417
1418                         if(cvar("g_campaign"))
1419                         if(!campaign_bots_may_start)
1420                         {
1421                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1422                                 self.lms_traveled_distance = 0;
1423                         }
1424
1425                         if(time > self.lms_nextcheck)
1426                         {
1427                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1428                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1429                                 {
1430                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1431                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1432                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1433                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1434                                 }
1435                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1436                                 self.lms_traveled_distance = 0;
1437                         }
1438                 }
1439
1440                 if (self.button5 && !self.hook.state)
1441                 {
1442                         if (!self.crouch)
1443                         {
1444                                 self.crouch = TRUE;
1445                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1446                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1447                         }
1448                 }
1449                 else
1450                 {
1451                         if (self.crouch)
1452                         {
1453                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1454                                 if (!trace_startsolid)
1455                                 {
1456                                         self.crouch = FALSE;
1457                                         self.view_ofs = PL_VIEW_OFS;
1458                                         setsize (self, PL_MIN, PL_MAX);
1459                                 }
1460                         }
1461                 }
1462
1463                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1464                         local string defaultmodel;
1465                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1466
1467                         if (defaultmodel != self.model)
1468                         {
1469                                 m1 = self.mins;
1470                                 m2 = self.maxs;
1471                                 setmodel_lod (self, defaultmodel);
1472                                 setsize (self, m1, m2);
1473                         }
1474
1475                         if (self.skin != cvar("sv_defaultplayerskin"))
1476                                 self.skin = cvar("sv_defaultplayerskin");
1477                 } else {
1478                         if (self.playermodel != self.model)
1479                         {
1480                                 self.playermodel = CheckPlayerModel(self.playermodel);
1481                                 m1 = self.mins;
1482                                 m2 = self.maxs;
1483                                 setmodel_lod (self, self.playermodel);
1484                                 setsize (self, m1, m2);
1485                         }
1486
1487                         if(teams_matter)
1488                         {
1489                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1490                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1491                         }
1492                         else
1493                         {
1494                                 if (self.skin != stof(self.playerskin))
1495                                         self.skin = stof(self.playerskin);
1496                         }
1497                 }
1498
1499                 GrapplingHookFrame();
1500
1501                 W_WeaponFrame();
1502
1503                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1504                 {
1505                         if (cvar("g_minstagib") && self.button3)
1506                         {
1507                                 if (self.jump_interval <= (time + 0.1))
1508                                 {
1509                                         self.jump_interval = time + 1;
1510                                         W_Laser_Attack();
1511                                 }
1512                         }
1513                         else if (self.viewzoom > 0.4)
1514                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1515                 }
1516                 else if (self.viewzoom < 1.0)
1517                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1518
1519
1520                 if (self.button2)
1521                         PlayerJump ();
1522                 else
1523                         self.flags = self.flags | FL_JUMPRELEASED;
1524
1525                 player_powerups();
1526                 player_regen();
1527                 player_anim();
1528
1529                 if (cvar("g_minstagib"))
1530                         minstagib_ammocheck();
1531
1532                 ctf_setstatus();
1533
1534                 //self.angles_y=self.v_angle_y + 90;   // temp
1535
1536                 if (self.waterlevel == 2)
1537                         CheckWaterJump ();
1538
1539                 //if (TetrisPreFrame()) return;
1540         } else if(gameover) {
1541                 if (intermission_running)
1542                         IntermissionThink ();   // otherwise a button could be missed between
1543                 return;
1544         } else if(self.classname == "observer") {
1545
1546                 if (self.flags & FL_JUMPRELEASED) {
1547                         if (self.button2 && self.version == cvar("gameversion")) {
1548                                 self.flags = self.flags - FL_JUMPRELEASED;
1549                                 LeaveSpectatorMode();
1550                                 return;
1551                         } else if(self.button0 && self.version == cvar("gameversion")) {
1552                                 self.flags = self.flags - FL_JUMPRELEASED;
1553                                 if(SpectateNext() == 1) {
1554                                         self.classname = "spectator";
1555                                 }
1556                         }
1557                 } else {
1558                         if (!(self.button0 || self.button2)) {
1559                                 self.flags = self.flags | FL_JUMPRELEASED;
1560                         }
1561                 }
1562                 PrintWelcomeMessage(self);
1563         } else if(self.classname == "spectator") {
1564                 if (self.flags & FL_JUMPRELEASED) {
1565                         if (self.button2 && self.version == cvar("gameversion")) {
1566                                 self.flags = self.flags - FL_JUMPRELEASED;
1567                                 LeaveSpectatorMode();
1568                                 return;
1569                         } else if(self.button0) {
1570                                 self.flags = self.flags - FL_JUMPRELEASED;
1571                                 if(SpectateNext() == 1) {
1572                                         self.classname = "spectator";
1573                                 } else {
1574                                         self.classname = "observer";
1575                                         PutClientInServer();
1576                                 }
1577                         } else if (self.button3) {
1578                                 self.flags = self.flags - FL_JUMPRELEASED;
1579                                 self.classname = "observer";
1580                                 PutClientInServer();
1581                         } else {
1582                                 SpectateUpdate();
1583                         }
1584                 } else {
1585                         if (!(self.button0 || self.button3)) {
1586                                 self.flags = self.flags | FL_JUMPRELEASED;
1587                         }
1588                 }
1589                 PrintWelcomeMessage(self);
1590                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1591         }
1592 }
1593
1594
1595 /*
1596 =============
1597 PlayerPostThink
1598
1599 Called every frame for each client after the physics are run
1600 =============
1601 */
1602 void PlayerPostThink (void)
1603 {
1604         // Savage: Check for nameless players
1605         if (strlen(self.netname) < 1) {
1606                 self.netname = "Player";
1607                 stuffcmd(self, "seta _cl_name Player\n");
1608         }
1609
1610         if(self.classname == "player") {
1611                 CheckRules_Player();
1612                 UpdateChatBubble();
1613                 UpdateTeamBubble();
1614                 if (self.deadflag == DEAD_NO)
1615                 if (self.impulse)
1616                         ImpulseCommands ();
1617                 if (intermission_running)
1618                         return;         // intermission or finale
1619
1620                 //PrintWelcomeMessage(self);
1621                 //if (TetrisPostFrame()) return;
1622         } else if (self.classname == "observer") {
1623                 //do nothing
1624         } else if (self.classname == "spectator") {
1625                 //do nothing
1626         }
1627         Arena_Warmup();
1628 }