data/qcsrc/menu-div0test/nexuiz/dialog_multiplayer_create.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizServerCreateTab) EXTENDS(NexuizTab)
   3         METHOD(NexuizServerCreateTab, fill, void(entity))
   4         METHOD(NexuizServerCreateTab, gameTypeChangeNotify, void(entity))
   5         ATTRIB(NexuizServerCreateTab, title, string, "Create")
   6         ATTRIB(NexuizServerCreateTab, intendedWidth, float, 0.9)
   7         ATTRIB(NexuizServerCreateTab, rows, float, 22)
   8         ATTRIB(NexuizServerCreateTab, columns, float, 6.5)
   9
  10         ATTRIB(NexuizServerCreateTab, mapListBox, entity, NULL)
  11         ATTRIB(NexuizServerCreateTab, sliderFraglimit, entity, NULL)
  12         ATTRIB(NexuizServerCreateTab, sliderTimelimit, entity, NULL)
  13         ATTRIB(NexuizServerCreateTab, checkboxFraglimit, entity, NULL)
  14 ENDCLASS(NexuizServerCreateTab)
  15 entity makeNexuizServerCreateTab();
  16 #endif
  17
  18 #ifdef IMPLEMENTATION
  19
  20 entity makeNexuizServerCreateTab()
  21 {
  22         entity me;
  23         me = spawnNexuizServerCreateTab();
  24         me.configureDialog(me);
  25         return me;
  26 }
  27
  28 void fillNexuizServerCreateTab(entity me)
  29 {
  30         entity e, e0;
  31         float n;
  32
  33         me.TR(me);
  34                 n = 8 + 2 * !!cvar("developer");
  35                 me.TD(me, 2, me.columns / n, e = makeNexuizGametypeButton(1, "g_dm", "DM"));
  36                         e0 = e;
  37                 me.TD(me, 2, me.columns / n, e = makeNexuizGametypeButton(1, "g_tdm", "TDM"));
  38                         if(e.checked) e0 = NULL;
  39                 me.TD(me, 2, me.columns / n, e = makeNexuizGametypeButton(1, "g_lms", "LMS"));
  40                         if(e.checked) e0 = NULL;
  41                 me.TD(me, 2, me.columns / n, e = makeNexuizGametypeButton(1, "g_arena", "Arena"));
  42                         if(e.checked) e0 = NULL;
  43                 me.TD(me, 2, me.columns / n, e = makeNexuizGametypeButton(1, "g_runematch", "Rune"));
  44                         if(e.checked) e0 = NULL;
  45                 me.TD(me, 2, me.columns / n, e = makeNexuizGametypeButton(1, "g_domination", "Dom"));
  46                         if(e.checked) e0 = NULL;
  47                 me.TD(me, 2, me.columns / n, e = makeNexuizGametypeButton(1, "g_keyhunt", "Key Hunt"));
  48                         if(e.checked) e0 = NULL;
  49                 me.TD(me, 2, me.columns / n, e = makeNexuizGametypeButton(1, "g_ctf", "CTF"));
  50                         if(e.checked) e0 = NULL;
  51                 if(cvar("developer"))
  52                 {
  53                         me.TD(me, 2, me.columns / n, e = makeNexuizGametypeButton(1, "g_assault", "Assault"));
  54                                 if(e.checked) e0 = NULL;
  55                         me.TD(me, 2, me.columns / n, e = makeNexuizGametypeButton(1, "g_onslaught", "Onslaught"));
  56                                 if(e.checked) e0 = NULL;
  57                 }
  58                 if(e0)
  59                 {
  60                         //print("NO CHECK\n");
  61                         e0.setChecked(e0, 1);
  62                 }
  63         me.TR(me);
  64         me.TR(me);
  65         me.TR(me);
  66                 me.TD(me, 1, 3, e = makeNexuizTextLabel(0, "Map list:"));
  67         me.TR(me);
  68                 me.TD(me, me.rows - 6, 3, e = makeNexuizMapList());
  69                 me.mapListBox = e;
  70         me.gotoXY(me, me.rows - 2, 0);
  71                 me.TDempty(me, 0.5);
  72                 me.TD(me, 1, 1, e = makeNexuizButton("All", '0 0 0'));
  73                         e.onClick = MapList_All;
  74                         e.onClickEntity = me.mapListBox;
  75                 me.TD(me, 1, 1, e = makeNexuizButton("None", '0 0 0'));
  76                         e.onClick = MapList_None;
  77                         e.onClickEntity = me.mapListBox;
  78                 me.TDempty(me, 0.5);
  79
  80         me.gotoXY(me, 3, 3.5); me.setFirstColumn(me, me.currentColumn);
  81                 me.TD(me, 1, 3, e = makeNexuizTextLabel(0, "Settings:"));
  82         me.TR(me);
  83                 me.sliderTimelimit = makeNexuizSlider(1.0, 60.0, 0.5, "timelimit_override");
  84                 me.TD(me, 1, 1, e = makeNexuizSliderCheckBox(0, 1, me.sliderTimelimit, "Time limit:"));
  85                 me.TD(me, 1, 2, me.sliderTimelimit);
  86         me.TR(me);
  87                 me.TDempty(me, 0.2);
  88                 me.TD(me, 1, 2.8, e = makeNexuizSliderCheckBox(-1, 0, me.sliderTimelimit, "Use map specified default"));
  89         me.TR(me);
  90                 me.sliderFraglimit = makeNexuizSlider(1.0, 2000.0, 5, "fraglimit_override");
  91                 me.TD(me, 1, 1, e = makeNexuizSliderCheckBox(0, 1, me.sliderFraglimit, "Point limit:"));
  92                         me.checkboxFraglimit = e;
  93                 me.TD(me, 1, 2, me.sliderFraglimit);
  94         me.TR(me);
  95                 me.TDempty(me, 0.2);
  96                 me.TD(me, 1, 2.8, e = makeNexuizSliderCheckBox(-1, 0, me.sliderFraglimit, "Use map specified default"));
  97         me.TR(me);
  98                 me.TD(me, 1, 1, e = makeNexuizButton("Mutators...", '0 0 0'));
  99                         e.onClick = DialogOpenButton_Click;
 100                         e.onClickEntity = main.mutatorsDialog;
 101                         main.mutatorsDialog.refilterEntity = me.mapListBox;
 102
 103         me.gotoXY(me, me.rows - 1, 0);
 104                 me.TD(me, 1, me.columns, e = makeNexuizButton("Start!", '0 0 0'));
 105                         e.onClick = MapList_LoadMap;
 106                         e.onClickEntity = me.mapListBox;
 107                         me.mapListBox.startButton = e;
 108
 109         me.gameTypeChangeNotify(me);
 110 }
 111
 112 void GameType_ConfigureSliders(entity e, entity l, string pLabel, float pMin, float pMax, float pStep, string pCvar)
 113 {
 114         e.configureNexuizSlider(e, pMin, pMax, pStep, pCvar);
 115         l.setText(l, pLabel);
 116 }
 117
 118 void gameTypeChangeNotifyNexuizServerCreateTab(entity me)
 119 {
 120         // tell the map list to update
 121         float gt;
 122         entity e, l;
 123         gt = MapInfo_CurrentGametype();
 124         e = me.sliderFraglimit;
 125         l = me.checkboxFraglimit;
 126         switch(gt)
 127         {
 128                 case MAPINFO_TYPE_CTF:        GameType_ConfigureSliders(e, l, "Point limit:",  50,  500, 10, "g_ctf_capture_limit");      break;
 129                 case MAPINFO_TYPE_DOMINATION: GameType_ConfigureSliders(e, l, "Point limit:",  50,  500, 10, "g_domination_point_limit"); break;
 130                 case MAPINFO_TYPE_KEYHUNT:    GameType_ConfigureSliders(e, l, "Point limit:", 200, 1500, 50, "g_keyhunt_point_limit");    break;
 131                 case MAPINFO_TYPE_RUNEMATCH:  GameType_ConfigureSliders(e, l, "Point limit:",  50,  500, 10, "g_runematch_point_limit");  break;
 132                 case MAPINFO_TYPE_LMS:        GameType_ConfigureSliders(e, l, "Lives:",         3,   50,  1, "g_lms_lives_override");     break;
 133                 default:                      GameType_ConfigureSliders(e, l, "Frag limit:",    5,  100,  5, "fraglimit_override");       break;
 134         }
 135         me.mapListBox.refilter(me.mapListBox);
 136 }
 137
 138 #endif