data/qcsrc/server/cl_client.qc

   1 .float spectatee_status;
   2 .float zoomstate;
   3 .float bloodloss_timer;
   4
   5 .entity clientdata;
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(to.classname == "spectator")
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(e2.classname == "spectator")
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74
  75 #define SPAWNPOINT_SCORE frags
  76
  77 .string netname_previous;
  78
  79 void spawnfunc_info_player_survivor (void)
  80 {
  81         spawnfunc_info_player_deathmatch();
  82 }
  83
  84 void spawnfunc_info_player_start (void)
  85 {
  86         spawnfunc_info_player_deathmatch();
  87 }
  88
  89 void spawnfunc_info_player_deathmatch (void)
  90 {
  91         self.classname = "info_player_deathmatch";
  92         relocate_spawnpoint();
  93 }
  94
  95 void spawnpoint_use()
  96 {
  97         if(teams_matter)
  98         if(have_team_spawns)
  99         {
 100                 self.team = activator.team;
 101                 some_spawn_has_been_used = 1;
 102         }
 103 };
 104
 105 // Returns:
 106 //   -1 if a spawn can't be used
 107 //   otherwise, a weight of the spawnpoint
 108 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 109 {
 110         float shortest, thisdist;
 111         entity player;
 112
 113         // filter out spots for the wrong team
 114         if(teamcheck)
 115         if(spot.team != teamcheck)
 116                 return -1;
 117
 118         if(race_spawns)
 119                 if(spot.target == "")
 120                         return -1;
 121
 122         // filter out spots for assault
 123         if(spot.target != "") {
 124                 local entity ent;
 125                 float good, found;
 126                 ent = find(world, targetname, spot.target);
 127                 while(ent) {
 128                         found = 1;
 129                         if(ent.classname == "target_objective")
 130                         {
 131                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 132                                         return -1;
 133                                 good = 1;
 134                         }
 135                         else if(ent.classname == "trigger_race_checkpoint")
 136                         {
 137                                 if(self.classname == "player") // spectators may spawn everywhere
 138                                 {
 139                                         if(g_race_qualifying)
 140                                         {
 141                                                 // spawn at first
 142                                                 if(ent.race_checkpoint != 0)
 143                                                         return -1;
 144                                                 if(spot.race_place != race_lowest_place_spawn)
 145                                                         return -1;
 146                                         }
 147                                         else
 148                                         {
 149                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 150                                                         return -1;
 151                                                 float pl;
 152                                                 pl = self.race_place;
 153                                                 if(pl > race_highest_place_spawn)
 154                                                         pl = 0;
 155                                                 if(spot.race_place != pl)
 156                                                         return -1;
 157                                         }
 158                                 }
 159                                 good = 1;
 160                         }
 161                         else
 162                         {
 163                         }
 164                         ent = find(ent, targetname, spot.target);
 165                 }
 166
 167                 if(found && !good)
 168                         return -1;
 169         }
 170
 171         player = playerlist;
 172         shortest = vlen(world.maxs - world.mins);
 173         for(player = playerlist; player; player = player.chain)
 174                 if (player != self)
 175                 {
 176                         thisdist = vlen(player.origin - spot.origin);
 177                         if (thisdist < shortest)
 178                                 shortest = thisdist;
 179                 }
 180         return shortest;
 181 }
 182
 183 float spawn_allbad;
 184 float spawn_allgood;
 185 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 186 {
 187         local entity spot, spotlist, spotlistend;
 188         spawn_allgood = TRUE;
 189         spawn_allbad = TRUE;
 190
 191         spotlist = world;
 192         spotlistend = world;
 193
 194         for(spot = firstspot; spot; spot = spot.chain)
 195         {
 196                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 197
 198                 if(cvar("spawn_debugview"))
 199                 {
 200                         setmodel(spot, "models/runematch/rune.mdl");
 201                         if(spot.SPAWNPOINT_SCORE < mindist)
 202                         {
 203                                 spot.colormod = '1 0 0';
 204                                 spot.scale = 1;
 205                         }
 206                         else
 207                         {
 208                                 spot.colormod = '0 1 0';
 209                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 210                         }
 211                 }
 212
 213                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 214                 {
 215                         if(spot.SPAWNPOINT_SCORE < mindist)
 216                         {
 217                                 // too short distance
 218                                 spawn_allgood = FALSE;
 219                         }
 220                         else
 221                         {
 222                                 // perfect
 223                                 spawn_allbad = FALSE;
 224
 225                                 if(spotlistend)
 226                                         spotlistend.chain = spot;
 227                                 spotlistend = spot;
 228                                 if(!spotlist)
 229                                         spotlist = spot;
 230
 231                                 /*
 232                                 if(teamcheck)
 233                                 if(spot.team != teamcheck)
 234                                         error("invalid spawn added");
 235
 236                                 print("added ", etos(spot), "\n");
 237                                 */
 238                         }
 239                 }
 240         }
 241         if(spotlistend)
 242                 spotlistend.chain = world;
 243
 244         /*
 245                 entity e;
 246                 if(teamcheck)
 247                         for(e = spotlist; e; e = e.chain)
 248                         {
 249                                 print("seen ", etos(e), "\n");
 250                                 if(e.team != teamcheck)
 251                                         error("invalid spawn found");
 252                         }
 253         */
 254
 255         return spotlist;
 256 }
 257
 258 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 259 {
 260         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 261         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 262         local entity spot;
 263
 264         RandomSelection_Init();
 265         for(spot = firstspot; spot; spot = spot.chain)
 266                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 267
 268         return RandomSelection_chosen_ent;
 269 }
 270
 271 /*
 272 =============
 273 SelectSpawnPoint
 274
 275 Finds a point to respawn
 276 =============
 277 */
 278 entity SelectSpawnPoint (float anypoint)
 279 {
 280         local float teamcheck;
 281         local entity firstspot_new;
 282         local entity spot, firstspot, playerlist;
 283
 284         spot = find (world, classname, "testplayerstart");
 285         if (spot)
 286                 return spot;
 287
 288         teamcheck = 0;
 289
 290         if(!anypoint && have_team_spawns)
 291                 teamcheck = self.team;
 292
 293         // get the list of players
 294         playerlist = findchain(classname, "player");
 295         // get the entire list of spots
 296         firstspot = findchain(classname, "info_player_deathmatch");
 297         // filter out the bad ones
 298         // (note this returns the original list if none survived)
 299         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 300         if(!firstspot_new)
 301                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 302         firstspot = firstspot_new;
 303
 304         // there is 50/50 chance of choosing a random spot or the furthest spot
 305         // (this means that roughly every other spawn will be furthest, so you
 306         // usually won't get fragged at spawn twice in a row)
 307         if (arena_roundbased)
 308         {
 309                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 310                 if(firstspot_new)
 311                         firstspot = firstspot_new;
 312                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 313         }
 314         else if (random() > cvar("g_spawn_furthest"))
 315                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 316         else
 317                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 318
 319         if(cvar("spawn_debugview"))
 320         {
 321                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 322
 323                 entity e;
 324                 if(teamcheck)
 325                         for(e = firstspot; e; e = e.chain)
 326                                 if(e.team != teamcheck)
 327                                         error("invalid spawn found");
 328         }
 329
 330         if (!spot)
 331         {
 332                 if(cvar("spawn_debug"))
 333                         GotoNextMap();
 334                 else
 335                 {
 336                         if(some_spawn_has_been_used)
 337                                 return world; // team can't spawn any more, because of actions of other team
 338                         else
 339                                 error("Cannot find a spawn point - please fix the map!");
 340                 }
 341         }
 342
 343         return spot;
 344 }
 345
 346 /*
 347 =============
 348 CheckPlayerModel
 349
 350 Checks if the argument string can be a valid playermodel.
 351 Returns a valid one in doubt.
 352 =============
 353 */
 354 string FallbackPlayerModel = "models/player/marine.zym";
 355 string CheckPlayerModel(string plyermodel) {
 356         if(strlen(plyermodel) < 4)
 357                 return FallbackPlayerModel;
 358         if( substring(plyermodel,0,14) != "models/player/")
 359                 return FallbackPlayerModel;
 360         else if(cvar("sv_servermodelsonly"))
 361         {
 362                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 363                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 364                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 365                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 366                         return FallbackPlayerModel;
 367                 if(plyermodel != strtolower(plyermodel))
 368                         return FallbackPlayerModel;
 369                 if(!fexists(plyermodel))
 370                         return FallbackPlayerModel;
 371         }
 372         return plyermodel;
 373 }
 374
 375 /*
 376 =============
 377 Client_customizeentityforclient
 378
 379 LOD reduction
 380 =============
 381 */
 382 float Client_customizeentityforclient()
 383 {
 384 #ifdef ALLOW_VARIABLE_LOD
 385         // self: me
 386         // other: the player viewing me
 387         float distance;
 388         float f;
 389
 390         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 391                 return TRUE;
 392
 393         if(other.cvar_cl_playerdetailreduction <= 0)
 394         {
 395                 if(other.cvar_cl_playerdetailreduction <= -2)
 396                         self.modelindex = self.modelindex_lod2;
 397                 else if(other.cvar_cl_playerdetailreduction <= -1)
 398                         self.modelindex = self.modelindex_lod1;
 399                 else
 400                         self.modelindex = self.modelindex_lod0;
 401         }
 402         else
 403         {
 404                 distance = vlen(self.origin - other.origin);
 405                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 406                 if(f > 10000)
 407                         self.modelindex = self.modelindex_lod2;
 408                 else if(f > 5000)
 409                         self.modelindex = self.modelindex_lod1;
 410                 else
 411                         self.modelindex = self.modelindex_lod0;
 412         }
 413 #endif
 414
 415         return TRUE;
 416 }
 417
 418 void UpdatePlayerSounds();
 419 void setmodel_lod(entity e, string modelname)
 420 {
 421 #ifdef ALLOW_VARIABLE_LOD
 422         string s;
 423
 424         // FIXME: this only supports 3-letter extensions
 425         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 426         if(fexists(s))
 427         {
 428                 precache_model(s);
 429                 setmodel(e, s); // players have high precision
 430                 self.modelindex_lod1 = self.modelindex;
 431         }
 432         else
 433                 self.modelindex_lod1 = -1;
 434
 435         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 436         if(fexists(s))
 437         {
 438                 precache_model(s);
 439                 setmodel(e, s); // players have high precision
 440                 self.modelindex_lod2 = self.modelindex;
 441         }
 442         else
 443                 self.modelindex_lod2 = -1;
 444
 445         precache_model(modelname);
 446         setmodel(e, modelname); // players have high precision
 447         self.modelindex_lod0 = self.modelindex;
 448
 449         if(self.modelindex_lod1 < 0)
 450                 self.modelindex_lod1 = self.modelindex;
 451
 452         if(self.modelindex_lod2 < 0)
 453                 self.modelindex_lod2 = self.modelindex;
 454 #else
 455         precache_model(modelname);
 456         setmodel(e, modelname); // players have high precision
 457 #endif
 458         player_setupanimsformodel();
 459         UpdatePlayerSounds();
 460 }
 461
 462 /*
 463 =============
 464 PutObserverInServer
 465
 466 putting a client as observer in the server
 467 =============
 468 */
 469 void PutObserverInServer (void)
 470 {
 471         entity  spot;
 472
 473         race_PreSpawnObserver();
 474
 475         spot = SelectSpawnPoint (TRUE);
 476         if(!spot)
 477                 error("No spawnpoints for observers?!?\n");
 478         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 479
 480         if(clienttype(self) == CLIENTTYPE_REAL)
 481         {
 482                 msg_entity = self;
 483                 WriteByte(MSG_ONE, SVC_SETVIEW);
 484                 WriteEntity(MSG_ONE, self);
 485         }
 486
 487         DropAllRunes(self);
 488         kh_Key_DropAll(self, TRUE);
 489
 490         Portal_ClearAll(self);
 491
 492         if(self.flagcarried)
 493                 DropFlag(self.flagcarried, world, world);
 494
 495         WaypointSprite_PlayerDead();
 496
 497         if(self.killcount != -666)
 498         {
 499                 if(g_lms)
 500                 {
 501                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 502                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 503                         else
 504                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 505                 }
 506                 else
 507                         bprint ("^4", self.netname, "^4 is spectating now\n");
 508         }
 509
 510         PlayerScore_Clear(self); // clear scores when needed
 511
 512         self.spectatortime = time;
 513
 514         self.classname = "observer";
 515         self.iscreature = FALSE;
 516         self.health = -666;
 517         self.takedamage = DAMAGE_NO;
 518         self.solid = SOLID_NOT;
 519         self.movetype = MOVETYPE_NOCLIP;
 520         self.flags = FL_CLIENT | FL_NOTARGET;
 521         self.armorvalue = 666;
 522         self.effects = 0;
 523         self.armorvalue = cvar("g_balance_armor_start");
 524         self.pauserotarmor_finished = 0;
 525         self.pauserothealth_finished = 0;
 526         self.pauseregen_finished = 0;
 527         self.damageforcescale = 0;
 528         self.death_time = 0;
 529         self.dead_frame = 0;
 530         self.alpha = 0;
 531         self.scale = 0;
 532         self.fade_time = 0;
 533         self.pain_frame = 0;
 534         self.pain_finished = 0;
 535         self.strength_finished = 0;
 536         self.invincible_finished = 0;
 537         self.pushltime = 0;
 538         self.think = SUB_Null;
 539         self.nextthink = 0;
 540         self.hook_time = 0;
 541         self.runes = 0;
 542         self.deadflag = DEAD_NO;
 543         self.angles = spot.angles;
 544         self.angles_z = 0;
 545         self.fixangle = TRUE;
 546         self.crouch = FALSE;
 547
 548         self.view_ofs = PL_VIEW_OFS;
 549         setorigin (self, spot.origin);
 550         setsize (self, '0 0 0', '0 0 0');
 551         self.oldorigin = self.origin;
 552         self.items = 0;
 553         self.weapons = 0;
 554         self.model = "";
 555         self.modelindex = 0;
 556         self.weapon = 0;
 557         self.weaponmodel = "";
 558         self.weaponentity = world;
 559         self.exteriorweaponentity = world;
 560         self.killcount = -666;
 561         self.velocity = '0 0 0';
 562         self.avelocity = '0 0 0';
 563         self.punchangle = '0 0 0';
 564         self.punchvector = '0 0 0';
 565         self.oldvelocity = self.velocity;
 566         self.customizeentityforclient = Client_customizeentityforclient;
 567
 568         if(g_arena)
 569         {
 570                 if(self.version_mismatch)
 571                 {
 572                         Spawnqueue_Unmark(self);
 573                         Spawnqueue_Remove(self);
 574                 }
 575                 else
 576                 {
 577                         Spawnqueue_Insert(self);
 578                 }
 579         }
 580         else if(g_lms)
 581         {
 582                 // Only if the player cannot play at all
 583                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 584                         self.frags = FRAGS_SPECTATOR;
 585                 else
 586                         self.frags = FRAGS_LMS_LOSER;
 587         }
 588         else
 589                 self.frags = FRAGS_SPECTATOR;
 590 }
 591
 592 float RestrictSkin(float s)
 593 {
 594         if(!teams_matter)
 595                 return s;
 596         if(s == 6)
 597                 return 6;
 598         return mod(s, 3);
 599 }
 600
 601 void FixPlayermodel()
 602 {
 603         local string defaultmodel;
 604         local float defaultskin;
 605         local vector m1, m2;
 606
 607         defaultmodel = "";
 608
 609         if(cvar("sv_defaultcharacter") == 1) {
 610                 defaultskin = 0;
 611
 612                 if(teams_matter)
 613                 {
 614                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 615                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 616                 }
 617
 618                 if(defaultmodel == "")
 619                 {
 620                         defaultmodel = cvar_string("sv_defaultplayermodel");
 621                         defaultskin = cvar("sv_defaultplayerskin");
 622                 }
 623         }
 624
 625         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 626         {
 627                 if(self.model != "")
 628                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 629                 self.model = ""; // force the != checks to return true
 630         }
 631
 632         if(defaultmodel != "")
 633         {
 634                 if (defaultmodel != self.model)
 635                 {
 636                         m1 = self.mins;
 637                         m2 = self.maxs;
 638                         setmodel_lod (self, defaultmodel);
 639                         setsize (self, m1, m2);
 640                 }
 641
 642                 self.skin = defaultskin;
 643         } else {
 644                 if (self.playermodel != self.model)
 645                 {
 646                         self.playermodel = CheckPlayerModel(self.playermodel);
 647                         m1 = self.mins;
 648                         m2 = self.maxs;
 649                         setmodel_lod (self, self.playermodel);
 650                         setsize (self, m1, m2);
 651                 }
 652
 653                 self.skin = RestrictSkin(stof(self.playerskin));
 654         }
 655
 656         if(!teams_matter)
 657                 if(strlen(cvar_string("sv_defaultplayercolors")))
 658                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 659                                 setcolor(self, cvar("sv_defaultplayercolors"));
 660 }
 661
 662 void PlayerTouchExplode(entity p1, entity p2)
 663 {
 664         vector org;
 665         org = (p1.origin + p2.origin) * 0.5;
 666         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 667
 668         te_explosion(org);
 669
 670         entity e;
 671         e = spawn();
 672         setorigin(e, org);
 673         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 674         remove(e);
 675 }
 676
 677 /*
 678 =============
 679 PutClientInServer
 680
 681 Called when a client spawns in the server
 682 =============
 683 */
 684 //void() ctf_playerchanged;
 685 void PutClientInServer (void)
 686 {
 687         if(clienttype(self) == CLIENTTYPE_BOT)
 688         {
 689                 self.classname = "player";
 690         }
 691         else if(clienttype(self) == CLIENTTYPE_REAL)
 692         {
 693                 msg_entity = self;
 694                 WriteByte(MSG_ONE, SVC_SETVIEW);
 695                 WriteEntity(MSG_ONE, self);
 696         }
 697
 698         // player is dead and becomes observer
 699         // FIXME fix LMS scoring for new system
 700         if(g_lms)
 701         {
 702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 703                         self.classname = "observer";
 704         }
 705
 706         if(g_arena)
 707         if(!self.spawned)
 708                 self.classname = "observer";
 709
 710         if(self.classname == "player") {
 711                 entity spot, oldself;
 712
 713                 race_PreSpawn();
 714
 715                 spot = SelectSpawnPoint (FALSE);
 716                 if(!spot)
 717                 {
 718                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 719                         return; // spawn failed
 720                 }
 721
 722                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 723                 self.campingrifle_bulletcounter = 0;
 724
 725                 self.classname = "player";
 726                 self.wasplayer = TRUE;
 727                 self.iscreature = TRUE;
 728                 self.movetype = MOVETYPE_WALK;
 729                 self.solid = SOLID_SLIDEBOX;
 730                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 731                 self.frags = FRAGS_PLAYER;
 732                 if(independent_players)
 733                         MAKE_INDEPENDENT_PLAYER(self);
 734                 self.flags = FL_CLIENT;
 735                 self.takedamage = DAMAGE_AIM;
 736                 if(g_minstagib)
 737                         self.effects = EF_FULLBRIGHT;
 738                 else
 739                         self.effects = 0;
 740                 self.air_finished = time + 12;
 741                 self.dmg = 2;
 742
 743                 if(inWarmupStage)
 744                 {
 745                         self.ammo_shells = warmup_start_ammo_shells;
 746                         self.ammo_nails = warmup_start_ammo_nails;
 747                         self.ammo_rockets = warmup_start_ammo_rockets;
 748                         self.ammo_cells = warmup_start_ammo_cells;
 749                         self.health = warmup_start_health;
 750                         self.armorvalue = warmup_start_armorvalue;
 751                         self.weapons = warmup_start_weapons;
 752                 }
 753                 else
 754                 {
 755                         self.ammo_shells = start_ammo_shells;
 756                         self.ammo_nails = start_ammo_nails;
 757                         self.ammo_rockets = start_ammo_rockets;
 758                         self.ammo_cells = start_ammo_cells;
 759                         self.health = start_health;
 760                         self.armorvalue = start_armorvalue;
 761                         self.weapons = start_weapons;
 762                 }
 763                 self.items = start_items;
 764                 self.switchweapon = w_getbestweapon(self);
 765                 self.cnt = self.switchweapon;
 766                 self.weapon = 0;
 767                 self.jump_interval = time;
 768
 769                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 770                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 771                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 772                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 773                 //extend the pause of rotting if client was reset at the beginning of the countdown
 774                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 775                         self.spawnshieldtime += game_starttime - time;
 776                         self.pauserotarmor_finished += game_starttime - time;
 777                         self.pauserothealth_finished += game_starttime - time;
 778                         self.pauseregen_finished += game_starttime - time;
 779                 }
 780                 self.damageforcescale = 2;
 781                 self.death_time = 0;
 782                 self.dead_frame = 0;
 783                 self.alpha = 0;
 784                 self.scale = 0;
 785                 self.fade_time = 0;
 786                 self.pain_frame = 0;
 787                 self.pain_finished = 0;
 788                 self.strength_finished = 0;
 789                 self.invincible_finished = 0;
 790                 self.pushltime = 0;
 791                 //self.speed_finished = 0;
 792                 //self.slowmo_finished = 0;
 793                 // players have no think function
 794                 self.think = SUB_Null;
 795                 self.nextthink = 0;
 796                 self.hook_time = 0;
 797                 self.dmg_team = 0;
 798
 799                 self.runes = 0;
 800
 801                 self.deadflag = DEAD_NO;
 802
 803                 self.angles = spot.angles;
 804
 805                 self.angles_z = 0; // never spawn tilted even if the spot says to
 806                 self.fixangle = TRUE; // turn this way immediately
 807                 self.velocity = '0 0 0';
 808                 self.avelocity = '0 0 0';
 809                 self.punchangle = '0 0 0';
 810                 self.punchvector = '0 0 0';
 811                 self.oldvelocity = self.velocity;
 812
 813                 msg_entity = self;
 814                 WRITESPECTATABLE_MSG_ONE({
 815                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 816                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 817                 });
 818
 819                 self.customizeentityforclient = Client_customizeentityforclient;
 820
 821                 self.model = "";
 822                 FixPlayermodel();
 823
 824                 self.crouch = FALSE;
 825                 self.view_ofs = PL_VIEW_OFS;
 826                 setsize (self, PL_MIN, PL_MAX);
 827                 self.spawnorigin = spot.origin;
 828                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 829                 // don't reset back to last position, even if new position is stuck in solid
 830                 self.oldorigin = self.origin;
 831
 832                 if(g_arena)
 833                 {
 834                         Spawnqueue_Remove(self);
 835                         Spawnqueue_Mark(self);
 836                 }
 837
 838                 self.event_damage = PlayerDamage;
 839
 840                 self.bot_attack = TRUE;
 841
 842                 self.statdraintime = time + 5;
 843                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 844
 845                 if(self.killcount == -666) {
 846                         PlayerScore_Clear(self);
 847                         self.killcount = 0;
 848                 }
 849
 850                 self.cnt = WEP_LASER;
 851                 self.nixnex_lastchange_id = -1;
 852
 853                 CL_SpawnWeaponentity();
 854                 self.alpha = default_player_alpha;
 855                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 856                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 857
 858                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 859                 self.lms_traveled_distance = 0;
 860                 self.speedrunning = FALSE;
 861
 862                 race_PostSpawn(spot);
 863
 864                 if(cvar("spawn_debug"))
 865                 {
 866                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 867                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 868                 }
 869
 870                 //stuffcmd(self, "chase_active 0");
 871                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 872
 873                 if (cvar("g_spawnsound"))
 874                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 875
 876                 if(g_assault) {
 877                         if(self.team == assault_attacker_team)
 878                                 centerprint(self, "You are attacking!");
 879                         else
 880                                 centerprint(self, "You are defending!");
 881                 }
 882
 883                 target_voicescript_clear(self);
 884
 885                 oldself = self;
 886                 self = spot;
 887                         activator = oldself;
 888                                 SUB_UseTargets();
 889                         activator = world;
 890                 self = oldself;
 891
 892         } else if(self.classname == "observer") {
 893                 PutObserverInServer ();
 894         }
 895
 896         //if(g_ctf)
 897         //      ctf_playerchanged();
 898 }
 899
 900 float ClientInit_SendEntity(entity to, float sf)
 901 {
 902         float i;
 903         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 904         WriteShort(MSG_ENTITY, CSQC_REVISION);
 905         for(i = 1; i <= 24; ++i)
 906                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
 907         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
 908         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
 909         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
 910
 911         if(sv_foginterval && world.fog != "")
 912                 WriteString(MSG_ENTITY, world.fog);
 913         else
 914                 WriteString(MSG_ENTITY, "");
 915
 916         return TRUE;
 917 }
 918
 919 void ClientInit_Spawn()
 920 {
 921         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
 922 }
 923
 924 /*
 925 =============
 926 SetNewParms
 927 =============
 928 */
 929 void SetNewParms (void)
 930 {
 931         // initialize parms for a new player
 932         parm1 = -(86400 * 366);
 933 }
 934
 935 /*
 936 =============
 937 SetChangeParms
 938 =============
 939 */
 940 void SetChangeParms (void)
 941 {
 942         // save parms for level change
 943         parm1 = self.parm_idlesince - time;
 944 }
 945
 946 /*
 947 =============
 948 DecodeLevelParms
 949 =============
 950 */
 951 void DecodeLevelParms (void)
 952 {
 953         // load parms
 954         self.parm_idlesince = parm1;
 955         if(self.parm_idlesince == -(86400 * 366))
 956                 self.parm_idlesince = time;
 957
 958         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 959         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 960 }
 961
 962 /*
 963 =============
 964 ClientKill
 965
 966 Called when a client types 'kill' in the console
 967 =============
 968 */
 969
 970 void ClientKill_Now_TeamChange()
 971 {
 972         if(self.killindicator_teamchange == -1)
 973         {
 974                 self.team = -1;
 975                 JoinBestTeam( self, FALSE, FALSE );
 976         }
 977         else
 978         {
 979                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 980         }
 981 }
 982
 983 void ClientKill_Now()
 984 {
 985         if(self.killindicator_teamchange)
 986                 ClientKill_Now_TeamChange();
 987
 988         // in any case:
 989         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 990
 991         if(self.killindicator)
 992         {
 993                 dprint("Cleaned up after a leaked kill indicator.\n");
 994                 remove(self.killindicator);
 995                 self.killindicator = world;
 996         }
 997 }
 998 void KillIndicator_Think()
 999 {
1000         if (!self.owner.modelindex)
1001         {
1002                 self.owner.killindicator = world;
1003                 remove(self);
1004                 return;
1005         }
1006
1007         if(self.cnt <= 0)
1008         {
1009                 self = self.owner;
1010                 ClientKill_Now(); // no oldself needed
1011                 return;
1012         }
1013         else
1014         {
1015                 if(self.cnt <= 10)
1016                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1017                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1018                 {
1019                         if(self.cnt <= 10)
1020                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1021                         if(self.owner.killindicator_teamchange)
1022                         {
1023                                 if(self.owner.killindicator_teamchange == -1)
1024                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1025                                 else
1026                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1027                         }
1028                         else
1029                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1030                 }
1031                 self.nextthink = time + 1;
1032                 self.cnt -= 1;
1033         }
1034 }
1035
1036 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1037 {
1038         float killtime;
1039         entity e;
1040         killtime = cvar("g_balance_kill_delay");
1041
1042         self.killindicator_teamchange = targetteam;
1043
1044         if(!self.killindicator)
1045         {
1046                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1047                 {
1048                         ClientKill_Now();
1049                 }
1050                 else
1051                 {
1052                         self.killindicator = spawn();
1053                         self.killindicator.owner = self;
1054                         self.killindicator.scale = 0.5;
1055                         setattachment(self.killindicator, self, "");
1056                         setorigin(self.killindicator, '0 0 52');
1057                         self.killindicator.think = KillIndicator_Think;
1058                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1059                         self.killindicator.cnt = ceil(killtime);
1060                         self.killindicator.count = bound(0, ceil(killtime), 10);
1061                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1062
1063                         for(e = world; (e = find(e, classname, "body")) != world; )
1064                         {
1065                                 if(e.enemy != self)
1066                                         continue;
1067                                 e.killindicator = spawn();
1068                                 e.killindicator.owner = e;
1069                                 e.killindicator.scale = 0.5;
1070                                 setattachment(e.killindicator, e, "");
1071                                 setorigin(e.killindicator, '0 0 52');
1072                                 e.killindicator.think = KillIndicator_Think;
1073                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1074                                 e.killindicator.cnt = ceil(killtime);
1075                         }
1076                         self.lip = 0;
1077                 }
1078         }
1079         if(self.killindicator)
1080         {
1081                 if(targetteam)
1082                         self.killindicator.colormod = TeamColor(targetteam);
1083                 else
1084                         self.killindicator.colormod = '0 0 0';
1085         }
1086 }
1087
1088 void ClientKill (void)
1089 {
1090         ClientKill_TeamChange(0);
1091 }
1092
1093 void DoTeamChange(float destteam)
1094 {
1095         float t, c0;
1096         if(!teams_matter)
1097         {
1098                 if(destteam >= 0)
1099                         SetPlayerColors(self, destteam);
1100                 return;
1101         }
1102         if(self.classname == "player")
1103         if(destteam == -1)
1104         {
1105                 CheckAllowedTeams(self);
1106                 t = FindSmallestTeam(self, TRUE);
1107                 switch(self.team)
1108                 {
1109                         case COLOR_TEAM1: c0 = c1; break;
1110                         case COLOR_TEAM2: c0 = c2; break;
1111                         case COLOR_TEAM3: c0 = c3; break;
1112                         case COLOR_TEAM4: c0 = c4; break;
1113                         default:          c0 = 999;
1114                 }
1115                 switch(t)
1116                 {
1117                         case 1:
1118                                 if(c0 > c1)
1119                                         destteam = COLOR_TEAM1;
1120                                 break;
1121                         case 2:
1122                                 if(c0 > c2)
1123                                         destteam = COLOR_TEAM2;
1124                                 break;
1125                         case 3:
1126                                 if(c0 > c3)
1127                                         destteam = COLOR_TEAM3;
1128                                 break;
1129                         case 4:
1130                                 if(c0 > c4)
1131                                         destteam = COLOR_TEAM4;
1132                                 break;
1133                 }
1134                 if(destteam == -1)
1135                         return;
1136         }
1137         if(destteam == self.team && !self.killindicator)
1138                 return;
1139         ClientKill_TeamChange(destteam);
1140 }
1141
1142 void FixClientCvars(entity e)
1143 {
1144         // send prediction settings to the client
1145         stuffcmd(e, "\nin_bindmap 0 0\n");
1146         /*
1147          * we no longer need to stuff this. Remove this comment block if you feel
1148          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1149         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1150         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1151         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1152         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1153         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1154         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1155         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1156         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1157         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1158         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1159         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1160         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1161         stuffcmd(e, "cl_movement_edgefriction 1\n");
1162          */
1163 }
1164
1165 /*
1166 =============
1167 ClientConnect
1168
1169 Called when a client connects to the server
1170 =============
1171 */
1172 //void ctf_clientconnect();
1173 string ColoredTeamName(float t);
1174 void DecodeLevelParms (void);
1175 //void dom_player_join_team(entity pl);
1176 void ClientConnect (void)
1177 {
1178         local string s;
1179         float t;
1180
1181         if(self.flags & FL_CLIENT)
1182         {
1183                 print("Warning: ClientConnect, but already connected!\n");
1184                 return;
1185         }
1186
1187         if(Ban_MaybeEnforceBan(self))
1188                 return;
1189
1190         DecodeLevelParms();
1191
1192         self.classname = "player_joining";
1193
1194         self.flags = FL_CLIENT;
1195         self.version_nagtime = time + 10 + random() * 10;
1196
1197         if(player_count<0)
1198         {
1199                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1200                 player_count = 0;
1201         }
1202
1203         PlayerScore_Attach(self);
1204         ClientData_Attach();
1205
1206         bot_clientconnect();
1207
1208         race_PreSpawnObserver();
1209
1210         //if(g_domination)
1211         //      dom_player_join_team(self);
1212
1213         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1214
1215         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1216                 self.classname = "observer";
1217         } else {
1218                 if(teams_matter)
1219                 {
1220                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1221                         {
1222                                 self.classname = "player";
1223                                 campaign_bots_may_start = 1;
1224                         }
1225                         else
1226                         {
1227                                 self.classname = "observer"; // do it anyway
1228                         }
1229                 }
1230                 else
1231                 {
1232                         self.classname = "player";
1233                         campaign_bots_may_start = 1;
1234                 }
1235         }
1236
1237         self.playerid = (playerid_last = playerid_last + 1);
1238         if(cvar("sv_eventlog"))
1239         {
1240                 if(clienttype(self) == CLIENTTYPE_REAL)
1241                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1242                 else
1243                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1244                 s = strcat(":team:", ftos(self.playerid), ":");
1245                 s = strcat(s, ftos(self.team));
1246                 GameLogEcho(s);
1247         }
1248         self.netname_previous = strzone(self.netname);
1249
1250         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1251
1252         bprint ("^4",self.netname);
1253         bprint ("^4 connected");
1254
1255         if(g_domination || g_ctf)
1256         {
1257                 bprint(" and joined the ");
1258                 bprint(ColoredTeamName(self.team));
1259         }
1260
1261         bprint("\n");
1262
1263         self.welcomemessage_time = 0;
1264
1265         stuffcmd(self, strcat(clientstuff, "\n"));
1266         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1267         stuffcmd(self, "cl_particles_reloadeffects\n");
1268
1269         FixClientCvars(self);
1270
1271         // spawnfunc_waypoint sprites
1272         WaypointSprite_InitClient(self);
1273
1274         // Wazat's grappling hook
1275         SetGrappleHookBindings();
1276
1277         // get autoswitch state from player when he toggles it
1278         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1279
1280         // get version info from player
1281         stuffcmd(self, "cmd clientversion $gameversion\n");
1282
1283         // get other cvars from player
1284         GetCvars(0);
1285
1286         // set cvar for team scoreboard
1287         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1288
1289         // notify about available teams
1290         if(teams_matter)
1291         {
1292                 CheckAllowedTeams(self);
1293                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1294                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1295         }
1296         else
1297                 stuffcmd(self, "set _teams_available 0\n");
1298
1299         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1300
1301         if(g_arena)
1302         {
1303                 self.classname = "observer";
1304                 Spawnqueue_Insert(self);
1305         }
1306         /*else if(g_ctf)
1307         {
1308                 ctf_clientconnect();
1309         }*/
1310
1311         if(teams_matter)
1312                 attach_entcs();
1313
1314         bot_relinkplayerlist();
1315
1316         self.spectatortime = time;
1317         if(blockSpectators)
1318         {
1319                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1320         }
1321
1322         self.jointime = time;
1323         self.allowedTimeouts = cvar("sv_timeout_number");
1324
1325         if(clienttype(self) == CLIENTTYPE_REAL)
1326         {
1327                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1328
1329                 if(cvar("g_bugrigs"))
1330                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1331         }
1332
1333         if(g_lms)
1334         {
1335                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1336                 {
1337                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1338                         self.frags = FRAGS_SPECTATOR;
1339                 }
1340         }
1341
1342         if(!sv_foginterval && world.fog != "")
1343                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1344
1345         SoundEntity_Attach(self);
1346 }
1347
1348 /*
1349 =============
1350 ClientDisconnect
1351
1352 Called when a client disconnects from the server
1353 =============
1354 */
1355 .entity chatbubbleentity;
1356 .entity teambubbleentity;
1357 void ReadyCount();
1358 void ClientDisconnect (void)
1359 {
1360         if not(self.flags & FL_CLIENT)
1361         {
1362                 print("Warning: ClientDisconnect without ClientConnect\n");
1363                 return;
1364         }
1365
1366         bot_clientdisconnect();
1367
1368         if(teams_matter)
1369                 detach_entcs();
1370
1371         if(cvar("sv_eventlog"))
1372                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1373         bprint ("^4",self.netname);
1374         bprint ("^4 disconnected\n");
1375
1376         SoundEntity_Detach(self);
1377
1378         DropAllRunes(self);
1379         kh_Key_DropAll(self, TRUE);
1380
1381         Portal_ClearAll(self);
1382
1383         if(self.flagcarried)
1384                 DropFlag(self.flagcarried, world, world);
1385
1386         // Here, everything has been done that requires this player to be a client.
1387
1388         self.flags &~= FL_CLIENT;
1389
1390         if (self.chatbubbleentity)
1391                 remove (self.chatbubbleentity);
1392
1393         if (self.teambubbleentity)
1394                 remove (self.teambubbleentity);
1395
1396         if (self.killindicator)
1397                 remove (self.killindicator);
1398
1399         WaypointSprite_PlayerGone();
1400
1401         bot_relinkplayerlist();
1402
1403         // remove laserdot
1404         if(self.weaponentity)
1405                 if(self.weaponentity.lasertarget)
1406                         remove(self.weaponentity.lasertarget);
1407
1408         if(g_arena)
1409         {
1410                 Spawnqueue_Unmark(self);
1411                 Spawnqueue_Remove(self);
1412         }
1413
1414         ClientData_Detach();
1415         PlayerScore_Detach(self);
1416
1417         if(self.netname_previous)
1418                 strunzone(self.netname_previous);
1419
1420         ClearPlayerSounds();
1421
1422         self.playerid = 0;
1423         ReadyCount();
1424
1425         // free cvars
1426         GetCvars(-1);
1427 }
1428
1429 .float BUTTON_CHAT;
1430 void ChatBubbleThink()
1431 {
1432         self.nextthink = time;
1433         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1434         {
1435                 if(self.owner) // but why can that ever be world?
1436                         self.owner.chatbubbleentity = world;
1437                 remove(self);
1438                 return;
1439         }
1440         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1441                 self.model = self.mdl;
1442         else
1443                 self.model = "";
1444 };
1445
1446 void UpdateChatBubble()
1447 {
1448         if (!self.modelindex)
1449                 return;
1450         // spawn a chatbubble entity if needed
1451         if (!self.chatbubbleentity)
1452         {
1453                 self.chatbubbleentity = spawn();
1454                 self.chatbubbleentity.owner = self;
1455                 self.chatbubbleentity.exteriormodeltoclient = self;
1456                 self.chatbubbleentity.think = ChatBubbleThink;
1457                 self.chatbubbleentity.nextthink = time;
1458                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1459                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1460                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1461                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1462                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1463                 self.chatbubbleentity.model = "";
1464                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1465         }
1466 }
1467
1468
1469 void TeamBubbleThink()
1470 {
1471         self.nextthink = time;
1472         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1473         {
1474                 if(self.owner) // but why can that ever be world?
1475                         self.owner.teambubbleentity = world;
1476                 remove(self);
1477                 return;
1478         }
1479 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1480         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1481                 self.model = "";
1482         else
1483                 self.model = self.mdl;
1484
1485 };
1486
1487 float TeamBubble_customizeentityforclient()
1488 {
1489         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1490 }
1491
1492 void UpdateTeamBubble()
1493 {
1494         if (!self.modelindex || !teams_matter)
1495                 return;
1496         // spawn a teambubble entity if needed
1497         if (!self.teambubbleentity && teams_matter)
1498         {
1499                 self.teambubbleentity = spawn();
1500                 self.teambubbleentity.owner = self;
1501                 self.teambubbleentity.exteriormodeltoclient = self;
1502                 self.teambubbleentity.think = TeamBubbleThink;
1503                 self.teambubbleentity.nextthink = time;
1504                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1505 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1506                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1507                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1508                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1509                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1510                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1511                 self.teambubbleentity.effects = EF_LOWPRECISION;
1512         }
1513 }
1514
1515 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1516 // added to the model skins
1517 /*void UpdateColorModHack()
1518 {
1519         local float c;
1520         c = self.clientcolors & 15;
1521         // LordHavoc: only bothering to support white, green, red, yellow, blue
1522              if (!teams_matter) self.colormod = '0 0 0';
1523         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1524         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1525         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1526         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1527         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1528         else self.colormod = '1 1 1';
1529 };*/
1530
1531 void respawn(void)
1532 {
1533         CopyBody(1);
1534         self.effects |= EF_NODRAW; // prevent another CopyBody
1535         PutClientInServer();
1536 }
1537
1538 /**
1539  * When sv_timeout is used this function returs strings like
1540  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1541  * Called by centerprint functions
1542  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1543  */
1544 string getTimeoutText(float addOneSecond) {
1545         if (!cvar("sv_timeout") || !timeoutStatus)
1546                 return "";
1547
1548         local string retStr;
1549         if (timeoutStatus == 1) {
1550                 if (addOneSecond == 1) {
1551                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1552                 }
1553                 else {
1554                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1555                 }
1556                 return retStr;
1557         }
1558         else if (timeoutStatus == 2) {
1559                 if (addOneSecond) {
1560                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1561                         //don't show messages like "Timeout ends in 0 seconds"...
1562                         if ((remainingTimeoutTime + 1) > 0)
1563                                 return retStr;
1564                         else
1565                                 return "";
1566                 }
1567                 else {
1568                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1569                         //don't show messages like "Timeout ends in 0 seconds"...
1570                         if (remainingTimeoutTime > 0)
1571                                 return retStr;
1572                         else
1573                                 return "";
1574                 }
1575         }
1576         else return "";
1577 }
1578
1579 void player_powerups (void)
1580 {
1581         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1582         {
1583                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, ATTN_IDLE);
1584                 self.modelflags |= MF_ROCKET;
1585         }
1586         else
1587         {
1588                 SoundEntity_StopSound(self, CHAN_PLAYER);
1589                 self.modelflags &~= MF_ROCKET;
1590         }
1591
1592         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1593
1594         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1595                 return;
1596
1597         if (g_minstagib)
1598         {
1599                 if (self.items & IT_STRENGTH)
1600                 {
1601                         if (time > self.strength_finished)
1602                         {
1603                                 self.alpha = default_player_alpha;
1604                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1605                                 self.items &~= IT_STRENGTH;
1606                                 sprint(self, "^3Invisibility has worn off\n");
1607                         }
1608                 }
1609                 else
1610                 {
1611                         if (time < self.strength_finished)
1612                         {
1613                                 self.alpha = g_minstagib_invis_alpha;
1614                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1615                                 self.items |= IT_STRENGTH;
1616                                 sprint(self, "^3You are invisible\n");
1617                         }
1618                 }
1619
1620                 if (self.items & IT_INVINCIBLE)
1621                 {
1622                         if (time > self.invincible_finished)
1623                         {
1624                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1625                                 sprint(self, "^3Speed has worn off\n");
1626                         }
1627                 }
1628                 else
1629                 {
1630                         if (time < self.invincible_finished)
1631                         {
1632                                 self.items = self.items | IT_INVINCIBLE;
1633                                 sprint(self, "^3You are on speed\n");
1634                         }
1635                 }
1636                 return;
1637         }
1638
1639         if (self.items & IT_STRENGTH)
1640         {
1641                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1642                 if (time > self.strength_finished)
1643                 {
1644                         self.items = self.items - (self.items & IT_STRENGTH);
1645                         sprint(self, "^3Strength has worn off\n");
1646                 }
1647         }
1648         else
1649         {
1650                 if (time < self.strength_finished)
1651                 {
1652                         self.items = self.items | IT_STRENGTH;
1653                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1654                 }
1655         }
1656         if (self.items & IT_INVINCIBLE)
1657         {
1658                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1659                 if (time > self.invincible_finished)
1660                 {
1661                         self.items = self.items - (self.items & IT_INVINCIBLE);
1662                         sprint(self, "^3Shield has worn off\n");
1663                 }
1664         }
1665         else
1666         {
1667                 if (time < self.invincible_finished)
1668                 {
1669                         self.items = self.items | IT_INVINCIBLE;
1670                         sprint(self, "^3Shield surrounds you\n");
1671                 }
1672         }
1673
1674         if (cvar("g_fullbrightplayers"))
1675                 self.effects = self.effects | EF_FULLBRIGHT;
1676
1677         // midair gamemode: damage only while in the air
1678         // if in midair mode, being on ground grants temporary invulnerability
1679         // (this is so that multishot weapon don't clear the ground flag on the
1680         // first damage in the frame, leaving the player vulnerable to the
1681         // remaining hits in the same frame)
1682         if (self.flags & FL_ONGROUND)
1683         if (g_midair)
1684                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1685
1686         if (time >= game_starttime)
1687         if (time < self.spawnshieldtime)
1688                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1689 }
1690
1691 float CalcRegen(float current, float stable, float regenfactor)
1692 {
1693         if(current > stable)
1694                 return current;
1695         else if(current > stable - 0.25) // when close enough, "snap"
1696                 return stable;
1697         else
1698                 return min(stable, current + (stable - current) * regenfactor * frametime);
1699 }
1700
1701 void player_regen (void)
1702 {
1703         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1704         maxh = cvar("g_balance_health_stable");
1705         maxa = cvar("g_balance_armor_stable");
1706         limith = cvar("g_balance_health_limit");
1707         limita = cvar("g_balance_armor_limit");
1708
1709         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1710                 return;
1711
1712         max_mod = regen_mod = rot_mod = limit_mod = 1;
1713
1714         if (self.runes & RUNE_REGEN)
1715         {
1716                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1717                 {
1718                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1719                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1720                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1721                 }
1722                 else
1723                 {
1724                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1725                         max_mod = cvar("g_balance_rune_regen_hpmod");
1726                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1727                 }
1728         }
1729         else if (self.runes & CURSE_VENOM)
1730         {
1731                 max_mod = cvar("g_balance_curse_venom_hpmod");
1732                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1733                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1734                 else
1735                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1736                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1737                 //if (!self.runes & RUNE_REGEN)
1738                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1739         }
1740         maxh = maxh * max_mod;
1741         //maxa = maxa * max_mod;
1742         limith = limith * limit_mod;
1743         limita = limita * limit_mod;
1744
1745         if (self.armorvalue > maxa)
1746         {
1747                 if (time > self.pauserotarmor_finished)
1748                 {
1749                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1750                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1751                 }
1752         }
1753         else if (self.armorvalue < maxa)
1754         {
1755                 if (time > self.pauseregen_finished)
1756                 {
1757                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1758                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1759                 }
1760         }
1761         if (self.health > maxh)
1762         {
1763                 if (time > self.pauserothealth_finished)
1764                 {
1765                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1766                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1767                 }
1768         }
1769         else if (self.health < maxh)
1770         {
1771                 if (time > self.pauseregen_finished)
1772                 {
1773                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1774                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1775                 }
1776         }
1777
1778         if (self.health > limith)
1779                 self.health = limith;
1780         if (self.armorvalue > limita)
1781                 self.armorvalue = limita;
1782
1783         // if player rotted to death...  die!
1784         if(self.health < 1)
1785                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1786 }
1787
1788 float zoomstate_set;
1789 void SetZoomState(float z)
1790 {
1791         if(z != self.zoomstate)
1792                 ClientData_Touch(self);
1793         zoomstate_set = 1;
1794 }
1795
1796 void GetPressedKeys(void) {
1797         if (self.movement_x > 0) // get if movement keys are pressed
1798         {       // forward key pressed
1799                 self.pressedkeys |= KEY_FORWARD;
1800                 self.pressedkeys &~= KEY_BACKWARD;
1801         }
1802         else if (self.movement_x < 0)
1803         {       // backward key pressed
1804                 self.pressedkeys |= KEY_BACKWARD;
1805                 self.pressedkeys &~= KEY_FORWARD;
1806         }
1807         else
1808         {       // no x input
1809                 self.pressedkeys &~= KEY_FORWARD;
1810                 self.pressedkeys &~= KEY_BACKWARD;
1811         }
1812
1813         if (self.movement_y > 0)
1814         {       // right key pressed
1815                 self.pressedkeys |= KEY_RIGHT;
1816                 self.pressedkeys &~= KEY_LEFT;
1817         }
1818         else if (self.movement_y < 0)
1819         {       // left key pressed
1820                 self.pressedkeys |= KEY_LEFT;
1821                 self.pressedkeys &~= KEY_RIGHT;
1822         }
1823         else
1824         {       // no y input
1825                 self.pressedkeys &~= KEY_RIGHT;
1826                 self.pressedkeys &~= KEY_LEFT;
1827         }
1828
1829         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1830                 self.pressedkeys |= KEY_JUMP;
1831         else
1832                 self.pressedkeys &~= KEY_JUMP;
1833         if (self.BUTTON_CROUCH)
1834                 self.pressedkeys |= KEY_CROUCH;
1835         else
1836                 self.pressedkeys &~= KEY_CROUCH;
1837 }
1838
1839 /*
1840 ======================
1841 spectate mode routines
1842 ======================
1843 */
1844 void SpectateCopy(entity spectatee) {
1845         self.armortype = spectatee.armortype;
1846         self.armorvalue = spectatee.armorvalue;
1847         self.ammo_cells = spectatee.ammo_cells;
1848         self.ammo_shells = spectatee.ammo_shells;
1849         self.ammo_nails = spectatee.ammo_nails;
1850         self.ammo_rockets = spectatee.ammo_rockets;
1851         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1852         self.health = spectatee.health;
1853         self.impulse = 0;
1854         self.items = spectatee.items;
1855         self.strength_finished = spectatee.strength_finished;
1856         self.invincible_finished = spectatee.invincible_finished;
1857         self.pressedkeys = spectatee.pressedkeys;
1858         self.weapons = spectatee.weapons;
1859         self.switchweapon = spectatee.switchweapon;
1860         self.weapon = spectatee.weapon;
1861         self.punchangle = spectatee.punchangle;
1862         self.view_ofs = spectatee.view_ofs;
1863         self.v_angle = spectatee.v_angle;
1864         self.velocity = spectatee.velocity;
1865         self.dmg_take = spectatee.dmg_take;
1866         self.dmg_save = spectatee.dmg_save;
1867         self.dmg_inflictor = spectatee.dmg_inflictor;
1868         self.angles = spectatee.v_angle;
1869         self.fixangle = TRUE;
1870         setorigin(self, spectatee.origin);
1871         setsize(self, spectatee.mins, spectatee.maxs);
1872         SetZoomState(spectatee.zoomstate);
1873 }
1874
1875 float SpectateUpdate() {
1876         if(!self.enemy)
1877                 return 0;
1878
1879         if (self == self.enemy)
1880                 return 0;
1881
1882         if(self.enemy.flags & FL_NOTARGET)
1883                 return 0;
1884
1885         SpectateCopy(self.enemy);
1886
1887         return 1;
1888 }
1889
1890 float SpectateNext() {
1891         other = find(self.enemy, classname, "player");
1892         if (!other) {
1893                 other = find(other, classname, "player");
1894         }
1895         if (other) {
1896                 self.enemy = other;
1897         }
1898         if(self.enemy.classname == "player") {
1899                 msg_entity = self;
1900                 WriteByte(MSG_ONE, SVC_SETVIEW);
1901                 WriteEntity(MSG_ONE, self.enemy);
1902                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1903                 if(!SpectateUpdate())
1904                         PutObserverInServer();
1905                 return 1;
1906         } else {
1907                 return 0;
1908         }
1909 }
1910
1911 /*
1912 =============
1913 ShowRespawnCountdown()
1914
1915 Update a respawn countdown display.
1916 =============
1917 */
1918 void ShowRespawnCountdown()
1919 {
1920         float number;
1921         if(self.deadflag == DEAD_NO) // just respawned?
1922                 return;
1923         else
1924         {
1925                 number = ceil(self.death_time - time);
1926                 if(number <= 0)
1927                         return;
1928                 if(number <= self.respawn_countdown)
1929                 {
1930                         self.respawn_countdown = number - 1;
1931                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1932                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
1933                 }
1934         }
1935 }
1936
1937 void LeaveSpectatorMode()
1938 {
1939         if(isJoinAllowed()) {
1940                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
1941                         self.classname = "player";
1942                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1943                                 JoinBestTeam(self, FALSE, TRUE);
1944                         if(cvar("g_campaign"))
1945                                 campaign_bots_may_start = 1;
1946                         PutClientInServer();
1947                         if(!(self.flags & FL_NOTARGET))
1948                                 bprint ("^4", self.netname, "^4 is playing now\n");
1949                         centerprint(self,"");
1950                         return;
1951                 } else {
1952                         stuffcmd(self,"menu_showteamselect\n");
1953                         return;
1954                 }
1955         }
1956         else {
1957                 //player may not join because of g_maxplayers is set
1958                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1959         }
1960 }
1961
1962 /**
1963  * Determines whether the player is allowed to join. This depends on cvar
1964  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1965  * it checks whether the number of currently playing players exceeds g_maxplayers.
1966  * @return bool TRUE if the player is allowed to join, false otherwise
1967  */
1968 float isJoinAllowed() {
1969         if (!cvar("g_maxplayers"))
1970                 return TRUE;
1971
1972         local entity e;
1973         local float currentlyPlaying;
1974         FOR_EACH_REALPLAYER(e) {
1975                 if(e.classname == "player")
1976                         currentlyPlaying += 1;
1977         }
1978         if(currentlyPlaying < cvar("g_maxplayers"))
1979                 return TRUE;
1980
1981         return FALSE;
1982 }
1983
1984 /**
1985  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1986  * g_maxplayers_spectator_blocktime seconds
1987  */
1988 void checkSpectatorBlock() {
1989         if(self.classname == "spectator" || self.classname == "observer") {
1990                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1991                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1992                         dropclient(self);
1993                 }
1994         }
1995 }
1996
1997 float vercmp_recursive(string v1, string v2)
1998 {
1999         float dot1, dot2;
2000         string s1, s2;
2001         float r;
2002
2003         dot1 = strstrofs(v1, ".", 0);
2004         dot2 = strstrofs(v2, ".", 0);
2005         if(dot1 == -1)
2006                 s1 = v1;
2007         else
2008                 s1 = substring(v1, 0, dot1);
2009         if(dot2 == -1)
2010                 s2 = v2;
2011         else
2012                 s2 = substring(v2, 0, dot2);
2013
2014         r = stof(s1) - stof(s2);
2015         if(r != 0)
2016                 return r;
2017
2018         r = strcasecmp(s1, s2);
2019         if(r != 0)
2020                 return r;
2021
2022         if(dot1 == -1)
2023                 if(dot2 == -1)
2024                         return 0;
2025                 else
2026                         return -1;
2027         else
2028                 if(dot2 == -1)
2029                         return 1;
2030                 else
2031                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2032 }
2033
2034 float vercmp(string v1, string v2)
2035 {
2036         if(strcasecmp(v1, v2) == 0) // early out check
2037                 return 0;
2038         return vercmp_recursive(v1, v2);
2039 }
2040
2041 void ObserverThink()
2042 {
2043         if (self.flags & FL_JUMPRELEASED) {
2044                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2045                         self.welcomemessage_time = 0;
2046                         self.flags &~= FL_JUMPRELEASED;
2047                         self.flags |= FL_SPAWNING;
2048                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2049                         self.welcomemessage_time = 0;
2050                         self.flags &~= FL_JUMPRELEASED;
2051                         if(SpectateNext() == 1) {
2052                                 self.classname = "spectator";
2053                         }
2054                 }
2055         } else {
2056                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2057                         self.flags |= FL_JUMPRELEASED;
2058                         if(self.flags & FL_SPAWNING)
2059                         {
2060                                 self.flags &~= FL_SPAWNING;
2061                                 LeaveSpectatorMode();
2062                                 return;
2063                         }
2064                 }
2065         }
2066         PrintWelcomeMessage(self);
2067 }
2068
2069 void SpectatorThink()
2070 {
2071         if (self.flags & FL_JUMPRELEASED) {
2072                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2073                         self.welcomemessage_time = 0;
2074                         self.flags &~= FL_JUMPRELEASED;
2075                         self.flags |= FL_SPAWNING;
2076                 } else if(self.BUTTON_ATCK) {
2077                         self.welcomemessage_time = 0;
2078                         self.flags &~= FL_JUMPRELEASED;
2079                         if(SpectateNext() == 1) {
2080                                 self.classname = "spectator";
2081                         } else {
2082                                 self.classname = "observer";
2083                                 PutClientInServer();
2084                         }
2085                 } else if (self.BUTTON_ATCK2) {
2086                         self.welcomemessage_time = 0;
2087                         self.flags &~= FL_JUMPRELEASED;
2088                         self.classname = "observer";
2089                         PutClientInServer();
2090                 } else {
2091                         if(!SpectateUpdate())
2092                                 PutObserverInServer();
2093                 }
2094         } else {
2095                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2096                         self.flags |= FL_JUMPRELEASED;
2097                         if(self.flags & FL_SPAWNING)
2098                         {
2099                                 self.flags &~= FL_SPAWNING;
2100                                 LeaveSpectatorMode();
2101                                 return;
2102                         }
2103                 }
2104         }
2105         PrintWelcomeMessage(self);
2106         self.flags |= FL_CLIENT | FL_NOTARGET;
2107 }
2108
2109 .float touchexplode_time;
2110
2111 /*
2112 =============
2113 PlayerPreThink
2114
2115 Called every frame for each client before the physics are run
2116 =============
2117 */
2118 void() ctf_setstatus;
2119 void PlayerPreThink (void)
2120 {
2121         self.stat_sys_ticrate = cvar("sys_ticrate");
2122         self.stat_game_starttime = game_starttime;
2123         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2124
2125         if(blockSpectators && frametime)
2126                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2127                 checkSpectatorBlock();
2128
2129         zoomstate_set = 0;
2130
2131         if(self.netname_previous != self.netname)
2132         {
2133                 if(cvar("sv_eventlog"))
2134                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2135                 if(self.netname_previous)
2136                         strunzone(self.netname_previous);
2137                 self.netname_previous = strzone(self.netname);
2138         }
2139
2140         // version nagging
2141         if(self.version_nagtime)
2142                 if(self.cvar_g_nexuizversion)
2143                         if(time > self.version_nagtime)
2144                         {
2145                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2146                                 {
2147                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2148                                         {
2149                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2150                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2151                                         }
2152                                         else
2153                                         {
2154                                                 float r;
2155                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2156                                                 if(r < 0)
2157                                                 {
2158                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2159                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2160                                                 }
2161                                                 else if(r > 0)
2162                                                 {
2163                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2164                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2165                                                 }
2166                                         }
2167                                 }
2168                                 self.version_nagtime = 0;
2169                         }
2170
2171         // GOD MODE info
2172         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2173         {
2174                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2175                 self.max_armorvalue = 0;
2176         }
2177
2178         if(frametime)
2179                 antilag_record(self);
2180
2181         if(self.classname == "player") {
2182 //              if(self.netname == "Wazat")
2183 //                      bprint(self.classname, "\n");
2184
2185                 CheckRules_Player();
2186
2187                 PrintWelcomeMessage(self);
2188
2189                 if (intermission_running)
2190                 {
2191                         IntermissionThink ();   // otherwise a button could be missed between
2192                         return;                                 // the think tics
2193                 }
2194
2195                 if(self.teleport_time)
2196                 if(time > self.teleport_time)
2197                 {
2198                         self.teleport_time = 0;
2199                         self.effects = self.effects - (self.effects & EF_NODRAW);
2200                 }
2201
2202                 Nixnex_GiveCurrentWeapon();
2203
2204                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2205                         UpdateSelectedPlayer();
2206
2207                 //don't allow the player to turn around while game is paused!
2208                 if(timeoutStatus == 2) {
2209                         self.v_angle = self.lastV_angle;
2210                         self.angles = self.lastV_angle;
2211                         self.fixangle = TRUE;
2212                 }
2213
2214                 player_powerups();
2215
2216                 if (self.deadflag != DEAD_NO)
2217                 {
2218                         float button_pressed, force_respawn;
2219                         if(frametime)
2220                                 player_anim();
2221                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2222                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2223                         if (self.deadflag == DEAD_DYING)
2224                         {
2225                                 if(force_respawn)
2226                                         self.deadflag = DEAD_RESPAWNING;
2227                                 else if(!button_pressed)
2228                                         self.deadflag = DEAD_DEAD;
2229                         }
2230                         else if (self.deadflag == DEAD_DEAD)
2231                         {
2232                                 if(button_pressed)
2233                                         self.deadflag = DEAD_RESPAWNABLE;
2234                         }
2235                         else if (self.deadflag == DEAD_RESPAWNABLE)
2236                         {
2237                                 if(!button_pressed)
2238                                         self.deadflag = DEAD_RESPAWNING;
2239                         }
2240                         else if (self.deadflag == DEAD_RESPAWNING)
2241                         {
2242                                 if(time > self.death_time)
2243                                 {
2244                                         self.death_time = time + 1; // only retry once a second
2245                                         respawn();
2246                                 }
2247                         }
2248                         ShowRespawnCountdown();
2249                         return;
2250                 }
2251
2252                 if(g_touchexplode)
2253                 if(time > self.touchexplode_time)
2254                 if(self.classname == "player")
2255                 if(self.deadflag == DEAD_NO)
2256                 if not(IS_INDEPENDENT_PLAYER(self))
2257                 FOR_EACH_PLAYER(other) if(self != other)
2258                 {
2259                         if(time > other.touchexplode_time)
2260                         if(other.classname == "player")
2261                         if(other.deadflag == DEAD_NO)
2262                         if not(IS_INDEPENDENT_PLAYER(other))
2263                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2264                         {
2265                                 PlayerTouchExplode(self, other);
2266                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2267                         }
2268                 }
2269
2270                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2271                 {
2272                         vector dist;
2273
2274                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2275                         dist = self.oldorigin - self.origin;
2276                         dist_z = 0;
2277                         self.lms_traveled_distance += fabs(vlen(dist));
2278
2279                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2280                         {
2281                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2282                                 self.lms_traveled_distance = 0;
2283                         }
2284
2285                         if(time > self.lms_nextcheck)
2286                         {
2287                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2288                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2289                                 {
2290                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2291                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2292                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2293                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2294                                 }
2295                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2296                                 self.lms_traveled_distance = 0;
2297                         }
2298                 }
2299
2300                 self.oldorigin = self.origin;
2301
2302                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2303                 {
2304                         if (!self.crouch)
2305                         {
2306                                 self.crouch = TRUE;
2307                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2308                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2309                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2310                         }
2311                 }
2312                 else
2313                 {
2314                         if (self.crouch)
2315                         {
2316                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2317                                 if (!trace_startsolid)
2318                                 {
2319                                         self.crouch = FALSE;
2320                                         self.view_ofs = PL_VIEW_OFS;
2321                                         setsize (self, PL_MIN, PL_MAX);
2322                                 }
2323                         }
2324                 }
2325
2326                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2327                 {
2328                         if(self.bloodloss_timer < time)
2329                         {
2330                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2331                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2332                         }
2333                 }
2334
2335                 FixPlayermodel();
2336
2337                 GrapplingHookFrame();
2338
2339                 if(frametime)
2340                         W_WeaponFrame();
2341
2342                 player_regen();
2343                 if(frametime)
2344                         player_anim();
2345
2346                 if (g_minstagib)
2347                         minstagib_ammocheck();
2348
2349                 ctf_setstatus();
2350                 kh_setstatus();
2351
2352                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2353
2354                 //self.angles_y=self.v_angle_y + 90;   // temp
2355
2356                 //if (TetrisPreFrame()) return;
2357         } else if(gameover) {
2358                 if (intermission_running)
2359                         IntermissionThink ();   // otherwise a button could be missed between
2360                 return;
2361         } else if(self.classname == "observer") {
2362                 ObserverThink();
2363         } else if(self.classname == "spectator") {
2364                 SpectatorThink();
2365         }
2366
2367         if(!zoomstate_set)
2368                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2369
2370         float oldspectatee_status;
2371         oldspectatee_status = self.spectatee_status;
2372         if(self.classname == "spectator")
2373                 self.spectatee_status = num_for_edict(self.enemy);
2374         else if(self.classname == "observer")
2375                 self.spectatee_status = num_for_edict(self);
2376         else
2377                 self.spectatee_status = 0;
2378         if(self.spectatee_status != oldspectatee_status)
2379         {
2380                 ClientData_Touch(self);
2381                 if(g_race)
2382                         race_InitSpectator();
2383         }
2384
2385         if(self.teamkill_soundtime)
2386         if(time > self.teamkill_soundtime)
2387         {
2388                 self.teamkill_soundtime = 0;
2389
2390                 entity oldpusher, oldself;
2391
2392                 oldself = self; self = self.teamkill_soundsource;
2393                 oldpusher = self.pusher; self.pusher = oldself;
2394
2395                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2396
2397                 self.pusher = oldpusher;
2398                 self = oldself;
2399         }
2400
2401         if(self.taunt_soundtime)
2402         if(time > self.taunt_soundtime)
2403         {
2404                 self.taunt_soundtime = 0;
2405                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2406         }
2407
2408         target_voicescript_next(self);
2409 }
2410
2411 // on dragger:
2412 .entity dragentity;
2413 .float draggravity;
2414 .float dragspeed; // speed of mouse wheel action
2415 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2416 .vector draglocalvector; // local attachment vector of the dragentity
2417 .float draglocalangle;
2418 // on draggee:
2419 .entity draggedby;
2420 .float dragmovetype;
2421 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2422 {
2423         float tagscale;
2424
2425         draggee.dragmovetype = draggee.movetype;
2426         draggee.draggravity = draggee.gravity;
2427         draggee.movetype = MOVETYPE_WALK;
2428         draggee.gravity = 0.00001;
2429         draggee.flags &~= FL_ONGROUND;
2430         draggee.draggedby = dragger;
2431
2432         dragger.dragentity = draggee;
2433
2434         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2435         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2436         touchpoint = touchpoint - gettaginfo(draggee, 0);
2437         tagscale = pow(vlen(v_forward), -2);
2438         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2439         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2440         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2441
2442         dragger.dragspeed = 64;
2443 }
2444
2445 void Drag_Finish(entity dragger)
2446 {
2447         entity draggee;
2448         draggee = dragger.dragentity;
2449         if(dragger)
2450                 dragger.dragentity = world;
2451         draggee.draggedby = world;
2452         draggee.movetype = draggee.dragmovetype;
2453         draggee.gravity = draggee.draggravity;
2454
2455         switch(draggee.movetype)
2456         {
2457                 case MOVETYPE_TOSS:
2458                 case MOVETYPE_WALK:
2459                 case MOVETYPE_STEP:
2460                 case MOVETYPE_FLYMISSILE:
2461                 case MOVETYPE_BOUNCE:
2462                 case MOVETYPE_BOUNCEMISSILE:
2463                         break;
2464                 default:
2465                         draggee.velocity = '0 0 0';
2466                         break;
2467         }
2468
2469         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2470         {
2471                 draggee.velocity = '0 0 0';
2472                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2473         }
2474 }
2475
2476 float Drag_IsDraggable(entity draggee)
2477 {
2478         // TODO add more checks for bad stuff here
2479         if(draggee.classname == "func_bobbing")
2480                 return FALSE;
2481         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2482                 return FALSE;
2483         if(draggee.classname == "plat")
2484                 return FALSE;
2485         if(draggee.classname == "func_button")
2486                 return FALSE;
2487         if(draggee.model == "")
2488                 return FALSE;
2489         if(draggee.classname == "spectator")
2490                 return FALSE;
2491         if(draggee.classname == "observer")
2492                 return FALSE;
2493         if(draggee.classname == "exteriorweaponentity")
2494                 return FALSE;
2495
2496         return TRUE;
2497 }
2498
2499 float Drag_MayChangeAngles(entity draggee)
2500 {
2501         // TODO add more checks for bad stuff here
2502         if(substring(draggee.model, 0, 1) == "*")
2503                 return FALSE;
2504         return TRUE;
2505 }
2506
2507 void Drag_MoveForward(entity dragger)
2508 {
2509         dragger.dragdistance += dragger.dragspeed;
2510 }
2511
2512 void Drag_SetSpeed(entity dragger, float s)
2513 {
2514         dragger.dragspeed = pow(2, s);
2515 }
2516
2517 void Drag_MoveBackward(entity dragger)
2518 {
2519         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2520 }
2521
2522 void Drag_Update(entity dragger)
2523 {
2524         vector curorigin, neworigin, goodvelocity;
2525         float f;
2526         entity draggee;
2527
2528         draggee = dragger.dragentity;
2529         draggee.flags &~= FL_ONGROUND;
2530
2531         curorigin = gettaginfo(draggee, 0);
2532         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2533         makevectors(dragger.v_angle);
2534         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2535         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2536
2537         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2538                 dragger.draglocalangle += 360;
2539         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2540                 dragger.draglocalangle -= 360;
2541
2542         f = min(frametime * 10, 1);
2543         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2544
2545         if(Drag_MayChangeAngles(draggee))
2546                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2547
2548         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2549
2550         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2551 }
2552
2553 float Drag_CanDrag(entity dragger)
2554 {
2555         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2556 }
2557
2558 float Drag_IsDragging(entity dragger)
2559 {
2560         if(!dragger.dragentity)
2561                 return FALSE;
2562         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2563         {
2564                 dragger.dragentity = world;
2565                 return FALSE;
2566         }
2567         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2568         {
2569                 Drag_Finish(dragger);
2570                 return FALSE;
2571         }
2572         return TRUE;
2573 }
2574
2575 void Drag_MoveDrag(entity from, entity to)
2576 {
2577         if(from.draggedby)
2578         {
2579                 to.draggedby = from.draggedby;
2580                 to.draggedby.dragentity = to;
2581                 from.draggedby = world;
2582         }
2583 }
2584
2585 /*
2586 =============
2587 PlayerPostThink
2588
2589 Called every frame for each client after the physics are run
2590 =============
2591 */
2592 .float idlekick_lasttimeleft;
2593 .float race_penalty;
2594 .float race_penalty_nagged;
2595 .float race_penalty_nagtime;
2596 void PlayerPostThink (void)
2597 {
2598         // Savage: Check for nameless players
2599         if (strlen(self.netname) < 1) {
2600                 self.netname = "Player";
2601                 stuffcmd(self, "seta _cl_name Player\n");
2602         }
2603
2604         if(sv_maxidle && frametime)
2605         {
2606                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2607                 float timeleft;
2608                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2609                 if(timeleft <= 0)
2610                 {
2611                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2612                         announce(self, "announcer/robotic/terminated.wav");
2613                         dropclient(self);
2614                         return;
2615                 }
2616                 else if(timeleft <= 10)
2617                 {
2618                         if(timeleft != self.idlekick_lasttimeleft)
2619                         {
2620                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2621                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2622                         }
2623                 }
2624                 else
2625                 {
2626                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2627                 }
2628                 self.idlekick_lasttimeleft = timeleft;
2629         }
2630
2631         if(sv_cheats)
2632                 if(Drag_CanDrag(self))
2633                         if(self.BUTTON_DRAG)
2634                                 if(!self.dragentity)
2635                                         if(self.cursor_trace_ent)
2636                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2637                                                 {
2638                                                         if(self.cursor_trace_ent.draggedby)
2639                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2640                                                         if(self.cursor_trace_ent.tag_entity)
2641                                                                 detach_sameorigin(self.cursor_trace_ent);
2642                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2643                                                 }
2644
2645         if(Drag_IsDragging(self))
2646         {
2647                 if(self.BUTTON_DRAG)
2648                 {
2649                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2650                         {
2651                                 Drag_MoveForward(self);
2652                                 self.impulse = 0;
2653                         }
2654                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2655                         {
2656                                 Drag_MoveBackward(self);
2657                                 self.impulse = 0;
2658                         }
2659                         else if(self.impulse >= 1 && self.impulse <= 9)
2660                         {
2661                                 Drag_SetSpeed(self, self.impulse - 1);
2662                         }
2663                         else if(self.impulse == 14)
2664                         {
2665                                 Drag_SetSpeed(self, 9);
2666                         }
2667
2668                         if(frametime)
2669                                 Drag_Update(self);
2670                 }
2671                 else
2672                 {
2673                         Drag_Finish(self);
2674                 }
2675         }
2676
2677         if(self.classname == "player") {
2678                 CheckRules_Player();
2679                 UpdateChatBubble();
2680                 UpdateTeamBubble();
2681                 if (self.impulse)
2682                         ImpulseCommands();
2683                 if (intermission_running)
2684                         return;         // intermission or finale
2685
2686                 //if (TetrisPostFrame()) return;
2687
2688                 // restart countdown
2689                         if(time < game_starttime) {
2690                                 if (!cvar("sv_ready_restart_after_countdown"))
2691                                 {
2692                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2693                                         {
2694                                                 if(time < game_starttime - 2)
2695                                                 {
2696                                                         if(!self.race_penalty_nagged)
2697                                                         {
2698                                                                 // TODO better notification for this!
2699                                                                 self.race_penalty_nagtime = 0;
2700                                                                 self.race_penalty_nagged = 1;
2701                                                         }
2702                                                 }
2703                                                 else if(!self.race_penalty)
2704                                                 {
2705                                                         self.race_penalty_nagtime = 0;
2706                                                         self.race_penalty = time + 5;
2707                                                 }
2708                                         }
2709                                         if(time > self.race_penalty_nagtime)
2710                                         {
2711                                                 if(self.race_penalty > time)
2712                                                 {
2713                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2714                                                 }
2715                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2716                                                 {
2717                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2718                                                 }
2719                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2720                                         }
2721                                         self.movetype = MOVETYPE_NONE;
2722                                         self.velocity = '0 0 0';
2723                                         self.avelocity = '0 0 0';
2724                                         self.movement = '0 0 0';
2725                                 }
2726                         }
2727                         else if (time < self.race_penalty)
2728                         {
2729                                 self.movetype = MOVETYPE_NONE;
2730                                 self.velocity = '0 0 0';
2731                                 self.avelocity = '0 0 0';
2732                                 self.movement = '0 0 0';
2733                         }
2734                         else
2735                         {
2736                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2737                                 if (!cvar("sv_ready_restart_after_countdown"))
2738                                 {
2739                                         if(self.movetype == MOVETYPE_NONE)
2740                                         {
2741                                                 self.movetype = MOVETYPE_WALK;
2742                                         }
2743                                         self.race_penalty = 0;
2744                                         self.race_penalty_nagged = 0;
2745                                 }
2746                         }
2747                 GetPressedKeys();
2748         } else if (self.classname == "observer") {
2749                 //do nothing
2750         } else if (self.classname == "spectator") {
2751                 //do nothing
2752         }
2753
2754         /*
2755         float i;
2756         for(i = 0; i < 1000; ++i)
2757         {
2758                 vector end;
2759                 end = self.origin + '0 0 1024' + 512 * randomvec();
2760                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2761                 if(trace_fraction < 1)
2762                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2763                 {
2764                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2765                         break;
2766                 }
2767         }
2768         */
2769
2770         Arena_Warmup();
2771
2772         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2773 }