data/qcsrc/server/bot/navigation.qc

   1
   2 // rough simulation of walking from one point to another to test if a path
   3 // can be traveled, used for waypoint linking and havocbot
   4
   5 float tracewalk(entity e, vector start, vector m1, vector m2, vector end, float movemode)
   6 {
   7         local vector org;
   8         local vector move;
   9         local vector dir;
  10         local float dist;
  11         local float totaldist;
  12         local float stepdist;
  13         local float yaw;
  14         local float ignorehazards;
  15         local float swimming;
  16
  17         #ifdef DEBUG_TRACEWALK
  18                 debugresetnodes();
  19                 debugnode(start);
  20         #endif
  21
  22         move = end - start;
  23         move_z = 0;
  24         org = start;
  25         dist = totaldist = vlen(move);
  26         dir = normalize(move);
  27         stepdist = 32;
  28         ignorehazards = FALSE;
  29
  30         // Analyze starting point
  31         traceline(start, start, MOVE_NORMAL, e);
  32         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  33                 ignorehazards = TRUE;
  34         else
  35         {
  36                 traceline( start, start + '0 0 -65536', MOVE_NORMAL, e);
  37                 if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  38                 {
  39                         ignorehazards = TRUE;
  40                         swimming = TRUE;
  41                 }
  42         }
  43         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
  44         if (trace_startsolid)
  45         {
  46                 // Bad start
  47                 #ifdef DEBUG_TRACEWALK
  48                         debugnodestatus(start, DEBUG_NODE_FAIL);
  49                 #endif
  50                 //print("tracewalk: ", vtos(start), " is a bad start\n");
  51                 return FALSE;
  52         }
  53
  54         // Movement loop
  55         yaw = vectoyaw(move);
  56         move = end - org;
  57         for (;;)
  58         {
  59                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
  60                 {
  61                         // Succeeded
  62                         #ifdef DEBUG_TRACEWALK
  63                                 debugnodestatus(org, DEBUG_NODE_SUCCESS);
  64                         #endif
  65                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
  66                         return TRUE;
  67                 }
  68                 #ifdef DEBUG_TRACEWALK
  69                         debugnode(org);
  70                 #endif
  71
  72                 if (dist <= 0)
  73                         break;
  74                 if (stepdist > dist)
  75                         stepdist = dist;
  76                 dist = dist - stepdist;
  77                 traceline(org, org, MOVE_NORMAL, e);
  78                 if (!ignorehazards)
  79                 {
  80                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  81                         {
  82                                 // hazards blocking path
  83                                 #ifdef DEBUG_TRACEWALK
  84                                         debugnodestatus(org, DEBUG_NODE_FAIL);
  85                                 #endif
  86                                 //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
  87                                 return FALSE;
  88                         }
  89                 }
  90                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
  91                 {
  92                         move = normalize(end - org);
  93                         tracebox(org, m1, m2, org + move * stepdist, movemode, e);
  94
  95                         #ifdef DEBUG_TRACEWALK
  96                                 debugnode(trace_endpos);
  97                         #endif
  98
  99                         if (trace_fraction < 1)
 100                         {
 101                                 swimming = TRUE;
 102                                 org = trace_endpos - normalize(org - trace_endpos) * stepdist;
 103                                 for(; org_z < end_z + self.maxs_z; org_z += stepdist)
 104                                 {
 105                                                 #ifdef DEBUG_TRACEWALK
 106                                                         debugnode(org);
 107                                                 #endif
 108                                         if(pointcontents(org) == CONTENT_EMPTY)
 109                                                         break;
 110                                 }
 111
 112                                 if not (pointcontents(org + '0 0 1') == CONTENT_EMPTY)
 113                                 {
 114                                         #ifdef DEBUG_TRACEWALK
 115                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 116                                         #endif
 117                                         return FALSE;
 118                                         //print("tracewalk: ", vtos(start), " failed under water\n");
 119                                 }
 120                                 continue;
 121
 122                         }
 123                         else
 124                                 org = trace_endpos;
 125                 }
 126                 else
 127                 {
 128                         move = dir * stepdist + org;
 129                         tracebox(org, m1, m2, move, movemode, e);
 130
 131                         #ifdef DEBUG_TRACEWALK
 132                                 debugnode(trace_endpos);
 133                         #endif
 134
 135                         // hit something
 136                         if (trace_fraction < 1)
 137                         {
 138                                 // check if we can walk over this obstacle
 139                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 140                                 if (trace_fraction < 1 || trace_startsolid)
 141                                 {
 142                                         #ifdef DEBUG_TRACEWALK
 143                                                 debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 144                                         #endif
 145
 146                                         // check for doors
 147                                         traceline( org, move, movemode, e);
 148                                         if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 149                                         {
 150                                                 local vector nextmove;
 151                                                 move = trace_endpos;
 152                                                 while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 153                                                 {
 154                                                         nextmove = move + (dir * stepdist);
 155                                                         traceline( move, nextmove, movemode, e);
 156                                                         move = nextmove;
 157                                                 }
 158                                         }
 159                                         else
 160                                         {
 161                                                 #ifdef DEBUG_TRACEWALK
 162                                                         debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 163                                                 #endif
 164                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 165                                                 //te_explosion(trace_endpos);
 166                                                 //print(ftos(e.dphitcontentsmask), "\n");
 167                                                 return FALSE; // failed
 168                                         }
 169                                 }
 170                                 else
 171                                         move = trace_endpos;
 172                         }
 173                         else
 174                                 move = trace_endpos;
 175
 176                         // trace down from stepheight as far as possible and move there,
 177                         // if this starts in solid we try again without the stepup, and
 178                         // if that also fails we assume it is a wall
 179                         // (this is the same logic as the Quake walkmove function used)
 180                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 181
 182                         // moved successfully
 183                         if(swimming)
 184                         {
 185                                 local float c;
 186                                 c = pointcontents(org + '0 0 1');
 187                                 if not(c == CONTENT_WATER || c == CONTENT_LAVA || c == CONTENT_SLIME)
 188                                         swimming = FALSE;
 189                                 else
 190                                         continue;
 191                         }
 192
 193                         org = trace_endpos;
 194                 }
 195         }
 196
 197         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 198
 199         // moved but didn't arrive at the intended destination
 200         #ifdef DEBUG_TRACEWALK
 201                 debugnodestatus(org, DEBUG_NODE_FAIL);
 202         #endif
 203
 204         return FALSE;
 205 };
 206
 207 /////////////////////////////////////////////////////////////////////////////
 208 // goal stack
 209 /////////////////////////////////////////////////////////////////////////////
 210
 211 // completely empty the goal stack, used when deciding where to go
 212 void navigation_clearroute()
 213 {
 214         //print("bot ", etos(self), " clear\n");
 215         self.navigation_hasgoals = FALSE;
 216         self.goalcurrent = world;
 217         self.goalstack01 = world;
 218         self.goalstack02 = world;
 219         self.goalstack03 = world;
 220         self.goalstack04 = world;
 221         self.goalstack05 = world;
 222         self.goalstack06 = world;
 223         self.goalstack07 = world;
 224         self.goalstack08 = world;
 225         self.goalstack09 = world;
 226         self.goalstack10 = world;
 227         self.goalstack11 = world;
 228         self.goalstack12 = world;
 229         self.goalstack13 = world;
 230         self.goalstack14 = world;
 231         self.goalstack15 = world;
 232         self.goalstack16 = world;
 233         self.goalstack17 = world;
 234         self.goalstack18 = world;
 235         self.goalstack19 = world;
 236         self.goalstack20 = world;
 237         self.goalstack21 = world;
 238         self.goalstack22 = world;
 239         self.goalstack23 = world;
 240         self.goalstack24 = world;
 241         self.goalstack25 = world;
 242         self.goalstack26 = world;
 243         self.goalstack27 = world;
 244         self.goalstack28 = world;
 245         self.goalstack29 = world;
 246         self.goalstack30 = world;
 247         self.goalstack31 = world;
 248 };
 249
 250 // add a new goal at the beginning of the stack
 251 // (in other words: add a new prerequisite before going to the later goals)
 252 void navigation_pushroute(entity e)
 253 {
 254         //print("bot ", etos(self), " push ", etos(e), "\n");
 255         self.goalstack31 = self.goalstack30;
 256         self.goalstack30 = self.goalstack29;
 257         self.goalstack29 = self.goalstack28;
 258         self.goalstack28 = self.goalstack27;
 259         self.goalstack27 = self.goalstack26;
 260         self.goalstack26 = self.goalstack25;
 261         self.goalstack25 = self.goalstack24;
 262         self.goalstack24 = self.goalstack23;
 263         self.goalstack23 = self.goalstack22;
 264         self.goalstack22 = self.goalstack21;
 265         self.goalstack21 = self.goalstack20;
 266         self.goalstack20 = self.goalstack19;
 267         self.goalstack19 = self.goalstack18;
 268         self.goalstack18 = self.goalstack17;
 269         self.goalstack17 = self.goalstack16;
 270         self.goalstack16 = self.goalstack15;
 271         self.goalstack15 = self.goalstack14;
 272         self.goalstack14 = self.goalstack13;
 273         self.goalstack13 = self.goalstack12;
 274         self.goalstack12 = self.goalstack11;
 275         self.goalstack11 = self.goalstack10;
 276         self.goalstack10 = self.goalstack09;
 277         self.goalstack09 = self.goalstack08;
 278         self.goalstack08 = self.goalstack07;
 279         self.goalstack07 = self.goalstack06;
 280         self.goalstack06 = self.goalstack05;
 281         self.goalstack05 = self.goalstack04;
 282         self.goalstack04 = self.goalstack03;
 283         self.goalstack03 = self.goalstack02;
 284         self.goalstack02 = self.goalstack01;
 285         self.goalstack01 = self.goalcurrent;
 286         self.goalcurrent = e;
 287 };
 288
 289 // remove first goal from stack
 290 // (in other words: remove a prerequisite for reaching the later goals)
 291 // (used when a spawnfunc_waypoint is reached)
 292 void navigation_poproute()
 293 {
 294         //print("bot ", etos(self), " pop\n");
 295         self.goalcurrent = self.goalstack01;
 296         self.goalstack01 = self.goalstack02;
 297         self.goalstack02 = self.goalstack03;
 298         self.goalstack03 = self.goalstack04;
 299         self.goalstack04 = self.goalstack05;
 300         self.goalstack05 = self.goalstack06;
 301         self.goalstack06 = self.goalstack07;
 302         self.goalstack07 = self.goalstack08;
 303         self.goalstack08 = self.goalstack09;
 304         self.goalstack09 = self.goalstack10;
 305         self.goalstack10 = self.goalstack11;
 306         self.goalstack11 = self.goalstack12;
 307         self.goalstack12 = self.goalstack13;
 308         self.goalstack13 = self.goalstack14;
 309         self.goalstack14 = self.goalstack15;
 310         self.goalstack15 = self.goalstack16;
 311         self.goalstack16 = self.goalstack17;
 312         self.goalstack17 = self.goalstack18;
 313         self.goalstack18 = self.goalstack19;
 314         self.goalstack19 = self.goalstack20;
 315         self.goalstack20 = self.goalstack21;
 316         self.goalstack21 = self.goalstack22;
 317         self.goalstack22 = self.goalstack23;
 318         self.goalstack23 = self.goalstack24;
 319         self.goalstack24 = self.goalstack25;
 320         self.goalstack25 = self.goalstack26;
 321         self.goalstack26 = self.goalstack27;
 322         self.goalstack27 = self.goalstack28;
 323         self.goalstack28 = self.goalstack29;
 324         self.goalstack29 = self.goalstack30;
 325         self.goalstack30 = self.goalstack31;
 326         self.goalstack31 = world;
 327 };
 328
 329 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 330 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 331 {
 332         local entity waylist, w, best;
 333         local float dist, bestdist;
 334         local vector v, org, pm1, pm2;
 335         pm1 = ent.origin + ent.mins;
 336         pm2 = ent.origin + ent.maxs;
 337         waylist = findchain(classname, "waypoint");
 338
 339         // do two scans, because box test is cheaper
 340         w = waylist;
 341         while (w)
 342         {
 343                 // if object is touching spawnfunc_waypoint
 344                 if(w != ent)
 345                         if (boxesoverlap(pm1, pm2, w.absmin, w.absmax))
 346                                 return w;
 347                 w = w.chain;
 348         }
 349
 350         org = ent.origin + 0.5 * (ent.mins + ent.maxs);
 351         org_z = ent.origin_z + ent.mins_z - PL_MIN_z; // player height
 352         // TODO possibly make other code have the same support for bboxes
 353         if(ent.tag_entity)
 354                 org = org + ent.tag_entity.origin;
 355         if (navigation_testtracewalk)
 356                 te_plasmaburn(org);
 357
 358         best = world;
 359         bestdist = 1050;
 360
 361         // box check failed, try walk
 362         w = waylist;
 363         while (w)
 364         {
 365                 // if object can walk from spawnfunc_waypoint
 366                 if(w != ent)
 367                 {
 368                         if (w.wpisbox)
 369                         {
 370                                 local vector wm1, wm2;
 371                                 wm1 = w.origin + w.mins;
 372                                 wm2 = w.origin + w.maxs;
 373                                 v_x = bound(wm1_x, org_x, wm2_x);
 374                                 v_y = bound(wm1_y, org_y, wm2_y);
 375                                 v_z = bound(wm1_z, org_z, wm2_z);
 376                         }
 377                         else
 378                                 v = w.origin;
 379                         dist = vlen(v - org);
 380                         if (bestdist > dist)
 381                         {
 382                                 traceline(v, org, TRUE, ent);
 383                                 if (trace_fraction == 1)
 384                                 {
 385                                         if (walkfromwp)
 386                                         {
 387                                                 //print("^1can I reach ", vtos(org), " from ", vtos(v), "?\n");
 388                                                 if (tracewalk(ent, v, PL_MIN, PL_MAX, org, bot_navigation_movemode))
 389                                                 {
 390                                                         bestdist = dist;
 391                                                         best = w;
 392                                                 }
 393                                         }
 394                                         else
 395                                         {
 396                                                 if (tracewalk(ent, org, PL_MIN, PL_MAX, v, bot_navigation_movemode))
 397                                                 {
 398                                                         bestdist = dist;
 399                                                         best = w;
 400                                                 }
 401                                         }
 402                                 }
 403                         }
 404                 }
 405                 w = w.chain;
 406         }
 407         return best;
 408 }
 409
 410 // finds the waypoints near the bot initiating a navigation query
 411 float navigation_markroutes_nearestwaypoints(entity waylist, float maxdist)
 412 {
 413         local entity head;
 414         local vector v, m1, m2, diff;
 415         local float c;
 416 //      navigation_testtracewalk = TRUE;
 417         c = 0;
 418         head = waylist;
 419         while (head)
 420         {
 421                 if (!head.wpconsidered)
 422                 {
 423                         if (head.wpisbox)
 424                         {
 425                                 m1 = head.origin + head.mins;
 426                                 m2 = head.origin + head.maxs;
 427                                 v = self.origin;
 428                                 v_x = bound(m1_x, v_x, m2_x);
 429                                 v_y = bound(m1_y, v_y, m2_y);
 430                                 v_z = bound(m1_z, v_z, m2_z);
 431                         }
 432                         else
 433                                 v = head.origin;
 434                         diff = v - self.origin;
 435                         diff_z = max(0, diff_z);
 436                         if (vlen(diff) < maxdist)
 437                         {
 438                                 head.wpconsidered = TRUE;
 439                                 if (tracewalk(self, self.origin, self.mins, self.maxs, v, bot_navigation_movemode))
 440                                 {
 441                                         head.wpnearestpoint = v;
 442                                         head.wpcost = vlen(v - self.origin) + head.dmg;
 443                                         head.wpfire = 1;
 444                                         head.enemy = world;
 445                                         c = c + 1;
 446                                 }
 447                         }
 448                 }
 449                 head = head.chain;
 450         }
 451         //navigation_testtracewalk = FALSE;
 452         return c;
 453 }
 454
 455 // updates a path link if a spawnfunc_waypoint link is better than the current one
 456 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost2, vector p)
 457 {
 458         local vector m1;
 459         local vector m2;
 460         local vector v;
 461         if (wp.wpisbox)
 462         {
 463                 m1 = wp.absmin;
 464                 m2 = wp.absmax;
 465                 v_x = bound(m1_x, p_x, m2_x);
 466                 v_y = bound(m1_y, p_y, m2_y);
 467                 v_z = bound(m1_z, p_z, m2_z);
 468         }
 469         else
 470                 v = wp.origin;
 471         cost2 = cost2 + vlen(v - p);
 472         if (wp.wpcost > cost2)
 473         {
 474                 wp.wpcost = cost2;
 475                 wp.enemy = w;
 476                 wp.wpfire = 1;
 477                 wp.wpnearestpoint = v;
 478         }
 479 };
 480
 481 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 482 void navigation_markroutes()
 483 {
 484         local entity w, wp, waylist;
 485         local float searching, cost, cost2;
 486         local vector p;
 487         w = waylist = findchain(classname, "waypoint");
 488         while (w)
 489         {
 490                 w.wpconsidered = FALSE;
 491                 w.wpnearestpoint = '0 0 0';
 492                 w.wpcost = 10000000;
 493                 w.wpfire = 0;
 494                 w.enemy = world;
 495                 w = w.chain;
 496         }
 497
 498         // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 499         // as this search is expensive we will use lower values if the bot is on the air
 500         local float i, increment, maxdistance;
 501         if(self.flags & FL_ONGROUND)
 502         {
 503                 increment = 750;
 504                 maxdistance = 50000;
 505         }
 506         else
 507         {
 508                 increment = 500;
 509                 maxdistance = 1500;
 510         }
 511
 512         for(i=increment;!navigation_markroutes_nearestwaypoints(waylist, i)&&i<maxdistance;i+=increment);
 513
 514         searching = TRUE;
 515         while (searching)
 516         {
 517                 searching = FALSE;
 518                 w = waylist;
 519                 while (w)
 520                 {
 521                         if (w.wpfire)
 522                         {
 523                                 searching = TRUE;
 524                                 w.wpfire = 0;
 525                                 cost = w.wpcost;
 526                                 p = w.wpnearestpoint;
 527                                 wp = w.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp00mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 528                                 wp = w.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp01mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 529                                 wp = w.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp02mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 530                                 wp = w.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp03mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 531                                 wp = w.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp04mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 532                                 wp = w.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp05mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 533                                 wp = w.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp06mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 534                                 wp = w.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp07mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 535                                 wp = w.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp08mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 536                                 wp = w.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp09mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 537                                 wp = w.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp10mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 538                                 wp = w.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp11mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 539                                 wp = w.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp12mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 540                                 wp = w.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp13mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 541                                 wp = w.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp14mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 542                                 wp = w.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp15mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 543                                 wp = w.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp16mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 544                                 wp = w.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp17mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 545                                 wp = w.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp18mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 546                                 wp = w.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp19mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 547                                 wp = w.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp20mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 548                                 wp = w.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp21mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 549                                 wp = w.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp22mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 550                                 wp = w.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp23mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 551                                 wp = w.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp24mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 552                                 wp = w.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp25mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 553                                 wp = w.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp26mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 554                                 wp = w.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp27mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 555                                 wp = w.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp28mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 556                                 wp = w.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp29mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 557                                 wp = w.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp30mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 558                                 wp = w.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp31mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 559                                 }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 560                         }
 561                         w = w.chain;
 562                 }
 563         }
 564 };
 565
 566 void navigation_bestgoals_reset()
 567 {
 568         local float i;
 569
 570         bestgoalswindex = 0;
 571         bestgoalsrindex = 0;
 572
 573         for(i=0;i>MAX_BESTGOALS-1;++i)
 574         {
 575                 navigation_bestgoals[i] = world;
 576         }
 577 }
 578
 579 void navigation_add_bestgoal(entity goal)
 580 {
 581         if(bestgoalsrindex>0)
 582         {
 583                 ++bestgoalsrindex;
 584
 585                 if(bestgoalsrindex==MAX_BESTGOALS)
 586                         bestgoalsrindex = 0;
 587         }
 588
 589         if(bestgoalswindex==MAX_BESTGOALS)
 590         {
 591                 bestgoalswindex=0;
 592                 if(bestgoalsrindex==0)
 593                         bestgoalsrindex=1;
 594         }
 595
 596         navigation_bestgoals[bestgoalswindex] = goal;
 597
 598         ++bestgoalswindex;
 599 }
 600
 601 entity navigation_get_bestgoal()
 602 {
 603         local entity ent;
 604
 605         ent = navigation_bestgoals[bestgoalsrindex];
 606         navigation_bestgoals[bestgoalsrindex] = world;
 607
 608         ++bestgoalsrindex;
 609
 610         if(bestgoalsrindex==MAX_BESTGOALS)
 611                 bestgoalsrindex = 0;
 612
 613         return ent;
 614 }
 615
 616 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
 617 void navigation_routerating(entity e, float f, float rangebias)
 618 {
 619         entity nwp;
 620         if (!e)
 621                 return;
 622
 623         // Evaluate path using jetpack
 624         if(g_jetpack)
 625         if(self.items & IT_JETPACK)
 626         if(cvar("bot_ai_navigation_jetpack"))
 627         if(vlen(self.origin - e.origin) > cvar("bot_ai_navigation_jetpack_mindistance"))
 628         {
 629                 vector pointa, pointb;
 630
 631         //      dprint("jetpack ai: evaluating path for ", e.classname,"\n");
 632
 633                 // Point A
 634                 traceline(self.origin, self.origin + '0 0 65535', MOVE_NORMAL, self);
 635                 pointa = trace_endpos - '0 0 1';
 636
 637                 // Point B
 638                 traceline(e.origin, e.origin + '0 0 65535', MOVE_NORMAL, e);
 639                 pointb = trace_endpos - '0 0 1';
 640
 641                 // Can I see these two points from the sky?
 642                 traceline(pointa, pointb, MOVE_NORMAL, self);
 643
 644                 if(trace_fraction==1)
 645                 {
 646                 //      dprint("jetpack ai: can bridge these two points\n");
 647
 648                         // Lower the altitude of these points as much as possible
 649                         local float zdistance, xydistance, cost, t, fuel;
 650                         local vector down, npa, npb;
 651
 652                         down = '0 0 -1' * (PL_MAX_z - PL_MIN_z) * 10;
 653
 654                         do{
 655                                 npa = pointa + down;
 656                                 npb = pointb + down;
 657
 658                                 if(npa_z<=self.absmax_z)
 659                                         break;
 660
 661                                 if(npb_z<=e.absmax_z)
 662                                         break;
 663
 664                                 traceline(npa, npb, MOVE_NORMAL, self);
 665                                 if(trace_fraction==1)
 666                                 {
 667                                         pointa = npa;
 668                                         pointb = npb;
 669                                 }
 670                         }
 671                         while(trace_fraction == 1);
 672
 673
 674                         // Rough estimation of fuel consumption
 675                         // (ignores acceleration and current xyz velocity)
 676                         xydistance = vlen(pointa - pointb);
 677                         zdistance = fabs(pointa_z - self.origin_z);
 678
 679                         t = zdistance / cvar("g_jetpack_maxspeed_up");
 680                         t += xydistance / cvar("g_jetpack_maxspeed_side");
 681                         fuel = t * cvar("g_jetpack_fuel") * 0.8;
 682
 683                 //      dprint("jetpack ai: required fuel ", ftos(fuel), " self.ammo_fuel ", ftos(self.ammo_fuel),"\n");
 684
 685                         // enough fuel ?
 686                         if(self.ammo_fuel>fuel)
 687                         {
 688                                 // Estimate cost
 689                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
 690                                 //  - between air and ground speeds)
 691
 692                                 cost = xydistance / (cvar("g_jetpack_maxspeed_side")/cvar("sv_maxspeed"));
 693                                 cost += zdistance / (cvar("g_jetpack_maxspeed_up")/cvar("sv_maxspeed"));
 694                                 cost *= 1.5;
 695
 696                                 // Compare against other goals
 697                                 f = f * rangebias / (rangebias + cost);
 698
 699                                 if (navigation_bestrating < f)
 700                                 {
 701                         //              dprint("jetpack path: added goal", e.classname, " (with rating ", ftos(f), ")\n");
 702                                         navigation_bestrating = f;
 703                                         navigation_add_bestgoal(e);
 704                                         self.navigation_jetpack_goal = e;
 705                                         self.navigation_jetpack_point = pointb;
 706                                 }
 707                                 return;
 708                         }
 709                 }
 710         }
 711
 712         //te_wizspike(e.origin);
 713         //bprint(etos(e));
 714         //bprint("\n");
 715         // update the cached spawnfunc_waypoint link on a dynamic item entity
 716         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
 717         {
 718                 nwp = e;
 719         }
 720         else
 721         {
 722                 if (time > e.nearestwaypointtimeout)
 723                 {
 724                         nwp = navigation_findnearestwaypoint(e, TRUE);
 725                         if(nwp)
 726                                 e.nearestwaypoint = nwp;
 727                         else
 728                                 print("FAILED to find a nearest waypoint to ", etos(e), "\n");
 729
 730                         // TODO: Cleaner solution, probably handling this timeout from ctf.qc
 731                         if(e.classname=="item_flag_team")
 732                                 e.nearestwaypointtimeout = time + 2;
 733                         else
 734                                 e.nearestwaypointtimeout = time + random() * 3 + 5;
 735                 }
 736                 nwp = e.nearestwaypoint;
 737         }
 738
 739         //dprint("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")\n");
 740         if (nwp)
 741         if (nwp.wpcost < 10000000)
 742         {
 743                 //te_wizspike(nwp.wpnearestpoint);
 744         //      dprint(e.classname, " ", ftos(f), "/(1+", ftos((nwp.wpcost + vlen(e.origin - nwp.wpnearestpoint))), "/", ftos(rangebias), ") = ");
 745                 f = f * rangebias / (rangebias + (nwp.wpcost + vlen(e.origin - nwp.wpnearestpoint)));
 746                 //dprint("considering ", e.classname, " (with rating ", ftos(f), ")\n");
 747                 //dprint(ftos(f));
 748                 if (navigation_bestrating < f)
 749                 {
 750                 //      dprint("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")\n");
 751                         navigation_bestrating = f;
 752                         navigation_add_bestgoal(e);
 753                 }
 754         }
 755         //dprint("\n");
 756 };
 757
 758 // adds an item to the the goal stack with the path to a given item
 759 float navigation_routetogoal(entity e, vector startposition)
 760 {
 761         self.goalentity = e;
 762
 763         // if there is no goal, just exit
 764         if (!e)
 765                 return FALSE;
 766
 767         self.navigation_hasgoals = TRUE;
 768
 769         // put the entity on the goal stack
 770         navigation_pushroute(e);
 771
 772         if(g_jetpack)
 773         if(e==self.navigation_jetpack_goal)
 774                 return TRUE;
 775
 776         // if it can reach the goal there is nothing more to do
 777         if (tracewalk(self, startposition, PL_MIN, PL_MAX, e.origin, bot_navigation_movemode))
 778                 return TRUE;
 779
 780         // see if there are waypoints describing a path to the item
 781         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
 782                 e = e.nearestwaypoint;
 783         else
 784                 e = e.enemy; // we already have added it, so...
 785
 786         if(e == world)
 787                 return FALSE;
 788
 789         for (;;)
 790         {
 791                 // add the spawnfunc_waypoint to the path
 792                 navigation_pushroute(e);
 793                 e = e.enemy;
 794
 795                 if(e==world)
 796                         break;
 797         }
 798
 799         return FALSE;
 800 };
 801
 802 void navigation_routetogoals()
 803 {
 804         entity g1, g2;
 805
 806         navigation_clearroute();
 807
 808         g1 = navigation_get_bestgoal();
 809         for(;;)
 810         {
 811                 if(g2==world)
 812                         g2 = navigation_get_bestgoal();
 813
 814                 if(g2==world)
 815                 {
 816                         navigation_routetogoal(g1, self.origin);
 817                         return;
 818                 }
 819
 820                 if(navigation_routetogoal(g1, g2.origin))
 821                 {
 822                         g1 = g2;
 823                         g2 = world;
 824                         continue;
 825                 }
 826
 827                 navigation_clearroute();
 828                 g1 = g2;
 829                 g2 = world;
 830         }
 831 }
 832
 833 // removes any currently touching waypoints from the goal stack
 834 // (this is how bots detect if they reached a goal)
 835 void navigation_poptouchedgoals()
 836 {
 837         local vector org, m1, m2;
 838         org = self.origin;
 839         m1 = org + self.mins;
 840         m2 = org + self.maxs;
 841
 842         if(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 843         {
 844                 if(self.lastteleporttime>0)
 845                 if(time-self.lastteleporttime<0.15)
 846                 {
 847                         navigation_poproute();
 848                         return;
 849                 }
 850         }
 851
 852         // Loose goal touching check when running
 853         if(self.aistatus & AI_STATUS_RUNNING)
 854         if(self.goalcurrent.classname=="waypoint")
 855         {
 856                 if(vlen(self.origin - self.goalcurrent.origin)<150)
 857                 {
 858                         traceline(self.origin + self.view_ofs , self.goalcurrent.origin, TRUE, world);
 859                         if(trace_fraction==1)
 860                         {
 861                                 // Detect personal waypoints
 862                                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 863                                 if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 864                                 {
 865                                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 866                                         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 867                                 }
 868
 869                                 navigation_poproute();
 870                         }
 871                 }
 872         }
 873
 874         while (self.goalcurrent && boxesoverlap(m1, m2, self.goalcurrent.absmin, self.goalcurrent.absmax))
 875         {
 876                 // Detect personal waypoints
 877                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 878                 if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 879                 {
 880                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 881                         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 882                 }
 883
 884                 navigation_poproute();
 885         }
 886 }
 887
 888 // begin a goal selection session (queries spawnfunc_waypoint network)
 889 void navigation_goalrating_start()
 890 {
 891         self.navigation_jetpack_goal = world;
 892         navigation_bestrating = -1;
 893         self.navigation_hasgoals = FALSE;
 894         navigation_bestgoals_reset();
 895         navigation_markroutes();
 896 };
 897
 898 // ends a goal selection session (updates goal stack to the best goal)
 899 void navigation_goalrating_end()
 900 {
 901         navigation_routetogoals();
 902 //      dprint("best goal ", self.goalcurrent.classname , "\n");
 903
 904         // Hack: if it can't walk to any goal just move blindly to the first visible waypoint
 905         if not (self.navigation_hasgoals)
 906         {
 907                 dprint(self.netname, " can't walk to any goal, going to a near waypoint\n");
 908
 909                 entity head;
 910
 911                 RandomSelection_Init();
 912                 head = findradius(self.origin,1000);
 913                 while(head)
 914                 {
 915                         if(head.classname=="waypoint")
 916                         if(!(head.wpflags & WAYPOINTFLAG_GENERATED))
 917                         if(vlen(self.origin-head.origin)>100)
 918                         if(checkpvs(self.view_ofs,head))
 919                                 RandomSelection_Add(head, 0, string_null, 1 + (vlen(self.origin-head.origin)<500), 0);
 920                         head = head.chain;
 921                 }
 922                 if(RandomSelection_chosen_ent)
 923                         navigation_routetogoal(RandomSelection_chosen_ent, self.origin);
 924
 925                 self.navigation_hasgoals = FALSE; // Reset this value
 926         }
 927 };
 928
 929 void botframe_updatedangerousobjects(float maxupdate)
 930 {
 931         local entity head, bot_dodgelist;
 932         local vector m1, m2, v;
 933         local float c, d, danger;
 934         c = 0;
 935         bot_dodgelist = findchainfloat(bot_dodge, TRUE);
 936         botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
 937         while (botframe_dangerwaypoint != world)
 938         {
 939                 danger = 0;
 940                 m1 = botframe_dangerwaypoint.mins;
 941                 m2 = botframe_dangerwaypoint.maxs;
 942                 head = bot_dodgelist;
 943                 while (head)
 944                 {
 945                         v = head.origin;
 946                         v_x = bound(m1_x, v_x, m2_x);
 947                         v_y = bound(m1_y, v_y, m2_y);
 948                         v_z = bound(m1_z, v_z, m2_z);
 949                         d = head.bot_dodgerating - vlen(head.origin - v);
 950                         if (d > 0)
 951                         {
 952                                 traceline(head.origin, v, TRUE, world);
 953                                 if (trace_fraction == 1)
 954                                         danger = danger + d;
 955                         }
 956                         head = head.chain;
 957                 }
 958                 botframe_dangerwaypoint.dmg = danger;
 959                 c = c + 1;
 960                 if (c >= maxupdate)
 961                         break;
 962                 botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
 963         }
 964 };
 965
 966 #ifdef DEBUG_TRACEWALK
 967
 968 void debugresetnodes()
 969 {
 970         debuglastnode = '0 0 0';
 971 }
 972
 973 void debugnode(vector node)
 974 {
 975         if not(self.classname=="player")
 976                 return;
 977
 978         if(debuglastnode=='0 0 0')
 979         {
 980                 debuglastnode = node;
 981                 return;
 982         }
 983
 984         te_lightning2(world, node, debuglastnode);
 985         debuglastnode = node;
 986 }
 987
 988 void debugnodestatus(vector position, float status)
 989 {
 990         vector color;
 991
 992         switch (status)
 993         {
 994                 case DEBUG_NODE_SUCCESS:
 995                         color = '0 15 0';
 996                         break;
 997                 case DEBUG_NODE_WARNING:
 998                         color = '15 15 0';
 999                         break;
1000                 case DEBUG_NODE_FAIL:
1001                         color = '15 0 0';
1002                         break;
1003                 default:
1004                         color = '15 15 15';
1005         }
1006
1007         te_customflash(position, 40,  2, color);
1008 }
1009
1010 #endif
1011
1012 #ifdef DEBUG_BOT_GOALSTACK
1013
1014 .float goalcounter;
1015 .vector lastposition;
1016
1017 // Debug the goal stack visually
1018 void debuggoalstack()
1019 {
1020         local entity target;
1021         local vector org;
1022
1023         if(self.goalcounter==0)target=self.goalcurrent;
1024         else if(self.goalcounter==1)target=self.goalstack01;
1025         else if(self.goalcounter==2)target=self.goalstack02;
1026         else if(self.goalcounter==3)target=self.goalstack03;
1027         else if(self.goalcounter==4)target=self.goalstack04;
1028         else if(self.goalcounter==5)target=self.goalstack05;
1029         else if(self.goalcounter==6)target=self.goalstack06;
1030         else if(self.goalcounter==7)target=self.goalstack07;
1031         else if(self.goalcounter==8)target=self.goalstack08;
1032         else if(self.goalcounter==9)target=self.goalstack09;
1033         else if(self.goalcounter==10)target=self.goalstack10;
1034         else if(self.goalcounter==11)target=self.goalstack11;
1035         else if(self.goalcounter==12)target=self.goalstack12;
1036         else if(self.goalcounter==13)target=self.goalstack13;
1037         else if(self.goalcounter==14)target=self.goalstack14;
1038         else if(self.goalcounter==15)target=self.goalstack15;
1039         else if(self.goalcounter==16)target=self.goalstack16;
1040         else if(self.goalcounter==17)target=self.goalstack17;
1041         else if(self.goalcounter==18)target=self.goalstack18;
1042         else if(self.goalcounter==19)target=self.goalstack19;
1043         else if(self.goalcounter==20)target=self.goalstack20;
1044         else if(self.goalcounter==21)target=self.goalstack21;
1045         else if(self.goalcounter==22)target=self.goalstack22;
1046         else if(self.goalcounter==23)target=self.goalstack23;
1047         else if(self.goalcounter==24)target=self.goalstack24;
1048         else if(self.goalcounter==25)target=self.goalstack25;
1049         else if(self.goalcounter==26)target=self.goalstack26;
1050         else if(self.goalcounter==27)target=self.goalstack27;
1051         else if(self.goalcounter==28)target=self.goalstack28;
1052         else if(self.goalcounter==29)target=self.goalstack29;
1053         else if(self.goalcounter==30)target=self.goalstack30;
1054         else if(self.goalcounter==31)target=self.goalstack31;
1055
1056         if(target==world)
1057         {
1058                 self.goalcounter = 0;
1059                 self.lastposition='0 0 0';
1060                 return;
1061         }
1062
1063         if(self.lastposition=='0 0 0')
1064                 org = self.origin;
1065         else
1066                 org = self.lastposition;
1067
1068
1069         te_lightning2(world, org, target.origin);
1070         self.lastposition = target.origin;
1071
1072         self.goalcounter++;
1073 }
1074
1075 #endif