data/qcsrc/server/bot/waypoints.qc

   1 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
   2 // them back to it as well
   3 // (suitable for spawnfunc_waypoint editor)
   4 entity waypoint_spawn(vector m1, vector m2, float f)
   5 {
   6         local entity w;
   7         local vector org;
   8         w = find(world, classname, "waypoint");
   9
  10         if not(f & WAYPOINTFLAG_PERSONAL)
  11         while (w)
  12         {
  13                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
  14                 if (boxesoverlap(m1, m2, w.absmin, w.absmax))
  15                         return w;
  16                 w = find(w, classname, "waypoint");
  17         }
  18
  19         w = spawn();
  20         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  21         w.classname = "waypoint";
  22         w.wpflags = f;
  23         setorigin(w, (m1 + m2) * 0.5);
  24         setsize(w, m1 - w.origin, m2 - w.origin);
  25         if (vlen(w.size) > 0)
  26                 w.wpisbox = TRUE;
  27
  28         if(!w.wpisbox)
  29         {
  30                 setsize(w, PL_MIN - '1 1 0', PL_MAX + '1 1 0');
  31                 if(!move_out_of_solid(w))
  32                 {
  33                         if(!(f & WAYPOINTFLAG_GENERATED))
  34                         {
  35                                 dprint("Killed a waypoint that was stuck in solid at ", vtos(org), "\n");
  36                                 remove(w);
  37                                 return world;
  38                         }
  39                         else
  40                                 dprint("A generated waypoint is stuck in solid at ", vtos(org), "\n");
  41                 }
  42                 setsize(w, '0 0 0', '0 0 0');
  43         }
  44
  45         waypoint_clearlinks(w);
  46         //waypoint_schedulerelink(w);
  47
  48         if (cvar("g_waypointeditor"))
  49         {
  50                 m1 = w.mins;
  51                 m2 = w.maxs;
  52                 setmodel(w, "models/runematch/rune.mdl"); w.effects = EF_LOWPRECISION;
  53                 setsize(w, m1, m2);
  54                 if (w.wpflags & WAYPOINTFLAG_ITEM)
  55                         w.colormod = '1 0 0';
  56                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
  57                         w.colormod = '1 1 0';
  58                 else
  59                         w.colormod = '1 1 1';
  60         }
  61         else
  62                 w.model = "";
  63
  64         return w;
  65 };
  66
  67 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
  68 void waypoint_addlink(entity from, entity to)
  69 {
  70         local float c;
  71
  72         if (from == to)
  73                 return;
  74         if (from.wpflags & WAYPOINTFLAG_NORELINK)
  75                 return;
  76
  77         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
  78         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
  79         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
  80         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
  81         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
  82         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
  83         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
  84         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
  85
  86         if (to.wpisbox || from.wpisbox)
  87         {
  88                 // if either is a box we have to find the nearest points on them to
  89                 // calculate the distance properly
  90                 local vector v1, v2, m1, m2;
  91                 v1 = from.origin;
  92                 m1 = to.absmin;
  93                 m2 = to.absmax;
  94                 v1_x = bound(m1_x, v1_x, m2_x);
  95                 v1_y = bound(m1_y, v1_y, m2_y);
  96                 v1_z = bound(m1_z, v1_z, m2_z);
  97                 v2 = to.origin;
  98                 m1 = from.absmin;
  99                 m2 = from.absmax;
 100                 v2_x = bound(m1_x, v2_x, m2_x);
 101                 v2_y = bound(m1_y, v2_y, m2_y);
 102                 v2_z = bound(m1_z, v2_z, m2_z);
 103                 v2 = to.origin;
 104                 c = vlen(v2 - v1);
 105         }
 106         else
 107                 c = vlen(to.origin - from.origin);
 108
 109         if (from.wp31mincost < c) return;
 110         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 111         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 112         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 113         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 114         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 115         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 116         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 117         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 118         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 119         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 120         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 121         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 122         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 123         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 124         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 125         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 126         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 127         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 128         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 129         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 130         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 131         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 132         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 133         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 134         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 135         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 136         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 137         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 138         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 139         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 140         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 141         from.wp00 = to;from.wp00mincost = c;return;
 142 };
 143
 144 // relink this spawnfunc_waypoint
 145 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 146 // (SLOW!)
 147 void waypoint_think()
 148 {
 149         local entity e;
 150         local vector sv, sm1, sm2, ev, em1, em2, dv;
 151
 152         stepheightvec = cvar("sv_stepheight") * '0 0 1';
 153         bot_navigation_movemode = ((cvar("bot_navigation_ignoreplayers")) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 154
 155         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 156         sm1 = self.origin + self.mins;
 157         sm2 = self.origin + self.maxs;
 158         for(e = world; (e = find(e, classname, "waypoint")); )
 159         {
 160                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 161                 {
 162                         waypoint_addlink(self, e);
 163                         waypoint_addlink(e, self);
 164                 }
 165                 else
 166                 {
 167                         ++relink_total;
 168                         if(!checkpvs(self.origin, e))
 169                         {
 170                                 ++relink_pvsculled;
 171                                 continue;
 172                         }
 173                         sv = e.origin;
 174                         sv_x = bound(sm1_x, sv_x, sm2_x);
 175                         sv_y = bound(sm1_y, sv_y, sm2_y);
 176                         sv_z = bound(sm1_z, sv_z, sm2_z);
 177                         ev = self.origin;
 178                         em1 = e.origin + e.mins;
 179                         em2 = e.origin + e.maxs;
 180                         ev_x = bound(em1_x, ev_x, em2_x);
 181                         ev_y = bound(em1_y, ev_y, em2_y);
 182                         ev_z = bound(em1_z, ev_z, em2_z);
 183                         dv = ev - sv;
 184                         dv_z = 0;
 185                         if (vlen(dv) >= 1050) // max search distance in XY
 186                         {
 187                                 ++relink_lengthculled;
 188                                 continue;
 189                         }
 190                         navigation_testtracewalk = 0;
 191                         if (!self.wpisbox)
 192                         {
 193                                 tracebox(sv - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, sv, FALSE, self);
 194                                 if (!trace_startsolid)
 195                                 {
 196                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 197                                         sv = trace_endpos + '0 0 1';
 198                                 }
 199                         }
 200                         if (!e.wpisbox)
 201                         {
 202                                 tracebox(ev - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, ev, FALSE, e);
 203                                 if (!trace_startsolid)
 204                                 {
 205                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 206                                         ev = trace_endpos + '0 0 1';
 207                                 }
 208                         }
 209                         //traceline(self.origin, e.origin, FALSE, world);
 210                         //if (trace_fraction == 1)
 211                         if (!self.wpisbox && tracewalk(self, sv, PL_MIN, PL_MAX, ev, MOVE_NOMONSTERS))
 212                                 waypoint_addlink(self, e);
 213                         else
 214                                 relink_walkculled += 0.5;
 215                         if (!e.wpisbox && tracewalk(e, ev, PL_MIN, PL_MAX, sv, MOVE_NOMONSTERS))
 216                                 waypoint_addlink(e, self);
 217                         else
 218                                 relink_walkculled += 0.5;
 219                 }
 220         }
 221         navigation_testtracewalk = 0;
 222         self.wplinked = TRUE;
 223 };
 224
 225 void waypoint_clearlinks(entity wp)
 226 {
 227         // clear links to other waypoints
 228         local float f;
 229         f = 10000000;
 230         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = world;
 231         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = world;
 232         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = world;
 233         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = world;
 234
 235         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 236         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 237         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 238         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 239
 240         wp.wplinked = FALSE;
 241 };
 242
 243 // tell a spawnfunc_waypoint to relink
 244 void waypoint_schedulerelink(entity wp)
 245 {
 246         if (wp == world)
 247                 return;
 248         // TODO: add some sort of visible box in edit mode for box waypoints
 249         if (cvar("g_waypointeditor"))
 250         {
 251                 local vector m1, m2;
 252                 m1 = wp.mins;
 253                 m2 = wp.maxs;
 254                 setmodel(wp, "models/runematch/rune.mdl"); wp.effects = EF_LOWPRECISION;
 255                 setsize(wp, m1, m2);
 256                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 257                         wp.colormod = '1 0 0';
 258                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 259                         wp.colormod = '1 1 0';
 260                 else
 261                         wp.colormod = '1 1 1';
 262         }
 263         else
 264                 wp.model = "";
 265         wp.wpisbox = vlen(wp.size) > 0;
 266         wp.enemy = world;
 267         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 268                 wp.owner = world;
 269         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 270                 waypoint_clearlinks(wp);
 271         // schedule an actual relink on next frame
 272         wp.think = waypoint_think;
 273         wp.nextthink = time;
 274         wp.effects = EF_LOWPRECISION;
 275 }
 276
 277 // spawnfunc_waypoint map entity
 278 void spawnfunc_waypoint()
 279 {
 280         setorigin(self, self.origin);
 281         // schedule a relink after other waypoints have had a chance to spawn
 282         waypoint_clearlinks(self);
 283         //waypoint_schedulerelink(self);
 284 };
 285
 286 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 287 void waypoint_remove(entity e)
 288 {
 289         // tell all linked waypoints that they need to relink
 290         waypoint_schedulerelink(e.wp00);
 291         waypoint_schedulerelink(e.wp01);
 292         waypoint_schedulerelink(e.wp02);
 293         waypoint_schedulerelink(e.wp03);
 294         waypoint_schedulerelink(e.wp04);
 295         waypoint_schedulerelink(e.wp05);
 296         waypoint_schedulerelink(e.wp06);
 297         waypoint_schedulerelink(e.wp07);
 298         waypoint_schedulerelink(e.wp08);
 299         waypoint_schedulerelink(e.wp09);
 300         waypoint_schedulerelink(e.wp10);
 301         waypoint_schedulerelink(e.wp11);
 302         waypoint_schedulerelink(e.wp12);
 303         waypoint_schedulerelink(e.wp13);
 304         waypoint_schedulerelink(e.wp14);
 305         waypoint_schedulerelink(e.wp15);
 306         waypoint_schedulerelink(e.wp16);
 307         waypoint_schedulerelink(e.wp17);
 308         waypoint_schedulerelink(e.wp18);
 309         waypoint_schedulerelink(e.wp19);
 310         waypoint_schedulerelink(e.wp20);
 311         waypoint_schedulerelink(e.wp21);
 312         waypoint_schedulerelink(e.wp22);
 313         waypoint_schedulerelink(e.wp23);
 314         waypoint_schedulerelink(e.wp24);
 315         waypoint_schedulerelink(e.wp25);
 316         waypoint_schedulerelink(e.wp26);
 317         waypoint_schedulerelink(e.wp27);
 318         waypoint_schedulerelink(e.wp28);
 319         waypoint_schedulerelink(e.wp29);
 320         waypoint_schedulerelink(e.wp30);
 321         waypoint_schedulerelink(e.wp31);
 322         // and now remove the spawnfunc_waypoint
 323         remove(e);
 324 };
 325
 326 // empties the map of waypoints
 327 void waypoint_removeall()
 328 {
 329         local entity head, next;
 330         head = findchain(classname, "waypoint");
 331         while (head)
 332         {
 333                 next = head.chain;
 334                 remove(head);
 335                 head = next;
 336         }
 337 };
 338
 339 // tell all waypoints to relink
 340 // (is this useful at all?)
 341 void waypoint_schedulerelinkall()
 342 {
 343         local entity head;
 344         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 345         head = findchain(classname, "waypoint");
 346         while (head)
 347         {
 348                 waypoint_schedulerelink(head);
 349                 head = head.chain;
 350         }
 351 };
 352
 353 // Load waypoint links from file
 354 float waypoint_load_links()
 355 {
 356         local string filename, s;
 357         local float file, tokens, c, found;
 358         local entity wp_from, wp_to;
 359         local vector wp_to_pos, wp_from_pos;
 360         filename = strcat("maps/", mapname);
 361         filename = strcat(filename, ".waypoints.cache");
 362         file = fopen(filename, FILE_READ);
 363
 364         if (file < 0)
 365         {
 366                 dprint("waypoint links load from ");
 367                 dprint(filename);
 368                 dprint(" failed\n");
 369                 return FALSE;
 370         }
 371
 372         while (1)
 373         {
 374                 s = fgets(file);
 375                 if (!s)
 376                         break;
 377
 378                 tokens = tokenizebyseparator(s, "*");
 379
 380                 if (tokens!=2)
 381                 {
 382                         // bad file format
 383                         fclose(file);
 384                         return FALSE;
 385                 }
 386
 387                 wp_from_pos     = stov(argv(0));
 388                 wp_to_pos       = stov(argv(1));
 389
 390                 // Search "from" waypoint
 391                 if(wp_from.origin!=wp_from_pos)
 392                 {
 393                         wp_from = findradius(wp_from_pos, 1);
 394                         found = FALSE;
 395                         while(wp_from)
 396                         {
 397                                 if(vlen(wp_from.origin-wp_from_pos)<1)
 398                                 if(wp_from.classname == "waypoint")
 399                                 {
 400                                         found = TRUE;
 401                                         break;
 402                                 }
 403                                 wp_from = wp_from.chain;
 404                         }
 405
 406                         if(!found)
 407                         {
 408                                 // can't find that waypoint
 409                                 fclose(file);
 410                                 return FALSE;
 411                         }
 412                 }
 413
 414                 // Search "to" waypoint
 415                 wp_to = findradius(wp_to_pos, 1);
 416                 found = FALSE;
 417                 while(wp_to)
 418                 {
 419                         if(vlen(wp_to.origin-wp_to_pos)<1)
 420                         if(wp_to.classname == "waypoint")
 421                         {
 422                                 found = TRUE;
 423                                 break;
 424                         }
 425                         wp_to = wp_to.chain;
 426                 }
 427
 428                 if(!found)
 429                 {
 430                         // can't find that waypoint
 431                         fclose(file);
 432                         return FALSE;
 433                 }
 434
 435                 ++c;
 436                 waypoint_addlink(wp_from, wp_to);
 437         }
 438
 439         fclose(file);
 440
 441         dprint("loaded ");
 442         dprint(ftos(c));
 443         dprint(" waypoint links from maps/");
 444         dprint(mapname);
 445         dprint(".waypoints.cache\n");
 446
 447         botframe_cachedwaypointlinks = TRUE;
 448         return TRUE;
 449 };
 450
 451 void waypoint_load_links_hardwired()
 452 {
 453         local string filename, s;
 454         local float file, tokens, c, found;
 455         local entity wp_from, wp_to;
 456         local vector wp_to_pos, wp_from_pos;
 457         filename = strcat("maps/", mapname);
 458         filename = strcat(filename, ".waypoints.hardwired");
 459         file = fopen(filename, FILE_READ);
 460
 461         botframe_loadedforcedlinks = TRUE;
 462
 463         if (file < 0)
 464         {
 465                 dprint("waypoint links load from ");
 466                 dprint(filename);
 467                 dprint(" failed\n");
 468                 return;
 469         }
 470
 471         for (;;)
 472         {
 473                 s = fgets(file);
 474                 if (!s)
 475                         break;
 476
 477                 if(substring(s, 0, 2)=="//")
 478                         continue;
 479
 480                 if(substring(s, 0, 1)=="#")
 481                         continue;
 482
 483                 tokens = tokenizebyseparator(s, "*");
 484
 485                 if (tokens!=2)
 486                         continue;
 487
 488                 wp_from_pos     = stov(argv(0));
 489                 wp_to_pos       = stov(argv(1));
 490
 491                 // Search "from" waypoint
 492                 if(wp_from.origin!=wp_from_pos)
 493                 {
 494                         wp_from = findradius(wp_from_pos, 1);
 495                         found = FALSE;
 496                         while(wp_from)
 497                         {
 498                                 if(vlen(wp_from.origin-wp_from_pos)<1)
 499                                 if(wp_from.classname == "waypoint")
 500                                 {
 501                                         found = TRUE;
 502                                         break;
 503                                 }
 504                                 wp_from = wp_from.chain;
 505                         }
 506
 507                         if(!found)
 508                         {
 509                                 print(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 510                                 continue;
 511                         }
 512                 }
 513
 514                 // Search "to" waypoint
 515                 wp_to = findradius(wp_to_pos, 1);
 516                 found = FALSE;
 517                 while(wp_to)
 518                 {
 519                         if(vlen(wp_to.origin-wp_to_pos)<1)
 520                         if(wp_to.classname == "waypoint")
 521                         {
 522                                 found = TRUE;
 523                                 break;
 524                         }
 525                         wp_to = wp_to.chain;
 526                 }
 527
 528                 if(!found)
 529                 {
 530                         print(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 531                         continue;
 532                 }
 533
 534                 ++c;
 535                 waypoint_addlink(wp_from, wp_to);
 536         }
 537
 538         fclose(file);
 539
 540         dprint("loaded ");
 541         dprint(ftos(c));
 542         dprint(" waypoint links from maps/");
 543         dprint(mapname);
 544         dprint(".waypoints.hardwired\n");
 545 };
 546
 547 // Save all waypoint links to a file
 548 void waypoint_save_links()
 549 {
 550         local string filename, s;
 551         local float file, c, i;
 552         local entity w, link;
 553         filename = strcat("maps/", mapname);
 554         filename = strcat(filename, ".waypoints.cache");
 555         file = fopen(filename, FILE_WRITE);
 556         if (file < 0)
 557         {
 558                 print("waypoint links save to ");
 559                 print(filename);
 560                 print(" failed\n");
 561         }
 562         c = 0;
 563         w = findchain(classname, "waypoint");
 564         while (w)
 565         {
 566                 for(i=0;i<32;++i)
 567                 {
 568                         // :S
 569                         switch(i)
 570                         {
 571                                 //      for i in $(seq -w 0 31); do echo "case $i:link = w.wp$i; break;"; done;
 572                                 case 00:link = w.wp00; break;
 573                                 case 01:link = w.wp01; break;
 574                                 case 02:link = w.wp02; break;
 575                                 case 03:link = w.wp03; break;
 576                                 case 04:link = w.wp04; break;
 577                                 case 05:link = w.wp05; break;
 578                                 case 06:link = w.wp06; break;
 579                                 case 07:link = w.wp07; break;
 580                                 case 08:link = w.wp08; break;
 581                                 case 09:link = w.wp09; break;
 582                                 case 10:link = w.wp10; break;
 583                                 case 11:link = w.wp11; break;
 584                                 case 12:link = w.wp12; break;
 585                                 case 13:link = w.wp13; break;
 586                                 case 14:link = w.wp14; break;
 587                                 case 15:link = w.wp15; break;
 588                                 case 16:link = w.wp16; break;
 589                                 case 17:link = w.wp17; break;
 590                                 case 18:link = w.wp18; break;
 591                                 case 19:link = w.wp19; break;
 592                                 case 20:link = w.wp20; break;
 593                                 case 21:link = w.wp21; break;
 594                                 case 22:link = w.wp22; break;
 595                                 case 23:link = w.wp23; break;
 596                                 case 24:link = w.wp24; break;
 597                                 case 25:link = w.wp25; break;
 598                                 case 26:link = w.wp26; break;
 599                                 case 27:link = w.wp27; break;
 600                                 case 28:link = w.wp28; break;
 601                                 case 29:link = w.wp29; break;
 602                                 case 30:link = w.wp30; break;
 603                                 case 31:link = w.wp31; break;
 604                         }
 605
 606                         if(link==world)
 607                                 continue;
 608
 609                         s = strcat(vtos(w.origin), "*", vtos(link.origin), "\n");
 610                         fputs(file, s);
 611                         ++c;
 612                 }
 613                 w = w.chain;
 614         }
 615         fclose(file);
 616         botframe_cachedwaypointlinks = TRUE;
 617
 618         print("saved ");
 619         print(ftos(c));
 620         print(" waypoints links to maps/");
 621         print(mapname);
 622         print(".waypoints.cache\n");
 623 };
 624
 625 // save waypoints to gamedir/data/maps/mapname.waypoints
 626 void waypoint_saveall()
 627 {
 628         local string filename, s;
 629         local float file, c;
 630         local entity w;
 631         filename = strcat("maps/", mapname);
 632         filename = strcat(filename, ".waypoints");
 633         file = fopen(filename, FILE_WRITE);
 634         if (file >= 0)
 635         {
 636                 c = 0;
 637                 w = findchain(classname, "waypoint");
 638                 while (w)
 639                 {
 640                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 641                         {
 642                                 s = strcat(vtos(w.origin + w.mins), "\n");
 643                                 s = strcat(s, vtos(w.origin + w.maxs));
 644                                 s = strcat(s, "\n");
 645                                 s = strcat(s, ftos(w.wpflags));
 646                                 s = strcat(s, "\n");
 647                                 fputs(file, s);
 648                                 c = c + 1;
 649                         }
 650                         w = w.chain;
 651                 }
 652                 fclose(file);
 653                 bprint("saved ");
 654                 bprint(ftos(c));
 655                 bprint(" waypoints to maps/");
 656                 bprint(mapname);
 657                 bprint(".waypoints\n");
 658         }
 659         else
 660         {
 661                 bprint("waypoint save to ");
 662                 bprint(filename);
 663                 bprint(" failed\n");
 664         }
 665         waypoint_save_links();
 666         botframe_loadedforcedlinks = FALSE;
 667 };
 668
 669 // load waypoints from file
 670 float waypoint_loadall()
 671 {
 672         local string filename, s;
 673         local float file, cwp, cwb, fl;
 674         local vector m1, m2;
 675         cwp = 0;
 676         cwb = 0;
 677         filename = strcat("maps/", mapname);
 678         filename = strcat(filename, ".waypoints");
 679         file = fopen(filename, FILE_READ);
 680         if (file >= 0)
 681         {
 682                 while (1)
 683                 {
 684                         s = fgets(file);
 685                         if (!s)
 686                                 break;
 687                         m1 = stov(s);
 688                         s = fgets(file);
 689                         if (!s)
 690                                 break;
 691                         m2 = stov(s);
 692                         s = fgets(file);
 693                         if (!s)
 694                                 break;
 695                         fl = stof(s);
 696                         waypoint_spawn(m1, m2, fl);
 697                         if (m1 == m2)
 698                                 cwp = cwp + 1;
 699                         else
 700                                 cwb = cwb + 1;
 701                 }
 702                 fclose(file);
 703                 dprint("loaded ");
 704                 dprint(ftos(cwp));
 705                 dprint(" waypoints and ");
 706                 dprint(ftos(cwb));
 707                 dprint(" wayboxes from maps/");
 708                 dprint(mapname);
 709                 dprint(".waypoints\n");
 710         }
 711         else
 712         {
 713                 dprint("waypoint load from ");
 714                 dprint(filename);
 715                 dprint(" failed\n");
 716         }
 717         return cwp + cwb;
 718 };
 719
 720 vector waypoint_fixorigin(vector position)
 721 {
 722         tracebox(position + '0 0 1' * (1 - PL_MIN_z), PL_MIN, PL_MAX, position + '0 0 -512', MOVE_NOMONSTERS, world);
 723         if(trace_fraction < 1)
 724                 position = trace_endpos;
 725         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, world);
 726         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 727         return position;
 728 }
 729
 730 void waypoint_spawnforitem_force(entity e, vector org)
 731 {
 732         local entity w;
 733
 734         // Fix the waypoint altitude if necessary
 735         org = waypoint_fixorigin(org);
 736
 737         // don't spawn an item spawnfunc_waypoint if it already exists
 738         w = findchain(classname, "waypoint");
 739         while (w)
 740         {
 741                 if (w.wpisbox)
 742                 {
 743                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 744                         {
 745                                 e.nearestwaypoint = w;
 746                                 return;
 747                         }
 748                 }
 749                 else
 750                 {
 751                         if (vlen(w.origin - org) < 16)
 752                         {
 753                                 e.nearestwaypoint = w;
 754                                 return;
 755                         }
 756                 }
 757                 w = w.chain;
 758         }
 759         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 760 }
 761
 762 void waypoint_spawnforitem(entity e)
 763 {
 764         if(!bot_waypoints_for_items)
 765                 return;
 766
 767         waypoint_spawnforitem_force(e, e.origin);
 768 };
 769
 770 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 771 {
 772         local entity w;
 773         local entity dw;
 774         w = waypoint_spawn(e.absmin, e.absmax, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 775         dw = waypoint_spawn(destination, destination, WAYPOINTFLAG_GENERATED);
 776         // one way link to the destination
 777         w.wp00 = dw;
 778         w.wp00mincost = timetaken; // this is just for jump pads
 779         // the teleporter's nearest spawnfunc_waypoint is this one
 780         // (teleporters are not goals, so this is probably useless)
 781         e.nearestwaypoint = w;
 782         e.nearestwaypointtimeout = time + 1000000000;
 783 };
 784
 785 entity waypoint_spawnpersonal(vector position)
 786 {
 787         entity w;
 788
 789         // drop the waypoint to a proper location:
 790         //   first move it up by a player height
 791         //   then move it down to hit the floor with player bbox size
 792         position = waypoint_fixorigin(position);
 793
 794         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 795         w.nearestwaypoint = world;
 796         w.nearestwaypointtimeout = 0;
 797         w.owner = self;
 798
 799         waypoint_schedulerelink(w);
 800
 801         return w;
 802 };
 803
 804 void botframe_showwaypointlinks()
 805 {
 806         local entity player, head, w;
 807         if (time < botframe_waypointeditorlightningtime)
 808                 return;
 809         botframe_waypointeditorlightningtime = time + 0.5;
 810         player = find(world, classname, "player");
 811         while (player)
 812         {
 813                 if (!player.isbot)
 814                 if (player.flags & FL_ONGROUND || player.waterlevel > WATERLEVEL_NONE)
 815                 {
 816                         //navigation_testtracewalk = TRUE;
 817                         head = navigation_findnearestwaypoint(player, FALSE);
 818                 //      print("currently selected WP is ", etos(head), "\n");
 819                         //navigation_testtracewalk = FALSE;
 820                         if (head)
 821                         {
 822                                 w = head     ;if (w) te_lightning2(world, w.origin, player.origin);
 823                                 w = head.wp00;if (w) te_lightning2(world, w.origin, head.origin);
 824                                 w = head.wp01;if (w) te_lightning2(world, w.origin, head.origin);
 825                                 w = head.wp02;if (w) te_lightning2(world, w.origin, head.origin);
 826                                 w = head.wp03;if (w) te_lightning2(world, w.origin, head.origin);
 827                                 w = head.wp04;if (w) te_lightning2(world, w.origin, head.origin);
 828                                 w = head.wp05;if (w) te_lightning2(world, w.origin, head.origin);
 829                                 w = head.wp06;if (w) te_lightning2(world, w.origin, head.origin);
 830                                 w = head.wp07;if (w) te_lightning2(world, w.origin, head.origin);
 831                                 w = head.wp08;if (w) te_lightning2(world, w.origin, head.origin);
 832                                 w = head.wp09;if (w) te_lightning2(world, w.origin, head.origin);
 833                                 w = head.wp10;if (w) te_lightning2(world, w.origin, head.origin);
 834                                 w = head.wp11;if (w) te_lightning2(world, w.origin, head.origin);
 835                                 w = head.wp12;if (w) te_lightning2(world, w.origin, head.origin);
 836                                 w = head.wp13;if (w) te_lightning2(world, w.origin, head.origin);
 837                                 w = head.wp14;if (w) te_lightning2(world, w.origin, head.origin);
 838                                 w = head.wp15;if (w) te_lightning2(world, w.origin, head.origin);
 839                                 w = head.wp16;if (w) te_lightning2(world, w.origin, head.origin);
 840                                 w = head.wp17;if (w) te_lightning2(world, w.origin, head.origin);
 841                                 w = head.wp18;if (w) te_lightning2(world, w.origin, head.origin);
 842                                 w = head.wp19;if (w) te_lightning2(world, w.origin, head.origin);
 843                                 w = head.wp20;if (w) te_lightning2(world, w.origin, head.origin);
 844                                 w = head.wp21;if (w) te_lightning2(world, w.origin, head.origin);
 845                                 w = head.wp22;if (w) te_lightning2(world, w.origin, head.origin);
 846                                 w = head.wp23;if (w) te_lightning2(world, w.origin, head.origin);
 847                                 w = head.wp24;if (w) te_lightning2(world, w.origin, head.origin);
 848                                 w = head.wp25;if (w) te_lightning2(world, w.origin, head.origin);
 849                                 w = head.wp26;if (w) te_lightning2(world, w.origin, head.origin);
 850                                 w = head.wp27;if (w) te_lightning2(world, w.origin, head.origin);
 851                                 w = head.wp28;if (w) te_lightning2(world, w.origin, head.origin);
 852                                 w = head.wp29;if (w) te_lightning2(world, w.origin, head.origin);
 853                                 w = head.wp30;if (w) te_lightning2(world, w.origin, head.origin);
 854                                 w = head.wp31;if (w) te_lightning2(world, w.origin, head.origin);
 855                         }
 856                 }
 857                 player = find(player, classname, "player");
 858         }
 859 };