data/qcsrc/server/bots.qc

   1 .float aistatus;
   2 float AI_STATUS_ROAMING                 = 1;    // Bot is just crawling the map. No enemies at sight
   3 float AI_STATUS_ATTACKING               = 2;    // There are enemies at sight
   4 float AI_STATUS_RUNNING                 = 4;    // Bot is bunny hopping
   5 float AI_STATUS_DANGER_AHEAD    = 8;    // There is lava/slime/abism ahead
   6 float AI_STATUS_OUT_JUMPPAD             = 16;   // Trying to get out of a "vertical" jump pad
   7 float AI_STATUS_OUT_WATER               = 32;   // Trying to get out of water
   8
   9 .string netname_freeme;
  10 // rough simulation of walking from one point to another to test if a path
  11 // can be traveled, used by havocbot
  12
  13 vector stepheightvec;
  14 float navigation_testtracewalk;
  15 float tracewalk(entity e, vector start, vector m1, vector m2, vector end, float movemode)
  16 {
  17         local vector org;
  18         local vector move;
  19         local vector dir;
  20         local float dist;
  21         local float totaldist;
  22         local float stepdist;
  23         local float yaw;
  24         local float ignorehazards;
  25         if (navigation_testtracewalk)
  26         {
  27                 if (navigation_testtracewalk > 1)
  28                         dprint("tracewalk: ");
  29                 //te_wizspike(start);
  30                 //te_knightspike(end);
  31                 //te_lightning2(world, start, end);
  32         }
  33         move = end - start;
  34         move_z = 0;
  35         org = start;
  36         dist = totaldist = vlen(move);
  37         dir = normalize(move);
  38         stepdist = 32;
  39         ignorehazards = FALSE;
  40         //self.angles = vectoangles(dir);
  41         traceline(start, start, MOVE_NORMAL, e);
  42         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  43                 ignorehazards = TRUE;
  44         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
  45         if (trace_startsolid)
  46         {
  47                 // failed - bad start
  48                 if (navigation_testtracewalk)
  49                 {
  50                         if (navigation_testtracewalk > 1)
  51                                 dprint("bad-start\n");
  52                         te_knightspike(start);
  53                 }
  54                 return 0;
  55         }
  56         yaw = vectoyaw(move);
  57         move = end - org;
  58         while (1)
  59         {
  60                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
  61                 {
  62                         if (navigation_testtracewalk)
  63                         {
  64                                 if (navigation_testtracewalk > 1)
  65                                         dprint("success\n");
  66                                 te_wizspike(org);
  67                         }
  68                         // succeeded
  69                         return 1;
  70                 }
  71                 if (dist <= 0)
  72                         break;
  73                 if (navigation_testtracewalk)
  74                 {
  75                         //dprint("trying ");
  76                         //te_gunshot(org);
  77                         particle(org, '0 0 0', 104, 8);
  78                 }
  79                 if (stepdist > dist)
  80                         stepdist = dist;
  81                 dist = dist - stepdist;
  82                 traceline(org, org, MOVE_NORMAL, e);
  83                 if (!ignorehazards)
  84                 {
  85                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  86                         {
  87                                 if (navigation_testtracewalk)
  88                                 {
  89                                         if (navigation_testtracewalk > 1)
  90                                                 dprint("hazard\n");
  91                                         te_gunshot(org);
  92                                 }
  93                                 // hazards blocking path
  94                                 return 0;
  95                         }
  96                 }
  97                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
  98                 {
  99                         move = normalize(end - org);
 100                         tracebox(org, m1, m2, org + move * stepdist, movemode, e);
 101                         if (trace_fraction < 1)
 102                         {
 103                                 if (navigation_testtracewalk)
 104                                 {
 105                                         if (navigation_testtracewalk > 1)
 106                                                 dprint("swimming-hit-something\n");
 107                                         //particle(org, move * 64, 104, 4);
 108                                         te_gunshot(org);
 109                                 }
 110                                 return 0;
 111                         }
 112                         org = trace_endpos;
 113                 }
 114                 else
 115                 {
 116                         move = dir * stepdist + org;
 117                         tracebox(org, m1, m2, move, movemode, e);
 118                         // hit something
 119                         if (trace_fraction < 1)
 120                         {
 121                                 // check if we can walk over this obstacle
 122                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 123                                 if (trace_fraction < 1 || trace_startsolid)
 124                                 {
 125                                         if (navigation_testtracewalk)
 126                                         {
 127                                                 if (navigation_testtracewalk > 1)
 128                                                         dprint("hit-something\n");
 129                                         //      move = normalize(end - org);
 130                                         //      particle(org, move * 64, 104, 4);
 131                                         //      te_gunshot(org);
 132                                         }
 133
 134                                         // check for doors
 135                                         traceline( org, move, movemode, e);
 136                                         if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 137                                         {
 138                                                 local vector nextmove;
 139                                                 move = trace_endpos;
 140                                                 while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 141                                                 {
 142                                                         nextmove = move + (dir * stepdist);
 143                                                         traceline( move, nextmove, movemode, e);
 144                                                         move = nextmove;
 145                                                 }
 146                                         }
 147                                         else
 148                                                 return 0; // failed
 149                                 }
 150                                 else
 151                                         move = trace_endpos;
 152                         }
 153                         else
 154                                 move = trace_endpos;
 155
 156                         // trace down from stepheight as far as possible and move there,
 157                         // if this starts in solid we try again without the stepup, and
 158                         // if that also fails we assume it is a wall
 159                         // (this is the same logic as the Quake walkmove function used)
 160                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 161                         /*
 162                         if (trace_startsolid)
 163                         {
 164                                 tracebox(move, m1, m2, move + '0 0 -65536', FALSE, e);
 165                                 if (trace_startsolid)
 166                                 {
 167                                         if (navigation_testtracewalk)
 168                                         {
 169                                                 if (navigation_testtracewalk > 1)
 170                                                         dprint("hit-something\n");
 171                                                 //move = normalize(end - org);
 172                                                 //particle(org, move * 64, 104, 4);
 173                                                 te_knightspike(org);
 174                                         }
 175                                         // failed
 176                                         return 0;
 177                                 }
 178                         }
 179                         */
 180                         // moved successfully
 181                         if (navigation_testtracewalk > 1)
 182                                 dprint("moved ");
 183                         org = trace_endpos;
 184                 }
 185         }
 186         if (navigation_testtracewalk)
 187         {
 188                 if (navigation_testtracewalk > 1)
 189                         dprint("wrong-place\n");
 190                 te_knightspike(org);
 191                 //te_gunshot(end);
 192         }
 193         // moved but didn't arrive at the intended destination
 194         return 0;
 195 };
 196
 197
 198 // grenade tracing to decide the best pitch to fire at
 199
 200 entity tracetossent;
 201 entity tracetossfaketarget;
 202
 203 // traces multiple trajectories to find one that will impact the target
 204 // 'end' vector is the place it aims for,
 205 // returns TRUE only if it hit targ (don't target non-solid entities)
 206 vector findtrajectory_velocity;
 207 float findtrajectorywithleading(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore)
 208 {
 209         local float c, savesolid, shottime;
 210         local vector dir, end, v;
 211         if (shotspeed < 1)
 212                 return FALSE; // could cause division by zero if calculated
 213         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
 214                 return FALSE; // could never hit it
 215         if (!tracetossent)
 216                 tracetossent = spawn();
 217         tracetossent.owner = ignore;
 218         setsize(tracetossent, m1, m2);
 219         savesolid = targ.solid;
 220         targ.solid = SOLID_NOT;
 221         shottime = ((vlen(targ.origin - org) / shotspeed) + shotdelay);
 222         v = targ.velocity * shottime + targ.origin;
 223         tracebox(targ.origin, targ.mins, targ.maxs, v, FALSE, targ);
 224         v = trace_endpos;
 225         end = v + (targ.mins + targ.maxs) * 0.5;
 226         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
 227         {
 228                 // out of range
 229                 targ.solid = savesolid;
 230                 return FALSE;
 231         }
 232
 233         if (!tracetossfaketarget)
 234                 tracetossfaketarget = spawn();
 235         tracetossfaketarget.solid = savesolid;
 236         tracetossfaketarget.movetype = targ.movetype;
 237         setmodel(tracetossfaketarget, targ.model); // no low precision
 238         tracetossfaketarget.model = targ.model;
 239         tracetossfaketarget.modelindex = targ.modelindex;
 240         setsize(tracetossfaketarget, targ.mins, targ.maxs);
 241         setorigin(tracetossfaketarget, v);
 242
 243         c = 0;
 244         dir = normalize(end - org);
 245         while (c < 10) // 10 traces
 246         {
 247                 setorigin(tracetossent, org); // reset
 248                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
 249                 tracetoss(tracetossent, ignore); // love builtin functions...
 250                 if (trace_ent == tracetossfaketarget) // done
 251                 {
 252                         targ.solid = savesolid;
 253
 254                         // make it disappear
 255                         tracetossfaketarget.solid = SOLID_NOT;
 256                         tracetossfaketarget.movetype = MOVETYPE_NONE;
 257                         tracetossfaketarget.model = "";
 258                         tracetossfaketarget.modelindex = 0;
 259                         // relink to remove it from physics considerations
 260                         setorigin(tracetossfaketarget, v);
 261
 262                         return TRUE;
 263                 }
 264                 dir_z = dir_z + 0.1; // aim up a little more
 265                 c = c + 1;
 266         }
 267         targ.solid = savesolid;
 268
 269         // make it disappear
 270         tracetossfaketarget.solid = SOLID_NOT;
 271         tracetossfaketarget.movetype = MOVETYPE_NONE;
 272         tracetossfaketarget.model = "";
 273         tracetossfaketarget.modelindex = 0;
 274         // relink to remove it from physics considerations
 275         setorigin(tracetossfaketarget, v);
 276
 277         // leave a valid one even if it won't reach
 278         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
 279         return FALSE;
 280 };
 281
 282
 283
 284 // lag simulation
 285
 286 .void(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4) lag_func;
 287
 288 // upto 5 queued messages
 289 .float lag1_time;
 290 .float lag1_float1;
 291 .float lag1_float2;
 292 .entity lag1_entity1;
 293 .vector lag1_vec1;
 294 .vector lag1_vec2;
 295 .vector lag1_vec3;
 296 .vector lag1_vec4;
 297
 298 .float lag2_time;
 299 .float lag2_float1;
 300 .float lag2_float2;
 301 .entity lag2_entity1;
 302 .vector lag2_vec1;
 303 .vector lag2_vec2;
 304 .vector lag2_vec3;
 305 .vector lag2_vec4;
 306
 307 .float lag3_time;
 308 .float lag3_float1;
 309 .float lag3_float2;
 310 .entity lag3_entity1;
 311 .vector lag3_vec1;
 312 .vector lag3_vec2;
 313 .vector lag3_vec3;
 314 .vector lag3_vec4;
 315
 316 .float lag4_time;
 317 .float lag4_float1;
 318 .float lag4_float2;
 319 .entity lag4_entity1;
 320 .vector lag4_vec1;
 321 .vector lag4_vec2;
 322 .vector lag4_vec3;
 323 .vector lag4_vec4;
 324
 325 .float lag5_time;
 326 .float lag5_float1;
 327 .float lag5_float2;
 328 .entity lag5_entity1;
 329 .vector lag5_vec1;
 330 .vector lag5_vec2;
 331 .vector lag5_vec3;
 332 .vector lag5_vec4;
 333
 334 void lag_update()
 335 {
 336         if (self.lag1_time) if (time > self.lag1_time) {self.lag_func(self.lag1_time, self.lag1_float1, self.lag1_float2, self.lag1_entity1, self.lag1_vec1, self.lag1_vec2, self.lag1_vec3, self.lag1_vec4);self.lag1_time = 0;}
 337         if (self.lag2_time) if (time > self.lag2_time) {self.lag_func(self.lag2_time, self.lag2_float1, self.lag2_float2, self.lag2_entity1, self.lag2_vec1, self.lag2_vec2, self.lag2_vec3, self.lag2_vec4);self.lag2_time = 0;}
 338         if (self.lag3_time) if (time > self.lag3_time) {self.lag_func(self.lag3_time, self.lag3_float1, self.lag3_float2, self.lag3_entity1, self.lag3_vec1, self.lag3_vec2, self.lag3_vec3, self.lag3_vec4);self.lag3_time = 0;}
 339         if (self.lag4_time) if (time > self.lag4_time) {self.lag_func(self.lag4_time, self.lag4_float1, self.lag4_float2, self.lag4_entity1, self.lag4_vec1, self.lag4_vec2, self.lag4_vec3, self.lag4_vec4);self.lag4_time = 0;}
 340         if (self.lag5_time) if (time > self.lag5_time) {self.lag_func(self.lag5_time, self.lag5_float1, self.lag5_float2, self.lag5_entity1, self.lag5_vec1, self.lag5_vec2, self.lag5_vec3, self.lag5_vec4);self.lag5_time = 0;}
 341 };
 342
 343 float lag_additem(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
 344 {
 345         if (self.lag1_time == 0) {self.lag1_time = t;self.lag1_float1 = f1;self.lag1_float2 = f2;self.lag1_entity1 = e1;self.lag1_vec1 = v1;self.lag1_vec2 = v2;self.lag1_vec3 = v3;self.lag1_vec4 = v4;return TRUE;}
 346         if (self.lag2_time == 0) {self.lag2_time = t;self.lag2_float1 = f1;self.lag2_float2 = f2;self.lag2_entity1 = e1;self.lag2_vec1 = v1;self.lag2_vec2 = v2;self.lag2_vec3 = v3;self.lag2_vec4 = v4;return TRUE;}
 347         if (self.lag3_time == 0) {self.lag3_time = t;self.lag3_float1 = f1;self.lag3_float2 = f2;self.lag3_entity1 = e1;self.lag3_vec1 = v1;self.lag3_vec2 = v2;self.lag3_vec3 = v3;self.lag3_vec4 = v4;return TRUE;}
 348         if (self.lag4_time == 0) {self.lag4_time = t;self.lag4_float1 = f1;self.lag4_float2 = f2;self.lag4_entity1 = e1;self.lag4_vec1 = v1;self.lag4_vec2 = v2;self.lag4_vec3 = v3;self.lag4_vec4 = v4;return TRUE;}
 349         if (self.lag5_time == 0) {self.lag5_time = t;self.lag5_float1 = f1;self.lag5_float2 = f2;self.lag5_entity1 = e1;self.lag5_vec1 = v1;self.lag5_vec2 = v2;self.lag5_vec3 = v3;self.lag5_vec4 = v4;return TRUE;}
 350         // no room for it (what is the best thing to do here??)
 351         return FALSE;
 352 };
 353
 354
 355 // Random skill system
 356 .float bot_thinkskill;
 357 .float bot_mouseskill;
 358 .float bot_predictionskill;
 359 .float bot_offsetskill;
 360
 361
 362 // spawnfunc_waypoint navigation system
 363
 364 // itemscore = (howmuchmoreIwant / howmuchIcanwant) / itemdistance
 365 // waypointscore = 0.7 / waypointdistance
 366
 367 .entity wp00, wp01, wp02, wp03, wp04, wp05, wp06, wp07;
 368 .entity wp08, wp09, wp10, wp11, wp12, wp13, wp14, wp15;
 369 .entity wp16, wp17, wp18, wp19, wp20, wp21, wp22, wp23, wp24, wp25, wp26, wp27, wp28, wp29, wp30, wp31;
 370 .float wp00mincost, wp01mincost, wp02mincost, wp03mincost, wp04mincost, wp05mincost, wp06mincost, wp07mincost;
 371 .float wp08mincost, wp09mincost, wp10mincost, wp11mincost, wp12mincost, wp13mincost, wp14mincost, wp15mincost;
 372 .float wp16mincost, wp17mincost, wp18mincost, wp19mincost, wp20mincost, wp21mincost, wp22mincost, wp23mincost, wp24mincost, wp25mincost, wp26mincost, wp27mincost, wp28mincost, wp29mincost, wp30mincost, wp31mincost;
 373 .float wpfire, wpcost, wpconsidered;
 374 .float wpisbox;
 375 .float wpflags;
 376 .vector wpnearestpoint;
 377
 378 // stack of current goals (the last one of which may be an item or other
 379 // desirable object, the rest are typically waypoints to reach it)
 380 .entity goalcurrent, goalstack01, goalstack02, goalstack03;
 381 .entity goalstack04, goalstack05, goalstack06, goalstack07;
 382 .entity goalstack08, goalstack09, goalstack10, goalstack11;
 383 .entity goalstack12, goalstack13, goalstack14, goalstack15;
 384 .entity goalstack16, goalstack17, goalstack18, goalstack19;
 385 .entity goalstack20, goalstack21, goalstack22, goalstack23;
 386 .entity goalstack24, goalstack25, goalstack26, goalstack27;
 387 .entity goalstack28, goalstack29, goalstack30, goalstack31;
 388
 389 .entity nearestwaypoint;
 390 .float nearestwaypointtimeout;
 391
 392 // used during navigation_goalrating_begin/end sessions
 393 float navigation_bestrating;
 394 entity navigation_bestgoal;
 395 entity navigation_alternativegoal;
 396 .entity alternativegoal;
 397
 398
 399
 400
 401 /////////////////////////////////////////////////////////////////////////////
 402 // spawnfunc_waypoint management
 403 /////////////////////////////////////////////////////////////////////////////
 404
 405 // waypoints with this flag are not saved, they are automatically generated
 406 // waypoints like jump pads, teleporters, and items
 407 float WAYPOINTFLAG_GENERATED = 8388608;
 408 float WAYPOINTFLAG_ITEM = 4194304;
 409 float WAYPOINTFLAG_TELEPORT = 2097152;
 410 float WAYPOINTFLAG_NORELINK = 1048576;
 411
 412 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 413 void waypoint_addlink(entity from, entity to)
 414 {
 415         local float c;
 416
 417         if (from == to)
 418                 return;
 419         if (from.wpflags & WAYPOINTFLAG_NORELINK)
 420                 return;
 421
 422         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
 423         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
 424         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
 425         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
 426         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
 427         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
 428         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
 429         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
 430
 431         if (to.wpisbox || from.wpisbox)
 432         {
 433                 // if either is a box we have to find the nearest points on them to
 434                 // calculate the distance properly
 435                 local vector v1, v2, m1, m2;
 436                 v1 = from.origin;
 437                 m1 = to.absmin;
 438                 m2 = to.absmax;
 439                 v1_x = bound(m1_x, v1_x, m2_x);
 440                 v1_y = bound(m1_y, v1_y, m2_y);
 441                 v1_z = bound(m1_z, v1_z, m2_z);
 442                 v2 = to.origin;
 443                 m1 = from.absmin;
 444                 m2 = from.absmax;
 445                 v2_x = bound(m1_x, v2_x, m2_x);
 446                 v2_y = bound(m1_y, v2_y, m2_y);
 447                 v2_z = bound(m1_z, v2_z, m2_z);
 448                 v2 = to.origin;
 449                 c = vlen(v2 - v1);
 450         }
 451         else
 452                 c = vlen(to.origin - from.origin);
 453
 454         if (from.wp31mincost < c) return;
 455         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 456         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 457         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 458         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 459         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 460         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 461         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 462         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 463         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 464         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 465         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 466         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 467         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 468         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 469         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 470         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 471         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 472         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 473         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 474         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 475         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 476         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 477         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 478         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 479         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 480         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 481         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 482         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 483         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 484         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 485         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 486         from.wp00 = to;from.wp00mincost = c;return;
 487 };
 488
 489 // relink this spawnfunc_waypoint
 490 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 491 // (SLOW!)
 492 void waypoint_think()
 493 {
 494         local entity e;
 495         local vector sv, sm1, sm2, ev, em1, em2, dv;
 496         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 497         sm1 = self.origin + self.mins;
 498         sm2 = self.origin + self.maxs;
 499         e = find(world, classname, "waypoint");
 500         stepheightvec = cvar("sv_stepheight") * '0 0 1';
 501         while (e)
 502         {
 503                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 504                 {
 505                         waypoint_addlink(self, e);
 506                         waypoint_addlink(e, self);
 507                 }
 508                 else
 509                 {
 510                         sv = e.origin;
 511                         sv_x = bound(sm1_x, sv_x, sm2_x);
 512                         sv_y = bound(sm1_y, sv_y, sm2_y);
 513                         sv_z = bound(sm1_z, sv_z, sm2_z);
 514                         ev = self.origin;
 515                         em1 = e.origin + e.mins;
 516                         em2 = e.origin + e.maxs;
 517                         ev_x = bound(em1_x, ev_x, em2_x);
 518                         ev_y = bound(em1_y, ev_y, em2_y);
 519                         ev_z = bound(em1_z, ev_z, em2_z);
 520                         dv = ev - sv;
 521                         dv_z = 0;
 522                         if (vlen(dv) < 1050) // max search distance in XY
 523                         {
 524                                 navigation_testtracewalk = 0;
 525                                 if (!self.wpisbox)
 526                                 {
 527                                         tracebox(sv - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, sv, FALSE, self);
 528                                         if (!trace_startsolid)
 529                                         {
 530                                                 //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 531                                                 sv = trace_endpos + '0 0 1';
 532                                         }
 533                                 }
 534                                 if (!e.wpisbox)
 535                                 {
 536                                         tracebox(ev - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, ev, FALSE, e);
 537                                         if (!trace_startsolid)
 538                                         {
 539                                                 //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 540                                                 ev = trace_endpos + '0 0 1';
 541                                         }
 542                                 }
 543                                 //traceline(self.origin, e.origin, FALSE, world);
 544                                 //if (trace_fraction == 1)
 545                                 if (!self.wpisbox)
 546                                 if (tracewalk(self, sv, PL_MIN, PL_MAX, ev, MOVE_NOMONSTERS))
 547                                         waypoint_addlink(self, e);
 548                                 if (!e.wpisbox)
 549                                 if (tracewalk(e, ev, PL_MIN, PL_MAX, sv, MOVE_NOMONSTERS))
 550                                         waypoint_addlink(e, self);
 551                         }
 552                 }
 553                 e = find(e, classname, "waypoint");
 554         }
 555         navigation_testtracewalk = 0;
 556 };
 557
 558 void waypoint_clearlinks(entity wp)
 559 {
 560         // clear links to other waypoints
 561         local float f;
 562         f = 10000000;
 563         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = world;wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 564         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = world;wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 565         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = world;wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 566         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = world;wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 567 };
 568
 569 // tell a spawnfunc_waypoint to relink
 570 void waypoint_schedulerelink(entity wp)
 571 {
 572         if (wp == world)
 573                 return;
 574         // TODO: add some sort of visible box in edit mode for box waypoints
 575         if (cvar("g_waypointeditor"))
 576         {
 577                 local vector m1, m2;
 578                 m1 = wp.mins;
 579                 m2 = wp.maxs;
 580                 setmodel(wp, "models/runematch/rune.mdl"); wp.effects = EF_LOWPRECISION;
 581                 setsize(wp, m1, m2);
 582                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 583                         wp.colormod = '1 0 0';
 584                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 585                         wp.colormod = '1 1 0';
 586                 else
 587                         wp.colormod = '1 1 1';
 588         }
 589         else
 590                 wp.model = "";
 591         wp.wpisbox = vlen(wp.size) > 0;
 592         wp.enemy = world;
 593         wp.owner = world;
 594         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 595                 waypoint_clearlinks(wp);
 596         // schedule an actual relink on next frame
 597         wp.think = waypoint_think;
 598         wp.nextthink = time;
 599         wp.effects = EF_LOWPRECISION;
 600 }
 601
 602 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 603 // them back to it as well
 604 // (suitable for spawnfunc_waypoint editor)
 605 entity waypoint_spawn(vector m1, vector m2, float f)
 606 {
 607         local entity w;
 608         local vector org;
 609         w = find(world, classname, "waypoint");
 610         while (w)
 611         {
 612                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 613                 if (boxesoverlap(m1, m2, w.absmin, w.absmax))
 614                         return w;
 615                 w = find(w, classname, "waypoint");
 616         }
 617         w = spawn();
 618         w.classname = "waypoint";
 619         w.wpflags = f;
 620         setorigin(w, (m1 + m2) * 0.5);
 621         setsize(w, m1 - w.origin, m2 - w.origin);
 622         if (vlen(w.size) > 0)
 623                 w.wpisbox = TRUE;
 624
 625         if(!(f & WAYPOINTFLAG_GENERATED))
 626         if(!w.wpisbox)
 627         {
 628                 traceline(w.origin + '0 0 1', w.origin + PL_MIN_z * '0 0 1' - '0 0 1', MOVE_NOMONSTERS, w);
 629                 if (trace_fraction < 1)
 630                         setorigin(w, trace_endpos - PL_MIN_z * '0 0 1');
 631
 632                 // check if the start position is stuck
 633                 tracebox(w.origin, PL_MIN + '-1 -1 -1', PL_MAX + '1 1 1', w.origin, MOVE_NOMONSTERS, w);
 634                 if (trace_startsolid)
 635                 {
 636                         org = w.origin + '0 0 26';
 637                         tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 638                         if(trace_startsolid)
 639                         {
 640                                 org = w.origin + '2 2 2';
 641                                 tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 642                                 if(trace_startsolid)
 643                                 {
 644                                         org = w.origin + '-2 -2 2';
 645                                         tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 646                                         if(trace_startsolid)
 647                                         {
 648                                                 org = w.origin + '-2 2 2';
 649                                                 tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 650                                                 if(trace_startsolid)
 651                                                 {
 652                                                         org = w.origin + '2 -2 2';
 653                                                         tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 654                                                         if(trace_startsolid)
 655                                                         {
 656                                                                 // this WP is in solid, refuse it
 657                                                                 dprint("Killed a waypoint that was stuck in solid at ", vtos(org), "\n");
 658                                                                 remove(w);
 659                                                                 return world;
 660                                                         }
 661                                                 }
 662                                         }
 663                                 }
 664                         }
 665                         setorigin(w, org * 0.05 + trace_endpos * 0.95); // don't trust the trace fully
 666                 }
 667
 668                 tracebox(w.origin, PL_MIN, PL_MAX, w.origin - '0 0 128', MOVE_WORLDONLY, w);
 669                 if(trace_startsolid)
 670                 {
 671                         dprint("Killed a waypoint that was stuck in solid ", vtos(w.origin), "\n");
 672                         remove(w);
 673                         return world;
 674                 }
 675                 if (!trace_inwater)
 676                 {
 677                         if(trace_fraction == 1)
 678                         {
 679                                 dprint("Killed a waypoint that was stuck in air at ", vtos(w.origin), "\n");
 680                                 remove(w);
 681                                 return world;
 682                         }
 683                         trace_endpos_z += 0.1; // don't trust the trace fully
 684 //                      dprint("Moved waypoint at ", vtos(w.origin), " by ", ftos(vlen(w.origin - trace_endpos)));
 685 //                      dprint(" direction: ", vtos((trace_endpos - w.origin)), "\n");
 686                         setorigin(w, trace_endpos);
 687                 }
 688         }
 689
 690         waypoint_clearlinks(w);
 691         //waypoint_schedulerelink(w);
 692         return w;
 693 };
 694
 695 // spawnfunc_waypoint map entity
 696 void spawnfunc_waypoint()
 697 {
 698         setorigin(self, self.origin);
 699         // schedule a relink after other waypoints have had a chance to spawn
 700         waypoint_clearlinks(self);
 701         //waypoint_schedulerelink(self);
 702 };
 703
 704 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 705 void waypoint_remove(entity e)
 706 {
 707         // tell all linked waypoints that they need to relink
 708         waypoint_schedulerelink(e.wp00);
 709         waypoint_schedulerelink(e.wp01);
 710         waypoint_schedulerelink(e.wp02);
 711         waypoint_schedulerelink(e.wp03);
 712         waypoint_schedulerelink(e.wp04);
 713         waypoint_schedulerelink(e.wp05);
 714         waypoint_schedulerelink(e.wp06);
 715         waypoint_schedulerelink(e.wp07);
 716         waypoint_schedulerelink(e.wp08);
 717         waypoint_schedulerelink(e.wp09);
 718         waypoint_schedulerelink(e.wp10);
 719         waypoint_schedulerelink(e.wp11);
 720         waypoint_schedulerelink(e.wp12);
 721         waypoint_schedulerelink(e.wp13);
 722         waypoint_schedulerelink(e.wp14);
 723         waypoint_schedulerelink(e.wp15);
 724         waypoint_schedulerelink(e.wp16);
 725         waypoint_schedulerelink(e.wp17);
 726         waypoint_schedulerelink(e.wp18);
 727         waypoint_schedulerelink(e.wp19);
 728         waypoint_schedulerelink(e.wp20);
 729         waypoint_schedulerelink(e.wp21);
 730         waypoint_schedulerelink(e.wp22);
 731         waypoint_schedulerelink(e.wp23);
 732         waypoint_schedulerelink(e.wp24);
 733         waypoint_schedulerelink(e.wp25);
 734         waypoint_schedulerelink(e.wp26);
 735         waypoint_schedulerelink(e.wp27);
 736         waypoint_schedulerelink(e.wp28);
 737         waypoint_schedulerelink(e.wp29);
 738         waypoint_schedulerelink(e.wp30);
 739         waypoint_schedulerelink(e.wp31);
 740         // and now remove the spawnfunc_waypoint
 741         remove(e);
 742 };
 743
 744 // empties the map of waypoints
 745 void waypoint_removeall()
 746 {
 747         local entity head, next;
 748         head = findchain(classname, "waypoint");
 749         while (head)
 750         {
 751                 next = head.chain;
 752                 remove(head);
 753                 head = next;
 754         }
 755 };
 756
 757 // tell all waypoints to relink
 758 // (is this useful at all?)
 759 void waypoint_schedulerelinkall()
 760 {
 761         local entity head;
 762         head = findchain(classname, "waypoint");
 763         while (head)
 764         {
 765                 waypoint_schedulerelink(head);
 766                 head = head.chain;
 767         }
 768 };
 769
 770 // save waypoints to gamedir/data/maps/mapname.waypoints
 771 // TODO: support saving wayboxes
 772 void waypoint_saveall()
 773 {
 774         local string filename, s;
 775         local float file, c;
 776         local entity w;
 777         filename = strcat("maps/", mapname);
 778         filename = strcat(filename, ".waypoints");
 779         file = fopen(filename, FILE_WRITE);
 780         if (file >= 0)
 781         {
 782                 c = 0;
 783                 w = findchain(classname, "waypoint");
 784                 while (w)
 785                 {
 786                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 787                         {
 788                                 s = strcat(vtos(w.origin + w.mins), "\n");
 789                                 s = strcat(s, vtos(w.origin + w.maxs));
 790                                 s = strcat(s, "\n");
 791                                 s = strcat(s, ftos(w.wpflags));
 792                                 s = strcat(s, "\n");
 793                                 fputs(file, s);
 794                                 c = c + 1;
 795                         }
 796                         w = w.chain;
 797                 }
 798                 fclose(file);
 799                 bprint("saved ");
 800                 bprint(ftos(c));
 801                 bprint(" waypoints to maps/");
 802                 bprint(mapname);
 803                 bprint(".waypoints\n");
 804         }
 805         else
 806         {
 807                 bprint("waypoint save to ");
 808                 bprint(filename);
 809                 bprint(" failed\n");
 810         }
 811 };
 812
 813 // load waypoints from file
 814 float waypoint_loadall()
 815 {
 816         local string filename, s;
 817         local float file, cwp, cwb, fl;
 818         local vector m1, m2;
 819         cwp = 0;
 820         cwb = 0;
 821         filename = strcat("maps/", mapname);
 822         filename = strcat(filename, ".waypoints");
 823         file = fopen(filename, FILE_READ);
 824         if (file >= 0)
 825         {
 826                 while (1)
 827                 {
 828                         s = fgets(file);
 829                         if (!s)
 830                                 break;
 831                         m1 = stov(s);
 832                         s = fgets(file);
 833                         if (!s)
 834                                 break;
 835                         m2 = stov(s);
 836                         s = fgets(file);
 837                         if (!s)
 838                                 break;
 839                         fl = stof(s);
 840                         waypoint_spawn(m1, m2, fl);
 841                         if (m1 == m2)
 842                                 cwp = cwp + 1;
 843                         else
 844                                 cwb = cwb + 1;
 845                 }
 846                 fclose(file);
 847                 dprint("loaded ");
 848                 dprint(ftos(cwp));
 849                 dprint(" waypoints and ");
 850                 dprint(ftos(cwb));
 851                 dprint(" wayboxes from maps/");
 852                 dprint(mapname);
 853                 dprint(".waypoints\n");
 854         }
 855         else
 856         {
 857                 dprint("waypoint load from ");
 858                 dprint(filename);
 859                 dprint(" failed\n");
 860         }
 861         return cwp + cwb;
 862 };
 863
 864 void waypoint_spawnforitem(entity e)
 865 {
 866         local entity w;
 867         local vector org;
 868
 869         if(!bot_waypoints_for_items)
 870                 return;
 871
 872         org = e.origin + (e.mins + e.maxs) * 0.5;
 873         org_z = e.origin_z + e.mins_z - PL_MIN_z + 1;
 874         e.nearestwaypointtimeout = time + 1000000000;
 875         // don't spawn an item spawnfunc_waypoint if it already exists
 876         w = findchain(classname, "waypoint");
 877         while (w)
 878         {
 879                 if (w.wpisbox)
 880                 {
 881                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 882                         {
 883                                 e.nearestwaypoint = w;
 884                                 return;
 885                         }
 886                 }
 887                 else
 888                 {
 889                         if (vlen(w.origin - org) < 16)
 890                         {
 891                                 e.nearestwaypoint = w;
 892                                 return;
 893                         }
 894                 }
 895                 w = w.chain;
 896         }
 897         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 898 };
 899
 900 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 901 {
 902         local entity w;
 903         local entity dw;
 904         w = waypoint_spawn(e.absmin, e.absmax, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 905         dw = waypoint_spawn(destination, destination, WAYPOINTFLAG_GENERATED);
 906         // one way link to the destination
 907         w.wp00 = dw;
 908         w.wp00mincost = timetaken; // this is just for jump pads
 909         // the teleporter's nearest spawnfunc_waypoint is this one
 910         // (teleporters are not goals, so this is probably useless)
 911         e.nearestwaypoint = w;
 912         e.nearestwaypointtimeout = time + 1000000000;
 913 };
 914
 915
 916
 917
 918
 919 /////////////////////////////////////////////////////////////////////////////
 920 // goal stack
 921 /////////////////////////////////////////////////////////////////////////////
 922
 923 // completely empty the goal stack, used when deciding where to go
 924 void navigation_clearroute()
 925 {
 926         self.goalcurrent = world;
 927         self.goalstack01 = world;
 928         self.goalstack02 = world;
 929         self.goalstack03 = world;
 930         self.goalstack04 = world;
 931         self.goalstack05 = world;
 932         self.goalstack06 = world;
 933         self.goalstack07 = world;
 934         self.goalstack08 = world;
 935         self.goalstack09 = world;
 936         self.goalstack10 = world;
 937         self.goalstack11 = world;
 938         self.goalstack12 = world;
 939         self.goalstack13 = world;
 940         self.goalstack14 = world;
 941         self.goalstack15 = world;
 942         self.goalstack16 = world;
 943         self.goalstack17 = world;
 944         self.goalstack18 = world;
 945         self.goalstack19 = world;
 946         self.goalstack20 = world;
 947         self.goalstack21 = world;
 948         self.goalstack22 = world;
 949         self.goalstack23 = world;
 950         self.goalstack24 = world;
 951         self.goalstack25 = world;
 952         self.goalstack26 = world;
 953         self.goalstack27 = world;
 954         self.goalstack28 = world;
 955         self.goalstack29 = world;
 956         self.goalstack30 = world;
 957         self.goalstack31 = world;
 958 };
 959
 960 // add a new goal at the beginning of the stack
 961 // (in other words: add a new prerequisite before going to the later goals)
 962 void navigation_pushroute(entity e)
 963 {
 964         self.goalstack31 = self.goalstack30;
 965         self.goalstack30 = self.goalstack29;
 966         self.goalstack29 = self.goalstack28;
 967         self.goalstack28 = self.goalstack27;
 968         self.goalstack27 = self.goalstack26;
 969         self.goalstack26 = self.goalstack25;
 970         self.goalstack25 = self.goalstack24;
 971         self.goalstack24 = self.goalstack23;
 972         self.goalstack23 = self.goalstack22;
 973         self.goalstack22 = self.goalstack21;
 974         self.goalstack21 = self.goalstack20;
 975         self.goalstack20 = self.goalstack19;
 976         self.goalstack19 = self.goalstack18;
 977         self.goalstack18 = self.goalstack17;
 978         self.goalstack17 = self.goalstack16;
 979         self.goalstack16 = self.goalstack15;
 980         self.goalstack15 = self.goalstack14;
 981         self.goalstack14 = self.goalstack13;
 982         self.goalstack13 = self.goalstack12;
 983         self.goalstack12 = self.goalstack11;
 984         self.goalstack11 = self.goalstack10;
 985         self.goalstack10 = self.goalstack09;
 986         self.goalstack09 = self.goalstack08;
 987         self.goalstack08 = self.goalstack07;
 988         self.goalstack07 = self.goalstack06;
 989         self.goalstack06 = self.goalstack05;
 990         self.goalstack05 = self.goalstack04;
 991         self.goalstack04 = self.goalstack03;
 992         self.goalstack03 = self.goalstack02;
 993         self.goalstack02 = self.goalstack01;
 994         self.goalstack01 = self.goalcurrent;
 995         self.goalcurrent = e;
 996 };
 997
 998 // remove first goal from stack
 999 // (in other words: remove a prerequisite for reaching the later goals)
1000 // (used when a spawnfunc_waypoint is reached)
1001 void navigation_poproute()
1002 {
1003         self.goalcurrent = self.goalstack01;
1004         self.goalstack01 = self.goalstack02;
1005         self.goalstack02 = self.goalstack03;
1006         self.goalstack03 = self.goalstack04;
1007         self.goalstack04 = self.goalstack05;
1008         self.goalstack05 = self.goalstack06;
1009         self.goalstack06 = self.goalstack07;
1010         self.goalstack07 = self.goalstack08;
1011         self.goalstack08 = self.goalstack09;
1012         self.goalstack09 = self.goalstack10;
1013         self.goalstack10 = self.goalstack11;
1014         self.goalstack11 = self.goalstack12;
1015         self.goalstack12 = self.goalstack13;
1016         self.goalstack13 = self.goalstack14;
1017         self.goalstack14 = self.goalstack15;
1018         self.goalstack15 = self.goalstack16;
1019         self.goalstack16 = self.goalstack17;
1020         self.goalstack17 = self.goalstack18;
1021         self.goalstack18 = self.goalstack19;
1022         self.goalstack19 = self.goalstack20;
1023         self.goalstack20 = self.goalstack21;
1024         self.goalstack21 = self.goalstack22;
1025         self.goalstack22 = self.goalstack23;
1026         self.goalstack23 = self.goalstack24;
1027         self.goalstack24 = self.goalstack25;
1028         self.goalstack25 = self.goalstack26;
1029         self.goalstack26 = self.goalstack27;
1030         self.goalstack27 = self.goalstack28;
1031         self.goalstack28 = self.goalstack29;
1032         self.goalstack29 = self.goalstack30;
1033         self.goalstack30 = self.goalstack31;
1034         self.goalstack31 = world;
1035 };
1036
1037 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
1038 entity navigation_findnearestwaypoint(entity player, float walkfromwp)
1039 {
1040         local entity waylist, w, best;
1041         local float dist, bestdist;
1042         local vector v, org, pm1, pm2;
1043         pm1 = player.origin + PL_MIN;
1044         pm2 = player.origin + PL_MAX;
1045         waylist = findchain(classname, "waypoint");
1046         // do two scans, because box test is cheaper
1047         w = waylist;
1048         while (w)
1049         {
1050                 // if object is touching spawnfunc_waypoint
1051                 if (boxesoverlap(pm1, pm2, w.absmin, w.absmax))
1052                         return w;
1053                 w = w.chain;
1054         }
1055
1056         org = player.origin + (player.mins_z - PL_MIN_z) * '0 0 1';
1057         if(player.tag_entity)
1058                 org = org + player.tag_entity.origin;
1059         if (navigation_testtracewalk)
1060                 te_plasmaburn(org);
1061         best = world;
1062         bestdist = 1050;
1063
1064         // box check failed, try walk
1065         w = waylist;
1066         while (w)
1067         {
1068                 // if object can walk from spawnfunc_waypoint
1069                 if (w.wpisbox)
1070                 {
1071                         local vector wm1, wm2;
1072                         wm1 = w.origin + w.mins;
1073                         wm2 = w.origin + w.maxs;
1074                         v_x = bound(wm1_x, org_x, wm2_x);
1075                         v_y = bound(wm1_y, org_y, wm2_y);
1076                         v_z = bound(wm1_z, org_z, wm2_z);
1077                 }
1078                 else
1079                         v = w.origin;
1080                 dist = vlen(v - org);
1081                 if (bestdist > dist)
1082                 {
1083                         if (walkfromwp)
1084                         {
1085                                 traceline(v, org, TRUE, player);
1086                                 if (trace_fraction == 1)
1087                                 if (tracewalk(player, v, PL_MIN, PL_MAX, org, MOVE_NORMAL))
1088                                 {
1089                                         bestdist = dist;
1090                                         best = w;
1091                                 }
1092                         }
1093                         else
1094                         {
1095                                 traceline(v, org, TRUE, player);
1096                                 if (trace_fraction == 1)
1097                                 if (tracewalk(player, org, PL_MIN, PL_MAX, v, MOVE_NORMAL))
1098                                 {
1099                                         bestdist = dist;
1100                                         best = w;
1101                                 }
1102                         }
1103                 }
1104                 w = w.chain;
1105         }
1106         return best;
1107 }
1108
1109 // finds the waypoints near the bot initiating a navigation query
1110 float navigation_markroutes_nearestwaypoints(entity waylist, float maxdist)
1111 {
1112         local entity head;
1113         local vector v, m1, m2, diff;
1114         local float c;
1115 //      navigation_testtracewalk = TRUE;
1116         c = 0;
1117         head = waylist;
1118         while (head)
1119         {
1120                 if (!head.wpconsidered)
1121                 {
1122                         if (head.wpisbox)
1123                         {
1124                                 m1 = head.origin + head.mins;
1125                                 m2 = head.origin + head.maxs;
1126                                 v = self.origin;
1127                                 v_x = bound(m1_x, v_x, m2_x);
1128                                 v_y = bound(m1_y, v_y, m2_y);
1129                                 v_z = bound(m1_z, v_z, m2_z);
1130                         }
1131                         else
1132                                 v = head.origin;
1133                         diff = v - self.origin;
1134                         diff_z = max(0, diff_z);
1135                         if (vlen(diff) < maxdist)
1136                         {
1137                                 head.wpconsidered = TRUE;
1138                                 if (tracewalk(self, self.origin, self.mins, self.maxs, v, MOVE_NORMAL))
1139                                 {
1140                                         head.wpnearestpoint = v;
1141                                         head.wpcost = vlen(v - self.origin) + head.dmg;
1142                                         head.wpfire = 1;
1143                                         head.enemy = world;
1144                                         c = c + 1;
1145                                 }
1146                         }
1147                 }
1148                 head = head.chain;
1149         }
1150         //navigation_testtracewalk = FALSE;
1151         return c;
1152 }
1153
1154 // updates a path link if a spawnfunc_waypoint link is better than the current one
1155 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost2, vector p)
1156 {
1157         local vector m1;
1158         local vector m2;
1159         local vector v;
1160         if (wp.wpisbox)
1161         {
1162                 m1 = wp.absmin;
1163                 m2 = wp.absmax;
1164                 v_x = bound(m1_x, p_x, m2_x);
1165                 v_y = bound(m1_y, p_y, m2_y);
1166                 v_z = bound(m1_z, p_z, m2_z);
1167         }
1168         else
1169                 v = wp.origin;
1170         cost2 = cost2 + vlen(v);
1171         if (wp.wpcost > cost2)
1172         {
1173                 wp.wpcost = cost2;
1174                 wp.enemy = w;
1175                 wp.wpfire = 1;
1176                 wp.wpnearestpoint = v;
1177         }
1178 };
1179
1180 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
1181 void navigation_markroutes()
1182 {
1183         local entity w, wp, waylist;
1184         local float searching, cost, cost2;
1185         local vector p;
1186         w = waylist = findchain(classname, "waypoint");
1187         while (w)
1188         {
1189                 w.wpconsidered = FALSE;
1190                 w.wpnearestpoint = '0 0 0';
1191                 w.wpcost = 10000000;
1192                 w.wpfire = 0;
1193                 w.enemy = world;
1194                 w = w.chain;
1195         }
1196
1197         // try a short range search for the nearest waypoints, and expand thesearch repeatedly if none are found
1198         local float i, increment, maxdistance;
1199         increment = 500;
1200         if(self.flags & FL_ONGROUND)
1201                 maxdistance = 50000;
1202         else
1203                 maxdistance = 1500;
1204
1205         for(i=increment;!navigation_markroutes_nearestwaypoints(waylist, i)&&i<maxdistance;i+=increment);
1206
1207         searching = TRUE;
1208         while (searching)
1209         {
1210                 searching = FALSE;
1211                 w = waylist;
1212                 while (w)
1213                 {
1214                         if (w.wpfire)
1215                         {
1216                                 searching = TRUE;
1217                                 w.wpfire = 0;
1218                                 cost = w.wpcost;
1219                                 p = w.wpnearestpoint;
1220                                 wp = w.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp00mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1221                                 wp = w.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp01mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1222                                 wp = w.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp02mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1223                                 wp = w.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp03mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1224                                 wp = w.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp04mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1225                                 wp = w.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp05mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1226                                 wp = w.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp06mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1227                                 wp = w.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp07mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1228                                 wp = w.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp08mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1229                                 wp = w.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp09mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1230                                 wp = w.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp10mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1231                                 wp = w.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp11mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1232                                 wp = w.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp12mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1233                                 wp = w.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp13mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1234                                 wp = w.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp14mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1235                                 wp = w.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp15mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1236                                 wp = w.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp16mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1237                                 wp = w.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp17mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1238                                 wp = w.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp18mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1239                                 wp = w.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp19mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1240                                 wp = w.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp20mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1241                                 wp = w.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp21mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1242                                 wp = w.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp22mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1243                                 wp = w.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp23mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1244                                 wp = w.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp24mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1245                                 wp = w.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp25mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1246                                 wp = w.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp26mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1247                                 wp = w.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp27mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1248                                 wp = w.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp28mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1249                                 wp = w.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp29mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1250                                 wp = w.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp30mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1251                                 wp = w.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp31mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1252                                 }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
1253                         }
1254                         w = w.chain;
1255                 }
1256         }
1257 };
1258
1259 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
1260 .void() havocbot_role;
1261 void() havocbot_role_ctf_offense;
1262 void navigation_routerating(entity e, float f, float rangebias)
1263 {
1264         if (!e)
1265                 return;
1266         //te_wizspike(e.origin);
1267         //bprint(etos(e));
1268         //bprint("\n");
1269         // update the cached spawnfunc_waypoint link on a dynamic item entity
1270         if (time > e.nearestwaypointtimeout)
1271         {
1272                 e.nearestwaypoint = navigation_findnearestwaypoint(e, TRUE);
1273                 e.nearestwaypointtimeout = time + random() * 3 + 5;
1274         }
1275         //dprint(e.classname, " ", ftos(f));
1276         //dprint("-- checking ", e.classname, " (with cost ", ftos(e.nearestwaypoint.wpcost), ")\n");
1277         if (e.nearestwaypoint)
1278         if (e.nearestwaypoint.wpcost < 10000000)
1279         {
1280                 //te_wizspike(e.nearestwaypoint.wpnearestpoint);
1281                 //dprint(e.classname, " ", ftos(f), "/(1+", ftos((e.nearestwaypoint.wpcost + vlen(e.origin - e.nearestwaypoint.wpnearestpoint))), "/", ftos(rangebias), ") = ");
1282                 f = f * rangebias / (rangebias + (e.nearestwaypoint.wpcost + vlen(e.origin - e.nearestwaypoint.wpnearestpoint)));
1283                 //if (self.havocbot_role == havocbot_role_ctf_offense)
1284                 //      dprint("-- considering ", e.classname, " (with rating ", ftos(f), ")\n");
1285                 //dprint(ftos(f));
1286                 if (navigation_bestrating < f)
1287                 {
1288                         navigation_alternativegoal = navigation_bestgoal;
1289                         navigation_bestrating = f;
1290                         navigation_bestgoal = e;
1291                 }
1292         }
1293         //dprint("\n");
1294 };
1295
1296 // replaces the goal stack with the path to a given item
1297 void navigation_routetogoal(entity e)
1298 {
1299         // if already going to this goal, don't stop
1300         //if (self.goalentity == e)
1301         //      return;
1302         // clear the route and add the new one
1303         navigation_clearroute();
1304         self.goalentity = e;
1305         // if there is no goal, just exit
1306         if (!e)
1307                 return;
1308         // put the entity on the goal stack as the only item
1309         navigation_pushroute(e);
1310         //te_smallflash((e.absmin + e.absmax) * 0.5);
1311         //bprint("navigation_routetogoal(");
1312         //bprint(etos(e));
1313         //bprint(") : ");
1314         //bprint(etos(e));
1315         //tracebox(self.origin, '-16 -16 0', '16 16 0', e.origin, TRUE, self);
1316         //if (trace_fraction == 1)
1317         if (tracewalk(self, self.origin, PL_MIN, PL_MAX, e.origin, MOVE_NORMAL))
1318                 return;
1319         // see if there are waypoints describing a path to the item
1320         e = e.nearestwaypoint;
1321         while (e != world)
1322         {
1323                 //bprint(" ");
1324                 //bprint(etos(e));
1325                 //te_smallflash((e.absmin + e.absmax) * 0.5);
1326                 //tracebox(self.origin, '-16 -16 0', '16 16 0', e.origin, TRUE, self);
1327                 //if (trace_fraction == 1)
1328                 //if (tracewalk(self, self.origin, PL_MIN, PL_MAX, e.origin, MOVE_NORMAL))
1329                 //      break;
1330                 // add the spawnfunc_waypoint to the path
1331                 navigation_pushroute(e);
1332                 e = e.enemy;
1333         }
1334         //bprint("\n");
1335 };
1336
1337 // removes any currently touching waypoints from the goal stack
1338 // (this is how bots detect if they have reached a goal)
1339 void navigation_poptouchedgoals()
1340 {
1341         local vector org, m1, m2;
1342         org = self.origin;// + self.velocity * 0.1;
1343         m1 = org + self.mins;
1344         m2 = org + self.maxs;
1345
1346         // Loose goal touching check for running state
1347         if(self.aistatus & AI_STATUS_RUNNING)
1348         if(self.goalcurrent.classname=="waypoint")
1349         {
1350                 if(vlen(self.origin - self.goalcurrent.origin)<150)
1351                 {
1352                                 traceline(self.origin + self.view_ofs , self.goalcurrent.origin, TRUE, world);
1353                                 if(trace_fraction==1)
1354                                 {
1355                                         navigation_poproute();
1356                                 }
1357                 }
1358         }
1359
1360         while (self.goalcurrent && boxesoverlap(m1, m2, self.goalcurrent.absmin, self.goalcurrent.absmax))
1361                 navigation_poproute();
1362 }
1363
1364 // begin a goal selection session (queries spawnfunc_waypoint network)
1365 void navigation_goalrating_start()
1366 {
1367         navigation_bestrating = -1;
1368         navigation_bestgoal = world;
1369         navigation_markroutes();
1370 };
1371
1372 // ends a goal selection session (updates goal stack to the best goal)
1373 void navigation_goalrating_end()
1374 {
1375         if (self.havocbot_role == havocbot_role_ctf_offense)
1376                 dprint(navigation_bestgoal.classname, " (with rating ", ftos(navigation_bestrating), ")\n");
1377         self.alternativegoal = navigation_alternativegoal;
1378         navigation_routetogoal(navigation_bestgoal);
1379 };
1380
1381
1382
1383
1384
1385 //////////////////////////////////////////////////////////////////////////////
1386 // general bot functions
1387 //////////////////////////////////////////////////////////////////////////////
1388
1389 .float isbot; // true if this client is actually a bot
1390
1391 float skill;
1392 entity bot_list;
1393 .entity nextbot;
1394
1395 float sv_maxspeed;
1396 .float createdtime;
1397
1398 .float bot_preferredcolors;
1399
1400 .float bot_attack;
1401 .float bot_dodge;
1402 .float bot_dodgerating;
1403
1404 //.float bot_painintensity;
1405 .float bot_firetimer;
1406 //.float bot_oldhealth;
1407 .void() bot_ai;
1408
1409 .entity bot_aimtarg;
1410 .float bot_aimlatency;
1411 .vector bot_aimselforigin;
1412 .vector bot_aimselfvelocity;
1413 .vector bot_aimtargorigin;
1414 .vector bot_aimtargvelocity;
1415
1416 .float bot_pickup;
1417 .float(entity player, entity item) bot_pickupevalfunc;
1418 .float bot_pickupbasevalue;
1419 .float bot_canfire;
1420 .float bot_strategytime;
1421
1422 // used for aiming currently
1423 // FIXME: make the weapon code use these and then replace the calculations here with a call to the weapon code
1424 vector shotorg;
1425 vector shotdir;
1426
1427 const float BOTSKINS = 19;
1428 const float BOTNAMES = 32;
1429 string bot_namefornumber(float r)
1430 {
1431         if (r <  1) return "Thunderstorm";
1432         if (r <  2) return "Darkness";
1433         if (r <  3) return "Scorcher";
1434         if (r <  4) return "Paranoia";
1435         if (r <  5) return "Eureka";
1436         if (r <  6) return "Mystery";
1437         if (r <  7) return "Toxic";
1438         if (r <  8) return "Dominion";
1439         if (r <  9) return "Pegasus";
1440         if (r < 10) return "Sensible";
1441         if (r < 11) return "Gator";
1442         if (r < 12) return "Kangaroo";
1443         if (r < 13) return "Deadline";
1444         if (r < 14) return "Frosty";
1445         if (r < 15) return "Roadkill";
1446         if (r < 16) return "Death";
1447         if (r < 17) return "Panic";
1448         if (r < 18) return "Discovery";
1449         if (r < 19) return "Shadow";
1450         if (r < 20) return "Acidic";
1451         if (r < 21) return "Dominator";
1452         if (r < 22) return "Hellfire";
1453         if (r < 23) return "Necrotic";
1454         if (r < 24) return "Newbie";
1455         if (r < 25) return "Spellbinder";
1456         if (r < 26) return "Lion";
1457         if (r < 27) return "Controlled";
1458         if (r < 28) return "Airhead";
1459         if (r < 29) return "Delirium";
1460         if (r < 30) return "Resurrection";
1461         if (r < 31) return "Danger";
1462         return "Flatline";
1463 };
1464
1465 string bot_skinfornumber(float r)
1466 {
1467              if (r <  1) {self.playermodel = "models/player/carni.zym"          ;self.playerskin = "0";return "Carni"          ;}
1468         else if (r <  2) {self.playermodel = "models/player/carni.zym"          ;self.playerskin = "1";return "Armored Carni"  ;}
1469         else if (r <  3) {self.playermodel = "models/player/crash.zym"          ;self.playerskin = "0";return "Quark"          ;}
1470         else if (r <  4) {self.playermodel = "models/player/grunt.zym"          ;self.playerskin = "0";return "Grunt"          ;}
1471         else if (r <  5) {self.playermodel = "models/player/headhunter.zym"     ;self.playerskin = "0";return "HeadHunter"     ;}
1472         else if (r <  6) {self.playermodel = "models/player/insurrectionist.zym";self.playerskin = "0";return "Insurrectionist";}
1473         else if (r <  7) {self.playermodel = "models/player/lurk.zym"           ;self.playerskin = "0";return "Lurk"           ;}
1474         else if (r <  8) {self.playermodel = "models/player/lurk.zym"           ;self.playerskin = "1";return "Reptile"        ;}
1475         else if (r <  9) {self.playermodel = "models/player/lycanthrope.zym"    ;self.playerskin = "0";return "Lycanthrope"    ;}
1476         else if (r < 10) {self.playermodel = "models/player/marine.zym"         ;self.playerskin = "0";return "Marine"         ;}
1477         else if (r < 11) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "0";return "Nexus"          ;}
1478         else if (r < 12) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "1";return "Mulder"         ;}
1479         else if (r < 13) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "2";return "Xolar"          ;}
1480         else if (r < 14) {self.playermodel = "models/player/pyria.zym"          ;self.playerskin = "0";return "Pyria"          ;}
1481         else if (r < 15) {self.playermodel = "models/player/shock.zym"          ;self.playerskin = "0";return "Shock"          ;}
1482         else if (r < 16) {self.playermodel = "models/player/skadi.zym"          ;self.playerskin = "0";return "Skadi"          ;}
1483         else if (r < 17) {self.playermodel = "models/player/specop.zym"         ;self.playerskin = "0";return "Specop"         ;}
1484         else             {self.playermodel = "models/player/visitant.zym"       ;self.playerskin = "0";return "Fricka"         ;}
1485 };
1486
1487 void bot_setnameandstuff()
1488 {
1489         local string name, prefix, suffix;
1490         local float r, b, shirt, pants;
1491
1492         prefix = cvar_string("bot_prefix");
1493         suffix = cvar_string("bot_suffix");
1494
1495         // this is really only a default, JoinBestTeam is called later
1496         pants = floor(random() * 15);
1497         shirt = floor(random() * 15);
1498         //shirt = pants;
1499         setcolor(self, shirt * 16 + pants);
1500         self.bot_preferredcolors = self.clientcolors;
1501
1502         // now pick a name...
1503
1504         if (cvar("bot_usemodelnames"))
1505         {
1506                 // first see if all skins are taken
1507                 b = 0;
1508                 do
1509                 {
1510                         name = bot_skinfornumber(b);
1511                         b = b + 1;
1512                 }
1513                 while (b < BOTSKINS && find(world, netname, name));
1514
1515                 // randomly pick a skin, if it's taken either repeat until we find one,
1516                 // or give up if we already know all skins are taken
1517                 do
1518                 {
1519                         r = floor(random() * BOTSKINS);
1520                         name = bot_skinfornumber(r);
1521                 }
1522                 while (b < BOTSKINS && find(world, netname, name));
1523         }
1524         else
1525         {
1526                 // first see if all names are taken
1527                 b = 0;
1528                 do
1529                 {
1530                         name = bot_namefornumber(b);
1531                         b = b + 1;
1532                 }
1533                 while (b < BOTNAMES && find(world, netname, name));
1534
1535                 // randomly pick a name, if it's taken either repeat until we find one,
1536                 // or give up if we already know all names are taken
1537                 do
1538                 {
1539                         r = floor(random() * BOTNAMES);
1540                         name = bot_namefornumber(r);
1541                 }
1542                 while (b < BOTNAMES && find(world, netname, name));
1543
1544                 // randomly pick a skin
1545                 bot_skinfornumber(floor(random() * BOTSKINS));
1546         }
1547         if(!cvar("g_campaign"))
1548                 self.netname = self.netname_freeme = strzone(strcat(prefix, name, suffix));
1549         else
1550                 self.netname = name;
1551 };
1552
1553 float bot_custom_weapon;
1554 float bot_distance_far;
1555 float bot_distance_close;
1556
1557 float bot_weapons_far[WEP_LAST];
1558 float bot_weapons_mid[WEP_LAST];
1559 float bot_weapons_close[WEP_LAST];
1560
1561 void bot_custom_weapon_priority_setup()
1562 {
1563         local float tokens, i, c, w;
1564
1565         bot_custom_weapon = FALSE;
1566
1567         if(     cvar_string("bot_ai_custom_weapon_priority_far") == "" ||
1568                 cvar_string("bot_ai_custom_weapon_priority_mid") == "" ||
1569                 cvar_string("bot_ai_custom_weapon_priority_close") == "" ||
1570                 cvar_string("bot_ai_custom_weapon_priority_distances") == ""
1571         )
1572                 return;
1573
1574         // Parse distances
1575         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_distances")," ");
1576
1577         if (tokens!=2)
1578                 return;
1579
1580         bot_distance_far = stof(argv(0));
1581         bot_distance_close = stof(argv(1));
1582
1583         if(bot_distance_far < bot_distance_close){
1584                 bot_distance_far = stof(argv(1));
1585                 bot_distance_close = stof(argv(0));
1586         }
1587
1588         // Initialize list of weapons
1589         bot_weapons_far[0] = -1;
1590         bot_weapons_mid[0] = -1;
1591         bot_weapons_close[0] = -1;
1592
1593         // Parse far distance weapon priorities
1594         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_far")," ");
1595
1596         c = 0;
1597         for(i=0; i < tokens && c < WEP_COUNT; ++i){
1598                 w = stof(argv(i));
1599                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
1600                         bot_weapons_far[c] = w;
1601                         ++c;
1602                 }
1603         }
1604         if(c < WEP_COUNT)
1605                 bot_weapons_far[c] = -1;
1606
1607         // Parse mid distance weapon priorities
1608         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_mid")," ");
1609
1610         c = 0;
1611         for(i=0; i < tokens && c < WEP_COUNT; ++i){
1612                 w = stof(argv(i));
1613                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
1614                         bot_weapons_mid[c] = w;
1615                         ++c;
1616                 }
1617         }
1618         if(c < WEP_COUNT)
1619                 bot_weapons_mid[c] = -1;
1620
1621         // Parse close distance weapon priorities
1622         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_close")," ");
1623
1624         c = 0;
1625         for(i=0; i < tokens && i < WEP_COUNT; ++i){
1626                 w = stof(argv(i));
1627                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
1628                         bot_weapons_close[c] = w;
1629                         ++c;
1630                 }
1631         }
1632         if(c < WEP_COUNT)
1633                 bot_weapons_close[c] = -1;
1634
1635         bot_custom_weapon = TRUE;
1636 };
1637
1638
1639 void bot_endgame()
1640 {
1641         local entity e;
1642         //dprint("bot_endgame\n");
1643         e = bot_list;
1644         while (e)
1645         {
1646                 setcolor(e, e.bot_preferredcolors);
1647                 e = e.nextbot;
1648         }
1649         // if dynamic waypoints are ever implemented, save them here
1650 };
1651
1652 float bot_ignore_bots; // let bots not attack other bots (only works in non-teamplay)
1653 float bot_shouldattack(entity e)
1654 {
1655         if (e.team == self.team)
1656         {
1657                 if (e == self)
1658                         return FALSE;
1659                 if (teams_matter)
1660                 if (e.team != 0)
1661                         return FALSE;
1662         }
1663         if(!teams_matter)
1664                 if(bot_ignore_bots)
1665                         if(clienttype(e) == CLIENTTYPE_BOT)
1666                                 return FALSE;
1667         if (!e.takedamage)
1668                 return FALSE;
1669         if (e.deadflag)
1670                 return FALSE;
1671         if (e.BUTTON_CHAT)
1672                 return FALSE;
1673         if(g_minstagib)
1674         if(e.items & IT_STRENGTH)
1675                 return FALSE;
1676         return TRUE;
1677 };
1678
1679 void bot_lagfunc(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
1680 {
1681         if(self.flags & FL_INWATER)
1682         {
1683                 self.bot_aimtarg = world;
1684                 return;
1685         }
1686         self.bot_aimtarg = e1;
1687         self.bot_aimlatency = self.ping; // FIXME?  Shouldn't this be in the lag item?
1688         self.bot_aimselforigin = v1;
1689         self.bot_aimselfvelocity = v2;
1690         self.bot_aimtargorigin = v3;
1691         self.bot_aimtargvelocity = v4;
1692         if(skill <= 0)
1693                 self.bot_canfire = (random() < 0.8);
1694         else if(skill <= 1)
1695                 self.bot_canfire = (random() < 0.9);
1696         else if(skill <= 2)
1697                 self.bot_canfire = (random() < 0.95);
1698         else
1699                 self.bot_canfire = 1;
1700 };
1701
1702 .float bot_nextthink;
1703 .float bot_badaimtime;
1704 .float bot_aimthinktime;
1705 .vector bot_mouseaim;
1706 .vector bot_badaimoffset;
1707 .vector bot_1st_order_aimfilter;
1708 .vector bot_2nd_order_aimfilter;
1709 .vector bot_3th_order_aimfilter;
1710 .vector bot_4th_order_aimfilter;
1711 .vector bot_5th_order_aimfilter;
1712 .vector bot_olddesiredang;
1713 float bot_aimdir(vector v, float maxfiredeviation)
1714 {
1715 /*
1716         local float snapcos;
1717         local vector olddir, newdir, desireddir;
1718
1719         makevectors(self.v_angle);
1720         olddir = newdir = v_forward;
1721         desireddir = normalize(v);
1722         snapcos = cos(cvar("bot_ai_aimskill_snapangle") * frametime * (skill + 1) * 0.5);
1723         if (desireddir * olddir < v_forward_x)
1724                 newdir = desireddir;
1725         else
1726         {
1727                 local float blendrate;
1728                 blendrate = cvar("bot_ai_aimskill_blendrate") * frametime * (skill + 1) * 0.5;
1729                 newdir = olddir + (desireddir - olddir) * bound(0, blendrate, 1);
1730         }
1731
1732         // decide whether to fire this time
1733         if ((desireddir * newdir) >= cos(maxfiredeviation))
1734                 self.bot_firetimer = time + 0.3;
1735
1736         self.v_angle = vectoangles(newdir);
1737         self.v_angle_x = self.v_angle_x * -1;
1738
1739         makevectors(self.v_angle);
1740         shotorg = self.origin + self.view_ofs;
1741         shotdir = newdir;
1742
1743         return time < self.bot_firetimer;
1744 */
1745
1746         local float dist;
1747         local vector desiredang, diffang;
1748
1749         //dprint("aim ", self.netname, ": old:", vtos(self.v_angle));
1750         // make sure v_angle is sane first
1751         self.v_angle_y = self.v_angle_y - floor(self.v_angle_y / 360) * 360;
1752         self.v_angle_z = 0;
1753
1754         // get the desired angles to aim at
1755         //dprint(" at:", vtos(v));
1756         v = normalize(v);
1757         //te_lightning2(world, self.origin + self.view_ofs, self.origin + self.view_ofs + v * 200);
1758         if (time >= self.bot_badaimtime)
1759         {
1760                 self.bot_badaimtime = max(self.bot_badaimtime + 0.3, time);
1761                 self.bot_badaimoffset = randomvec() * bound(0, 5 - 0.5 * (skill+self.bot_offsetskill), 5) * cvar("bot_ai_aimskill_offset");
1762         }
1763         desiredang = vectoangles(v) + self.bot_badaimoffset;
1764         //dprint(" desired:", vtos(desiredang));
1765         if (desiredang_x >= 180)
1766                 desiredang_x = desiredang_x - 360;
1767         desiredang_x = bound(-90, 0 - desiredang_x, 90);
1768         desiredang_z = self.v_angle_z;
1769         //dprint(" / ", vtos(desiredang));
1770
1771         //// pain throws off aim
1772         //if (self.bot_painintensity)
1773         //{
1774         //      // shake from pain
1775         //      desiredang = desiredang + randomvec() * self.bot_painintensity * 0.2;
1776         //}
1777
1778         // calculate turn angles
1779         diffang = (desiredang - self.bot_olddesiredang);
1780         // wrap yaw turn
1781         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
1782         if (diffang_y >= 180)
1783                 diffang_y = diffang_y - 360;
1784         self.bot_olddesiredang = desiredang;
1785         //dprint(" diff:", vtos(diffang));
1786
1787         // Here we will try to anticipate the comming aiming direction
1788         self.bot_1st_order_aimfilter= self.bot_1st_order_aimfilter
1789                 + (diffang * (1 / frametime)    - self.bot_1st_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_1st"),1);
1790         self.bot_2nd_order_aimfilter= self.bot_2nd_order_aimfilter
1791                 + (self.bot_1st_order_aimfilter - self.bot_2nd_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_2nd"),1);
1792         self.bot_3th_order_aimfilter= self.bot_3th_order_aimfilter
1793                 + (self.bot_2nd_order_aimfilter - self.bot_3th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_3th"),1);
1794         self.bot_4th_order_aimfilter= self.bot_4th_order_aimfilter
1795                 + (self.bot_3th_order_aimfilter - self.bot_4th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_4th"),1);
1796         self.bot_5th_order_aimfilter= self.bot_5th_order_aimfilter
1797                 + (self.bot_4th_order_aimfilter - self.bot_5th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_5th"),1);
1798
1799         local float blend;
1800         //blend = (bound(0,skill,10)*0.1)*pow(1-bound(0,skill,10)*0.05,2.5)*5.656854249; //Plot formule before changing !
1801         blend = bound(0,skill,10)*0.1;
1802         desiredang = desiredang + blend *
1803         (
1804                   self.bot_1st_order_aimfilter * cvar("bot_ai_aimskill_order_mix_1st")
1805                 + self.bot_2nd_order_aimfilter * cvar("bot_ai_aimskill_order_mix_2nd")
1806                 + self.bot_3th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_3th")
1807                 + self.bot_4th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_4th")
1808                 + self.bot_5th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_5th")
1809         );
1810
1811         // calculate turn angles
1812         diffang = desiredang - self.bot_mouseaim;
1813         // wrap yaw turn
1814         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
1815         if (diffang_y >= 180)
1816                 diffang_y = diffang_y - 360;
1817         //dprint(" diff:", vtos(diffang));
1818
1819         if (time >= self.bot_aimthinktime)
1820         {
1821                 self.bot_aimthinktime = max(self.bot_aimthinktime + 0.5 - 0.05*(skill+self.bot_thinkskill), time);
1822                 self.bot_mouseaim = self.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-skill,10));
1823         }
1824
1825         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
1826
1827         diffang = self.bot_mouseaim - desiredang;
1828         // wrap yaw turn
1829         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
1830         if (diffang_y >= 180)
1831                 diffang_y = diffang_y - 360;
1832         desiredang = desiredang + diffang * bound(0,cvar("bot_ai_aimskill_think"),1);
1833
1834         // calculate turn angles
1835         diffang = desiredang - self.v_angle;
1836         // wrap yaw turn
1837         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
1838         if (diffang_y >= 180)
1839                 diffang_y = diffang_y - 360;
1840         //dprint(" diff:", vtos(diffang));
1841
1842         // jitter tracking
1843         dist = vlen(diffang);
1844         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
1845
1846         // turn
1847         local float r, fixedrate, blendrate;
1848         fixedrate = cvar("bot_ai_aimskill_fixedrate") / bound(1,dist,1000);
1849         blendrate = cvar("bot_ai_aimskill_blendrate");
1850         r = max(fixedrate, blendrate);
1851         //self.v_angle = self.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
1852         self.v_angle = self.v_angle + diffang * bound(frametime, r * frametime * (2+pow(skill+self.bot_mouseskill,3)*0.005-random()), 1);
1853         self.v_angle = self.v_angle * bound(0,cvar("bot_ai_aimskill_mouse"),1) + desiredang * bound(0,(1-cvar("bot_ai_aimskill_mouse")),1);
1854         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
1855         //self.v_angle = self.v_angle + diffang * (1/ blendrate);
1856         self.v_angle_z = 0;
1857         self.v_angle_y = self.v_angle_y - floor(self.v_angle_y / 360) * 360;
1858         //dprint(" turn:", vtos(self.v_angle));
1859
1860         makevectors(self.v_angle);
1861         shotorg = self.origin + self.view_ofs;
1862         shotdir = v_forward;
1863
1864         //dprint(" dir:", vtos(v_forward));
1865         //te_lightning2(world, shotorg, shotorg + shotdir * 100);
1866
1867         // calculate turn angles again
1868         //diffang = desiredang - self.v_angle;
1869         //diffang_y = diffang_y - floor(diffang_y / 360) * 360;
1870         //if (diffang_y >= 180)
1871         //      diffang_y = diffang_y - 360;
1872
1873         //dprint("e ", vtos(diffang), " < ", ftos(maxfiredeviation), "\n");
1874
1875         // decide whether to fire this time
1876         // note the maxfiredeviation is in degrees so this has to convert to radians first
1877         //if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
1878         if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
1879         if (vlen(trace_endpos-shotorg) < 500+500*bound(0, skill, 10) || random()*random()>bound(0,skill*0.05,1))
1880                 self.bot_firetimer = time + bound(0.1, 0.5-skill*0.05, 0.5);
1881         //traceline(shotorg,shotorg+shotdir*1000,FALSE,world);
1882         //dprint(ftos(maxfiredeviation),"\n");
1883         //dprint(" diff:", vtos(diffang), "\n");
1884
1885         return self.bot_canfire && (time < self.bot_firetimer);
1886 };
1887
1888 vector bot_shotlead(vector targorigin, vector targvelocity, float shotspeed, float shotdelay)
1889 {
1890         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
1891         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
1892 };
1893
1894 float bot_aim(float shotspeed, float shotspeedupward, float maxshottime, float applygravity)
1895 {
1896         local float f, r;
1897         local vector v;
1898         /*
1899         eprint(self);
1900         dprint("bot_aim(", ftos(shotspeed));
1901         dprint(", ", ftos(shotspeedupward));
1902         dprint(", ", ftos(maxshottime));
1903         dprint(", ", ftos(applygravity));
1904         dprint(");\n");
1905         */
1906         if (!shotspeed)
1907         {
1908                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " shotspeed is zero!\n");
1909                 shotspeed = 1000000;
1910         }
1911         if (!maxshottime)
1912         {
1913                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " maxshottime is zero!\n");
1914                 maxshottime = 1;
1915         }
1916         makevectors(self.v_angle);
1917         shotorg = self.origin + self.view_ofs;
1918         shotdir = v_forward;
1919         v = bot_shotlead(self.bot_aimtargorigin, self.bot_aimtargvelocity, shotspeed, self.bot_aimlatency);
1920         local float distanceratio;
1921         distanceratio =sqrt(bound(0,skill,10000))*0.3*(vlen(v-shotorg)-100)/cvar("bot_ai_aimskill_firetolerance_distdegrees");
1922         distanceratio = bound(0,distanceratio,1);
1923         r =  (cvar("bot_ai_aimskill_firetolerance_maxdegrees")-cvar("bot_ai_aimskill_firetolerance_mindegrees"))
1924                 * (1-distanceratio) + cvar("bot_ai_aimskill_firetolerance_mindegrees");
1925         if (applygravity && self.bot_aimtarg)
1926         {
1927                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', self.bot_aimtarg, shotspeed, shotspeedupward, maxshottime, 0, self))
1928                         return FALSE;
1929                 f = bot_aimdir(findtrajectory_velocity - shotspeedupward * '0 0 1', r);
1930         }
1931         else
1932         {
1933                 f = bot_aimdir(v - shotorg, r);
1934                 //dprint("AIM: ");dprint(vtos(self.bot_aimtargorigin));dprint(" + ");dprint(vtos(self.bot_aimtargvelocity));dprint(" * ");dprint(ftos(self.bot_aimlatency + vlen(self.bot_aimtargorigin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
1935                 traceline(shotorg, shotorg + shotdir * 10000, FALSE, self);
1936                 if (trace_ent.takedamage)
1937                 if (trace_fraction < 1)
1938                 if (!bot_shouldattack(trace_ent))
1939                         return FALSE;
1940                 traceline(shotorg, self.bot_aimtargorigin, FALSE, self);
1941                 if (trace_fraction < 1)
1942                 if (trace_ent != self.enemy)
1943                 if (!bot_shouldattack(trace_ent))
1944                         return FALSE;
1945         }
1946         if (r > maxshottime * shotspeed)
1947                 return FALSE;
1948         return f;
1949 };
1950
1951 // TODO: move this painintensity code to the player damage code
1952 void bot_think()
1953 {
1954         if (self.bot_nextthink > time)
1955                 return;
1956         self.bot_nextthink = self.bot_nextthink + cvar("bot_ai_thinkinterval");
1957         //if (self.bot_painintensity > 0)
1958         //      self.bot_painintensity = self.bot_painintensity - (skill + 1) * 40 * frametime;
1959
1960         //self.bot_painintensity = self.bot_painintensity + self.bot_oldhealth - self.health;
1961         //self.bot_painintensity = bound(0, self.bot_painintensity, 100);
1962
1963         if(time < game_starttime || ((cvar("g_campaign") && !campaign_bots_may_start)))
1964         {
1965                 self.nextthink = time + 0.5;
1966                 return;
1967         }
1968
1969         if (self.fixangle)
1970         {
1971                 self.v_angle = self.angles;
1972                 self.v_angle_z = 0;
1973                 self.fixangle = FALSE;
1974         }
1975
1976         self.dmg_take = 0;
1977         self.dmg_save = 0;
1978         self.dmg_inflictor = world;
1979
1980         // calculate an aiming latency based on the skill setting
1981         // (simulated network latency + naturally delayed reflexes)
1982         //self.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
1983         // minimum ping 20+10 random
1984         self.ping = bound(0,0.07 - bound(0, skill * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
1985         // skill 10 = ping 0.2 (adrenaline)
1986         // skill 0 = ping 0.7 (slightly drunk)
1987
1988         // clear buttons
1989         self.BUTTON_ATCK = 0;
1990         self.button1 = 0;
1991         self.BUTTON_JUMP = 0;
1992         self.BUTTON_ATCK2 = 0;
1993         self.BUTTON_ZOOM = 0;
1994         self.BUTTON_CROUCH = 0;
1995         self.BUTTON_HOOK = 0;
1996         self.BUTTON_INFO = 0;
1997         self.button8 = 0;
1998         self.BUTTON_CHAT = 0;
1999         self.BUTTON_USE = 0;
2000
2001         // if dead, just wait until we can respawn
2002         if (self.deadflag)
2003         {
2004                 if (self.deadflag == DEAD_DEAD)
2005                 {
2006                         self.BUTTON_JUMP = 1; // press jump to respawn
2007                         self.bot_strategytime = 0;
2008                 }
2009                 return;
2010         }
2011
2012         // now call the current bot AI (havocbot for example)
2013         self.bot_ai();
2014 };
2015
2016 entity bot_strategytoken;
2017 float bot_strategytoken_taken;
2018 entity player_list;
2019 .entity nextplayer;
2020 void bot_relinkplayerlist()
2021 {
2022         local entity e;
2023         local entity prevbot;
2024         player_count = 0;
2025         currentbots = 0;
2026         player_list = e = findchainflags(flags, FL_CLIENT);
2027         bot_list = world;
2028         prevbot = world;
2029         while (e)
2030         {
2031                 player_count = player_count + 1;
2032                 e.nextplayer = e.chain;
2033                 if (clienttype(e) == CLIENTTYPE_BOT)
2034                 {
2035                         if (prevbot)
2036                                 prevbot.nextbot = e;
2037                         else
2038                                 bot_list = e;
2039                         prevbot = e;
2040                         currentbots = currentbots + 1;
2041                 }
2042                 e = e.chain;
2043         }
2044         dprint(strcat("relink: ", ftos(currentbots), " bots seen.\n"));
2045         bot_strategytoken = bot_list;
2046         bot_strategytoken_taken = TRUE;
2047 };
2048
2049 void() havocbot_setupbot;
2050 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam);
2051
2052 void bot_clientdisconnect()
2053 {
2054         if (clienttype(self) != CLIENTTYPE_BOT)
2055                 return;
2056         if(self.netname_freeme)
2057                 strunzone(self.netname_freeme);
2058         self.netname_freeme = string_null;
2059 }
2060
2061 void bot_clientconnect()
2062 {
2063         if (clienttype(self) != CLIENTTYPE_BOT)
2064                 return;
2065         self.bot_preferredcolors = self.clientcolors;
2066         self.bot_nextthink = time - random();
2067         self.lag_func = bot_lagfunc;
2068         self.isbot = TRUE;
2069         self.createdtime = self.nextthink;
2070         JoinBestTeam(self, FALSE, TRUE);
2071         havocbot_setupbot();
2072         self.bot_mouseskill=random()-0.5;
2073         self.bot_thinkskill=random()-0.5;
2074         self.bot_predictionskill=random()-0.5;
2075         self.bot_offsetskill=random()-0.5;
2076 };
2077
2078 entity bot_spawn()
2079 {
2080         local entity oldself, bot;
2081         bot = spawnclient();
2082         if (bot)
2083         {
2084                 currentbots = currentbots + 1;
2085                 oldself = self;
2086                 self = bot;
2087                 bot_setnameandstuff();
2088                 ClientConnect();
2089                 PutClientInServer();
2090                 self = oldself;
2091         }
2092         return bot;
2093 };
2094
2095 void CheckAllowedTeams(entity for_whom); void GetTeamCounts(entity other); float c1, c2, c3, c4;
2096 void bot_removefromlargestteam()
2097 {
2098         local float besttime, bestcount, thiscount;
2099         local entity best, head;
2100         CheckAllowedTeams(world);
2101         GetTeamCounts(world);
2102         head = findchainfloat(isbot, TRUE);
2103         if (!head)
2104                 return;
2105         best = head;
2106         besttime = head.createdtime;
2107         bestcount = 0;
2108         while (head)
2109         {
2110                 if(head.team == COLOR_TEAM1)
2111                         thiscount = c1;
2112                 else if(head.team == COLOR_TEAM2)
2113                         thiscount = c2;
2114                 else if(head.team == COLOR_TEAM3)
2115                         thiscount = c3;
2116                 else if(head.team == COLOR_TEAM4)
2117                         thiscount = c4;
2118                 else
2119                         thiscount = 0;
2120                 if (thiscount > bestcount)
2121                 {
2122                         bestcount = thiscount;
2123                         besttime = head.createdtime;
2124                         best = head;
2125                 }
2126                 else if (thiscount == bestcount && besttime < head.createdtime)
2127                 {
2128                         besttime = head.createdtime;
2129                         best = head;
2130                 }
2131                 head = head.chain;
2132         }
2133         currentbots = currentbots - 1;
2134         dropclient(best);
2135 };
2136
2137 void bot_removenewest()
2138 {
2139         local float besttime;
2140         local entity best, head;
2141
2142         if(teams_matter)
2143         {
2144                 bot_removefromlargestteam();
2145                 return;
2146         }
2147
2148         head = findchainfloat(isbot, TRUE);
2149         if (!head)
2150                 return;
2151         best = head;
2152         besttime = head.createdtime;
2153         while (head)
2154         {
2155                 if (besttime < head.createdtime)
2156                 {
2157                         besttime = head.createdtime;
2158                         best = head;
2159                 }
2160                 head = head.chain;
2161         }
2162         currentbots = currentbots - 1;
2163         dropclient(best);
2164 };
2165
2166 float botframe_waypointeditorlightningtime;
2167 void botframe_showwaypointlinks()
2168 {
2169         local entity player, head, w;
2170         if (time < botframe_waypointeditorlightningtime)
2171                 return;
2172         botframe_waypointeditorlightningtime = time + 0.5;
2173         player = find(world, classname, "player");
2174         while (player)
2175         {
2176                 if (!player.isbot)
2177                 if (player.flags & FL_ONGROUND)
2178                 {
2179                         //navigation_testtracewalk = TRUE;
2180                         head = navigation_findnearestwaypoint(player, FALSE);
2181                         //navigation_testtracewalk = FALSE;
2182                         if (head)
2183                         {
2184                                 w = head     ;if (w) te_lightning2(world, w.origin, player.origin);
2185                                 w = head.wp00;if (w) te_lightning2(world, w.origin, head.origin);
2186                                 w = head.wp01;if (w) te_lightning2(world, w.origin, head.origin);
2187                                 w = head.wp02;if (w) te_lightning2(world, w.origin, head.origin);
2188                                 w = head.wp03;if (w) te_lightning2(world, w.origin, head.origin);
2189                                 w = head.wp04;if (w) te_lightning2(world, w.origin, head.origin);
2190                                 w = head.wp05;if (w) te_lightning2(world, w.origin, head.origin);
2191                                 w = head.wp06;if (w) te_lightning2(world, w.origin, head.origin);
2192                                 w = head.wp07;if (w) te_lightning2(world, w.origin, head.origin);
2193                                 w = head.wp08;if (w) te_lightning2(world, w.origin, head.origin);
2194                                 w = head.wp09;if (w) te_lightning2(world, w.origin, head.origin);
2195                                 w = head.wp10;if (w) te_lightning2(world, w.origin, head.origin);
2196                                 w = head.wp11;if (w) te_lightning2(world, w.origin, head.origin);
2197                                 w = head.wp12;if (w) te_lightning2(world, w.origin, head.origin);
2198                                 w = head.wp13;if (w) te_lightning2(world, w.origin, head.origin);
2199                                 w = head.wp14;if (w) te_lightning2(world, w.origin, head.origin);
2200                                 w = head.wp15;if (w) te_lightning2(world, w.origin, head.origin);
2201                                 w = head.wp16;if (w) te_lightning2(world, w.origin, head.origin);
2202                                 w = head.wp17;if (w) te_lightning2(world, w.origin, head.origin);
2203                                 w = head.wp18;if (w) te_lightning2(world, w.origin, head.origin);
2204                                 w = head.wp19;if (w) te_lightning2(world, w.origin, head.origin);
2205                                 w = head.wp20;if (w) te_lightning2(world, w.origin, head.origin);
2206                                 w = head.wp21;if (w) te_lightning2(world, w.origin, head.origin);
2207                                 w = head.wp22;if (w) te_lightning2(world, w.origin, head.origin);
2208                                 w = head.wp23;if (w) te_lightning2(world, w.origin, head.origin);
2209                                 w = head.wp24;if (w) te_lightning2(world, w.origin, head.origin);
2210                                 w = head.wp25;if (w) te_lightning2(world, w.origin, head.origin);
2211                                 w = head.wp26;if (w) te_lightning2(world, w.origin, head.origin);
2212                                 w = head.wp27;if (w) te_lightning2(world, w.origin, head.origin);
2213                                 w = head.wp28;if (w) te_lightning2(world, w.origin, head.origin);
2214                                 w = head.wp29;if (w) te_lightning2(world, w.origin, head.origin);
2215                                 w = head.wp30;if (w) te_lightning2(world, w.origin, head.origin);
2216                                 w = head.wp31;if (w) te_lightning2(world, w.origin, head.origin);
2217                         }
2218                 }
2219                 player = find(player, classname, "player");
2220         }
2221 };
2222
2223 entity botframe_dangerwaypoint;
2224 void botframe_updatedangerousobjects(float maxupdate)
2225 {
2226         local entity head, bot_dodgelist;
2227         local vector m1, m2, v;
2228         local float c, d, danger;
2229         c = 0;
2230         bot_dodgelist = findchainfloat(bot_dodge, TRUE);
2231         botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
2232         while (botframe_dangerwaypoint != world)
2233         {
2234                 danger = 0;
2235                 m1 = botframe_dangerwaypoint.mins;
2236                 m2 = botframe_dangerwaypoint.maxs;
2237                 head = bot_dodgelist;
2238                 while (head)
2239                 {
2240                         v = head.origin;
2241                         v_x = bound(m1_x, v_x, m2_x);
2242                         v_y = bound(m1_y, v_y, m2_y);
2243                         v_z = bound(m1_z, v_z, m2_z);
2244                         d = head.bot_dodgerating - vlen(head.origin - v);
2245                         if (d > 0)
2246                         {
2247                                 traceline(head.origin, v, TRUE, world);
2248                                 if (trace_fraction == 1)
2249                                         danger = danger + d;
2250                         }
2251                         head = head.chain;
2252                 }
2253                 botframe_dangerwaypoint.dmg = danger;
2254                 c = c + 1;
2255                 if (c >= maxupdate)
2256                         break;
2257                 botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
2258         }
2259 };
2260
2261
2262 float botframe_spawnedwaypoints;
2263 float botframe_nextthink;
2264 float botframe_nextdangertime;
2265
2266 float autoskill_nextthink;
2267 .float totalfrags_lastcheck;
2268 void autoskill(float factor)
2269 {
2270         float bestbot;
2271         float bestplayer;
2272         entity head;
2273
2274         bestbot = -1;
2275         bestplayer = -1;
2276         FOR_EACH_PLAYER(head)
2277         {
2278                 if(clienttype(head) == CLIENTTYPE_REAL)
2279                         bestplayer = max(bestplayer, head.totalfrags - head.totalfrags_lastcheck);
2280                 else
2281                         bestbot = max(bestbot, head.totalfrags - head.totalfrags_lastcheck);
2282         }
2283
2284         dprint("autoskill: best player got ", ftos(bestplayer), ", ");
2285         dprint("best bot got ", ftos(bestbot), "; ");
2286         if(bestbot < 0 || bestplayer < 0)
2287         {
2288                 dprint("not doing anything\n");
2289                 // don't return, let it reset all counters below
2290         }
2291         else if(bestbot <= bestplayer * factor - 2)
2292         {
2293                 if(cvar("skill") < 17)
2294                 {
2295                         dprint("2 frags difference, increasing skill\n");
2296                         cvar_set("skill", ftos(cvar("skill") + 1));
2297                         bprint("^2SKILL UP!^7 Now at level ", ftos(cvar("skill")), "\n");
2298                 }
2299         }
2300         else if(bestbot >= bestplayer * factor + 2)
2301         {
2302                 if(cvar("skill") > 0)
2303                 {
2304                         dprint("2 frags difference, decreasing skill\n");
2305                         cvar_set("skill", ftos(cvar("skill") - 1));
2306                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(cvar("skill")), "\n");
2307                 }
2308         }
2309         else
2310         {
2311                 dprint("not doing anything\n");
2312                 return;
2313                 // don't reset counters, wait for them to accumulate
2314         }
2315
2316         FOR_EACH_PLAYER(head)
2317                 head.totalfrags_lastcheck = head.totalfrags;
2318 }
2319
2320 float bot_cvar_nextthink;
2321 void bot_serverframe()
2322 {
2323         float realplayers, bots, activerealplayers;
2324         entity head;
2325
2326         if (intermission_running)
2327                 return;
2328
2329         if (time < 2)
2330                 return;
2331
2332         if(time > autoskill_nextthink)
2333         {
2334                 float a;
2335                 a = cvar("skill_auto");
2336                 if(!cvar("g_campaign"))
2337                         if(a)
2338                                 autoskill(a);
2339                 autoskill_nextthink = time + 5;
2340         }
2341
2342         activerealplayers = 0;
2343         realplayers = 0;
2344
2345         FOR_EACH_REALCLIENT(head)
2346         {
2347                 if(head.classname == "player" || g_lms || g_arena)
2348                         ++activerealplayers;
2349                 ++realplayers;
2350         }
2351
2352         // add/remove bots if needed to make sure there are at least
2353         // minplayers+bot_number, or remove all bots if no one is playing
2354         // But don't remove bots immediately on level change, as the real players
2355         // usually haven't rejoined yet
2356         bots_would_leave = FALSE;
2357         if (realplayers || cvar("bot_join_empty") || (currentbots > 0 && time < 5))
2358         {
2359                 float realminplayers, minplayers;
2360                 realminplayers = cvar("minplayers");
2361                 minplayers = max(0, floor(realminplayers));
2362
2363                 float realminbots, minbots;
2364                 if(cvar("bot_vs_human"))
2365                         realminbots = ceil(fabs(cvar("bot_vs_human")) * activerealplayers);
2366                 else
2367                         realminbots = cvar("bot_number");
2368                 minbots = max(0, floor(realminbots));
2369
2370                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
2371                 if(bots > minbots)
2372                         bots_would_leave = TRUE;
2373         }
2374         else
2375         {
2376                 // if there are no players, remove bots
2377                 bots = 0;
2378         }
2379
2380         bot_ignore_bots = cvar("bot_ignore_bots");
2381
2382         // only add one bot per frame to avoid utter chaos
2383         if(time > botframe_nextthink)
2384         {
2385                 //dprint(ftos(bots), " ? ", ftos(currentbots), "\n");
2386                 while (currentbots < bots)
2387                 {
2388                         if (bot_spawn() == world)
2389                         {
2390                                 bprint("Can not add bot, server full.\n");
2391                                 botframe_nextthink = time + 10;
2392                                 break;
2393                         }
2394                 }
2395                 while (currentbots > bots)
2396                         bot_removenewest();
2397         }
2398
2399         if(botframe_spawnedwaypoints)
2400         {
2401                 if(cvar("waypoint_benchmark"))
2402                         localcmd("quit\n");
2403         }
2404
2405         if (currentbots > 0 || cvar("g_waypointeditor"))
2406         if (!botframe_spawnedwaypoints)
2407         {
2408                 botframe_spawnedwaypoints = TRUE;
2409                 waypoint_loadall();
2410                 waypoint_schedulerelinkall();
2411         }
2412
2413         if (bot_list)
2414         {
2415                 // cycle the goal token from one bot to the next each frame
2416                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
2417                 //  frame, which causes choppy framerates)
2418                 if (bot_strategytoken_taken)
2419                 {
2420                         bot_strategytoken_taken = FALSE;
2421                         if (bot_strategytoken)
2422                                 bot_strategytoken = bot_strategytoken.nextbot;
2423                         if (!bot_strategytoken)
2424                                 bot_strategytoken = bot_list;
2425                 }
2426
2427                 if (botframe_nextdangertime < time)
2428                 {
2429                         local float interval;
2430                         interval = cvar("bot_ai_dangerdetectioninterval");
2431                         if (botframe_nextdangertime < time - interval * 1.5)
2432                                 botframe_nextdangertime = time;
2433                         botframe_nextdangertime = botframe_nextdangertime + interval;
2434                         botframe_updatedangerousobjects(cvar("bot_ai_dangerdetectionupdates"));
2435                 }
2436         }
2437
2438         if (cvar("g_waypointeditor"))
2439                 botframe_showwaypointlinks();
2440
2441         if(time > bot_cvar_nextthink)
2442         {
2443                 if(currentbots>1)
2444                         bot_custom_weapon_priority_setup();
2445                 bot_cvar_nextthink = time + 5;
2446         }
2447 };