data/qcsrc/server/bots.qc

   1 .float aistatus;
   2 float AI_STATUS_ROAMING                         = 1;    // Bot is just crawling the map. No enemies at sight
   3 float AI_STATUS_ATTACKING                       = 2;    // There are enemies at sight
   4 float AI_STATUS_RUNNING                         = 4;    // Bot is bunny hopping
   5 float AI_STATUS_DANGER_AHEAD                    = 8;    // There is lava/slime/trigger_hurt ahead
   6 float AI_STATUS_OUT_JUMPPAD                     = 16;   // Trying to get out of a "vertical" jump pad
   7 float AI_STATUS_OUT_WATER                       = 32;   // Trying to get out of water
   8 float AI_STATUS_WAYPOINT_PERSONAL_LINKING       = 64;   // Waiting for the personal waypoint to be linked
   9 float AI_STATUS_WAYPOINT_PERSONAL_GOING         = 128;  // Going to a personal waypoint
  10 float AI_STATUS_WAYPOINT_PERSONAL_REACHED       = 256;  // Personal waypoint reached
  11 float AI_STATUS_JETPACK_FLYING                  = 512;
  12 float AI_STATUS_JETPACK_LANDING                 = 1024;
  13
  14 // utilities for path debugging
  15 #ifdef DEBUG_TRACEWALK
  16
  17 float DEBUG_NODE_SUCCESS        = 1;
  18 float DEBUG_NODE_WARNING        = 2;
  19 float DEBUG_NODE_FAIL           = 3;
  20
  21 vector debuglastnode;
  22
  23 void debugresetnodes()
  24 {
  25         debuglastnode = '0 0 0';
  26 }
  27
  28 void debugnode(vector node)
  29 {
  30         if not(self.classname=="player")
  31                 return;
  32
  33         if(debuglastnode=='0 0 0')
  34         {
  35                 debuglastnode = node;
  36                 return;
  37         }
  38
  39         te_lightning2(world, node, debuglastnode);
  40         debuglastnode = node;
  41 }
  42
  43 void debugnodestatus(vector position, float status)
  44 {
  45         vector color;
  46
  47         switch (status)
  48         {
  49                 case DEBUG_NODE_SUCCESS:
  50                         color = '0 15 0';
  51                         break;
  52                 case DEBUG_NODE_WARNING:
  53                         color = '15 15 0';
  54                         break;
  55                 case DEBUG_NODE_FAIL:
  56                         color = '15 0 0';
  57                         break;
  58                 default:
  59                         color = '15 15 15';
  60         }
  61
  62         te_customflash(position, 40,  2, color);
  63 }
  64
  65 #endif
  66
  67 // rough simulation of walking from one point to another to test if a path
  68 // can be traveled, used for waypoint linking and havocbot
  69
  70 vector stepheightvec;
  71 float bot_navigation_movemode;
  72 float navigation_testtracewalk;
  73 float tracewalk(entity e, vector start, vector m1, vector m2, vector end, float movemode)
  74 {
  75         local vector org;
  76         local vector move;
  77         local vector dir;
  78         local float dist;
  79         local float totaldist;
  80         local float stepdist;
  81         local float yaw;
  82         local float ignorehazards;
  83         local float swimming;
  84
  85         #ifdef DEBUG_TRACEWALK
  86                 debugresetnodes();
  87                 debugnode(start);
  88         #endif
  89
  90         move = end - start;
  91         move_z = 0;
  92         org = start;
  93         dist = totaldist = vlen(move);
  94         dir = normalize(move);
  95         stepdist = 32;
  96         ignorehazards = FALSE;
  97
  98         // Analyze starting point
  99         traceline(start, start, MOVE_NORMAL, e);
 100         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 101                 ignorehazards = TRUE;
 102         else
 103         {
 104                 traceline( start, start + '0 0 -65536', MOVE_NORMAL, e);
 105                 if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 106                 {
 107                         ignorehazards = TRUE;
 108                         swimming = TRUE;
 109                 }
 110         }
 111         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
 112         if (trace_startsolid)
 113         {
 114                 // Bad start
 115                 #ifdef DEBUG_TRACEWALK
 116                         debugnodestatus(start, DEBUG_NODE_FAIL);
 117                 #endif
 118                 //print("tracewalk: ", vtos(start), " is a bad start\n");
 119                 return FALSE;
 120         }
 121
 122         // Movement loop
 123         yaw = vectoyaw(move);
 124         move = end - org;
 125         for (;;)
 126         {
 127                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
 128                 {
 129                         // Succeeded
 130                         #ifdef DEBUG_TRACEWALK
 131                                 debugnodestatus(org, DEBUG_NODE_SUCCESS);
 132                         #endif
 133                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 134                         return TRUE;
 135                 }
 136                 #ifdef DEBUG_TRACEWALK
 137                         debugnode(org);
 138                 #endif
 139
 140                 if (dist <= 0)
 141                         break;
 142                 if (stepdist > dist)
 143                         stepdist = dist;
 144                 dist = dist - stepdist;
 145                 traceline(org, org, MOVE_NORMAL, e);
 146                 if (!ignorehazards)
 147                 {
 148                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 149                         {
 150                                 // hazards blocking path
 151                                 #ifdef DEBUG_TRACEWALK
 152                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 153                                 #endif
 154                                 //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
 155                                 return FALSE;
 156                         }
 157                 }
 158                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
 159                 {
 160                         move = normalize(end - org);
 161                         tracebox(org, m1, m2, org + move * stepdist, movemode, e);
 162
 163                         #ifdef DEBUG_TRACEWALK
 164                                 debugnode(trace_endpos);
 165                         #endif
 166
 167                         if (trace_fraction < 1)
 168                         {
 169                                 swimming = TRUE;
 170                                 org = trace_endpos - normalize(org - trace_endpos) * stepdist;
 171                                 for(; org_z < end_z + self.maxs_z; org_z += stepdist)
 172                                 {
 173                                                 #ifdef DEBUG_TRACEWALK
 174                                                         debugnode(org);
 175                                                 #endif
 176                                         if(pointcontents(org) == CONTENT_EMPTY)
 177                                                         break;
 178                                 }
 179
 180                                 if not (pointcontents(org + '0 0 1') == CONTENT_EMPTY)
 181                                 {
 182                                         #ifdef DEBUG_TRACEWALK
 183                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 184                                         #endif
 185                                         return FALSE;
 186                                         //print("tracewalk: ", vtos(start), " failed under water\n");
 187                                 }
 188                                 continue;
 189
 190                         }
 191                         else
 192                                 org = trace_endpos;
 193                 }
 194                 else
 195                 {
 196                         move = dir * stepdist + org;
 197                         tracebox(org, m1, m2, move, movemode, e);
 198
 199                         #ifdef DEBUG_TRACEWALK
 200                                 debugnode(trace_endpos);
 201                         #endif
 202
 203                         // hit something
 204                         if (trace_fraction < 1)
 205                         {
 206                                 // check if we can walk over this obstacle
 207                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 208                                 if (trace_fraction < 1 || trace_startsolid)
 209                                 {
 210                                         #ifdef DEBUG_TRACEWALK
 211                                                 debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 212                                         #endif
 213
 214                                         // check for doors
 215                                         traceline( org, move, movemode, e);
 216                                         if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 217                                         {
 218                                                 local vector nextmove;
 219                                                 move = trace_endpos;
 220                                                 while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 221                                                 {
 222                                                         nextmove = move + (dir * stepdist);
 223                                                         traceline( move, nextmove, movemode, e);
 224                                                         move = nextmove;
 225                                                 }
 226                                         }
 227                                         else
 228                                         {
 229                                                 #ifdef DEBUG_TRACEWALK
 230                                                         debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 231                                                 #endif
 232                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 233                                                 //te_explosion(trace_endpos);
 234                                                 //print(ftos(e.dphitcontentsmask), "\n");
 235                                                 return FALSE; // failed
 236                                         }
 237                                 }
 238                                 else
 239                                         move = trace_endpos;
 240                         }
 241                         else
 242                                 move = trace_endpos;
 243
 244                         // trace down from stepheight as far as possible and move there,
 245                         // if this starts in solid we try again without the stepup, and
 246                         // if that also fails we assume it is a wall
 247                         // (this is the same logic as the Quake walkmove function used)
 248                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 249
 250                         // moved successfully
 251                         if(swimming)
 252                         {
 253                                 local float c;
 254                                 c = pointcontents(org + '0 0 1');
 255                                 if not(c == CONTENT_WATER || c == CONTENT_LAVA || c == CONTENT_SLIME)
 256                                         swimming = FALSE;
 257                                 else
 258                                         continue;
 259                         }
 260
 261                         org = trace_endpos;
 262                 }
 263         }
 264
 265         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 266
 267         // moved but didn't arrive at the intended destination
 268         #ifdef DEBUG_TRACEWALK
 269                 debugnodestatus(org, DEBUG_NODE_FAIL);
 270         #endif
 271
 272         return FALSE;
 273 };
 274
 275
 276 // grenade tracing to decide the best pitch to fire at
 277
 278 entity tracetossent;
 279 entity tracetossfaketarget;
 280
 281 // traces multiple trajectories to find one that will impact the target
 282 // 'end' vector is the place it aims for,
 283 // returns TRUE only if it hit targ (don't target non-solid entities)
 284 vector findtrajectory_velocity;
 285 float findtrajectorywithleading(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore)
 286 {
 287         local float c, savesolid, shottime;
 288         local vector dir, end, v;
 289         if (shotspeed < 1)
 290                 return FALSE; // could cause division by zero if calculated
 291         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
 292                 return FALSE; // could never hit it
 293         if (!tracetossent)
 294                 tracetossent = spawn();
 295         tracetossent.owner = ignore;
 296         setsize(tracetossent, m1, m2);
 297         savesolid = targ.solid;
 298         targ.solid = SOLID_NOT;
 299         shottime = ((vlen(targ.origin - org) / shotspeed) + shotdelay);
 300         v = targ.velocity * shottime + targ.origin;
 301         tracebox(targ.origin, targ.mins, targ.maxs, v, FALSE, targ);
 302         v = trace_endpos;
 303         end = v + (targ.mins + targ.maxs) * 0.5;
 304         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
 305         {
 306                 // out of range
 307                 targ.solid = savesolid;
 308                 return FALSE;
 309         }
 310
 311         if (!tracetossfaketarget)
 312                 tracetossfaketarget = spawn();
 313         tracetossfaketarget.solid = savesolid;
 314         tracetossfaketarget.movetype = targ.movetype;
 315         setmodel(tracetossfaketarget, targ.model); // no low precision
 316         tracetossfaketarget.model = targ.model;
 317         tracetossfaketarget.modelindex = targ.modelindex;
 318         setsize(tracetossfaketarget, targ.mins, targ.maxs);
 319         setorigin(tracetossfaketarget, v);
 320
 321         c = 0;
 322         dir = normalize(end - org);
 323         while (c < 10) // 10 traces
 324         {
 325                 setorigin(tracetossent, org); // reset
 326                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
 327                 tracetoss(tracetossent, ignore); // love builtin functions...
 328                 if (trace_ent == tracetossfaketarget) // done
 329                 {
 330                         targ.solid = savesolid;
 331
 332                         // make it disappear
 333                         tracetossfaketarget.solid = SOLID_NOT;
 334                         tracetossfaketarget.movetype = MOVETYPE_NONE;
 335                         tracetossfaketarget.model = "";
 336                         tracetossfaketarget.modelindex = 0;
 337                         // relink to remove it from physics considerations
 338                         setorigin(tracetossfaketarget, v);
 339
 340                         return TRUE;
 341                 }
 342                 dir_z = dir_z + 0.1; // aim up a little more
 343                 c = c + 1;
 344         }
 345         targ.solid = savesolid;
 346
 347         // make it disappear
 348         tracetossfaketarget.solid = SOLID_NOT;
 349         tracetossfaketarget.movetype = MOVETYPE_NONE;
 350         tracetossfaketarget.model = "";
 351         tracetossfaketarget.modelindex = 0;
 352         // relink to remove it from physics considerations
 353         setorigin(tracetossfaketarget, v);
 354
 355         // leave a valid one even if it won't reach
 356         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
 357         return FALSE;
 358 };
 359
 360
 361
 362 // Lag simulation
 363 #define LAG_QUEUE_LENGTH 4
 364
 365 .void(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4) lag_func;
 366
 367 .float lag_time[LAG_QUEUE_LENGTH];
 368 .float lag_float1[LAG_QUEUE_LENGTH];
 369 .float lag_float2[LAG_QUEUE_LENGTH];
 370 .vector lag_vec1[LAG_QUEUE_LENGTH];
 371 .vector lag_vec2[LAG_QUEUE_LENGTH];
 372 .vector lag_vec3[LAG_QUEUE_LENGTH];
 373 .vector lag_vec4[LAG_QUEUE_LENGTH];
 374 .entity lag_entity1[LAG_QUEUE_LENGTH];
 375
 376 void lag_update()
 377 {
 378         float i;
 379         for(i=0;i<LAG_QUEUE_LENGTH;++i)
 380         {
 381                 if (self.lag_time[i])
 382                 if (time > self.lag_time[i])
 383                 {
 384                         self.lag_func(
 385                                 self.lag_time[i], self.lag_float1[i], self.lag_float2[i],
 386                                 self.lag_entity1[i], self.lag_vec1[i], self.lag_vec2[i], self.lag_vec3[i],
 387                                 self.lag_vec4[i]
 388                         );
 389                         // Clear this position on the queue
 390                         self.(lag_time[i]) = 0;
 391                 }
 392         }
 393 };
 394
 395 float lag_additem(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
 396 {
 397         float i;
 398         for(i=0;i<LAG_QUEUE_LENGTH;++i)
 399         {
 400                 // Find a free position on the queue
 401                 if (self.lag_time[i] == 0)
 402                 {
 403                         self.(lag_time[i]) = t;
 404                         self.(lag_vec1[i]) = v1;
 405                         self.(lag_vec2[i]) = v2;
 406                         self.(lag_vec3[i]) = v3;
 407                         self.(lag_vec4[i]) = v4;
 408                         self.(lag_float1[i]) = f1;
 409                         self.(lag_float2[i]) = f2;
 410                         self.(lag_entity1[i]) = e1;
 411                         return TRUE;
 412                 }
 413         }
 414         return FALSE;
 415 };
 416
 417
 418 // Random skill system
 419 .float bot_thinkskill;
 420 .float bot_mouseskill;
 421 .float bot_predictionskill;
 422 .float bot_offsetskill;
 423
 424
 425 // spawnfunc_waypoint navigation system
 426
 427 // itemscore = (howmuchmoreIwant / howmuchIcanwant) / itemdistance
 428 // waypointscore = 0.7 / waypointdistance
 429
 430 #define MAX_WAYPOINTS_LINKS 32
 431 .vector wpnearestpoint;
 432 .entity wlink[MAX_WAYPOINTS_LINKS];
 433 .float wpmincost[MAX_WAYPOINTS_LINKS];
 434 .float wpfire, wpcost, wpconsidered, wpisbox, wpflags, wplinked;
 435
 436 // stack of current goals (the last one of which may be an item or other
 437 // desirable object, the rest are typically waypoints to reach it)
 438 .entity goalcurrent, goalstack01, goalstack02, goalstack03;
 439 .entity goalstack04, goalstack05, goalstack06, goalstack07;
 440 .entity goalstack08, goalstack09, goalstack10, goalstack11;
 441 .entity goalstack12, goalstack13, goalstack14, goalstack15;
 442 .entity goalstack16, goalstack17, goalstack18, goalstack19;
 443 .entity goalstack20, goalstack21, goalstack22, goalstack23;
 444 .entity goalstack24, goalstack25, goalstack26, goalstack27;
 445 .entity goalstack28, goalstack29, goalstack30, goalstack31;
 446
 447 .entity nearestwaypoint;
 448 .float nearestwaypointtimeout;
 449
 450 // used during navigation_goalrating_begin/end sessions
 451 #define MAX_BESTGOALS 3
 452 float bestgoalswindex;
 453 float bestgoalsrindex;
 454 float navigation_bestrating;
 455 entity navigation_bestgoals[MAX_BESTGOALS];
 456 .float navigation_hasgoals;
 457
 458 /////////////////////////////////////////////////////////////////////////////
 459 // spawnfunc_waypoint management
 460 /////////////////////////////////////////////////////////////////////////////
 461
 462 // waypoints with this flag are not saved, they are automatically generated
 463 // waypoints like jump pads, teleporters, and items
 464 float WAYPOINTFLAG_GENERATED = 8388608;
 465 float WAYPOINTFLAG_ITEM = 4194304;
 466 float WAYPOINTFLAG_TELEPORT = 2097152;
 467 float WAYPOINTFLAG_NORELINK = 1048576;
 468 float WAYPOINTFLAG_PERSONAL = 524288;
 469
 470 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 471 void waypoint_addlink(entity from, entity to)
 472 {
 473         local float c, i;
 474
 475         if (from == to)
 476                 return;
 477
 478         if (from.wpflags & WAYPOINTFLAG_NORELINK)
 479                 return;
 480
 481         // return if already linked
 482         for(i=0;i<MAX_WAYPOINTS_LINKS;++i)
 483         {
 484                 if(from.wlink[i]==to)
 485                         return;
 486         }
 487
 488         // if either is a box we have to find the nearest points on them to
 489         // calculate the distance properly
 490         if (to.wpisbox || from.wpisbox)
 491         {
 492                 local vector v1, v2, m1, m2;
 493                 v1 = from.origin;
 494                 m1 = to.absmin;
 495                 m2 = to.absmax;
 496                 v1_x = bound(m1_x, v1_x, m2_x);
 497                 v1_y = bound(m1_y, v1_y, m2_y);
 498                 v1_z = bound(m1_z, v1_z, m2_z);
 499                 v2 = to.origin;
 500                 m1 = from.absmin;
 501                 m2 = from.absmax;
 502                 v2_x = bound(m1_x, v2_x, m2_x);
 503                 v2_y = bound(m1_y, v2_y, m2_y);
 504                 v2_z = bound(m1_z, v2_z, m2_z);
 505                 v2 = to.origin;
 506                 c = vlen(v2 - v1);
 507         }
 508         else
 509                 c = vlen(to.origin - from.origin);
 510
 511         if (from.wpmincost[MAX_WAYPOINTS_LINKS - 1] < c)
 512                 return;
 513
 514         for(i=MAX_WAYPOINTS_LINKS - 2;i>0;--i)
 515         {
 516                 if (from.wpmincost[i] < c)
 517                 {
 518                         from.(wlink[i]) = to;
 519                         from.(wpmincost[i]) = c;
 520                         return;
 521                 }
 522                 from.(wlink[i]) = from.wlink[i-1];
 523                 from.(wpmincost[i]) = from.wpmincost[i-1];
 524         }
 525         from.(wlink[0]) = to;
 526         from.(wpmincost[0]) = c;
 527         return;
 528 };
 529
 530 // fields you can query using prvm_global server to get some statistics about waypoint linking culling
 531 float relink_total, relink_walkculled, relink_pvsculled, relink_lengthculled;
 532
 533 // relink this spawnfunc_waypoint
 534 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 535 // (SLOW!)
 536 void waypoint_think()
 537 {
 538         local entity e;
 539         local vector sv, sm1, sm2, ev, em1, em2, dv;
 540
 541         stepheightvec = cvar("sv_stepheight") * '0 0 1';
 542         bot_navigation_movemode = ((cvar("bot_navigation_ignoreplayers")) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 543
 544         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 545         sm1 = self.origin + self.mins;
 546         sm2 = self.origin + self.maxs;
 547         for(e = world; (e = find(e, classname, "waypoint")); )
 548         {
 549                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 550                 {
 551                         waypoint_addlink(self, e);
 552                         waypoint_addlink(e, self);
 553                 }
 554                 else
 555                 {
 556                         ++relink_total;
 557                         if(!checkpvs(self.origin, e))
 558                         {
 559                                 ++relink_pvsculled;
 560                                 continue;
 561                         }
 562                         sv = e.origin;
 563                         sv_x = bound(sm1_x, sv_x, sm2_x);
 564                         sv_y = bound(sm1_y, sv_y, sm2_y);
 565                         sv_z = bound(sm1_z, sv_z, sm2_z);
 566                         ev = self.origin;
 567                         em1 = e.origin + e.mins;
 568                         em2 = e.origin + e.maxs;
 569                         ev_x = bound(em1_x, ev_x, em2_x);
 570                         ev_y = bound(em1_y, ev_y, em2_y);
 571                         ev_z = bound(em1_z, ev_z, em2_z);
 572                         dv = ev - sv;
 573                         dv_z = 0;
 574                         if (vlen(dv) >= 1050) // max search distance in XY
 575                         {
 576                                 ++relink_lengthculled;
 577                                 continue;
 578                         }
 579                         navigation_testtracewalk = 0;
 580                         if (!self.wpisbox)
 581                         {
 582                                 tracebox(sv - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, sv, FALSE, self);
 583                                 if (!trace_startsolid)
 584                                 {
 585                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 586                                         sv = trace_endpos + '0 0 1';
 587                                 }
 588                         }
 589                         if (!e.wpisbox)
 590                         {
 591                                 tracebox(ev - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, ev, FALSE, e);
 592                                 if (!trace_startsolid)
 593                                 {
 594                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 595                                         ev = trace_endpos + '0 0 1';
 596                                 }
 597                         }
 598                         //traceline(self.origin, e.origin, FALSE, world);
 599                         //if (trace_fraction == 1)
 600                         if (!self.wpisbox && tracewalk(self, sv, PL_MIN, PL_MAX, ev, MOVE_NOMONSTERS))
 601                                 waypoint_addlink(self, e);
 602                         else
 603                                 relink_walkculled += 0.5;
 604                         if (!e.wpisbox && tracewalk(e, ev, PL_MIN, PL_MAX, sv, MOVE_NOMONSTERS))
 605                                 waypoint_addlink(e, self);
 606                         else
 607                                 relink_walkculled += 0.5;
 608                 }
 609         }
 610         navigation_testtracewalk = 0;
 611         self.wplinked = TRUE;
 612 };
 613
 614 void waypoint_clearlinks(entity w)
 615 {
 616         // clear links to other waypoints
 617         float f, i;
 618         f = 10000000;
 619
 620         for(i=0;i<MAX_WAYPOINTS_LINKS;++i)
 621         {
 622                 w.(wlink[i]) = world;
 623                 w.(wpmincost[i]) = f;
 624         }
 625         w.wplinked = FALSE;
 626 };
 627
 628 // tell a spawnfunc_waypoint to relink
 629 void waypoint_schedulerelink(entity w)
 630 {
 631         if (w == world)
 632                 return;
 633
 634         // TODO: add some sort of visible box in edit mode for box waypoints
 635         if (cvar("g_waypointeditor"))
 636         {
 637                 local vector m1, m2;
 638                 m1 = w.mins;
 639                 m2 = w.maxs;
 640                 setmodel(w, "models/runematch/rune.mdl");
 641                 w.effects = EF_LOWPRECISION;
 642                 setsize(w, m1, m2);
 643                 if (w.wpflags & WAYPOINTFLAG_ITEM)
 644                         w.colormod = '1 0 0';
 645                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
 646                         w.colormod = '1 1 0';
 647                 else
 648                         w.colormod = '1 1 1';
 649         }
 650         else
 651                 w.model = "";
 652         w.wpisbox = vlen(w.size) > 0;
 653         w.enemy = world;
 654         if (!(w.wpflags & WAYPOINTFLAG_PERSONAL))
 655                 w.owner = world;
 656         if (!(w.wpflags & WAYPOINTFLAG_NORELINK))
 657                 waypoint_clearlinks(w);
 658         // schedule an actual relink on next frame
 659         w.think = waypoint_think;
 660         w.nextthink = time;
 661         w.effects = EF_LOWPRECISION;
 662 }
 663
 664 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 665 // them back to it as well
 666 // (suitable for spawnfunc_waypoint editor)
 667 entity waypoint_spawn(vector m1, vector m2, float f)
 668 {
 669         local entity w;
 670         local vector org;
 671         w = find(world, classname, "waypoint");
 672
 673         if not(f & WAYPOINTFLAG_PERSONAL)
 674         while (w)
 675         {
 676                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 677                 if (boxesoverlap(m1, m2, w.absmin, w.absmax))
 678                         return w;
 679                 w = find(w, classname, "waypoint");
 680         }
 681
 682         w = spawn();
 683         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 684         w.classname = "waypoint";
 685         w.wpflags = f;
 686         setorigin(w, (m1 + m2) * 0.5);
 687         setsize(w, m1 - w.origin, m2 - w.origin);
 688         if (vlen(w.size) > 0)
 689                 w.wpisbox = TRUE;
 690
 691         if(!(f & WAYPOINTFLAG_GENERATED))
 692         if(!w.wpisbox)
 693         {
 694                 traceline(w.origin + '0 0 1', w.origin + PL_MIN_z * '0 0 1' - '0 0 1', MOVE_NOMONSTERS, w);
 695                 if (trace_fraction < 1)
 696                         setorigin(w, trace_endpos - PL_MIN_z * '0 0 1');
 697
 698                 // check if the start position is stuck
 699                 tracebox(w.origin, PL_MIN + '-1 -1 -1', PL_MAX + '1 1 1', w.origin, MOVE_NOMONSTERS, w);
 700                 if (trace_startsolid)
 701                 {
 702                         org = w.origin + '0 0 26';
 703                         tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 704                         if(trace_startsolid)
 705                         {
 706                                 org = w.origin + '2 2 2';
 707                                 tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 708                                 if(trace_startsolid)
 709                                 {
 710                                         org = w.origin + '-2 -2 2';
 711                                         tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 712                                         if(trace_startsolid)
 713                                         {
 714                                                 org = w.origin + '-2 2 2';
 715                                                 tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 716                                                 if(trace_startsolid)
 717                                                 {
 718                                                         org = w.origin + '2 -2 2';
 719                                                         tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 720                                                         if(trace_startsolid)
 721                                                         {
 722                                                                 // this WP is in solid, refuse it
 723                                                                 dprint("Killed a waypoint that was stuck in solid at ", vtos(org), "\n");
 724                                                                 remove(w);
 725                                                                 return world;
 726                                                         }
 727                                                 }
 728                                         }
 729                                 }
 730                         }
 731                         setorigin(w, org * 0.05 + trace_endpos * 0.95); // don't trust the trace fully
 732                 }
 733
 734                 tracebox(w.origin, PL_MIN, PL_MAX, w.origin - '0 0 128', MOVE_WORLDONLY, w);
 735                 if(trace_startsolid)
 736                 {
 737                         dprint("Killed a waypoint that was stuck in solid ", vtos(w.origin), "\n");
 738                         remove(w);
 739                         return world;
 740                 }
 741                 if (!trace_inwater)
 742                 {
 743                         if(trace_fraction == 1)
 744                         {
 745                                 dprint("Killed a waypoint that was stuck in air at ", vtos(w.origin), "\n");
 746                                 remove(w);
 747                                 return world;
 748                         }
 749                         trace_endpos_z += 0.1; // don't trust the trace fully
 750 //                      dprint("Moved waypoint at ", vtos(w.origin), " by ", ftos(vlen(w.origin - trace_endpos)));
 751 //                      dprint(" direction: ", vtos((trace_endpos - w.origin)), "\n");
 752                         setorigin(w, trace_endpos);
 753                 }
 754         }
 755
 756         waypoint_clearlinks(w);
 757         //waypoint_schedulerelink(w);
 758
 759         if (cvar("g_waypointeditor"))
 760         {
 761                 m1 = w.mins;
 762                 m2 = w.maxs;
 763                 setmodel(w, "models/runematch/rune.mdl"); w.effects = EF_LOWPRECISION;
 764                 setsize(w, m1, m2);
 765                 if (w.wpflags & WAYPOINTFLAG_ITEM)
 766                         w.colormod = '1 0 0';
 767                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
 768                         w.colormod = '1 1 0';
 769                 else
 770                         w.colormod = '1 1 1';
 771         }
 772         else
 773                 w.model = "";
 774
 775         return w;
 776 };
 777
 778 // spawnfunc_waypoint map entity
 779 void spawnfunc_waypoint()
 780 {
 781         setorigin(self, self.origin);
 782         // schedule a relink after other waypoints have had a chance to spawn
 783         waypoint_clearlinks(self);
 784         //waypoint_schedulerelink(self);
 785 };
 786
 787 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 788 void waypoint_remove(entity e)
 789 {
 790         float i;
 791
 792         // tell all linked waypoints that they need to relink
 793         for(i=0;i<MAX_WAYPOINTS_LINKS;++i)
 794         {
 795                 if(e.wlink[i])
 796                         waypoint_schedulerelink(e.wlink[i]);
 797         }
 798
 799         // and now remove the spawnfunc_waypoint
 800         remove(e);
 801 };
 802
 803 // empties the map of waypoints
 804 void waypoint_removeall()
 805 {
 806         local entity head, next;
 807         head = findchain(classname, "waypoint");
 808         while (head)
 809         {
 810                 next = head.chain;
 811                 remove(head);
 812                 head = next;
 813         }
 814 };
 815
 816 // tell all waypoints to relink
 817 // (is this useful at all?)
 818 void waypoint_schedulerelinkall()
 819 {
 820         local entity head;
 821         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 822         head = findchain(classname, "waypoint");
 823         while (head)
 824         {
 825                 waypoint_schedulerelink(head);
 826                 head = head.chain;
 827         }
 828 };
 829
 830 // Load waypoint links from file
 831 float botframe_cachedwaypointlinks;
 832 float waypoint_load_links()
 833 {
 834         local string filename, s;
 835         local float file, tokens, c, found;
 836         local entity wp_from, wp_to;
 837         local vector wp_to_pos, wp_from_pos;
 838         filename = strcat("maps/", mapname);
 839         filename = strcat(filename, ".waypoints.cache");
 840         file = fopen(filename, FILE_READ);
 841
 842         if (file < 0)
 843         {
 844                 dprint("waypoint links load from ");
 845                 dprint(filename);
 846                 dprint(" failed\n");
 847                 return FALSE;
 848         }
 849
 850         while (1)
 851         {
 852                 s = fgets(file);
 853                 if (!s)
 854                         break;
 855
 856                 tokens = tokenizebyseparator(s, "*");
 857
 858                 if (tokens!=2)
 859                 {
 860                         // bad file format
 861                         fclose(file);
 862                         return FALSE;
 863                 }
 864
 865                 wp_from_pos     = stov(argv(0));
 866                 wp_to_pos       = stov(argv(1));
 867
 868                 // Search "from" waypoint
 869                 if(wp_from.origin!=wp_from_pos)
 870                 {
 871                         wp_from = findradius(wp_from_pos, 1);
 872                         found = FALSE;
 873                         while(wp_from)
 874                         {
 875                                 if(vlen(wp_from.origin-wp_from_pos)<1)
 876                                 if(wp_from.classname == "waypoint")
 877                                 {
 878                                         found = TRUE;
 879                                         break;
 880                                 }
 881                                 wp_from = wp_from.chain;
 882                         }
 883
 884                         if(!found)
 885                         {
 886                                 // can't find that waypoint
 887                                 fclose(file);
 888                                 return FALSE;
 889                         }
 890                 }
 891
 892                 // Search "to" waypoint
 893                 wp_to = findradius(wp_to_pos, 1);
 894                 found = FALSE;
 895                 while(wp_to)
 896                 {
 897                         if(vlen(wp_to.origin-wp_to_pos)<1)
 898                         if(wp_to.classname == "waypoint")
 899                         {
 900                                 found = TRUE;
 901                                 break;
 902                         }
 903                         wp_to = wp_to.chain;
 904                 }
 905
 906                 if(!found)
 907                 {
 908                         // can't find that waypoint
 909                         fclose(file);
 910                         return FALSE;
 911                 }
 912
 913                 ++c;
 914                 waypoint_addlink(wp_from, wp_to);
 915         }
 916
 917         fclose(file);
 918
 919         dprint("loaded ");
 920         dprint(ftos(c));
 921         dprint(" waypoint links from maps/");
 922         dprint(mapname);
 923         dprint(".waypoints.cache\n");
 924
 925         botframe_cachedwaypointlinks = TRUE;
 926         return TRUE;
 927 };
 928
 929 float botframe_loadedforcedlinks;
 930 void waypoint_load_links_hardwired()
 931 {
 932         local string filename, s;
 933         local float file, tokens, c, found;
 934         local entity wp_from, wp_to;
 935         local vector wp_to_pos, wp_from_pos;
 936         filename = strcat("maps/", mapname);
 937         filename = strcat(filename, ".waypoints.hardwired");
 938         file = fopen(filename, FILE_READ);
 939
 940         botframe_loadedforcedlinks = TRUE;
 941
 942         if (file < 0)
 943         {
 944                 dprint("waypoint links load from ");
 945                 dprint(filename);
 946                 dprint(" failed\n");
 947                 return;
 948         }
 949
 950         for (;;)
 951         {
 952                 s = fgets(file);
 953                 if (!s)
 954                         break;
 955
 956                 if(substring(s, 0, 2)=="//")
 957                         continue;
 958
 959                 if(substring(s, 0, 1)=="#")
 960                         continue;
 961
 962                 tokens = tokenizebyseparator(s, "*");
 963
 964                 if (tokens!=2)
 965                         continue;
 966
 967                 wp_from_pos     = stov(argv(0));
 968                 wp_to_pos       = stov(argv(1));
 969
 970                 // Search "from" waypoint
 971                 if(wp_from.origin!=wp_from_pos)
 972                 {
 973                         wp_from = findradius(wp_from_pos, 1);
 974                         found = FALSE;
 975                         while(wp_from)
 976                         {
 977                                 if(vlen(wp_from.origin-wp_from_pos)<1)
 978                                 if(wp_from.classname == "waypoint")
 979                                 {
 980                                         found = TRUE;
 981                                         break;
 982                                 }
 983                                 wp_from = wp_from.chain;
 984                         }
 985
 986                         if(!found)
 987                         {
 988                                 print(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 989                                 continue;
 990                         }
 991                 }
 992
 993                 // Search "to" waypoint
 994                 wp_to = findradius(wp_to_pos, 1);
 995                 found = FALSE;
 996                 while(wp_to)
 997                 {
 998                         if(vlen(wp_to.origin-wp_to_pos)<1)
 999                         if(wp_to.classname == "waypoint")
1000                         {
1001                                 found = TRUE;
1002                                 break;
1003                         }
1004                         wp_to = wp_to.chain;
1005                 }
1006
1007                 if(!found)
1008                 {
1009                         print(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
1010                         continue;
1011                 }
1012
1013                 ++c;
1014                 waypoint_addlink(wp_from, wp_to);
1015         }
1016
1017         fclose(file);
1018
1019         dprint("loaded ");
1020         dprint(ftos(c));
1021         dprint(" waypoint links from maps/");
1022         dprint(mapname);
1023         dprint(".waypoints.hardwired\n");
1024 };
1025
1026
1027 // Save all waypoint links to a file
1028 void waypoint_save_links()
1029 {
1030         local string filename, s;
1031         local float file, c, i;
1032         local entity w, link;
1033         filename = strcat("maps/", mapname);
1034         filename = strcat(filename, ".waypoints.cache");
1035         file = fopen(filename, FILE_WRITE);
1036         if (file < 0)
1037         {
1038                 print("waypoint links save to ");
1039                 print(filename);
1040                 print(" failed\n");
1041         }
1042         c = 0;
1043         w = findchain(classname, "waypoint");
1044         while (w)
1045         {
1046                 for(i=0;i<MAX_WAYPOINTS_LINKS;++i)
1047                 {
1048                         link = w.wlink[i];
1049
1050                         if(link==world)
1051                                 continue;
1052
1053                         s = strcat(vtos(w.origin), "*", vtos(link.origin), "\n");
1054                         fputs(file, s);
1055                         ++c;
1056                 }
1057                 w = w.chain;
1058         }
1059         fclose(file);
1060         botframe_cachedwaypointlinks = TRUE;
1061
1062         print("saved ");
1063         print(ftos(c));
1064         print(" waypoints links to maps/");
1065         print(mapname);
1066         print(".waypoints.cache\n");
1067 };
1068
1069 // save waypoints to gamedir/data/maps/mapname.waypoints
1070 void waypoint_saveall()
1071 {
1072         local string filename, s;
1073         local float file, c;
1074         local entity w;
1075         filename = strcat("maps/", mapname);
1076         filename = strcat(filename, ".waypoints");
1077         file = fopen(filename, FILE_WRITE);
1078         if (file >= 0)
1079         {
1080                 c = 0;
1081                 w = findchain(classname, "waypoint");
1082                 while (w)
1083                 {
1084                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
1085                         {
1086                                 s = strcat(vtos(w.origin + w.mins), "\n");
1087                                 s = strcat(s, vtos(w.origin + w.maxs));
1088                                 s = strcat(s, "\n");
1089                                 s = strcat(s, ftos(w.wpflags));
1090                                 s = strcat(s, "\n");
1091                                 fputs(file, s);
1092                                 c = c + 1;
1093                         }
1094                         w = w.chain;
1095                 }
1096                 fclose(file);
1097                 bprint("saved ");
1098                 bprint(ftos(c));
1099                 bprint(" waypoints to maps/");
1100                 bprint(mapname);
1101                 bprint(".waypoints\n");
1102         }
1103         else
1104         {
1105                 bprint("waypoint save to ");
1106                 bprint(filename);
1107                 bprint(" failed\n");
1108         }
1109         waypoint_save_links();
1110         botframe_loadedforcedlinks = FALSE;
1111 };
1112
1113 // load waypoints from file
1114 float waypoint_loadall()
1115 {
1116         local string filename, s;
1117         local float file, cwp, cwb, fl;
1118         local vector m1, m2;
1119         cwp = 0;
1120         cwb = 0;
1121         filename = strcat("maps/", mapname);
1122         filename = strcat(filename, ".waypoints");
1123         file = fopen(filename, FILE_READ);
1124         if (file >= 0)
1125         {
1126                 while (1)
1127                 {
1128                         s = fgets(file);
1129                         if (!s)
1130                                 break;
1131                         m1 = stov(s);
1132                         s = fgets(file);
1133                         if (!s)
1134                                 break;
1135                         m2 = stov(s);
1136                         s = fgets(file);
1137                         if (!s)
1138                                 break;
1139                         fl = stof(s);
1140                         waypoint_spawn(m1, m2, fl);
1141                         if (m1 == m2)
1142                                 cwp = cwp + 1;
1143                         else
1144                                 cwb = cwb + 1;
1145                 }
1146                 fclose(file);
1147                 dprint("loaded ");
1148                 dprint(ftos(cwp));
1149                 dprint(" waypoints and ");
1150                 dprint(ftos(cwb));
1151                 dprint(" wayboxes from maps/");
1152                 dprint(mapname);
1153                 dprint(".waypoints\n");
1154         }
1155         else
1156         {
1157                 dprint("waypoint load from ");
1158                 dprint(filename);
1159                 dprint(" failed\n");
1160         }
1161         return cwp + cwb;
1162 };
1163
1164 void waypoint_spawnforitem(entity e)
1165 {
1166         local entity w;
1167         local vector org;
1168
1169         if(!bot_waypoints_for_items)
1170                 return;
1171
1172         // Center of entity
1173         org = (e.absmax + e.absmin) * 0.5;
1174
1175         // Fix the waypoint altitude if necessary
1176         traceline(org, org + '0 0 -65535', TRUE, e);
1177         if(
1178                 org_z - trace_endpos_z > PL_MAX_z - PL_MIN_z + 10 // If middle of entiy is above player heigth
1179                 || org_z - trace_endpos_z < (PL_MAX_z - PL_MIN_z) * 0.5 // or below half player height
1180         )
1181                 org_z = trace_endpos_z + PL_MAX_z - PL_MIN_z;
1182
1183         // TODO: Cleaner solution
1184         if(e.classname!="item_flag_team")
1185                 e.nearestwaypointtimeout = time + 1000000000;
1186
1187         // don't spawn an item spawnfunc_waypoint if it already exists
1188         w = findchain(classname, "waypoint");
1189         while (w)
1190         {
1191                 if (w.wpisbox)
1192                 {
1193                         if (boxesoverlap(org, org, w.absmin, w.absmax))
1194                         {
1195                                 e.nearestwaypoint = w;
1196                                 return;
1197                         }
1198                 }
1199                 else
1200                 {
1201                         if (vlen(w.origin - org) < 16)
1202                         {
1203                                 e.nearestwaypoint = w;
1204                                 return;
1205                         }
1206                 }
1207                 w = w.chain;
1208         }
1209         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1210 };
1211
1212 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
1213 {
1214         local entity w;
1215         local entity dw;
1216         w = waypoint_spawn(e.absmin, e.absmax, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
1217         dw = waypoint_spawn(destination, destination, WAYPOINTFLAG_GENERATED);
1218         // one way link to the destination
1219         w.(wlink[0]) = dw;
1220         w.(wpmincost[0]) = timetaken; // this is just for jump pads
1221         // the teleporter's nearest spawnfunc_waypoint is this one
1222         // (teleporters are not goals, so this is probably useless)
1223         e.nearestwaypoint = w;
1224         e.nearestwaypointtimeout = time + 1000000000;
1225 };
1226
1227 entity waypoint_spawnpersonal(vector position)
1228 {
1229         entity w;
1230
1231         // drop the waypoint to a proper location:
1232         //   first move it up by a player height
1233         //   then move it down to hit the floor with player bbox size
1234         traceline(position, position + '0 0 1' * (PL_MAX_z - PL_MIN_z), MOVE_NOMONSTERS, world);
1235         tracebox(trace_endpos, PL_MIN, PL_MAX, trace_endpos + '0 0 -1024', MOVE_NOMONSTERS, world);
1236         if(trace_fraction < 1)
1237                 position = trace_endpos;
1238
1239         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1240         w.nearestwaypoint = world;
1241         w.nearestwaypointtimeout = 0;
1242         w.owner = self;
1243
1244         waypoint_schedulerelink(w);
1245
1246         return w;
1247 };
1248
1249 /////////////////////////////////////////////////////////////////////////////
1250 // goal stack
1251 /////////////////////////////////////////////////////////////////////////////
1252
1253 // completely empty the goal stack, used when deciding where to go
1254 void navigation_clearroute()
1255 {
1256         //print("bot ", etos(self), " clear\n");
1257         self.navigation_hasgoals = FALSE;
1258         self.goalcurrent = world;
1259         self.goalstack01 = world;
1260         self.goalstack02 = world;
1261         self.goalstack03 = world;
1262         self.goalstack04 = world;
1263         self.goalstack05 = world;
1264         self.goalstack06 = world;
1265         self.goalstack07 = world;
1266         self.goalstack08 = world;
1267         self.goalstack09 = world;
1268         self.goalstack10 = world;
1269         self.goalstack11 = world;
1270         self.goalstack12 = world;
1271         self.goalstack13 = world;
1272         self.goalstack14 = world;
1273         self.goalstack15 = world;
1274         self.goalstack16 = world;
1275         self.goalstack17 = world;
1276         self.goalstack18 = world;
1277         self.goalstack19 = world;
1278         self.goalstack20 = world;
1279         self.goalstack21 = world;
1280         self.goalstack22 = world;
1281         self.goalstack23 = world;
1282         self.goalstack24 = world;
1283         self.goalstack25 = world;
1284         self.goalstack26 = world;
1285         self.goalstack27 = world;
1286         self.goalstack28 = world;
1287         self.goalstack29 = world;
1288         self.goalstack30 = world;
1289         self.goalstack31 = world;
1290 };
1291
1292 // add a new goal at the beginning of the stack
1293 // (in other words: add a new prerequisite before going to the later goals)
1294 void navigation_pushroute(entity e)
1295 {
1296         //print("bot ", etos(self), " push ", etos(e), "\n");
1297         self.goalstack31 = self.goalstack30;
1298         self.goalstack30 = self.goalstack29;
1299         self.goalstack29 = self.goalstack28;
1300         self.goalstack28 = self.goalstack27;
1301         self.goalstack27 = self.goalstack26;
1302         self.goalstack26 = self.goalstack25;
1303         self.goalstack25 = self.goalstack24;
1304         self.goalstack24 = self.goalstack23;
1305         self.goalstack23 = self.goalstack22;
1306         self.goalstack22 = self.goalstack21;
1307         self.goalstack21 = self.goalstack20;
1308         self.goalstack20 = self.goalstack19;
1309         self.goalstack19 = self.goalstack18;
1310         self.goalstack18 = self.goalstack17;
1311         self.goalstack17 = self.goalstack16;
1312         self.goalstack16 = self.goalstack15;
1313         self.goalstack15 = self.goalstack14;
1314         self.goalstack14 = self.goalstack13;
1315         self.goalstack13 = self.goalstack12;
1316         self.goalstack12 = self.goalstack11;
1317         self.goalstack11 = self.goalstack10;
1318         self.goalstack10 = self.goalstack09;
1319         self.goalstack09 = self.goalstack08;
1320         self.goalstack08 = self.goalstack07;
1321         self.goalstack07 = self.goalstack06;
1322         self.goalstack06 = self.goalstack05;
1323         self.goalstack05 = self.goalstack04;
1324         self.goalstack04 = self.goalstack03;
1325         self.goalstack03 = self.goalstack02;
1326         self.goalstack02 = self.goalstack01;
1327         self.goalstack01 = self.goalcurrent;
1328         self.goalcurrent = e;
1329 };
1330
1331 // remove first goal from stack
1332 // (in other words: remove a prerequisite for reaching the later goals)
1333 // (used when a spawnfunc_waypoint is reached)
1334 void navigation_poproute()
1335 {
1336         //print("bot ", etos(self), " pop\n");
1337         self.goalcurrent = self.goalstack01;
1338         self.goalstack01 = self.goalstack02;
1339         self.goalstack02 = self.goalstack03;
1340         self.goalstack03 = self.goalstack04;
1341         self.goalstack04 = self.goalstack05;
1342         self.goalstack05 = self.goalstack06;
1343         self.goalstack06 = self.goalstack07;
1344         self.goalstack07 = self.goalstack08;
1345         self.goalstack08 = self.goalstack09;
1346         self.goalstack09 = self.goalstack10;
1347         self.goalstack10 = self.goalstack11;
1348         self.goalstack11 = self.goalstack12;
1349         self.goalstack12 = self.goalstack13;
1350         self.goalstack13 = self.goalstack14;
1351         self.goalstack14 = self.goalstack15;
1352         self.goalstack15 = self.goalstack16;
1353         self.goalstack16 = self.goalstack17;
1354         self.goalstack17 = self.goalstack18;
1355         self.goalstack18 = self.goalstack19;
1356         self.goalstack19 = self.goalstack20;
1357         self.goalstack20 = self.goalstack21;
1358         self.goalstack21 = self.goalstack22;
1359         self.goalstack22 = self.goalstack23;
1360         self.goalstack23 = self.goalstack24;
1361         self.goalstack24 = self.goalstack25;
1362         self.goalstack25 = self.goalstack26;
1363         self.goalstack26 = self.goalstack27;
1364         self.goalstack27 = self.goalstack28;
1365         self.goalstack28 = self.goalstack29;
1366         self.goalstack29 = self.goalstack30;
1367         self.goalstack30 = self.goalstack31;
1368         self.goalstack31 = world;
1369 };
1370
1371 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
1372 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
1373 {
1374         local entity waylist, w, best;
1375         local float dist, bestdist;
1376         local vector v, org, pm1, pm2;
1377         pm1 = ent.origin + PL_MIN;
1378         pm2 = ent.origin + PL_MAX;
1379         waylist = findchain(classname, "waypoint");
1380
1381         // do two scans, because box test is cheaper
1382         w = waylist;
1383         while (w)
1384         {
1385                 // if object is touching spawnfunc_waypoint
1386                 if(w != ent)
1387                         if (boxesoverlap(pm1, pm2, w.absmin, w.absmax))
1388                                 return w;
1389                 w = w.chain;
1390         }
1391
1392         org = ent.origin + (ent.mins_z - PL_MIN_z) * '0 0 1';
1393         if(ent.tag_entity)
1394                 org = org + ent.tag_entity.origin;
1395         if (navigation_testtracewalk)
1396                 te_plasmaburn(org);
1397
1398         best = world;
1399         bestdist = 1050;
1400
1401         // box check failed, try walk
1402         w = waylist;
1403         while (w)
1404         {
1405                 // if object can walk from spawnfunc_waypoint
1406                 if(w != ent)
1407                 {
1408                         if (w.wpisbox)
1409                         {
1410                                 local vector wm1, wm2;
1411                                 wm1 = w.origin + w.mins;
1412                                 wm2 = w.origin + w.maxs;
1413                                 v_x = bound(wm1_x, org_x, wm2_x);
1414                                 v_y = bound(wm1_y, org_y, wm2_y);
1415                                 v_z = bound(wm1_z, org_z, wm2_z);
1416                         }
1417                         else
1418                                 v = w.origin;
1419                         dist = vlen(v - org);
1420                         if (bestdist > dist)
1421                         {
1422                                 traceline(v, org, TRUE, ent);
1423                                 if (trace_fraction == 1)
1424                                 {
1425                                         if (walkfromwp)
1426                                         {
1427                                                 //print("^1can I reach ", vtos(org), " from ", vtos(v), "?\n");
1428                                                 if (tracewalk(ent, v, PL_MIN, PL_MAX, org, bot_navigation_movemode))
1429                                                 {
1430                                                         bestdist = dist;
1431                                                         best = w;
1432                                                 }
1433                                         }
1434                                         else
1435                                         {
1436                                                 if (tracewalk(ent, org, PL_MIN, PL_MAX, v, bot_navigation_movemode))
1437                                                 {
1438                                                         bestdist = dist;
1439                                                         best = w;
1440                                                 }
1441                                         }
1442                                 }
1443                         }
1444                 }
1445                 w = w.chain;
1446         }
1447         return best;
1448 }
1449
1450 // finds the waypoints near the bot initiating a navigation query
1451 float navigation_markroutes_nearestwaypoints(entity waylist, float maxdist)
1452 {
1453         local entity head;
1454         local vector v, m1, m2, diff;
1455         local float c;
1456 //      navigation_testtracewalk = TRUE;
1457         c = 0;
1458         head = waylist;
1459         while (head)
1460         {
1461                 if (!head.wpconsidered)
1462                 {
1463                         if (head.wpisbox)
1464                         {
1465                                 m1 = head.origin + head.mins;
1466                                 m2 = head.origin + head.maxs;
1467                                 v = self.origin;
1468                                 v_x = bound(m1_x, v_x, m2_x);
1469                                 v_y = bound(m1_y, v_y, m2_y);
1470                                 v_z = bound(m1_z, v_z, m2_z);
1471                         }
1472                         else
1473                                 v = head.origin;
1474                         diff = v - self.origin;
1475                         diff_z = max(0, diff_z);
1476                         if (vlen(diff) < maxdist)
1477                         {
1478                                 head.wpconsidered = TRUE;
1479                                 if (tracewalk(self, self.origin, self.mins, self.maxs, v, bot_navigation_movemode))
1480                                 {
1481                                         head.wpnearestpoint = v;
1482                                         head.wpcost = vlen(v - self.origin) + head.dmg;
1483                                         head.wpfire = 1;
1484                                         head.enemy = world;
1485                                         c = c + 1;
1486                                 }
1487                         }
1488                 }
1489                 head = head.chain;
1490         }
1491         //navigation_testtracewalk = FALSE;
1492         return c;
1493 }
1494
1495 // updates a path link if a spawnfunc_waypoint link is better than the current one
1496 void navigation_markroutes_checkwaypoint(entity w, entity w2, float cost2, vector p)
1497 {
1498         local vector m1;
1499         local vector m2;
1500         local vector v;
1501         if (w2.wpisbox)
1502         {
1503                 m1 = w2.absmin;
1504                 m2 = w2.absmax;
1505                 v_x = bound(m1_x, p_x, m2_x);
1506                 v_y = bound(m1_y, p_y, m2_y);
1507                 v_z = bound(m1_z, p_z, m2_z);
1508         }
1509         else
1510                 v = w2.origin;
1511         cost2 = cost2 + vlen(v);
1512         if (w2.wpcost > cost2)
1513         {
1514                 w2.wpcost = cost2;
1515                 w2.enemy = w;
1516                 w2.wpfire = 1;
1517                 w2.wpnearestpoint = v;
1518         }
1519 };
1520
1521 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
1522 void navigation_markroutes()
1523 {
1524         local entity w, wp, waylist;
1525         local float searching, cost, cost2;
1526         local vector p;
1527         w = waylist = findchain(classname, "waypoint");
1528         while (w)
1529         {
1530                 w.wpconsidered = FALSE;
1531                 w.wpnearestpoint = '0 0 0';
1532                 w.wpcost = 10000000;
1533                 w.wpfire = 0;
1534                 w.enemy = world;
1535                 w = w.chain;
1536         }
1537
1538         // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
1539         // as this search is expensive we will use lower values if the bot is on the air
1540         local float i, increment, maxdistance;
1541         if(self.flags & FL_ONGROUND)
1542         {
1543                 increment = 750;
1544                 maxdistance = 50000;
1545         }
1546         else
1547         {
1548                 increment = 500;
1549                 maxdistance = 1500;
1550         }
1551
1552         for(i=increment;!navigation_markroutes_nearestwaypoints(waylist, i)&&i<maxdistance;i+=increment);
1553
1554         searching = TRUE;
1555         while (searching)
1556         {
1557                 searching = FALSE;
1558                 w = waylist;
1559                 while (w)
1560                 {
1561                         if (w.wpfire)
1562                         {
1563                                 searching = TRUE;
1564                                 w.wpfire = 0;
1565                                 cost = w.wpcost;
1566                                 p = w.wpnearestpoint;
1567
1568                                 for(i=0;i<MAX_WAYPOINTS_LINKS;++i)
1569                                 {
1570                                         wp = w.wlink[i];
1571
1572                                         if(wp)
1573                                         {
1574                                                 cost2 = cost + wp.dmg;
1575                                                 if (wp.wpcost > cost2 + wp.wpmincost[i])
1576                                                         navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1577                                         }
1578                                         // break
1579                                 }
1580                         }
1581                         w = w.chain;
1582                 }
1583         }
1584 };
1585
1586 void navigation_bestgoals_reset()
1587 {
1588         local float i;
1589
1590         bestgoalswindex = 0;
1591         bestgoalsrindex = 0;
1592
1593         for(i=0;i>MAX_BESTGOALS-1;++i)
1594         {
1595                 navigation_bestgoals[i] = world;
1596         }
1597 }
1598
1599 void navigation_add_bestgoal(entity goal)
1600 {
1601         if(bestgoalsrindex>0)
1602         {
1603                 ++bestgoalsrindex;
1604
1605                 if(bestgoalsrindex==MAX_BESTGOALS)
1606                         bestgoalsrindex = 0;
1607         }
1608
1609         if(bestgoalswindex==MAX_BESTGOALS)
1610         {
1611                 bestgoalswindex=0;
1612                 if(bestgoalsrindex==0)
1613                         bestgoalsrindex=1;
1614         }
1615
1616         navigation_bestgoals[bestgoalswindex] = goal;
1617
1618         ++bestgoalswindex;
1619 }
1620
1621 entity navigation_get_bestgoal()
1622 {
1623         local entity ent;
1624
1625         ent = navigation_bestgoals[bestgoalsrindex];
1626         navigation_bestgoals[bestgoalsrindex] = world;
1627
1628         ++bestgoalsrindex;
1629
1630         if(bestgoalsrindex==MAX_BESTGOALS)
1631                 bestgoalsrindex = 0;
1632
1633         return ent;
1634 }
1635
1636 // fields required for jetpack navigation
1637 .entity navigation_jetpack_goal;
1638 .vector navigation_jetpack_point;
1639
1640 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
1641 .void() havocbot_role;
1642 void() havocbot_role_ctf_offense;
1643 void navigation_routerating(entity e, float f, float rangebias)
1644 {
1645         if (!e)
1646                 return;
1647
1648         // Evaluate path using jetpack
1649         if(g_jetpack)
1650         if(self.items & IT_JETPACK)
1651         if(cvar("bot_ai_navigation_jetpack"))
1652         if(vlen(self.origin - e.origin) > cvar("bot_ai_navigation_jetpack_mindistance"))
1653         {
1654                 vector pointa, pointb;
1655
1656         //      dprint("jetpack ai: evaluating path for ", e.classname,"\n");
1657
1658                 // Point A
1659                 traceline(self.origin, self.origin + '0 0 65535', MOVE_NORMAL, self);
1660                 pointa = trace_endpos - '0 0 1';
1661
1662                 // Point B
1663                 traceline(e.origin, e.origin + '0 0 65535', MOVE_NORMAL, e);
1664                 pointb = trace_endpos - '0 0 1';
1665
1666                 // Can I see these two points from the sky?
1667                 traceline(pointa, pointb, MOVE_NORMAL, self);
1668
1669                 if(trace_fraction==1)
1670                 {
1671                 //      dprint("jetpack ai: can bridge these two points\n");
1672
1673                         // Lower the altitude of these points as much as possible
1674                         local float zdistance, xydistance, cost, t, fuel;
1675                         local vector down, npa, npb;
1676
1677                         down = '0 0 -1' * (PL_MAX_z - PL_MIN_z) * 10;
1678
1679                         do{
1680                                 npa = pointa + down;
1681                                 npb = pointb + down;
1682
1683                                 if(npa_z<=self.absmax_z)
1684                                         break;
1685
1686                                 if(npb_z<=e.absmax_z)
1687                                         break;
1688
1689                                 traceline(npa, npb, MOVE_NORMAL, self);
1690                                 if(trace_fraction==1)
1691                                 {
1692                                         pointa = npa;
1693                                         pointb = npb;
1694                                 }
1695                         }
1696                         while(trace_fraction == 1);
1697
1698
1699                         // Rough estimation of fuel consumption
1700                         // (ignores acceleration and current xyz velocity)
1701                         xydistance = vlen(pointa - pointb);
1702                         zdistance = fabs(pointa_z - self.origin_z);
1703
1704                         t = zdistance / cvar("g_jetpack_maxspeed_up");
1705                         t += xydistance / cvar("g_jetpack_maxspeed_side");
1706                         fuel = t * cvar("g_jetpack_fuel") * 0.8;
1707
1708                 //      dprint("jetpack ai: required fuel ", ftos(fuel), " self.ammo_fuel ", ftos(self.ammo_fuel),"\n");
1709
1710                         // enough fuel ?
1711                         if(self.ammo_fuel>fuel)
1712                         {
1713                                 // Estimate cost
1714                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
1715                                 //  - between air and ground speeds)
1716
1717                                 cost = xydistance / (cvar("g_jetpack_maxspeed_side")/cvar("sv_maxspeed"));
1718                                 cost += zdistance / (cvar("g_jetpack_maxspeed_up")/cvar("sv_maxspeed"));
1719                                 cost *= 1.5;
1720
1721                                 // Compare against other goals
1722                                 f = f * rangebias / (rangebias + cost);
1723
1724                                 if (navigation_bestrating < f)
1725                                 {
1726                         //              dprint("jetpack path: added goal", e.classname, " (with rating ", ftos(f), ")\n");
1727                                         navigation_bestrating = f;
1728                                         navigation_add_bestgoal(e);
1729                                         self.navigation_jetpack_goal = e;
1730                                         self.navigation_jetpack_point = pointb;
1731                                 }
1732                                 return;
1733                         }
1734                 }
1735         }
1736
1737         //te_wizspike(e.origin);
1738         //bprint(etos(e));
1739         //bprint("\n");
1740         // update the cached spawnfunc_waypoint link on a dynamic item entity
1741         if (time > e.nearestwaypointtimeout)
1742         {
1743                 e.nearestwaypoint = navigation_findnearestwaypoint(e, TRUE);
1744
1745                 // TODO: Cleaner solution, probably handling this timeout from ctf.qc
1746                 if(e.classname=="item_flag_team")
1747                         e.nearestwaypointtimeout = time + 2;
1748                 else
1749                         e.nearestwaypointtimeout = time + random() * 3 + 5;
1750         }
1751
1752         //dprint("-- checking ", e.classname, " (with cost ", ftos(e.nearestwaypoint.wpcost), ")\n");
1753         if (e.nearestwaypoint)
1754         if (e.nearestwaypoint.wpcost < 10000000)
1755         {
1756                 //te_wizspike(e.nearestwaypoint.wpnearestpoint);
1757         //      dprint(e.classname, " ", ftos(f), "/(1+", ftos((e.nearestwaypoint.wpcost + vlen(e.origin - e.nearestwaypoint.wpnearestpoint))), "/", ftos(rangebias), ") = ");
1758                 f = f * rangebias / (rangebias + (e.nearestwaypoint.wpcost + vlen(e.origin - e.nearestwaypoint.wpnearestpoint)));
1759                 //if (self.havocbot_role == havocbot_role_ctf_offense)
1760                 //dprint("considering ", e.classname, " (with rating ", ftos(f), ")\n");
1761                 //dprint(ftos(f));
1762                 if (navigation_bestrating < f)
1763                 {
1764                 //      dprint("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")\n");
1765                         navigation_bestrating = f;
1766                         navigation_add_bestgoal(e);
1767                 }
1768         }
1769         //dprint("\n");
1770 };
1771
1772 // adds an item to the the goal stack with the path to a given item
1773 float navigation_routetogoal(entity e, vector startposition)
1774 {
1775         self.goalentity = e;
1776
1777         // if there is no goal, just exit
1778         if (!e)
1779                 return FALSE;
1780
1781         self.navigation_hasgoals = TRUE;
1782
1783         // put the entity on the goal stack
1784         navigation_pushroute(e);
1785
1786         if(g_jetpack)
1787         if(e==self.navigation_jetpack_goal)
1788                 return TRUE;
1789
1790         // if it can reach the goal there is nothing more to do
1791         if (tracewalk(self, startposition, PL_MIN, PL_MAX, e.origin, bot_navigation_movemode))
1792                 return TRUE;
1793
1794         // see if there are waypoints describing a path to the item
1795         e = e.nearestwaypoint;
1796         if(e == world)
1797                 return FALSE;
1798
1799         for (;;)
1800         {
1801                 // add the spawnfunc_waypoint to the path
1802                 navigation_pushroute(e);
1803                 e = e.enemy;
1804
1805                 if(e==world)
1806                         break;
1807         }
1808
1809         return FALSE;
1810 };
1811
1812 void navigation_routetogoals()
1813 {
1814         entity g1, g2;
1815
1816         navigation_clearroute();
1817
1818         g1 = navigation_get_bestgoal();
1819         for(;;)
1820         {
1821                 if(g2==world)
1822                         g2 = navigation_get_bestgoal();
1823
1824                 if(g2==world)
1825                 {
1826                         navigation_routetogoal(g1, self.origin);
1827                         return;
1828                 }
1829
1830                 if(navigation_routetogoal(g1, g2.origin))
1831                 {
1832                         g1 = g2;
1833                         g2 = world;
1834                         continue;
1835                 }
1836
1837                 navigation_clearroute();
1838                 g1 = g2;
1839                 g2 = world;
1840         }
1841 }
1842
1843 // removes any currently touching waypoints from the goal stack
1844 // (this is how bots detect if they have reached a goal)
1845 .float lastteleporttime;
1846
1847 void navigation_poptouchedgoals()
1848 {
1849         local vector org, m1, m2;
1850         org = self.origin;
1851         m1 = org + self.mins;
1852         m2 = org + self.maxs;
1853
1854         if(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1855         {
1856                 if(self.lastteleporttime>0)
1857                 if(time-self.lastteleporttime<0.15)
1858                 {
1859                         navigation_poproute();
1860                         return;
1861                 }
1862         }
1863
1864         // Loose goal touching check when running
1865         if(self.aistatus & AI_STATUS_RUNNING)
1866         if(self.goalcurrent.classname=="waypoint")
1867         {
1868                 if(vlen(self.origin - self.goalcurrent.origin)<150)
1869                 {
1870                         traceline(self.origin + self.view_ofs , self.goalcurrent.origin, TRUE, world);
1871                         if(trace_fraction==1)
1872                         {
1873                                 // Detect personal waypoints
1874                                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1875                                 if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
1876                                 {
1877                                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1878                                         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1879                                 }
1880
1881                                 navigation_poproute();
1882                         }
1883                 }
1884         }
1885
1886         while (self.goalcurrent && boxesoverlap(m1, m2, self.goalcurrent.absmin, self.goalcurrent.absmax))
1887         {
1888                 // Detect personal waypoints
1889                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1890                 if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
1891                 {
1892                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1893                         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1894                 }
1895
1896                 navigation_poproute();
1897         }
1898 }
1899
1900 // begin a goal selection session (queries spawnfunc_waypoint network)
1901 void navigation_goalrating_start()
1902 {
1903         self.navigation_jetpack_goal = world;
1904         navigation_bestrating = -1;
1905         self.navigation_hasgoals = FALSE;
1906         navigation_bestgoals_reset();
1907         navigation_markroutes();
1908 };
1909
1910 // ends a goal selection session (updates goal stack to the best goal)
1911 void navigation_goalrating_end()
1912 {
1913         navigation_routetogoals();
1914 //      dprint("best goal ", self.goalcurrent.classname , "\n");
1915
1916         // Hack: if it can't walk to any goal just move blindly to the first visible waypoint
1917         if not (self.navigation_hasgoals)
1918         {
1919                 dprint(self.netname, " can't walk to any goal, going to a near waypoint\n");
1920
1921                 entity head;
1922
1923                 RandomSelection_Init();
1924                 head = findradius(self.origin,1000);
1925                 while(head)
1926                 {
1927                         if(head.classname=="waypoint")
1928                         if(!(head.wpflags & WAYPOINTFLAG_GENERATED))
1929                         if(vlen(self.origin-head.origin)>100)
1930                         if(checkpvs(self.view_ofs,head))
1931                                 RandomSelection_Add(head, 0, string_null, 1 + (vlen(self.origin-head.origin)<500), 0);
1932                         head = head.chain;
1933                 }
1934                 if(RandomSelection_chosen_ent)
1935                         navigation_routetogoal(RandomSelection_chosen_ent, self.origin);
1936
1937                 self.navigation_hasgoals = FALSE; // Reset this value
1938         }
1939 };
1940
1941
1942 //////////////////////////////////////////////////////////////////////////////
1943 // general bot functions
1944 //////////////////////////////////////////////////////////////////////////////
1945
1946 .float isbot; // true if this client is actually a bot
1947
1948 float skill;
1949 entity bot_list;
1950 .entity nextbot;
1951 .string netname_freeme;
1952 .string playermodel_freeme;
1953 .string playerskin_freeme;
1954
1955 float sv_maxspeed;
1956 .float createdtime;
1957
1958 .float bot_preferredcolors;
1959
1960 .float bot_attack;
1961 .float bot_dodge;
1962 .float bot_dodgerating;
1963
1964 //.float bot_painintensity;
1965 .float bot_firetimer;
1966 //.float bot_oldhealth;
1967 .void() bot_ai;
1968
1969 .entity bot_aimtarg;
1970 .float bot_aimlatency;
1971 .vector bot_aimselforigin;
1972 .vector bot_aimselfvelocity;
1973 .vector bot_aimtargorigin;
1974 .vector bot_aimtargvelocity;
1975
1976 .float bot_pickup;
1977 .float(entity player, entity item) bot_pickupevalfunc;
1978 .float bot_pickupbasevalue;
1979 .float bot_canfire;
1980 .float bot_strategytime;
1981
1982 // used for aiming currently
1983 // FIXME: make the weapon code use these and then replace the calculations here with a call to the weapon code
1984 vector shotorg;
1985 vector shotdir;
1986
1987 .float bot_forced_team;
1988 .float bot_config_loaded;
1989
1990 void bot_setnameandstuff()
1991 {
1992         string readfile, s;
1993         float file, tokens, prio;
1994         entity p;
1995
1996         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
1997         string name, prefix, suffix;
1998
1999         if(cvar("g_campaign"))
2000         {
2001                 prefix = "";
2002                 suffix = "";
2003         }
2004         else
2005         {
2006                 prefix = cvar_string("bot_prefix");
2007                 suffix = cvar_string("bot_suffix");
2008         }
2009
2010         file = fopen(cvar_string("bot_config_file"), FILE_READ);
2011
2012         if(file < 0)
2013                 print(strcat("Error: Can not open the bot configuration file '",cvar_string("bot_config_file"),"'\n"));
2014         else
2015         {
2016                 RandomSelection_Init();
2017                 for(;;)
2018                 {
2019                         readfile = fgets(file);
2020                         if(!readfile)
2021                                 break;
2022                         if(substring(readfile, 0, 2) == "//")
2023                                 continue;
2024                         if(substring(readfile, 0, 1) == "#")
2025                                 continue;
2026                         tokens = tokenizebyseparator(readfile, "\t");
2027                         s = argv(0);
2028                         prio = 1;
2029                         FOR_EACH_CLIENT(p)
2030                         {
2031                                 if(strcat(prefix, s, suffix) == p.netname)
2032                                 {
2033                                         prio = 0;
2034                                         break;
2035                                 }
2036                         }
2037                         RandomSelection_Add(world, 0, readfile, 1, prio);
2038                 }
2039                 readfile = RandomSelection_chosen_string;
2040                 fclose(file);
2041         }
2042
2043         tokens = tokenizebyseparator(readfile, "\t");
2044         if(argv(0) != "") bot_name = argv(0);
2045         else bot_name = "Bot";
2046
2047         if(argv(1) != "") bot_model = argv(1);
2048         else bot_model = "marine";
2049
2050         if(argv(2) != "") bot_skin = argv(2);
2051         else bot_skin = "0";
2052
2053         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
2054         else bot_shirt = ftos(floor(random() * 15));
2055
2056         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
2057         else bot_pants = ftos(floor(random() * 15));
2058
2059         self.bot_forced_team = stof(argv(5));
2060         self.bot_config_loaded = TRUE;
2061
2062         // this is really only a default, JoinBestTeam is called later
2063         setcolor(self, stof(bot_shirt) * 16 + stof(bot_pants));
2064         self.bot_preferredcolors = self.clientcolors;
2065
2066         // pick the name
2067         if (cvar("bot_usemodelnames"))
2068                 name = bot_model;
2069         else
2070                 name = bot_name;
2071
2072         // pick the model and skin
2073         if(substring(bot_model, -4, 1) != ".")
2074                 bot_model = strcat(bot_model, ".zym");
2075         self.playermodel = self.playermodel_freeme = strzone(strcat("models/player/", bot_model));
2076         self.playerskin = self.playerskin_freeme = strzone(bot_skin);
2077
2078         self.netname = self.netname_freeme = strzone(strcat(prefix, name, suffix));
2079 };
2080
2081 float bot_custom_weapon;
2082 float bot_distance_far;
2083 float bot_distance_close;
2084
2085 float bot_weapons_far[WEP_LAST];
2086 float bot_weapons_mid[WEP_LAST];
2087 float bot_weapons_close[WEP_LAST];
2088
2089 void bot_custom_weapon_priority_setup()
2090 {
2091         local float tokens, i, c, w;
2092
2093         bot_custom_weapon = FALSE;
2094
2095         if(     cvar_string("bot_ai_custom_weapon_priority_far") == "" ||
2096                 cvar_string("bot_ai_custom_weapon_priority_mid") == "" ||
2097                 cvar_string("bot_ai_custom_weapon_priority_close") == "" ||
2098                 cvar_string("bot_ai_custom_weapon_priority_distances") == ""
2099         )
2100                 return;
2101
2102         // Parse distances
2103         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_distances")," ");
2104
2105         if (tokens!=2)
2106                 return;
2107
2108         bot_distance_far = stof(argv(0));
2109         bot_distance_close = stof(argv(1));
2110
2111         if(bot_distance_far < bot_distance_close){
2112                 bot_distance_far = stof(argv(1));
2113                 bot_distance_close = stof(argv(0));
2114         }
2115
2116         // Initialize list of weapons
2117         bot_weapons_far[0] = -1;
2118         bot_weapons_mid[0] = -1;
2119         bot_weapons_close[0] = -1;
2120
2121         // Parse far distance weapon priorities
2122         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_far")," ");
2123
2124         c = 0;
2125         for(i=0; i < tokens && c < WEP_COUNT; ++i){
2126                 w = stof(argv(i));
2127                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
2128                         bot_weapons_far[c] = w;
2129                         ++c;
2130                 }
2131         }
2132         if(c < WEP_COUNT)
2133                 bot_weapons_far[c] = -1;
2134
2135         // Parse mid distance weapon priorities
2136         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_mid")," ");
2137
2138         c = 0;
2139         for(i=0; i < tokens && c < WEP_COUNT; ++i){
2140                 w = stof(argv(i));
2141                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
2142                         bot_weapons_mid[c] = w;
2143                         ++c;
2144                 }
2145         }
2146         if(c < WEP_COUNT)
2147                 bot_weapons_mid[c] = -1;
2148
2149         // Parse close distance weapon priorities
2150         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_close")," ");
2151
2152         c = 0;
2153         for(i=0; i < tokens && i < WEP_COUNT; ++i){
2154                 w = stof(argv(i));
2155                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
2156                         bot_weapons_close[c] = w;
2157                         ++c;
2158                 }
2159         }
2160         if(c < WEP_COUNT)
2161                 bot_weapons_close[c] = -1;
2162
2163         bot_custom_weapon = TRUE;
2164 };
2165
2166
2167 void bot_endgame()
2168 {
2169         local entity e;
2170         //dprint("bot_endgame\n");
2171         e = bot_list;
2172         while (e)
2173         {
2174                 setcolor(e, e.bot_preferredcolors);
2175                 e = e.nextbot;
2176         }
2177         // if dynamic waypoints are ever implemented, save them here
2178 };
2179
2180 float bot_ignore_bots; // let bots not attack other bots (only works in non-teamplay)
2181 float bot_shouldattack(entity e)
2182 {
2183         if (e.team == self.team)
2184         {
2185                 if (e == self)
2186                         return FALSE;
2187                 if (teams_matter)
2188                 if (e.team != 0)
2189                         return FALSE;
2190         }
2191
2192         if(teams_matter)
2193         {
2194                 if(e.team==0)
2195                         return FALSE;
2196         }
2197         else if(bot_ignore_bots)
2198                 if(clienttype(e) == CLIENTTYPE_BOT)
2199                         return FALSE;
2200
2201         if (!e.takedamage)
2202                 return FALSE;
2203         if (e.deadflag)
2204                 return FALSE;
2205         if (e.BUTTON_CHAT)
2206                 return FALSE;
2207         if(g_minstagib)
2208         if(e.items & IT_STRENGTH)
2209                 return FALSE;
2210         if(e.flags & FL_NOTARGET)
2211                 return FALSE;
2212         return TRUE;
2213 };
2214
2215 void bot_lagfunc(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
2216 {
2217         if(self.flags & FL_INWATER)
2218         {
2219                 self.bot_aimtarg = world;
2220                 return;
2221         }
2222         self.bot_aimtarg = e1;
2223         self.bot_aimlatency = self.ping; // FIXME?  Shouldn't this be in the lag item?
2224         self.bot_aimselforigin = v1;
2225         self.bot_aimselfvelocity = v2;
2226         self.bot_aimtargorigin = v3;
2227         self.bot_aimtargvelocity = v4;
2228         if(skill <= 0)
2229                 self.bot_canfire = (random() < 0.8);
2230         else if(skill <= 1)
2231                 self.bot_canfire = (random() < 0.9);
2232         else if(skill <= 2)
2233                 self.bot_canfire = (random() < 0.95);
2234         else
2235                 self.bot_canfire = 1;
2236 };
2237
2238 .float bot_nextthink;
2239 .float bot_badaimtime;
2240 .float bot_aimthinktime;
2241 .float bot_prevaimtime;
2242 .vector bot_mouseaim;
2243 .vector bot_badaimoffset;
2244 .vector bot_1st_order_aimfilter;
2245 .vector bot_2nd_order_aimfilter;
2246 .vector bot_3th_order_aimfilter;
2247 .vector bot_4th_order_aimfilter;
2248 .vector bot_5th_order_aimfilter;
2249 .vector bot_olddesiredang;
2250 float bot_aimdir(vector v, float maxfiredeviation)
2251 {
2252         local float dist, delta_t, blend;
2253         local vector desiredang, diffang;
2254
2255         //dprint("aim ", self.netname, ": old:", vtos(self.v_angle));
2256         // make sure v_angle is sane first
2257         self.v_angle_y = self.v_angle_y - floor(self.v_angle_y / 360) * 360;
2258         self.v_angle_z = 0;
2259
2260         // get the desired angles to aim at
2261         //dprint(" at:", vtos(v));
2262         v = normalize(v);
2263         //te_lightning2(world, self.origin + self.view_ofs, self.origin + self.view_ofs + v * 200);
2264         if (time >= self.bot_badaimtime)
2265         {
2266                 self.bot_badaimtime = max(self.bot_badaimtime + 0.3, time);
2267                 self.bot_badaimoffset = randomvec() * bound(0, 5 - 0.5 * (skill+self.bot_offsetskill), 5) * cvar("bot_ai_aimskill_offset");
2268         }
2269         desiredang = vectoangles(v) + self.bot_badaimoffset;
2270         //dprint(" desired:", vtos(desiredang));
2271         if (desiredang_x >= 180)
2272                 desiredang_x = desiredang_x - 360;
2273         desiredang_x = bound(-90, 0 - desiredang_x, 90);
2274         desiredang_z = self.v_angle_z;
2275         //dprint(" / ", vtos(desiredang));
2276
2277         //// pain throws off aim
2278         //if (self.bot_painintensity)
2279         //{
2280         //      // shake from pain
2281         //      desiredang = desiredang + randomvec() * self.bot_painintensity * 0.2;
2282         //}
2283
2284         // calculate turn angles
2285         diffang = (desiredang - self.bot_olddesiredang);
2286         // wrap yaw turn
2287         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
2288         if (diffang_y >= 180)
2289                 diffang_y = diffang_y - 360;
2290         self.bot_olddesiredang = desiredang;
2291         //dprint(" diff:", vtos(diffang));
2292
2293         delta_t = time-self.bot_prevaimtime;
2294         self.bot_prevaimtime = time;
2295         // Here we will try to anticipate the comming aiming direction
2296         self.bot_1st_order_aimfilter= self.bot_1st_order_aimfilter
2297                 + (diffang * (1 / delta_t)    - self.bot_1st_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_1st"),1);
2298         self.bot_2nd_order_aimfilter= self.bot_2nd_order_aimfilter
2299                 + (self.bot_1st_order_aimfilter - self.bot_2nd_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_2nd"),1);
2300         self.bot_3th_order_aimfilter= self.bot_3th_order_aimfilter
2301                 + (self.bot_2nd_order_aimfilter - self.bot_3th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_3th"),1);
2302         self.bot_4th_order_aimfilter= self.bot_4th_order_aimfilter
2303                 + (self.bot_3th_order_aimfilter - self.bot_4th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_4th"),1);
2304         self.bot_5th_order_aimfilter= self.bot_5th_order_aimfilter
2305                 + (self.bot_4th_order_aimfilter - self.bot_5th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_5th"),1);
2306
2307         //blend = (bound(0,skill,10)*0.1)*pow(1-bound(0,skill,10)*0.05,2.5)*5.656854249; //Plot formule before changing !
2308         blend = bound(0,skill,10)*0.1;
2309         desiredang = desiredang + blend *
2310         (
2311                   self.bot_1st_order_aimfilter * cvar("bot_ai_aimskill_order_mix_1st")
2312                 + self.bot_2nd_order_aimfilter * cvar("bot_ai_aimskill_order_mix_2nd")
2313                 + self.bot_3th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_3th")
2314                 + self.bot_4th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_4th")
2315                 + self.bot_5th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_5th")
2316         );
2317
2318         // calculate turn angles
2319         diffang = desiredang - self.bot_mouseaim;
2320         // wrap yaw turn
2321         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
2322         if (diffang_y >= 180)
2323                 diffang_y = diffang_y - 360;
2324         //dprint(" diff:", vtos(diffang));
2325
2326         if (time >= self.bot_aimthinktime)
2327         {
2328                 self.bot_aimthinktime = max(self.bot_aimthinktime + 0.5 - 0.05*(skill+self.bot_thinkskill), time);
2329                 self.bot_mouseaim = self.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-skill,10));
2330         }
2331
2332         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
2333
2334         diffang = self.bot_mouseaim - desiredang;
2335         // wrap yaw turn
2336         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
2337         if (diffang_y >= 180)
2338                 diffang_y = diffang_y - 360;
2339         desiredang = desiredang + diffang * bound(0,cvar("bot_ai_aimskill_think"),1);
2340
2341         // calculate turn angles
2342         diffang = desiredang - self.v_angle;
2343         // wrap yaw turn
2344         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
2345         if (diffang_y >= 180)
2346                 diffang_y = diffang_y - 360;
2347         //dprint(" diff:", vtos(diffang));
2348
2349         // jitter tracking
2350         dist = vlen(diffang);
2351         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
2352
2353         // turn
2354         local float r, fixedrate, blendrate;
2355         fixedrate = cvar("bot_ai_aimskill_fixedrate") / bound(1,dist,1000);
2356         blendrate = cvar("bot_ai_aimskill_blendrate");
2357         r = max(fixedrate, blendrate);
2358         //self.v_angle = self.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
2359         self.v_angle = self.v_angle + diffang * bound(delta_t, r * delta_t * (2+pow(skill+self.bot_mouseskill,3)*0.005-random()), 1);
2360         self.v_angle = self.v_angle * bound(0,cvar("bot_ai_aimskill_mouse"),1) + desiredang * bound(0,(1-cvar("bot_ai_aimskill_mouse")),1);
2361         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
2362         //self.v_angle = self.v_angle + diffang * (1/ blendrate);
2363         self.v_angle_z = 0;
2364         self.v_angle_y = self.v_angle_y - floor(self.v_angle_y / 360) * 360;
2365         //dprint(" turn:", vtos(self.v_angle));
2366
2367         makevectors(self.v_angle);
2368         shotorg = self.origin + self.view_ofs;
2369         shotdir = v_forward;
2370
2371         //dprint(" dir:", vtos(v_forward));
2372         //te_lightning2(world, shotorg, shotorg + shotdir * 100);
2373
2374         // calculate turn angles again
2375         //diffang = desiredang - self.v_angle;
2376         //diffang_y = diffang_y - floor(diffang_y / 360) * 360;
2377         //if (diffang_y >= 180)
2378         //      diffang_y = diffang_y - 360;
2379
2380         //dprint("e ", vtos(diffang), " < ", ftos(maxfiredeviation), "\n");
2381
2382         // decide whether to fire this time
2383         // note the maxfiredeviation is in degrees so this has to convert to radians first
2384         //if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
2385         if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
2386         if (vlen(trace_endpos-shotorg) < 500+500*bound(0, skill, 10) || random()*random()>bound(0,skill*0.05,1))
2387                 self.bot_firetimer = time + bound(0.1, 0.5-skill*0.05, 0.5);
2388         //traceline(shotorg,shotorg+shotdir*1000,FALSE,world);
2389         //dprint(ftos(maxfiredeviation),"\n");
2390         //dprint(" diff:", vtos(diffang), "\n");
2391
2392         return self.bot_canfire && (time < self.bot_firetimer);
2393 };
2394
2395 vector bot_shotlead(vector targorigin, vector targvelocity, float shotspeed, float shotdelay)
2396 {
2397         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
2398         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
2399 };
2400
2401 float bot_aim(float shotspeed, float shotspeedupward, float maxshottime, float applygravity)
2402 {
2403         local float f, r;
2404         local vector v;
2405         /*
2406         eprint(self);
2407         dprint("bot_aim(", ftos(shotspeed));
2408         dprint(", ", ftos(shotspeedupward));
2409         dprint(", ", ftos(maxshottime));
2410         dprint(", ", ftos(applygravity));
2411         dprint(");\n");
2412         */
2413         shotspeed *= g_weaponspeedfactor;
2414         shotspeedupward *= g_weaponspeedfactor;
2415         if (!shotspeed)
2416         {
2417                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " shotspeed is zero!\n");
2418                 shotspeed = 1000000;
2419         }
2420         if (!maxshottime)
2421         {
2422                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " maxshottime is zero!\n");
2423                 maxshottime = 1;
2424         }
2425         makevectors(self.v_angle);
2426         shotorg = self.origin + self.view_ofs;
2427         shotdir = v_forward;
2428         v = bot_shotlead(self.bot_aimtargorigin, self.bot_aimtargvelocity, shotspeed, self.bot_aimlatency);
2429         local float distanceratio;
2430         distanceratio =sqrt(bound(0,skill,10000))*0.3*(vlen(v-shotorg)-100)/cvar("bot_ai_aimskill_firetolerance_distdegrees");
2431         distanceratio = bound(0,distanceratio,1);
2432         r =  (cvar("bot_ai_aimskill_firetolerance_maxdegrees")-cvar("bot_ai_aimskill_firetolerance_mindegrees"))
2433                 * (1-distanceratio) + cvar("bot_ai_aimskill_firetolerance_mindegrees");
2434         if (applygravity && self.bot_aimtarg)
2435         {
2436                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', self.bot_aimtarg, shotspeed, shotspeedupward, maxshottime, 0, self))
2437                         return FALSE;
2438                 f = bot_aimdir(findtrajectory_velocity - shotspeedupward * '0 0 1', r);
2439         }
2440         else
2441         {
2442                 f = bot_aimdir(v - shotorg, r);
2443                 //dprint("AIM: ");dprint(vtos(self.bot_aimtargorigin));dprint(" + ");dprint(vtos(self.bot_aimtargvelocity));dprint(" * ");dprint(ftos(self.bot_aimlatency + vlen(self.bot_aimtargorigin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
2444                 traceline(shotorg, shotorg + shotdir * 10000, FALSE, self);
2445                 if (trace_ent.takedamage)
2446                 if (trace_fraction < 1)
2447                 if (!bot_shouldattack(trace_ent))
2448                         return FALSE;
2449                 traceline(shotorg, self.bot_aimtargorigin, FALSE, self);
2450                 if (trace_fraction < 1)
2451                 if (trace_ent != self.enemy)
2452                 if (!bot_shouldattack(trace_ent))
2453                         return FALSE;
2454         }
2455         if (r > maxshottime * shotspeed)
2456                 return FALSE;
2457         return f;
2458 };
2459
2460 // TODO: move this painintensity code to the player damage code
2461 void bot_think()
2462 {
2463         if (self.bot_nextthink > time)
2464                 return;
2465
2466         self.flags &~= FL_GODMODE;
2467         if(cvar("bot_god"))
2468                 self.flags |= FL_GODMODE;
2469
2470         self.bot_nextthink = self.bot_nextthink + cvar("bot_ai_thinkinterval");
2471         //if (self.bot_painintensity > 0)
2472         //      self.bot_painintensity = self.bot_painintensity - (skill + 1) * 40 * frametime;
2473
2474         //self.bot_painintensity = self.bot_painintensity + self.bot_oldhealth - self.health;
2475         //self.bot_painintensity = bound(0, self.bot_painintensity, 100);
2476
2477         if(time < game_starttime || ((cvar("g_campaign") && !campaign_bots_may_start)))
2478         {
2479                 self.nextthink = time + 0.5;
2480                 return;
2481         }
2482
2483         if (self.fixangle)
2484         {
2485                 self.v_angle = self.angles;
2486                 self.v_angle_z = 0;
2487                 self.fixangle = FALSE;
2488         }
2489
2490         self.dmg_take = 0;
2491         self.dmg_save = 0;
2492         self.dmg_inflictor = world;
2493
2494         // calculate an aiming latency based on the skill setting
2495         // (simulated network latency + naturally delayed reflexes)
2496         //self.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
2497         // minimum ping 20+10 random
2498         self.ping = bound(0,0.07 - bound(0, skill * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
2499         // skill 10 = ping 0.2 (adrenaline)
2500         // skill 0 = ping 0.7 (slightly drunk)
2501
2502         // clear buttons
2503         self.BUTTON_ATCK = 0;
2504         self.button1 = 0;
2505         self.BUTTON_JUMP = 0;
2506         self.BUTTON_ATCK2 = 0;
2507         self.BUTTON_ZOOM = 0;
2508         self.BUTTON_CROUCH = 0;
2509         self.BUTTON_HOOK = 0;
2510         self.BUTTON_INFO = 0;
2511         self.button8 = 0;
2512         self.BUTTON_CHAT = 0;
2513         self.BUTTON_USE = 0;
2514
2515         // if dead, just wait until we can respawn
2516         if (self.deadflag)
2517         {
2518                 if (self.deadflag == DEAD_DEAD)
2519                 {
2520                         self.BUTTON_JUMP = 1; // press jump to respawn
2521                         self.bot_strategytime = 0;
2522                 }
2523         }
2524
2525         // now call the current bot AI (havocbot for example)
2526         self.bot_ai();
2527 };
2528
2529 entity bot_strategytoken;
2530 float bot_strategytoken_taken;
2531 entity player_list;
2532 .entity nextplayer;
2533 void bot_relinkplayerlist()
2534 {
2535         local entity e;
2536         local entity prevbot;
2537         player_count = 0;
2538         currentbots = 0;
2539         player_list = e = findchainflags(flags, FL_CLIENT);
2540         bot_list = world;
2541         prevbot = world;
2542         while (e)
2543         {
2544                 player_count = player_count + 1;
2545                 e.nextplayer = e.chain;
2546                 if (clienttype(e) == CLIENTTYPE_BOT)
2547                 {
2548                         if (prevbot)
2549                                 prevbot.nextbot = e;
2550                         else
2551                         {
2552                                 bot_list = e;
2553                                 bot_list.nextbot = world;
2554                         }
2555                         prevbot = e;
2556                         currentbots = currentbots + 1;
2557                 }
2558                 e = e.chain;
2559         }
2560         dprint(strcat("relink: ", ftos(currentbots), " bots seen.\n"));
2561         bot_strategytoken = bot_list;
2562         bot_strategytoken_taken = TRUE;
2563 };
2564
2565 void() havocbot_setupbot;
2566 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam);
2567
2568 void bot_clientdisconnect()
2569 {
2570         if (clienttype(self) != CLIENTTYPE_BOT)
2571                 return;
2572         if(self.netname_freeme)
2573                 strunzone(self.netname_freeme);
2574         if(self.playermodel_freeme)
2575                 strunzone(self.playermodel_freeme);
2576         if(self.playerskin_freeme)
2577                 strunzone(self.playerskin_freeme);
2578         self.netname_freeme = string_null;
2579         self.playermodel_freeme = string_null;
2580         self.playerskin_freeme = string_null;
2581 }
2582
2583 void bot_clientconnect()
2584 {
2585         if (clienttype(self) != CLIENTTYPE_BOT)
2586                 return;
2587         self.bot_preferredcolors = self.clientcolors;
2588         self.bot_nextthink = time - random();
2589         self.lag_func = bot_lagfunc;
2590         self.isbot = TRUE;
2591         self.createdtime = self.nextthink;
2592
2593         if(!self.bot_config_loaded) // This is needed so team overrider doesn't break between matches
2594                 bot_setnameandstuff();
2595
2596         if(self.bot_forced_team==1)
2597                 self.team = COLOR_TEAM1;
2598         else if(self.bot_forced_team==2)
2599                 self.team = COLOR_TEAM2;
2600         else if(self.bot_forced_team==3)
2601                 self.team = COLOR_TEAM3;
2602         else if(self.bot_forced_team==4)
2603                 self.team = COLOR_TEAM4;
2604         else
2605                 JoinBestTeam(self, FALSE, TRUE);
2606
2607         havocbot_setupbot();
2608         self.bot_mouseskill=random()-0.5;
2609         self.bot_thinkskill=random()-0.5;
2610         self.bot_predictionskill=random()-0.5;
2611         self.bot_offsetskill=random()-0.5;
2612 };
2613
2614 entity bot_spawn()
2615 {
2616         local entity oldself, bot;
2617         bot = spawnclient();
2618         if (bot)
2619         {
2620                 currentbots = currentbots + 1;
2621                 oldself = self;
2622                 self = bot;
2623                 bot_setnameandstuff();
2624                 ClientConnect();
2625                 PutClientInServer();
2626                 self = oldself;
2627         }
2628         return bot;
2629 };
2630
2631 void CheckAllowedTeams(entity for_whom); void GetTeamCounts(entity other); float c1, c2, c3, c4;
2632 void bot_removefromlargestteam()
2633 {
2634         local float besttime, bestcount, thiscount;
2635         local entity best, head;
2636         CheckAllowedTeams(world);
2637         GetTeamCounts(world);
2638         head = findchainfloat(isbot, TRUE);
2639         if (!head)
2640                 return;
2641         best = head;
2642         besttime = head.createdtime;
2643         bestcount = 0;
2644         while (head)
2645         {
2646                 if(head.team == COLOR_TEAM1)
2647                         thiscount = c1;
2648                 else if(head.team == COLOR_TEAM2)
2649                         thiscount = c2;
2650                 else if(head.team == COLOR_TEAM3)
2651                         thiscount = c3;
2652                 else if(head.team == COLOR_TEAM4)
2653                         thiscount = c4;
2654                 else
2655                         thiscount = 0;
2656                 if (thiscount > bestcount)
2657                 {
2658                         bestcount = thiscount;
2659                         besttime = head.createdtime;
2660                         best = head;
2661                 }
2662                 else if (thiscount == bestcount && besttime < head.createdtime)
2663                 {
2664                         besttime = head.createdtime;
2665                         best = head;
2666                 }
2667                 head = head.chain;
2668         }
2669         currentbots = currentbots - 1;
2670         dropclient(best);
2671 };
2672
2673 void bot_removenewest()
2674 {
2675         local float besttime;
2676         local entity best, head;
2677
2678         if(teams_matter)
2679         {
2680                 bot_removefromlargestteam();
2681                 return;
2682         }
2683
2684         head = findchainfloat(isbot, TRUE);
2685         if (!head)
2686                 return;
2687         best = head;
2688         besttime = head.createdtime;
2689         while (head)
2690         {
2691                 if (besttime < head.createdtime)
2692                 {
2693                         besttime = head.createdtime;
2694                         best = head;
2695                 }
2696                 head = head.chain;
2697         }
2698         currentbots = currentbots - 1;
2699         dropclient(best);
2700 };
2701
2702 float botframe_waypointeditorlightningtime;
2703 void botframe_showwaypointlinks()
2704 {
2705         local entity player, head, w;
2706         float i;
2707
2708         if (time < botframe_waypointeditorlightningtime)
2709                 return;
2710         botframe_waypointeditorlightningtime = time + 0.5;
2711         player = find(world, classname, "player");
2712         while (player)
2713         {
2714                 if (!player.isbot)
2715                 if (player.flags & FL_ONGROUND || player.waterlevel > WATERLEVEL_NONE)
2716                 {
2717                         //navigation_testtracewalk = TRUE;
2718                         head = navigation_findnearestwaypoint(player, FALSE);
2719                 //      print("currently selected WP is ", etos(head), "\n");
2720                         //navigation_testtracewalk = FALSE;
2721                         if (head)
2722                         {
2723                                 te_lightning2(world, head.origin, player.origin);
2724
2725                                 for(i=0;i<MAX_WAYPOINTS_LINKS;++i)
2726                                 {
2727                                         w = head.wlink[i];
2728                                         if (w)
2729                                                 te_lightning2(world, w.origin, head.origin);
2730                                 }
2731                         }
2732                 }
2733                 player = find(player, classname, "player");
2734         }
2735 };
2736
2737 entity botframe_dangerwaypoint;
2738 void botframe_updatedangerousobjects(float maxupdate)
2739 {
2740         local entity head, bot_dodgelist;
2741         local vector m1, m2, v;
2742         local float c, d, danger;
2743         c = 0;
2744         bot_dodgelist = findchainfloat(bot_dodge, TRUE);
2745         botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
2746         while (botframe_dangerwaypoint != world)
2747         {
2748                 danger = 0;
2749                 m1 = botframe_dangerwaypoint.mins;
2750                 m2 = botframe_dangerwaypoint.maxs;
2751                 head = bot_dodgelist;
2752                 while (head)
2753                 {
2754                         v = head.origin;
2755                         v_x = bound(m1_x, v_x, m2_x);
2756                         v_y = bound(m1_y, v_y, m2_y);
2757                         v_z = bound(m1_z, v_z, m2_z);
2758                         d = head.bot_dodgerating - vlen(head.origin - v);
2759                         if (d > 0)
2760                         {
2761                                 traceline(head.origin, v, TRUE, world);
2762                                 if (trace_fraction == 1)
2763                                         danger = danger + d;
2764                         }
2765                         head = head.chain;
2766                 }
2767                 botframe_dangerwaypoint.dmg = danger;
2768                 c = c + 1;
2769                 if (c >= maxupdate)
2770                         break;
2771                 botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
2772         }
2773 };
2774
2775
2776 float botframe_spawnedwaypoints;
2777 float botframe_nextthink;
2778 float botframe_nextdangertime;
2779
2780 float autoskill_nextthink;
2781 .float totalfrags_lastcheck;
2782 void autoskill(float factor)
2783 {
2784         float bestbot;
2785         float bestplayer;
2786         entity head;
2787
2788         bestbot = -1;
2789         bestplayer = -1;
2790         FOR_EACH_PLAYER(head)
2791         {
2792                 if(clienttype(head) == CLIENTTYPE_REAL)
2793                         bestplayer = max(bestplayer, head.totalfrags - head.totalfrags_lastcheck);
2794                 else
2795                         bestbot = max(bestbot, head.totalfrags - head.totalfrags_lastcheck);
2796         }
2797
2798         dprint("autoskill: best player got ", ftos(bestplayer), ", ");
2799         dprint("best bot got ", ftos(bestbot), "; ");
2800         if(bestbot < 0 || bestplayer < 0)
2801         {
2802                 dprint("not doing anything\n");
2803                 // don't return, let it reset all counters below
2804         }
2805         else if(bestbot <= bestplayer * factor - 2)
2806         {
2807                 if(cvar("skill") < 17)
2808                 {
2809                         dprint("2 frags difference, increasing skill\n");
2810                         cvar_set("skill", ftos(cvar("skill") + 1));
2811                         bprint("^2SKILL UP!^7 Now at level ", ftos(cvar("skill")), "\n");
2812                 }
2813         }
2814         else if(bestbot >= bestplayer * factor + 2)
2815         {
2816                 if(cvar("skill") > 0)
2817                 {
2818                         dprint("2 frags difference, decreasing skill\n");
2819                         cvar_set("skill", ftos(cvar("skill") - 1));
2820                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(cvar("skill")), "\n");
2821                 }
2822         }
2823         else
2824         {
2825                 dprint("not doing anything\n");
2826                 return;
2827                 // don't reset counters, wait for them to accumulate
2828         }
2829
2830         FOR_EACH_PLAYER(head)
2831                 head.totalfrags_lastcheck = head.totalfrags;
2832 }
2833
2834 float bot_cvar_nextthink;
2835 void bot_serverframe()
2836 {
2837         float realplayers, bots, activerealplayers;
2838         entity head;
2839
2840         if (intermission_running)
2841                 return;
2842
2843         if (time < 2)
2844                 return;
2845
2846         stepheightvec = cvar("sv_stepheight") * '0 0 1';
2847         bot_navigation_movemode = ((cvar("bot_navigation_ignoreplayers")) ? MOVE_NOMONSTERS : MOVE_NORMAL);
2848
2849         if(time > autoskill_nextthink)
2850         {
2851                 float a;
2852                 a = cvar("skill_auto");
2853                 if(a)
2854                         autoskill(a);
2855                 autoskill_nextthink = time + 5;
2856         }
2857
2858         activerealplayers = 0;
2859         realplayers = 0;
2860
2861         FOR_EACH_REALCLIENT(head)
2862         {
2863                 if(head.classname == "player" || g_lms || g_arena)
2864                         ++activerealplayers;
2865                 ++realplayers;
2866         }
2867
2868         // add/remove bots if needed to make sure there are at least
2869         // minplayers+bot_number, or remove all bots if no one is playing
2870         // But don't remove bots immediately on level change, as the real players
2871         // usually haven't rejoined yet
2872         bots_would_leave = FALSE;
2873         if ((realplayers || cvar("bot_join_empty") || (currentbots > 0 && time < 5)))
2874         {
2875                 float realminplayers, minplayers;
2876                 realminplayers = cvar("minplayers");
2877                 minplayers = max(0, floor(realminplayers));
2878
2879                 float realminbots, minbots;
2880                 if(teamplay && cvar("bot_vs_human"))
2881                         realminbots = ceil(fabs(cvar("bot_vs_human")) * activerealplayers);
2882                 else
2883                         realminbots = cvar("bot_number");
2884                 minbots = max(0, floor(realminbots));
2885
2886                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
2887                 if(bots > minbots)
2888                         bots_would_leave = TRUE;
2889         }
2890         else
2891         {
2892                 // if there are no players, remove bots
2893                 bots = 0;
2894         }
2895
2896         bot_ignore_bots = cvar("bot_ignore_bots");
2897
2898         // only add one bot per frame to avoid utter chaos
2899         if(time > botframe_nextthink)
2900         {
2901                 //dprint(ftos(bots), " ? ", ftos(currentbots), "\n");
2902                 while (currentbots < bots)
2903                 {
2904                         if (bot_spawn() == world)
2905                         {
2906                                 bprint("Can not add bot, server full.\n");
2907                                 botframe_nextthink = time + 10;
2908                                 break;
2909                         }
2910                 }
2911                 while (currentbots > bots)
2912                         bot_removenewest();
2913         }
2914
2915         if(botframe_spawnedwaypoints)
2916         {
2917                 if(cvar("waypoint_benchmark"))
2918                         localcmd("quit\n");
2919         }
2920
2921         if (currentbots > 0 || cvar("g_waypointeditor"))
2922         if (botframe_spawnedwaypoints)
2923         {
2924                 if(botframe_cachedwaypointlinks)
2925                 {
2926                         if(!botframe_loadedforcedlinks)
2927                                 waypoint_load_links_hardwired();
2928                 }
2929                 else
2930                 {
2931                         // TODO: Make this check cleaner
2932                         local entity w = findchain(classname, "waypoint");
2933                         if(time - w.nextthink > 10)
2934                                 waypoint_save_links();
2935                 }
2936         }
2937         else
2938         {
2939                 botframe_spawnedwaypoints = TRUE;
2940                 waypoint_loadall();
2941                 if(!waypoint_load_links())
2942                         waypoint_schedulerelinkall();
2943         }
2944
2945         if (bot_list)
2946         {
2947                 // cycle the goal token from one bot to the next each frame
2948                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
2949                 //  frame, which causes choppy framerates)
2950                 if (bot_strategytoken_taken)
2951                 {
2952                         bot_strategytoken_taken = FALSE;
2953                         if (bot_strategytoken)
2954                                 bot_strategytoken = bot_strategytoken.nextbot;
2955                         if (!bot_strategytoken)
2956                                 bot_strategytoken = bot_list;
2957                 }
2958
2959                 if (botframe_nextdangertime < time)
2960                 {
2961                         local float interval;
2962                         interval = cvar("bot_ai_dangerdetectioninterval");
2963                         if (botframe_nextdangertime < time - interval * 1.5)
2964                                 botframe_nextdangertime = time;
2965                         botframe_nextdangertime = botframe_nextdangertime + interval;
2966                         botframe_updatedangerousobjects(cvar("bot_ai_dangerdetectionupdates"));
2967                 }
2968         }
2969
2970         if (cvar("g_waypointeditor"))
2971                 botframe_showwaypointlinks();
2972
2973         if(time > bot_cvar_nextthink)
2974         {
2975                 if(currentbots>0)
2976                         bot_custom_weapon_priority_setup();
2977                 bot_cvar_nextthink = time + 5;
2978         }
2979 };
2980
2981 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(lag_time);
2982 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(lag_float1);
2983 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(lag_float2);
2984 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(lag_vec1);
2985 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(lag_vec2);
2986 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(lag_vec3);
2987 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(lag_vec4);
2988 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(lag_entity1);
2989 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(wlink);
2990 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(wpmincost);