data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         DistributeFragsAmongTeam(self, self.team, 1);
 294
 295         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 297         else if(self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 299
 300         self.classname = "observer";
 301         self.health = -666;
 302         self.takedamage = DAMAGE_NO;
 303         self.solid = SOLID_NOT;
 304         self.movetype = MOVETYPE_NOCLIP;
 305         self.flags = FL_CLIENT | FL_NOTARGET;
 306         self.armorvalue = 666;
 307         self.effects = 0;
 308         self.armorvalue = cvar("g_balance_armor_start");
 309         self.pauserotarmor_finished = 0;
 310         self.pauserothealth_finished = 0;
 311         self.pauseregen_finished = 0;
 312         self.damageforcescale = 0;
 313         self.death_time = 0;
 314         self.dead_time = 0;
 315         self.dead_frame = 0;
 316         self.die_frame = 0;
 317         self.deaths = 0;
 318         self.alpha = 0;
 319         self.scale = 0;
 320         self.fade_time = 0;
 321         self.pain_frame = 0;
 322         self.pain_finished = 0;
 323         self.strength_finished = 0;
 324         self.invincible_finished = 0;
 325         self.pushltime = 0;
 326         self.think = SUB_Null;
 327         self.nextthink = 0;
 328         self.hook_time = 0;
 329         self.runes = 0;
 330         self.deadflag = DEAD_NO;
 331         self.angles = spot.angles;
 332         self.angles_z = 0;
 333         self.fixangle = TRUE;
 334         self.crouch = FALSE;
 335
 336         self.view_ofs = PL_VIEW_OFS;
 337         setorigin (self, spot.origin);
 338         setsize (self, '0 0 0', '0 0 0');
 339         self.oldorigin = self.origin;
 340         self.items = 0;
 341         self.model = "";
 342         self.modelindex = 0;
 343         self.weapon = 0;
 344         self.weaponmodel = "";
 345         self.weaponentity = world;
 346         self.killcount = -666;
 347         self.velocity = '0 0 0';
 348         self.avelocity = '0 0 0';
 349         self.punchangle = '0 0 0';
 350         self.punchvector = '0 0 0';
 351         self.oldvelocity = self.velocity;
 352         self.customizeentityforclient = Client_customizeentityforclient;
 353
 354         if(cvar("g_arena"))
 355         {
 356                 if(self.frags != -2)
 357                 {
 358                         Spawnqueue_Insert(self);
 359                 }
 360                 else
 361                 {
 362                         Spawnqueue_Unmark(self);
 363                         Spawnqueue_Remove(self);
 364                 }
 365         }
 366         else if(!cvar("g_lms"))
 367                 self.frags = -666;
 368 }
 369
 370
 371 /*
 372 =============
 373 PutClientInServer
 374
 375 Called when a client spawns in the server
 376 =============
 377 */
 378 void PutClientInServer (void)
 379 {
 380         if(clienttype(self) == CLIENTTYPE_BOT)
 381         {
 382                 self.classname = "player";
 383         }
 384         else if(clienttype(self) == CLIENTTYPE_REAL)
 385         {
 386                 msg_entity = self;
 387                 WriteByte(MSG_ONE, SVC_SETVIEW);
 388                 WriteEntity(MSG_ONE, self);
 389         }
 390
 391         // player is dead and becomes observer
 392         if(cvar("g_lms") && self.frags < 1)
 393                 self.classname = "observer";
 394
 395         if(cvar("g_arena"))
 396         if(!self.spawned)
 397                 self.classname = "observer";
 398
 399         if(self.classname == "player") {
 400                 entity  spot;
 401
 402                 spot = SelectSpawnPoint (FALSE);
 403
 404                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 405
 406                 self.classname = "player";
 407                 self.iscreature = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.flags = FL_CLIENT;
 411                 self.takedamage = DAMAGE_AIM;
 412                 self.effects = 0;
 413                 self.health = cvar("g_balance_health_start");
 414                 self.armorvalue = cvar("g_balance_armor_start");
 415                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 416                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 417                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 418                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 419                 self.damageforcescale = 2;
 420                 self.death_time = 0;
 421                 self.dead_time = 0;
 422                 self.dead_frame = 0;
 423                 self.die_frame = 0;
 424                 self.alpha = 0;
 425                 self.scale = 0;
 426                 self.fade_time = 0;
 427                 self.pain_frame = 0;
 428                 self.pain_finished = 0;
 429                 self.strength_finished = 0;
 430                 self.invincible_finished = 0;
 431                 self.pushltime = 0;
 432                 //self.speed_finished = 0;
 433                 //self.slowmo_finished = 0;
 434                 // players have no think function
 435                 self.think = SUB_Null;
 436                 self.nextthink = 0;
 437                 self.weapon = 0;
 438                 self.switchweapon = 0;
 439                 self.hook_time = 0;
 440
 441                 self.runes = 0;
 442
 443                 self.deadflag = DEAD_NO;
 444
 445                 self.angles = spot.angles;
 446
 447                 self.angles_z = 0; // never spawn tilted even if the spot says to
 448                 self.fixangle = TRUE; // turn this way immediately
 449                 self.velocity = '0 0 0';
 450                 self.avelocity = '0 0 0';
 451                 self.punchangle = '0 0 0';
 452                 self.punchvector = '0 0 0';
 453                 self.oldvelocity = self.velocity;
 454
 455                 self.viewzoom = 0.6;
 456
 457                 self.customizeentityforclient = Client_customizeentityforclient;
 458
 459                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 460                         local string defaultmodel;
 461                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 462                         setmodel_lod (self, defaultmodel);
 463                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 464                 } else {
 465                         self.playermodel = CheckPlayerModel(self.playermodel);
 466                         setmodel_lod (self, self.playermodel);
 467                         if(teams_matter)
 468                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 469                         else
 470                                 self.skin = stof(self.playerskin);
 471                 }
 472
 473                 self.crouch = FALSE;
 474                 self.view_ofs = PL_VIEW_OFS;
 475                 setsize (self, PL_MIN, PL_MAX);
 476                 self.spawnorigin = spot.origin;
 477                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 478                 // don't reset back to last position, even if new position is stuck in solid
 479                 self.oldorigin = self.origin;
 480
 481                 if(cvar("g_lms"))
 482                 {
 483                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 484                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 485                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 486                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 487                         self.health = cvar("g_lms_start_health");
 488                         self.armorvalue = cvar("g_lms_start_armor");
 489                 }
 490                 else if (cvar("g_use_ammunition")) {
 491                         self.ammo_shells = cvar("g_start_ammo_shells");
 492                         self.ammo_nails = cvar("g_start_ammo_nails");
 493                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 494                         self.ammo_cells = cvar("g_start_ammo_cells");
 495                 } else {
 496                         self.ammo_shells = 999;
 497                         self.ammo_nails = 999;
 498                         self.ammo_rockets = 999;
 499                         self.ammo_cells = 999;
 500                 }
 501
 502                 self.items = 0;
 503                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 504                 {
 505                         self.items = self.items | IT_LASER;
 506                         self.switchweapon = WEP_LASER;
 507                 }
 508                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 509                 {
 510                         self.items = self.items | IT_SHOTGUN;
 511                         self.switchweapon = WEP_SHOTGUN;
 512                 }
 513                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 514                 {
 515                         self.items = self.items | IT_UZI;
 516                         self.switchweapon = WEP_UZI;
 517                 }
 518                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 519                 {
 520                         self.items = self.items | IT_GRENADE_LAUNCHER;
 521                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 522                 }
 523                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 524                 {
 525                         self.items = self.items | IT_ELECTRO;
 526                         self.switchweapon = WEP_ELECTRO;
 527                 }
 528                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 529                 {
 530                         self.items = self.items | IT_CRYLINK;
 531                         self.switchweapon = WEP_CRYLINK;
 532                 }
 533                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 534                 {
 535                         self.items = self.items | IT_NEX;
 536                         self.switchweapon = WEP_NEX;
 537                 }
 538                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 539                 {
 540                         self.items = self.items | IT_HAGAR;
 541                         self.switchweapon = WEP_HAGAR;
 542                 }
 543                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 544                 {
 545                         self.items = self.items | IT_ROCKET_LAUNCHER;
 546                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 547                 }
 548
 549                 if(cvar("g_instagib"))
 550                 {
 551                         self.items = IT_NEX;
 552                         self.switchweapon = WEP_NEX;
 553                         self.ammo_cells = 999;
 554                 }
 555
 556                 if(cvar("g_rocketarena"))
 557                 {
 558                         self.items = IT_ROCKET_LAUNCHER;
 559                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 560                         self.ammo_rockets = 999;
 561                 }
 562
 563                 if(cvar("g_nixnex"))
 564                 {
 565                         self.items = 0;
 566                         // will be done later
 567                 }
 568
 569                 if(cvar("g_minstagib"))
 570                 {
 571                         self.health = 100;
 572                         self.armorvalue = 0;
 573                         self.items = IT_NEX;
 574                         self.switchweapon = WEP_NEX;
 575                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 576                         self.jump_interval = time;
 577                 }
 578
 579                 if(cvar("g_arena"))
 580                 {
 581                         Spawnqueue_Remove(self);
 582                         Spawnqueue_Mark(self);
 583                 }
 584
 585                 self.event_damage = PlayerDamage;
 586
 587                 self.bot_attack = TRUE;
 588
 589                 self.statdraintime = time + 5;
 590                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 591
 592                 if(self.killcount == -666) {
 593                         self.killcount = 0;
 594                         if(!cvar("g_arena"))
 595                         if(!cvar("g_lms"))
 596                                 self.frags = 0;
 597                 }
 598
 599                 self.cnt = WEP_LASER;
 600                 self.nixnex_lastchange_id = -1;
 601
 602                 CL_SpawnWeaponentity();
 603                 self.alpha = default_player_alpha;
 604                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 605
 606                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 607                 self.lms_traveled_distance = 0;
 608
 609                 if(cvar("spawn_debug"))
 610                 {
 611                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 612                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 613                 }
 614
 615                 //stuffcmd(self, "chase_active 0");
 616                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 617         } else if(self.classname == "observer") {
 618                 PutObserverInServer ();
 619         }
 620 }
 621
 622 /*
 623 =============
 624 SetNewParms
 625 =============
 626 */
 627 void SetNewParms (void)
 628 {
 629
 630 }
 631
 632 /*
 633 =============
 634 SetChangeParms
 635 =============
 636 */
 637 void SetChangeParms (void)
 638 {
 639
 640 }
 641
 642 /*
 643 =============
 644 ClientKill
 645
 646 Called when a client types 'kill' in the console
 647 =============
 648 */
 649 void ClientKill (void)
 650 {
 651         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 652 }
 653
 654 /*
 655 =============
 656 ClientConnect
 657
 658 Called when a client connects to the server
 659 =============
 660 */
 661 string ColoredTeamName(float t);
 662 //void dom_player_join_team(entity pl);
 663 void ClientConnect (void)
 664 {
 665         //local float fh;
 666         local string s;
 667
 668         self.classname = "player_joining";
 669         self.flags = self.flags | FL_CLIENT;
 670         self.version_nagtime = time + 10 + random() * 10;
 671
 672         if(player_count<0)
 673         {
 674                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 675                 player_count = 0;
 676         }
 677
 678         bot_clientconnect();
 679
 680         //if(cvar("g_domination"))
 681         //      dom_player_join_team(self);
 682
 683         //JoinBestTeam(self, FALSE);
 684
 685         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 686                 self.classname = "observer";
 687         } else {
 688                 self.classname = "player";
 689                 campaign_bots_may_start = 1;
 690         }
 691
 692         self.playerid = (playerid_last = playerid_last + 1);
 693         if(cvar("sv_eventlog"))
 694         {
 695                 if(clienttype(self) == CLIENTTYPE_REAL)
 696                         s = "player";
 697                 else
 698                         s = "bot";
 699                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 700                 s = strcat(":team:", ftos(self.playerid), ":");
 701                 s = strcat(s, ftos(self.team));
 702                 GameLogEcho(s, FALSE);
 703         }
 704
 705         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 706
 707         bprint ("^4",self.netname);
 708         bprint ("^4 connected");
 709
 710         if(cvar("g_domination") || cvar("g_ctf"))
 711         {
 712                 bprint(" and joined the ");
 713                 bprint(ColoredTeamName(self.team));
 714         }
 715
 716         bprint("\n");
 717
 718         self.welcomemessage_time = time + cvar("welcome_message_time");
 719         self.welcomemessage_time2 = 0;
 720
 721         /*
 722         // the client might not have his maps/%s.cfg file yet!
 723         // so send the one from the server...
 724         fh = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 725         if(fh >= 0)
 726         {
 727                 while((s = fgets(fh)))
 728                         stuffcmd(self, strcat(s, "\n"));
 729                 fclose(fh);
 730         }
 731         // and then execute the client's so he can still override CD tracks
 732
 733         not needed any more: current map download system disconnects and reconnects
 734         after the download, and then the file will be there
 735         */
 736         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 737
 738         // TODO: is this being used for anything else than cd tracks?
 739         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 740
 741         // send prediction settings to the client
 742         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 743         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 744         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 745         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 746         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 747         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 748         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 749         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 750         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 751         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 752         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 753         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 754         // Wazat's grappling hook
 755         SetGrappleHookBindings();
 756
 757         // get autoswitch state from player
 758         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 759         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 760
 761         // get version info from player
 762         stuffcmd(self, "cmd clientversion $gameversion\n");
 763
 764         // get other cvars from player
 765         GetCvars(0);
 766
 767         // set cvar for team scoreboard
 768         if (teams_matter)
 769         {
 770                 local float t;
 771                 t = cvar("teamplay");
 772                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 773                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 774         }
 775         else
 776                 stuffcmd(self, strcat("set teamplay 0\n"));
 777
 778         if(cvar("g_lms"))
 779         {
 780                 self.frags = cvar("fraglimit");
 781                 // no fraglimit was set, so player gets 999 lives
 782                 if(self.frags < 1)
 783                         self.frags = 999;
 784
 785                 self.frags = LMS_NewPlayerLives();
 786                 if(!self.frags)
 787                 {
 788                         self.frags = -666;
 789                 }
 790         }
 791         else if(cvar("g_arena"))
 792         {
 793                 self.classname = "observer";
 794                 Spawnqueue_Insert(self);
 795         }
 796
 797         bot_relinkplayerlist();
 798
 799         self.jointime = time;
 800 }
 801
 802 /*
 803 =============
 804 ClientDisconnect
 805
 806 Called when a client disconnects from the server
 807 =============
 808 */
 809 void(entity e) DropFlag;
 810 .entity chatbubbleentity;
 811 .entity teambubbleentity;
 812 void ClientDisconnect (void)
 813 {
 814         float save;
 815         if(cvar("sv_eventlog"))
 816                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 817         bprint ("^4",self.netname);
 818         bprint ("^4 disconnected\n");
 819
 820         if (self.chatbubbleentity)
 821         {
 822                 remove (self.chatbubbleentity);
 823                 self.chatbubbleentity = world;
 824         }
 825
 826         if (self.teambubbleentity)
 827         {
 828                 remove (self.teambubbleentity);
 829                 self.teambubbleentity = world;
 830         }
 831
 832         DropAllRunes(self);
 833
 834         if(self.flagcarried)
 835                 DropFlag(self.flagcarried);
 836
 837         DistributeFragsAmongTeam(self, self.team, 1);
 838
 839         save = self.flags;
 840         self.flags = self.flags - (self.flags & FL_CLIENT);
 841         bot_relinkplayerlist();
 842         self.flags = save;
 843
 844         // remove laserdot
 845         if(self.weaponentity)
 846                 if(self.weaponentity.lasertarget)
 847                         remove(self.weaponentity.lasertarget);
 848
 849         if(cvar("g_arena"))
 850         {
 851                 Spawnqueue_Unmark(self);
 852                 Spawnqueue_Remove(self);
 853         }
 854
 855         // free cvars
 856         GetCvars(-1);
 857 }
 858
 859 .float buttonchat;
 860 void() ChatBubbleThink =
 861 {
 862         self.nextthink = time;
 863         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 864         {
 865                 self.owner.chatbubbleentity = world;
 866                 remove(self);
 867                 return;
 868         }
 869         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 870         if (self.owner.buttonchat && !self.owner.deadflag)
 871                 self.model = self.mdl;
 872         else
 873                 self.model = "";
 874 };
 875
 876 void() UpdateChatBubble =
 877 {
 878         if (!self.modelindex)
 879                 return;
 880         // spawn a chatbubble entity if needed
 881         if (!self.chatbubbleentity)
 882         {
 883                 self.chatbubbleentity = spawn();
 884                 self.chatbubbleentity.owner = self;
 885                 self.chatbubbleentity.exteriormodeltoclient = self;
 886                 self.chatbubbleentity.think = ChatBubbleThink;
 887                 self.chatbubbleentity.nextthink = time;
 888                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 889                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 890                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 891                 self.chatbubbleentity.model = "";
 892         }
 893 }
 894
 895
 896 void() TeamBubbleThink =
 897 {
 898         self.nextthink = time;
 899         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 900         {
 901                 self.owner.teambubbleentity = world;
 902                 remove(self);
 903                 return;
 904         }
 905 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 906         if (self.owner.buttonchat || self.owner.deadflag)
 907                 self.model = "";
 908         else
 909                 self.model = self.mdl;
 910
 911 };
 912
 913 float() TeamBubble_customizeentityforclient
 914 {
 915         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 916 }
 917
 918 void() UpdateTeamBubble =
 919 {
 920         if (!self.modelindex || !cvar("teamplay"))
 921                 return;
 922         // spawn a teambubble entity if needed
 923         if (!self.teambubbleentity && cvar("teamplay"))
 924         {
 925                 self.teambubbleentity = spawn();
 926                 self.teambubbleentity.owner = self;
 927                 self.teambubbleentity.exteriormodeltoclient = self;
 928                 self.teambubbleentity.think = TeamBubbleThink;
 929                 self.teambubbleentity.nextthink = time;
 930                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 931 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 932                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 933                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 934                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 935                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 936                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 937         }
 938 }
 939
 940 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 941 // added to the model skins
 942 /*void() UpdateColorModHack =
 943 {
 944         local float c;
 945         c = self.clientcolors & 15;
 946         // LordHavoc: only bothering to support white, green, red, yellow, blue
 947              if (teamplay == 0) self.colormod = '0 0 0';
 948         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 949         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 950         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 951         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 952         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 953         else self.colormod = '1 1 1';
 954 };*/
 955
 956 /*
 957 =============
 958 PlayerJump
 959
 960 When you press the jump key
 961 =============
 962 */
 963 void PlayerJump (void)
 964 {
 965         float mjumpheight;
 966
 967         mjumpheight = cvar("g_balance_jumpheight");
 968         if (self.waterlevel >= 2)
 969         {
 970                 if (self.watertype == CONTENT_WATER)
 971                         self.velocity_z = 200;
 972                 else if (self.watertype == CONTENT_SLIME)
 973                         self.velocity_z = 80;
 974                 else
 975                         self.velocity_z = 50;
 976
 977                 return;
 978         }
 979
 980
 981         if (!(self.flags & FL_ONGROUND))
 982                 return;
 983
 984         if (!(self.flags & FL_JUMPRELEASED))
 985                 return;
 986
 987         if(cvar("g_runematch"))
 988         {
 989                 if(self.runes & RUNE_SPEED)
 990                 {
 991                         if(self.runes & CURSE_SLOW)
 992                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 993                         else
 994                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 995                 }
 996                 else if(self.runes & CURSE_SLOW)
 997                 {
 998                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 999                 }
1000         }
1001
1002         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
1003         {
1004                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
1005         }
1006
1007         self.velocity_z = self.velocity_z + mjumpheight;
1008         self.oldvelocity_z = self.velocity_z;
1009
1010         self.flags = self.flags - FL_ONGROUND;
1011         self.flags = self.flags - FL_JUMPRELEASED;
1012 }
1013
1014 void() CheckWaterJump =
1015 {
1016         local vector start, end;
1017
1018 // check for a jump-out-of-water
1019         makevectors (self.angles);
1020         start = self.origin;
1021         start_z = start_z + 8;
1022         v_forward_z = 0;
1023         normalize(v_forward);
1024         end = start + v_forward*24;
1025         traceline (start, end, TRUE, self);
1026         if (trace_fraction < 1)
1027         {       // solid at waist
1028                 start_z = start_z + self.maxs_z - 8;
1029                 end = start + v_forward*24;
1030                 self.movedir = trace_plane_normal * -50;
1031                 traceline (start, end, TRUE, self);
1032                 if (trace_fraction == 1)
1033                 {       // open at eye level
1034                         self.flags = self.flags | FL_WATERJUMP;
1035                         self.velocity_z = 225;
1036                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1037                         self.teleport_time = time + 2;  // safety net
1038                         return;
1039                 }
1040         }
1041 };
1042
1043
1044 void respawn(void)
1045 {
1046         CopyBody(1);
1047         PutClientInServer();
1048 }
1049
1050 void player_powerups (void)
1051 {
1052         if (cvar("g_minstagib"))
1053         {
1054                 self.effects = EF_FULLBRIGHT;
1055                 if (self.items & IT_STRENGTH)
1056                 {
1057                         if (time > self.strength_finished)
1058                         {
1059                                 self.alpha = default_player_alpha;
1060                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1061                                 self.items = self.items - (self.items & IT_STRENGTH);
1062                                 sprint(self, "^3Invisibility has worn off\n");
1063                         }
1064                 }
1065                 else
1066                 {
1067                         if (time < self.strength_finished)
1068                         {
1069                                 self.alpha = cvar("g_minstagib_invis_alpha");
1070                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1071                                 self.items = self.items | IT_STRENGTH;
1072                                 sprint(self, "^3You are invisible\n");
1073                         }
1074                 }
1075
1076                 if (self.items & IT_INVINCIBLE)
1077                 {
1078                         if (time > self.invincible_finished)
1079                         {
1080                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1081                                 sprint(self, "^3Speed has worn off\n");
1082                         }
1083                 }
1084                 else
1085                 {
1086                         if (time < self.invincible_finished)
1087                         {
1088                                 self.items = self.items | IT_INVINCIBLE;
1089                                 sprint(self, "^3You are on speed\n");
1090                         }
1091                 }
1092                 return;
1093         }
1094
1095         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1096         if (self.items & IT_STRENGTH)
1097         {
1098                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1099                 if (time > self.strength_finished)
1100                 {
1101                         self.items = self.items - (self.items & IT_STRENGTH);
1102                         sprint(self, "^3Strength has worn off\n");
1103                 }
1104         }
1105         else
1106         {
1107                 if (time < self.strength_finished)
1108                 {
1109                         self.items = self.items | IT_STRENGTH;
1110                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1111                 }
1112         }
1113         if (self.items & IT_INVINCIBLE)
1114         {
1115                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1116                 if (time > self.invincible_finished)
1117                 {
1118                         self.items = self.items - (self.items & IT_INVINCIBLE);
1119                         sprint(self, "^3Shield has worn off\n");
1120                 }
1121         }
1122         else
1123         {
1124                 if (time < self.invincible_finished)
1125                 {
1126                         self.items = self.items | IT_INVINCIBLE;
1127                         sprint(self, "^3Shield surrounds you\n");
1128                 }
1129         }
1130
1131         if (cvar("g_fullbrightplayers"))
1132                 self.effects = self.effects | EF_FULLBRIGHT;
1133
1134         // midair gamemode: damage only while in the air
1135         // if in midair mode, being on ground grants temporary invulnerability
1136         // (this is so that multishot weapon don't clear the ground flag on the
1137         // first damage in the frame, leaving the player vulnerable to the
1138         // remaining hits in the same frame)
1139         if (self.flags & FL_ONGROUND)
1140         if (cvar("g_midair"))
1141                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1142
1143         if (time < self.spawnshieldtime)
1144                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1145 }
1146
1147 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1148 {
1149         if(current > stable)
1150                 return current;
1151         else if(current > stable - 0.25) // when close enough, "snap"
1152                 return stable;
1153         else
1154                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1155 }
1156
1157 void player_regen (void)
1158 {
1159         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1160         maxh = cvar("g_balance_health_stable");
1161         maxa = cvar("g_balance_armor_stable");
1162         limith = cvar("g_balance_health_limit");
1163         limita = cvar("g_balance_armor_limit");
1164
1165         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1166                 return;
1167
1168         if(cvar("g_runematch"))
1169         {
1170                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1171                 if (self.runes & RUNE_REGEN)
1172                 {
1173                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1174                         {
1175                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1176                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1177                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1178                         }
1179                         else
1180                         {
1181                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1182                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1183                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1184                         }
1185                 }
1186                 else if (self.runes & CURSE_VENOM)
1187                 {
1188                         max_mod = cvar("g_balance_curse_venom_hpmod");
1189                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1190                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1191                         else
1192                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1193                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1194                         //if (!self.runes & RUNE_REGEN)
1195                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1196                 }
1197                 maxh = maxh * max_mod;
1198                 //maxa = maxa * max_mod;
1199
1200                 if (time > self.pauserotarmor_finished)
1201                 {
1202                         if (self.armorvalue > maxa)
1203                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1204                 }
1205                 if (time > self.pauserothealth_finished)
1206                 {
1207                         if (self.health > maxh)
1208                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1209                 }
1210                 if (time > self.pauseregen_finished)
1211                 {
1212                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1213                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1214                 }
1215         }
1216         else
1217         {
1218                 if (time > self.pauserothealth_finished)
1219                 if (self.health > maxh)
1220                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1221                 if (time > self.pauserotarmor_finished)
1222                 if (self.armorvalue > maxa)
1223                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1224                 if (time > self.pauseregen_finished)
1225                 {
1226                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1227                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1228                 }
1229         }
1230
1231         if (self.health > limith)
1232                 self.health = limith;
1233         if(self.health < 1)
1234                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1235         if (self.armorvalue > limita)
1236                 self.armorvalue = limita;
1237 }
1238
1239 /*
1240 ======================
1241 spectate mode routines
1242 ======================
1243 */
1244 void SpectateCopy(entity spectatee) {
1245         self.armortype = spectatee.armortype;
1246         self.armorvalue = spectatee.armorvalue;
1247         self.currentammo = spectatee.currentammo;
1248         self.effects = spectatee.effects;
1249         self.health = spectatee.health;
1250         self.impulse = 0;
1251         self.items = spectatee.items;
1252         self.punchangle = spectatee.punchangle;
1253         self.view_ofs = spectatee.view_ofs;
1254         self.v_angle = spectatee.v_angle;
1255         self.viewzoom = spectatee.viewzoom;
1256         setorigin(self, spectatee.origin);
1257         setsize(self, spectatee.mins, spectatee.maxs);
1258 }
1259
1260 void SpectateUpdate() {
1261         if(!self.enemy)
1262                         PutObserverInServer();
1263
1264         if (self != self.enemy) {
1265                 if(self.enemy.flags & FL_NOTARGET)
1266                         PutObserverInServer();
1267                 SpectateCopy(self.enemy);
1268                 self.dmg_take = self.enemy.dmg_take;
1269                 self.dmg_save = self.enemy.dmg_save;
1270                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1271                 self.fixangle = TRUE;
1272                 self.angles = self.enemy.v_angle;
1273                 //msg_entity = self;
1274                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1275                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1276                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1277                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1278         }
1279 }
1280
1281 float SpectateNext() {
1282         other = find(self.enemy, classname, "player");
1283         if (!other) {
1284                 other = find(other, classname, "player");
1285         }
1286         if (other) {
1287                 self.enemy = other;
1288         }
1289         if(self.enemy.classname == "player") {
1290                 msg_entity = self;
1291                 WriteByte(MSG_ONE, SVC_SETVIEW);
1292                 WriteEntity(MSG_ONE, self.enemy);
1293                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1294                 SpectateUpdate();
1295                 return 1;
1296         } else {
1297                 return 0;
1298         }
1299 }
1300
1301 /*
1302 =============
1303 PlayerPreThink
1304
1305 Called every frame for each client before the physics are run
1306 =============
1307 */
1308 void() ctf_setstatus;
1309 void PlayerPreThink (void)
1310 {
1311         // version nagging
1312         if(self.version_nagtime)
1313                 if(self.cvar_g_nexuizversion)
1314                         if(time > self.version_nagtime)
1315                         {
1316                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1317                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1318                                         {
1319                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1320                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1321                                         }
1322                                 self.version_nagtime = 0;
1323                         }
1324
1325         if(self.classname == "player") {
1326                 local vector m1, m2;
1327
1328 //              if(self.netname == "Wazat")
1329 //                      bprint(strcat(self.classname, "\n"));
1330
1331                 CheckRules_Player();
1332
1333                 Nixnex_GiveCurrentWeapon();
1334
1335                 if(self.button7)
1336                         PrintWelcomeMessage(self);
1337
1338                 if(cvar("g_lms") || !cvar("sv_spectate"))
1339                 if((time - self.jointime) <= cvar("welcome_message_time"))
1340                         PrintWelcomeMessage(self);
1341
1342                 if (intermission_running)
1343                 {
1344                         IntermissionThink ();   // otherwise a button could be missed between
1345                         return;                                 // the think tics
1346                 }
1347
1348                 if (self.deadflag != DEAD_NO)
1349                 {
1350                         player_anim();
1351                         if (self.deadflag == DEAD_DYING)
1352                         {
1353                                 if (time > self.dead_time)
1354                                         self.deadflag = DEAD_DEAD;
1355                         }
1356                         else if (self.deadflag == DEAD_DEAD)
1357                         {
1358                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1359                                         self.deadflag = DEAD_RESPAWNABLE;
1360                                 else if (!self.button0 && !self.button2 && !self.button3)
1361                                         self.deadflag = DEAD_RESPAWNABLE;
1362                         }
1363                         else if (self.deadflag == DEAD_RESPAWNABLE)
1364                         {
1365                                 if (self.button0  ||
1366                                     self.button2  ||
1367                                     self.button3  ||
1368                                     self.button4  ||
1369                                     self.button5  ||
1370                                     self.button6  ||
1371                                     self.button7  ||
1372                                     self.button8  ||
1373                                     self.buttonuse ||
1374                                     cvar("g_lms") ||
1375                                     cvar("g_forced_respawn"))
1376                                         respawn();
1377                         }
1378                         return;
1379                 }
1380
1381                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1382                 {
1383                         vector dist;
1384
1385                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1386                         dist = self.oldorigin - self.origin;
1387                         dist_z = 0;
1388                         self.lms_traveled_distance += fabs(vlen(dist));
1389
1390                         if(cvar("g_campaign"))
1391                         if(!campaign_bots_may_start)
1392                         {
1393                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1394                                 self.lms_traveled_distance = 0;
1395                         }
1396
1397                         if(time > self.lms_nextcheck)
1398                         {
1399                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1400                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1401                                 {
1402                                         centermsg_set(CENTERMSG_CAMP, cvar_string("g_lms_campcheck_message"));
1403                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1404                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1405                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1406                                 }
1407                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1408                                 self.lms_traveled_distance = 0;
1409                         }
1410                 }
1411
1412                 if (self.button5 && !self.hook.state)
1413                 {
1414                         if (!self.crouch)
1415                         {
1416                                 self.crouch = TRUE;
1417                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1418                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1419                         }
1420                 }
1421                 else
1422                 {
1423                         if (self.crouch)
1424                         {
1425                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1426                                 if (!trace_startsolid)
1427                                 {
1428                                         self.crouch = FALSE;
1429                                         self.view_ofs = PL_VIEW_OFS;
1430                                         setsize (self, PL_MIN, PL_MAX);
1431                                 }
1432                         }
1433                 }
1434
1435                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1436                         local string defaultmodel;
1437                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1438
1439                         if (defaultmodel != self.model)
1440                         {
1441                                 m1 = self.mins;
1442                                 m2 = self.maxs;
1443                                 setmodel_lod (self, defaultmodel);
1444                                 setsize (self, m1, m2);
1445                         }
1446
1447                         if (self.skin != cvar("sv_defaultplayerskin"))
1448                                 self.skin = cvar("sv_defaultplayerskin");
1449                 } else {
1450                         if (self.playermodel != self.model)
1451                         {
1452                                 self.playermodel = CheckPlayerModel(self.playermodel);
1453                                 m1 = self.mins;
1454                                 m2 = self.maxs;
1455                                 setmodel_lod (self, self.playermodel);
1456                                 setsize (self, m1, m2);
1457                         }
1458
1459                         if(teams_matter)
1460                         {
1461                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1462                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1463                         }
1464                         else
1465                         {
1466                                 if (self.skin != stof(self.playerskin))
1467                                         self.skin = stof(self.playerskin);
1468                         }
1469                 }
1470                 // Savage: Check for nameless players
1471                 if (strlen(self.netname) < 1) {
1472                         self.netname = "Player";
1473                         stuffcmd(self, "name Player\n");
1474                 }
1475
1476                 GrapplingHookFrame();
1477
1478                 W_WeaponFrame();
1479
1480                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1481                 {
1482                         if (cvar("g_minstagib") && self.button3)
1483                         {
1484                                 if (self.jump_interval <= (time + 0.1))
1485                                 {
1486                                         self.jump_interval = time + 1;
1487                                         W_Laser_Attack();
1488                                 }
1489                         }
1490                         else if (self.viewzoom > 0.4)
1491                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1492                 }
1493                 else if (self.viewzoom < 1.0)
1494                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1495
1496
1497                 if (self.button2)
1498                         PlayerJump ();
1499                 else
1500                         self.flags = self.flags | FL_JUMPRELEASED;
1501
1502                 player_powerups();
1503                 player_regen();
1504                 player_anim();
1505
1506                 if (cvar("g_minstagib"))
1507                         minstagib_ammocheck();
1508
1509                 ctf_setstatus();
1510
1511                 //self.angles_y=self.v_angle_y + 90;   // temp
1512
1513                 if (self.waterlevel == 2)
1514                         CheckWaterJump ();
1515
1516                 //if (TetrisPreFrame()) return;
1517         } else if(gameover) {
1518                 if (intermission_running)
1519                         IntermissionThink ();   // otherwise a button could be missed between
1520                 return;
1521         } else if(self.classname == "observer") {
1522
1523                 if (self.flags & FL_JUMPRELEASED) {
1524                         if (self.button2 && self.version == cvar("gameversion")) {
1525                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1526                                         self.flags = self.flags & !FL_JUMPRELEASED;
1527                                         self.classname = "player";
1528                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1529                                                 JoinBestTeam(self, 0);
1530                                         if(cvar("g_campaign"))
1531                                                 campaign_bots_may_start = 1;
1532                                         PutClientInServer();
1533                                         if(self.flags & !FL_NOTARGET)
1534                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1535                                         centermsg_reset();
1536                                         return;
1537                                 } else {
1538                                         self.flags = self.flags & !FL_JUMPRELEASED;
1539                                         stuffcmd(self,"menu_showteamselect\n");
1540                                         return;
1541                                 }
1542                         } else if(self.button0 && self.version == cvar("gameversion")) {
1543                                 self.flags = self.flags & !FL_JUMPRELEASED;
1544                                 if(SpectateNext() == 1) {
1545                                         self.classname = "spectator";
1546                                 }
1547                         }
1548                 } else {
1549                         if (!(self.button0 || self.button2)) {
1550                                 self.flags = self.flags | FL_JUMPRELEASED;
1551                         }
1552                 }
1553                 PrintWelcomeMessage(self);
1554         } else if(self.classname == "spectator") {
1555                 if (self.flags & FL_JUMPRELEASED) {
1556                         if (self.button2 && self.version == cvar("gameversion")) {
1557                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1558                                         self.flags = self.flags & !FL_JUMPRELEASED;
1559                                         self.classname = "player";
1560                                         if(!cvar("g_lms"))
1561                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1562
1563                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1564                                                 JoinBestTeam(self, 0);
1565                                         if(cvar("g_campaign"))
1566                                                 campaign_bots_may_start = 1;
1567                                         PutClientInServer();
1568                                         centermsg_reset();
1569                                         return;
1570                                 } else {
1571                                         self.flags = self.flags & !FL_JUMPRELEASED;
1572                                         stuffcmd(self,"menu_showteamselect\n");
1573                                         return;
1574                                 }
1575                         } else if(self.button0) {
1576                                 self.flags = self.flags & !FL_JUMPRELEASED;
1577                                 if(SpectateNext() == 1) {
1578                                         self.classname = "spectator";
1579                                 } else {
1580                                         self.classname = "observer";
1581                                         PutClientInServer();
1582                                 }
1583                         } else if (self.button3) {
1584                                 self.flags = self.flags & !FL_JUMPRELEASED;
1585                                 self.classname = "observer";
1586                                 PutClientInServer();
1587                         } else {
1588                                 SpectateUpdate();
1589                         }
1590                 } else {
1591                         if (!(self.button0 || self.button3)) {
1592                                 self.flags = self.flags | FL_JUMPRELEASED;
1593                         }
1594                 }
1595                 PrintWelcomeMessage(self);
1596                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1597         }
1598 }
1599
1600
1601 /*
1602 =============
1603 PlayerPostThink
1604
1605 Called every frame for each client after the physics are run
1606 =============
1607 */
1608 void PlayerPostThink (void)
1609 {
1610         if(self.classname == "player") {
1611                 CheckRules_Player();
1612                 UpdateChatBubble();
1613                 UpdateTeamBubble();
1614                 if (self.deadflag == DEAD_NO)
1615                 if (self.impulse)
1616                         ImpulseCommands ();
1617                 if (intermission_running)
1618                         return;         // intermission or finale
1619
1620                 //PrintWelcomeMessage(self);
1621                 //if (TetrisPostFrame()) return;
1622         } else if (self.classname == "observer") {
1623                 //do nothing
1624         } else if (self.classname == "spectator") {
1625                 //do nothing
1626         }
1627         Arena_Warmup();
1628 }