data/qcsrc/server/cl_client.qc

   1 #define SPAWNPOINT_SCORE frags
   2
   3 .float wantswelcomemessage;
   4 .string netname_previous;
   5
   6 void spawnfunc_info_player_survivor (void)
   7 {
   8         spawnfunc_info_player_deathmatch();
   9 }
  10
  11 void spawnfunc_info_player_start (void)
  12 {
  13         spawnfunc_info_player_deathmatch();
  14 }
  15
  16 void spawnfunc_info_player_deathmatch (void)
  17 {
  18         self.classname = "info_player_deathmatch";
  19         relocate_spawnpoint();
  20 }
  21
  22 void spawnpoint_use()
  23 {
  24         if(teams_matter)
  25         if(have_team_spawns)
  26         {
  27                 self.team = activator.team;
  28                 some_spawn_has_been_used = 1;
  29         }
  30 };
  31
  32 // Returns:
  33 //   -1 if a spawn can't be used
  34 //   otherwise, a weight of the spawnpoint
  35 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  36 {
  37         float shortest, thisdist;
  38         entity player;
  39
  40         // filter out spots for the wrong team
  41         if(teamcheck)
  42         if(spot.team != teamcheck)
  43                 return -1;
  44
  45         if(race_spawns)
  46                 if(spot.target == "")
  47                         return -1;
  48
  49         // filter out spots for assault
  50         if(spot.target != "") {
  51                 local entity ent;
  52                 float good, found;
  53                 ent = find(world, targetname, spot.target);
  54                 while(ent) {
  55                         found = 1;
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(g_race_qualifying)
  67                                         {
  68                                                 // spawn at first
  69                                                 if(ent.race_checkpoint != 0)
  70                                                         return -1;
  71                                                 if(spot.race_place != race_lowest_place_spawn)
  72                                                         return -1;
  73                                         }
  74                                         else
  75                                         {
  76                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  77                                                         return -1;
  78                                                 float pl;
  79                                                 pl = self.race_place;
  80                                                 if(pl > race_highest_place_spawn)
  81                                                         pl = 0;
  82                                                 if(spot.race_place != pl)
  83                                                         return -1;
  84                                         }
  85                                 }
  86                                 good = 1;
  87                         }
  88                         else
  89                         {
  90                         }
  91                         ent = find(ent, targetname, spot.target);
  92                 }
  93
  94                 if(found && !good)
  95                         return -1;
  96         }
  97
  98         player = playerlist;
  99         shortest = vlen(world.maxs - world.mins);
 100         for(player = playerlist; player; player = player.chain)
 101                 if (player != self)
 102                 {
 103                         thisdist = vlen(player.origin - spot.origin);
 104                         if (thisdist < shortest)
 105                                 shortest = thisdist;
 106                 }
 107         return shortest;
 108 }
 109
 110 float spawn_allbad;
 111 float spawn_allgood;
 112 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 113 {
 114         local entity spot, spotlist, spotlistend;
 115         spawn_allgood = TRUE;
 116         spawn_allbad = TRUE;
 117
 118         spotlist = world;
 119         spotlistend = world;
 120
 121         for(spot = firstspot; spot; spot = spot.chain)
 122         {
 123                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 124
 125                 if(cvar("spawn_debugview"))
 126                 {
 127                         setmodel(spot, "models/runematch/rune.mdl");
 128                         if(spot.SPAWNPOINT_SCORE < mindist)
 129                         {
 130                                 spot.colormod = '1 0 0';
 131                                 spot.scale = 1;
 132                         }
 133                         else
 134                         {
 135                                 spot.colormod = '0 1 0';
 136                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 137                         }
 138                 }
 139
 140                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 141                 {
 142                         if(spot.SPAWNPOINT_SCORE < mindist)
 143                         {
 144                                 // too short distance
 145                                 spawn_allgood = FALSE;
 146                         }
 147                         else
 148                         {
 149                                 // perfect
 150                                 spawn_allbad = FALSE;
 151
 152                                 if(spotlistend)
 153                                         spotlistend.chain = spot;
 154                                 spotlistend = spot;
 155                                 if(!spotlist)
 156                                         spotlist = spot;
 157
 158                                 /*
 159                                 if(teamcheck)
 160                                 if(spot.team != teamcheck)
 161                                         error("invalid spawn added");
 162
 163                                 print("added ", etos(spot), "\n");
 164                                 */
 165                         }
 166                 }
 167         }
 168         if(spotlistend)
 169                 spotlistend.chain = world;
 170
 171         /*
 172                 entity e;
 173                 if(teamcheck)
 174                         for(e = spotlist; e; e = e.chain)
 175                         {
 176                                 print("seen ", etos(e), "\n");
 177                                 if(e.team != teamcheck)
 178                                         error("invalid spawn found");
 179                         }
 180         */
 181
 182         return spotlist;
 183 }
 184
 185 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 186 {
 187         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 188         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 189         local entity spot;
 190
 191         RandomSelection_Init();
 192         for(spot = firstspot; spot; spot = spot.chain)
 193                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 194
 195         return RandomSelection_chosen_ent;
 196 }
 197
 198 /*
 199 =============
 200 SelectSpawnPoint
 201
 202 Finds a point to respawn
 203 =============
 204 */
 205 entity SelectSpawnPoint (float anypoint)
 206 {
 207         local float teamcheck;
 208         local entity firstspot_new;
 209         local entity spot, firstspot, playerlist;
 210
 211         spot = find (world, classname, "testplayerstart");
 212         if (spot)
 213                 return spot;
 214
 215         teamcheck = 0;
 216
 217         if(!anypoint && have_team_spawns)
 218                 teamcheck = self.team;
 219
 220         // get the list of players
 221         playerlist = findchain(classname, "player");
 222         // get the entire list of spots
 223         firstspot = findchain(classname, "info_player_deathmatch");
 224         // filter out the bad ones
 225         // (note this returns the original list if none survived)
 226         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 227         if(!firstspot_new)
 228                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 229         firstspot = firstspot_new;
 230
 231         // there is 50/50 chance of choosing a random spot or the furthest spot
 232         // (this means that roughly every other spawn will be furthest, so you
 233         // usually won't get fragged at spawn twice in a row)
 234         if (arena_roundbased)
 235         {
 236                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 237                 if(firstspot_new)
 238                         firstspot = firstspot_new;
 239                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 240         }
 241         else if (random() > cvar("g_spawn_furthest"))
 242                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 243         else
 244                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 245
 246         if(cvar("spawn_debugview"))
 247         {
 248                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 249
 250                 entity e;
 251                 if(teamcheck)
 252                         for(e = firstspot; e; e = e.chain)
 253                                 if(e.team != teamcheck)
 254                                         error("invalid spawn found");
 255         }
 256
 257         if (!spot)
 258         {
 259                 if(cvar("spawn_debug"))
 260                         GotoNextMap();
 261                 else
 262                 {
 263                         if(some_spawn_has_been_used)
 264                                 return world; // team can't spawn any more, because of actions of other team
 265                         else
 266                                 error("Cannot find a spawn point - please fix the map!");
 267                 }
 268         }
 269
 270         return spot;
 271 }
 272
 273 /*
 274 =============
 275 CheckPlayerModel
 276
 277 Checks if the argument string can be a valid playermodel.
 278 Returns a valid one in doubt.
 279 =============
 280 */
 281 string FallbackPlayerModel = "models/player/marine.zym";
 282 string CheckPlayerModel(string plyermodel) {
 283         if(strlen(plyermodel) < 4)
 284                 return FallbackPlayerModel;
 285         if( substring(plyermodel,0,14) != "models/player/")
 286                 return FallbackPlayerModel;
 287         else if(cvar("sv_servermodelsonly"))
 288         {
 289                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 290                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 291                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 292                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 293                         return FallbackPlayerModel;
 294                 if(plyermodel != strtolower(plyermodel))
 295                         return FallbackPlayerModel;
 296                 if(!fexists(plyermodel))
 297                         return FallbackPlayerModel;
 298         }
 299         return plyermodel;
 300 }
 301
 302 /*
 303 =============
 304 Client_customizeentityforclient
 305
 306 LOD reduction
 307 =============
 308 */
 309 float Client_customizeentityforclient()
 310 {
 311 #ifdef ALLOW_VARIABLE_LOD
 312         // self: me
 313         // other: the player viewing me
 314         float distance;
 315         float f;
 316
 317         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 318                 return TRUE;
 319
 320         if(other.cvar_cl_playerdetailreduction <= 0)
 321         {
 322                 if(other.cvar_cl_playerdetailreduction <= -2)
 323                         self.modelindex = self.modelindex_lod2;
 324                 else if(other.cvar_cl_playerdetailreduction <= -1)
 325                         self.modelindex = self.modelindex_lod1;
 326                 else
 327                         self.modelindex = self.modelindex_lod0;
 328         }
 329         else
 330         {
 331                 distance = vlen(self.origin - other.origin);
 332                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 333                 if(f > 10000)
 334                         self.modelindex = self.modelindex_lod2;
 335                 else if(f > 5000)
 336                         self.modelindex = self.modelindex_lod1;
 337                 else
 338                         self.modelindex = self.modelindex_lod0;
 339         }
 340 #endif
 341
 342         return TRUE;
 343 }
 344
 345 void UpdatePlayerSounds();
 346 void setmodel_lod(entity e, string modelname)
 347 {
 348 #ifdef ALLOW_VARIABLE_LOD
 349         string s;
 350
 351         // FIXME: this only supports 3-letter extensions
 352         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 353         if(fexists(s))
 354         {
 355                 precache_model(s);
 356                 setmodel(e, s); // players have high precision
 357                 self.modelindex_lod1 = self.modelindex;
 358         }
 359         else
 360                 self.modelindex_lod1 = -1;
 361
 362         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 363         if(fexists(s))
 364         {
 365                 precache_model(s);
 366                 setmodel(e, s); // players have high precision
 367                 self.modelindex_lod2 = self.modelindex;
 368         }
 369         else
 370                 self.modelindex_lod2 = -1;
 371
 372         precache_model(modelname);
 373         setmodel(e, modelname); // players have high precision
 374         self.modelindex_lod0 = self.modelindex;
 375
 376         if(self.modelindex_lod1 < 0)
 377                 self.modelindex_lod1 = self.modelindex;
 378
 379         if(self.modelindex_lod2 < 0)
 380                 self.modelindex_lod2 = self.modelindex;
 381 #else
 382         precache_model(modelname);
 383         setmodel(e, modelname); // players have high precision
 384 #endif
 385         player_setupanimsformodel();
 386         UpdatePlayerSounds();
 387 }
 388
 389 /*
 390 =============
 391 PutObserverInServer
 392
 393 putting a client as observer in the server
 394 =============
 395 */
 396 void PutObserverInServer (void)
 397 {
 398         entity  spot;
 399
 400         race_PreSpawnObserver();
 401
 402         spot = SelectSpawnPoint (TRUE);
 403         if(!spot)
 404                 error("No spawnpoints for observers?!?\n");
 405         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 406
 407         if(clienttype(self) == CLIENTTYPE_REAL)
 408         {
 409                 msg_entity = self;
 410                 WriteByte(MSG_ONE, SVC_SETVIEW);
 411                 WriteEntity(MSG_ONE, self);
 412         }
 413
 414         DropAllRunes(self);
 415         kh_Key_DropAll(self, TRUE);
 416
 417         Portal_ClearAll(self);
 418
 419         if(self.flagcarried)
 420                 DropFlag(self.flagcarried, world, world);
 421
 422         WaypointSprite_PlayerDead();
 423
 424         if(self.killcount != -666)
 425         {
 426                 if(g_lms)
 427                 {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 429                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 430                         else
 431                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 432                 }
 433                 else
 434                         bprint ("^4", self.netname, "^4 is spectating now\n");
 435         }
 436
 437         PlayerScore_Clear(self); // clear scores when needed
 438
 439         self.spectatortime = time;
 440
 441         self.classname = "observer";
 442         self.iscreature = FALSE;
 443         self.health = -666;
 444         self.takedamage = DAMAGE_NO;
 445         self.solid = SOLID_NOT;
 446         self.movetype = MOVETYPE_NOCLIP;
 447         self.flags = FL_CLIENT | FL_NOTARGET;
 448         self.armorvalue = 666;
 449         self.effects = 0;
 450         self.armorvalue = cvar("g_balance_armor_start");
 451         self.pauserotarmor_finished = 0;
 452         self.pauserothealth_finished = 0;
 453         self.pauseregen_finished = 0;
 454         self.damageforcescale = 0;
 455         self.death_time = 0;
 456         self.dead_frame = 0;
 457         self.alpha = 0;
 458         self.scale = 0;
 459         self.fade_time = 0;
 460         self.pain_frame = 0;
 461         self.pain_finished = 0;
 462         self.strength_finished = 0;
 463         self.invincible_finished = 0;
 464         self.pushltime = 0;
 465         self.think = SUB_Null;
 466         self.nextthink = 0;
 467         self.hook_time = 0;
 468         self.runes = 0;
 469         self.deadflag = DEAD_NO;
 470         self.angles = spot.angles;
 471         self.angles_z = 0;
 472         self.fixangle = TRUE;
 473         self.crouch = FALSE;
 474
 475         self.view_ofs = PL_VIEW_OFS;
 476         setorigin (self, spot.origin);
 477         setsize (self, '0 0 0', '0 0 0');
 478         self.oldorigin = self.origin;
 479         self.items = 0;
 480         self.weapons = 0;
 481         self.model = "";
 482         self.modelindex = 0;
 483         self.weapon = 0;
 484         self.weaponmodel = "";
 485         self.weaponentity = world;
 486         self.killcount = -666;
 487         self.velocity = '0 0 0';
 488         self.avelocity = '0 0 0';
 489         self.punchangle = '0 0 0';
 490         self.punchvector = '0 0 0';
 491         self.oldvelocity = self.velocity;
 492         self.customizeentityforclient = Client_customizeentityforclient;
 493         self.wantswelcomemessage = 1;
 494
 495         if(g_arena)
 496         {
 497                 if(self.version_mismatch)
 498                 {
 499                         Spawnqueue_Unmark(self);
 500                         Spawnqueue_Remove(self);
 501                 }
 502                 else
 503                 {
 504                         Spawnqueue_Insert(self);
 505                 }
 506         }
 507         else if(g_lms)
 508         {
 509                 // Only if the player cannot play at all
 510                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 511                         self.frags = FRAGS_SPECTATOR;
 512                 else
 513                         self.frags = FRAGS_SPECTATOR; // this was -667 before, is this okay?
 514         }
 515         else
 516                 self.frags = FRAGS_SPECTATOR;
 517 }
 518
 519 float RestrictSkin(float s)
 520 {
 521         if(!teams_matter)
 522                 return s;
 523         if(s == 6)
 524                 return 6;
 525         return mod(s, 3);
 526 }
 527
 528 void FixPlayermodel()
 529 {
 530         local string defaultmodel;
 531         local float defaultskin;
 532         local vector m1, m2;
 533
 534         defaultmodel = "";
 535
 536         if(cvar("sv_defaultcharacter") == 1) {
 537                 defaultskin = 0;
 538
 539                 if(teams_matter)
 540                 {
 541                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 542                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 543                 }
 544
 545                 if(defaultmodel == "")
 546                 {
 547                         defaultmodel = cvar_string("sv_defaultplayermodel");
 548                         defaultskin = cvar("sv_defaultplayerskin");
 549                 }
 550         }
 551
 552         if(self.modelindex == 0)
 553         {
 554                 if(self.model != "")
 555                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 556                 self.model = ""; // force the != checks to return true
 557         }
 558
 559         if(defaultmodel != "")
 560         {
 561                 if (defaultmodel != self.model)
 562                 {
 563                         m1 = self.mins;
 564                         m2 = self.maxs;
 565                         setmodel_lod (self, defaultmodel);
 566                         setsize (self, m1, m2);
 567                 }
 568
 569                 self.skin = defaultskin;
 570         } else {
 571                 if (self.playermodel != self.model)
 572                 {
 573                         self.playermodel = CheckPlayerModel(self.playermodel);
 574                         m1 = self.mins;
 575                         m2 = self.maxs;
 576                         setmodel_lod (self, self.playermodel);
 577                         setsize (self, m1, m2);
 578                 }
 579
 580                 self.skin = RestrictSkin(stof(self.playerskin));
 581         }
 582
 583         if(!teams_matter)
 584                 if(strlen(cvar_string("sv_defaultplayercolors")))
 585                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 586                                 setcolor(self, cvar("sv_defaultplayercolors"));
 587 }
 588
 589 void PlayerTouchExplode(entity p1, entity p2)
 590 {
 591         vector org;
 592         org = (p1.origin + p2.origin) * 0.5;
 593         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 594
 595         te_explosion(org);
 596
 597         entity e;
 598         e = spawn();
 599         setorigin(e, org);
 600         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 601         remove(e);
 602 }
 603
 604 /*
 605 =============
 606 PutClientInServer
 607
 608 Called when a client spawns in the server
 609 =============
 610 */
 611 //void() ctf_playerchanged;
 612 void PutClientInServer (void)
 613 {
 614         if(clienttype(self) == CLIENTTYPE_BOT)
 615         {
 616                 self.classname = "player";
 617         }
 618         else if(clienttype(self) == CLIENTTYPE_REAL)
 619         {
 620                 msg_entity = self;
 621                 WriteByte(MSG_ONE, SVC_SETVIEW);
 622                 WriteEntity(MSG_ONE, self);
 623         }
 624
 625         // player is dead and becomes observer
 626         // FIXME fix LMS scoring for new system
 627         if(g_lms)
 628         {
 629                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 630                         self.classname = "observer";
 631         }
 632
 633         if(g_arena)
 634         if(!self.spawned)
 635                 self.classname = "observer";
 636
 637         if(self.classname == "player") {
 638                 entity spot, oldself;
 639
 640                 race_PreSpawn();
 641
 642                 spot = SelectSpawnPoint (FALSE);
 643                 if(!spot)
 644                 {
 645                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 646                         return; // spawn failed
 647                 }
 648
 649                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 650                 self.campingrifle_bulletcounter = 0;
 651
 652                 self.classname = "player";
 653                 self.iscreature = TRUE;
 654                 self.movetype = MOVETYPE_WALK;
 655                 self.solid = SOLID_SLIDEBOX;
 656                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 657                 self.frags = FRAGS_PLAYER;
 658                 if(independent_players)
 659                         MAKE_INDEPENDENT_PLAYER(self);
 660                 self.flags = FL_CLIENT;
 661                 self.takedamage = DAMAGE_AIM;
 662                 if(g_minstagib)
 663                         self.effects = EF_FULLBRIGHT;
 664                 else
 665                         self.effects = 0;
 666                 self.air_finished = time + 12;
 667                 self.dmg = 2;
 668
 669                 if(inWarmupStage)
 670                 {
 671                         self.ammo_shells = warmup_start_ammo_shells;
 672                         self.ammo_nails = warmup_start_ammo_nails;
 673                         self.ammo_rockets = warmup_start_ammo_rockets;
 674                         self.ammo_cells = warmup_start_ammo_cells;
 675                         self.health = warmup_start_health;
 676                         self.armorvalue = warmup_start_armorvalue;
 677                         self.weapons = warmup_start_weapons;
 678                 }
 679                 else
 680                 {
 681                         self.ammo_shells = start_ammo_shells;
 682                         self.ammo_nails = start_ammo_nails;
 683                         self.ammo_rockets = start_ammo_rockets;
 684                         self.ammo_cells = start_ammo_cells;
 685                         self.health = start_health;
 686                         self.armorvalue = start_armorvalue;
 687                         self.weapons = start_weapons;
 688                 }
 689                 self.items = start_items;
 690                 self.switchweapon = w_getbestweapon(self);
 691                 self.cnt = self.switchweapon;
 692                 self.weapon = 0;
 693                 self.jump_interval = time;
 694
 695                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 696                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 697                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 698                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 699                 //extend the pause of rotting if client was reset at the beginning of the countdown
 700                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 701                         self.spawnshieldtime += game_starttime - time;
 702                         self.pauserotarmor_finished += game_starttime - time;
 703                         self.pauserothealth_finished += game_starttime - time;
 704                         self.pauseregen_finished += game_starttime - time;
 705                 }
 706                 self.damageforcescale = 2;
 707                 self.death_time = 0;
 708                 self.dead_frame = 0;
 709                 self.alpha = 0;
 710                 self.scale = 0;
 711                 self.fade_time = 0;
 712                 self.pain_frame = 0;
 713                 self.pain_finished = 0;
 714                 self.strength_finished = 0;
 715                 self.invincible_finished = 0;
 716                 self.pushltime = 0;
 717                 //self.speed_finished = 0;
 718                 //self.slowmo_finished = 0;
 719                 // players have no think function
 720                 self.think = SUB_Null;
 721                 self.nextthink = 0;
 722                 self.hook_time = 0;
 723                 self.dmg_team = 0;
 724
 725                 self.runes = 0;
 726
 727                 self.deadflag = DEAD_NO;
 728
 729                 self.angles = spot.angles;
 730
 731                 self.angles_z = 0; // never spawn tilted even if the spot says to
 732                 self.fixangle = TRUE; // turn this way immediately
 733                 self.velocity = '0 0 0';
 734                 self.avelocity = '0 0 0';
 735                 self.punchangle = '0 0 0';
 736                 self.punchvector = '0 0 0';
 737                 self.oldvelocity = self.velocity;
 738
 739                 msg_entity = self;
 740                 WRITESPECTATABLE_MSG_ONE({
 741                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 742                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 743                 });
 744
 745                 self.customizeentityforclient = Client_customizeentityforclient;
 746
 747                 self.model = "";
 748                 FixPlayermodel();
 749
 750                 self.crouch = FALSE;
 751                 self.view_ofs = PL_VIEW_OFS;
 752                 setsize (self, PL_MIN, PL_MAX);
 753                 self.spawnorigin = spot.origin;
 754                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 755                 // don't reset back to last position, even if new position is stuck in solid
 756                 self.oldorigin = self.origin;
 757
 758                 if(g_arena)
 759                 {
 760                         Spawnqueue_Remove(self);
 761                         Spawnqueue_Mark(self);
 762                 }
 763
 764                 self.event_damage = PlayerDamage;
 765
 766                 self.bot_attack = TRUE;
 767
 768                 self.statdraintime = time + 5;
 769                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 770
 771                 if(self.killcount == -666) {
 772                         PlayerScore_Clear(self);
 773                         self.killcount = 0;
 774                 }
 775
 776                 self.cnt = WEP_LASER;
 777                 self.nixnex_lastchange_id = -1;
 778
 779                 CL_SpawnWeaponentity();
 780                 self.alpha = default_player_alpha;
 781                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 782                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 783
 784                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 785                 self.lms_traveled_distance = 0;
 786                 self.speedrunning = FALSE;
 787
 788                 race_PostSpawn(spot);
 789
 790                 if(cvar("spawn_debug"))
 791                 {
 792                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 793                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 794                 }
 795
 796                 //stuffcmd(self, "chase_active 0");
 797                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 798
 799                 if (cvar("g_spawnsound"))
 800                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 801
 802                 if(g_assault) {
 803                         if(self.team == assault_attacker_team)
 804                                 centerprint(self, "You are attacking!\n");
 805                         else
 806                                 centerprint(self, "You are defending!\n");
 807                 }
 808
 809                 target_voicescript_clear(self);
 810
 811                 oldself = self;
 812                 self = spot;
 813                         activator = oldself;
 814                                 SUB_UseTargets();
 815                         activator = world;
 816                 self = oldself;
 817
 818         } else if(self.classname == "observer") {
 819                 PutObserverInServer ();
 820         }
 821
 822         //if(g_ctf)
 823         //      ctf_playerchanged();
 824 }
 825
 826 float ClientInit_SendEntity(entity to, float sf)
 827 {
 828         float i;
 829         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 830         WriteShort(MSG_ENTITY, CSQC_REVISION);
 831         WriteByte(MSG_ENTITY, maxclients);
 832         for(i = 1; i <= 24; ++i)
 833                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
 834         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
 835         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
 836         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
 837         return TRUE;
 838 }
 839
 840 void ClientInit_Spawn()
 841 {
 842         entity e;
 843         e = spawn();
 844         e.classname = "ent_client_init";
 845         e.SendEntity = ClientInit_SendEntity;
 846         setmodel(e, "null");
 847         e.effects = EF_NODEPTHTEST;
 848 }
 849
 850 /*
 851 =============
 852 SetNewParms
 853 =============
 854 */
 855 void SetNewParms (void)
 856 {
 857         // initialize parms for a new player
 858         parm1 = -(86400 * 366);
 859 }
 860
 861 /*
 862 =============
 863 SetChangeParms
 864 =============
 865 */
 866 void SetChangeParms (void)
 867 {
 868         // save parms for level change
 869         parm1 = self.parm_idlesince - time;
 870 }
 871
 872 /*
 873 =============
 874 DecodeLevelParms
 875 =============
 876 */
 877 void DecodeLevelParms (void)
 878 {
 879         // load parms
 880         self.parm_idlesince = parm1;
 881         if(self.parm_idlesince == -(86400 * 366))
 882                 self.parm_idlesince = time;
 883
 884         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 885         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 886 }
 887
 888 /*
 889 =============
 890 ClientKill
 891
 892 Called when a client types 'kill' in the console
 893 =============
 894 */
 895
 896 void ClientKill_Now_TeamChange()
 897 {
 898         if(self.killindicator_teamchange == -1)
 899         {
 900                 self.team = -1;
 901                 JoinBestTeam( self, FALSE, FALSE );
 902         }
 903         else
 904         {
 905                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 906         }
 907 }
 908
 909 void ClientKill_Now()
 910 {
 911         if(self.killindicator_teamchange)
 912                 ClientKill_Now_TeamChange();
 913
 914         // in any case:
 915         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 916
 917         if(self.killindicator)
 918         {
 919                 dprint("Cleaned up after a leaked kill indicator.\n");
 920                 remove(self.killindicator);
 921                 self.killindicator = world;
 922         }
 923 }
 924 void KillIndicator_Think()
 925 {
 926         if (!self.owner.modelindex)
 927         {
 928                 self.owner.killindicator = world;
 929                 remove(self);
 930                 return;
 931         }
 932
 933         if(self.cnt <= 0)
 934         {
 935                 self = self.owner;
 936                 ClientKill_Now(); // no oldself needed
 937                 return;
 938         }
 939         else
 940         {
 941                 if(self.cnt <= 10)
 942                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 943                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 944                 {
 945                         if(self.cnt <= 10)
 946                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
 947                         if(self.owner.killindicator_teamchange)
 948                         {
 949                                 if(self.owner.killindicator_teamchange == -1)
 950                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 951                                 else
 952                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 953                         }
 954                         else
 955                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 956                 }
 957                 self.nextthink = time + 1;
 958                 self.cnt -= 1;
 959         }
 960 }
 961
 962 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 963 {
 964         float killtime;
 965         entity e;
 966         killtime = cvar("g_balance_kill_delay");
 967
 968         self.killindicator_teamchange = targetteam;
 969
 970         if(!self.killindicator)
 971         {
 972                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 973                 {
 974                         ClientKill_Now();
 975                 }
 976                 else
 977                 {
 978                         self.killindicator = spawn();
 979                         self.killindicator.owner = self;
 980                         self.killindicator.scale = 0.5;
 981                         setattachment(self.killindicator, self, "");
 982                         setorigin(self.killindicator, '0 0 52');
 983                         self.killindicator.think = KillIndicator_Think;
 984                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 985                         self.killindicator.cnt = ceil(killtime);
 986                         self.killindicator.count = bound(0, ceil(killtime), 10);
 987                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 988
 989                         for(e = world; (e = find(e, classname, "body")) != world; )
 990                         {
 991                                 if(e.enemy != self)
 992                                         continue;
 993                                 e.killindicator = spawn();
 994                                 e.killindicator.owner = e;
 995                                 e.killindicator.scale = 0.5;
 996                                 setattachment(e.killindicator, e, "");
 997                                 setorigin(e.killindicator, '0 0 52');
 998                                 e.killindicator.think = KillIndicator_Think;
 999                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1000                                 e.killindicator.cnt = ceil(killtime);
1001                         }
1002                         self.lip = 0;
1003                 }
1004         }
1005         if(self.killindicator)
1006         {
1007                 if(targetteam)
1008                         self.killindicator.colormod = TeamColor(targetteam);
1009                 else
1010                         self.killindicator.colormod = '0 0 0';
1011         }
1012 }
1013
1014 void ClientKill (void)
1015 {
1016         ClientKill_TeamChange(0);
1017 }
1018
1019 void DoTeamChange(float destteam)
1020 {
1021         float t, c0;
1022         if(!cvar("teamplay"))
1023         {
1024                 if(destteam >= 0)
1025                         SetPlayerColors(self, destteam);
1026                 return;
1027         }
1028         if(self.classname == "player")
1029         if(destteam == -1)
1030         {
1031                 CheckAllowedTeams(self);
1032                 t = FindSmallestTeam(self, TRUE);
1033                 switch(self.team)
1034                 {
1035                         case COLOR_TEAM1: c0 = c1; break;
1036                         case COLOR_TEAM2: c0 = c2; break;
1037                         case COLOR_TEAM3: c0 = c3; break;
1038                         case COLOR_TEAM4: c0 = c4; break;
1039                         default:          c0 = 999;
1040                 }
1041                 switch(t)
1042                 {
1043                         case 1:
1044                                 if(c0 > c1)
1045                                         destteam = COLOR_TEAM1;
1046                                 break;
1047                         case 2:
1048                                 if(c0 > c2)
1049                                         destteam = COLOR_TEAM2;
1050                                 break;
1051                         case 3:
1052                                 if(c0 > c3)
1053                                         destteam = COLOR_TEAM3;
1054                                 break;
1055                         case 4:
1056                                 if(c0 > c4)
1057                                         destteam = COLOR_TEAM4;
1058                                 break;
1059                 }
1060                 if(destteam == -1)
1061                         return;
1062         }
1063         if(destteam == self.team && !self.killindicator)
1064                 return;
1065         ClientKill_TeamChange(destteam);
1066 }
1067
1068 void FixClientCvars(entity e)
1069 {
1070         // send prediction settings to the client
1071         stuffcmd(e, "\nin_bindmap 0 0\n");
1072         /*
1073          * we no longer need to stuff this. Remove this comment block if you feel
1074          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1075         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1076         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1077         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1078         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1079         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1080         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1081         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1082         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1083         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1084         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1085         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1086         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1087         stuffcmd(e, "cl_movement_edgefriction 1\n");
1088          */
1089 }
1090
1091 .float fog_set;
1092 void SendFog()
1093 {
1094         if(clienttype(self) == CLIENTTYPE_REAL)
1095         if(world.fog) // NOT string_null!
1096         {
1097                 if(!self.fog_set)
1098                 {
1099                         if(sv_foginterval)
1100                         {
1101                                 msg_entity = self;
1102                                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1103                                 WriteByte(MSG_ONE, TE_CSQC_FOG);
1104                                 WriteCoord(MSG_ONE, sv_foginterval);
1105                                 WriteString(MSG_ONE, world.fog);
1106                         }
1107                         else
1108                                 // set it once
1109                                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1110
1111                         self.fog_set = 1;
1112                 }
1113         }
1114 }
1115
1116 /*
1117 =============
1118 ClientConnect
1119
1120 Called when a client connects to the server
1121 =============
1122 */
1123 //void ctf_clientconnect();
1124 string ColoredTeamName(float t);
1125 void DecodeLevelParms (void);
1126 //void dom_player_join_team(entity pl);
1127 void ClientConnect (void)
1128 {
1129         local string s;
1130
1131         if(self.flags & FL_CLIENT)
1132         {
1133                 print("Warning: ClientConnect, but already connected!\n");
1134                 return;
1135         }
1136
1137         if(Ban_MaybeEnforceBan(self))
1138                 return;
1139
1140         DecodeLevelParms();
1141
1142         self.classname = "player_joining";
1143
1144         self.flags = self.flags | FL_CLIENT;
1145         self.version_nagtime = time + 10 + random() * 10;
1146
1147         if(player_count<0)
1148         {
1149                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1150                 player_count = 0;
1151         }
1152
1153         PlayerScore_Attach(self);
1154
1155         bot_clientconnect();
1156
1157         race_PreSpawnObserver();
1158
1159         //if(g_domination)
1160         //      dom_player_join_team(self);
1161
1162         //JoinBestTeam(self, FALSE, FALSE);
1163         //
1164         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1165                 self.classname = "observer";
1166         } else {
1167                 self.classname = "player";
1168                 campaign_bots_may_start = 1;
1169         }
1170
1171         self.playerid = (playerid_last = playerid_last + 1);
1172         if(cvar("sv_eventlog"))
1173         {
1174                 if(clienttype(self) == CLIENTTYPE_REAL)
1175                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1176                 else
1177                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1178                 s = strcat(":team:", ftos(self.playerid), ":");
1179                 s = strcat(s, ftos(self.team));
1180                 GameLogEcho(s);
1181         }
1182         self.netname_previous = strzone(self.netname);
1183
1184         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1185
1186         bprint ("^4",self.netname);
1187         bprint ("^4 connected");
1188
1189         if(g_domination || g_ctf)
1190         {
1191                 bprint(" and joined the ");
1192                 bprint(ColoredTeamName(self.team));
1193         }
1194
1195         bprint("\n");
1196
1197         self.welcomemessage_time = 0;
1198
1199         stuffcmd(self, strcat(clientstuff, "\n"));
1200         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1201         stuffcmd(self, "cl_particles_reloadeffects\n");
1202
1203         FixClientCvars(self);
1204
1205         // spawnfunc_waypoint sprites
1206         WaypointSprite_InitClient(self);
1207
1208         // Wazat's grappling hook
1209         SetGrappleHookBindings();
1210
1211         // get autoswitch state from player when he toggles it
1212         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1213
1214         // get version info from player
1215         stuffcmd(self, "cmd clientversion $gameversion\n");
1216
1217         // get other cvars from player
1218         GetCvars(0);
1219
1220         // set cvar for team scoreboard
1221         if (teams_matter)
1222         {
1223                 local float t;
1224                 t = cvar("teamplay");
1225                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1226                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1227         }
1228         else
1229                 stuffcmd(self, "set teamplay 0\n");
1230
1231         // notify about available teams
1232         if(teamplay)
1233         {
1234                 CheckAllowedTeams(self);
1235                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1236                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1237         }
1238         else
1239                 stuffcmd(self, "set _teams_available 0\n");
1240
1241         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1242
1243         if(g_arena)
1244         {
1245                 self.classname = "observer";
1246                 Spawnqueue_Insert(self);
1247         }
1248         /*else if(g_ctf)
1249         {
1250                 ctf_clientconnect();
1251         }*/
1252
1253         if(teams_matter)
1254                 attach_entcs();
1255
1256         bot_relinkplayerlist();
1257
1258         self.spectatortime = time;
1259         if(blockSpectators)
1260         {
1261                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1262         }
1263
1264         self.jointime = time;
1265         self.allowedTimeouts = cvar("sv_timeout_number");
1266
1267         if(clienttype(self) == CLIENTTYPE_REAL)
1268         {
1269                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1270
1271                 if(cvar("g_bugrigs"))
1272                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1273         }
1274
1275         if(g_lms)
1276         {
1277                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1278                 {
1279                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1280                         self.frags = FRAGS_SPECTATOR; // FIXME do we still need this?
1281                 }
1282         }
1283
1284         SendFog();
1285 }
1286
1287 /*
1288 =============
1289 ClientDisconnect
1290
1291 Called when a client disconnects from the server
1292 =============
1293 */
1294 .entity chatbubbleentity;
1295 .entity teambubbleentity;
1296 void ReadyCount();
1297 void ClientDisconnect (void)
1298 {
1299         if not(self.flags & FL_CLIENT)
1300         {
1301                 print("Warning: ClientDisconnect without ClientConnect\n");
1302                 return;
1303         }
1304
1305         bot_clientdisconnect();
1306
1307         if(teams_matter)
1308                 detach_entcs();
1309
1310         if(cvar("sv_eventlog"))
1311                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1312         bprint ("^4",self.netname);
1313         bprint ("^4 disconnected\n");
1314
1315         DropAllRunes(self);
1316         kh_Key_DropAll(self, TRUE);
1317
1318         Portal_ClearAll(self);
1319
1320         if(self.flagcarried)
1321                 DropFlag(self.flagcarried, world, world);
1322
1323         // Here, everything has been done that requires this player to be a client.
1324
1325         self.flags &~= FL_CLIENT;
1326
1327         if (self.chatbubbleentity)
1328                 remove (self.chatbubbleentity);
1329
1330         if (self.teambubbleentity)
1331                 remove (self.teambubbleentity);
1332
1333         if (self.killindicator)
1334                 remove (self.killindicator);
1335
1336         WaypointSprite_PlayerGone();
1337
1338         bot_relinkplayerlist();
1339
1340         // remove laserdot
1341         if(self.weaponentity)
1342                 if(self.weaponentity.lasertarget)
1343                         remove(self.weaponentity.lasertarget);
1344
1345         if(g_arena)
1346         {
1347                 Spawnqueue_Unmark(self);
1348                 Spawnqueue_Remove(self);
1349         }
1350
1351         PlayerScore_Detach(self);
1352
1353         if(self.netname_previous)
1354                 strunzone(self.netname_previous);
1355
1356         ClearPlayerSounds();
1357
1358         self.playerid = 0;
1359         ReadyCount();
1360
1361         // free cvars
1362         GetCvars(-1);
1363 }
1364
1365 .float BUTTON_CHAT;
1366 void ChatBubbleThink()
1367 {
1368         self.nextthink = time;
1369         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1370         {
1371                 if(self.owner) // but why can that ever be world?
1372                         self.owner.chatbubbleentity = world;
1373                 remove(self);
1374                 return;
1375         }
1376         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1377                 self.model = self.mdl;
1378         else
1379                 self.model = "";
1380 };
1381
1382 void UpdateChatBubble()
1383 {
1384         if (!self.modelindex)
1385                 return;
1386         // spawn a chatbubble entity if needed
1387         if (!self.chatbubbleentity)
1388         {
1389                 self.chatbubbleentity = spawn();
1390                 self.chatbubbleentity.owner = self;
1391                 self.chatbubbleentity.exteriormodeltoclient = self;
1392                 self.chatbubbleentity.think = ChatBubbleThink;
1393                 self.chatbubbleentity.nextthink = time;
1394                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1395                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1396                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1397                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1398                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1399                 self.chatbubbleentity.model = "";
1400                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1401         }
1402 }
1403
1404
1405 void TeamBubbleThink()
1406 {
1407         self.nextthink = time;
1408         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1409         {
1410                 if(self.owner) // but why can that ever be world?
1411                         self.owner.teambubbleentity = world;
1412                 remove(self);
1413                 return;
1414         }
1415 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1416         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1417                 self.model = "";
1418         else
1419                 self.model = self.mdl;
1420
1421 };
1422
1423 float TeamBubble_customizeentityforclient()
1424 {
1425         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1426 }
1427
1428 void UpdateTeamBubble()
1429 {
1430         if (!self.modelindex || !cvar("teamplay"))
1431                 return;
1432         // spawn a teambubble entity if needed
1433         if (!self.teambubbleentity && cvar("teamplay"))
1434         {
1435                 self.teambubbleentity = spawn();
1436                 self.teambubbleentity.owner = self;
1437                 self.teambubbleentity.exteriormodeltoclient = self;
1438                 self.teambubbleentity.think = TeamBubbleThink;
1439                 self.teambubbleentity.nextthink = time;
1440                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1441 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1442                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1443                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1444                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1445                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1446                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1447                 self.teambubbleentity.effects = EF_LOWPRECISION;
1448         }
1449 }
1450
1451 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1452 // added to the model skins
1453 /*void UpdateColorModHack()
1454 {
1455         local float c;
1456         c = self.clientcolors & 15;
1457         // LordHavoc: only bothering to support white, green, red, yellow, blue
1458              if (teamplay == 0) self.colormod = '0 0 0';
1459         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1460         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1461         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1462         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1463         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1464         else self.colormod = '1 1 1';
1465 };*/
1466
1467 void respawn(void)
1468 {
1469         CopyBody(1);
1470         self.effects |= EF_NODRAW; // prevent another CopyBody
1471         PutClientInServer();
1472 }
1473
1474 /**
1475  * When sv_timeout is used this function returs strings like
1476  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1477  * Called by centerprint functions
1478  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1479  */
1480 string getTimeoutText(float addOneSecond) {
1481         if (!cvar("sv_timeout") || !timeoutStatus)
1482                 return "";
1483
1484         local string retStr;
1485         if (timeoutStatus == 1) {
1486                 if (addOneSecond == 1) {
1487                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1488                 }
1489                 else {
1490                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1491                 }
1492                 return retStr;
1493         }
1494         else if (timeoutStatus == 2) {
1495                 if (addOneSecond) {
1496                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1497                         //don't show messages like "Timeout ends in 0 seconds"...
1498                         if ((remainingTimeoutTime + 1) > 0)
1499                                 return retStr;
1500                         else
1501                                 return "";
1502                 }
1503                 else {
1504                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1505                         //don't show messages like "Timeout ends in 0 seconds"...
1506                         if (remainingTimeoutTime > 0)
1507                                 return retStr;
1508                         else
1509                                 return "";
1510                 }
1511         }
1512         else return "";
1513 }
1514
1515 void player_powerups (void)
1516 {
1517         if (g_minstagib)
1518         {
1519                 if (self.items & IT_STRENGTH)
1520                 {
1521                         if (time > self.strength_finished)
1522                         {
1523                                 self.alpha = default_player_alpha;
1524                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1525                                 self.items &~= IT_STRENGTH;
1526                                 sprint(self, "^3Invisibility has worn off\n");
1527                         }
1528                 }
1529                 else
1530                 {
1531                         if (time < self.strength_finished)
1532                         {
1533                                 self.alpha = g_minstagib_invis_alpha;
1534                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1535                                 self.items |= IT_STRENGTH;
1536                                 sprint(self, "^3You are invisible\n");
1537                         }
1538                 }
1539
1540                 if (self.items & IT_INVINCIBLE)
1541                 {
1542                         if (time > self.invincible_finished)
1543                         {
1544                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1545                                 sprint(self, "^3Speed has worn off\n");
1546                         }
1547                 }
1548                 else
1549                 {
1550                         if (time < self.invincible_finished)
1551                         {
1552                                 self.items = self.items | IT_INVINCIBLE;
1553                                 sprint(self, "^3You are on speed\n");
1554                         }
1555                 }
1556                 return;
1557         }
1558
1559         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1560         if (self.items & IT_STRENGTH)
1561         {
1562                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1563                 if (time > self.strength_finished)
1564                 {
1565                         self.items = self.items - (self.items & IT_STRENGTH);
1566                         sprint(self, "^3Strength has worn off\n");
1567                 }
1568         }
1569         else
1570         {
1571                 if (time < self.strength_finished)
1572                 {
1573                         self.items = self.items | IT_STRENGTH;
1574                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1575                 }
1576         }
1577         if (self.items & IT_INVINCIBLE)
1578         {
1579                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1580                 if (time > self.invincible_finished)
1581                 {
1582                         self.items = self.items - (self.items & IT_INVINCIBLE);
1583                         sprint(self, "^3Shield has worn off\n");
1584                 }
1585         }
1586         else
1587         {
1588                 if (time < self.invincible_finished)
1589                 {
1590                         self.items = self.items | IT_INVINCIBLE;
1591                         sprint(self, "^3Shield surrounds you\n");
1592                 }
1593         }
1594
1595         if (cvar("g_fullbrightplayers"))
1596                 self.effects = self.effects | EF_FULLBRIGHT;
1597
1598         // midair gamemode: damage only while in the air
1599         // if in midair mode, being on ground grants temporary invulnerability
1600         // (this is so that multishot weapon don't clear the ground flag on the
1601         // first damage in the frame, leaving the player vulnerable to the
1602         // remaining hits in the same frame)
1603         if (self.flags & FL_ONGROUND)
1604         if (g_midair)
1605                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1606
1607         if (time >= game_starttime)
1608         if (time < self.spawnshieldtime)
1609                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1610 }
1611
1612 float CalcRegen(float current, float stable, float regenfactor)
1613 {
1614         if(current > stable)
1615                 return current;
1616         else if(current > stable - 0.25) // when close enough, "snap"
1617                 return stable;
1618         else
1619                 return min(stable, current + (stable - current) * regenfactor * frametime);
1620 }
1621
1622 void player_regen (void)
1623 {
1624         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1625         maxh = cvar("g_balance_health_stable");
1626         maxa = cvar("g_balance_armor_stable");
1627         limith = cvar("g_balance_health_limit");
1628         limita = cvar("g_balance_armor_limit");
1629
1630         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1631                 return;
1632
1633         max_mod = regen_mod = rot_mod = limit_mod = 1;
1634
1635         if (self.runes & RUNE_REGEN)
1636         {
1637                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1638                 {
1639                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1640                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1641                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1642                 }
1643                 else
1644                 {
1645                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1646                         max_mod = cvar("g_balance_rune_regen_hpmod");
1647                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1648                 }
1649         }
1650         else if (self.runes & CURSE_VENOM)
1651         {
1652                 max_mod = cvar("g_balance_curse_venom_hpmod");
1653                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1654                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1655                 else
1656                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1657                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1658                 //if (!self.runes & RUNE_REGEN)
1659                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1660         }
1661         maxh = maxh * max_mod;
1662         //maxa = maxa * max_mod;
1663         limith = limith * limit_mod;
1664         limita = limita * limit_mod;
1665
1666         if (self.armorvalue > maxa)
1667         {
1668                 if (time > self.pauserotarmor_finished)
1669                 {
1670                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1671                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1672                 }
1673         }
1674         else if (self.armorvalue < maxa)
1675         {
1676                 if (time > self.pauseregen_finished)
1677                 {
1678                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1679                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1680                 }
1681         }
1682         if (self.health > maxh)
1683         {
1684                 if (time > self.pauserothealth_finished)
1685                 {
1686                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1687                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1688                 }
1689         }
1690         else if (self.health < maxh)
1691         {
1692                 if (time > self.pauseregen_finished)
1693                 {
1694                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1695                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1696                 }
1697         }
1698
1699         if (self.health > limith)
1700                 self.health = limith;
1701         if (self.armorvalue > limita)
1702                 self.armorvalue = limita;
1703
1704         // if player rotted to death...  die!
1705         if(self.health < 1)
1706                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1707 }
1708
1709 .float zoomstate;
1710 float zoomstate_set;
1711 void SetZoomState(float z)
1712 {
1713         if(z != self.zoomstate)
1714         {
1715                 msg_entity = self;
1716                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1717                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1718                 WriteByte(MSG_ONE, z);
1719                 self.zoomstate = z;
1720         }
1721         zoomstate_set = 1;
1722 }
1723
1724 /*
1725 ======================
1726 spectate mode routines
1727 ======================
1728 */
1729 void SpectateCopy(entity spectatee) {
1730         self.armortype = spectatee.armortype;
1731         self.armorvalue = spectatee.armorvalue;
1732         self.currentammo = spectatee.currentammo;
1733         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1734         self.health = spectatee.health;
1735         self.impulse = 0;
1736         self.items = spectatee.items;
1737         self.weapons = spectatee.weapons;
1738         self.switchweapon = spectatee.switchweapon;
1739         self.weapon = spectatee.weapon;
1740         self.punchangle = spectatee.punchangle;
1741         self.view_ofs = spectatee.view_ofs;
1742         self.v_angle = spectatee.v_angle;
1743         self.velocity = spectatee.velocity;
1744         self.dmg_take = spectatee.dmg_take;
1745         self.dmg_save = spectatee.dmg_save;
1746         self.dmg_inflictor = spectatee.dmg_inflictor;
1747         self.angles = spectatee.v_angle;
1748         self.fixangle = TRUE;
1749         setorigin(self, spectatee.origin);
1750         setsize(self, spectatee.mins, spectatee.maxs);
1751         SetZoomState(spectatee.zoomstate);
1752 }
1753
1754 float SpectateUpdate() {
1755         if(!self.enemy)
1756                 return 0;
1757
1758         if (self == self.enemy)
1759                 return 0;
1760
1761         if(self.enemy.flags & FL_NOTARGET)
1762                 return 0;
1763
1764         SpectateCopy(self.enemy);
1765
1766         return 1;
1767 }
1768
1769 float SpectateNext() {
1770         other = find(self.enemy, classname, "player");
1771         if (!other) {
1772                 other = find(other, classname, "player");
1773         }
1774         if (other) {
1775                 self.enemy = other;
1776         }
1777         if(self.enemy.classname == "player") {
1778                 msg_entity = self;
1779                 WriteByte(MSG_ONE, SVC_SETVIEW);
1780                 WriteEntity(MSG_ONE, self.enemy);
1781                 self.wantswelcomemessage = 1;
1782                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1783                 if(!SpectateUpdate())
1784                         PutObserverInServer();
1785                 return 1;
1786         } else {
1787                 return 0;
1788         }
1789 }
1790
1791 /*
1792 =============
1793 ShowRespawnCountdown()
1794
1795 Update a respawn countdown display.
1796 =============
1797 */
1798 void ShowRespawnCountdown()
1799 {
1800         float number;
1801         if(self.deadflag == DEAD_NO) // just respawned?
1802                 return;
1803         else
1804         {
1805                 number = ceil(self.death_time - time);
1806                 if(number <= 0)
1807                         return;
1808                 if(number <= self.respawn_countdown)
1809                 {
1810                         self.respawn_countdown = number - 1;
1811                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1812                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
1813                 }
1814         }
1815 }
1816
1817 void LeaveSpectatorMode()
1818 {
1819         if(isJoinAllowed()) {
1820                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1821                         self.classname = "player";
1822                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1823                                 JoinBestTeam(self, FALSE, TRUE);
1824                         if(cvar("g_campaign"))
1825                                 campaign_bots_may_start = 1;
1826                         PutClientInServer();
1827                         if(!(self.flags & FL_NOTARGET))
1828                                 bprint ("^4", self.netname, "^4 is playing now\n");
1829                         centerprint(self,"");
1830                         return;
1831                 } else {
1832                         stuffcmd(self,"menu_showteamselect\n");
1833                         return;
1834                 }
1835         }
1836         else {
1837                 //player may not join because of g_maxplayers is set
1838                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1839         }
1840 }
1841
1842 /**
1843  * Determines whether the player is allowed to join. This depends on cvar
1844  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1845  * it checks whether the number of currently playing players exceeds g_maxplayers.
1846  * @return bool TRUE if the player is allowed to join, false otherwise
1847  */
1848 float isJoinAllowed() {
1849         if (!cvar("g_maxplayers"))
1850                 return TRUE;
1851
1852         local entity e;
1853         local float currentlyPlaying;
1854         FOR_EACH_REALPLAYER(e) {
1855                 if(e.classname == "player")
1856                         currentlyPlaying += 1;
1857         }
1858         if(currentlyPlaying < cvar("g_maxplayers"))
1859                 return TRUE;
1860
1861         return FALSE;
1862 }
1863
1864 /**
1865  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1866  * g_maxplayers_spectator_blocktime seconds
1867  */
1868 void checkSpectatorBlock() {
1869         if(self.classname == "spectator" || self.classname == "observer") {
1870                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1871                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1872                         dropclient(self);
1873                 }
1874         }
1875 }
1876
1877 float vercmp_recursive(string v1, string v2)
1878 {
1879         float dot1, dot2;
1880         string s1, s2;
1881         float r;
1882
1883         dot1 = strstrofs(v1, ".", 0);
1884         dot2 = strstrofs(v2, ".", 0);
1885         if(dot1 == -1)
1886                 s1 = v1;
1887         else
1888                 s1 = substring(v1, 0, dot1);
1889         if(dot2 == -1)
1890                 s2 = v2;
1891         else
1892                 s2 = substring(v2, 0, dot2);
1893
1894         r = stof(s1) - stof(s2);
1895         if(r != 0)
1896                 return r;
1897
1898         r = strcasecmp(s1, s2);
1899         if(r != 0)
1900                 return r;
1901
1902         if(dot1 == -1)
1903                 if(dot2 == -1)
1904                         return 0;
1905                 else
1906                         return -1;
1907         else
1908                 if(dot2 == -1)
1909                         return 1;
1910                 else
1911                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1912 }
1913
1914 float vercmp(string v1, string v2)
1915 {
1916         if(strcasecmp(v1, v2) == 0) // early out check
1917                 return 0;
1918         return vercmp_recursive(v1, v2);
1919 }
1920
1921 void ObserverThink()
1922 {
1923         if (self.flags & FL_JUMPRELEASED) {
1924                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1925                         self.welcomemessage_time = 0;
1926                         self.flags = self.flags - FL_JUMPRELEASED;
1927                         LeaveSpectatorMode();
1928                         return;
1929                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1930                         self.welcomemessage_time = 0;
1931                         self.flags = self.flags - FL_JUMPRELEASED;
1932                         if(SpectateNext() == 1) {
1933                                 self.classname = "spectator";
1934                         }
1935                 }
1936         } else {
1937                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1938                         self.flags = self.flags | FL_JUMPRELEASED;
1939                 }
1940         }
1941         if(self.BUTTON_ZOOM)
1942                 self.wantswelcomemessage = 0;
1943         if(self.wantswelcomemessage)
1944                 PrintWelcomeMessage(self);
1945 }
1946
1947 void SpectatorThink()
1948 {
1949         if (self.flags & FL_JUMPRELEASED) {
1950                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1951                         self.welcomemessage_time = 0;
1952                         self.flags = self.flags - FL_JUMPRELEASED;
1953                         LeaveSpectatorMode();
1954                         return;
1955                 } else if(self.BUTTON_ATCK) {
1956                         self.welcomemessage_time = 0;
1957                         self.flags = self.flags - FL_JUMPRELEASED;
1958                         if(SpectateNext() == 1) {
1959                                 self.classname = "spectator";
1960                         } else {
1961                                 self.classname = "observer";
1962                                 PutClientInServer();
1963                         }
1964                 } else if (self.BUTTON_ATCK2) {
1965                         self.welcomemessage_time = 0;
1966                         self.flags = self.flags - FL_JUMPRELEASED;
1967                         self.classname = "observer";
1968                         PutClientInServer();
1969                 } else {
1970                         if(!SpectateUpdate())
1971                                 PutObserverInServer();
1972                 }
1973         } else {
1974                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1975                         self.flags = self.flags | FL_JUMPRELEASED;
1976                 }
1977         }
1978         if(self.BUTTON_ZOOM)
1979                 self.wantswelcomemessage = 0;
1980         if(self.wantswelcomemessage)
1981                 PrintWelcomeMessage(self);
1982         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1983 }
1984
1985 .float touchexplode_time;
1986
1987 /*
1988 =============
1989 PlayerPreThink
1990
1991 Called every frame for each client before the physics are run
1992 =============
1993 */
1994 void() ctf_setstatus;
1995 .float spectatee_status;
1996 void PlayerPreThink (void)
1997 {
1998         self.stat_sys_ticrate = cvar("sys_ticrate");
1999         self.stat_game_starttime = game_starttime;
2000
2001         if(blockSpectators && frametime)
2002                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2003                 checkSpectatorBlock();
2004
2005         zoomstate_set = 0;
2006
2007         if(self.netname_previous != self.netname)
2008         {
2009                 if(cvar("sv_eventlog"))
2010                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2011                 if(self.netname_previous)
2012                         strunzone(self.netname_previous);
2013                 self.netname_previous = strzone(self.netname);
2014         }
2015
2016         // version nagging
2017         if(self.version_nagtime)
2018                 if(self.cvar_g_nexuizversion)
2019                         if(time > self.version_nagtime)
2020                         {
2021                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2022                                 {
2023                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2024                                         {
2025                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2026                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2027                                         }
2028                                         else
2029                                         {
2030                                                 float r;
2031                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2032                                                 if(r < 0)
2033                                                 {
2034                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2035                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2036                                                 }
2037                                                 else if(r > 0)
2038                                                 {
2039                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2040                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2041                                                 }
2042                                         }
2043                                 }
2044                                 self.version_nagtime = 0;
2045                         }
2046
2047         // GOD MODE info
2048         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2049         {
2050                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2051                 self.max_armorvalue = 0;
2052         }
2053
2054         if(frametime)
2055         {
2056                 SendFog();
2057                 antilag_record(self);
2058         }
2059
2060         if(self.classname == "player") {
2061 //              if(self.netname == "Wazat")
2062 //                      bprint(self.classname, "\n");
2063
2064                 CheckRules_Player();
2065
2066                 if(self.BUTTON_INFO)
2067                         PrintWelcomeMessage(self);
2068
2069                 if(g_lms || !cvar("sv_spectate"))
2070                 if((time - self.jointime) <= cvar("welcome_message_time"))
2071                         PrintWelcomeMessage(self);
2072
2073                 if (intermission_running)
2074                 {
2075                         IntermissionThink ();   // otherwise a button could be missed between
2076                         return;                                 // the think tics
2077                 }
2078
2079                 if(self.teleport_time)
2080                 if(time > self.teleport_time)
2081                 {
2082                         self.teleport_time = 0;
2083                         if(! (self.items & IT_STRENGTH))
2084                                 self.effects = self.effects - (self.effects & EF_NODRAW);
2085                 }
2086
2087                 Nixnex_GiveCurrentWeapon();
2088
2089                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2090                         UpdateSelectedPlayer();
2091
2092                 //don't allow the player to turn around while game is paused!
2093                 if(timeoutStatus == 2) {
2094                         self.v_angle = self.lastV_angle;
2095                         self.angles = self.lastV_angle;
2096                         self.fixangle = TRUE;
2097                 }
2098
2099                 if (self.deadflag != DEAD_NO)
2100                 {
2101                         float button_pressed, force_respawn;
2102                         player_anim();
2103                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2104                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2105                         if (self.deadflag == DEAD_DYING)
2106                         {
2107                                 if(force_respawn)
2108                                         self.deadflag = DEAD_RESPAWNING;
2109                                 else if(!button_pressed)
2110                                         self.deadflag = DEAD_DEAD;
2111                         }
2112                         else if (self.deadflag == DEAD_DEAD)
2113                         {
2114                                 if(button_pressed)
2115                                         self.deadflag = DEAD_RESPAWNABLE;
2116                         }
2117                         else if (self.deadflag == DEAD_RESPAWNABLE)
2118                         {
2119                                 if(!button_pressed)
2120                                         self.deadflag = DEAD_RESPAWNING;
2121                         }
2122                         else if (self.deadflag == DEAD_RESPAWNING)
2123                         {
2124                                 if(time > self.death_time)
2125                                 {
2126                                         self.death_time = time + 1; // only retry once a second
2127                                         respawn();
2128                                 }
2129                         }
2130                         ShowRespawnCountdown();
2131                         return;
2132                 }
2133
2134                 if(g_touchexplode)
2135                 if(time > self.touchexplode_time)
2136                 if(self.classname == "player")
2137                 if(self.deadflag == DEAD_NO)
2138                 if not(IS_INDEPENDENT_PLAYER(self))
2139                 FOR_EACH_PLAYER(other) if(self != other)
2140                 {
2141                         if(time > other.touchexplode_time)
2142                         if(other.classname == "player")
2143                         if(other.deadflag == DEAD_NO)
2144                         if not(IS_INDEPENDENT_PLAYER(other))
2145                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2146                         {
2147                                 PlayerTouchExplode(self, other);
2148                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2149                         }
2150                 }
2151
2152                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2153                 {
2154                         vector dist;
2155
2156                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2157                         dist = self.oldorigin - self.origin;
2158                         dist_z = 0;
2159                         self.lms_traveled_distance += fabs(vlen(dist));
2160
2161                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2162                         {
2163                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2164                                 self.lms_traveled_distance = 0;
2165                         }
2166
2167                         if(time > self.lms_nextcheck)
2168                         {
2169                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2170                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2171                                 {
2172                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2173                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2174                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2175                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2176                                 }
2177                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2178                                 self.lms_traveled_distance = 0;
2179                         }
2180                 }
2181
2182                 self.oldorigin = self.origin;
2183
2184                 if (self.BUTTON_CROUCH && !self.hook.state)
2185                 {
2186                         if (!self.crouch)
2187                         {
2188                                 self.crouch = TRUE;
2189                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2190                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2191                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2192                         }
2193                 }
2194                 else
2195                 {
2196                         if (self.crouch)
2197                         {
2198                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2199                                 if (!trace_startsolid)
2200                                 {
2201                                         self.crouch = FALSE;
2202                                         self.view_ofs = PL_VIEW_OFS;
2203                                         setsize (self, PL_MIN, PL_MAX);
2204                                 }
2205                         }
2206                 }
2207
2208                 FixPlayermodel();
2209
2210                 GrapplingHookFrame();
2211
2212                 W_WeaponFrame();
2213
2214                 player_powerups();
2215                 player_regen();
2216                 player_anim();
2217
2218                 if (g_minstagib)
2219                         minstagib_ammocheck();
2220
2221                 ctf_setstatus();
2222                 kh_setstatus();
2223
2224                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2225
2226                 //self.angles_y=self.v_angle_y + 90;   // temp
2227
2228                 //if (TetrisPreFrame()) return;
2229         } else if(gameover) {
2230                 if (intermission_running)
2231                         IntermissionThink ();   // otherwise a button could be missed between
2232                 return;
2233         } else if(self.classname == "observer") {
2234                 ObserverThink();
2235         } else if(self.classname == "spectator") {
2236                 SpectatorThink();
2237         }
2238
2239         if(!zoomstate_set)
2240                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2241
2242         float oldspectatee_status;
2243         oldspectatee_status = self.spectatee_status;
2244         if(self.classname == "spectator")
2245                 self.spectatee_status = num_for_edict(self.enemy);
2246         else if(self.classname == "observer")
2247                 self.spectatee_status = num_for_edict(self);
2248         else
2249                 self.spectatee_status = 0;
2250         if(self.spectatee_status != oldspectatee_status)
2251         {
2252                 msg_entity = self;
2253                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2254                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2255                 WriteByte(MSG_ONE, self.spectatee_status);
2256                 if(g_race)
2257                         race_InitSpectator();
2258         }
2259
2260         if(self.teamkill_soundtime)
2261         if(time > self.teamkill_soundtime)
2262         {
2263                 self.teamkill_soundtime = 0;
2264
2265                 entity oldpusher, oldself;
2266
2267                 oldself = self; self = self.teamkill_soundsource;
2268                 oldpusher = self.pusher; self.pusher = oldself;
2269
2270                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2271
2272                 self.pusher = oldpusher;
2273                 self = oldself;
2274         }
2275
2276         if(self.taunt_soundtime)
2277         if(time > self.taunt_soundtime)
2278         {
2279                 self.taunt_soundtime = 0;
2280                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2281         }
2282
2283         target_voicescript_next(self);
2284 }
2285
2286
2287 /*
2288 =============
2289 PlayerPostThink
2290
2291 Called every frame for each client after the physics are run
2292 =============
2293 */
2294 .float idlekick_lasttimeleft;
2295 .float race_penalty;
2296 .float race_penalty_nagged;
2297 .float race_penalty_nagtime;
2298 void PlayerPostThink (void)
2299 {
2300         // Savage: Check for nameless players
2301         if (strlen(self.netname) < 1) {
2302                 self.netname = "Player";
2303                 stuffcmd(self, "seta _cl_name Player\n");
2304         }
2305
2306         if(sv_maxidle && frametime)
2307         {
2308                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2309                 float timeleft;
2310                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2311                 if(timeleft <= 0)
2312                 {
2313                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2314                         announce(self, "announcer/robotic/terminated.wav");
2315                         dropclient(self);
2316                         return;
2317                 }
2318                 else if(timeleft <= 10)
2319                 {
2320                         if(timeleft != self.idlekick_lasttimeleft)
2321                         {
2322                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2323                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2324                         }
2325                 }
2326                 else
2327                 {
2328                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2329                 }
2330                 self.idlekick_lasttimeleft = timeleft;
2331         }
2332
2333         if(self.classname == "player") {
2334                 CheckRules_Player();
2335                 UpdateChatBubble();
2336                 UpdateTeamBubble();
2337                 if (self.impulse)
2338                         ImpulseCommands();
2339                 if (intermission_running)
2340                         return;         // intermission or finale
2341
2342                 //PrintWelcomeMessage(self);
2343                 //if (TetrisPostFrame()) return;
2344
2345                 // restart countdown
2346                         if(time < game_starttime) {
2347                                 if (!cvar("sv_ready_restart_after_countdown"))
2348                                 {
2349                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2350                                         {
2351                                                 if(time < game_starttime - 2)
2352                                                 {
2353                                                         if(!self.race_penalty_nagged)
2354                                                         {
2355                                                                 // TODO better notification for this!
2356                                                                 self.race_penalty_nagtime = 0;
2357                                                                 self.race_penalty_nagged = 1;
2358                                                         }
2359                                                 }
2360                                                 else if(!self.race_penalty)
2361                                                 {
2362                                                         self.race_penalty_nagtime = 0;
2363                                                         self.race_penalty = time + 5;
2364                                                 }
2365                                         }
2366                                         if(time > self.race_penalty_nagtime)
2367                                         {
2368                                                 if(self.race_penalty > time)
2369                                                 {
2370                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2371                                                 }
2372                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2373                                                 {
2374                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2375                                                 }
2376                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2377                                         }
2378                                         self.movetype = MOVETYPE_NONE;
2379                                         self.velocity = '0 0 0';
2380                                         self.avelocity = '0 0 0';
2381                                         self.movement = '0 0 0';
2382                                 }
2383                         }
2384                         else if (time < self.race_penalty)
2385                         {
2386                                 self.movetype = MOVETYPE_NONE;
2387                                 self.velocity = '0 0 0';
2388                                 self.avelocity = '0 0 0';
2389                                 self.movement = '0 0 0';
2390                         }
2391                         else
2392                         {
2393                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2394                                 if (!cvar("sv_ready_restart_after_countdown"))
2395                                 {
2396                                         if(self.movetype == MOVETYPE_NONE)
2397                                         {
2398                                                 self.movetype = MOVETYPE_WALK;
2399                                         }
2400                                         self.race_penalty = 0;
2401                                         self.race_penalty_nagged = 0;
2402                                 }
2403                         }
2404
2405         } else if (self.classname == "observer") {
2406                 //do nothing
2407         } else if (self.classname == "spectator") {
2408                 //do nothing
2409         }
2410
2411         /*
2412         float i;
2413         for(i = 0; i < 1000; ++i)
2414         {
2415                 vector end;
2416                 end = self.origin + '0 0 1024' + 512 * randomvec();
2417                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2418                 if(trace_fraction < 1)
2419                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2420                 {
2421                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2422                         break;
2423                 }
2424         }
2425         */
2426
2427         Arena_Warmup();
2428
2429         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2430 }