data/qcsrc/server/campaign.qc

   1 // campaign cvars:
   2 //   _campaign_index: index of CURRENT map
   3 //   _campaign_name: name of the current campaign
   4 //   g_campaign(name)_index: index of current LAST map (saved)
   5 //   g_campaign_skill: bot skill offset
   6
   7 float campaign_level;
   8 float campaign_won;
   9 string campaign_index_var;
  10 float checkrules_equality;
  11
  12 float CampaignBailout(string s)
  13 {
  14         cvar = cvar_builtin;
  15         cvar_string = cvar_string_builtin;
  16         cvar_set = cvar_set_builtin;
  17         cvar_set("g_campaign", "0");
  18         print("campaign initialization failed: ", s, "\n");
  19         return 1;
  20 }
  21
  22 string cvar_campaignwrapper_list; // string of format ; var value; var value; var value;
  23 string cvar_string_campaignwrapper(string theCvar)
  24 {
  25         float p, q;
  26         p = strstrofs(cvar_campaignwrapper_list, strcat("; ", theCvar, " "), 0);
  27         if(p < 0)
  28                 return cvar_defstring(theCvar);
  29         p += strlen(theCvar) + 3;
  30         q = strstrofs(cvar_campaignwrapper_list, ";", p);
  31         if(q < 0)
  32                 return cvar_defstring(theCvar);
  33         return substring(cvar_campaignwrapper_list, p, q - p);
  34 }
  35 float cvar_campaignwrapper(string theCvar)
  36 {
  37         return stof(cvar_string_campaignwrapper(theCvar));
  38 }
  39 void cvar_set_campaignwrapper(string theCvar, string theValue)
  40 {
  41         if(cvar_string_campaignwrapper(theCvar) == theValue)
  42                 return;
  43         string s;
  44         s = cvar_campaignwrapper_list;
  45         cvar_campaignwrapper_list = strzone(strcat("; ", theCvar, " ", theValue, s));
  46         strunzone(s);
  47         //print(cvar_campaignwrapper_list, "\n");
  48 }
  49
  50 float Campaign_Invalid()
  51 {
  52         string thismapname, wantedmapname;
  53         thismapname = GetMapname();
  54         wantedmapname = campaign_gametype[0];
  55         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname))
  56                 return CampaignBailout("wrong game type!");
  57         wantedmapname = campaign_mapname[0];
  58         if(wantedmapname != thismapname)
  59                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  60         return 0;
  61 }
  62
  63 void CampaignPreInit()
  64 {
  65         float baseskill;
  66         string title;
  67         campaign_level = cvar("_campaign_index");
  68         campaign_name = strzone(cvar_string("_campaign_name"));
  69         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  70         CampaignFile_Load(campaign_level, 2);
  71         if(campaign_entries < 1)
  72         {
  73                 CampaignBailout("unknown map");
  74                 return;
  75         }
  76
  77         baseskill = cvar("g_campaign_skill");
  78         baseskill = baseskill + campaign_botskill[0];
  79         if(baseskill < 0)
  80                 baseskill = 0;
  81
  82         cvar_set("sv_public", "0");
  83         cvar_set("pausable", "1");
  84
  85         cvar_campaignwrapper_list = strzone(strcat("; ", campaign_mutators[0], "; "));
  86
  87         cvar = cvar_campaignwrapper;
  88         cvar_string = cvar_string_campaignwrapper;
  89         cvar_set = cvar_set_campaignwrapper;
  90
  91         cvar_set("g_campaign", "1");
  92         cvar_set("g_dm", "0");
  93         cvar_set("skill", ftos(baseskill));
  94         cvar_set("bot_number", ftos(campaign_bots[0]));
  95         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
  96
  97         if(Campaign_Invalid())
  98                 return;
  99
 100         title = campaign_shortdesc[0];
 101         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
 102         campaign_message = strzone(strcat("\n\n\n\n\n\n\n\n\n\n^1\n", title, "\n^3\n", campaign_longdesc[0], "\n\n^1press jump to enter the game"));
 103         strunzone(title);
 104 }
 105
 106 string GetMapname();
 107 void CampaignPostInit()
 108 {
 109         // now some sanity checks
 110         if(Campaign_Invalid())
 111                 return;
 112         cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
 113         cvar_set("timelimit", "0");
 114 }
 115
 116 void CampaignSaveCvar(string cvarname, float value)
 117 {
 118         float fh;
 119         float len;
 120         string contents;
 121         string l;
 122
 123         registercvar(cvarname, ftos(value));
 124         cvar_set_builtin(cvarname, ftos(value));
 125         // note: cvarname must be remembered
 126
 127         fh = fopen("campaign.cfg", FILE_READ);
 128         contents = "";
 129         if(fh >= 0)
 130         {
 131                 while((l = fgets(fh)))
 132                 {
 133                         len = tokenize_sane(l);
 134                         if(len != 3)
 135                                 continue;
 136                         if(argv(0) != "set")
 137                                 continue;
 138                         if(argv(1) == cvarname)
 139                                 continue;
 140                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 141                 }
 142                 fclose(fh);
 143         }
 144         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 145         fh = fopen("campaign.cfg", FILE_WRITE);
 146         if(fh >= 0)
 147         {
 148                 fputs(fh, contents);
 149         }
 150         else
 151         {
 152                 error("Cannot write to campaign file");
 153         }
 154 }
 155
 156 void CampaignPreIntermission()
 157 {
 158         entity head;
 159         float won;
 160         float lost;
 161         local string savevar;
 162
 163         won = 0;
 164
 165         head = findchain(classname, "player");
 166         while(head)
 167         {
 168                 if(clienttype(head) == CLIENTTYPE_REAL)
 169                 {
 170                         if(head.winning)
 171                                 won = won + 1;
 172                         else
 173                                 lost = lost + 1;
 174                 }
 175                 head = head.chain;
 176         }
 177
 178         if(won == 1 && lost == 0 && checkrules_equality == 0)
 179         {
 180                 campaign_won = 1;
 181                 bprint("The current level has been WON.\n");
 182                 // sound!
 183         }
 184         else
 185         {
 186                 campaign_won = 0;
 187                 bprint("The current level has been LOST.\n");
 188                 // sound!
 189         }
 190
 191         if(campaign_won)
 192         {
 193                 if(campaign_entries < 2)
 194                 {
 195                         // I have won
 196                         savevar = strcat("g_campaign", campaign_name, "_won");
 197                         CampaignSaveCvar(savevar, 1);
 198                         // advance level (for menu to show it right)
 199                         CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 200                 }
 201                 else if(campaign_level == cvar_builtin(campaign_index_var))
 202                 {
 203                         // advance level
 204                         CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 205                 }
 206         }
 207 }
 208
 209 void CampaignPostIntermission()
 210 {
 211         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 212
 213         if(campaign_won && campaign_entries < 2)
 214         {
 215                 // last map won!
 216                 localcmd("togglemenu 1\n");
 217                 CampaignFile_Unload();
 218                 return;
 219         }
 220
 221         CampaignSetup(campaign_won);
 222         CampaignFile_Unload();
 223         strunzone(campaign_message);
 224         strunzone(campaign_index_var);
 225         strunzone(campaign_name);
 226         campaign_name = "";
 227 }
 228
 229
 230
 231 void CampaignLevelWarp(float n)
 232 {
 233         if(!sv_cheats)
 234                 return;
 235         CampaignFile_Unload();
 236         CampaignFile_Load(n, 1);
 237         if(campaign_entries)
 238                 CampaignSetup(0);
 239         else
 240                 error("Sorry, cheater. You are NOT WELCOME.");
 241         CampaignFile_Unload();
 242 }