data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         info_player_deathmatch();
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8         self.classname = "info_player_deathmatch";
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27
  28                 local float spotactive;
  29                 spotactive = 1;
  30
  31                 // filter out spots for assault
  32                 if(spot.target != "") {
  33                         local entity ent;
  34                         ent = find(world, targetname, spot.target);
  35                         while(ent) {
  36                                 if(ent.classname == "target_objective")
  37                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  38                                                 spotactive = 0;
  39                                 ent = find(ent, targetname, spot.target);
  40                         }
  41                 }
  42
  43                 if (spot.team == teamcheck && spotactive > 0)
  44                 {
  45                         pcount = 0;
  46                         player = playerlist;
  47                         while (player)
  48                         {
  49                                 if (player != self)
  50                                 if (vlen(player.origin - spot.origin) < mindist)
  51                                         pcount = pcount + 1;
  52                                 player = player.chain;
  53                         }
  54                         if (!pcount)
  55                         {
  56                                 spawn_allbad = FALSE;
  57                                 if (newfirstspot)
  58                                         previousspot.chain = spot;
  59                                 else
  60                                         newfirstspot = spot;
  61                                 previousspot = spot;
  62                                 spot.chain = world;
  63                         }
  64                         else
  65                                 spawn_allgood = FALSE;
  66                 }
  67                 spot = nextspot;
  68         }
  69         // if we couldn't find ANY good points, return the original list
  70         if (!newfirstspot)
  71                 newfirstspot = firstspot;
  72         return newfirstspot;
  73 }
  74
  75 entity Spawn_RandomPoint(entity firstspot)
  76 {
  77         local entity spot;
  78         local float numspots;
  79         // count number of spots
  80         numspots = 0;
  81         spot = firstspot;
  82         while (spot)
  83         {
  84                 numspots = numspots + 1;
  85                 spot = spot.chain;
  86         }
  87         // pick a random one
  88         numspots = numspots * random();
  89         spot = firstspot;
  90         while (spot.chain && numspots >= 1)
  91         {
  92                 numspots = numspots - 1;
  93                 spot = spot.chain;
  94         }
  95         return spot;
  96 }
  97
  98 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  99 {
 100         local entity best, spot, player;
 101         local float bestrating, rating;
 102         best = world;
 103         bestrating = -1000000;
 104         spot = firstspot;
 105         while (spot)
 106         {
 107                 rating = 1000000000;
 108                 player = playerlist;
 109                 while (player)
 110                 {
 111                         if (player != self)
 112                                 rating = min(rating, vlen(player.origin - spot.origin));
 113                         player = player.chain;
 114                 }
 115                 rating = rating + random() * 16;
 116                 if (bestrating < rating)
 117                 {
 118                         best = spot;
 119                         bestrating = rating;
 120                 }
 121                 spot = spot.chain;
 122         }
 123         return best;
 124 }
 125
 126 /*
 127 =============
 128 SelectSpawnPoint
 129
 130 Finds a point to respawn
 131 =============
 132 */
 133 entity SelectSpawnPoint (float anypoint)
 134 {
 135         local float teamcheck;
 136         local entity spot, firstspot, playerlist;
 137
 138         spot = find (world, classname, "testplayerstart");
 139         if (spot)
 140                 return spot;
 141
 142         teamcheck = 0;
 143
 144         if(!anypoint && cvar("g_ctf") )
 145                 teamcheck = self.team;
 146
 147         // get the list of players
 148         playerlist = findchain(classname, "player");
 149         // get the entire list of spots
 150         firstspot = findchain(classname, "info_player_deathmatch");
 151         // filter out the bad ones
 152         // (note this returns the original list if none survived)
 153         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 154
 155         // there is 50/50 chance of choosing a random spot or the furthest spot
 156         // (this means that roughly every other spawn will be furthest, so you
 157         // usually won't get fragged at spawn twice in a row)
 158         if (arena_roundbased)
 159         {
 160                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 161                 spot = Spawn_RandomPoint(firstspot);
 162         }
 163         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 164                 spot = Spawn_RandomPoint(firstspot);
 165         else
 166                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 167
 168         if (!spot)
 169         {
 170                 if(cvar("spawn_debug"))
 171                         GotoNextMap();
 172                 else
 173                         error ("PutClientInServer: no start points on level");
 174         }
 175
 176         return spot;
 177 }
 178
 179 /*
 180 =============
 181 CheckPlayerModel
 182
 183 Checks if the argument string can be a valid playermodel.
 184 Returns a valid one in doubt.
 185 =============
 186 */
 187 string FallbackPlayerModel = "models/player/marine.zym";
 188 string CheckPlayerModel(string plyermodel) {
 189         if(strlen(plyermodel) < 4)
 190                 return FallbackPlayerModel;
 191         if( substring(plyermodel,0,14) != "models/player/")
 192                 return FallbackPlayerModel;
 193         else if(cvar("sv_servermodelsonly"))
 194         {
 195                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 196                         return FallbackPlayerModel;
 197                 if(!fexists(plyermodel))
 198                         return FallbackPlayerModel;
 199         }
 200         return plyermodel;
 201 }
 202
 203 /*
 204 =============
 205 Client_customizeentityforclient
 206
 207 LOD reduction
 208 =============
 209 */
 210 float Client_customizeentityforclient()
 211 {
 212 #ifdef ALLOW_VARIABLE_LOD
 213         // self: me
 214         // other: the player viewing me
 215         float distance;
 216         float f;
 217
 218         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 219                 return TRUE;
 220
 221         if(other.cvar_cl_playerdetailreduction <= 0)
 222         {
 223                 if(other.cvar_cl_playerdetailreduction <= -2)
 224                         self.modelindex = self.modelindex_lod2;
 225                 else if(other.cvar_cl_playerdetailreduction <= -1)
 226                         self.modelindex = self.modelindex_lod1;
 227                 else
 228                         self.modelindex = self.modelindex_lod0;
 229         }
 230         else
 231         {
 232                 distance = vlen(self.origin - other.origin);
 233                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 234                 if(f > 10000)
 235                         self.modelindex = self.modelindex_lod2;
 236                 else if(f > 5000)
 237                         self.modelindex = self.modelindex_lod1;
 238                 else
 239                         self.modelindex = self.modelindex_lod0;
 240         }
 241 #endif
 242
 243         return TRUE;
 244 }
 245
 246 void setmodel_lod(entity e, string modelname)
 247 {
 248 #ifdef ALLOW_VARIABLE_LOD
 249         string s;
 250
 251         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 252         if(fexists(s))
 253         {
 254                 precache_model(s);
 255                 setmodel(e, s); // players have high precision
 256                 self.modelindex_lod1 = self.modelindex;
 257         }
 258         else
 259                 self.modelindex_lod1 = -1;
 260
 261         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 262         if(fexists(s))
 263         {
 264                 precache_model(s);
 265                 setmodel(e, s); // players have high precision
 266                 self.modelindex_lod2 = self.modelindex;
 267         }
 268         else
 269                 self.modelindex_lod2 = -1;
 270
 271         precache_model(modelname);
 272         setmodel(e, modelname); // players have high precision
 273         self.modelindex_lod0 = self.modelindex;
 274
 275         if(self.modelindex_lod1 < 0)
 276                 self.modelindex_lod1 = self.modelindex;
 277
 278         if(self.modelindex_lod2 < 0)
 279                 self.modelindex_lod2 = self.modelindex;
 280 #else
 281         precache_model(modelname);
 282         setmodel(e, modelname); // players have high precision
 283 #endif
 284 }
 285
 286 /*
 287 =============
 288 PutObserverInServer
 289
 290 putting a client as observer in the server
 291 =============
 292 */
 293 void PutObserverInServer (void)
 294 {
 295         entity  spot;
 296         spot = SelectSpawnPoint (FALSE);
 297         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 298
 299         if(clienttype(self) == CLIENTTYPE_REAL)
 300         {
 301                 msg_entity = self;
 302                 WriteByte(MSG_ONE, SVC_SETVIEW);
 303                 WriteEntity(MSG_ONE, self);
 304         }
 305
 306         DropAllRunes(self);
 307         kh_Key_DropAll(self, TRUE);
 308
 309         if(self.flagcarried)
 310                 DropFlag(self.flagcarried);
 311
 312         WaypointSprite_PlayerDead();
 313
 314         DistributeFragsAmongTeam(self, self.team, 1);
 315
 316         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 317                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 318         else if(self.killcount != -666)
 319                 bprint ("^4", self.netname, "^4 is spectating now\n");
 320
 321         self.classname = "observer";
 322         self.health = -666;
 323         self.takedamage = DAMAGE_NO;
 324         self.solid = SOLID_NOT;
 325         self.movetype = MOVETYPE_NOCLIP;
 326         self.flags = FL_CLIENT | FL_NOTARGET;
 327         self.armorvalue = 666;
 328         self.effects = 0;
 329         self.armorvalue = cvar("g_balance_armor_start");
 330         self.pauserotarmor_finished = 0;
 331         self.pauserothealth_finished = 0;
 332         self.pauseregen_finished = 0;
 333         self.damageforcescale = 0;
 334         self.death_time = 0;
 335         self.dead_time = 0;
 336         self.dead_frame = 0;
 337         self.die_frame = 0;
 338         self.deaths = 0;
 339         self.alpha = 0;
 340         self.scale = 0;
 341         self.fade_time = 0;
 342         self.pain_frame = 0;
 343         self.pain_finished = 0;
 344         self.strength_finished = 0;
 345         self.invincible_finished = 0;
 346         self.pushltime = 0;
 347         self.think = SUB_Null;
 348         self.nextthink = 0;
 349         self.hook_time = 0;
 350         self.runes = 0;
 351         self.deadflag = DEAD_NO;
 352         self.angles = spot.angles;
 353         self.angles_z = 0;
 354         self.fixangle = TRUE;
 355         self.crouch = FALSE;
 356
 357         self.view_ofs = PL_VIEW_OFS;
 358         setorigin (self, spot.origin);
 359         setsize (self, '0 0 0', '0 0 0');
 360         self.oldorigin = self.origin;
 361         self.items = 0;
 362         self.model = "";
 363         self.modelindex = 0;
 364         self.weapon = 0;
 365         self.weaponmodel = "";
 366         self.weaponentity = world;
 367         self.killcount = -666;
 368         self.velocity = '0 0 0';
 369         self.avelocity = '0 0 0';
 370         self.punchangle = '0 0 0';
 371         self.punchvector = '0 0 0';
 372         self.oldvelocity = self.velocity;
 373         self.customizeentityforclient = Client_customizeentityforclient;
 374
 375         if(cvar("g_arena"))
 376         {
 377                 if(self.frags != -2)
 378                 {
 379                         Spawnqueue_Insert(self);
 380                 }
 381                 else
 382                 {
 383                         Spawnqueue_Unmark(self);
 384                         Spawnqueue_Remove(self);
 385                 }
 386         }
 387         else if(!cvar("g_lms"))
 388                 self.frags = -666;
 389 }
 390
 391
 392 /*
 393 =============
 394 PutClientInServer
 395
 396 Called when a client spawns in the server
 397 =============
 398 */
 399 void PutClientInServer (void)
 400 {
 401         if(clienttype(self) == CLIENTTYPE_BOT)
 402         {
 403                 self.classname = "player";
 404         }
 405         else if(clienttype(self) == CLIENTTYPE_REAL)
 406         {
 407                 msg_entity = self;
 408                 WriteByte(MSG_ONE, SVC_SETVIEW);
 409                 WriteEntity(MSG_ONE, self);
 410         }
 411
 412         // player is dead and becomes observer
 413         if(cvar("g_lms") && self.frags < 1)
 414                 self.classname = "observer";
 415
 416         if(cvar("g_arena"))
 417         if(!self.spawned)
 418                 self.classname = "observer";
 419
 420         if(self.classname == "player") {
 421                 entity  spot;
 422
 423                 spot = SelectSpawnPoint (FALSE);
 424
 425                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 426
 427                 self.classname = "player";
 428                 self.iscreature = TRUE;
 429                 self.movetype = MOVETYPE_WALK;
 430                 self.solid = SOLID_SLIDEBOX;
 431                 self.flags = FL_CLIENT;
 432                 self.takedamage = DAMAGE_AIM;
 433                 self.effects = 0;
 434                 self.air_finished = time + 12;
 435                 self.dmg = 2;
 436
 437                 self.ammo_shells = start_ammo_shells;
 438                 self.ammo_nails = start_ammo_nails;
 439                 self.ammo_rockets = start_ammo_rockets;
 440                 self.ammo_cells = start_ammo_cells;
 441                 self.health = start_health;
 442                 self.armorvalue = start_armorvalue;
 443                 self.items = start_items;
 444                 self.switchweapon = start_switchweapon;
 445                 self.weapon = 0;
 446                 self.jump_interval = time;
 447
 448                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 449                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 450                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 451                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 452                 self.damageforcescale = 2;
 453                 self.death_time = 0;
 454                 self.dead_time = 0;
 455                 self.dead_frame = 0;
 456                 self.die_frame = 0;
 457                 self.alpha = 0;
 458                 self.scale = 0;
 459                 self.fade_time = 0;
 460                 self.pain_frame = 0;
 461                 self.pain_finished = 0;
 462                 self.strength_finished = 0;
 463                 self.invincible_finished = 0;
 464                 self.pushltime = 0;
 465                 //self.speed_finished = 0;
 466                 //self.slowmo_finished = 0;
 467                 // players have no think function
 468                 self.think = SUB_Null;
 469                 self.nextthink = 0;
 470                 self.hook_time = 0;
 471
 472                 self.runes = 0;
 473
 474                 self.deadflag = DEAD_NO;
 475
 476                 self.angles = spot.angles;
 477
 478                 self.angles_z = 0; // never spawn tilted even if the spot says to
 479                 self.fixangle = TRUE; // turn this way immediately
 480                 self.velocity = '0 0 0';
 481                 self.avelocity = '0 0 0';
 482                 self.punchangle = '0 0 0';
 483                 self.punchvector = '0 0 0';
 484                 self.oldvelocity = self.velocity;
 485
 486                 self.viewzoom = 0.6;
 487                 self.has_zoomed = 0;
 488
 489                 self.customizeentityforclient = Client_customizeentityforclient;
 490
 491                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 492                         local string defaultmodel;
 493                         defaultmodel = cvar_string("sv_defaultplayermodel");
 494                         setmodel_lod (self, defaultmodel);
 495                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 496                 } else {
 497                         self.playermodel = CheckPlayerModel(self.playermodel);
 498                         setmodel_lod (self, self.playermodel);
 499                         if(teams_matter)
 500                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 501                         else
 502                                 self.skin = stof(self.playerskin);
 503                 }
 504
 505                 self.crouch = FALSE;
 506                 self.view_ofs = PL_VIEW_OFS;
 507                 setsize (self, PL_MIN, PL_MAX);
 508                 self.spawnorigin = spot.origin;
 509                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 510                 // don't reset back to last position, even if new position is stuck in solid
 511                 self.oldorigin = self.origin;
 512
 513                 if(cvar("g_arena"))
 514                 {
 515                         Spawnqueue_Remove(self);
 516                         Spawnqueue_Mark(self);
 517                 }
 518
 519                 self.event_damage = PlayerDamage;
 520
 521                 self.bot_attack = TRUE;
 522
 523                 self.statdraintime = time + 5;
 524                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 525
 526                 if(self.killcount == -666) {
 527                         self.killcount = 0;
 528                         if(!cvar("g_arena"))
 529                         if(!cvar("g_lms"))
 530                                 self.frags = 0;
 531                 }
 532
 533                 self.cnt = WEP_LASER;
 534                 self.nixnex_lastchange_id = -1;
 535
 536                 CL_SpawnWeaponentity();
 537                 self.alpha = default_player_alpha;
 538                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 539
 540                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 541                 self.lms_traveled_distance = 0;
 542
 543                 if(cvar("spawn_debug"))
 544                 {
 545                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 546                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 547                 }
 548
 549                 //stuffcmd(self, "chase_active 0");
 550                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 551
 552                 if (cvar("g_spawnsound"))
 553                         sound (self, CHAN_AUTO, "misc/teleport.wav", 1, ATTN_NORM);
 554
 555         } else if(self.classname == "observer") {
 556                 PutObserverInServer ();
 557         }
 558 }
 559
 560 /*
 561 =============
 562 SetNewParms
 563 =============
 564 */
 565 void SetNewParms (void)
 566 {
 567
 568 }
 569
 570 /*
 571 =============
 572 SetChangeParms
 573 =============
 574 */
 575 void SetChangeParms (void)
 576 {
 577
 578 }
 579
 580 /*
 581 =============
 582 ClientKill
 583
 584 Called when a client types 'kill' in the console
 585 =============
 586 */
 587 void ClientKill (void)
 588 {
 589         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 590 }
 591
 592 void FixClientCvars(entity e)
 593 {
 594         // send prediction settings to the client
 595         stuffcmd(e, "\nin_bindmap 0 0\n");
 596         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 597         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 598         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 599         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 600         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 601         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 602         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 603         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 604         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 605         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 606         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 607         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 608         stuffcmd(e, "cl_movement_edgefriction 1\n");
 609 }
 610
 611 /*
 612 =============
 613 ClientConnect
 614
 615 Called when a client connects to the server
 616 =============
 617 */
 618 string ColoredTeamName(float t);
 619 //void dom_player_join_team(entity pl);
 620 void ClientConnect (void)
 621 {
 622         local string s;
 623
 624         self.classname = "player_joining";
 625         self.flags = self.flags | FL_CLIENT;
 626         self.version_nagtime = time + 10 + random() * 10;
 627
 628         if(player_count<0)
 629         {
 630                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 631                 player_count = 0;
 632         }
 633
 634         bot_clientconnect();
 635
 636         //if(cvar("g_domination"))
 637         //      dom_player_join_team(self);
 638
 639         //JoinBestTeam(self, FALSE);
 640
 641         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 642                 self.classname = "observer";
 643         } else {
 644                 self.classname = "player";
 645                 campaign_bots_may_start = 1;
 646         }
 647
 648         self.playerid = (playerid_last = playerid_last + 1);
 649         if(cvar("sv_eventlog"))
 650         {
 651                 if(clienttype(self) == CLIENTTYPE_REAL)
 652                         s = "player";
 653                 else
 654                         s = "bot";
 655                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 656                 s = strcat(":team:", ftos(self.playerid), ":");
 657                 s = strcat(s, ftos(self.team));
 658                 GameLogEcho(s, FALSE);
 659         }
 660
 661         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 662
 663         bprint ("^4",self.netname);
 664         bprint ("^4 connected");
 665
 666         if(cvar("g_domination") || cvar("g_ctf"))
 667         {
 668                 bprint(" and joined the ");
 669                 bprint(ColoredTeamName(self.team));
 670         }
 671
 672         bprint("\n");
 673
 674         self.welcomemessage_time = 0;
 675
 676         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 677         // TODO: is this being used for anything else than cd tracks?
 678         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 679
 680         FixClientCvars(self);
 681
 682         // waypoint sprites
 683         WaypointSprite_InitClient(self);
 684
 685         // Wazat's grappling hook
 686         SetGrappleHookBindings();
 687
 688         // get autoswitch state from player when he toggles it
 689         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 690
 691         // get version info from player
 692         stuffcmd(self, "cmd clientversion $gameversion\n");
 693
 694         // get other cvars from player
 695         GetCvars(0);
 696
 697         // set cvar for team scoreboard
 698         if (teams_matter)
 699         {
 700                 local float t;
 701                 t = cvar("teamplay");
 702                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 703                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 704         }
 705         else
 706                 stuffcmd(self, "set teamplay 0\n");
 707
 708         if(cvar("g_lms"))
 709         {
 710                 self.frags = cvar("fraglimit");
 711                 // no fraglimit was set, so player gets 999 lives
 712                 if(self.frags < 1)
 713                         self.frags = 999;
 714
 715                 self.frags = LMS_NewPlayerLives();
 716                 if(!self.frags)
 717                 {
 718                         self.frags = -666;
 719                 }
 720         }
 721         else if(cvar("g_arena"))
 722         {
 723                 self.classname = "observer";
 724                 Spawnqueue_Insert(self);
 725         }
 726
 727         bot_relinkplayerlist();
 728
 729         self.jointime = time;
 730 }
 731
 732 /*
 733 =============
 734 ClientDisconnect
 735
 736 Called when a client disconnects from the server
 737 =============
 738 */
 739 void(entity e) DropFlag;
 740 .entity chatbubbleentity;
 741 .entity teambubbleentity;
 742 void ClientDisconnect (void)
 743 {
 744         float save;
 745         if(cvar("sv_eventlog"))
 746                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 747         bprint ("^4",self.netname);
 748         bprint ("^4 disconnected\n");
 749
 750         if (self.chatbubbleentity)
 751         {
 752                 remove (self.chatbubbleentity);
 753                 self.chatbubbleentity = world;
 754         }
 755
 756         if (self.teambubbleentity)
 757         {
 758                 remove (self.teambubbleentity);
 759                 self.teambubbleentity = world;
 760         }
 761
 762         WaypointSprite_PlayerGone();
 763
 764         DropAllRunes(self);
 765         kh_Key_DropAll(self, TRUE);
 766
 767         if(self.flagcarried)
 768                 DropFlag(self.flagcarried);
 769
 770         DistributeFragsAmongTeam(self, self.team, 1);
 771
 772         save = self.flags;
 773         self.flags = self.flags - (self.flags & FL_CLIENT);
 774         bot_relinkplayerlist();
 775         self.flags = save;
 776
 777         // remove laserdot
 778         if(self.weaponentity)
 779                 if(self.weaponentity.lasertarget)
 780                         remove(self.weaponentity.lasertarget);
 781
 782         if(cvar("g_arena"))
 783         {
 784                 Spawnqueue_Unmark(self);
 785                 Spawnqueue_Remove(self);
 786         }
 787
 788         // free cvars
 789         GetCvars(-1);
 790 }
 791
 792 .float buttonchat;
 793 void() ChatBubbleThink =
 794 {
 795         self.nextthink = time;
 796         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 797         {
 798                 self.owner.chatbubbleentity = world;
 799                 remove(self);
 800                 return;
 801         }
 802         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 803         if (self.owner.buttonchat && !self.owner.deadflag)
 804                 self.model = self.mdl;
 805         else
 806                 self.model = "";
 807 };
 808
 809 void() UpdateChatBubble =
 810 {
 811         if (!self.modelindex)
 812                 return;
 813         // spawn a chatbubble entity if needed
 814         if (!self.chatbubbleentity)
 815         {
 816                 self.chatbubbleentity = spawn();
 817                 self.chatbubbleentity.owner = self;
 818                 self.chatbubbleentity.exteriormodeltoclient = self;
 819                 self.chatbubbleentity.think = ChatBubbleThink;
 820                 self.chatbubbleentity.nextthink = time;
 821                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
 822                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 823                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 824                 self.chatbubbleentity.model = "";
 825                 self.chatbubbleentity.effects = EF_LOWPRECISION;
 826         }
 827 }
 828
 829
 830 void() TeamBubbleThink =
 831 {
 832         self.nextthink = time;
 833         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 834         {
 835                 self.owner.teambubbleentity = world;
 836                 remove(self);
 837                 return;
 838         }
 839 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 840         if (self.owner.buttonchat || self.owner.deadflag)
 841                 self.model = "";
 842         else
 843                 self.model = self.mdl;
 844
 845 };
 846
 847 float() TeamBubble_customizeentityforclient
 848 {
 849         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 850 }
 851
 852 void() UpdateTeamBubble =
 853 {
 854         if (!self.modelindex || !cvar("teamplay"))
 855                 return;
 856         // spawn a teambubble entity if needed
 857         if (!self.teambubbleentity && cvar("teamplay"))
 858         {
 859                 self.teambubbleentity = spawn();
 860                 self.teambubbleentity.owner = self;
 861                 self.teambubbleentity.exteriormodeltoclient = self;
 862                 self.teambubbleentity.think = TeamBubbleThink;
 863                 self.teambubbleentity.nextthink = time;
 864                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
 865 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 866                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 867                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 868                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 869                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 870                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 871                 self.teambubbleentity.effects = EF_LOWPRECISION;
 872         }
 873 }
 874
 875 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 876 // added to the model skins
 877 /*void() UpdateColorModHack =
 878 {
 879         local float c;
 880         c = self.clientcolors & 15;
 881         // LordHavoc: only bothering to support white, green, red, yellow, blue
 882              if (teamplay == 0) self.colormod = '0 0 0';
 883         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 884         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 885         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 886         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 887         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 888         else self.colormod = '1 1 1';
 889 };*/
 890
 891 void respawn(void)
 892 {
 893         CopyBody(1);
 894         PutClientInServer();
 895 }
 896
 897 void player_powerups (void)
 898 {
 899         if (cvar("g_minstagib"))
 900         {
 901                 self.effects = EF_FULLBRIGHT;
 902                 if (self.items & IT_STRENGTH)
 903                 {
 904                         if (time > self.strength_finished)
 905                         {
 906                                 self.alpha = default_player_alpha;
 907                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 908                                 self.items = self.items - (self.items & IT_STRENGTH);
 909                                 sprint(self, "^3Invisibility has worn off\n");
 910                         }
 911                 }
 912                 else
 913                 {
 914                         if (time < self.strength_finished)
 915                         {
 916                                 self.alpha = cvar("g_minstagib_invis_alpha");
 917                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 918                                 self.items = self.items | IT_STRENGTH;
 919                                 sprint(self, "^3You are invisible\n");
 920                         }
 921                 }
 922
 923                 if (self.items & IT_INVINCIBLE)
 924                 {
 925                         if (time > self.invincible_finished)
 926                         {
 927                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 928                                 sprint(self, "^3Speed has worn off\n");
 929                         }
 930                 }
 931                 else
 932                 {
 933                         if (time < self.invincible_finished)
 934                         {
 935                                 self.items = self.items | IT_INVINCIBLE;
 936                                 sprint(self, "^3You are on speed\n");
 937                         }
 938                 }
 939                 return;
 940         }
 941
 942         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 943         if (self.items & IT_STRENGTH)
 944         {
 945                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 946                 if (time > self.strength_finished)
 947                 {
 948                         self.items = self.items - (self.items & IT_STRENGTH);
 949                         sprint(self, "^3Strength has worn off\n");
 950                 }
 951         }
 952         else
 953         {
 954                 if (time < self.strength_finished)
 955                 {
 956                         self.items = self.items | IT_STRENGTH;
 957                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
 958                 }
 959         }
 960         if (self.items & IT_INVINCIBLE)
 961         {
 962                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 963                 if (time > self.invincible_finished)
 964                 {
 965                         self.items = self.items - (self.items & IT_INVINCIBLE);
 966                         sprint(self, "^3Shield has worn off\n");
 967                 }
 968         }
 969         else
 970         {
 971                 if (time < self.invincible_finished)
 972                 {
 973                         self.items = self.items | IT_INVINCIBLE;
 974                         sprint(self, "^3Shield surrounds you\n");
 975                 }
 976         }
 977
 978         if (cvar("g_fullbrightplayers"))
 979                 self.effects = self.effects | EF_FULLBRIGHT;
 980
 981         // midair gamemode: damage only while in the air
 982         // if in midair mode, being on ground grants temporary invulnerability
 983         // (this is so that multishot weapon don't clear the ground flag on the
 984         // first damage in the frame, leaving the player vulnerable to the
 985         // remaining hits in the same frame)
 986         if (self.flags & FL_ONGROUND)
 987         if (cvar("g_midair"))
 988                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
 989
 990         if (time < self.spawnshieldtime)
 991                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
 992 }
 993
 994 float CalcRegen(float current, float stable, float regenfactor)
 995 {
 996         if(current > stable)
 997                 return current;
 998         else if(current > stable - 0.25) // when close enough, "snap"
 999                 return stable;
1000         else
1001                 return min(stable, current + (stable - current) * regenfactor * frametime);
1002 }
1003
1004 void player_regen (void)
1005 {
1006         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1007         maxh = cvar("g_balance_health_stable");
1008         maxa = cvar("g_balance_armor_stable");
1009         limith = cvar("g_balance_health_limit");
1010         limita = cvar("g_balance_armor_limit");
1011
1012         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1013                 return;
1014
1015         max_mod = regen_mod = rot_mod = limit_mod = 1;
1016
1017         if (self.runes & RUNE_REGEN)
1018         {
1019                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1020                 {
1021                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1022                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1023                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1024                 }
1025                 else
1026                 {
1027                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1028                         max_mod = cvar("g_balance_rune_regen_hpmod");
1029                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1030                 }
1031         }
1032         else if (self.runes & CURSE_VENOM)
1033         {
1034                 max_mod = cvar("g_balance_curse_venom_hpmod");
1035                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1036                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1037                 else
1038                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1039                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1040                 //if (!self.runes & RUNE_REGEN)
1041                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1042         }
1043         maxh = maxh * max_mod;
1044         //maxa = maxa * max_mod;
1045         limith = limith * limit_mod;
1046         limita = limita * limit_mod;
1047
1048         if (self.armorvalue > maxa)
1049         {
1050                 if (time > self.pauserotarmor_finished)
1051                 {
1052                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1053                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1054                 }
1055         }
1056         else if (self.armorvalue < maxa)
1057         {
1058                 if (time > self.pauseregen_finished)
1059                 {
1060                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1061                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1062                 }
1063         }
1064         if (self.health > maxh)
1065         {
1066                 if (time > self.pauserothealth_finished)
1067                 {
1068                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1069                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1070                 }
1071         }
1072         else if (self.health < maxh)
1073         {
1074                 if (time > self.pauseregen_finished)
1075                 {
1076                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1077                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1078                 }
1079         }
1080
1081         if (self.health > limith)
1082                 self.health = limith;
1083         if (self.armorvalue > limita)
1084                 self.armorvalue = limita;
1085
1086         // if player rotted to death...  die!
1087         if(self.health < 1)
1088                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1089 }
1090
1091 /*
1092 ======================
1093 spectate mode routines
1094 ======================
1095 */
1096 void SpectateCopy(entity spectatee) {
1097         self.armortype = spectatee.armortype;
1098         self.armorvalue = spectatee.armorvalue;
1099         self.currentammo = spectatee.currentammo;
1100         self.effects = spectatee.effects;
1101         self.health = spectatee.health;
1102         self.impulse = 0;
1103         self.items = spectatee.items;
1104         self.punchangle = spectatee.punchangle;
1105         self.view_ofs = spectatee.view_ofs;
1106         self.v_angle = spectatee.v_angle;
1107         self.viewzoom = spectatee.viewzoom;
1108         setorigin(self, spectatee.origin);
1109         setsize(self, spectatee.mins, spectatee.maxs);
1110 }
1111
1112 void SpectateUpdate() {
1113         if(!self.enemy)
1114                         PutObserverInServer();
1115
1116         if (self != self.enemy) {
1117                 if(self.enemy.flags & FL_NOTARGET)
1118                         PutObserverInServer();
1119                 SpectateCopy(self.enemy);
1120                 self.dmg_take = self.enemy.dmg_take;
1121                 self.dmg_save = self.enemy.dmg_save;
1122                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1123                 self.fixangle = TRUE;
1124                 self.angles = self.enemy.v_angle;
1125                 //msg_entity = self;
1126                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1127                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1128                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1129                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1130         }
1131 }
1132
1133 float SpectateNext() {
1134         other = find(self.enemy, classname, "player");
1135         if (!other) {
1136                 other = find(other, classname, "player");
1137         }
1138         if (other) {
1139                 self.enemy = other;
1140         }
1141         if(self.enemy.classname == "player") {
1142                 msg_entity = self;
1143                 WriteByte(MSG_ONE, SVC_SETVIEW);
1144                 WriteEntity(MSG_ONE, self.enemy);
1145                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1146                 SpectateUpdate();
1147                 return 1;
1148         } else {
1149                 return 0;
1150         }
1151 }
1152
1153 /*
1154 =============
1155 ShowRespawnCountdown()
1156
1157 Update a respawn countdown display.
1158 =============
1159 */
1160 void ShowRespawnCountdown()
1161 {
1162         float number;
1163         if(self.deadflag == DEAD_NO) // just respawned?
1164                 return;
1165         else
1166         {
1167                 number = ceil(self.death_time - time);
1168                 if(number <= 0)
1169                         return;
1170                 if(number <= self.respawn_countdown)
1171                 {
1172                         self.respawn_countdown = number - 1;
1173                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1174                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1175                 }
1176         }
1177 }
1178
1179 void LeaveSpectatorMode()
1180 {
1181         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1182                 self.classname = "player";
1183                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1184                         JoinBestTeam(self, 0);
1185                 if(cvar("g_campaign"))
1186                         campaign_bots_may_start = 1;
1187                 PutClientInServer();
1188                 if(!(self.flags & FL_NOTARGET))
1189                         bprint ("^4", self.netname, "^4 is playing now\n");
1190                 centerprint(self,"");
1191                 return;
1192         } else {
1193                 stuffcmd(self,"menu_showteamselect\n");
1194                 return;
1195         }
1196 }
1197
1198 /*
1199 =============
1200 PlayerPreThink
1201
1202 Called every frame for each client before the physics are run
1203 =============
1204 */
1205 void() ctf_setstatus;
1206 .float vote_nagtime;
1207 void PlayerPreThink (void)
1208 {
1209         // version nagging
1210         if(self.version_nagtime)
1211                 if(self.cvar_g_nexuizversion)
1212                         if(time > self.version_nagtime)
1213                         {
1214                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1215                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1216                                         {
1217                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1218                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1219                                         }
1220                                 self.version_nagtime = 0;
1221                         }
1222
1223         // vote nagging
1224         if(self.cvar_scr_centertime)
1225                 if(time > self.vote_nagtime)
1226                 {
1227                         VoteNag();
1228                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1229                 }
1230
1231         // GOD MODE info
1232         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1233         {
1234                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1235                 self.max_armorvalue = 0;
1236         }
1237
1238         if(self.classname == "player") {
1239                 local vector m1, m2;
1240
1241 //              if(self.netname == "Wazat")
1242 //                      bprint(self.classname, "\n");
1243
1244                 CheckRules_Player();
1245
1246                 if(self.button7)
1247                         PrintWelcomeMessage(self);
1248
1249                 if(cvar("g_lms") || !cvar("sv_spectate"))
1250                 if((time - self.jointime) <= cvar("welcome_message_time"))
1251                         PrintWelcomeMessage(self);
1252
1253                 if (intermission_running)
1254                 {
1255                         IntermissionThink ();   // otherwise a button could be missed between
1256                         return;                                 // the think tics
1257                 }
1258
1259                 if(time > self.teleport_time)
1260                 {
1261                         self.effects = self.effects - (self.effects & EF_NODRAW);
1262                         if(self.weaponentity)
1263                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1264                 }
1265
1266                 Nixnex_GiveCurrentWeapon();
1267                 UpdateSelectedPlayer();
1268
1269                 if (self.deadflag != DEAD_NO)
1270                 {
1271                         float button_pressed, force_respawn;
1272                         player_anim();
1273                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1274                         force_respawn = (cvar("g_lms") || cvar("g_forced_respawn"));
1275                         if (self.deadflag == DEAD_DYING)
1276                         {
1277                                 if(force_respawn)
1278                                         self.deadflag = DEAD_RESPAWNING;
1279                                 else if(!button_pressed)
1280                                         self.deadflag = DEAD_DEAD;
1281                         }
1282                         else if (self.deadflag == DEAD_DEAD)
1283                         {
1284                                 if(button_pressed)
1285                                         self.deadflag = DEAD_RESPAWNABLE;
1286                         }
1287                         else if (self.deadflag == DEAD_RESPAWNABLE)
1288                         {
1289                                 if(!button_pressed)
1290                                         self.deadflag = DEAD_RESPAWNING;
1291                         }
1292                         else if (self.deadflag == DEAD_RESPAWNING)
1293                         {
1294                                 if(time > self.death_time)
1295                                         respawn();
1296                         }
1297                         ShowRespawnCountdown();
1298                         return;
1299                 }
1300
1301                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1302                 {
1303                         vector dist;
1304
1305                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1306                         dist = self.oldorigin - self.origin;
1307                         dist_z = 0;
1308                         self.lms_traveled_distance += fabs(vlen(dist));
1309
1310                         if(cvar("g_campaign"))
1311                         if(!campaign_bots_may_start)
1312                         {
1313                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1314                                 self.lms_traveled_distance = 0;
1315                         }
1316
1317                         if(time > self.lms_nextcheck)
1318                         {
1319                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1320                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1321                                 {
1322                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1323                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1324                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1325                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1326                                 }
1327                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1328                                 self.lms_traveled_distance = 0;
1329                         }
1330                 }
1331
1332                 if (self.button5 && !self.hook.state)
1333                 {
1334                         if (!self.crouch)
1335                         {
1336                                 self.crouch = TRUE;
1337                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1338                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1339                         }
1340                 }
1341                 else
1342                 {
1343                         if (self.crouch)
1344                         {
1345                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1346                                 if (!trace_startsolid)
1347                                 {
1348                                         self.crouch = FALSE;
1349                                         self.view_ofs = PL_VIEW_OFS;
1350                                         setsize (self, PL_MIN, PL_MAX);
1351                                 }
1352                         }
1353                 }
1354
1355                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1356                         local string defaultmodel;
1357                         defaultmodel = cvar_string("sv_defaultplayermodel");
1358
1359                         if (defaultmodel != self.model)
1360                         {
1361                                 m1 = self.mins;
1362                                 m2 = self.maxs;
1363                                 setmodel_lod (self, defaultmodel);
1364                                 setsize (self, m1, m2);
1365                         }
1366
1367                         if (self.skin != cvar("sv_defaultplayerskin"))
1368                                 self.skin = cvar("sv_defaultplayerskin");
1369                 } else {
1370                         if (self.playermodel != self.model)
1371                         {
1372                                 self.playermodel = CheckPlayerModel(self.playermodel);
1373                                 m1 = self.mins;
1374                                 m2 = self.maxs;
1375                                 setmodel_lod (self, self.playermodel);
1376                                 setsize (self, m1, m2);
1377                         }
1378
1379                         if(teams_matter)
1380                         {
1381                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1382                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1383                         }
1384                         else
1385                         {
1386                                 if (self.skin != stof(self.playerskin))
1387                                         self.skin = stof(self.playerskin);
1388                         }
1389                 }
1390
1391                 GrapplingHookFrame();
1392
1393                 W_WeaponFrame();
1394
1395                 {
1396                         float zoomfactor, zoomspeed, zoomdir;
1397                         zoomfactor = self.cvar_cl_zoomfactor;
1398                         if(zoomfactor < 1 || zoomfactor > 16)
1399                                 zoomfactor = 2.5;
1400                         zoomspeed = self.cvar_cl_zoomspeed;
1401                         if(zoomspeed >= 0) // < 0 is instant zoom
1402                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1403                                         zoomspeed = 3.5;
1404
1405                         zoomdir = self.button4;
1406                         if(self.button3)
1407                                 if(self.weapon == WEP_NEX)
1408                                         if(!cvar("g_minstagib"))
1409                                                 zoomdir = 1;
1410
1411                         if(zoomdir)
1412                                 self.has_zoomed = 1;
1413
1414                         if(self.has_zoomed)
1415                         {
1416                                 if(zoomspeed <= 0) // instant zoom
1417                                 {
1418                                         if(zoomdir)
1419                                                 self.viewzoom = 1 / zoomfactor;
1420                                         else
1421                                                 self.viewzoom = 1;
1422                                 }
1423                                 else
1424                                 {
1425                                         // geometric zoom would be:
1426                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1427                                         // however, testing showed that arithmetic/harmonic zoom works better
1428                                         if(zoomdir)
1429                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1430                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1431                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1432                                         else
1433                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1434                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1435                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1436                                 }
1437                         }
1438                         else
1439                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1440                 }
1441
1442                 player_powerups();
1443                 player_regen();
1444                 player_anim();
1445
1446                 if (cvar("g_minstagib"))
1447                         minstagib_ammocheck();
1448
1449                 ctf_setstatus();
1450                 kh_setstatus();
1451
1452                 //self.angles_y=self.v_angle_y + 90;   // temp
1453
1454                 //if (TetrisPreFrame()) return;
1455         } else if(gameover) {
1456                 if (intermission_running)
1457                         IntermissionThink ();   // otherwise a button could be missed between
1458                 return;
1459         } else if(self.classname == "observer") {
1460
1461                 if (self.flags & FL_JUMPRELEASED) {
1462                         if (self.button2 && self.version == cvar("gameversion")) {
1463                                 self.welcomemessage_time = 0;
1464                                 self.flags = self.flags - FL_JUMPRELEASED;
1465                                 LeaveSpectatorMode();
1466                                 return;
1467                         } else if(self.button0 && self.version == cvar("gameversion")) {
1468                                 self.welcomemessage_time = 0;
1469                                 self.flags = self.flags - FL_JUMPRELEASED;
1470                                 if(SpectateNext() == 1) {
1471                                         self.classname = "spectator";
1472                                 }
1473                         }
1474                 } else {
1475                         if (!(self.button0 || self.button2)) {
1476                                 self.flags = self.flags | FL_JUMPRELEASED;
1477                         }
1478                 }
1479                 PrintWelcomeMessage(self);
1480         } else if(self.classname == "spectator") {
1481                 if (self.flags & FL_JUMPRELEASED) {
1482                         if (self.button2 && self.version == cvar("gameversion")) {
1483                                 self.welcomemessage_time = 0;
1484                                 self.flags = self.flags - FL_JUMPRELEASED;
1485                                 LeaveSpectatorMode();
1486                                 return;
1487                         } else if(self.button0) {
1488                                 self.welcomemessage_time = 0;
1489                                 self.flags = self.flags - FL_JUMPRELEASED;
1490                                 if(SpectateNext() == 1) {
1491                                         self.classname = "spectator";
1492                                 } else {
1493                                         self.classname = "observer";
1494                                         PutClientInServer();
1495                                 }
1496                         } else if (self.button3) {
1497                                 self.welcomemessage_time = 0;
1498                                 self.flags = self.flags - FL_JUMPRELEASED;
1499                                 self.classname = "observer";
1500                                 PutClientInServer();
1501                         } else {
1502                                 SpectateUpdate();
1503                         }
1504                 } else {
1505                         if (!(self.button0 || self.button3)) {
1506                                 self.flags = self.flags | FL_JUMPRELEASED;
1507                         }
1508                 }
1509                 PrintWelcomeMessage(self);
1510                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1511         }
1512 }
1513
1514
1515 /*
1516 =============
1517 PlayerPostThink
1518
1519 Called every frame for each client after the physics are run
1520 =============
1521 */
1522 void PlayerPostThink (void)
1523 {
1524         // Savage: Check for nameless players
1525         if (strlen(self.netname) < 1) {
1526                 self.netname = "Player";
1527                 stuffcmd(self, "seta _cl_name Player\n");
1528         }
1529
1530         if(self.classname == "player") {
1531                 CheckRules_Player();
1532                 UpdateChatBubble();
1533                 UpdateTeamBubble();
1534                 if (self.impulse)
1535                         ImpulseCommands ();
1536                 if (intermission_running)
1537                         return;         // intermission or finale
1538
1539                 //PrintWelcomeMessage(self);
1540                 //if (TetrisPostFrame()) return;
1541         } else if (self.classname == "observer") {
1542                 //do nothing
1543         } else if (self.classname == "spectator") {
1544                 //do nothing
1545         }
1546         Arena_Warmup();
1547 }